code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/debug.el

   1 ;;; debug.el --- debuggers and related commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: lisp, tools, maint
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This is a major mode documented in the Emacs manual.
  28
  29 ;;; Code:
  30
  31 (defgroup debugger nil
  32   "Debuggers and related commands for Emacs."
  33   :prefix "debugger-"
  34   :group 'debug)
  35
  36 (defcustom debugger-mode-hook nil
  37   "*Hooks run when `debugger-mode' is turned on."
  38   :type 'hook
  39   :group 'debugger)
  40
  41
  42 (defcustom debug-function-list nil
  43   "List of functions currently set for debug on entry."
  44   :type '(repeat function)
  45   :group 'debugger)
  46
  47 (defcustom debugger-step-after-exit nil
  48   "Non-nil means \"single-step\" after the debugger exits."
  49   :type 'boolean
  50   :group 'debugger)
  51
  52 (defvar debugger-value nil
  53   "This is the value for the debugger to return, when it returns.")
  54
  55 (defvar debugger-old-buffer nil
  56   "This is the buffer that was current when the debugger was entered.")
  57
  58 (defvar debugger-outer-match-data)
  59 (defvar debugger-outer-load-read-function)
  60 (defvar debugger-outer-overriding-local-map)
  61 (defvar debugger-outer-overriding-terminal-local-map)
  62 (defvar debugger-outer-track-mouse)
  63 (defvar debugger-outer-last-command)
  64 (defvar debugger-outer-this-command)
  65 (defvar debugger-outer-unread-command-char)
  66 (defvar debugger-outer-unread-command-events)
  67 (defvar debugger-outer-last-input-event)
  68 (defvar debugger-outer-last-command-event)
  69 (defvar debugger-outer-last-nonmenu-event)
  70 (defvar debugger-outer-last-event-frame)
  71 (defvar debugger-outer-standard-input)
  72 (defvar debugger-outer-standard-output)
  73 (defvar debugger-outer-cursor-in-echo-area)
  74
  75 ;;;###autoload
  76 (setq debugger 'debug)
  77 ;;;###autoload
  78 (defun debug (&rest debugger-args)
  79   "Enter debugger.  To return, type \\<debugger-mode-map>`\\[debugger-continue]'.
  80 Arguments are mainly for use when this is called from the internals
  81 of the evaluator.
  82
  83 You may call with no args, or you may pass nil as the first arg and
  84 any other args you like.  In that case, the list of args after the
  85 first will be printed into the backtrace buffer."
  86   (interactive)
  87   (message "Entering debugger...")
  88   (let (debugger-value
  89         (debug-on-error nil)
  90         (debug-on-quit nil)
  91         (debugger-buffer (let ((default-major-mode 'fundamental-mode))
  92                            (get-buffer-create "*Backtrace*")))
  93         (debugger-old-buffer (current-buffer))
  94         (debugger-step-after-exit nil)
  95         ;; Don't keep reading from an executing kbd macro!
  96         (executing-kbd-macro nil)
  97         ;; Save the outer values of these vars for the `e' command
  98         ;; before we replace the values.
  99         (debugger-outer-match-data (match-data))
 100         (debugger-outer-load-read-function load-read-function)
 101         (debugger-outer-overriding-local-map overriding-local-map)
 102         (debugger-outer-overriding-terminal-local-map
 103          overriding-terminal-local-map)
 104         (debugger-outer-track-mouse track-mouse)
 105         (debugger-outer-last-command last-command)
 106         (debugger-outer-this-command this-command)
 107         (debugger-outer-unread-command-char unread-command-char)
 108         (debugger-outer-unread-command-events unread-command-events)
 109         (debugger-outer-last-input-event last-input-event)
 110         (debugger-outer-last-command-event last-command-event)
 111         (debugger-outer-last-nonmenu-event last-nonmenu-event)
 112         (debugger-outer-last-event-frame last-event-frame)
 113         (debugger-outer-standard-input standard-input)
 114         (debugger-outer-standard-output standard-output)
 115         (debugger-outer-cursor-in-echo-area cursor-in-echo-area))
 116     ;; Set this instead of binding it, so that `q'
 117     ;; will not restore it.
 118     (setq overriding-terminal-local-map nil)
 119     ;; Don't let these magic variables affect the debugger itself.
 120     (let ((last-command nil) this-command track-mouse
 121           (unread-command-char -1) unread-command-events
 122           last-input-event last-command-event last-nonmenu-event
 123           last-event-frame
 124           overriding-local-map
 125           load-read-function
 126           ;; If we are inside a minibuffer, allow nesting
 127           ;; so that we don't get an error from the `e' command.
 128           (enable-recursive-minibuffers (> (minibuffer-depth) 0))
 129           (standard-input t) (standard-output t)
 130           (cursor-in-echo-area nil))
 131       (unwind-protect
 132           (save-excursion
 133             (save-window-excursion
 134               (pop-to-buffer debugger-buffer)
 135               (erase-buffer)
 136               (set-buffer-multibyte nil)
 137               (let ((standard-output (current-buffer))
 138                     (print-escape-newlines t)
 139                     (print-length 50))
 140                 (backtrace))
 141               (goto-char (point-min))
 142               (debugger-mode)
 143               (delete-region (point)
 144                              (progn
 145                                (search-forward "\n  debug(")
 146                                (forward-line 1)
 147                                (point)))
 148               (debugger-reenable)
 149               ;; lambda is for debug-on-call when a function call is next.
 150               ;; debug is for debug-on-entry function called.
 151               (cond ((memq (car debugger-args) '(lambda debug))
 152                      (insert "Entering:\n")
 153                      (if (eq (car debugger-args) 'debug)
 154                          (progn
 155                            ;; Skip the frames for backtrace-debug, byte-code,
 156                            ;; and debug.
 157                            (backtrace-debug 3 t)
 158                            (delete-char 1)
 159                            (insert ?*)
 160                            (beginning-of-line))))
 161                     ;; Exiting a function.
 162                     ((eq (car debugger-args) 'exit)
 163                      (insert "Return value: ")
 164                      (setq debugger-value (nth 1 debugger-args))
 165                      (prin1 debugger-value (current-buffer))
 166                      (insert ?\n)
 167                      (delete-char 1)
 168                      (insert ? )
 169                      (beginning-of-line))
 170                     ;; Debugger entered for an error.
 171                     ((eq (car debugger-args) 'error)
 172                      (insert "Signaling: ")
 173                      (prin1 (nth 1 debugger-args) (current-buffer))
 174                      (insert ?\n))
 175                     ;; debug-on-call, when the next thing is an eval.
 176                     ((eq (car debugger-args) t)
 177                      (insert "Beginning evaluation of function call form:\n"))
 178                     ;; User calls debug directly.
 179                     (t
 180                      (prin1 (if (eq (car debugger-args) 'nil)
 181                                 (cdr debugger-args) debugger-args)
 182                             (current-buffer))
 183                      (insert ?\n)))
 184               (message "")
 185               (let ((inhibit-trace t)
 186                     (standard-output nil)
 187                     (buffer-read-only t))
 188                 (message "")
 189                 ;; Make sure we unbind buffer-read-only in the right buffer.
 190                 (save-excursion
 191                   (recursive-edit)))))
 192         ;; Kill or at least neuter the backtrace buffer, so that users
 193         ;; don't try to execute debugger commands in an invalid context.
 194         (if (get-buffer-window debugger-buffer 'visible)
 195             ;; Still visible despite the save-window-excursion?  Maybe it
 196             ;; it's in a pop-up frame.  It would be annoying to delete and
 197             ;; recreate it every time the debugger stops, so instead we'll
 198             ;; erase it but leave it visible.
 199             (save-excursion
 200               (set-buffer debugger-buffer)
 201               (erase-buffer)
 202               (fundamental-mode))
 203           (kill-buffer debugger-buffer))
 204         (set-match-data debugger-outer-match-data)))
 205     ;; Put into effect the modified values of these variables
 206     ;; in case the user set them with the `e' command.
 207     (setq load-read-function debugger-outer-load-read-function)
 208     (setq overriding-local-map debugger-outer-overriding-local-map)
 209     (setq overriding-terminal-local-map
 210           debugger-outer-overriding-terminal-local-map)
 211     (setq track-mouse debugger-outer-track-mouse)
 212     (setq last-command debugger-outer-last-command)
 213     (setq this-command debugger-outer-this-command)
 214     (setq unread-command-char debugger-outer-unread-command-char)
 215     (setq unread-command-events debugger-outer-unread-command-events)
 216     (setq last-input-event debugger-outer-last-input-event)
 217     (setq last-command-event debugger-outer-last-command-event)
 218     (setq last-nonmenu-event debugger-outer-last-nonmenu-event)
 219     (setq last-event-frame debugger-outer-last-event-frame)
 220     (setq standard-input debugger-outer-standard-input)
 221     (setq standard-output debugger-outer-standard-output)
 222     (setq cursor-in-echo-area debugger-outer-cursor-in-echo-area)
 223     (setq debug-on-next-call debugger-step-after-exit)
 224     debugger-value))
 225 \f
 226 (defun debugger-step-through ()
 227   "Proceed, stepping through subexpressions of this expression.
 228 Enter another debugger on next entry to eval, apply or funcall."
 229   (interactive)
 230   (setq debugger-step-after-exit t)
 231   (message "Proceeding, will debug on next eval or call.")
 232   (exit-recursive-edit))
 233
 234 (defun debugger-continue ()
 235   "Continue, evaluating this expression without stopping."
 236   (interactive)
 237   (message "Continuing.")
 238   (exit-recursive-edit))
 239
 240 (defun debugger-return-value (val)
 241   "Continue, specifying value to return.
 242 This is only useful when the value returned from the debugger
 243 will be used, such as in a debug on exit from a frame."
 244   (interactive "XReturn value (evaluated): ")
 245   (setq debugger-value val)
 246   (princ "Returning " t)
 247   (prin1 debugger-value)
 248   (exit-recursive-edit))
 249
 250 (defun debugger-jump ()
 251   "Continue to exit from this frame, with all debug-on-entry suspended."
 252   (interactive)
 253   ;; Compensate for the two extra stack frames for debugger-jump.
 254   (let ((debugger-frame-offset (+ debugger-frame-offset 2)))
 255     (debugger-frame))
 256   ;; Turn off all debug-on-entry functions
 257   ;; but leave them in the list.
 258   (let ((list debug-function-list))
 259     (while list
 260       (fset (car list)
 261             (debug-on-entry-1 (car list) (symbol-function (car list)) nil))
 262       (setq list (cdr list))))
 263   (message "Continuing through this frame")
 264   (exit-recursive-edit))
 265
 266 (defun debugger-reenable ()
 267   "Turn all debug-on-entry functions back on."
 268   (let ((list debug-function-list))
 269     (while list
 270       (or (consp (symbol-function (car list)))
 271           (debug-convert-byte-code (car list)))
 272       (fset (car list)
 273             (debug-on-entry-1 (car list) (symbol-function (car list)) t))
 274       (setq list (cdr list)))))
 275
 276 (defun debugger-frame-number ()
 277   "Return number of frames in backtrace before the one point points at."
 278   (save-excursion
 279     (beginning-of-line)
 280     (let ((opoint (point))
 281           (count 0))
 282       (goto-char (point-min))
 283       (if (or (equal (buffer-substring (point) (+ (point) 6))
 284                      "Signal")
 285               (equal (buffer-substring (point) (+ (point) 6))
 286                      "Return"))
 287           (progn
 288             (search-forward ":")
 289             (forward-sexp 1)))
 290       (forward-line 1)
 291       (while (progn
 292                (forward-char 2)
 293                (if (= (following-char) ?\()
 294                    (forward-sexp 1)
 295                  (forward-sexp 2))
 296                (forward-line 1)
 297                (<= (point) opoint))
 298         (setq count (1+ count)))
 299       count)))
 300
 301 ;; Chosen empirically to account for all the frames
 302 ;; that will exist when debugger-frame is called
 303 ;; within the first one that appears in the backtrace buffer.
 304 ;; Assumes debugger-frame is called from a key;
 305 ;; will be wrong if it is called with Meta-x.
 306 (defconst debugger-frame-offset 8 "")
 307
 308 (defun debugger-frame ()
 309   "Request entry to debugger when this frame exits.
 310 Applies to the frame whose line point is on in the backtrace."
 311   (interactive)
 312   (beginning-of-line)
 313   (let ((level (debugger-frame-number)))
 314     (backtrace-debug (+ level debugger-frame-offset) t))
 315   (if (= (following-char) ? )
 316       (let ((buffer-read-only nil))
 317         (delete-char 1)
 318         (insert ?*)))
 319   (beginning-of-line))
 320
 321 (defun debugger-frame-clear ()
 322   "Do not enter to debugger when this frame exits.
 323 Applies to the frame whose line point is on in the backtrace."
 324   (interactive)
 325   (beginning-of-line)
 326   (let ((level (debugger-frame-number)))
 327     (backtrace-debug (+ level debugger-frame-offset) nil))
 328   (if (= (following-char) ?*)
 329       (let ((buffer-read-only nil))
 330         (delete-char 1)
 331         (insert ? )))
 332   (beginning-of-line))
 333
 334
 335
 336 (put 'debugger-env-macro 'lisp-indent-function 0)
 337 (defmacro debugger-env-macro (&rest body)
 338   "Run BODY in original environment."
 339   (`
 340    (save-excursion
 341      (if (null (buffer-name debugger-old-buffer))
 342          ;; old buffer deleted
 343          (setq debugger-old-buffer (current-buffer)))
 344      (set-buffer debugger-old-buffer)
 345      (let ((track-mouse debugger-outer-track-mouse)
 346            (last-command debugger-outer-last-command)
 347            (this-command debugger-outer-this-command)
 348            (unread-command-char debugger-outer-unread-command-char)
 349            (unread-command-events debugger-outer-unread-command-events)
 350            (last-input-event debugger-outer-last-input-event)
 351            (last-command-event debugger-outer-last-command-event)
 352            (last-nonmenu-event debugger-outer-last-nonmenu-event)
 353            (last-event-frame debugger-outer-last-event-frame)
 354            (standard-input debugger-outer-standard-input)
 355            (standard-output debugger-outer-standard-output)
 356            (cursor-in-echo-area debugger-outer-cursor-in-echo-area)
 357            (overriding-local-map debugger-outer-overriding-local-map)
 358            (overriding-terminal-local-map
 359             debugger-outer-overriding-terminal-local-map)
 360            (load-read-function debugger-outer-load-read-function))
 361        (set-match-data debugger-outer-match-data)
 362        (prog1 (progn (,@ body))
 363          (setq debugger-outer-match-data (match-data))
 364          (setq debugger-outer-load-read-function load-read-function)
 365          (setq debugger-outer-overriding-terminal-local-map
 366                overriding-terminal-local-map)
 367          (setq debugger-outer-overriding-local-map overriding-local-map)
 368          (setq debugger-outer-track-mouse track-mouse)
 369          (setq debugger-outer-last-command last-command)
 370          (setq debugger-outer-this-command this-command)
 371          (setq debugger-outer-unread-command-char unread-command-char)
 372          (setq debugger-outer-unread-command-events unread-command-events)
 373          (setq debugger-outer-last-input-event last-input-event)
 374          (setq debugger-outer-last-command-event last-command-event)
 375          (setq debugger-outer-last-nonmenu-event last-nonmenu-event)
 376          (setq debugger-outer-last-event-frame last-event-frame)
 377          (setq debugger-outer-standard-input standard-input)
 378          (setq debugger-outer-standard-output standard-output)
 379          (setq debugger-outer-cursor-in-echo-area cursor-in-echo-area)
 380          )))))
 381
 382 (defun debugger-eval-expression (exp)
 383   "Eval an expression, in an environment like that outside the debugger."
 384   (interactive
 385    (list (read-from-minibuffer "Eval: "
 386                                nil read-expression-map t
 387                                'read-expression-history)))
 388   (debugger-env-macro (eval-expression exp)))
 389 \f
 390 (defvar debugger-mode-map nil)
 391 (if debugger-mode-map
 392     nil
 393   (let ((loop ? ))
 394     (setq debugger-mode-map (make-keymap))
 395     (suppress-keymap debugger-mode-map)
 396     (define-key debugger-mode-map "-" 'negative-argument)
 397     (define-key debugger-mode-map "b" 'debugger-frame)
 398     (define-key debugger-mode-map "c" 'debugger-continue)
 399     (define-key debugger-mode-map "j" 'debugger-jump)
 400     (define-key debugger-mode-map "r" 'debugger-return-value)
 401     (define-key debugger-mode-map "u" 'debugger-frame-clear)
 402     (define-key debugger-mode-map "d" 'debugger-step-through)
 403     (define-key debugger-mode-map "l" 'debugger-list-functions)
 404     (define-key debugger-mode-map "h" 'describe-mode)
 405     (define-key debugger-mode-map "q" 'top-level)
 406     (define-key debugger-mode-map "e" 'debugger-eval-expression)
 407     (define-key debugger-mode-map " " 'next-line)
 408     (define-key debugger-mode-map "R" 'debugger-record-expression)
 409     ))
 410
 411
 412 (defcustom debugger-record-buffer "*Debugger-record*"
 413   "*Buffer name for expression values, for \\[debugger-record-expression]."
 414   :type 'string
 415   :group 'debugger)
 416
 417 (defun debugger-record-expression  (exp)
 418   "Display a variable's value and record it in `*Backtrace-record*' buffer."
 419   (interactive
 420    (list (read-from-minibuffer
 421           "Record Eval: "
 422           nil
 423           read-expression-map t
 424           'read-expression-history)))
 425   (let* ((buffer (get-buffer-create debugger-record-buffer))
 426          (standard-output buffer))
 427     (princ (format "Debugger Eval (%s): " exp))
 428     (princ (debugger-eval-expression exp))
 429     (terpri))
 430
 431   (with-current-buffer (get-buffer debugger-record-buffer)
 432     (save-excursion
 433       (forward-line -1)
 434       (message
 435        (buffer-substring (point) (progn (end-of-line) (point)))))))
 436
 437 (put 'debugger-mode 'mode-class 'special)
 438
 439 (defun debugger-mode ()
 440   "Mode for backtrace buffers, selected in debugger.
 441 \\<debugger-mode-map>
 442 A line starts with `*' if exiting that frame will call the debugger.
 443 Type \\[debugger-frame] or \\[debugger-frame-clear] to set or remove the `*'.
 444
 445 When in debugger due to frame being exited,
 446 use the \\[debugger-return-value] command to override the value
 447 being returned from that frame.
 448
 449 Use \\[debug-on-entry] and \\[cancel-debug-on-entry] to control
 450 which functions will enter the debugger when called.
 451
 452 Complete list of commands:
 453 \\{debugger-mode-map}"
 454   (kill-all-local-variables)
 455   (setq major-mode 'debugger-mode)
 456   (setq mode-name "Debugger")
 457   (setq truncate-lines t)
 458   (set-syntax-table emacs-lisp-mode-syntax-table)
 459   (use-local-map debugger-mode-map)
 460   (run-hooks 'debugger-mode-hook))
 461 \f
 462 ;;;###autoload
 463 (defun debug-on-entry (function)
 464   "Request FUNCTION to invoke debugger each time it is called.
 465 If you tell the debugger to continue, FUNCTION's execution proceeds.
 466 This works by modifying the definition of FUNCTION,
 467 which must be written in Lisp, not predefined.
 468 Use \\[cancel-debug-on-entry] to cancel the effect of this command.
 469 Redefining FUNCTION also cancels it."
 470   (interactive "aDebug on entry (to function): ")
 471   (debugger-reenable)
 472   ;; Handle a function that has been aliased to some other function.
 473   (if (symbolp (symbol-function function))
 474       (fset function `(lambda (&rest debug-on-entry-args)
 475                         (apply ',(symbol-function function)
 476                                debug-on-entry-args))))
 477   (if (subrp (symbol-function function))
 478       (error "Function %s is a primitive" function))
 479   (or (consp (symbol-function function))
 480       (debug-convert-byte-code function))
 481   (or (consp (symbol-function function))
 482       (error "Definition of %s is not a list" function))
 483   (fset function (debug-on-entry-1 function (symbol-function function) t))
 484   (or (memq function debug-function-list)
 485       (setq debug-function-list (cons function debug-function-list)))
 486   function)
 487
 488 ;;;###autoload
 489 (defun cancel-debug-on-entry (&optional function)
 490   "Undo effect of \\[debug-on-entry] on FUNCTION.
 491 If argument is nil or an empty string, cancel for all functions."
 492   (interactive
 493    (list (let ((name
 494                 (completing-read "Cancel debug on entry (to function): "
 495                                  ;; Make an "alist" of the functions
 496                                  ;; that now have debug on entry.
 497                                  (mapcar 'list
 498                                          (mapcar 'symbol-name
 499                                                  debug-function-list))
 500                                  nil t nil)))
 501            (if name (intern name)))))
 502   (debugger-reenable)
 503   (if (and function (not (string= function "")))
 504       (progn
 505         (fset function
 506               (debug-on-entry-1 function (symbol-function function) nil))
 507         (setq debug-function-list (delq function debug-function-list))
 508         function)
 509     (message "Cancelling debug-on-entry for all functions")
 510     (mapcar 'cancel-debug-on-entry debug-function-list)))
 511
 512 (defun debug-convert-byte-code (function)
 513   (let ((defn (symbol-function function)))
 514     (if (not (consp defn))
 515         ;; Assume a compiled code object.
 516         (let* ((contents (append defn nil))
 517                (body
 518                 (list (list 'byte-code (nth 1 contents)
 519                             (nth 2 contents) (nth 3 contents)))))
 520           (if (nthcdr 5 contents)
 521               (setq body (cons (list 'interactive (nth 5 contents)) body)))
 522           (if (nth 4 contents)
 523               ;; Use `documentation' here, to get the actual string,
 524               ;; in case the compiled function has a reference
 525               ;; to the .elc file.
 526               (setq body (cons (documentation function) body)))
 527           (fset function (cons 'lambda (cons (car contents) body)))))))
 528
 529 (defun debug-on-entry-1 (function defn flag)
 530   (if (subrp defn)
 531       (error "%s is a built-in function" function)
 532     (if (eq (car defn) 'macro)
 533         (debug-on-entry-1 function (cdr defn) flag)
 534       (or (eq (car defn) 'lambda)
 535           (error "%s not user-defined Lisp function" function))
 536       (let (tail prec)
 537         (if (stringp (car (nthcdr 2 defn)))
 538             (setq tail (nthcdr 3 defn)
 539                   prec (list (car defn) (car (cdr defn))
 540                              (car (cdr (cdr defn)))))
 541           (setq tail (nthcdr 2 defn)
 542                 prec (list (car defn) (car (cdr defn)))))
 543         (if (eq flag (equal (car tail) '(debug 'debug)))
 544             defn
 545           (if flag
 546               (nconc prec (cons '(debug 'debug) tail))
 547             (nconc prec (cdr tail))))))))
 548
 549 (defun debugger-list-functions ()
 550   "Display a list of all the functions now set to debug on entry."
 551   (interactive)
 552   (with-output-to-temp-buffer "*Help*"
 553     (if (null debug-function-list)
 554         (princ "No debug-on-entry functions now\n")
 555       (princ "Functions set to debug on entry:\n\n")
 556       (let ((list debug-function-list))
 557         (while list
 558           (prin1 (car list))
 559           (terpri)
 560           (setq list (cdr list))))
 561       (princ "Note: if you have redefined a function, then it may no longer\n")
 562       (princ "be set to debug on entry, even if it is in the list."))
 563     (save-excursion
 564       (set-buffer standard-output)
 565       (help-mode))))
 566
 567 (provide 'debug)
 568
 569 ;;; debug.el ends here