code.delx.au - gnu-emacs/blob - lisp/smerge-mode.el

   1 ;;; smerge-mode.el --- Minor mode to resolve diff3 conflicts
   2
   3 ;; Copyright (C) 1999, 2000, 01, 03, 2004  Free Software Foundation, Inc.
   4
   5 ;; Author: Stefan Monnier <monnier@cs.yale.edu>
   6 ;; Keywords: revision-control merge diff3 cvs conflict
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Provides a lightweight alternative to emerge/ediff.
  28 ;; To use it, simply add to your .emacs the following lines:
  29 ;;
  30 ;;   (autoload 'smerge-mode "smerge-mode" nil t)
  31 ;;
  32 ;; you can even have it turned on automatically with the following
  33 ;; piece of code in your .emacs:
  34 ;;
  35 ;;   (defun sm-try-smerge ()
  36 ;;     (save-excursion
  37 ;;       (goto-char (point-min))
  38 ;;       (when (re-search-forward "^<<<<<<< " nil t)
  39 ;;         (smerge-mode 1))))
  40 ;;   (add-hook 'find-file-hook 'sm-try-smerge t)
  41
  42 ;;; Todo:
  43
  44 ;; - if requested, ask the user whether he wants to call ediff right away
  45
  46 ;;; Code:
  47
  48 (eval-when-compile (require 'cl))
  49
  50
  51 (defgroup smerge ()
  52   "Minor mode to resolve diff3 conflicts."
  53   :group 'tools
  54   :prefix "smerge-")
  55
  56 (defcustom smerge-diff-buffer-name "*vc-diff*"
  57   "Buffer name to use for displaying diffs."
  58   :group 'smerge
  59   :type '(choice
  60           (const "*vc-diff*")
  61           (const "*cvs-diff*")
  62           (const "*smerge-diff*")
  63           string))
  64
  65 (defcustom smerge-diff-switches
  66   (append '("-d" "-b")
  67           (if (listp diff-switches) diff-switches (list diff-switches)))
  68   "*A list of strings specifying switches to be be passed to diff.
  69 Used in `smerge-diff-base-mine' and related functions."
  70   :group 'smerge
  71   :type '(repeat string))
  72
  73 (defcustom smerge-auto-leave t
  74   "*Non-nil means to leave `smerge-mode' when the last conflict is resolved."
  75   :group 'smerge
  76   :type 'boolean)
  77
  78 (defface smerge-mine-face
  79   '((((background light))
  80      (:foreground "blue"))
  81     (((background dark))
  82      (:foreground "cyan")))
  83   "Face for your code."
  84   :group 'smerge)
  85 (defvar smerge-mine-face 'smerge-mine-face)
  86
  87 (defface smerge-other-face
  88   '((((background light))
  89      (:foreground "darkgreen"))
  90     (((background dark))
  91      (:foreground "lightgreen")))
  92   "Face for the other code."
  93   :group 'smerge)
  94 (defvar smerge-other-face 'smerge-other-face)
  95
  96 (defface smerge-base-face
  97   '((((background light))
  98      (:foreground "red"))
  99     (((background dark))
 100      (:foreground "orange")))
 101   "Face for the base code."
 102   :group 'smerge)
 103 (defvar smerge-base-face 'smerge-base-face)
 104
 105 (defface smerge-markers-face
 106   '((((background light))
 107      (:background "grey85"))
 108     (((background dark))
 109      (:background "grey30")))
 110   "Face for the conflict markers."
 111   :group 'smerge)
 112 (defvar smerge-markers-face 'smerge-markers-face)
 113
 114 (easy-mmode-defmap smerge-basic-map
 115   `(("n" . smerge-next)
 116     ("p" . smerge-prev)
 117     ("r" . smerge-resolve)
 118     ("a" . smerge-keep-all)
 119     ("b" . smerge-keep-base)
 120     ("o" . smerge-keep-other)
 121     ("m" . smerge-keep-mine)
 122     ("E" . smerge-ediff)
 123     ("\C-m" . smerge-keep-current)
 124     ("=" . ,(make-sparse-keymap "Diff"))
 125     ("=<" "base-mine" . smerge-diff-base-mine)
 126     ("=>" "base-other" . smerge-diff-base-other)
 127     ("==" "mine-other" . smerge-diff-mine-other))
 128   "The base keymap for `smerge-mode'.")
 129
 130 (defcustom smerge-command-prefix "\C-c^"
 131   "Prefix for `smerge-mode' commands."
 132   :group 'smerge
 133   :type '(choice (string "\e") (string "\C-c^") (string "") string))
 134
 135 (easy-mmode-defmap smerge-mode-map
 136   `((,smerge-command-prefix . ,smerge-basic-map))
 137   "Keymap for `smerge-mode'.")
 138
 139 (defvar smerge-check-cache nil)
 140 (make-variable-buffer-local 'smerge-check-cache)
 141 (defun smerge-check (n)
 142   (condition-case nil
 143       (let ((state (cons (point) (buffer-modified-tick))))
 144         (unless (equal (cdr smerge-check-cache) state)
 145           (smerge-match-conflict)
 146           (setq smerge-check-cache (cons (match-data) state)))
 147         (nth (* 2 n) (car smerge-check-cache)))
 148     (error nil)))
 149
 150 (easy-menu-define smerge-mode-menu smerge-mode-map
 151   "Menu for `smerge-mode'."
 152   '("SMerge"
 153     ["Next" smerge-next :help "Go to next conflict"]
 154     ["Previous" smerge-prev :help "Go to previous conflict"]
 155     "--"
 156     ["Keep All" smerge-keep-all :help "Keep all three versions"
 157      :active (smerge-check 1)]
 158     ["Keep Current" smerge-keep-current :help "Use current (at point) version"
 159      :active (and (smerge-check 1) (> (smerge-get-current) 0))]
 160     "--"
 161     ["Revert to Base" smerge-keep-base :help "Revert to base version"
 162      :active (smerge-check 2)]
 163     ["Keep Other" smerge-keep-other :help "Keep `other' version"
 164      :active (smerge-check 3)]
 165     ["Keep Yours" smerge-keep-mine :help "Keep your version"
 166      :active (smerge-check 1)]
 167     "--"
 168     ["Diff Base/Mine" smerge-diff-base-mine
 169      :help "Diff `base' and `mine' for current conflict"
 170      :active (smerge-check 2)]
 171     ["Diff Base/Other" smerge-diff-base-other
 172      :help "Diff `base' and `other' for current conflict"
 173      :active (smerge-check 2)]
 174     ["Diff Mine/Other" smerge-diff-mine-other
 175      :help "Diff `mine' and `other' for current conflict"
 176      :active (smerge-check 1)]
 177     "--"
 178     ["Invoke Ediff" smerge-ediff
 179      :help "Use Ediff to resolve the conflicts"
 180      :active (smerge-check 1)]
 181     ["Auto Resolve" smerge-resolve
 182      :help "Use mode-provided resolution function"
 183      :active (and (smerge-check 1) (local-variable-p 'smerge-resolve-function))]
 184     ["Combine" smerge-combine-with-next
 185      :help "Combine current conflict with next"
 186      :active (smerge-check 1)]
 187     ))
 188
 189 (easy-mmode-defmap smerge-context-menu-map
 190   `(([down-mouse-3] . smerge-activate-context-menu))
 191   "Keymap for context menu appeared on conflicts area.")
 192 (easy-menu-define smerge-context-menu nil
 193   "Context menu for mine area in `smerge-mode'."
 194   '(nil
 195     ["Keep Current" smerge-keep-current :help "Use current (at point) version"]
 196     ["Kill Current" smerge-kill-current :help "Remove current (at point) version"]
 197     ["Keep All" smerge-keep-all :help "Keep all three versions"]
 198     "---"
 199     ["More..." (popup-menu smerge-mode-menu) :help "Show full SMerge mode menu"]
 200     ))
 201
 202 (defconst smerge-font-lock-keywords
 203   '((smerge-find-conflict
 204      (1 smerge-mine-face prepend t)
 205      (2 smerge-base-face prepend t)
 206      (3 smerge-other-face prepend t)
 207      ;; FIXME: `keep' doesn't work right with syntactic fontification.
 208      (0 smerge-markers-face keep)
 209      (4 nil t t)
 210      (5 nil t t)))
 211   "Font lock patterns for `smerge-mode'.")
 212
 213 (defconst smerge-begin-re "^<<<<<<< \\(.*\\)\n")
 214 (defconst smerge-end-re "^>>>>>>> .*\n")
 215 (defconst smerge-base-re "^||||||| .*\n")
 216 (defconst smerge-other-re "^=======\n")
 217
 218 (defvar smerge-conflict-style nil
 219   "Keep track of which style of conflict is in use.
 220 Can be nil if the style is undecided, or else:
 221 - `diff3-E'
 222 - `diff3-A'")
 223
 224 ;; Compiler pacifiers
 225 (defvar font-lock-mode)
 226 (defvar font-lock-keywords)
 227
 228 ;;;;
 229 ;;;; Actual code
 230 ;;;;
 231
 232 ;; Define smerge-next and smerge-prev
 233 (easy-mmode-define-navigation smerge smerge-begin-re "conflict")
 234
 235 (defconst smerge-match-names ["conflict" "mine" "base" "other"])
 236
 237 (defun smerge-ensure-match (n)
 238   (unless (match-end n)
 239     (error (format "No `%s'" (aref smerge-match-names n)))))
 240
 241 (defun smerge-auto-leave ()
 242   (when (and smerge-auto-leave
 243              (save-excursion (goto-char (point-min))
 244                              (not (re-search-forward smerge-begin-re nil t))))
 245     (smerge-mode -1)))
 246
 247
 248 (defun smerge-keep-all ()
 249   "Keep all three versions.
 250 Convenient for the kind of conflicts that can arise in ChangeLog files."
 251   (interactive)
 252   (smerge-match-conflict)
 253   (replace-match (concat (or (match-string 1) "")
 254                          (or (match-string 2) "")
 255                          (or (match-string 3) ""))
 256                  t t)
 257   (smerge-auto-leave))
 258
 259 (defun smerge-combine-with-next ()
 260   "Combine the current conflict with the next one."
 261   (interactive)
 262   (smerge-match-conflict)
 263   (let ((ends nil))
 264     (dolist (i '(3 2 1 0))
 265       (push (if (match-end i) (copy-marker (match-end i) t)) ends))
 266     (setq ends (apply 'vector ends))
 267     (goto-char (aref ends 0))
 268     (if (not (re-search-forward smerge-begin-re nil t))
 269         (error "No next conflict")
 270       (smerge-match-conflict)
 271       (let ((match-data (mapcar (lambda (m) (if m (copy-marker m)))
 272                                 (match-data))))
 273         ;; First copy the in-between text in each alternative.
 274         (dolist (i '(1 2 3))
 275           (when (aref ends i)
 276             (goto-char (aref ends i))
 277             (insert-buffer-substring (current-buffer)
 278                                      (aref ends 0) (car match-data))))
 279         (delete-region (aref ends 0) (car match-data))
 280         ;; Then move the second conflict's alternatives into the first.
 281         (dolist (i '(1 2 3))
 282           (set-match-data match-data)
 283           (when (and (aref ends i) (match-end i))
 284             (goto-char (aref ends i))
 285             (insert-buffer-substring (current-buffer)
 286                                      (match-beginning i) (match-end i))))
 287         (delete-region (car match-data) (cadr match-data))
 288         ;; Free the markers.
 289         (dolist (m match-data) (if m (move-marker m nil)))
 290         (mapc (lambda (m) (if m (move-marker m nil))) ends)))))
 291
 292 (defvar smerge-resolve-function
 293   (lambda () (error "Don't know how to resolve"))
 294   "Mode-specific merge function.
 295 The function is called with no argument and with the match data set
 296 according to `smerge-match-conflict'.")
 297
 298 (defvar smerge-text-properties
 299   `(help-echo "merge conflict: mouse-3 shows a menu"
 300     ;; mouse-face highlight
 301     keymap (keymap (down-mouse-3 . smerge-popup-context-menu))))
 302
 303 (defun smerge-remove-props (&optional beg end)
 304   (remove-text-properties
 305    (or beg (match-beginning 0))
 306    (or end (match-end 0))
 307    smerge-text-properties))
 308
 309 (defun smerge-popup-context-menu (event)
 310   "Pop up the Smerge mode context menu under mouse."
 311   (interactive "e")
 312   (if (and smerge-mode
 313           (save-excursion (mouse-set-point event) (smerge-check 1)))
 314       (progn
 315        (mouse-set-point event)
 316        (smerge-match-conflict)
 317        (let ((i (smerge-get-current))
 318              o)
 319          (if (<= i 0)
 320              ;; Out of range
 321              (popup-menu smerge-mode-menu)
 322            ;; Install overlay.
 323            (setq o (make-overlay (match-beginning i) (match-end i)))
 324            (unwind-protect
 325                (progn
 326                  (overlay-put o 'face 'highlight)
 327                  (sit-for 0)
 328                  (popup-menu (if (smerge-check 2)
 329                                  smerge-mode-menu
 330                                smerge-context-menu)))
 331              ;; Delete overlay.
 332              (delete-overlay o)))))
 333     ;; There's no conflict at point, the text-props are just obsolete.
 334     (save-excursion
 335       (let ((beg (re-search-backward smerge-end-re nil t))
 336            (end (re-search-forward smerge-begin-re nil t)))
 337        (smerge-remove-props (or beg (point-min)) (or end (point-max)))
 338        (push event unread-command-events)))))
 339
 340 (defun smerge-resolve ()
 341   "Resolve the conflict at point intelligently.
 342 This relies on mode-specific knowledge and thus only works in
 343 some major modes.  Uses `smerge-resolve-function' to do the actual work."
 344   (interactive)
 345   (smerge-match-conflict)
 346   (smerge-remove-props)
 347   (funcall smerge-resolve-function)
 348   (smerge-auto-leave))
 349
 350 (defun smerge-keep-base ()
 351   "Revert to the base version."
 352   (interactive)
 353   (smerge-match-conflict)
 354   (smerge-ensure-match 2)
 355   (smerge-remove-props)
 356   (replace-match (match-string 2) t t)
 357   (smerge-auto-leave))
 358
 359 (defun smerge-keep-other ()
 360   "Use \"other\" version."
 361   (interactive)
 362   (smerge-match-conflict)
 363   ;;(smerge-ensure-match 3)
 364   (smerge-remove-props)
 365   (replace-match (match-string 3) t t)
 366   (smerge-auto-leave))
 367
 368 (defun smerge-keep-mine ()
 369   "Keep your version."
 370   (interactive)
 371   (smerge-match-conflict)
 372   ;;(smerge-ensure-match 1)
 373   (smerge-remove-props)
 374   (replace-match (match-string 1) t t)
 375   (smerge-auto-leave))
 376
 377 (defun smerge-get-current ()
 378   (let ((i 3))
 379     (while (or (not (match-end i))
 380                (< (point) (match-beginning i))
 381                (>= (point) (match-end i)))
 382       (decf i))
 383     i))
 384
 385 (defun smerge-keep-current ()
 386   "Use the current (under the cursor) version."
 387   (interactive)
 388   (smerge-match-conflict)
 389   (let ((i (smerge-get-current)))
 390     (if (<= i 0) (error "Not inside a version")
 391       (smerge-remove-props)
 392       (replace-match (match-string i) t t)
 393       (smerge-auto-leave))))
 394
 395 (defun smerge-kill-current ()
 396   "Remove the current (under the cursor) version."
 397   (interactive)
 398   (smerge-match-conflict)
 399   (let ((i (smerge-get-current)))
 400     (if (<= i 0) (error "Not inside a version")
 401       (smerge-remove-props)
 402       (replace-match (mapconcat
 403                       (lambda (j)
 404                         (match-string j))
 405                       (remove i '(1 2 3)) "") t t)
 406       (smerge-auto-leave))))
 407
 408 (defun smerge-diff-base-mine ()
 409   "Diff 'base' and 'mine' version in current conflict region."
 410   (interactive)
 411   (smerge-diff 2 1))
 412
 413 (defun smerge-diff-base-other ()
 414   "Diff 'base' and 'other' version in current conflict region."
 415   (interactive)
 416   (smerge-diff 2 3))
 417
 418 (defun smerge-diff-mine-other ()
 419   "Diff 'mine' and 'other' version in current conflict region."
 420   (interactive)
 421   (smerge-diff 1 3))
 422
 423 (defun smerge-match-conflict ()
 424   "Get info about the conflict.  Puts the info in the `match-data'.
 425 The submatches contain:
 426  0:  the whole conflict.
 427  1:  your code.
 428  2:  the base code.
 429  3:  other code.
 430 An error is raised if not inside a conflict."
 431   (save-excursion
 432     (condition-case nil
 433         (let* ((orig-point (point))
 434
 435                (_ (forward-line 1))
 436                (_ (re-search-backward smerge-begin-re))
 437
 438                (start (match-beginning 0))
 439                (mine-start (match-end 0))
 440                (filename (or (match-string 1) ""))
 441
 442                (_ (re-search-forward smerge-end-re))
 443                (_ (assert (< orig-point (match-end 0))))
 444
 445                (other-end (match-beginning 0))
 446                (end (match-end 0))
 447
 448                (_ (re-search-backward smerge-other-re start))
 449
 450                (mine-end (match-beginning 0))
 451                (other-start (match-end 0))
 452
 453                base-start base-end)
 454
 455           ;; handle the various conflict styles
 456           (cond
 457            ((re-search-backward smerge-base-re start t)
 458             ;; a 3-parts conflict
 459             (set (make-local-variable 'smerge-conflict-style) 'diff3-A)
 460             (setq base-end mine-end)
 461             (setq mine-end (match-beginning 0))
 462             (setq base-start (match-end 0)))
 463
 464            ((string= filename (file-name-nondirectory
 465                                (or buffer-file-name "")))
 466             ;; a 2-parts conflict
 467             (set (make-local-variable 'smerge-conflict-style) 'diff3-E))
 468
 469            ((and (not base-start)
 470                  (or (eq smerge-conflict-style 'diff3-A)
 471                      (equal filename "ANCESTOR")
 472                      (string-match "\\`[.0-9]+\\'" filename)))
 473             ;; a same-diff conflict
 474             (setq base-start mine-start)
 475             (setq base-end   mine-end)
 476             (setq mine-start other-start)
 477             (setq mine-end   other-end)))
 478
 479           (let ((inhibit-read-only t)
 480                 (inhibit-modification-hooks t)
 481                 (m (buffer-modified-p)))
 482             (unwind-protect
 483                 (add-text-properties start end smerge-text-properties)
 484               (restore-buffer-modified-p m)))
 485
 486           (store-match-data (list start end
 487                                   mine-start mine-end
 488                                   base-start base-end
 489                                   other-start other-end
 490                                   (when base-start (1- base-start)) base-start
 491                                   (1- other-start) other-start))
 492           t)
 493       (search-failed (error "Point not in conflict region")))))
 494
 495 (defun smerge-find-conflict (&optional limit)
 496   "Find and match a conflict region.  Intended as a font-lock MATCHER.
 497 The submatches are the same as in `smerge-match-conflict'.
 498 Returns non-nil if a match is found between the point and LIMIT.
 499 The point is moved to the end of the conflict."
 500   (when (re-search-forward smerge-begin-re limit t)
 501     (ignore-errors
 502       (smerge-match-conflict)
 503       (goto-char (match-end 0)))))
 504
 505 (defun smerge-diff (n1 n2)
 506   (smerge-match-conflict)
 507   (smerge-ensure-match n1)
 508   (smerge-ensure-match n2)
 509   (let ((name1 (aref smerge-match-names n1))
 510         (name2 (aref smerge-match-names n2))
 511         ;; Read them before the match-data gets clobbered.
 512         (beg1 (match-beginning n1))
 513         (end1 (match-end n1))
 514         (beg2 (match-beginning n2))
 515         (end2 (match-end n2))
 516         (file1 (make-temp-file "smerge1"))
 517         (file2 (make-temp-file "smerge2"))
 518         (dir default-directory)
 519         (file (file-relative-name buffer-file-name))
 520         (coding-system-for-read buffer-file-coding-system))
 521     (write-region beg1 end1 file1 nil 'nomessage)
 522     (write-region beg2 end2 file2 nil 'nomessage)
 523     (unwind-protect
 524         (with-current-buffer (get-buffer-create smerge-diff-buffer-name)
 525           (setq default-directory dir)
 526           (let ((inhibit-read-only t))
 527             (erase-buffer)
 528             (let ((status
 529                    (apply 'call-process diff-command nil t nil
 530                           (append smerge-diff-switches
 531                                   (list "-L" (concat name1 "/" file)
 532                                         "-L" (concat name2 "/" file)
 533                                         file1 file2)))))
 534               (if (eq status 0) (insert "No differences found.\n"))))
 535           (goto-char (point-min))
 536           (diff-mode)
 537           (display-buffer (current-buffer) t))
 538       (delete-file file1)
 539       (delete-file file2))))
 540
 541 ;; compiler pacifiers
 542 (defvar smerge-ediff-windows)
 543 (defvar smerge-ediff-buf)
 544 (defvar ediff-buffer-A)
 545 (defvar ediff-buffer-B)
 546 (defvar ediff-buffer-C)
 547
 548 ;;;###autoload
 549 (defun smerge-ediff (&optional name-mine name-other name-base)
 550   "Invoke ediff to resolve the conflicts.
 551 NAME-MINE, NAME-OTHER, and NAME-BASE, if non-nil, are used for the
 552 buffer names."
 553   (interactive)
 554   (let* ((buf (current-buffer))
 555          (mode major-mode)
 556          ;;(ediff-default-variant 'default-B)
 557          (config (current-window-configuration))
 558          (filename (file-name-nondirectory buffer-file-name))
 559          (mine (generate-new-buffer
 560                 (or name-mine (concat "*" filename " MINE*"))))
 561          (other (generate-new-buffer
 562                  (or name-other (concat "*" filename " OTHER*"))))
 563          base)
 564     (with-current-buffer mine
 565       (buffer-disable-undo)
 566       (insert-buffer-substring buf)
 567       (goto-char (point-min))
 568       (while (smerge-find-conflict)
 569         (when (match-beginning 2) (setq base t))
 570         (replace-match (match-string 1) t t))
 571       (buffer-enable-undo)
 572       (set-buffer-modified-p nil)
 573       (funcall mode))
 574
 575     (with-current-buffer other
 576       (buffer-disable-undo)
 577       (insert-buffer-substring buf)
 578       (goto-char (point-min))
 579       (while (smerge-find-conflict)
 580         (replace-match (match-string 3) t t))
 581       (buffer-enable-undo)
 582       (set-buffer-modified-p nil)
 583       (funcall mode))
 584
 585     (when base
 586       (setq base (generate-new-buffer
 587                   (or name-base (concat "*" filename " BASE*"))))
 588       (with-current-buffer base
 589         (buffer-disable-undo)
 590         (insert-buffer-substring buf)
 591         (goto-char (point-min))
 592         (while (smerge-find-conflict)
 593           (replace-match (or (match-string 2) "") t t))
 594         (buffer-enable-undo)
 595         (set-buffer-modified-p nil)
 596         (funcall mode)))
 597
 598     ;; the rest of the code is inspired from vc.el
 599     ;; Fire up ediff.
 600     (set-buffer
 601      (if base
 602          (ediff-merge-buffers-with-ancestor mine other base)
 603           ;; nil 'ediff-merge-revisions-with-ancestor buffer-file-name)
 604        (ediff-merge-buffers mine other)))
 605         ;; nil 'ediff-merge-revisions buffer-file-name)))
 606
 607     ;; Ediff is now set up, and we are in the control buffer.
 608     ;; Do a few further adjustments and take precautions for exit.
 609     (set (make-local-variable 'smerge-ediff-windows) config)
 610     (set (make-local-variable 'smerge-ediff-buf) buf)
 611     (set (make-local-variable 'ediff-quit-hook)
 612          (lambda ()
 613            (let ((buffer-A ediff-buffer-A)
 614                  (buffer-B ediff-buffer-B)
 615                  (buffer-C ediff-buffer-C)
 616                  (buffer-Ancestor ediff-ancestor-buffer)
 617                  (buf smerge-ediff-buf)
 618                  (windows smerge-ediff-windows))
 619              (ediff-cleanup-mess)
 620              (with-current-buffer buf
 621                (erase-buffer)
 622                (insert-buffer buffer-C)
 623                (kill-buffer buffer-A)
 624                (kill-buffer buffer-B)
 625                (kill-buffer buffer-C)
 626                (when (bufferp buffer-Ancestor) (kill-buffer buffer-Ancestor))
 627                (set-window-configuration windows)
 628                (message "Conflict resolution finished; you may save the buffer")))))
 629     (message "Please resolve conflicts now; exit ediff when done")))
 630
 631
 632 ;;;###autoload
 633 (define-minor-mode smerge-mode
 634   "Minor mode to simplify editing output from the diff3 program.
 635 \\{smerge-mode-map}"
 636   nil " SMerge" nil
 637   (when (and (boundp 'font-lock-mode) font-lock-mode)
 638     (set (make-local-variable 'font-lock-multiline) t)
 639     (save-excursion
 640       (if smerge-mode
 641           (font-lock-add-keywords nil smerge-font-lock-keywords 'append)
 642         (font-lock-remove-keywords nil smerge-font-lock-keywords))
 643       (goto-char (point-min))
 644       (while (smerge-find-conflict)
 645         (save-excursion
 646           (font-lock-fontify-region (match-beginning 0) (match-end 0) nil))))))
 647
 648
 649 (provide 'smerge-mode)
 650
 651 ;;; arch-tag: 605c8d1e-e43d-4943-a6f3-1bcc4333e690
 652 ;;; smerge-mode.el ends here