code.delx.au - gnu-emacs/blob - build-aux/git-hooks/commit-msg

   1 #!/bin/sh
   2 # Check the format of GNU Emacs change log entries.
   3
   4 # Copyright 2014-2015 Free Software Foundation, Inc.
   5
   6 # This file is part of GNU Emacs.
   7
   8 # GNU Emacs is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12
  13 # GNU Emacs is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17
  18 # You should have received a copy of the GNU General Public License
  19 # along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  20
  21 # Written by Paul Eggert.
  22
  23 # Prefer gawk if available, as it handles NUL bytes properly.
  24 if type gawk >/dev/null 2>&1; then
  25   awk=gawk
  26 else
  27   awk=awk
  28 fi
  29
  30 # Use a UTF-8 locale if available, so that the UTF-8 check works.
  31 # Use U+00A2 CENT SIGN to test whether the locale works.
  32 cent_sign_utf8_format='\302\242\n'
  33 cent_sign=`printf "$cent_sign_utf8_format"`
  34 print_at_sign='{print substr("'$cent_sign'@", 2)}'
  35 at_sign=`$awk "$print_at_sign" 2>/dev/null`
  36 if test "$at_sign" != @; then
  37   at_sign=`LC_ALL=en_US.UTF-8 $awk "$print_at_sign" 2>/dev/null`
  38   if test "$at_sign" = @; then
  39     LC_ALL=en_US.UTF-8; export LC_ALL
  40   fi
  41 fi
  42
  43 # Check the log entry.
  44 exec $awk -v at_sign="$at_sign" -v cent_sign="$cent_sign" '
  45   BEGIN {
  46     # These regular expressions assume traditional Unix unibyte behavior.
  47     # They are needed for old or broken versions of awk, e.g.,
  48     # mawk 1.3.3 (1996), Gawk 3.0.4 (1999).
  49     space = "[ \f\n\r\t\v]"
  50     non_space = "[^ \f\n\r\t\v]"
  51     non_print = "[\1-\37\177]"
  52
  53     # Prefer POSIX regular expressions if available, as they do a
  54     # better job of checking.  Similarly, prefer POSIX negated
  55     # expressions if UTF-8 also works.
  56     if (" " ~ /[[:space:]]/) {
  57       space = "[[:space:]]"
  58       if (at_sign == "@" && cent_sign ~ /^[[:print:]]$/) {
  59         non_space = "[^[:space:]]"
  60         non_print = "[^[:print:]]"
  61       }
  62     }
  63   }
  64
  65   /^#/ {
  66     # Ignore every line after a scissors line.
  67     if (/^# *---* *(>[8%]|[8%]<) *---* *$/) { exit }
  68
  69     # Ignore comment lines.
  70     next
  71   }
  72
  73   !/^.*$/ {
  74     print "Invalid character (not UTF-8) in commit message"
  75     status = 1
  76   }
  77
  78   nlines == 0 && $0 !~ non_space { next }
  79
  80   { nlines++ }
  81
  82   nlines == 1 {
  83     # Ignore special markers used by "git rebase --autosquash".
  84     if (! sub(/^fixup! /, ""))
  85       sub(/^squash! /, "")
  86
  87     if ($0 ~ "^" space) {
  88       print "White space at start of commit message'\''s first line"
  89       status = 1
  90     }
  91   }
  92
  93   nlines == 2 && $0 ~ non_space {
  94     print "Nonempty second line in commit message"
  95     status = 1
  96   }
  97
  98   {
  99     # Expand tabs to spaces for length calculations etc.
 100     while (match($0, /\t/)) {
 101       before_tab = substr($0, 1, RSTART - 1)
 102       after_tab = substr($0, RSTART + 1)
 103       $0 = sprintf("%s%*s%s", before_tab, 8 - (RSTART - 1) % 8, "", after_tab)
 104     }
 105   }
 106
 107   78 < length && $0 ~ space {
 108     print "Line longer than 78 characters in commit message"
 109     status = 1
 110   }
 111
 112   140 < length {
 113     print "Word longer than 140 characters in commit message"
 114     status = 1
 115   }
 116
 117   /^Signed-off-by: / {
 118     print "'\''Signed-off-by:'\'' in commit message"
 119     status = 1
 120   }
 121
 122   $0 ~ non_print {
 123     print "Unprintable character in commit message"
 124     status = 1
 125   }
 126
 127   END {
 128     if (nlines == 0) {
 129       print "Empty commit message"
 130       status = 1
 131     }
 132     if (status != 0) {
 133       print "Commit aborted; please see the file 'CONTRIBUTE'"
 134     }
 135     exit status
 136   }
 137 ' <"$1"