code.delx.au - gnu-emacs/blob - lisp/avoid.el

   1 ;;; avoid.el -- make mouse pointer stay out of the way of editing.
   2
   3 ;;; Copyright (C) 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@cs.rochester.edu>
   6 ;; Keywords: mouse
   7 ;; Version: 1.10
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26 ;;;
  27 ;;; For those who are annoyed by the mouse pointer obscuring text,
  28 ;;; this mode moves the mouse pointer - either just a little out of
  29 ;;; the way, or all the way to the corner of the frame.
  30 ;;; To use, load or evaluate this file and type M-x mouse-avoidance-mode .
  31 ;;; To set up permanently, put this file on your load-path and put the
  32 ;;; following in your .emacs:
  33 ;;;
  34 ;;; (cond (window-system
  35 ;;;        (require 'avoid)
  36 ;;;        (mouse-avoidance-mode 'animate)))
  37 ;;;
  38 ;;; The 'animate can be 'jump or 'banish or 'exile or 'protean if you prefer.
  39 ;;; See the documentation for function `mouse-avoidance-mode' for
  40 ;;; details of the different modes.
  41 ;;;
  42 ;;; For added silliness, make the animatee animate...
  43 ;;; put something similar to the following into your .emacs:
  44 ;;;
  45 ;;; (cond (window-system
  46 ;;;       (setq x-pointer-shape
  47 ;;;          (eval (nth (random 4)
  48 ;;;                     '(x-pointer-man x-pointer-spider
  49 ;;;                       x-pointer-gobbler x-pointer-gumby))))
  50 ;;;       (set-mouse-color (cdr (assoc 'mouse-color (frame-parameters))))))
  51 ;;;
  52 ;;; For completely random pointer shape, replace the setq above with:
  53 ;;; (setq x-pointer-shape (mouse-avoidance-random-shape))
  54 ;;;
  55 ;;; Bugs / Warnings / To-Do:
  56 ;;;
  57 ;;; - Using this code does slow emacs down.  "banish" mode shouldn't
  58 ;;;   ever be too bad though, and on my workstation even "animate" doesn't
  59 ;;;   seem to have a noticable effect during editing.
  60 ;;;
  61 ;;; - It should find out where any overlapping frames are and avoid them,
  62 ;;;   rather than always raising the frame.
  63
  64 ;;; Credits:
  65 ;;; This code was helped by all those who contributed suggestions,
  66 ;;;   fixes, and additions
  67 ;;; Joe Harrington (and his advisor), for the original inspiration.
  68 ;;; Ken Manheimer, for dreaming up the Protean mode.
  69 ;;; Richard Stallman, for the awful cat-and-mouse pun, among other things.
  70 ;;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris,
  71 ;;; Simon Marshall, and M.S. Ashton, for their feedback.
  72 ;;;
  73 ;;; Code:
  74
  75 (provide 'avoid)
  76
  77 (defvar mouse-avoidance-mode nil
  78   "Value is t or a symbol if the mouse pointer should avoid the cursor.
  79 See function mouse-avoidance-mode for possible values.  Changing this
  80 variable is NOT the recommended way to change modes; use the function
  81 instead.")
  82
  83 (defvar mouse-avoidance-nudge-dist 15
  84   "*Average distance that mouse will be moved when approached by cursor.
  85 Only applies in mode-avoidance-mode and `jump' and its derivatives.
  86 For best results make this larger than mouse-avoidance-threshhold.")
  87
  88 (defvar mouse-avoidance-nudge-var 10
  89   "*Variability of mouse-avoidance-nudge-dist (which see).")
  90
  91 (defvar mouse-avoidance-animation-delay .01
  92   "Delay between animation steps, in seconds.")
  93
  94 (defvar mouse-avoidance-threshhold 5
  95   "*Mouse-pointer's flight distance.
  96 If the cursor gets closer than this, the mouse pointer will move away.
  97 Only applies in mouse-avoidance-modes `animate' and `jump'.")
  98
  99 ;; Internal variables
 100 (defvar mouse-avoidance-state nil)
 101 (defvar mouse-avoidance-pointer-shapes nil)
 102 (defvar mouse-avoidance-n-pointer-shapes 0)
 103
 104 ;;; Functions:
 105
 106 (defun mouse-avoidance-point-position ()
 107   "Return the position of point as (frame x . y).
 108 Analogous to mouse-position."
 109   (let* ((w (selected-window))
 110          (edges (window-edges w))
 111          (list
 112           (compute-motion (window-start w)                     ; start pos
 113                           (cons (car edges) (car (cdr edges))) ; start XY
 114                           (point)                              ; stop pos
 115                           (cons (nth 2 edges) (nth 3 edges))   ; stop XY: none
 116                           (1- (window-width))                  ; width
 117                           (cons (window-hscroll w) 0) ; 0 may not be right?
 118                           (selected-window))))
 119     ;; compute-motion returns (pos HPOS VPOS prevhpos contin)
 120     ;; we want:               (frame hpos . vpos)
 121     (setcar list (selected-frame))
 122     (setcdr (cdr list) (car (cdr (cdr list))))
 123     list))
 124
 125 (defun mouse-avoidance-set-mouse-position (pos)
 126   ;; Carefully set mouse position to given position (X . Y)
 127   ;; Ideally, should check if X,Y is in the current frame, and if not,
 128   ;; leave the mouse where it was.  However, this is currently
 129   ;; difficult to do, so we just raise the frame to avoid frame switches.
 130   ;; Returns t if it moved the mouse.
 131   (let ((f (selected-frame)))
 132     (raise-frame f)
 133     (set-mouse-position f (car pos) (cdr pos))
 134     t))
 135
 136 (defun mouse-avoidance-too-close-p (mouse)
 137   ;;  Return t if mouse pointer and point cursor are too close.
 138   ;; Acceptable distance is defined by mouse-avoidance-threshhold.
 139   (let ((point (mouse-avoidance-point-position)))
 140     (and (eq (car mouse) (car point))
 141          (car (cdr mouse))
 142          (< (abs (- (car (cdr mouse)) (car (cdr point))))
 143             mouse-avoidance-threshhold)
 144          (< (abs (- (cdr (cdr mouse)) (cdr (cdr point))))
 145             mouse-avoidance-threshhold))))
 146
 147 (defun mouse-avoidance-banish-destination ()
 148   "The position to which mouse-avoidance-mode 'banish moves the mouse.
 149 You can redefine this if you want the mouse banished to a different corner."
 150  (cons (1- (frame-width))
 151        0))
 152
 153 (defun mouse-avoidance-banish-mouse ()
 154   ;; Put the mouse pointer in the upper-right corner of the current frame.
 155   (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination)))
 156
 157 (defsubst mouse-avoidance-delta (cur delta dist var min max)
 158   ;; Decide how far to move in either dimension.
 159   ;; Args are the CURRENT location, the desired DELTA for
 160   ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY
 161   ;; in distance allowed, and the MIN and MAX possible window positions.
 162   ;; Returns something as close to DELTA as possible withing the constraints.
 163   (let ((L1 (max (- min cur) (+ (- dist) (- var))))
 164         (R1                  (+ (- dist)    var ))
 165         (L2                  (+    dist  (- var)))
 166         (R2 (min (- max cur) (+    dist     var))))
 167     (if (< R1 (- min cur)) (setq L1 nil R1 nil))
 168     (if (> L2 (- max cur)) (setq L2 nil R2 nil))
 169     (cond ((and L1 (< delta L1)) L1)
 170           ((and R1 (< delta R1)) delta)
 171           ((and R1 (< delta 0)) R1)
 172           ((and L2 (< delta L2)) L2)
 173           ((and R2 (< delta R2)) delta)
 174           (R2)
 175           ((or R1 L2))
 176           (t 0))))
 177
 178 (defun mouse-avoidance-nudge-mouse ()
 179   ;; Push the mouse a little way away, possibly animating the move
 180   ;; For these modes, state keeps track of the total offset that we've
 181   ;; accumulated, and tries to keep it close to zero.
 182   (let* ((cur (mouse-position))
 183          (cur-frame (car cur))
 184          (cur-pos (cdr cur))
 185          (deltax (mouse-avoidance-delta
 186                   (car cur-pos) (- (random mouse-avoidance-nudge-var)
 187                                    (car mouse-avoidance-state))
 188                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 189                   0 (frame-width)))
 190          (deltay (mouse-avoidance-delta
 191                   (cdr cur-pos) (- (random mouse-avoidance-nudge-var)
 192                                    (cdr mouse-avoidance-state))
 193                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 194                   0 (frame-height))))
 195     (setq mouse-avoidance-state
 196           (cons (+ (car mouse-avoidance-state) deltax)
 197                 (+ (cdr mouse-avoidance-state) deltay)))
 198     (if (or (eq mouse-avoidance-mode 'animate)
 199             (eq mouse-avoidance-mode 'proteus))
 200         (let ((i 0.0)
 201               (color (cdr (assoc 'mouse-color (frame-parameters)))))
 202           (while (<= i 1)
 203             (mouse-avoidance-set-mouse-position
 204              (cons (+ (car cur-pos) (round (* i deltax)))
 205                    (+ (cdr cur-pos) (round (* i deltay)))))
 206             (setq i (+ i (max .1 (/ 1.0 mouse-avoidance-nudge-dist))))
 207             (if (eq mouse-avoidance-mode 'proteus)
 208                 (progn
 209                   (setq x-pointer-shape (mouse-avoidance-random-shape))
 210                   (set-mouse-color color)))
 211             (sit-for mouse-avoidance-animation-delay)))
 212       (mouse-avoidance-set-mouse-position
 213        (cons (mod (+ (car (cdr cur)) deltax) (window-width))
 214              (mod (+ (cdr (cdr cur)) deltay) (window-height)))))))
 215
 216 (defun mouse-avoidance-random-shape ()
 217   "Return a random cursor shape.
 218 This assumes that any variable whose name begins with x-pointer- and
 219 has an integer value is a valid cursor shape.  You might want to
 220 redefine this function to suit your own tastes."
 221   (if (null mouse-avoidance-pointer-shapes)
 222       (progn
 223         (setq mouse-avoidance-pointer-shapes
 224               (mapcar '(lambda (x) (symbol-value (intern x)))
 225                       (all-completions "x-pointer-" obarray
 226                                        '(lambda (x)
 227                                           (and (boundp x)
 228                                                (integerp (symbol-value x)))))))
 229         (setq mouse-avoidance-n-pointer-shapes
 230               (length mouse-avoidance-pointer-shapes))))
 231   (nth (random mouse-avoidance-n-pointer-shapes)
 232        mouse-avoidance-pointer-shapes))
 233
 234 (defun mouse-avoidance-banish-hook ()
 235   (if (and (not executing-kbd-macro)    ; don't check inside macro
 236            (mouse-avoidance-kbd-command (this-command-keys)))
 237       (mouse-avoidance-banish-mouse)))
 238
 239 (defun mouse-avoidance-exile-hook ()
 240   ;; For exile mode, the state is nil when the mouse is in its normal
 241   ;; position, and set to the old mouse-position when the mouse is in exile.
 242   (if (and (not executing-kbd-macro)
 243            (mouse-avoidance-kbd-command (this-command-keys)))
 244       (let ((mp (mouse-position)))
 245         (cond ((and (not mouse-avoidance-state)
 246                     (mouse-avoidance-too-close-p mp))
 247                (setq mouse-avoidance-state mp)
 248                (mouse-avoidance-banish-mouse))
 249               ((and mouse-avoidance-state
 250                     (not (mouse-avoidance-too-close-p mouse-avoidance-state)))
 251                (if (and (eq (car mp) (selected-frame))
 252                         (equal (cdr mp) (mouse-avoidance-banish-destination)))
 253                    (mouse-avoidance-set-mouse-position
 254                     ;; move back only if user has not moved mouse
 255                     (cdr mouse-avoidance-state)))
 256                ;; but clear state anyway, to be ready for another move
 257                (setq mouse-avoidance-state nil))))))
 258
 259 (defun mouse-avoidance-fancy-hook ()
 260   ;; Used for the "fancy" modes, ie jump et al.
 261   (if (and (not executing-kbd-macro)    ; don't check inside macro
 262            (mouse-avoidance-kbd-command (this-command-keys))
 263            (mouse-avoidance-too-close-p (mouse-position)))
 264       (let ((old-pos (mouse-position)))
 265         (mouse-avoidance-nudge-mouse)
 266         (if (not (eq (selected-frame) (car old-pos))) ; move went awry
 267             (set-mouse-position old-pos (car old-pos) ; sigh..
 268                                 (car (cdr old-pos))
 269                                 (cdr (cdr old-pos)))))))
 270
 271 (defun mouse-avoidance-kbd-command (key)
 272   "Return t if the KEYSEQENCE is composed of keyboard events only.
 273 Returns nil if there are any lists in the key sequence."
 274   (cond ((null key) nil)                ; Null event seems to be
 275                                         ; returned occasionally.
 276         ((not (vectorp key)) t)         ; Strings are keyboard events.
 277         ((catch 'done
 278            (let ((i 0)
 279                  (l (length key)))
 280              (while (< i l)
 281                (if (listp (aref key i))
 282                    (throw 'done nil))
 283                (setq i (1+ i))))
 284            t))))
 285
 286 (defun mouse-avoidance-mode (&optional mode)
 287   "Set cursor avoidance mode to MODE.
 288 MODE should be one of the symbols `banish', `exile', `jump', `animate',
 289 `cat-and-mouse', `proteus', or `none'.
 290
 291 If MODE is nil, toggle mouse avoidance between `none` and `banish'
 292 modes.  Positive numbers and symbols other than the above are treated
 293 as equivalent to `banish'; negative numbers and `-' are equivalent to `none'.
 294
 295 Effects of the different modes:
 296  * BANISH: Move the mouse to the upper-right corner on any keypress.
 297  * EXILE: Move the mouse to the corner only if the cursor gets too close,
 298      and allow it to return once the cursor is out of the way.
 299  * JUMP: If the cursor gets too close to the mouse, displace the mouse
 300      a random distance & direction.
 301  * ANIMATE: As `jump', but shows steps along the way for illusion of motion.
 302  * CAT-AND-MOUSE: Same as `animate'.
 303  * PROTEUS: As `animate', but changes the shape of the mouse pointer too.
 304
 305 Whenever the mouse is moved, the frame is also raised.
 306
 307 \(see `mouse-avoidance-threshhold' for definition of \"too close\",
 308 and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for
 309 definition of \"random distance\".)"
 310   (interactive
 311    (list (intern (completing-read
 312                   "Select cursor avoidance technique (SPACE for list): "
 313                   '(("banish") ("exile") ("jump") ("animate")
 314                     ("cat-and-mouse") ("proteus") ("none"))
 315                   nil t))))
 316   (if (eq mode 'cat-and-mouse)
 317       (setq mode 'animate))
 318   (setq post-command-hook
 319         (delete 'mouse-avoidance-banish-hook (append post-command-hook nil)))
 320   (setq post-command-hook
 321         (delete 'mouse-avoidance-exile-hook (append post-command-hook nil)))
 322   (setq post-command-hook
 323         (delete 'mouse-avoidance-fancy-hook (append post-command-hook nil)))
 324   (cond ((eq mode 'none)
 325          (setq mouse-avoidance-mode nil))
 326         ((or (eq mode 'jump)
 327              (eq mode 'animate)
 328              (eq mode 'proteus))
 329          (add-hook 'post-command-hook 'mouse-avoidance-fancy-hook)
 330          (setq mouse-avoidance-mode mode
 331                mouse-avoidance-state (cons 0 0)))
 332         ((eq mode 'exile)
 333          (add-hook 'post-command-hook 'mouse-avoidance-exile-hook)
 334          (setq mouse-avoidance-mode mode
 335                mouse-avoidance-state nil))
 336         ((or (eq mode 'banish)
 337              (eq mode t)
 338              (and (null mode) (null mouse-avoidance-mode))
 339              (and mode (> (prefix-numeric-value mode) 0)))
 340          (add-hook 'post-command-hook 'mouse-avoidance-banish-hook)
 341          (setq mouse-avoidance-mode 'banish))
 342         (t (setq mouse-avoidance-mode nil)))
 343   (force-mode-line-update))
 344
 345 (or (assq 'mouse-avoidance-mode minor-mode-alist)
 346     (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid")
 347                                  minor-mode-alist)))
 348
 349 ;;; End of avoid.el