code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/lisp.el

   1 ;;; lisp.el --- Lisp editing commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1994, 2000 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: lisp, languages
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Lisp editing commands to go with Lisp major mode.  More-or-less
  28 ;; applicable in other modes too.
  29
  30 ;;; Code:
  31
  32 ;; Note that this variable is used by non-lisp modes too.
  33 (defcustom defun-prompt-regexp nil
  34   "*If non-nil, a regexp to ignore before the character that starts a defun.
  35 This is only necessary if the opening paren or brace is not in column 0.
  36 See function `beginning-of-defun'.
  37
  38 Setting this variable automatically makes it local to the current buffer."
  39   :type '(choice (const nil)
  40                  regexp)
  41   :group 'lisp)
  42 (make-variable-buffer-local 'defun-prompt-regexp)
  43
  44 (defcustom parens-require-spaces t
  45   "Non-nil means `insert-parentheses' should insert whitespace as needed."
  46   :type 'boolean
  47   :group 'lisp)
  48
  49 (defvar forward-sexp-function nil
  50   "If non-nil, `forward-sexp' delegates to this function.
  51 Should take the same arguments and behave similarly to `forward-sexp'.")
  52
  53 (defun forward-sexp (&optional arg)
  54   "Move forward across one balanced expression (sexp).
  55 With ARG, do it that many times.  Negative arg -N means
  56 move backward across N balanced expressions."
  57   (interactive "p")
  58   (or arg (setq arg 1))
  59   (if forward-sexp-function
  60       (funcall forward-sexp-function arg)
  61     (goto-char (or (scan-sexps (point) arg) (buffer-end arg)))
  62     (if (< arg 0) (backward-prefix-chars))))
  63
  64 (defun backward-sexp (&optional arg)
  65   "Move backward across one balanced expression (sexp).
  66 With ARG, do it that many times.  Negative arg -N means
  67 move forward across N balanced expressions."
  68   (interactive "p")
  69   (or arg (setq arg 1))
  70   (forward-sexp (- arg)))
  71
  72 (defun mark-sexp (&optional arg)
  73   "Set mark ARG sexps from point.
  74 The place mark goes is the same place \\[forward-sexp] would
  75 move to with the same argument.
  76 If this command is repeated, it marks the next ARG sexps after the ones
  77 already marked."
  78   (interactive "p")
  79   (cond ((and (eq last-command this-command) (mark t))
  80          (set-mark
  81           (save-excursion
  82            (goto-char (mark))
  83            (forward-sexp (or arg 1))
  84            (point))))
  85         (t
  86          (push-mark
  87           (save-excursion
  88             (forward-sexp (or arg 1))
  89             (point))
  90           nil t))))
  91
  92 (defun forward-list (&optional arg)
  93   "Move forward across one balanced group of parentheses.
  94 With ARG, do it that many times.
  95 Negative arg -N means move backward across N groups of parentheses."
  96   (interactive "p")
  97   (or arg (setq arg 1))
  98   (goto-char (or (scan-lists (point) arg 0) (buffer-end arg))))
  99
 100 (defun backward-list (&optional arg)
 101   "Move backward across one balanced group of parentheses.
 102 With ARG, do it that many times.
 103 Negative arg -N means move forward across N groups of parentheses."
 104   (interactive "p")
 105   (or arg (setq arg 1))
 106   (forward-list (- arg)))
 107
 108 (defun down-list (&optional arg)
 109   "Move forward down one level of parentheses.
 110 With ARG, do this that many times.
 111 A negative argument means move backward but still go down a level."
 112   (interactive "p")
 113   (or arg (setq arg 1))
 114   (let ((inc (if (> arg 0) 1 -1)))
 115     (while (/= arg 0)
 116       (goto-char (or (scan-lists (point) inc -1) (buffer-end arg)))
 117       (setq arg (- arg inc)))))
 118
 119 (defun backward-up-list (&optional arg)
 120   "Move backward out of one level of parentheses.
 121 With ARG, do this that many times.
 122 A negative argument means move forward but still to a less deep spot."
 123   (interactive "p")
 124   (up-list (- (or arg 1))))
 125
 126 (defun up-list (&optional arg)
 127   "Move forward out of one level of parentheses.
 128 With ARG, do this that many times.
 129 A negative argument means move backward but still to a less deep spot."
 130   (interactive "p")
 131   (or arg (setq arg 1))
 132   (let ((inc (if (> arg 0) 1 -1)))
 133     (while (/= arg 0)
 134       (goto-char (or (scan-lists (point) inc 1) (buffer-end arg)))
 135       (setq arg (- arg inc)))))
 136
 137 (defun kill-sexp (&optional arg)
 138   "Kill the sexp (balanced expression) following the cursor.
 139 With ARG, kill that many sexps after the cursor.
 140 Negative arg -N means kill N sexps before the cursor."
 141   (interactive "p")
 142   (let ((opoint (point)))
 143     (forward-sexp (or arg 1))
 144     (kill-region opoint (point))))
 145
 146 (defun backward-kill-sexp (&optional arg)
 147   "Kill the sexp (balanced expression) preceding the cursor.
 148 With ARG, kill that many sexps before the cursor.
 149 Negative arg -N means kill N sexps after the cursor."
 150   (interactive "p")
 151   (kill-sexp (- (or arg 1))))
 152 \f
 153 (defvar beginning-of-defun-function nil
 154   "If non-nil, function for `beginning-of-defun-raw' to call.
 155 This is used to find the beginning of the defun instead of using the
 156 normal recipe (see `beginning-of-defun').  Major modes can define this
 157 if defining `defun-prompt-regexp' is not sufficient to handle the mode's
 158 needs.
 159
 160 The function (of no args) should go to the line on which the current
 161 defun starts, and return non-nil, or should return nil if it can't
 162 find the beginning.")
 163
 164 (defun beginning-of-defun (&optional arg)
 165   "Move backward to the beginning of a defun.
 166 With ARG, do it that many times.  Negative arg -N
 167 means move forward to Nth following beginning of defun.
 168 Returns t unless search stops due to beginning or end of buffer.
 169
 170 Normally a defun starts when there is a char with open-parenthesis
 171 syntax at the beginning of a line.  If `defun-prompt-regexp' is
 172 non-nil, then a string which matches that regexp may precede the
 173 open-parenthesis, and point ends up at the beginning of the line.
 174
 175 If variable `beginning-of-defun-function' is non-nil, its value
 176 is called as a function to find the defun's beginning."
 177   (interactive "p")
 178   (and (beginning-of-defun-raw arg)
 179        (progn (beginning-of-line) t)))
 180
 181 (defun beginning-of-defun-raw (&optional arg)
 182   "Move point to the character that starts a defun.
 183 This is identical to function `beginning-of-defun', except that point
 184 does not move to the beginning of the line when `defun-prompt-regexp'
 185 is non-nil.
 186
 187 If variable `beginning-of-defun-function' is non-nil, its value
 188 is called as a function to find the defun's beginning."
 189   (interactive "p")
 190   (if beginning-of-defun-function
 191       (dotimes (i (or arg 1))
 192         (funcall beginning-of-defun-function))
 193     (and arg (< arg 0) (not (eobp)) (forward-char 1))
 194     (and (re-search-backward (if defun-prompt-regexp
 195                                  (concat (if open-paren-in-column-0-is-defun-start
 196                                              "^\\s(\\|" "")
 197                                          "\\(?:" defun-prompt-regexp "\\)\\s(")
 198                                "^\\s(")
 199                              nil 'move (or arg 1))
 200          (progn (goto-char (1- (match-end 0)))) t)))
 201
 202 (defvar end-of-defun-function nil
 203   "If non-nil, function for function `end-of-defun' to call.
 204 This is used to find the end of the defun instead of using the normal
 205 recipe (see `end-of-defun').  Major modes can define this if the
 206 normal method is not appropriate.")
 207
 208 (defun buffer-end (arg)
 209   (if (> arg 0) (point-max) (point-min)))
 210
 211 (defun end-of-defun (&optional arg)
 212   "Move forward to next end of defun.  With argument, do it that many times.
 213 Negative argument -N means move back to Nth preceding end of defun.
 214
 215 An end of a defun occurs right after the close-parenthesis that
 216 matches the open-parenthesis that starts a defun; see function
 217 `beginning-of-defun'.
 218
 219 If variable `end-of-defun-function' is non-nil, its value
 220 is called as a function to find the defun's end."
 221   (interactive "p")
 222   (if end-of-defun-function
 223       (dotimes (i (or arg 1))
 224         (funcall end-of-defun-function))
 225     (if (or (null arg) (= arg 0)) (setq arg 1))
 226     (let ((first t))
 227       (while (and (> arg 0) (< (point) (point-max)))
 228         (let ((pos (point)) npos)
 229           (while (progn
 230                    (if (and first
 231                             (progn
 232                               (end-of-line 1)
 233                               (beginning-of-defun-raw 1)))
 234                        nil
 235                      (or (bobp) (forward-char -1))
 236                      (beginning-of-defun-raw -1))
 237                    (setq first nil)
 238                    (forward-list 1)
 239                    (skip-chars-forward " \t")
 240                    (if (looking-at "\\s<\\|\n")
 241                        (forward-line 1))
 242                    (<= (point) pos))))
 243         (setq arg (1- arg)))
 244       (while (< arg 0)
 245         (let ((pos (point)))
 246           (beginning-of-defun-raw 1)
 247           (forward-sexp 1)
 248           (forward-line 1)
 249           (if (>= (point) pos)
 250               (if (beginning-of-defun-raw 2)
 251                   (progn
 252                     (forward-list 1)
 253                     (skip-chars-forward " \t")
 254                     (if (looking-at "\\s<\\|\n")
 255                         (forward-line 1)))
 256                 (goto-char (point-min)))))
 257         (setq arg (1+ arg))))))
 258
 259 (defun mark-defun ()
 260   "Put mark at end of this defun, point at beginning.
 261 The defun marked is the one that contains point or follows point.
 262 If this command is repeated, marks more defuns after the ones
 263 already marked."
 264   (interactive)
 265   (cond ((and (eq last-command this-command) (mark t))
 266          (set-mark
 267           (save-excursion
 268             (goto-char (mark))
 269             (end-of-defun)
 270             (point))))
 271         (t
 272          ;; Do it in this order for the sake of languages with nested
 273          ;; functions where several can end at the same place as with
 274          ;; the offside rule, e.g. Python.
 275          (push-mark (point))
 276          (beginning-of-defun)
 277          (push-mark (point) nil t)
 278          (end-of-defun)
 279          (exchange-point-and-mark)
 280          (re-search-backward "^\n" (- (point) 1) t))))
 281
 282 (defun narrow-to-defun (&optional arg)
 283   "Make text outside current defun invisible.
 284 The defun visible is the one that contains point or follows point.
 285 Optional ARG is ignored."
 286   (interactive)
 287   (save-excursion
 288     (widen)
 289     ;; Do it in this order for the sake of languages with nested
 290     ;; functions where several can end at the same place as with the
 291     ;; offside rule, e.g. Python.
 292     (beginning-of-defun)
 293     (let ((beg (point)))
 294       (end-of-defun)
 295       (narrow-to-region beg (point)))))
 296
 297 (defun insert-parentheses (arg)
 298   "Enclose following ARG sexps in parentheses.  Leave point after open-paren.
 299 A negative ARG encloses the preceding ARG sexps instead.
 300 No argument is equivalent to zero: just insert `()' and leave point between.
 301 If `parens-require-spaces' is non-nil, this command also inserts a space
 302 before and after, depending on the surrounding characters."
 303   (interactive "P")
 304   (if arg (setq arg (prefix-numeric-value arg))
 305     (setq arg 0))
 306   (cond ((> arg 0) (skip-chars-forward " \t"))
 307         ((< arg 0) (forward-sexp arg) (setq arg (- arg))))
 308   (and parens-require-spaces
 309        (not (bobp))
 310        (memq (char-syntax (preceding-char)) '(?w ?_ ?\) ))
 311        (insert " "))
 312   (insert ?\()
 313   (save-excursion
 314     (or (eq arg 0) (forward-sexp arg))
 315     (insert ?\))
 316     (and parens-require-spaces
 317          (not (eobp))
 318          (memq (char-syntax (following-char)) '(?w ?_ ?\( ))
 319          (insert " "))))
 320
 321 (defun move-past-close-and-reindent ()
 322   "Move past next `)', delete indentation before it, then indent after it."
 323   (interactive)
 324   (up-list 1)
 325   (forward-char -1)
 326   (while (save-excursion                ; this is my contribution
 327            (let ((before-paren (point)))
 328              (back-to-indentation)
 329              (and (= (point) before-paren)
 330                   (progn
 331                     ;; Move to end of previous line.
 332                     (beginning-of-line)
 333                     (forward-char -1)
 334                     ;; Verify it doesn't end within a string or comment.
 335                     (let ((end (point))
 336                           state)
 337                       (beginning-of-line)
 338                       ;; Get state at start of line.
 339                       (setq state  (list 0 nil nil
 340                                          (null (calculate-lisp-indent))
 341                                          nil nil nil nil
 342                                          nil))
 343                       ;; Parse state across the line to get state at end.
 344                       (setq state (parse-partial-sexp (point) end nil nil
 345                                                       state))
 346                       ;; Check not in string or comment.
 347                       (and (not (elt state 3)) (not (elt state 4))))))))
 348     (delete-indentation))
 349   (forward-char 1)
 350   (newline-and-indent))
 351
 352 (defun check-parens ()                  ; lame name?
 353   "Check for unbalanced parentheses in the current buffer.
 354 More accurately, check the narrowed part of the buffer for unbalanced
 355 expressions (\"sexps\") in general.  This is done according to the
 356 current syntax table and will find unbalanced brackets or quotes as
 357 appropriate.  (See Info node `(emacs)Lists and Sexps'.)  If imbalance
 358 is found, an error is signalled and point is left at the first
 359 unbalanced character."
 360   (interactive)
 361   (condition-case data
 362       ;; Buffer can't have more than (point-max) sexps.
 363       (scan-sexps (point-min) (point-max))
 364     (scan-error (goto-char (nth 2 data))
 365                 ;; Could print (nth 1 data), which is either
 366                 ;; "Containing expression ends prematurely" or
 367                 ;; "Unbalanced parentheses", but those may not be so
 368                 ;; accurate/helpful, e.g. quotes may actually be
 369                 ;; mismatched.
 370                 (error "Unmatched bracket or quote"))
 371     (error (cond ((eq 'scan-error (car data))
 372                   (goto-char (nth 2 data))
 373                   (error "Unmatched bracket or quote"))
 374                  (t (signal (car data) (cdr data)))))))
 375 \f
 376 (defun lisp-complete-symbol (&optional predicate)
 377   "Perform completion on Lisp symbol preceding point.
 378 Compare that symbol against the known Lisp symbols.
 379 If no characters can be completed, display a list of possible completions.
 380 Repeating the command at that point scrolls the list.
 381
 382 When called from a program, optional arg PREDICATE is a predicate
 383 determining which symbols are considered, e.g. `commandp'.
 384 If PREDICATE is nil, the context determines which symbols are
 385 considered.  If the symbol starts just after an open-parenthesis, only
 386 symbols with function definitions are considered.  Otherwise, all
 387 symbols with function definitions, values or properties are
 388 considered."
 389   (interactive)
 390
 391   (let ((window (get-buffer-window "*Completions*")))
 392     (if (and (eq last-command this-command)
 393              window (window-live-p window) (window-buffer window)
 394              (buffer-name (window-buffer window)))
 395         ;; If this command was repeated, and
 396         ;; there's a fresh completion window with a live buffer,
 397         ;; and this command is repeated, scroll that window.
 398         (with-current-buffer (window-buffer window)
 399           (if (pos-visible-in-window-p (point-max) window)
 400               (set-window-start window (point-min))
 401             (save-selected-window
 402               (select-window window)
 403               (scroll-up))))
 404
 405       ;; Do completion.
 406       (let* ((end (point))
 407              (beg (with-syntax-table emacs-lisp-mode-syntax-table
 408                     (save-excursion
 409                       (backward-sexp 1)
 410                       (while (= (char-syntax (following-char)) ?\')
 411                         (forward-char 1))
 412                       (point))))
 413              (pattern (buffer-substring-no-properties beg end))
 414              (predicate
 415               (or predicate
 416                   (save-excursion
 417                     (goto-char beg)
 418                     (if (not (eq (char-before) ?\())
 419                         (lambda (sym)   ;why not just nil ?   -sm
 420                           (or (boundp sym) (fboundp sym)
 421                               (symbol-plist sym)))
 422                       ;; Looks like a funcall position.  Let's double check.
 423                       (if (condition-case nil
 424                               (progn (up-list -2) (forward-char 1)
 425                                      (eq (char-after) ?\())
 426                             (error nil))
 427                           ;; If the first element of the parent list is an open
 428                           ;; parenthesis we are probably not in a funcall position.
 429                           ;; Maybe a `let' varlist or something.
 430                           nil
 431                         ;; Else, we assume that a function name is expected.
 432                         'fboundp)))))
 433              (completion (try-completion pattern obarray predicate)))
 434         (cond ((eq completion t))
 435               ((null completion)
 436                (message "Can't find completion for \"%s\"" pattern)
 437                (ding))
 438               ((not (string= pattern completion))
 439                (delete-region beg end)
 440                (insert completion))
 441               (t
 442                (message "Making completion list...")
 443                (let ((list (all-completions pattern obarray predicate)))
 444                  (setq list (sort list 'string<))
 445                  (or (eq predicate 'fboundp)
 446                      (let (new)
 447                        (while list
 448                          (setq new (cons (if (fboundp (intern (car list)))
 449                                              (list (car list) " <f>")
 450                                            (car list))
 451                                          new))
 452                          (setq list (cdr list)))
 453                        (setq list (nreverse new))))
 454                  (with-output-to-temp-buffer "*Completions*"
 455                    (display-completion-list list)))
 456                (message "Making completion list...%s" "done")))))))
 457
 458 ;;; arch-tag: aa7fa8a4-2e6f-4e9b-9cd9-fef06340e67e
 459 ;;; lisp.el ends here