code.delx.au - gnu-emacs/blob - configure.ac

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the 'configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2016 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 dnl Note this is parsed by (at least) make-dist and lisp/cedet/ede/emacs.el.
  26 AC_INIT(GNU Emacs, 25.1.50, bug-gnu-emacs@gnu.org)
  27
  28 dnl Set emacs_config_options to the options of 'configure', quoted for the shell,
  29 dnl and then quoted again for a C string.  Separate options with spaces.
  30 dnl Add some environment variables, if they were passed via the environment
  31 dnl rather than on the command-line.
  32 emacs_config_options=
  33 optsep=
  34 dnl This is the documented way to record the args passed to configure,
  35 dnl rather than $ac_configure_args.
  36 for opt in "$@" CFLAGS CPPFLAGS LDFLAGS; do
  37   case $opt in
  38     -n | --no-create | --no-recursion)
  39       continue ;;
  40     CFLAGS | CPPFLAGS | LDFLAGS)
  41       eval 'test "${'$opt'+set}" = set' || continue
  42       case " $*" in
  43         *" $opt="*) continue ;;
  44       esac
  45       eval opt=$opt=\$$opt ;;
  46   esac
  47
  48   emacs_shell_specials=$IFS\''"#$&()*;<>?@<:@\\`{|~'
  49   case $opt in
  50     *[["$emacs_shell_specials"]]*)
  51       case $opt in
  52         *\'*)
  53           emacs_quote_apostrophes="s/'/'\\\\''/g"
  54           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_apostrophes"` ;;
  55       esac
  56       opt="'$opt'"
  57       case $opt in
  58         *[['"\\']]*)
  59           emacs_quote_for_c='s/[["\\]]/\\&/g; $!s/$/\\n\\/'
  60           opt=`AS_ECHO(["$opt"]) | sed "$emacs_quote_for_c"` ;;
  61       esac ;;
  62   esac
  63   AS_VAR_APPEND([emacs_config_options], ["$optsep$opt"])
  64   optsep=' '
  65 done
  66
  67 AC_CONFIG_HEADERS(src/config.h:src/config.in)
  68 AC_CONFIG_SRCDIR(src/lisp.h)
  69 AC_CONFIG_AUX_DIR(build-aux)
  70 dnl automake 1.13 and later understand this, making -I m4 unnecessary.
  71 dnl With older versions this is a no-op.
  72 AC_CONFIG_MACRO_DIR(m4)
  73
  74 xcsdkdir=
  75 AC_CHECK_PROGS(XCRUN, [xcrun])
  76 if test -n "$XCRUN"; then
  77   if test -z "$MAKE"; then
  78     dnl Call the variable MAKE_PROG, not MAKE, to avoid confusion with
  79     dnl the usual MAKE variable that 'make' itself uses.
  80     AC_CHECK_PROG([MAKE_PROG], [make], [yes])
  81     if test -z "$MAKE_PROG"; then
  82       MAKE="$XCRUN MAKE"
  83       export MAKE
  84       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
  85     fi
  86   fi
  87 fi
  88
  89 dnl GNU Make is required, so don't test for its individual features.
  90 am_cv_make_support_nested_variables=yes
  91 AC_DEFUN([AC_PROG_MAKE_SET],
  92   [SET_MAKE=
  93    AC_SUBST([SET_MAKE])])
  94
  95 dnl Check for GNU Make and possibly set MAKE before running AM_INIT_AUTOMAKE.
  96 [emacs_check_gnu_make ()
  97 {
  98   emacs_makeout=`($1 --version) 2>/dev/null` &&
  99   case $emacs_makeout in
 100     'GNU Make '3.8[1-9]* | 'GNU Make '3.9[0-9]* | \
 101     'GNU Make '3.[1-9][0-9][0-9]* | 'GNU Make '[4-9]* | 'GNU Make '[1-9][0-9]* )
 102        ac_path_MAKE_found=:;;
 103   esac
 104 }]
 105 AC_CACHE_CHECK([for GNU Make], [ac_cv_path_MAKE],
 106   [ac_path_MAKE_found=false
 107    if test -n "$MAKE"; then
 108      emacs_check_gnu_make "$MAKE"
 109      ac_cv_path_MAKE=$MAKE
 110    else
 111      emacs_tried_make=false
 112      emacs_tried_gmake=false
 113      emacs_tried_gnumake=false
 114      AC_PATH_PROGS_FEATURE_CHECK([MAKE], [make gmake gnumake],
 115        [[emacs_check_gnu_make "$ac_path_MAKE"
 116          if $ac_path_MAKE_found; then
 117            # Use the fully-qualified program name only if the basename
 118            # would not resolve to it.
 119            if eval \$emacs_tried_$ac_prog; then
 120              ac_cv_path_MAKE=$ac_path_MAKE
 121            else
 122              ac_cv_path_MAKE=$ac_prog
 123            fi
 124          fi
 125          eval emacs_tried_$ac_prog=:]])
 126    fi])
 127 $ac_path_MAKE_found || {
 128 AC_MSG_ERROR([[Building Emacs requires GNU Make, at least version 3.81.
 129 If you have it installed under another name, configure with 'MAKE=...'.
 130 For example, run '$0 MAKE=gnu-make'.]])
 131 }
 132 MAKE=$ac_cv_path_MAKE
 133 export MAKE
 134
 135 dnl Fairly arbitrary, older versions might work too.
 136 AM_INIT_AUTOMAKE(1.11)
 137
 138 dnl Canonicalize the configuration name.
 139 AC_CANONICAL_HOST
 140
 141 case $host in
 142  *-mingw*)
 143
 144   if test -z "$host_alias"; then
 145
 146       # No --host argument was given to 'configure'; therefore $host
 147       # was set to a default value based on the build platform.  But
 148       # this default value may be wrong if we are building from a
 149       # 64-bit MSYS[2] pre-configured to build 32-bit MinGW programs.
 150       # Therefore, we'll try to get the right host platform from the
 151       # compiler's target.
 152
 153       AC_MSG_CHECKING([the compiler's target])
 154       if test -z "$CC"; then
 155           cc=gcc
 156       else
 157           cc=$CC
 158       fi
 159       cc_target=`$cc -v 2>&1 | sed -n 's/Target: //p'`
 160       case "$cc_target" in
 161           *-*) host=$cc_target
 162               ;;
 163           "") AC_MSG_ERROR([Impossible to obtain $cc compiler target.
 164 Please explicitly provide --host.])
 165               ;;
 166           *) AC_MSG_WARN([Compiler reported non-standard target.
 167 Defaulting to $host.])
 168               ;;
 169       esac
 170       AC_MSG_RESULT([$host])
 171   fi
 172
 173   . $srcdir/nt/mingw-cfg.site
 174
 175   case $srcdir in
 176     /* | ?:*)
 177       # srcdir is an absolute path.  In this case, force the format
 178       # "/c/foo/bar", to simplify later conversions to native Windows
 179       # format ("c:/foo/bar").
 180       srcdir=`cd "${srcdir}" && pwd -W`
 181       # 'eval' pacifies strict POSIX non-MinGW shells (Bug#18612).
 182       eval 'srcdir="/${srcdir:0:1}${srcdir:2}"'
 183       ;;
 184   esac;;
 185 esac
 186
 187 canonical=$host
 188 configuration=${host_alias-${build_alias-$host}}
 189
 190 dnl Support for --program-prefix, --program-suffix and
 191 dnl --program-transform-name options
 192 AC_ARG_PROGRAM
 193
 194 dnl It is important that variables on the RHS not be expanded here,
 195 dnl hence the single quotes.  This is per the GNU coding standards, see
 196 dnl (autoconf) Installation Directory Variables
 197 dnl See also epaths.h below.
 198 lispdir='${datadir}/emacs/${version}/lisp'
 199 standardlisppath='${lispdir}'
 200 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
 201 '${datadir}/emacs/site-lisp'
 202 lisppath='${locallisppath}:${standardlisppath}'
 203 etcdir='${datadir}/emacs/${version}/etc'
 204 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
 205 etcdocdir='${datadir}/emacs/${version}/etc'
 206 gamedir='${localstatedir}/games/emacs'
 207
 208 dnl Special option to disable the most of other options.
 209 AC_ARG_WITH(all,
 210 [AS_HELP_STRING([--without-all],
 211                 [omit almost all features and build
 212                 small executable with minimal dependencies])],
 213   [with_features=$withval],
 214   [with_features=yes])
 215
 216 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
 217 dnl Create a new --with option that defaults to being disabled.
 218 dnl NAME is the base name of the option.  The shell variable with_NAME
 219 dnl   will be set to either the user's value (if the option is
 220 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
 221 dnl   option is not specified).  Note that the shell variable name is
 222 dnl   constructed as autoconf does, by replacing non-alphanumeric
 223 dnl   characters with "_".
 224 dnl HELP-STRING is the help text for the option.
 225 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
 226   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
 227     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
 228 ])dnl
 229
 230 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
 231 dnl Create a new --with option that defaults to $with_features.
 232 dnl NAME is the base name of the option.  The shell variable with_NAME
 233 dnl   will be set either to 'no' (for a plain --without-NAME) or to
 234 dnl   'yes' (if the option is not specified).  Note that the shell
 235 dnl   variable name is constructed as autoconf does, by replacing
 236 dnl   non-alphanumeric characters with "_".
 237 dnl HELP-STRING is the help text for the option.
 238 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
 239   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
 240    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=$with_features])dnl
 241 ])dnl
 242
 243 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
 244 if test "$with_pop" = yes; then
 245    AC_DEFINE(MAIL_USE_POP)
 246 fi
 247 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
 248
 249 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
 250 if test "$with_kerberos" != no; then
 251    AC_DEFINE(KERBEROS)
 252 fi
 253 AH_TEMPLATE(KERBEROS,
 254             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
 255
 256 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
 257 if test "${with_kerberos5}" != no; then
 258   if test "${with_kerberos}" = no; then
 259     with_kerberos=yes
 260     AC_DEFINE(KERBEROS)
 261   fi
 262   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
 263 fi
 264
 265 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
 266 dnl FIXME hesiod support may not be present, so it seems like an error
 267 dnl to define, or at least use, this unconditionally.
 268 if test "$with_hesiod" != no; then
 269   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 270 fi
 271
 272 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 273 if test "$with_mail_unlink" != no; then
 274    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 275 fi
 276
 277 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 278     [string giving default POP mail host])],
 279     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 280
 281 AC_ARG_WITH([sound],[AS_HELP_STRING([--with-sound=VALUE],
 282   [compile with sound support (VALUE one of: yes, alsa, oss, bsd-ossaudio, no;
 283 default yes).  Only for GNU/Linux, FreeBSD, NetBSD, MinGW, Cygwin.])],
 284   [ case "${withval}" in
 285       yes|no|alsa|oss|bsd-ossaudio) val=$withval ;;
 286       *) AC_MSG_ERROR(['--with-sound=$withval' is invalid;
 287 this option's value should be 'yes', 'no', 'alsa', 'oss', or 'bsd-ossaudio'.])
 288       ;;
 289     esac
 290     with_sound=$val
 291   ],
 292   [with_sound=$with_features])
 293
 294 dnl FIXME currently it is not the last.
 295 dnl This should be the last --with option, because --with-x is
 296 dnl added later on when we find the file name of X, and it's best to
 297 dnl keep them together visually.
 298 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 299  [use an X toolkit (KIT one of: yes or gtk, gtk2, gtk3, lucid or athena, motif, no)])],
 300 [         case "${withval}" in
 301             y | ye | yes )      val=gtk ;;
 302             n | no )            val=no  ;;
 303             l | lu | luc | luci | lucid )       val=lucid ;;
 304             a | at | ath | athe | athen | athena )      val=athena ;;
 305             m | mo | mot | moti | motif )       val=motif ;;
 306             g | gt | gtk  )     val=gtk ;;
 307             gtk2  )     val=gtk2 ;;
 308             gtk3  )     val=gtk3 ;;
 309             * )
 310 AC_MSG_ERROR(['--with-x-toolkit=$withval' is invalid;
 311 this option's value should be 'yes', 'no', 'lucid', 'athena', 'motif', 'gtk',
 312 'gtk2' or 'gtk3'.  'yes' and 'gtk' are synonyms.
 313 'athena' and 'lucid' are synonyms.])
 314             ;;
 315           esac
 316           with_x_toolkit=$val
 317 ])
 318
 319 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit); allows buffer and string size up to 2GB on 32-bit hosts, at the cost of 10% to 30% slowdown of Lisp interpreter and larger memory footprint])
 320 if test "$with_wide_int" = yes; then
 321   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 322 fi
 323
 324 dnl _ON results in a '--without' option in the --help output, so
 325 dnl the help text should refer to "don't compile", etc.
 326 with_xpm_set=${with_xpm+set}
 327 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 328 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 329 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 330 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 331 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 332 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 333 OPTION_DEFAULT_OFF([cairo],[compile with Cairo drawing (experimental)])
 334 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 335 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 336
 337 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 338 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 339 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 340
 341 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 342 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 343 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 344 AC_ARG_WITH([ns],[AS_HELP_STRING([--with-ns],
 345 [use Nextstep (OS X Cocoa or GNUstep) windowing system.
 346 On by default on Mac OS X.])],[],[with_ns=maybe])
 347 OPTION_DEFAULT_OFF([w32], [use native MS Windows GUI in a Cygwin build])
 348
 349 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 350 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 351 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 352 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 353 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 354 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 355 OPTION_DEFAULT_ON([zlib],[don't compile with zlib decompression support])
 356 OPTION_DEFAULT_OFF([modules],[compile with dynamic modules support])
 357
 358 AC_ARG_WITH([file-notification],[AS_HELP_STRING([--with-file-notification=LIB],
 359  [use a file notification library (LIB one of: yes, inotify, kqueue, gfile, w32, no)])],
 360  [ case "${withval}" in
 361     y | ye | yes )      val=yes ;;
 362     n | no )            val=no  ;;
 363     i | in | ino | inot | inoti | inotif | inotify )    val=inotify ;;
 364     k | kq | kqu | kque | kqueu | kqueue )      val=kqueue ;;
 365     g | gf | gfi | gfil | gfile )       val=gfile ;;
 366     w | w3 | w32 )      val=w32 ;;
 367     * ) AC_MSG_ERROR(['--with-file-notification=$withval' is invalid;
 368 this option's value should be 'yes', 'no', 'inotify', 'kqueue', 'gfile' or 'w32'.
 369 'yes' is a synonym for 'w32' on MS-Windows, for 'no' on Nextstep,
 370 otherwise for the first of 'inotify', 'kqueue' or 'gfile' that is usable.])
 371     ;;
 372    esac
 373    with_file_notification=$val
 374  ],
 375  [with_file_notification=$with_features])
 376
 377 OPTION_DEFAULT_OFF([xwidgets],
 378   [enable use of some gtk widgets in Emacs buffers (requires gtk3)])
 379
 380 ## For the times when you want to build Emacs but don't have
 381 ## a suitable makeinfo, and can live without the manuals.
 382 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 383 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 384
 385 ## This might be a 'configure' arg.
 386 AC_SUBST([ACLOCAL_PATH])
 387
 388 ## Makefile.in needs the cache file name.
 389 AC_SUBST(cache_file)
 390
 391 ## This is an option because I do not know if all info/man support
 392 ## compressed files, nor how to test if they do so.
 393 OPTION_DEFAULT_ON([compress-install],
 394   [don't compress some files (.el, .info, etc.) when installing.  Equivalent to:
 395 make GZIP_PROG= install])
 396
 397 AC_ARG_WITH(gameuser,dnl
 398 [AS_HELP_STRING([--with-gameuser=USER_OR_GROUP],
 399                 [user for shared game score files.
 400                 An argument prefixed by ':' specifies a group instead.])])
 401 gameuser=
 402 gamegroup=
 403 # We don't test if we can actually chown/chgrp here, because configure
 404 # may run without root privileges.  lib-src/Makefile.in will handle
 405 # any errors due to missing user/group gracefully.
 406 case ${with_gameuser} in
 407   no) ;;
 408   "" | yes) gamegroup=games ;;
 409   :*) gamegroup=${with_gameuser#:} ;;
 410   *) gameuser=${with_gameuser} ;;
 411 esac
 412
 413 AC_ARG_WITH([gnustep-conf],dnl
 414 [AS_HELP_STRING([--with-gnustep-conf=FILENAME],
 415    [name of GNUstep configuration file to use on systems where the command
 416     'gnustep-config' does not work; default $GNUSTEP_CONFIG_FILE, or
 417     /etc/GNUstep/GNUstep.conf])])
 418 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 419   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 420 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 421      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 422
 423 AC_ARG_ENABLE(ns-self-contained,
 424 [AS_HELP_STRING([--disable-ns-self-contained],
 425                 [disable self contained build under NeXTstep])],
 426    EN_NS_SELF_CONTAINED=$enableval,
 427    EN_NS_SELF_CONTAINED=yes)
 428
 429 locallisppathset=no
 430 AC_ARG_ENABLE(locallisppath,
 431 [AS_HELP_STRING([--enable-locallisppath=PATH],
 432                 [directories Emacs should search for lisp files specific
 433                  to this site])],
 434 if test "${enableval}" = "no"; then
 435   locallisppath=
 436 elif test "${enableval}" != "yes"; then
 437   locallisppath=${enableval} locallisppathset=yes
 438 fi)
 439
 440 AC_ARG_ENABLE(checking,
 441 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 442                 [enable expensive run-time checks.  With LIST,
 443                  enable only specific categories of checks.
 444                  Categories are: all,yes,no.
 445                  Flags are: stringbytes, stringoverrun, stringfreelist,
 446                  xmallocoverrun, conslist, glyphs])],
 447 [ac_checking_flags="${enableval}"],[])
 448 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 449 for check in $ac_checking_flags
 450 do
 451         case $check in
 452         # these set all the flags to specific states
 453         yes)            ac_enable_checking=1 ;;
 454         no)             ac_enable_checking= ;
 455                         ac_gc_check_stringbytes= ;
 456                         ac_gc_check_string_overrun= ;
 457                         ac_gc_check_string_free_list= ;
 458                         ac_xmalloc_overrun= ;
 459                         ac_gc_check_cons_list= ;
 460                         ac_glyphs_debug= ;;
 461         all)            ac_enable_checking=1 ;
 462                         ac_gc_check_stringbytes=1 ;
 463                         ac_gc_check_string_overrun=1 ;
 464                         ac_gc_check_string_free_list=1 ;
 465                         ac_xmalloc_overrun=1 ;
 466                         ac_gc_check_cons_list=1 ;
 467                         ac_glyphs_debug=1 ;;
 468         # these enable particular checks
 469         stringbytes)    ac_gc_check_stringbytes=1 ;;
 470         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 471         stringfreelist) ac_gc_check_string_free_list=1 ;;
 472         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 473         conslist)       ac_gc_check_cons_list=1 ;;
 474         glyphs)         ac_glyphs_debug=1 ;;
 475         *)      AC_MSG_ERROR(unknown check category $check) ;;
 476         esac
 477 done
 478 IFS="$ac_save_IFS"
 479
 480 if test x$ac_enable_checking != x ; then
 481   AC_DEFINE(ENABLE_CHECKING, 1,
 482 [Define to 1 if expensive run-time data type and consistency checks are enabled.])
 483 fi
 484 if test x$ac_gc_check_stringbytes != x ; then
 485   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 486 [Define this temporarily to hunt a bug.  If defined, the size of
 487    strings is redundantly recorded in sdata structures so that it can
 488    be compared to the sizes recorded in Lisp strings.])
 489 fi
 490 if test x$ac_gc_check_string_overrun != x ; then
 491   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 492 [Define this to check for short string overrun.])
 493 fi
 494 if test x$ac_gc_check_string_free_list != x ; then
 495   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 496 [Define this to check the string free list.])
 497 fi
 498 if test x$ac_xmalloc_overrun != x ; then
 499   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 500 [Define this to check for malloc buffer overrun.])
 501 fi
 502 if test x$ac_gc_check_cons_list != x ; then
 503   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 504 [Define this to check for errors in cons list.])
 505 fi
 506 if test x$ac_glyphs_debug != x ; then
 507   AC_DEFINE(GLYPH_DEBUG, 1,
 508 [Define this to enable glyphs debugging code.])
 509 fi
 510
 511 AC_ARG_ENABLE(check-lisp-object-type,
 512 [AS_HELP_STRING([--enable-check-lisp-object-type],
 513                 [enable compile time checks for the Lisp_Object data type.
 514                 This is useful for development for catching certain types of bugs.])],
 515 if test "${enableval}" != "no"; then
 516    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 517    [Define this to enable compile time checks for the Lisp_Object data type.])
 518 fi)
 519
 520
 521 dnl The name of this option is unfortunate.  It predates, and has no
 522 dnl relation to, the "sampling-based elisp profiler" added in 24.3.
 523 dnl Actually, it stops it working.
 524 dnl http://lists.gnu.org/archive/html/emacs-devel/2012-11/msg00393.html
 525 AC_ARG_ENABLE(profiling,
 526 [AS_HELP_STRING([--enable-profiling],
 527                 [build emacs with low-level, gprof profiling support.
 528                 Mainly useful for debugging Emacs itself.  May not work on
 529                 all platforms.  Stops profiler.el working.])],
 530 [ac_enable_profiling="${enableval}"],[])
 531 if test x$ac_enable_profiling != x ; then
 532    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 533 else
 534    PROFILING_CFLAGS=
 535 fi
 536 AC_SUBST(PROFILING_CFLAGS)
 537
 538 AC_ARG_ENABLE(autodepend,
 539 [AS_HELP_STRING([--enable-autodepend],
 540                 [automatically generate dependencies to .h-files.
 541                  Requires gcc, enabled if found.])],
 542 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 543
 544 AC_ARG_ENABLE(gtk-deprecation-warnings,
 545 [AS_HELP_STRING([--enable-gtk-deprecation-warnings],
 546                 [Show Gtk+/Gdk deprecation warnings for Gtk+ >= 3.0])],
 547 [ac_enable_gtk_deprecation_warnings="${enableval}"],[])
 548
 549 BUILD_DETAILS=
 550 AC_ARG_ENABLE([build-details],
 551   [AS_HELP_STRING([--disable-build-details],
 552                   [Make the build more deterministic by omitting host
 553                    names, time stamps, etc. from the output.])],
 554   [test "$enableval" = no && BUILD_DETAILS=--no-build-details])
 555 AC_SUBST([BUILD_DETAILS])
 556
 557 dnl This used to use changequote, but, apart from 'changequote is evil'
 558 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 559 dnl the great gob of text.  Thus it's not processed for possible expansion.
 560 dnl Just make sure the brackets remain balanced.
 561 dnl
 562 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 563 dnl indicated by comments.
 564 dnl quotation begins
 565 [
 566
 567 ### If you add support for a new configuration, add code to this
 568 ### switch statement to recognize your configuration name and select
 569 ### the appropriate opsys.
 570
 571 ### As far as handling version numbers on operating systems is
 572 ### concerned, make sure things will fail in a fixable way.  If
 573 ### /etc/MACHINES doesn't say anything about version numbers, be
 574 ### prepared to handle anything reasonably.  If version numbers
 575 ### matter, be sure /etc/MACHINES says something about it.
 576
 577 opsys='' unported=no
 578 case "${canonical}" in
 579
 580   ## GNU/Linux and similar ports
 581   *-*-linux* )
 582     opsys=gnu-linux
 583   ;;
 584
 585   ## FreeBSD ports
 586   *-*-freebsd* )
 587     opsys=freebsd
 588   ;;
 589
 590   ## DragonFly ports
 591   *-*-dragonfly* )
 592     opsys=dragonfly
 593   ;;
 594
 595   ## FreeBSD kernel + glibc based userland
 596   *-*-kfreebsd*gnu* )
 597     opsys=gnu-kfreebsd
 598   ;;
 599
 600   ## NetBSD ports
 601   *-*-netbsd* )
 602     opsys=netbsd
 603   ;;
 604
 605   ## OpenBSD ports
 606   *-*-openbsd* | *-*-mirbsd* )
 607     opsys=openbsd
 608   ;;
 609
 610   ## Apple Darwin / Mac OS X
 611   *-apple-darwin* )
 612     case "${canonical}" in
 613       *-apple-darwin[0-9].*) unported=yes ;;
 614       i[3456]86-* | x86_64-* )  ;;
 615       * )            unported=yes ;;
 616     esac
 617     opsys=darwin
 618     ## FIXME: Find a way to use Fink if available (Bug#11507).
 619   ;;
 620
 621   ## Chromium Native Client
 622   *-nacl )
 623     opsys=nacl
 624   ;;
 625
 626   ## Cygwin ports
 627   *-*-cygwin )
 628     opsys=cygwin
 629   ;;
 630
 631   ## HP 9000 series 700 and 800, running HP/UX
 632   hppa*-hp-hpux10.2* )
 633     opsys=hpux10-20
 634   ;;
 635   hppa*-hp-hpux1[1-9]* )
 636     opsys=hpux11
 637     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 638   ;;
 639
 640   ## IBM machines
 641   rs6000-ibm-aix4.[23]* )
 642     opsys=aix4-2
 643   ;;
 644   powerpc-ibm-aix4.[23]*  )
 645     opsys=aix4-2
 646   ;;
 647   rs6000-ibm-aix[56]* )
 648     opsys=aix4-2
 649   ;;
 650   powerpc-ibm-aix[5-9]* | powerpc-ibm-aix[1-9][0-9]* )
 651     opsys=aix4-2
 652   ;;
 653
 654   ## Suns
 655   *-sun-solaris* \
 656     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 657     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 658     case "${canonical}" in
 659       i[3456]86-*-* )   ;;
 660       amd64-*-*|x86_64-*-*) ;;
 661       sparc* )          ;;
 662       * )               unported=yes ;;
 663     esac
 664     case "${canonical}" in
 665       *-sunos5.[1-9][0-9]* | *-solaris2.[1-9][0-9]* )
 666                 opsys=sol2-10
 667                 emacs_check_sunpro_c=yes
 668                 ;;
 669       *-sunos5.[1-5]* | *-solaris2.[1-5]* ) unported=yes ;;
 670       ## Note that Emacs 23.1's NEWS said the following would be dropped.
 671       *-sunos5.6* | *-solaris2.6* )
 672                 opsys=sol2-6
 673                 RANLIB="ar -ts"
 674                 ;;
 675       ## 5.7 EOL Aug 2008, 5.8 EOL Mar 2012.
 676       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 677                 opsys=sol2-6
 678                 emacs_check_sunpro_c=yes
 679                 ;;
 680     esac
 681     ## Watch out for a compiler that we know will not work.
 682     case "${canonical}" in
 683      *-solaris* | *-sunos5* )
 684                 if [ "x$CC" = x/usr/ucb/cc ]; then
 685                   ## /usr/ucb/cc doesn't work;
 686                   ## we should find some other compiler that does work.
 687                   unset CC
 688                 fi
 689                 ;;
 690       *) ;;
 691     esac
 692   ;;
 693
 694   ## Intel 386 machines where we don't care about the manufacturer.
 695   i[3456]86-*-* )
 696     case "${canonical}" in
 697       *-darwin* )               opsys=darwin ;;
 698       *-mingw* )
 699                 opsys=mingw32
 700                 # MinGW overrides and adds some system headers in nt/inc.
 701                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 702                 ;;
 703       *-sysv4.2uw* )            opsys=unixware ;;
 704       *-sysv5uw* )              opsys=unixware ;;
 705       *-sysv5OpenUNIX* )        opsys=unixware ;;
 706       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 707     esac
 708   ;;
 709
 710   # MinGW64
 711   x86_64-*-* )
 712     case "${canonical}" in
 713       *-mingw* )
 714                 opsys=mingw32
 715                 # MinGW overrides and adds some system headers in nt/inc.
 716                 GCC_TEST_OPTIONS="-I $srcdir/nt/inc"
 717                 ;;
 718       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 719     esac
 720   ;;
 721
 722   * )
 723     unported=yes
 724   ;;
 725 esac
 726
 727 ### If the code above didn't choose an operating system, just choose
 728 ### an operating system based on the configuration name.  You really
 729 ### only want to use this when you have no idea what the right
 730 ### operating system is; if you know what operating systems a machine
 731 ### runs, it's cleaner to make it explicit in the case statement
 732 ### above.
 733 if test x"${opsys}" = x; then
 734   case "${canonical}" in
 735     *-gnu* )                            opsys=gnu ;;
 736     * )
 737       unported=yes
 738     ;;
 739   esac
 740 fi
 741
 742 ]
 743 dnl quotation ends
 744
 745 if test $unported = yes; then
 746   AC_MSG_ERROR([Emacs does not support '${canonical}' systems.
 747 If you think it should, please send a report to ${PACKAGE_BUGREPORT}.
 748 Check 'etc/MACHINES' for recognized configuration names.])
 749 fi
 750
 751 #### Choose a compiler.
 752
 753 dnl Don't bother to test for C89.
 754 AC_DEFUN([_AC_PROG_CC_C89], [$2])
 755
 756 dnl Sets GCC=yes if using gcc.
 757 AC_PROG_CC([gcc cc cl clang "$XCRUN gcc" "$XCRUN clang"])
 758 if test -n "$XCRUN"; then
 759   AC_CHECK_PROGS(AR, [ar "$XCRUN ar"])
 760   test -n "$AR" && export AR
 761 fi
 762
 763 dnl Emacs needs C99 or later.
 764 gl_PROG_CC_C99
 765
 766 AM_PROG_CC_C_O
 767
 768 if test x$GCC = xyes; then
 769   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 770 fi
 771
 772 dnl This is used in lib/Makefile.am to use nt/gnulib.mk, the
 773 dnl alternative to lib/gnulib.mk, so as to avoid generating header files
 774 dnl that clash with MinGW.
 775 AM_CONDITIONAL([BUILDING_FOR_WINDOWSNT], [test "x$opsys" = "xmingw32"])
 776
 777 # Avoid gnulib's tests for -lcrypto, so that there's no static dependency on it.
 778 AC_DEFUN([gl_CRYPTO_CHECK])
 779 # Avoid gnulib's tests for HAVE_WORKING_O_NOATIME and HAVE_WORKING_O_NOFOLLOW,
 780 # as we don't use them.
 781 AC_DEFUN([gl_FCNTL_O_FLAGS])
 782 # Avoid gnulib's test for pthread_sigmask.
 783 funcs=
 784 for func in $ac_func_list; do
 785   test $func = pthread_sigmask || AS_VAR_APPEND([funcs], [" $func"])
 786 done
 787 ac_func_list=$funcs
 788 # Use the system putenv even if it lacks GNU features, as we don't need them,
 789 # and the gnulib replacement runs afoul of a FreeBSD 10.1 bug; see Bug#19874.
 790 AC_CHECK_FUNCS_ONCE([putenv])
 791 AC_DEFUN([gl_FUNC_PUTENV],
 792   [test "$ac_cv_func_putenv" = yes || REPLACE_PUTENV=1])
 793
 794 # Initialize gnulib right after choosing the compiler.
 795 dnl Amongst other things, this sets AR and ARFLAGS.
 796 gl_EARLY
 797
 798 if test "$ac_test_CFLAGS" != set; then
 799   # It's helpful to have C macros available to GDB, so prefer -g3 to -g
 800   # if -g3 works and the user does not specify CFLAGS.
 801   # This test must follow gl_EARLY; otherwise AC_LINK_IFELSE complains.
 802   case $CFLAGS in
 803     '-g')
 804       emacs_g3_CFLAGS='-g3';;
 805     '-g -O2')
 806       emacs_g3_CFLAGS='-g3 -O2';;
 807     *)
 808       emacs_g3_CFLAGS='';;
 809   esac
 810   if test -n "$emacs_g3_CFLAGS"; then
 811     emacs_save_CFLAGS=$CFLAGS
 812     CFLAGS=$emacs_g3_CFLAGS
 813     AC_CACHE_CHECK([whether $CC accepts $emacs_g3_CFLAGS],
 814       [emacs_cv_prog_cc_g3],
 815       [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 816          [emacs_cv_prog_cc_g3=yes],
 817          [emacs_cv_prog_cc_g3=no])])
 818     if test $emacs_cv_prog_cc_g3 != yes; then
 819       CFLAGS=$emacs_save_CFLAGS
 820     fi
 821     if test $opsys = mingw32; then
 822       CFLAGS="$CFLAGS -gdwarf-2"
 823     fi
 824   fi
 825
 826   case $CFLAGS in
 827     *-O*) ;;
 828     *)
 829       # No optimization flag was inferred for this non-GCC compiler.
 830       # Try -O.  This is needed for xlc on AIX; see Bug#14258.
 831       emacs_save_CFLAGS=$CFLAGS
 832       test -z "$CFLAGS" || CFLAGS="$CFLAGS "
 833       CFLAGS=${CFLAGS}-O
 834       AC_CACHE_CHECK([whether $CC accepts -O],
 835         [emacs_cv_prog_cc_o],
 836         [AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 837            [emacs_cv_prog_cc_o=yes],
 838            [emacs_cv_prog_cc_o=no])])
 839       if test $emacs_cv_prog_cc_o != yes; then
 840         CFLAGS=$emacs_save_CFLAGS
 841       fi ;;
 842   esac
 843 fi
 844
 845 AC_ARG_ENABLE([gcc-warnings],
 846   [AS_HELP_STRING([--enable-gcc-warnings],
 847                   [turn on lots of GCC warnings/errors. This is intended for
 848                    developers, and may generate false alarms when used
 849                    with older or non-GNU development tools.])],
 850   [case $enableval in
 851      yes|no) ;;
 852      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 853    esac
 854    gl_gcc_warnings=$enableval],
 855   [gl_gcc_warnings=no]
 856 )
 857
 858 # clang is unduly picky about some things.
 859 AC_CACHE_CHECK([whether the compiler is clang], [emacs_cv_clang],
 860   [AC_COMPILE_IFELSE(
 861      [AC_LANG_PROGRAM([[
 862           #ifndef __clang__
 863             error "not clang";
 864           #endif
 865         ]])],
 866      [emacs_cv_clang=yes],
 867      [emacs_cv_clang=no])])
 868
 869 # When compiling with GCC, prefer -isystem to -I when including system
 870 # include files, to avoid generating useless diagnostics for the files.
 871 if test "$gl_gcc_warnings" != yes; then
 872   isystem='-I'
 873   if test "$emacs_cv_clang" = yes
 874   then
 875      # Turn off some warnings if supported.
 876      gl_WARN_ADD([-Wno-switch])
 877      gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 878      gl_WARN_ADD([-Wno-pointer-sign])
 879      gl_WARN_ADD([-Wno-string-plus-int])
 880      gl_WARN_ADD([-Wno-unknown-attributes])
 881   fi
 882 else
 883   isystem='-isystem '
 884
 885   # This, $nw, is the list of warnings we disable.
 886   nw=
 887
 888   case $with_x_toolkit in
 889     lucid | athena | motif)
 890        # Old toolkits mishandle 'const'.
 891        nw="$nw -Wwrite-strings"
 892        ;;
 893     *)
 894        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 895        ;;
 896   esac
 897   AC_SUBST([WERROR_CFLAGS])
 898
 899   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 900   nw="$nw -Woverlength-strings"     # Not a problem these days
 901   nw="$nw -Wformat-nonliteral"      # we do this a lot
 902   nw="$nw -Wvla"                    # Emacs uses <vla.h>.
 903   nw="$nw -Wswitch-default"         # Too many warnings for now
 904   nw="$nw -Winline"                 # OK to ignore 'inline'
 905   nw="$nw -Wstrict-overflow"        # OK to optimize assuming that
 906                                     # signed overflow has undefined behavior
 907   nw="$nw -Wsync-nand"              # irrelevant here, and provokes ObjC warning
 908   nw="$nw -Wunsafe-loop-optimizations" # OK to suppress unsafe optimizations
 909   nw="$nw -Wbad-function-cast"      # These casts are no worse than others.
 910
 911   # Emacs doesn't care about shadowing; see
 912   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 913   nw="$nw -Wshadow"
 914
 915   # Emacs's use of alloca inhibits protecting the stack.
 916   nw="$nw -Wstack-protector"
 917
 918   # Emacs's use of partly-const functions such as Fgnutls_available_p
 919   # make this option problematic.
 920   nw="$nw -Wsuggest-attribute=const"
 921
 922   # Emacs's use of partly-pure functions such as CHECK_TYPE make this
 923   # option problematic.
 924   nw="$nw -Wsuggest-attribute=pure"
 925
 926   # This part is merely for shortening the command line,
 927   # since -Wall implies -Wswitch.
 928   nw="$nw -Wswitch"
 929
 930   # This part is merely for shortening the command line,
 931   # since -Wno-FOO needs to be added below regardless.
 932   nw="$nw -Wmissing-field-initializers"
 933   nw="$nw -Wtype-limits"
 934   nw="$nw -Wunused-parameter"
 935
 936   if test $emacs_cv_clang = yes; then
 937     nw="$nw -Wcast-align"
 938   fi
 939
 940   gl_MANYWARN_ALL_GCC([ws])
 941   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 942   for w in $ws; do
 943     gl_WARN_ADD([$w])
 944   done
 945   gl_WARN_ADD([-Wredundant-decls])     # Prefer this, as we don't use Bison.
 946   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 947   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 948   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 949   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 950   gl_WARN_ADD([-Wno-format-nonliteral])
 951
 952   # More things that clang is unduly picky about.
 953   if test $emacs_cv_clang = yes; then
 954     gl_WARN_ADD([-Wno-format-extra-args])
 955     gl_WARN_ADD([-Wno-tautological-constant-out-of-range-compare])
 956     gl_WARN_ADD([-Wno-unused-command-line-argument])
 957     gl_WARN_ADD([-Wno-unused-value])
 958   fi
 959
 960   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 961   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 962   AH_VERBATIM([GNULIB_PORTCHECK_FORTIFY_SOURCE],
 963   [/* Enable compile-time and run-time bounds-checking, and some warnings,
 964       without upsetting glibc 2.15+. */
 965    #if (defined GNULIB_PORTCHECK && !defined _FORTIFY_SOURCE \
 966         && defined __OPTIMIZE__ && __OPTIMIZE__)
 967    # define _FORTIFY_SOURCE 2
 968    #endif
 969   ])
 970
 971   # We use a slightly smaller set of warning options for lib/.
 972   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 973   nw=
 974   nw="$nw -Wunused-macros"
 975
 976   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 977   AC_SUBST([GNULIB_WARN_CFLAGS])
 978 fi
 979
 980 edit_cflags="
 981   s,///*,/,g
 982   s/^/ /
 983   s/ -I/ $isystem/g
 984   s/^ //
 985 "
 986
 987 AC_ARG_ENABLE(link-time-optimization,
 988 [AS_HELP_STRING([--enable-link-time-optimization],
 989                 [build emacs with link-time optimization.
 990                  This requires GCC 4.5.0 or later, or clang.
 991                  (Note that clang support is experimental - see INSTALL.)
 992                  It also makes Emacs harder to debug, and when we tried it
 993                  with GCC 4.9.0 x86-64 it made Emacs slower, so it's not
 994                  recommended for typical use.])],
 995 if test "${enableval}" != "no"; then
 996    ac_lto_supported=no
 997    if test $emacs_cv_clang = yes; then
 998       AC_MSG_CHECKING([whether link-time optimization is supported by clang])
 999       GOLD_PLUGIN=`$CC -print-file-name=LLVMgold.so 2>/dev/null`
1000       if test -x "$GOLD_PLUGIN"; then
1001          LTO="-flto"
1002       fi
1003    elif test x$GCC = xyes; then
1004       AC_MSG_CHECKING([whether link-time optimization is supported by gcc])
1005       CPUS=`getconf _NPROCESSORS_ONLN 2>/dev/null`
1006       if test x$CPUS != x; then
1007          LTO="-flto=$CPUS"
1008       else
1009          LTO="-flto"
1010       fi
1011    else
1012       AC_MSG_ERROR([Link-time optimization is not supported with your compiler.])
1013    fi
1014    if test -z "$LTO"; then
1015       ac_lto_supported=no
1016    else
1017       old_CFLAGS=$CFLAGS
1018       CFLAGS="$CFLAGS $LTO"
1019       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])],
1020          [ac_lto_supported=yes], [ac_lto_supported=no])
1021          CFLAGS="$old_CFLAGS"
1022    fi
1023    AC_MSG_RESULT([$ac_lto_supported])
1024    if test "$ac_lto_supported" = "yes"; then
1025       CFLAGS="$CFLAGS $LTO"
1026       if test x$emacs_cv_clang = xyes; then
1027          AC_MSG_WARN([Please read INSTALL before using link-time optimization with clang])
1028          # WARNING: 'ar --plugin ...' doesn't work without
1029          # command, so plugin name is appended to ARFLAGS.
1030          ARFLAGS="cru --plugin $GOLD_PLUGIN"
1031          RANLIB="$RANLIB --plugin $GOLD_PLUGIN"
1032       else
1033         dnl The following is needed for GCC 4.9.0.  The GCC 4.9.0 release notes
1034         dnl suggest that instead of -ffat-lto-objects we should use gcc-ar and
1035         dnl gcc-ranlib in place of ar and ranlib, but gcc-ar makes /usr/bin/ar
1036         dnl dump core on Fedora 20, so play it safe for now.
1037         gl_COMPILER_OPTION_IF([-ffat-lto-objects],
1038           [CFLAGS="$CFLAGS -ffat-lto-objects"])
1039       fi
1040    fi
1041 fi)
1042
1043 dnl Prefer silent make output.  For verbose output, use
1044 dnl 'configure --disable-silent-rules' or 'make V=1' .
1045 AM_SILENT_RULES([yes])
1046 dnl Port to Automake 1.11.
1047 dnl This section can be removed once we assume Automake 1.14 or later.
1048 : ${AM_V=$AM_DEFAULT_VERBOSITY}
1049 : ${AM_DEFAULT_V=$AM_DEFAULT_VERBOSITY}
1050 AC_SUBST([AM_V])
1051 AM_SUBST_NOTMAKE([AM_V])
1052 AC_SUBST([AM_DEFAULT_V])
1053 AM_SUBST_NOTMAKE([AM_DEFAULT_V])
1054 AC_SUBST([AM_DEFAULT_VERBOSITY])
1055
1056 dnl Some other nice autoconf tests.
1057 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
1058 dnl AC_PROG_INSTALL
1059 dnl AC_PROG_MKDIR_P
1060 dnl if test "x$RANLIB" = x; then
1061 dnl   AC_PROG_RANLIB
1062 dnl fi
1063
1064
1065 dnl Sadly, AC_PROG_LN_S is too restrictive.  It also tests whether links
1066 dnl can be made to directories.  This is not relevant for our usage, and
1067 dnl excludes some cases that work fine for us.  Eg MS Windows or files
1068 dnl hosted on AFS, both examples where simple links work, but links to
1069 dnl directories fail.  We use a cut-down version instead.
1070 dnl AC_PROG_LN_S
1071
1072 AC_MSG_CHECKING([whether ln -s works for files in the same directory])
1073 rm -f conf$$ conf$$.file
1074
1075 LN_S_FILEONLY='cp -p'
1076
1077 dnl On MinGW, ensure we will call the MSYS /bin/ln.exe, not some
1078 dnl random program in the current directory.
1079 if (echo >conf$$.file) 2>/dev/null; then
1080   if ln -s conf$$.file conf$$ 2>/dev/null; then
1081     if test "$opsys" = "mingw32"; then
1082       LN_S_FILEONLY='/bin/ln -s'
1083     else
1084       LN_S_FILEONLY='ln -s'
1085     fi
1086   elif ln conf$$.file conf$$ 2>/dev/null; then
1087     if test "$opsys" = "mingw32"; then
1088       LN_S_FILEONLY=/bin/ln
1089     else
1090       LN_S_FILEONLY=ln
1091     fi
1092   fi
1093 fi
1094
1095 rm -f conf$$ conf$$.file
1096
1097 if test "$LN_S_FILEONLY" = "ln -s"; then
1098    AC_MSG_RESULT([yes])
1099 else
1100    AC_MSG_RESULT([no, using $LN_S_FILEONLY])
1101 fi
1102
1103 AC_SUBST(LN_S_FILEONLY)
1104
1105
1106 dnl AC_PROG_LN_S sets LN_S to 'cp -pR' for MinGW, on the premise that 'ln'
1107 dnl doesn't support links to directories, as in "ln file dir".  But that
1108 dnl use is non-portable, and OTOH MinGW wants to use hard links for Emacs
1109 dnl executables at "make install" time.
1110 dnl See http://lists.gnu.org/archive/html/emacs-devel/2013-04/msg00475.html
1111 dnl for more details.
1112 if test "$opsys" = "mingw32"; then
1113   LN_S="/bin/ln"
1114 fi
1115
1116 dnl On some Debian versions, "install-info" prints irritating messages
1117 dnl "This is not dpkg install-info anymore, but GNU install-info"
1118 dnl if called via an absolute file name.
1119 dnl Use the entirely-identical-but-quieter ginstall-info instead if present.
1120 dnl Sadly some people may have an old ginstall-info installed on
1121 dnl non-Debian systems, so we can't use this.
1122 dnl AC_PATH_PROGS(INSTALL_INFO, [ginstall-info install-info], :,
1123 dnl   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1124
1125 AC_PATH_PROG(INSTALL_INFO, install-info, :,
1126   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
1127 dnl Don't use GZIP, which is used by gzip for additional parameters.
1128 AC_PATH_PROG(GZIP_PROG, gzip)
1129
1130 test $with_compress_install != yes && test -n "$GZIP_PROG" && \
1131    GZIP_PROG=" # $GZIP_PROG # (disabled by configure --without-compress-install)"
1132
1133 if test $opsys = gnu-linux; then
1134   AC_PATH_PROG(PAXCTL, paxctl,,
1135     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
1136   if test "X$PAXCTL" != X; then
1137     AC_MSG_CHECKING([whether binaries have a PT_PAX_FLAGS header])
1138     AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1139       [if $PAXCTL -v conftest$EXEEXT >/dev/null 2>&1; then AC_MSG_RESULT(yes)
1140       else AC_MSG_RESULT(no); PAXCTL=""; fi])
1141   fi
1142
1143   if test "${SETFATTR+set}" != set; then
1144     AC_CACHE_CHECK([for setfattr],
1145       [emacs_cv_prog_setfattr],
1146       [touch conftest.tmp
1147        if (setfattr -n user.pax.flags conftest.tmp) >/dev/null 2>&1; then
1148          emacs_cv_prog_setfattr=yes
1149        else
1150          emacs_cv_prog_setfattr=no
1151        fi])
1152     if test "$emacs_cv_prog_setfattr" = yes; then
1153       SETFATTR=setfattr
1154     else
1155       SETFATTR=
1156     fi
1157     rm -f conftest.tmp
1158     AC_SUBST([SETFATTR])
1159   fi
1160 fi
1161
1162 ## Need makeinfo >= 4.7 (?) to build the manuals.
1163 if test "$MAKEINFO" != "no"; then
1164   if test "$MAKEINFO" = "${am_missing_run}makeinfo"; then
1165     MAKEINFO=makeinfo
1166   fi
1167   case `($MAKEINFO --version) 2>/dev/null` in
1168     *' (GNU texinfo) '4.[[7-9]]* | \
1169     *' (GNU texinfo) '4.[[1-9][0-9]]* | \
1170     *' (GNU texinfo) '[[5-9]]* | \
1171     *' (GNU texinfo) '[[1-9][0-9]]* ) ;;
1172     *) MAKEINFO=no;;
1173   esac
1174 fi
1175
1176 ## Makeinfo is unusual.  For a released Emacs, the manuals are
1177 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
1178 ## therefore in the category of "special tools" not normally required, which
1179 ## configure does not have to check for (eg autoconf itself).
1180 ## In a repository checkout on the other hand, the manuals are not included.
1181 ## So makeinfo is a requirement to build from the repository, and configure
1182 ## should test for it as it does for any other build requirement.
1183 ## We use the presence of $srcdir/info/emacs to distinguish a release,
1184 ## with pre-built manuals, from a repository checkout.
1185 HAVE_MAKEINFO=yes
1186
1187 if test "$MAKEINFO" = "no"; then
1188   MAKEINFO=makeinfo
1189   if test "x${with_makeinfo}" = "xno"; then
1190     HAVE_MAKEINFO=no
1191   elif test ! -e "$srcdir/info/emacs" && test ! -e "$srcdir/info/emacs.info"; then
1192     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
1193 source tree does not seem to have pre-built manuals in the 'info' directory.
1194 Either install a suitable version of makeinfo, or re-run configure
1195 with the '--without-makeinfo' option to build without the manuals.] )
1196   fi
1197 fi
1198 AC_SUBST(HAVE_MAKEINFO)
1199
1200 if test $opsys = mingw32; then
1201    DOCMISC_W32=efaq-w32
1202 else
1203    DOCMISC_W32=
1204 fi
1205 AC_SUBST(DOCMISC_W32)
1206
1207 dnl Add our options to ac_link now, after it is set up.
1208
1209 if test x$GCC = xyes; then
1210   test "x$GCC_LINK_TEST_OPTIONS" != x && \
1211     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1212 else
1213   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
1214     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1215 fi
1216
1217 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1218 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1219 dnl Treat GCC specially since it just gives a non-fatal 'unrecognized option'
1220 dnl if not built to support GNU ld.
1221
1222 dnl For a long time, -znocombreloc was added to LDFLAGS rather than
1223 dnl LD_SWITCH_SYSTEM_TEMACS.  That is:
1224 dnl * inappropriate, as LDFLAGS is a user option but this is essential.
1225 dnl   Eg "make LDFLAGS=... all" could run into problems,
1226 dnl   http://bugs.debian.org/684788
1227 dnl * unnecessary, since temacs is the only thing that actually needs it.
1228 dnl   Indeed this is where it was originally, prior to:
1229 dnl   http://lists.gnu.org/archive/html/emacs-pretest-bug/2004-03/msg00170.html
1230 late_LDFLAGS="$LDFLAGS"
1231 if test x$GCC = xyes; then
1232   LDFLAGS_NOCOMBRELOC="-Wl,-znocombreloc"
1233 else
1234   LDFLAGS_NOCOMBRELOC="-znocombreloc"
1235 fi
1236
1237 LDFLAGS="$LDFLAGS $LDFLAGS_NOCOMBRELOC"
1238
1239 AC_MSG_CHECKING([for -znocombreloc])
1240 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
1241   [AC_MSG_RESULT(yes)],
1242   LDFLAGS_NOCOMBRELOC=
1243   [AC_MSG_RESULT(no)])
1244
1245 LDFLAGS="$late_LDFLAGS"
1246
1247 AC_CACHE_CHECK([whether addresses are sanitized],
1248   [emacs_cv_sanitize_address],
1249   [AC_COMPILE_IFELSE(
1250      [AC_LANG_PROGRAM(
1251         [[#ifndef __has_feature
1252           #define __has_feature(f) 0
1253           #endif
1254           #if defined __SANITIZE_ADDRESS__ || __has_feature (address_sanitizer)
1255           #else
1256            error "Addresses are not sanitized.";
1257           #endif
1258         ]])],
1259      [emacs_cv_sanitize_address=yes],
1260      [emacs_cv_sanitize_address=no])])
1261
1262 dnl The function dump-emacs will not be defined and temacs will do
1263 dnl (load "loadup") automatically unless told otherwise.
1264 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
1265 case "$opsys" in
1266   nacl) CANNOT_DUMP=yes ;;
1267 esac
1268
1269 if test "$CANNOT_DUMP" = "yes"; then
1270   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
1271 elif test "$emacs_cv_sanitize_address" = yes; then
1272   AC_MSG_WARN([[Addresses are sanitized; suggest CANNOT_DUMP=yes]])
1273 fi
1274
1275 AC_SUBST(CANNOT_DUMP)
1276
1277
1278 UNEXEC_OBJ=unexelf.o
1279 case "$opsys" in
1280   # MSDOS uses unexcoff.o
1281   aix4-2)
1282    UNEXEC_OBJ=unexaix.o
1283    ;;
1284   cygwin)
1285    UNEXEC_OBJ=unexcw.o
1286    ;;
1287   darwin)
1288    UNEXEC_OBJ=unexmacosx.o
1289    ;;
1290   hpux10-20 | hpux11)
1291    UNEXEC_OBJ=unexhp9k800.o
1292    ;;
1293   mingw32)
1294    UNEXEC_OBJ=unexw32.o
1295    ;;
1296   sol2-10)
1297    # Use the Solaris dldump() function, called from unexsol.c, to dump
1298    # emacs, instead of the generic ELF dump code found in unexelf.c.
1299    # The resulting binary has a complete symbol table, and is better
1300    # for debugging and other observability tools (debuggers, pstack, etc).
1301    #
1302    # If you encounter a problem using dldump(), please consider sending
1303    # a message to the OpenSolaris tools-linking mailing list:
1304    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
1305    #
1306    # It is likely that dldump() works with older Solaris too, but this has
1307    # not been tested, so for now this change is for Solaris 10 or newer.
1308    UNEXEC_OBJ=unexsol.o
1309    ;;
1310 esac
1311
1312 LD_SWITCH_SYSTEM=
1313 case "$opsys" in
1314   freebsd|dragonfly)
1315    ## Let 'ld' find image libs and similar things in /usr/local/lib.
1316    ## The system compiler, GCC, has apparently been modified to not
1317    ## look there, contrary to what a stock GCC would do.
1318 ### It's not our place to do this.  See bug#10313#17.
1319 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
1320       :
1321    ;;
1322
1323   gnu-linux)
1324    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
1325    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
1326    ;;
1327
1328   netbsd)
1329 ### It's not our place to do this.  See bug#10313#17.
1330 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
1331       :
1332    ;;
1333
1334   openbsd)
1335    ## Han Boetes <han@boetes.org> says this is necessary,
1336    ## otherwise Emacs dumps core on elf systems.
1337    LD_SWITCH_SYSTEM="-Z"
1338    ;;
1339 esac
1340 AC_SUBST(LD_SWITCH_SYSTEM)
1341
1342 ac_link="$ac_link $LD_SWITCH_SYSTEM"
1343
1344 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
1345 ## which has not been defined yet.  When this was handled with cpp,
1346 ## it was expanded to null when configure sourced the s/*.h file.
1347 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
1348 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
1349 ## (or somesuch), but because it is supposed to go at the _front_
1350 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
1351 ## Compare with the gnu-linux case below, which added to the end
1352 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
1353 ## LD_SWITCH_SYSTEM_TEMACS.
1354 case "$opsys" in
1355   netbsd|openbsd)
1356    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
1357 esac
1358
1359
1360 C_SWITCH_MACHINE=
1361 case $canonical in
1362  alpha*)
1363   AC_CHECK_DECL([__ELF__])
1364   if test "$ac_cv_have_decl___ELF__" = "yes"; then
1365     ## With ELF, make sure that all common symbols get allocated to in the
1366     ## data section.  Otherwise, the dump of temacs may miss variables in
1367     ## the shared library that have been initialized.  For example, with
1368     ## GNU libc, __malloc_initialized would normally be resolved to the
1369     ## shared library's .bss section, which is fatal.
1370     if test "x$GCC" = "xyes"; then
1371       C_SWITCH_MACHINE="-fno-common"
1372     else
1373       AC_MSG_ERROR([Non-GCC compilers are not supported.])
1374     fi
1375   else
1376       dnl This was the unexalpha.c case.  Removed in 24.1, 2010-07-24,
1377       dnl albeit under the mistaken assumption that said file
1378       dnl was no longer used.
1379       AC_MSG_ERROR([Non-ELF systems are not supported since Emacs 24.1.])
1380   fi
1381   ;;
1382 esac
1383 AC_SUBST(C_SWITCH_MACHINE)
1384
1385 AC_SUBST(UNEXEC_OBJ)
1386
1387 C_SWITCH_SYSTEM=
1388 ## Some programs in src produce warnings saying certain subprograms
1389 ## are too complex and need a MAXMEM value greater than 2000 for
1390 ## additional optimization.  --nils@exp-math.uni-essen.de
1391 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
1392   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
1393 if test "$opsys" = "mingw32"; then
1394   case "$canonical" in
1395     x86_64-*-mingw*) C_SWITCH_SYSTEM="-mtune=generic" ;;
1396     *) C_SWITCH_SYSTEM="-mtune=pentium4" ;;
1397   esac
1398 fi
1399 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
1400 ## It is redundant in glibc2, since we define _GNU_SOURCE.
1401 AC_SUBST(C_SWITCH_SYSTEM)
1402
1403
1404 LIBS_SYSTEM=
1405 case "$opsys" in
1406   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
1407   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
1408
1409   freebsd|dragonfly) LIBS_SYSTEM="-lutil" ;;
1410
1411   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
1412
1413   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
1414
1415   ## Motif needs -lgen.
1416   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
1417 esac
1418
1419 AC_SUBST(LIBS_SYSTEM)
1420
1421 ### Make sure subsequent tests use flags consistent with the build flags.
1422
1423 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1424   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1425 else
1426   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
1427 fi
1428
1429 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C99 or better.
1430 AC_DEFUN([AC_TYPE_SIZE_T])
1431 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
1432 AC_DEFUN([AC_TYPE_UID_T])
1433
1434 # sqrt and other floating-point functions such as fmod and frexp
1435 # are found in -lm on many systems.
1436 OLD_LIBS=$LIBS
1437 AC_SEARCH_LIBS([sqrt], [m])
1438 if test "X$LIBS" = "X$OLD_LIBS"; then
1439   LIB_MATH=
1440 else
1441   LIB_MATH=$ac_cv_search_sqrt
1442 fi
1443 LIBS=$OLD_LIBS
1444
1445 dnl Current possibilities handled by sed (aix4-2 -> aix,
1446 dnl gnu-linux -> gnu/linux, etc.):
1447 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux.
1448 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
1449 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
1450
1451 case $opsys in
1452   cygwin )
1453     LIB_MATH=
1454     ;;
1455   darwin )
1456     ## Adding -lm confuses the dynamic linker, so omit it.
1457     LIB_MATH=
1458     ;;
1459   freebsd | dragonfly )
1460     SYSTEM_TYPE=berkeley-unix
1461     ;;
1462   gnu-linux | gnu-kfreebsd )
1463     ;;
1464   hpux10-20 | hpux11 )
1465     ;;
1466   mingw32 )
1467     LIB_MATH=
1468     SYSTEM_TYPE=windows-nt
1469     ;;
1470   dnl NB this may be adjusted below.
1471   netbsd | openbsd )
1472     SYSTEM_TYPE=berkeley-unix
1473     ;;
1474
1475   sol2* | unixware )
1476     SYSTEM_TYPE=usg-unix-v
1477     ;;
1478
1479 esac
1480
1481 AC_SUBST(LIB_MATH)
1482 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
1483   [The type of system you are compiling for; sets 'system-type'.])
1484
1485
1486 pre_PKG_CONFIG_CFLAGS=$CFLAGS
1487 pre_PKG_CONFIG_LIBS=$LIBS
1488
1489 PKG_PROG_PKG_CONFIG(0.9.0)
1490
1491 dnl EMACS_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4)
1492 dnl acts like PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4,
1493 dnl HAVE_GSTUFF=yes, HAVE_GSTUFF=no) -- see pkg-config man page --
1494 dnl except that it postprocesses CFLAGS as needed for --enable-gcc-warnings.
1495 dnl EMACS_CHECK_MODULES accepts optional 3rd and 4th arguments that
1496 dnl can take the place of the default HAVE_GSTUFF=yes and HAVE_GSTUFF=no
1497 dnl actions.
1498 AC_DEFUN([EMACS_CHECK_MODULES],
1499   [PKG_CHECK_MODULES([$1], [$2],
1500      [$1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1501       m4_default([$3], [HAVE_$1=yes])],
1502      [m4_default([$4], [HAVE_$1=no])])])
1503
1504 HAVE_SOUND=no
1505 if test "${with_sound}" != "no"; then
1506   # Sound support for GNU/Linux, the free BSDs, MinGW, and Cygwin.
1507   AC_CHECK_HEADERS([machine/soundcard.h sys/soundcard.h soundcard.h mmsystem.h],
1508     have_sound_header=yes, [], [
1509     #ifdef __MINGW32__
1510     #define WIN32_LEAN_AND_MEAN
1511     #include <windows.h>
1512     #endif
1513     ])
1514   test "${with_sound}" = "oss" && test "${have_sound_header}" != "yes" && \
1515     AC_MSG_ERROR([OSS sound support requested but not found.])
1516
1517   if test "${with_sound}" = "bsd-ossaudio" || test "${with_sound}" = "yes"; then
1518     # Emulation library used on NetBSD.
1519     AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1520     test "${with_sound}" = "bsd-ossaudio" && test -z "$LIBSOUND" && \
1521       AC_MSG_ERROR([bsd-ossaudio sound support requested but not found.])
1522     dnl FIXME?  If we did find ossaudio, should we set with_sound=bsd-ossaudio?
1523     dnl Traditionally, we go on to check for alsa too.  Does that make sense?
1524   fi
1525   AC_SUBST(LIBSOUND)
1526
1527   if test "${with_sound}" = "alsa" || test "${with_sound}" = "yes"; then
1528     ALSA_REQUIRED=1.0.0
1529     ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1530     EMACS_CHECK_MODULES([ALSA], [$ALSA_MODULES])
1531     if test $HAVE_ALSA = yes; then
1532       SAVE_CFLAGS="$CFLAGS"
1533       SAVE_LIBS="$LIBS"
1534       CFLAGS="$ALSA_CFLAGS $CFLAGS"
1535       LIBS="$ALSA_LIBS $LIBS"
1536       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1537                       emacs_alsa_normal=yes,
1538                     emacs_alsa_normal=no)
1539       if test "$emacs_alsa_normal" != yes; then
1540         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1541                        [[snd_lib_error_set_handler (0);]])],
1542                        emacs_alsa_subdir=yes,
1543                      emacs_alsa_subdir=no)
1544         if test "$emacs_alsa_subdir" != yes; then
1545           AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1546         fi
1547         ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1548       fi
1549
1550       CFLAGS="$SAVE_CFLAGS"
1551       LIBS="$SAVE_LIBS"
1552       LIBSOUND="$LIBSOUND $ALSA_LIBS"
1553       CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1554       AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1555     elif test "${with_sound}" = "alsa"; then
1556       AC_MSG_ERROR([ALSA sound support requested but not found.])
1557     fi
1558   fi                            dnl with_sound = alsa|yes
1559
1560   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1561   dnl compiles only on the specified platforms.  For others, it
1562   dnl probably doesn't make sense to try.
1563   dnl FIXME So surely we should bypass this whole section if not using
1564   dnl one of these platforms?
1565   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1566      case "$opsys" in
1567        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1568        dnl Adjust the --with-sound help text if you change this.
1569        gnu-linux|freebsd|netbsd|mingw32|cygwin)
1570          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1571          HAVE_SOUND=yes
1572          ;;
1573      esac
1574   fi
1575
1576   AC_SUBST(CFLAGS_SOUND)
1577 fi
1578
1579 dnl checks for header files
1580 AC_CHECK_HEADERS_ONCE(
1581   malloc.h
1582   sys/systeminfo.h
1583   sys/sysinfo.h
1584   coff.h pty.h
1585   sys/resource.h
1586   sys/utsname.h pwd.h utmp.h util.h)
1587
1588 AC_MSG_CHECKING(if personality LINUX32 can be set)
1589 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1590                emacs_cv_personality_linux32=yes,
1591                emacs_cv_personality_linux32=no)
1592 AC_MSG_RESULT($emacs_cv_personality_linux32)
1593
1594 if test $emacs_cv_personality_linux32 = yes; then
1595   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1596             [Define to 1 if personality LINUX32 can be set.])
1597 fi
1598
1599 # Note that Solaris has sys/sysinfo.h which defines struct
1600 # sysinfo as well.  To make sure that we're using GNU/Linux
1601 # sysinfo, we explicitly set one of its fields.
1602 if test "$ac_cv_header_sys_sysinfo_h" = yes; then
1603   AC_MSG_CHECKING([if Linux sysinfo may be used])
1604   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1605                                      [[struct sysinfo si;
1606                                        si.totalram = 0;
1607                                        sysinfo (&si)]])],
1608     emacs_cv_linux_sysinfo=yes, emacs_cv_linux_sysinfo=no)
1609   AC_MSG_RESULT($emacs_cv_linux_sysinfo)
1610   if test $emacs_cv_linux_sysinfo = yes; then
1611     AC_DEFINE([HAVE_LINUX_SYSINFO], 1, [Define to 1 if you have Linux sysinfo function.])
1612     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/sysinfo.h>]],
1613                                        [[struct sysinfo si; return si.mem_unit]])],
1614       AC_DEFINE(LINUX_SYSINFO_UNIT, 1,
1615                 [Define to 1 if Linux sysinfo sizes are in multiples of mem_unit bytes.]))
1616   fi
1617 fi
1618
1619 dnl On Solaris 8 there's a compilation warning for term.h because
1620 dnl it doesn't define 'bool'.
1621 AC_CHECK_HEADERS(term.h, , , -)
1622 AC_HEADER_TIME
1623 AC_CHECK_DECLS([sys_siglist], [], [], [[#include <signal.h>
1624                                       ]])
1625 if test $ac_cv_have_decl_sys_siglist != yes; then
1626   # For Tru64, at least:
1627   AC_CHECK_DECLS([__sys_siglist], [], [], [[#include <signal.h>
1628                                           ]])
1629 fi
1630 AC_HEADER_SYS_WAIT
1631
1632 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1633 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1634 #if HAVE_SYS_SOCKET_H
1635 #include <sys/socket.h>
1636 #endif])
1637 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1638 #if HAVE_SYS_SOCKET_H
1639 #include <sys/socket.h>
1640 #endif])
1641 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1642 #if HAVE_SYS_SOCKET_H
1643 #include <sys/socket.h>
1644 #endif])
1645
1646 dnl checks for structure members
1647 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1648                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1649                   struct ifreq.ifr_addr,
1650                   struct ifreq.ifr_addr.sa_len], , ,
1651                  [AC_INCLUDES_DEFAULT
1652 #if HAVE_SYS_SOCKET_H
1653 #include <sys/socket.h>
1654 #endif
1655 #if HAVE_NET_IF_H
1656 #include <net/if.h>
1657 #endif])
1658
1659 dnl Check for endianness.
1660 dnl AC_C_BIGENDIAN is done by gnulib.
1661
1662 dnl check for Make feature
1663
1664 AUTO_DEPEND=no
1665 dnl check if we have GCC and autodepend is on.
1666 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1667    AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1668    SAVE_CFLAGS="$CFLAGS"
1669    CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1670    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1671    CFLAGS="$SAVE_CFLAGS"
1672    test -f deps.d || ac_enable_autodepend=no
1673    rm -rf deps.d
1674    AC_MSG_RESULT([$ac_enable_autodepend])
1675    if test $ac_enable_autodepend = yes; then
1676       AUTO_DEPEND=yes
1677    fi
1678 fi
1679 AC_SUBST(AUTO_DEPEND)
1680
1681 dnl checks for operating system services
1682 AC_SYS_LONG_FILE_NAMES
1683
1684 #### Choose a window system.
1685
1686 ## We leave window_system equal to none if
1687 ## we end up building without one.  Any new window system should
1688 ## set window_system to an appropriate value and add objects to
1689 ## window-system-specific substs.
1690
1691 window_system=none
1692 AC_PATH_X
1693 if test "$no_x" != yes; then
1694   window_system=x11
1695 fi
1696
1697 LD_SWITCH_X_SITE_RPATH=
1698 if test "${x_libraries}" != NONE; then
1699   if test -n "${x_libraries}"; then
1700     LD_SWITCH_X_SITE=-L`AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -L/g'`
1701     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`
1702       AS_ECHO(["$x_libraries"]) | sed -e 's/:/ -Wl,-rpath,/g'
1703     `
1704   fi
1705   x_default_search_path=""
1706   x_search_path=${x_libraries}
1707   if test -z "${x_search_path}"; then
1708     x_search_path=/usr/lib
1709   fi
1710   for x_library in `AS_ECHO(["$x_search_path:"]) | \
1711                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1712     x_search_path="\
1713 ${x_library}/X11/%L/%T/%N%C%S:\
1714 ${x_library}/X11/%l/%T/%N%C%S:\
1715 ${x_library}/X11/%T/%N%C%S:\
1716 ${x_library}/X11/%L/%T/%N%S:\
1717 ${x_library}/X11/%l/%T/%N%S:\
1718 ${x_library}/X11/%T/%N%S"
1719     if test x"${x_default_search_path}" = x; then
1720       x_default_search_path=${x_search_path}
1721     else
1722       x_default_search_path="${x_search_path}:${x_default_search_path}"
1723     fi
1724   done
1725 fi
1726 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1727
1728 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1729   C_SWITCH_X_SITE=$isystem`AS_ECHO(["$x_includes"]) | sed -e "s/:/ $isystem/g"`
1730 fi
1731
1732 if test x"${x_includes}" = x; then
1733   bitmapdir=/usr/include/X11/bitmaps
1734 else
1735   # accumulate include directories that have X11 bitmap subdirectories
1736   bmd_acc=
1737   for bmd in `AS_ECHO(["$x_includes"]) | sed -e 's/:/ /g'`; do
1738     if test -d "${bmd}/X11/bitmaps"; then
1739       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1740     fi
1741     if test -d "${bmd}/bitmaps"; then
1742       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1743     fi
1744   done
1745   bitmapdir=${bmd_acc#:}
1746 fi
1747
1748 test "${with_ns}" = maybe && test "${opsys}" != darwin && with_ns=no
1749 HAVE_NS=no
1750 NS_GNUSTEP_CONFIG=no
1751 NS_IMPL_COCOA=no
1752 NS_IMPL_GNUSTEP=no
1753 tmp_CPPFLAGS="$CPPFLAGS"
1754 tmp_CFLAGS="$CFLAGS"
1755 CPPFLAGS="$CPPFLAGS -x objective-c"
1756 CFLAGS="$CFLAGS -x objective-c"
1757 GNU_OBJC_CFLAGS=
1758 LIBS_GNUSTEP=
1759 if test "${with_ns}" != no; then
1760   if test "${opsys}" = darwin; then
1761      NS_IMPL_COCOA=yes
1762      ns_appdir=`pwd`/nextstep/Emacs.app
1763      ns_appbindir=${ns_appdir}/Contents/MacOS
1764      ns_appresdir=${ns_appdir}/Contents/Resources
1765      ns_appsrc=Cocoa/Emacs.base
1766      ns_fontfile=macfont.o
1767   elif flags=$( (gnustep-config --objc-flags) 2>/dev/null); then
1768      NS_IMPL_GNUSTEP=yes
1769      NS_GNUSTEP_CONFIG=yes
1770      GNU_OBJC_CFLAGS=$flags
1771      LIBS_GNUSTEP=$(gnustep-config --gui-libs) || exit
1772   elif test -f $GNUSTEP_CONFIG_FILE; then
1773      NS_IMPL_GNUSTEP=yes
1774      dnl FIXME sourcing this several times in subshells seems inefficient.
1775      GNUSTEP_SYSTEM_HEADERS=$(
1776        . $GNUSTEP_CONFIG_FILE
1777        AS_ECHO(["$GNUSTEP_SYSTEM_HEADERS"])
1778      )
1779      GNUSTEP_SYSTEM_LIBRARIES=$(
1780        . $GNUSTEP_CONFIG_FILE
1781        AS_ECHO(["$GNUSTEP_SYSTEM_LIBRARIES"])
1782      )
1783      dnl I seemed to need these as well with GNUstep-startup 0.25.
1784      GNUSTEP_LOCAL_HEADERS=$(
1785        . $GNUSTEP_CONFIG_FILE
1786        AS_ECHO(["$GNUSTEP_LOCAL_HEADERS"])
1787      )
1788      GNUSTEP_LOCAL_LIBRARIES=$(
1789        . $GNUSTEP_CONFIG_FILE
1790        AS_ECHO(["$GNUSTEP_LOCAL_LIBRARIES"])
1791      )
1792      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1793        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1794      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1795        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1796      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1797      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1798      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1799      LIBS_GNUSTEP="-lgnustep-gui -lgnustep-base -lobjc -lpthread"
1800      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1801      dnl If they had chosen to either define it or not, we could have
1802      dnl just used AC_CHECK_DECL here.
1803      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1804        emacs_cv_objc_exceptions,
1805 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1806 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1807 1;
1808 #else
1809 fail;
1810 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1811      if test $emacs_cv_objc_exceptions = yes; then
1812        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1813        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1814          [Define if GNUstep uses ObjC exceptions.])
1815        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1816      fi
1817   fi
1818   if test $NS_IMPL_GNUSTEP = yes; then
1819      ns_appdir=`pwd`/nextstep/Emacs.app
1820      ns_appbindir=${ns_appdir}
1821      ns_appresdir=${ns_appdir}/Resources
1822      ns_appsrc=GNUstep/Emacs.base
1823      ns_fontfile=nsfont.o
1824   fi
1825
1826   dnl This is only used while we test the NS headers, it gets reset below.
1827   CPPFLAGS="$CPPFLAGS $GNU_OBJC_CFLAGS"
1828   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1829
1830   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1831                   [AC_MSG_ERROR([The include files (AppKit/AppKit.h etc) that
1832 are required for a Nextstep build are missing or cannot be compiled.
1833 Either fix this, or re-configure with the option '--without-ns'.])])
1834
1835   macfont_file=""
1836   if test "${NS_IMPL_COCOA}" = "yes"; then
1837     AC_MSG_CHECKING([for OSX 10.6 or newer])
1838     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <AppKit/AppKit.h>],
1839                                      [
1840 #ifdef MAC_OS_X_VERSION_MAX_ALLOWED
1841 #if MAC_OS_X_VERSION_MAX_ALLOWED >= 1060
1842  ; /* OK */
1843 #else
1844  error "OSX 10.6 or newer required";
1845 #endif
1846 #endif
1847                     ])],
1848                     ns_osx_have_106=yes,
1849                     ns_osx_have_106=no)
1850     AC_MSG_RESULT([$ns_osx_have_106])
1851
1852     if test $ns_osx_have_106 = no; then
1853        AC_MSG_ERROR([OSX 10.6 or newer is required]);
1854     fi
1855   fi
1856 fi
1857
1858 AC_SUBST(LIBS_GNUSTEP)
1859
1860 INSTALL_ARCH_INDEP_EXTRA=install-etc
1861 ns_self_contained=no
1862 NS_OBJ=
1863 NS_OBJC_OBJ=
1864 if test "${HAVE_NS}" = yes; then
1865   if test "$with_toolkit_scroll_bars" = "no"; then
1866     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1867   fi
1868
1869   window_system=nextstep
1870   # set up packaging dirs
1871   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1872      ns_self_contained=yes
1873      prefix=${ns_appresdir}
1874      exec_prefix=${ns_appbindir}
1875      dnl This one isn't really used, only archlibdir is.
1876      libexecdir="\${ns_appbindir}/libexec"
1877      archlibdir="\${ns_appbindir}/libexec"
1878      etcdocdir="\${ns_appresdir}/etc"
1879      etcdir="\${ns_appresdir}/etc"
1880      dnl FIXME maybe set datarootdir instead.
1881      dnl That would also get applications, icons, man.
1882      infodir="\${ns_appresdir}/info"
1883      mandir="\${ns_appresdir}/man"
1884      lispdir="\${ns_appresdir}/lisp"
1885      test "$locallisppathset" = no && locallisppath=""
1886      INSTALL_ARCH_INDEP_EXTRA=
1887   fi
1888
1889   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o $ns_fontfile"
1890 fi
1891 CFLAGS="$tmp_CFLAGS"
1892 CPPFLAGS="$tmp_CPPFLAGS"
1893 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1894 AC_SUBST(ns_self_contained)
1895 AC_SUBST(NS_OBJ)
1896 AC_SUBST(NS_OBJC_OBJ)
1897
1898 HAVE_W32=no
1899 W32_OBJ=
1900 W32_LIBS=
1901 EMACSRES=
1902 CLIENTRES=
1903 CLIENTW=
1904 W32_RES_LINK=
1905 EMACS_MANIFEST=
1906 UPDATE_MANIFEST=
1907 if test "${with_w32}" != no; then
1908   case "${opsys}" in
1909     cygwin)
1910       AC_CHECK_HEADER([windows.h], [HAVE_W32=yes],
1911              [AC_MSG_ERROR(['--with-w32' was specified, but windows.h
1912                    cannot be found.])])
1913     ;;
1914     mingw32)
1915     ## Using --with-w32 with MinGW is a no-op, but we allow it.
1916     ;;
1917     *)
1918       AC_MSG_ERROR([Using w32 with an autotools build is only supported for Cygwin and MinGW32.])
1919     ;;
1920   esac
1921 fi
1922
1923 if test "${opsys}" = "mingw32"; then
1924   AC_MSG_CHECKING([whether Windows API headers are recent enough])
1925   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1926      #include <windows.h>
1927      #include <usp10.h>]],
1928    [[PIMAGE_NT_HEADERS pHeader;
1929      PIMAGE_SECTION_HEADER pSection = IMAGE_FIRST_SECTION(pHeader)]])],
1930    [emacs_cv_w32api=yes
1931     HAVE_W32=yes],
1932    emacs_cv_w32api=no)
1933   AC_MSG_RESULT($emacs_cv_w32api)
1934   if test "${emacs_cv_w32api}" = "no"; then
1935     AC_MSG_ERROR([the Windows API headers are too old to support this build.])
1936   fi
1937 fi
1938
1939 FIRSTFILE_OBJ=
1940 NTDIR=
1941 LIBS_ECLIENT=
1942 LIB_WSOCK32=
1943 NTLIB=
1944 CM_OBJ="cm.o"
1945 XARGS_LIMIT=
1946 if test "${HAVE_W32}" = "yes"; then
1947   AC_DEFINE(HAVE_NTGUI, 1, [Define to use native MS Windows GUI.])
1948   if test "$with_toolkit_scroll_bars" = "no"; then
1949     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for w32 build.])
1950   fi
1951   AC_CHECK_TOOL(WINDRES, [windres],
1952                 [AC_MSG_ERROR([No resource compiler found.])])
1953   W32_OBJ="w32fns.o w32menu.o w32reg.o w32font.o w32term.o"
1954   W32_OBJ="$W32_OBJ w32xfns.o w32select.o w32uniscribe.o"
1955   EMACSRES="emacs.res"
1956   case "$canonical" in
1957     x86_64-*-*) EMACS_MANIFEST="emacs-x64.manifest" ;;
1958     *) EMACS_MANIFEST="emacs-x86.manifest" ;;
1959   esac
1960   dnl Construct something of the form "24,4,0,0" with 4 components.
1961   comma_version=`echo "${PACKAGE_VERSION}.0.0" | sed -e 's/\./,/g' -e 's/^\([[^,]]*,[[^,]]*,[[^,]]*,[[^,]]*\).*/\1/'`
1962
1963   comma_space_version=`echo "$comma_version" | sed 's/,/, /g'`
1964   AC_SUBST(comma_version)
1965   AC_SUBST(comma_space_version)
1966   AC_CONFIG_FILES([nt/emacs.rc nt/emacsclient.rc])
1967   if test "${opsys}" = "cygwin"; then
1968     W32_LIBS="$W32_LIBS -lkernel32 -luser32 -lgdi32 -lole32 -lcomdlg32"
1969     W32_LIBS="$W32_LIBS -lusp10 -lcomctl32 -lwinspool"
1970     # Tell the linker that emacs.res is an object (which we compile from
1971     # the rc file), not a linker script.
1972     W32_RES_LINK="-Wl,emacs.res"
1973   else
1974     UPDATE_MANIFEST=update-game-score.exe.manifest
1975     W32_OBJ="$W32_OBJ w32.o w32console.o w32heap.o w32inevt.o w32proc.o"
1976     W32_LIBS="$W32_LIBS -lwinmm -lgdi32 -lcomdlg32"
1977     W32_LIBS="$W32_LIBS -lmpr -lwinspool -lole32 -lcomctl32 -lusp10"
1978     W32_RES_LINK="\$(EMACSRES)"
1979     CLIENTRES="emacsclient.res"
1980     CLIENTW="emacsclientw\$(EXEEXT)"
1981     FIRSTFILE_OBJ=firstfile.o
1982     NTDIR=nt
1983     CM_OBJ=
1984     LIBS_ECLIENT="-lcomctl32"
1985     LIB_WSOCK32="-lwsock32"
1986     NTLIB="ntlib.$ac_objext"
1987     XARGS_LIMIT="-s 10000"
1988   fi
1989 fi
1990 AC_SUBST(W32_OBJ)
1991 AC_SUBST(W32_LIBS)
1992 AC_SUBST(EMACSRES)
1993 AC_SUBST(EMACS_MANIFEST)
1994 AC_SUBST(UPDATE_MANIFEST)
1995 AC_SUBST(CLIENTRES)
1996 AC_SUBST(CLIENTW)
1997 AC_SUBST(W32_RES_LINK)
1998 AC_SUBST(FIRSTFILE_OBJ)
1999 AC_SUBST(NTDIR)
2000 AC_SUBST(CM_OBJ)
2001 AC_SUBST(LIBS_ECLIENT)
2002 AC_SUBST(LIB_WSOCK32)
2003 AC_SUBST(NTLIB)
2004 AC_SUBST(XARGS_LIMIT)
2005
2006 if test "${HAVE_W32}" = "yes"; then
2007   window_system=w32
2008   with_xft=no
2009 fi
2010
2011 ## $window_system is now set to the window system we will
2012 ## ultimately use.
2013
2014 if test "$window_system" = none && test "$gl_gcc_warnings" = yes; then
2015    # Too many warnings for now.
2016    nw=
2017    nw="$nw -Wsuggest-attribute=noreturn"
2018    gl_MANYWARN_COMPLEMENT([WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
2019
2020    gl_WARN_ADD([-Wno-unused-variable])
2021    gl_WARN_ADD([-Wno-unused-but-set-variable])
2022    gl_WARN_ADD([-Wno-unused-but-set-parameter])
2023 fi
2024
2025 term_header=
2026 HAVE_X_WINDOWS=no
2027 HAVE_X11=no
2028 USE_X_TOOLKIT=none
2029
2030 case "${window_system}" in
2031   x11 )
2032     HAVE_X_WINDOWS=yes
2033     HAVE_X11=yes
2034     term_header=xterm.h
2035     case "${with_x_toolkit}" in
2036       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
2037       motif ) USE_X_TOOLKIT=MOTIF ;;
2038       gtk ) with_gtk=yes
2039             term_header=gtkutil.h
2040 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
2041 dnl USE_X_TOOLKIT is set.
2042             USE_X_TOOLKIT=none ;;
2043       gtk2 ) with_gtk2=yes
2044              term_header=gtkutil.h
2045              USE_X_TOOLKIT=none ;;
2046       gtk3 ) with_gtk3=yes
2047              term_header=gtkutil.h
2048              USE_X_TOOLKIT=none ;;
2049       no ) USE_X_TOOLKIT=none ;;
2050 dnl If user did not say whether to use a toolkit, make this decision later:
2051 dnl use the toolkit if we have gtk, or X11R5 or newer.
2052       * ) USE_X_TOOLKIT=maybe ;;
2053     esac
2054   ;;
2055   nextstep )
2056     term_header=nsterm.h
2057   ;;
2058   w32 )
2059     term_header=w32term.h
2060   ;;
2061 esac
2062
2063 if test "$window_system" = none && test "X$with_x" != "Xno"; then
2064    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
2065    if test "$HAVE_XSERVER" = true ||
2066       test -n "$DISPLAY" ||
2067       {
2068         for emacs_libX11 in /usr/lib/libX11.*; do break; done
2069         test "$emacs_libX11" != '/usr/lib/libX11.*'
2070       }
2071    then
2072         AC_MSG_ERROR([You seem to be running X, but no X development libraries
2073 were found.  You should install the relevant development files for X
2074 and for the toolkit you want, such as Gtk+ or Motif.  Also make
2075 sure you have development files for image handling, i.e.
2076 tiff, gif, jpeg, png and xpm.
2077 If you are sure you want Emacs compiled without X window support, pass
2078   --without-x
2079 to configure.])
2080    fi
2081 fi
2082
2083 # Does the opsystem file prohibit the use of the GNU malloc?
2084 # Assume not, until told otherwise.
2085 GNU_MALLOC=yes
2086
2087 AC_CACHE_CHECK(
2088   [whether malloc is Doug Lea style],
2089   [emacs_cv_var_doug_lea_malloc],
2090   [emacs_cv_var_doug_lea_malloc=no
2091    dnl Hooks do not work with address sanitization.
2092    if test "$emacs_cv_sanitize_address" != yes; then
2093      AC_LINK_IFELSE(
2094        [AC_LANG_PROGRAM(
2095           [[#include <malloc.h>
2096             static void hook (void) {}]],
2097           [[malloc_set_state (malloc_get_state ());
2098             __after_morecore_hook = hook;
2099             __malloc_initialize_hook = hook;]])],
2100        [emacs_cv_var_doug_lea_malloc=yes])
2101    fi])
2102 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
2103
2104 system_malloc=$emacs_cv_sanitize_address
2105
2106 hybrid_malloc=
2107
2108 case "$opsys" in
2109   ## darwin ld insists on the use of malloc routines in the System framework.
2110   darwin | mingw32 | nacl | sol2-10) system_malloc=yes ;;
2111   cygwin) hybrid_malloc=yes;;
2112 esac
2113
2114 if test "${system_malloc}" != yes && test "${doug_lea_malloc}" != yes \
2115    && test "${UNEXEC_OBJ}" = unexelf.o; then
2116   hybrid_malloc=yes
2117 fi
2118
2119 GMALLOC_OBJ=
2120 HYBRID_MALLOC=
2121 if test "${system_malloc}" = "yes"; then
2122   AC_DEFINE([SYSTEM_MALLOC], 1,
2123     [Define to 1 to use the system memory allocator, even if it is not
2124      Doug Lea style.])
2125   GNU_MALLOC=no
2126   GNU_MALLOC_reason="
2127     (The GNU allocators don't work with this system configuration.)"
2128   VMLIMIT_OBJ=
2129 elif test "$hybrid_malloc" = yes; then
2130   AC_DEFINE(HYBRID_MALLOC, 1,
2131     [Define to use gmalloc before dumping and the system malloc after.])
2132   HYBRID_MALLOC=1
2133   GNU_MALLOC=
2134   GNU_MALLOC_reason="only before dumping"
2135   GMALLOC_OBJ=gmalloc.o
2136   VMLIMIT_OBJ=
2137 else
2138   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
2139   VMLIMIT_OBJ=vm-limit.o
2140
2141   AC_CHECK_HEADERS([sys/vlimit.h])
2142   AC_CACHE_CHECK([for data_start], [emacs_cv_data_start],
2143     [AC_LINK_IFELSE(
2144        [AC_LANG_PROGRAM(
2145          [[extern char data_start[]; char ch;]],
2146          [[return data_start < &ch;]])],
2147        [emacs_cv_data_start=yes],
2148        [emacs_cv_data_start=no])])
2149   if test $emacs_cv_data_start = yes; then
2150     AC_DEFINE([HAVE_DATA_START], 1,
2151       [Define to 1 if data_start is the address of the start
2152        of the main data segment.])
2153   fi
2154 fi
2155 AC_SUBST([HYBRID_MALLOC])
2156 AM_CONDITIONAL([HYBRID_MALLOC_LIB], [test -n "$HYBRID_MALLOC"])
2157 AC_SUBST(GMALLOC_OBJ)
2158 AC_SUBST(VMLIMIT_OBJ)
2159
2160 if test "$doug_lea_malloc" = "yes" && test "$hybrid_malloc" != yes; then
2161   if test "$GNU_MALLOC" = yes ; then
2162     GNU_MALLOC_reason="
2163       (Using Doug Lea's new malloc from the GNU C Library.)"
2164   fi
2165   AC_DEFINE(DOUG_LEA_MALLOC, 1,
2166     [Define to 1 if the system memory allocator is Doug Lea style,
2167      with malloc hooks and malloc_set_state.])
2168
2169   ## Use mmap directly for allocating larger buffers.
2170   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
2171   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
2172   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
2173   case "$opsys" in
2174     mingw32|gnu*) REL_ALLOC=no ;;
2175   esac
2176 fi
2177
2178 if test x"${REL_ALLOC}" = x; then
2179   REL_ALLOC=${GNU_MALLOC}
2180 fi
2181
2182 use_mmap_for_buffers=no
2183 case "$opsys" in
2184   cygwin|mingw32) use_mmap_for_buffers=yes ;;
2185 esac
2186
2187 AC_FUNC_MMAP
2188 if test $use_mmap_for_buffers = yes; then
2189   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
2190   REL_ALLOC=no
2191 fi
2192
2193 LIBS="$LIBS_SYSTEM $LIBS"
2194
2195 dnl FIXME replace main with a function we actually want from this library.
2196 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
2197
2198 dnl Check for the POSIX thread library.
2199 LIB_PTHREAD=
2200 AC_CHECK_HEADERS_ONCE(pthread.h)
2201 if test "$ac_cv_header_pthread_h" && test "$opsys" != "mingw32"; then
2202   AC_CACHE_CHECK([for pthread library],
2203     [emacs_cv_pthread_lib],
2204     [emacs_cv_pthread_lib=no
2205      OLD_LIBS=$LIBS
2206      for emacs_pthread_lib in 'none needed' -lpthread; do
2207        case $emacs_pthread_lib in
2208          -*) LIBS="$OLD_LIBS $emacs_pthread_lib";;
2209        esac
2210        AC_LINK_IFELSE(
2211          [AC_LANG_PROGRAM(
2212             [[#include <pthread.h>
2213               #include <signal.h>
2214               sigset_t old_mask, new_mask;
2215               void noop (void) {}]],
2216             [[pthread_t th = pthread_self ();
2217               int status = 0;
2218               status += pthread_create (&th, 0, 0, 0);
2219               status += pthread_sigmask (SIG_BLOCK, &new_mask, &old_mask);
2220               status += pthread_kill (th, 0);
2221               #if ! (defined SYSTEM_MALLOC || defined HYBRID_MALLOC \
2222                      || defined DOUG_LEA_MALLOC)
2223               /* Test for pthread_atfork only if gmalloc uses it,
2224                  as older-style hosts like MirBSD 10 lack it.  */
2225               status += pthread_atfork (noop, noop, noop);
2226               #endif
2227               return status;]])],
2228          [emacs_cv_pthread_lib=$emacs_pthread_lib])
2229        LIBS=$OLD_LIBS
2230        if test "$emacs_cv_pthread_lib" != no; then
2231          break
2232        fi
2233      done])
2234   if test "$emacs_cv_pthread_lib" != no; then
2235     AC_DEFINE([HAVE_PTHREAD], 1, [Define to 1 if you have POSIX threads.])
2236     case $emacs_cv_pthread_lib in
2237       -*) LIB_PTHREAD=$emacs_cv_pthread_lib;;
2238     esac
2239     ac_cv_func_pthread_sigmask=yes
2240     # Some systems optimize for single-threaded programs by default, and
2241     # need special flags to disable these optimizations. For example, the
2242     # definition of 'errno' in <errno.h>.
2243     case $opsys in
2244       hpux* | sol*)
2245         AC_DEFINE([_REENTRANT], 1,
2246           [Define to 1 if your system requires this in multithreaded code.]);;
2247       aix4-2)
2248         AC_DEFINE([_THREAD_SAFE], 1,
2249           [Define to 1 if your system requires this in multithreaded code.]);;
2250     esac
2251   fi
2252 fi
2253 AC_SUBST([LIB_PTHREAD])
2254
2255 dnl Check for need for bigtoc support on IBM AIX
2256
2257 case ${host_os} in
2258 aix*)
2259   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
2260     case $GCC in
2261     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
2262     *) gdb_cv_bigtoc=-bbigtoc ;;
2263     esac
2264
2265     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
2266     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
2267   ])
2268   ;;
2269 esac
2270
2271 # Change CFLAGS, CPPFLAGS, and LIBS temporarily so that C_SWITCH_X_SITE
2272 # is for the tests that follow.  We set them back later on.
2273
2274 REAL_CFLAGS="$CFLAGS"
2275 REAL_CPPFLAGS="$CPPFLAGS"
2276 REAL_LIBS="$LIBS"
2277
2278 if test "${HAVE_X11}" = "yes"; then
2279   DEFS="$C_SWITCH_X_SITE $DEFS"
2280   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
2281   LIBS="-lX11 $LIBS"
2282   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
2283   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
2284
2285   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
2286   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
2287   # but it's more convenient here to set LD_RUN_PATH since this
2288   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
2289   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
2290     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
2291     export LD_RUN_PATH
2292   fi
2293
2294   if test "${opsys}" = "gnu-linux"; then
2295     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
2296     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2297      [[XOpenDisplay ("foo");]])],
2298      [xgnu_linux_first_failure=no],
2299      [xgnu_linux_first_failure=yes])
2300     if test "${xgnu_linux_first_failure}" = "yes"; then
2301       OLD_CPPFLAGS="$CPPFLAGS"
2302       OLD_LIBS="$LIBS"
2303       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
2304       LIBS="$LIBS -b i486-linuxaout"
2305       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
2306        [[XOpenDisplay ("foo");]])],
2307        [xgnu_linux_second_failure=no],
2308        [xgnu_linux_second_failure=yes])
2309       if test "${xgnu_linux_second_failure}" = "yes"; then
2310         # If we get the same failure with -b, there is no use adding -b.
2311         # So leave it out.  This plays safe.
2312         AC_MSG_RESULT(no)
2313       else
2314         LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
2315         C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
2316         AC_MSG_RESULT(yes)
2317       fi
2318       CPPFLAGS=$OLD_CPPFLAGS
2319       LIBS=$OLD_LIBS
2320     else
2321       AC_MSG_RESULT(no)
2322     fi
2323   fi
2324
2325   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
2326   # header files included from there.
2327   AC_MSG_CHECKING(for Xkb)
2328   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
2329 #include <X11/XKBlib.h>]],
2330         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
2331         emacs_xkb=yes, emacs_xkb=no)
2332   AC_MSG_RESULT($emacs_xkb)
2333   if test $emacs_xkb = yes; then
2334     AC_DEFINE(HAVE_XKB, 1, [Define to 1 if you have the Xkb extension.])
2335   fi
2336
2337   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
2338 XScreenNumberOfScreen)
2339 fi
2340
2341 if test "${window_system}" = "x11"; then
2342   AC_MSG_CHECKING(X11 version 6)
2343   AC_CACHE_VAL(emacs_cv_x11_version_6,
2344   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
2345 [[#if XlibSpecificationRelease < 6
2346 fail;
2347 #endif
2348 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
2349   if test $emacs_cv_x11_version_6 = yes; then
2350     AC_MSG_RESULT(6 or newer)
2351     AC_DEFINE(HAVE_X11R6, 1,
2352               [Define to 1 if you have the X11R6 or newer version of Xlib.])
2353     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
2354     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
2355     ## XIM support.
2356     case "$opsys" in
2357       sol2-*) : ;;
2358       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
2359            [Define if you have usable X11R6-style XIM support.])
2360          ;;
2361     esac
2362   else
2363     AC_MSG_RESULT(before 6)
2364   fi
2365 fi
2366
2367
2368 ### Use -lrsvg-2 if available, unless '--with-rsvg=no' is specified.
2369 HAVE_RSVG=no
2370 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${opsys}" = "mingw32"; then
2371   if test "${with_rsvg}" != "no"; then
2372     RSVG_REQUIRED=2.11.0
2373     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
2374
2375     EMACS_CHECK_MODULES([RSVG], [$RSVG_MODULE])
2376     AC_SUBST(RSVG_CFLAGS)
2377     AC_SUBST(RSVG_LIBS)
2378
2379     if test $HAVE_RSVG = yes; then
2380       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
2381       CFLAGS="$CFLAGS $RSVG_CFLAGS"
2382       # Windows loads librsvg dynamically
2383       if test "${opsys}" = "mingw32"; then
2384         RSVG_LIBS=
2385       fi
2386     fi
2387   fi
2388 fi
2389
2390 HAVE_IMAGEMAGICK=no
2391 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes" || test "${HAVE_W32}" = "yes"; then
2392   if test "${with_imagemagick}" != "no"; then
2393     ## 6.3.5 is the earliest version known to work; see Bug#17339.
2394     ## 6.8.2 makes Emacs crash; see Bug#13867.
2395     IMAGEMAGICK_MODULE="Wand >= 6.3.5 Wand != 6.8.2"
2396     EMACS_CHECK_MODULES([IMAGEMAGICK], [$IMAGEMAGICK_MODULE])
2397     AC_SUBST(IMAGEMAGICK_CFLAGS)
2398     AC_SUBST(IMAGEMAGICK_LIBS)
2399
2400     if test $HAVE_IMAGEMAGICK = yes; then
2401       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
2402       OLD_CFLAGS=$CFLAGS
2403       OLD_LIBS=$LIBS
2404       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
2405       LIBS="$IMAGEMAGICK_LIBS $LIBS"
2406       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers MagickAutoOrientImage)
2407       CFLAGS=$OLD_CFLAGS
2408       LIBS=$OLD_LIBS
2409     fi
2410   fi
2411 fi
2412
2413 AC_CHECK_LIB(anl, getaddrinfo_a, HAVE_GETADDRINFO_A=yes)
2414 if test "${HAVE_GETADDRINFO_A}" = "yes"; then
2415   AC_DEFINE(HAVE_GETADDRINFO_A, 1,
2416 [Define to 1 if you have getaddrinfo_a for asynchronous DNS resolution.])
2417   GETADDRINFO_A_LIBS="-lanl"
2418   AC_SUBST(GETADDRINFO_A_LIBS)
2419 fi
2420
2421 HAVE_GTK=no
2422 GTK_OBJ=
2423 gtk_term_header=$term_header
2424 check_gtk2=no
2425 gtk3_pkg_errors=
2426 if test "${opsys}" != "mingw32"; then
2427   if test "${with_gtk3}" = "yes" || test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
2428     GLIB_REQUIRED=2.28
2429     GTK_REQUIRED=3.0
2430     GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2431
2432     dnl Checks for libraries.
2433     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2434       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2435     if test "$pkg_check_gtk" = "no" && test "$with_gtk3" = "yes"; then
2436        AC_MSG_ERROR($GTK_PKG_ERRORS)
2437     fi
2438     if test "$pkg_check_gtk" = "yes"; then
2439        AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
2440        GTK_OBJ=emacsgtkfixed.o
2441        gtk_term_header=gtkutil.h
2442        USE_GTK_TOOLKIT="GTK3"
2443        if test "x$ac_enable_gtk_deprecation_warnings" = x; then
2444          AC_DEFINE([GDK_DISABLE_DEPRECATION_WARNINGS], [1],
2445            [Define to 1 to disable GTK+/GDK deprecation warnings.])
2446          AC_DEFINE([GLIB_DISABLE_DEPRECATION_WARNINGS], [1],
2447            [Define to 1 to disable Glib deprecation warnings.])
2448        fi
2449     else
2450        check_gtk2=yes
2451        gtk3_pkg_errors="$GTK_PKG_ERRORS "
2452     fi
2453   fi
2454
2455   if test "${with_gtk2}" = "yes" || test "$check_gtk2" = "yes"; then
2456     GLIB_REQUIRED=2.10
2457     GTK_REQUIRED=2.10
2458     GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
2459
2460     dnl Checks for libraries.
2461     EMACS_CHECK_MODULES([GTK], [$GTK_MODULES],
2462       [pkg_check_gtk=yes], [pkg_check_gtk=no])
2463     if test "$pkg_check_gtk" = "no" &&
2464        { test "$with_gtk" = yes || test "$with_gtk2" = "yes"; }
2465     then
2466       AC_MSG_ERROR($gtk3_pkg_errors$GTK_PKG_ERRORS)
2467     fi
2468     test "$pkg_check_gtk" = "yes" && USE_GTK_TOOLKIT="GTK2"
2469   fi
2470 fi
2471
2472 OLD_CFLAGS=$CFLAGS
2473 OLD_LIBS=$LIBS
2474
2475 if test x"$pkg_check_gtk" = xyes; then
2476
2477   AC_SUBST(GTK_LIBS)
2478   CFLAGS="$CFLAGS $GTK_CFLAGS"
2479   LIBS="$GTK_LIBS $LIBS"
2480   dnl Try to compile a simple GTK program.
2481   AC_MSG_CHECKING([whether GTK compiles])
2482   GTK_COMPILES=no
2483   AC_LINK_IFELSE(
2484     [AC_LANG_PROGRAM(
2485        [[/* Check the Gtk and Glib APIs.  */
2486          #include <gtk/gtk.h>
2487          #include <glib-object.h>
2488          static void
2489          callback (GObject *go, GParamSpec *spec, gpointer user_data)
2490          {}
2491        ]],
2492        [[
2493          GtkSettings *gs = 0;
2494          /* Use G_CALLBACK to make sure function pointers can be cast to void *;
2495             strict C prohibits this.  Use gtk_main_iteration to test that the
2496             libraries are there.  */
2497          if (g_signal_handler_find (G_OBJECT (gs), G_SIGNAL_MATCH_FUNC,
2498                                     0, 0, 0, G_CALLBACK (callback), 0))
2499            gtk_main_iteration ();
2500        ]])],
2501     [GTK_COMPILES=yes])
2502   AC_MSG_RESULT([$GTK_COMPILES])
2503   if test "${GTK_COMPILES}" != "yes"; then
2504     GTK_OBJ=
2505     if test "$USE_X_TOOLKIT" != "maybe"; then
2506       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
2507     fi
2508   else
2509     C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
2510     HAVE_GTK=yes
2511     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
2512     GTK_OBJ="gtkutil.o $GTK_OBJ"
2513     term_header=$gtk_term_header
2514     USE_X_TOOLKIT=none
2515     AC_MSG_WARN([[Your version of Gtk+ will have problems with
2516        closing open displays.  This is no problem if you just use
2517        one display, but if you use more than one and close one of them
2518        Emacs may crash.
2519        See http://bugzilla.gnome.org/show_bug.cgi?id=85715]])
2520     sleep 3
2521   fi
2522
2523 fi
2524 AC_SUBST(GTK_OBJ)
2525
2526
2527 if test "${HAVE_GTK}" = "yes"; then
2528
2529   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
2530   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
2531   if test "$with_toolkit_scroll_bars" != no; then
2532     with_toolkit_scroll_bars=yes
2533   fi
2534
2535   dnl  Check if we have the old file selection dialog declared and
2536   dnl  in the link library.  In 2.x it may be in the library,
2537   dnl  but not declared if deprecated featured has been selected out.
2538   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
2539   HAVE_GTK_FILE_SELECTION=no
2540   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
2541                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
2542 #include <gtk/gtk.h>])
2543   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
2544     AC_CHECK_FUNCS(gtk_file_selection_new)
2545   fi
2546
2547   dnl Same as above for gtk_handle_box.
2548   HAVE_GTK_HANDLE_BOX=no
2549   AC_CHECK_DECL(GTK_TYPE_HANDLE_BOX, HAVE_GTK_HANDLE_BOX=yes,
2550                    HAVE_GTK_HANDLE_BOX=no, [AC_INCLUDES_DEFAULT
2551 #include <gtk/gtk.h>])
2552   if test "$HAVE_GTK_HANDLE_BOX" = yes; then
2553     AC_CHECK_FUNCS(gtk_handle_box_new)
2554   fi
2555
2556   dnl Same as above for gtk_tearoff_menu_item.
2557   HAVE_GTK_TEAROFF_MENU_ITEM=no
2558   AC_CHECK_DECL(GTK_TYPE_TEAROFF_MENU_ITEM, HAVE_GTK_TEAROFF_MENU_ITEM=yes,
2559                    HAVE_GTK_TEAROFF_MENU_ITEM=no, [AC_INCLUDES_DEFAULT
2560 #include <gtk/gtk.h>])
2561   if test "$HAVE_GTK_TEAROFF_MENU_ITEM" = yes; then
2562     AC_CHECK_FUNCS(gtk_tearoff_menu_item_new)
2563   fi
2564
2565   dnl Check for functions introduced in 2.14 and later.
2566   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
2567                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
2568                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
2569                  gtk_orientable_set_orientation \
2570                  gtk_window_set_has_resize_grip)
2571
2572  term_header=gtkutil.h
2573 fi
2574
2575
2576 dnl Enable xwidgets if GTK3 and WebKitGTK+ are available.
2577 HAVE_XWIDGETS=no
2578 XWIDGETS_OBJ=
2579 if test "$with_xwidgets" != "no"; then
2580   test "$USE_GTK_TOOLKIT" = "GTK3" && test "$window_system" != "none" ||
2581     AC_MSG_ERROR([xwidgets requested but gtk3 not used.])
2582
2583   WEBKIT_REQUIRED=1.4.0
2584   WEBKIT_MODULES="webkitgtk-3.0 >= $WEBKIT_REQUIRED"
2585   EMACS_CHECK_MODULES([WEBKIT], [$WEBKIT_MODULES])
2586   HAVE_XWIDGETS=$HAVE_WEBKIT
2587   test $HAVE_XWIDGETS = yes ||
2588     AC_MSG_ERROR([xwidgets requested but WebKitGTK+ not found.])
2589
2590   XWIDGETS_OBJ=xwidget.o
2591   AC_DEFINE([HAVE_XWIDGETS], 1, [Define to 1 if you have xwidgets support.])
2592 fi
2593 AC_SUBST(XWIDGETS_OBJ)
2594
2595 CFLAGS=$OLD_CFLAGS
2596 LIBS=$OLD_LIBS
2597
2598 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
2599 dnl other platforms.
2600 HAVE_DBUS=no
2601 DBUS_OBJ=
2602 if test "${with_dbus}" = "yes"; then
2603    EMACS_CHECK_MODULES([DBUS], [dbus-1 >= 1.0])
2604    if test "$HAVE_DBUS" = yes; then
2605      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
2606      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
2607      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
2608      dnl D-Bus 1.5.12.
2609      OLD_LIBS=$LIBS
2610      LIBS="$LIBS $DBUS_LIBS"
2611      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
2612                     dbus_type_is_valid \
2613                     dbus_validate_bus_name \
2614                     dbus_validate_path \
2615                     dbus_validate_interface \
2616                     dbus_validate_member)
2617      LIBS=$OLD_LIBS
2618      DBUS_OBJ=dbusbind.o
2619    fi
2620 fi
2621 AC_SUBST(DBUS_CFLAGS)
2622 AC_SUBST(DBUS_LIBS)
2623 AC_SUBST(DBUS_OBJ)
2624
2625 dnl GSettings has been tested under GNU/Linux only.
2626 HAVE_GSETTINGS=no
2627 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
2628    EMACS_CHECK_MODULES([GSETTINGS], [gio-2.0 >= 2.26])
2629    if test "$HAVE_GSETTINGS" = "yes"; then
2630       old_CFLAGS=$CFLAGS
2631       CFLAGS="$CFLAGS $GSETTINGS_CFLAGS"
2632       old_LIBS=$LIBS
2633       LIBS="$LIBS $GSETTINGS_LIBS"
2634       AC_MSG_CHECKING([whether GSettings is in gio])
2635       AC_LINK_IFELSE(
2636          [AC_LANG_PROGRAM(
2637              [[/* Check that gsettings really is present.  */
2638              #include <glib-object.h>
2639              #include <gio/gio.h>
2640              ]],
2641              [[
2642                GSettings *settings;
2643                GVariant *val = g_settings_get_value (settings, "");
2644              ]])],
2645          [], HAVE_GSETTINGS=no)
2646       AC_MSG_RESULT([$HAVE_GSETTINGS])
2647
2648       if test "$HAVE_GSETTINGS" = "yes"; then
2649         AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
2650         SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
2651         SETTINGS_LIBS="$GSETTINGS_LIBS"
2652       fi
2653       CFLAGS=$old_CFLAGS
2654       LIBS=$old_LIBS
2655    fi
2656 fi
2657
2658 dnl GConf has been tested under GNU/Linux only.
2659 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
2660 HAVE_GCONF=no
2661 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
2662    EMACS_CHECK_MODULES([GCONF], [gconf-2.0 >= 2.13])
2663    if test "$HAVE_GCONF" = yes; then
2664       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
2665       dnl Newer GConf doesn't link with g_objects, so this is not defined.
2666       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
2667       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
2668    fi
2669 fi
2670
2671 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
2672     EMACS_CHECK_MODULES([GOBJECT], [gobject-2.0 >= 2.0])
2673     if test "$HAVE_GOBJECT" = "yes"; then
2674        SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GOBJECT_CFLAGS"
2675        SETTINGS_LIBS="$SETTINGS_LIBS $GOBJECT_LIBS"
2676     fi
2677     SAVE_CFLAGS="$CFLAGS"
2678     SAVE_LIBS="$LIBS"
2679     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
2680     LIBS="$SETTINGS_LIBS $LIBS"
2681     CFLAGS="$SAVE_CFLAGS"
2682     LIBS="$SAVE_LIBS"
2683 fi
2684 AC_SUBST(SETTINGS_CFLAGS)
2685 AC_SUBST(SETTINGS_LIBS)
2686
2687
2688 dnl SELinux is available for GNU/Linux only.
2689 HAVE_LIBSELINUX=no
2690 LIBSELINUX_LIBS=
2691 if test "${with_selinux}" = "yes"; then
2692    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
2693    if test "$HAVE_LIBSELINUX" = yes; then
2694       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
2695       LIBSELINUX_LIBS=-lselinux
2696    fi
2697 fi
2698 AC_SUBST(LIBSELINUX_LIBS)
2699
2700 HAVE_GNUTLS=no
2701 if test "${with_gnutls}" = "yes" ; then
2702   EMACS_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6],
2703     [HAVE_GNUTLS=yes], [HAVE_GNUTLS=no])
2704   if test "${HAVE_GNUTLS}" = "yes"; then
2705     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2706     EMACS_CHECK_MODULES([LIBGNUTLS3], [gnutls >= 3.0.0],
2707       [AC_DEFINE(HAVE_GNUTLS3, 1, [Define if using GnuTLS v3.])], [])
2708   fi
2709
2710   # Windows loads GnuTLS dynamically
2711   if test "${opsys}" = "mingw32"; then
2712     LIBGNUTLS_LIBS=
2713   fi
2714 fi
2715
2716 AC_SUBST(LIBGNUTLS_LIBS)
2717 AC_SUBST(LIBGNUTLS_CFLAGS)
2718
2719 NOTIFY_OBJ=
2720 NOTIFY_SUMMARY=no
2721
2722 dnl MS Windows native file monitor is available for mingw32 only.
2723 case $with_file_notification,$opsys in
2724   w32,cygwin)
2725     AC_MSG_ERROR(['--with-file-notification=w32' was specified, but
2726     this is only supported on MS-Windows native and MinGW32 builds.
2727     Consider using gfile instead.])
2728     ;;
2729   w32,* | yes,mingw32)
2730     AC_CHECK_HEADER(windows.h)
2731     if test "$ac_cv_header_windows_h" = yes ; then
2732        AC_DEFINE(HAVE_W32NOTIFY, 1, [Define to 1 to use w32notify.])
2733        NOTIFY_OBJ=w32notify.o
2734        NOTIFY_SUMMARY="yes (w32)"
2735     fi ;;
2736 esac
2737
2738 dnl inotify is available only on GNU/Linux.
2739 case $with_file_notification,$NOTIFY_OBJ in
2740   inotify, | yes,)
2741     AC_CHECK_HEADER(sys/inotify.h)
2742     if test "$ac_cv_header_sys_inotify_h" = yes ; then
2743         AC_CHECK_FUNC(inotify_init1)
2744         if test "$ac_cv_func_inotify_init1" = yes; then
2745           AC_DEFINE(HAVE_INOTIFY, 1, [Define to 1 to use inotify.])
2746           NOTIFY_OBJ=inotify.o
2747           NOTIFY_SUMMARY="yes -lglibc (inotify)"
2748        fi
2749     fi ;;
2750 esac
2751
2752 dnl kqueue is available on BSD-like systems.
2753 case $with_file_notification,$NOTIFY_OBJ in
2754   kqueue,* | yes,)
2755     EMACS_CHECK_MODULES([KQUEUE], [libkqueue])
2756     if test "$HAVE_KQUEUE" = "yes"; then
2757        AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2758        CPPFLAGS="$CPPFLAGS -I/usr/include/kqueue"
2759        NOTIFY_CFLAGS=$KQUEUE_CFLAGS
2760        NOTIFY_LIBS=$KQUEUE_LIBS
2761        NOTIFY_OBJ=kqueue.o
2762        NOTIFY_SUMMARY="yes -lkqueue"
2763     else
2764        AC_SEARCH_LIBS(kqueue, [])
2765        if test "$ac_cv_search_kqueue" != no; then
2766          AC_DEFINE(HAVE_KQUEUE, 1, [Define to 1 to use kqueue.])
2767          NOTIFY_OBJ=kqueue.o
2768          NOTIFY_SUMMARY="yes (kqueue)"
2769        fi
2770     fi ;;
2771 esac
2772
2773 dnl g_file_monitor exists since glib 2.18.  G_FILE_MONITOR_EVENT_MOVED
2774 dnl has been added in glib 2.24.  It has been tested under
2775 dnl GNU/Linux only.
2776 case $with_file_notification,$NOTIFY_OBJ in
2777   gfile,* | yes,)
2778     if test "${HAVE_NS}" = yes; then
2779        AC_MSG_ERROR(['--with-file-notification=gfile' is not supported in NextStep builds.
2780 Consider kqueue instead.])
2781     else
2782        EMACS_CHECK_MODULES([GFILENOTIFY], [gio-2.0 >= 2.24])
2783        if test "$HAVE_GFILENOTIFY" = "yes"; then
2784           AC_DEFINE(HAVE_GFILENOTIFY, 1, [Define to 1 if using GFile.])
2785           NOTIFY_CFLAGS=$GFILENOTIFY_CFLAGS
2786           NOTIFY_LIBS=$GFILENOTIFY_LIBS
2787           NOTIFY_OBJ=gfilenotify.o
2788           NOTIFY_SUMMARY="yes -lgio (gfile)"
2789        fi
2790     fi ;;
2791 esac
2792
2793 case $with_file_notification,$NOTIFY_OBJ in
2794   yes,* | no,* | *,?*) ;;
2795   *) AC_MSG_ERROR([File notification '$with_file_notification' requested but requirements not found.]) ;;
2796 esac
2797
2798 if test -n "$NOTIFY_OBJ"; then
2799    AC_DEFINE(USE_FILE_NOTIFY, 1, [Define to 1 if using file notifications.])
2800 fi
2801 AC_SUBST(NOTIFY_CFLAGS)
2802 AC_SUBST(NOTIFY_LIBS)
2803 AC_SUBST(NOTIFY_OBJ)
2804
2805 dnl Do not put whitespace before the #include statements below.
2806 dnl Older compilers (eg sunos4 cc) choke on it.
2807 HAVE_XAW3D=no
2808 LUCID_LIBW=
2809 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2810   if test "$with_xaw3d" != no; then
2811     AC_CACHE_VAL(emacs_cv_xaw3d,
2812     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2813 #include <X11/Intrinsic.h>
2814 #include <X11/Xaw3d/Simple.h>]],
2815       [[]])],
2816       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2817                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2818       emacs_cv_xaw3d=no)])
2819   else
2820     emacs_cv_xaw3d=no
2821   fi
2822   if test $emacs_cv_xaw3d = yes; then
2823     AC_MSG_CHECKING(for xaw3d)
2824     AC_MSG_RESULT([yes; using Lucid toolkit])
2825     USE_X_TOOLKIT=LUCID
2826     HAVE_XAW3D=yes
2827     LUCID_LIBW=-lXaw3d
2828     AC_DEFINE(HAVE_XAW3D, 1,
2829               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2830   else
2831     AC_MSG_CHECKING(for xaw3d)
2832     AC_MSG_RESULT(no)
2833     AC_MSG_CHECKING(for libXaw)
2834     AC_CACHE_VAL(emacs_cv_xaw,
2835     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2836 #include <X11/Intrinsic.h>
2837 #include <X11/Xaw/Simple.h>]],
2838       [[]])],
2839       emacs_cv_xaw=yes,
2840       emacs_cv_xaw=no)])
2841     if test $emacs_cv_xaw = yes; then
2842       AC_MSG_RESULT([yes; using Lucid toolkit])
2843       USE_X_TOOLKIT=LUCID
2844       LUCID_LIBW=-lXaw
2845     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2846       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2847     else
2848       AC_MSG_ERROR([No X toolkit could be found.
2849 If you are sure you want Emacs compiled without an X toolkit, pass
2850   --with-x-toolkit=no
2851 to configure.  Otherwise, install the development libraries for the toolkit
2852 that you want to use (e.g. Gtk+) and re-run configure.])
2853     fi
2854   fi
2855 fi
2856
2857 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2858
2859 LIBXTR6=
2860 LIBXMU=
2861 if test "${USE_X_TOOLKIT}" != "none"; then
2862   AC_MSG_CHECKING(X11 toolkit version)
2863   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2864   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2865 [[#if XtSpecificationRelease < 6
2866 fail;
2867 #endif
2868 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2869   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2870   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2871     AC_MSG_RESULT(6 or newer)
2872     AC_DEFINE(HAVE_X11XTR6, 1,
2873               [Define to 1 if you have the X11R6 or newer version of Xt.])
2874     LIBXTR6="-lSM -lICE"
2875     case "$opsys" in
2876       ## Use libw.a along with X11R6 Xt.
2877       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2878     esac
2879   else
2880     AC_MSG_RESULT(before 6)
2881   fi
2882
2883 dnl If using toolkit, check whether libXmu.a exists.
2884 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2885   OLDLIBS="$LIBS"
2886   if test x$HAVE_X11XTR6 = xyes; then
2887     OTHERLIBS='-lXt -lSM -lICE'
2888   else
2889     OTHERLIBS='-lXt'
2890   fi
2891   AC_SEARCH_LIBS([XmuConvertStandardSelection], [Xmu], [], [], [$OTHERLIBS])
2892   if test "X$LIBS" != "X$OLDLIBS"; then
2893     LIBXMU=$ac_cv_search_XmuConvertStandardSelection
2894   fi
2895   LIBS=$OLDLIBS
2896   dnl ac_cv_search_XmuConvertStandardSelection is also referenced below.
2897 fi
2898 AC_SUBST(LIBXTR6)
2899 AC_SUBST(LIBXMU)
2900
2901 LIBXP=
2902 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2903   # OpenMotif may be installed in such a way on some GNU/Linux systems.
2904   if test -d /usr/include/openmotif; then
2905     CPPFLAGS="-I/usr/include/openmotif $CPPFLAGS"
2906     emacs_cv_openmotif=yes
2907     case "$canonical" in
2908       x86_64-*-linux-gnu* | powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*)
2909       test -d /usr/lib64/openmotif && LDFLAGS="-L/usr/lib64/openmotif $LDFLAGS"
2910       ;;
2911       *)
2912       test -d /usr/lib/openmotif && LDFLAGS="-L/usr/lib/openmotif $LDFLAGS"
2913     esac
2914   else
2915     emacs_cv_openmotif=no
2916   fi
2917   AC_CACHE_CHECK(for (Open)Motif version 2.1, emacs_cv_motif_version_2_1,
2918   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2919     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2920 int x = 5;
2921 #else
2922 Motif version prior to 2.1.
2923 #endif]])],
2924     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2925   if test $emacs_cv_motif_version_2_1 = yes; then
2926     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2927     if test x$emacs_cv_openmotif = xyes; then
2928       REAL_CPPFLAGS="-I/usr/include/openmotif $REAL_CPPFLAGS"
2929     fi
2930   else
2931     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2932     # We put this in CFLAGS temporarily to precede other -I options
2933     # that might be in CFLAGS temporarily.
2934     # We put this in CPPFLAGS where it precedes the other -I options.
2935     OLD_CPPFLAGS=$CPPFLAGS
2936     OLD_CFLAGS=$CFLAGS
2937     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2938     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2939     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2940       [[int x = 5;]])],
2941       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2942     if test $emacs_cv_lesstif = yes; then
2943       # Make sure this -I option remains in CPPFLAGS after it is set
2944       # back to REAL_CPPFLAGS.
2945       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2946       # have those other -I options anyway.  Ultimately, having this
2947       # directory ultimately in CPPFLAGS will be enough.
2948       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2949       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2950     else
2951       CFLAGS=$OLD_CFLAGS
2952       CPPFLAGS=$OLD_CPPFLAGS
2953     fi
2954   fi
2955   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2956     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2957 fi
2958
2959 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2960 dnl using Motif or Xaw3d is available, and unless
2961 dnl --with-toolkit-scroll-bars=no was specified.
2962
2963 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2964             [Define to 1 if we should use toolkit scroll bars.])dnl
2965 USE_TOOLKIT_SCROLL_BARS=no
2966 if test "${with_toolkit_scroll_bars}" != "no"; then
2967   if test "${USE_X_TOOLKIT}" != "none"; then
2968     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2969       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2970       HAVE_XAW3D=no
2971       USE_TOOLKIT_SCROLL_BARS=yes
2972     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2973       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2974       USE_TOOLKIT_SCROLL_BARS=yes
2975     fi
2976   elif test "${HAVE_GTK}" = "yes"; then
2977     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2978     USE_TOOLKIT_SCROLL_BARS=yes
2979   elif test "${HAVE_NS}" = "yes"; then
2980     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2981     USE_TOOLKIT_SCROLL_BARS=yes
2982   elif test "${HAVE_W32}" = "yes"; then
2983     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2984     USE_TOOLKIT_SCROLL_BARS=yes
2985   fi
2986 fi
2987
2988 dnl See if XIM is available.
2989 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2990           #include <X11/Xlib.h>
2991           #include <X11/Xresource.h>]],
2992          [[XIMProc  callback;]])],
2993          [HAVE_XIM=yes
2994          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2995          HAVE_XIM=no)
2996
2997 dnl '--with-xim' now controls only the initial value of use_xim at run time.
2998
2999 if test "${with_xim}" != "no"; then
3000   AC_DEFINE(USE_XIM, 1,
3001             [Define to 1 if we should use XIM, if it is available.])
3002 fi
3003
3004
3005 if test "${HAVE_XIM}" != "no"; then
3006   late_CFLAGS=$CFLAGS
3007   if test "$GCC" = yes; then
3008     CFLAGS="$CFLAGS --pedantic-errors"
3009   fi
3010   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
3011 #include <X11/Xlib.h>
3012 #include <X11/Xresource.h>]],
3013 [[Display *display;
3014 XrmDatabase db;
3015 char *res_name;
3016 char *res_class;
3017 XIMProc  callback;
3018 XPointer *client_data;
3019 #ifndef __GNUC__
3020 /* If we're not using GCC, it's probably not XFree86, and this is
3021    probably right, but we can't use something like --pedantic-errors.  */
3022 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
3023                                            char*, XIMProc, XPointer*);
3024 #endif
3025 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
3026    client_data);]])],
3027     [emacs_cv_arg6_star=yes])
3028   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
3029          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
3030 either XPointer or XPointer*.])dnl
3031   if test "$emacs_cv_arg6_star" = yes; then
3032     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
3033   else
3034     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
3035   fi
3036   CFLAGS=$late_CFLAGS
3037 fi
3038
3039 ### Start of font-backend (under any platform) section.
3040 # (nothing here yet -- this is a placeholder)
3041 ### End of font-backend (under any platform) section.
3042
3043 ### Start of font-backend (under X11) section.
3044 if test "${HAVE_X11}" = "yes"; then
3045     ## Use -lXft if available, unless '--with-xft=no'.
3046     HAVE_XFT=maybe
3047     if test "x${with_x}" = "xno"; then
3048       with_xft="no";
3049     fi
3050
3051     if test "$with_xft" != no; then
3052       EMACS_CHECK_MODULES([FONTCONFIG], [fontconfig >= 2.2.0])
3053       with_xft=$HAVE_FONTCONFIG
3054     fi
3055
3056     if test "x${with_xft}" != "xno"; then
3057
3058       EMACS_CHECK_MODULES([XFT], [xft >= 0.13.0], [], [HAVE_XFT=no])
3059       ## Because xftfont.c uses XRenderQueryExtension, we also
3060       ## need to link to -lXrender.
3061       HAVE_XRENDER=no
3062       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
3063       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
3064         OLD_CPPFLAGS="$CPPFLAGS"
3065         OLD_CFLAGS="$CFLAGS"
3066         OLD_LIBS="$LIBS"
3067         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
3068         CFLAGS="$CFLAGS $XFT_CFLAGS"
3069         XFT_LIBS="-lXrender $XFT_LIBS"
3070         LIBS="$XFT_LIBS $LIBS"
3071         AC_CHECK_HEADER(X11/Xft/Xft.h,
3072           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS) , ,
3073           [[#include <X11/X.h>]])
3074
3075         if test "${HAVE_XFT}" = "yes"; then
3076           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
3077             AC_SUBST(XFT_LIBS)
3078           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
3079         fi                        # "${HAVE_XFT}" = "yes"
3080         CPPFLAGS=$OLD_CPPFLAGS
3081         CFLAGS=$OLD_CFLAGS
3082         LIBS=$OLD_LIBS
3083       fi                          # "$HAVE_XFT" != no
3084     fi                            # "x${with_xft}" != "xno"
3085
3086     ## We used to allow building with FreeType and without Xft.
3087     ## However, the ftx font backend driver is not in good shape.
3088     if test "$HAVE_XFT" != "yes"; then
3089        dnl For the "Does Emacs use" message at the end.
3090        HAVE_XFT=no
3091        HAVE_FREETYPE=no
3092     else
3093        dnl Strict linkers fail with
3094        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
3095        dnl if -lfreetype is not specified.
3096        dnl The following is needed to set FREETYPE_LIBS.
3097        EMACS_CHECK_MODULES([FREETYPE], [freetype2])
3098
3099        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
3100     fi
3101
3102     HAVE_LIBOTF=no
3103     if test "${HAVE_FREETYPE}" = "yes"; then
3104       AC_DEFINE(HAVE_FREETYPE, 1,
3105                 [Define to 1 if using the freetype and fontconfig libraries.])
3106       if test "${with_libotf}" != "no"; then
3107         EMACS_CHECK_MODULES([LIBOTF], [libotf])
3108         if test "$HAVE_LIBOTF" = "yes"; then
3109           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
3110           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
3111                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
3112                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
3113           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
3114             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
3115                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
3116           fi
3117         fi
3118       fi
3119     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
3120     dnl Does the new font backend require it, or can it work without it?
3121     fi
3122
3123     HAVE_M17N_FLT=no
3124     if test "${HAVE_LIBOTF}" = yes; then
3125       if test "${with_m17n_flt}" != "no"; then
3126         EMACS_CHECK_MODULES([M17N_FLT], [m17n-flt])
3127         if test "$HAVE_M17N_FLT" = "yes"; then
3128           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
3129         fi
3130       fi
3131     fi
3132 else
3133     HAVE_XFT=no
3134     HAVE_FREETYPE=no
3135     HAVE_LIBOTF=no
3136     HAVE_M17N_FLT=no
3137 fi
3138
3139 ### End of font-backend (under X11) section.
3140
3141 AC_SUBST(FREETYPE_CFLAGS)
3142 AC_SUBST(FREETYPE_LIBS)
3143 AC_SUBST(FONTCONFIG_CFLAGS)
3144 AC_SUBST(FONTCONFIG_LIBS)
3145 AC_SUBST(LIBOTF_CFLAGS)
3146 AC_SUBST(LIBOTF_LIBS)
3147 AC_SUBST(M17N_FLT_CFLAGS)
3148 AC_SUBST(M17N_FLT_LIBS)
3149
3150 HAVE_CAIRO=no
3151 if test "${HAVE_X11}" = "yes"; then
3152   if test "${with_cairo}" != "no"; then
3153     CAIRO_REQUIRED=1.12.0
3154     CAIRO_MODULE="cairo >= $CAIRO_REQUIRED"
3155     EMACS_CHECK_MODULES(CAIRO, $CAIRO_MODULE)
3156     if test $HAVE_CAIRO = yes; then
3157       AC_DEFINE(USE_CAIRO, 1, [Define to 1 if using cairo.])
3158     else
3159       AC_MSG_ERROR([cairo requested but not found.])
3160     fi
3161
3162     CFLAGS="$CFLAGS $CAIRO_CFLAGS"
3163     LIBS="$LIBS $CAIRO_LIBS"
3164     AC_SUBST(CAIRO_CFLAGS)
3165     AC_SUBST(CAIRO_LIBS)
3166   fi
3167 fi
3168
3169 if test "${HAVE_X11}" = "yes"; then
3170   AC_CHECK_HEADER(X11/Xlib-xcb.h,
3171     AC_CHECK_LIB(xcb, xcb_translate_coordinates, HAVE_XCB=yes))
3172   if test "${HAVE_XCB}" = "yes"; then
3173     AC_CHECK_LIB(X11-xcb, XGetXCBConnection, HAVE_X11_XCB=yes)
3174     if test "${HAVE_X11_XCB}" = "yes"; then
3175       AC_DEFINE(USE_XCB, 1,
3176 [Define to 1 if you have the XCB library and X11-XCB library for mixed
3177    X11/XCB programming.])
3178       XCB_LIBS="-lX11-xcb -lxcb"
3179       AC_SUBST(XCB_LIBS)
3180     fi
3181   fi
3182 fi
3183
3184 ### Use -lXpm if available, unless '--with-xpm=no'.
3185 ### mingw32 doesn't use -lXpm, since it loads the library dynamically.
3186 ### In the Cygwin-w32 build, we need to use /usr/include/noX/X11/xpm.h
3187 ### rather than /usr/include/X11/xpm.h, so we set CPPFLAGS (and
3188 ### LDFLAGS) accordingly.
3189 HAVE_XPM=no
3190 LIBXPM=
3191 if test "${HAVE_W32}" = "yes" && test "${opsys}" = "cygwin"; then
3192   if test "${with_xpm}" != "no"; then
3193     SAVE_CPPFLAGS="$CPPFLAGS"
3194     SAVE_LDFLAGS="$LDFLAGS"
3195     CPPFLAGS="$CPPFLAGS -I/usr/include/noX"
3196     LDFLAGS="$LDFLAGS -L/usr/lib/noX"
3197     AC_CHECK_HEADER(X11/xpm.h,
3198       [AC_CHECK_LIB(Xpm, XpmReadFileToImage, HAVE_XPM=yes)])
3199     if test "${HAVE_XPM}" = "yes"; then
3200       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3201       AC_EGREP_CPP(no_return_alloc_pixels,
3202       [#include "X11/xpm.h"
3203 #ifndef XpmReturnAllocPixels
3204 no_return_alloc_pixels
3205 #endif
3206       ], HAVE_XPM=no, HAVE_XPM=yes)
3207
3208       if test "${HAVE_XPM}" = "yes"; then
3209         REAL_CPPFLAGS="$REAL_CPPFLAGS -I/usr/include/noX"
3210         AC_MSG_RESULT(yes)
3211       else
3212         AC_MSG_RESULT(no)
3213         CPPFLAGS="$SAVE_CPPFLAGS"
3214         LDFLAGS="$SAVE_LDFLAGS"
3215       fi
3216     fi
3217   fi
3218
3219   if test "${HAVE_XPM}" = "yes"; then
3220     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3221     LIBXPM=-lXpm
3222   fi
3223 fi
3224
3225 if test "${HAVE_X11}" = "yes"; then
3226   dnl Avoid Xpm on AIX unless requested, as it crashes; see Bug#17598.
3227   test "$opsys$with_xpm_set" = aix4-2 && with_xpm=no
3228
3229   if test "${with_xpm}" != "no"; then
3230     AC_CHECK_HEADER(X11/xpm.h,
3231       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
3232     if test "${HAVE_XPM}" = "yes"; then
3233       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
3234       AC_EGREP_CPP(no_return_alloc_pixels,
3235       [#include "X11/xpm.h"
3236 #ifndef XpmReturnAllocPixels
3237 no_return_alloc_pixels
3238 #endif
3239       ], HAVE_XPM=no, HAVE_XPM=yes)
3240
3241       if test "${HAVE_XPM}" = "yes"; then
3242         AC_MSG_RESULT(yes)
3243       else
3244         AC_MSG_RESULT(no)
3245       fi
3246     fi
3247   fi
3248
3249   if test "${HAVE_XPM}" = "yes"; then
3250     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3251     LIBXPM=-lXpm
3252   elif test "$opsys,$LUCID_LIBW" = aix4-2,-lXaw; then
3253     dnl AIX -lXaw needs -lXpm linked too; see Bug#17598 Message#152.
3254     LIBXPM=-lXpm
3255   fi
3256 fi
3257
3258 ### FIXME: Perhaps regroup to minimize code duplication due to MinGW's
3259 ### slightly different requirements wrt image libraries (it doesn't
3260 ### use -lXpm because it loads the xpm shared library dynamically at
3261 ### run time).
3262 if test "${opsys}" = "mingw32"; then
3263   if test "${with_xpm}" != "no"; then
3264     AC_CHECK_HEADER(X11/xpm.h, HAVE_XPM=yes, HAVE_XPM=no, [
3265 #define FOR_MSW 1])
3266   fi
3267
3268   if test "${HAVE_XPM}" = "yes"; then
3269     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
3270   fi
3271 fi
3272
3273 AC_SUBST(LIBXPM)
3274
3275 ### Use -ljpeg if available, unless '--with-jpeg=no'.
3276 HAVE_JPEG=no
3277 LIBJPEG=
3278 if test "${with_jpeg}" != "no"; then
3279   AC_CACHE_CHECK([for jpeglib 6b or later],
3280     [emacs_cv_jpeglib],
3281     [OLD_LIBS=$LIBS
3282      for emacs_cv_jpeglib in yes -ljpeg no; do
3283        case $emacs_cv_jpeglib in
3284          yes) ;;
3285          no) break;;
3286          *) LIBS="$LIBS $emacs_cv_jpeglib";;
3287        esac
3288        AC_LINK_IFELSE(
3289          [AC_LANG_PROGRAM(
3290             [[#undef HAVE_STDLIB_H /* Avoid config.h/jpeglib.h collision.  */
3291               #include <stdio.h> /* jpeglib.h needs FILE and size_t.  */
3292               #include <jpeglib.h>
3293               #include <jerror.h>
3294               char verify[JPEG_LIB_VERSION < 62 ? -1 : 1];
3295               struct jpeg_decompress_struct cinfo;
3296             ]],
3297             [[
3298               jpeg_create_decompress (&cinfo);
3299               WARNMS (&cinfo, JWRN_JPEG_EOF);
3300               jpeg_destroy_decompress (&cinfo);
3301             ]])],
3302          [emacs_link_ok=yes],
3303          [emacs_link_ok=no])
3304        LIBS=$OLD_LIBS
3305        test $emacs_link_ok = yes && break
3306      done])
3307   if test "$emacs_cv_jpeglib" != no; then
3308     HAVE_JPEG=yes
3309     AC_DEFINE([HAVE_JPEG], 1,
3310       [Define to 1 if you have the jpeg library (typically -ljpeg).])
3311     ### mingw32 doesn't use -ljpeg, since it loads the library
3312     ### dynamically when needed, and doesn't want a run-time
3313     ### dependency on the jpeglib DLL.
3314     test "$emacs_cv_jpeglib" != yes && test "${opsys}" != "mingw32" \
3315     && LIBJPEG=$emacs_cv_jpeglib
3316   fi
3317 fi
3318 AC_SUBST(LIBJPEG)
3319
3320 HAVE_ZLIB=no
3321 LIBZ=
3322 if test "${with_zlib}" != "no"; then
3323   OLIBS=$LIBS
3324   AC_SEARCH_LIBS([inflateEnd], [z], [HAVE_ZLIB=yes])
3325   LIBS=$OLIBS
3326   case $ac_cv_search_inflateEnd in
3327     -*) LIBZ=$ac_cv_search_inflateEnd ;;
3328   esac
3329 fi
3330 if test "${HAVE_ZLIB}" = "yes"; then
3331   AC_DEFINE([HAVE_ZLIB], 1, [Define to 1 if you have the zlib library (-lz).])
3332   ### mingw32 doesn't use -lz, since it loads the library dynamically.
3333   if test "${opsys}" = "mingw32"; then
3334      LIBZ=
3335   fi
3336 fi
3337 AC_SUBST(LIBZ)
3338
3339 ### Dynamic modules support
3340 LIBMODULES=
3341 HAVE_MODULES=no
3342 MODULES_OBJ=
3343 MODULES_SUFFIX=
3344 if test "${with_modules}" != "no"; then
3345   if test "$opsys" = "gnu-linux"; then
3346     LIBMODULES="-ldl"
3347     MODULES_SUFFIX=".so"
3348     HAVE_MODULES=yes
3349   elif test "$opsys" = "cygwin"; then
3350     MODULES_SUFFIX=".dll"
3351     HAVE_MODULES=yes
3352   elif test "$opsys" = "darwin"; then
3353     MODULES_SUFFIX=".so"
3354     HAVE_MODULES=yes
3355   elif test "$opsys" = "mingw32"; then
3356     MODULES_SUFFIX=".dll"
3357     HAVE_MODULES=yes
3358   else
3359     # BSD system have dlopen in the libc
3360     AC_CHECK_FUNC(dlopen, [MODULES_SUFFIX=".so"]
3361                           [HAVE_MODULES=yes], [])
3362   fi
3363
3364   if test "${HAVE_MODULES}" = no; then
3365     AC_MSG_ERROR([Dynamic modules are not supported on your system])
3366   else
3367     SAVE_LIBS=$LIBS
3368     LIBS="$LIBS $LIBMODULES"
3369     AC_CHECK_FUNCS([dladdr dlfunc])
3370     LIBS=$SAVE_LIBS
3371   fi
3372 fi
3373
3374 if test "${HAVE_MODULES}" = yes; then
3375    MODULES_OBJ="dynlib.o emacs-module.o"
3376    AC_DEFINE(HAVE_MODULES, 1, [Define to 1 if dynamic modules are enabled])
3377    AC_DEFINE_UNQUOTED(MODULES_SUFFIX, "$MODULES_SUFFIX",
3378      [System extension for dynamic libraries])
3379 fi
3380 AC_SUBST(MODULES_OBJ)
3381 AC_SUBST(LIBMODULES)
3382
3383 ### Use -lpng if available, unless '--with-png=no'.
3384 HAVE_PNG=no
3385 LIBPNG=
3386 PNG_CFLAGS=
3387 if test "${NS_IMPL_COCOA}" = yes; then
3388   : # Nothing to do
3389 elif test "${with_png}" != no; then
3390   # mingw32 loads the library dynamically.
3391   if test "$opsys" = mingw32; then
3392     AC_CHECK_HEADER([png.h], [HAVE_PNG=yes])
3393   elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3394     AC_MSG_CHECKING([for png])
3395     png_cflags=`(libpng-config --cflags) 2>&AS_MESSAGE_LOG_FD` &&
3396     png_libs=`(libpng-config --libs) 2>&AS_MESSAGE_LOG_FD` || {
3397       # libpng-config does not work; configure by hand.
3398       # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
3399       # in /usr/include/libpng.
3400       if test -r /usr/include/libpng/png.h &&
3401          test ! -r /usr/include/png.h; then
3402         png_cflags=-I/usr/include/libpng
3403       else
3404         png_cflags=
3405       fi
3406       png_libs='-lpng'
3407     }
3408     SAVE_CFLAGS=$CFLAGS
3409     SAVE_LIBS=$LIBS
3410     CFLAGS="$CFLAGS $png_cflags"
3411     LIBS="$png_libs -lz -lm $LIBS"
3412     AC_LINK_IFELSE(
3413       [AC_LANG_PROGRAM([[#include <png.h>]],
3414          [[return !png_get_channels (0, 0);]])],
3415       [HAVE_PNG=yes
3416        PNG_CFLAGS=`AS_ECHO(["$png_cflags"]) | sed -e "$edit_cflags"`
3417        LIBPNG=$png_libs
3418        # $LIBPNG requires explicit -lz in some cases.
3419        # We don't know what those cases are, exactly, so play it safe and
3420        # append -lz to any nonempty $LIBPNG, unless we're already using LIBZ.
3421        if test -n "$LIBPNG" && test -z "$LIBZ"; then
3422          LIBPNG="$LIBPNG -lz"
3423        fi])
3424     CFLAGS=$SAVE_CFLAGS
3425     LIBS=$SAVE_LIBS
3426     AC_MSG_RESULT([$HAVE_PNG])
3427   fi
3428 fi
3429 if test $HAVE_PNG = yes; then
3430   AC_DEFINE([HAVE_PNG], [1], [Define to 1 if you have the png library.])
3431
3432   SAVE_CFLAGS=$CFLAGS
3433   CFLAGS="$CFLAGS $PNG_CFLAGS"
3434   AC_CHECK_DECL([png_longjmp],
3435     [],
3436     [AC_DEFINE([PNG_DEPSTRUCT], [],
3437        [Define to empty to suppress deprecation warnings when building
3438         with --enable-gcc-warnings and with libpng versions before 1.5,
3439         which lack png_longjmp.])],
3440     [[#include <png.h>
3441     ]])
3442   CFLAGS=$SAVE_CFLAGS
3443 fi
3444 AC_SUBST(LIBPNG)
3445 AC_SUBST(PNG_CFLAGS)
3446
3447 ### Use -ltiff if available, unless '--with-tiff=no'.
3448 ### mingw32 doesn't use -ltiff, since it loads the library dynamically.
3449 HAVE_TIFF=no
3450 LIBTIFF=
3451 if test "${opsys}" = "mingw32"; then
3452   if test "${with_tiff}" != "no"; then
3453     AC_CHECK_HEADER(tiffio.h, HAVE_TIFF=yes, HAVE_TIFF=no)
3454   fi
3455   if test "${HAVE_TIFF}" = "yes"; then
3456     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3457   fi
3458 elif test "${HAVE_X11}" = "yes" || test "${HAVE_W32}" = "yes"; then
3459   if test "${with_tiff}" != "no"; then
3460     AC_CHECK_HEADER(tiffio.h,
3461       [tifflibs="-lz -lm"
3462       # At least one tiff package requires the jpeg library.
3463       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
3464       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
3465   fi
3466
3467   if test "${HAVE_TIFF}" = "yes"; then
3468     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
3469     dnl FIXME -lz -lm, as per libpng?
3470     LIBTIFF=-ltiff
3471   fi
3472 fi
3473 AC_SUBST(LIBTIFF)
3474
3475 ### Use -lgif or -lungif if available, unless '--with-gif=no'.
3476 ### mingw32 doesn't use -lgif/-lungif, since it loads the library dynamically.
3477 HAVE_GIF=no
3478 LIBGIF=
3479 if test "${opsys}" = "mingw32"; then
3480   if test "${with_gif}" != "no"; then
3481     AC_CHECK_HEADER(gif_lib.h, HAVE_GIF=yes, HAVE_GIF=no)
3482   fi
3483   if test "${HAVE_GIF}" = "yes"; then
3484     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3485   fi
3486 elif test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no" \
3487         || test "${HAVE_W32}" = "yes"; then
3488   AC_CHECK_HEADER(gif_lib.h,
3489 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
3490 # Earlier versions can crash Emacs, but version 5.0 removes EGifPutExtensionLast.
3491     [AC_CHECK_LIB(gif, GifMakeMapObject, HAVE_GIF=yes,
3492         [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])])
3493
3494   if test "$HAVE_GIF" = yes; then
3495     LIBGIF=-lgif
3496   elif test "$HAVE_GIF" = maybe; then
3497 # If gif_lib.h but no libgif, try libungif.
3498     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
3499     test "$HAVE_GIF" = yes && LIBGIF=-lungif
3500   fi
3501
3502   if test "${HAVE_GIF}" = "yes"; then
3503     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
3504   fi
3505 fi
3506 AC_SUBST(LIBGIF)
3507
3508 dnl Check for required libraries.
3509 if test "${HAVE_X11}" = "yes"; then
3510   MISSING=""
3511   WITH_NO=""
3512   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
3513     MISSING="libXpm" && WITH_NO="--with-xpm=no"
3514   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
3515     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
3516   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
3517     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
3518   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
3519     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
3520   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
3521     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
3522
3523   if test "X${MISSING}" != X; then
3524     AC_MSG_ERROR([The following required libraries were not found:
3525     $MISSING
3526 Maybe some development libraries/packages are missing?
3527 If you don't want to link with them give
3528     $WITH_NO
3529 as options to configure])
3530   fi
3531 fi
3532
3533 ### Use -lgpm if available, unless '--with-gpm=no'.
3534 HAVE_GPM=no
3535 LIBGPM=
3536 if test "${with_gpm}" != "no"; then
3537   AC_CHECK_HEADER(gpm.h,
3538     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
3539
3540   if test "${HAVE_GPM}" = "yes"; then
3541     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
3542     LIBGPM=-lgpm
3543   fi
3544 fi
3545 AC_SUBST(LIBGPM)
3546
3547 dnl Check for malloc/malloc.h on darwin
3548 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
3549
3550 GNUSTEP_CFLAGS=
3551 ### Use NeXTstep API to implement GUI.
3552 if test "${HAVE_NS}" = "yes"; then
3553   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
3554   if test "${NS_IMPL_COCOA}" = "yes"; then
3555     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
3556   fi
3557   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
3558     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
3559     if test $NS_GNUSTEP_CONFIG != yes; then
3560       # See also .m.o rule in src/Makefile.in.  */
3561       # FIXME: are all these flags really needed?  Document here why.  */
3562       GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
3563       ## Extra CFLAGS applied to src/*.m files.
3564       GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
3565     fi
3566   fi
3567   OTHER_FILES=ns-app
3568 fi
3569
3570 ### Use session management (-lSM -lICE) if available
3571 HAVE_X_SM=no
3572 LIBXSM=
3573 if test "${HAVE_X11}" = "yes"; then
3574   AC_CHECK_HEADER(X11/SM/SMlib.h,
3575     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
3576
3577   if test "${HAVE_X_SM}" = "yes"; then
3578     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
3579     LIBXSM="-lSM -lICE"
3580   fi
3581 fi
3582 AC_SUBST(LIBXSM)
3583
3584 ### Use XRandr (-lXrandr) if available
3585 HAVE_XRANDR=no
3586 if test "${HAVE_X11}" = "yes"; then
3587   XRANDR_REQUIRED=1.2.2
3588   XRANDR_MODULES="xrandr >= $XRANDR_REQUIRED"
3589   EMACS_CHECK_MODULES([XRANDR], [$XRANDR_MODULES])
3590   if test $HAVE_XRANDR = no; then
3591     # Test old way in case pkg-config doesn't have it (older machines).
3592     # Include Xrender.h by hand to work around bug in older Xrandr.h
3593     # (e.g. RHEL5) and silence (harmless) configure warning (bug#18465).
3594     AC_CHECK_HEADER(X11/extensions/Xrandr.h,
3595       [AC_CHECK_LIB(Xrandr, XRRGetScreenResources, HAVE_XRANDR=yes)],
3596       [], [AC_INCLUDES_DEFAULT
3597 #include <X11/extensions/Xrender.h>])
3598     if test $HAVE_XRANDR = yes; then
3599       XRANDR_LIBS=-lXrandr
3600     fi
3601   fi
3602   if test $HAVE_XRANDR = yes; then
3603     SAVE_CFLAGS="$CFLAGS"
3604     SAVE_LIBS="$LIBS"
3605     CFLAGS="$XRANDR_CFLAGS $CFLAGS"
3606     LIBS="$XRANDR_LIBS $LIBS"
3607     AC_CHECK_FUNCS(XRRGetOutputPrimary XRRGetScreenResourcesCurrent)
3608     CFLAGS="$SAVE_CFLAGS"
3609     LIBS="$SAVE_LIBS"
3610
3611     AC_DEFINE(HAVE_XRANDR, 1, [Define to 1 if you have the XRandr extension.])
3612   fi
3613 fi
3614 AC_SUBST(XRANDR_CFLAGS)
3615 AC_SUBST(XRANDR_LIBS)
3616
3617 ### Use Xinerama (-lXinerama) if available
3618 HAVE_XINERAMA=no
3619 if test "${HAVE_X11}" = "yes"; then
3620   XINERAMA_REQUIRED=1.0.2
3621   XINERAMA_MODULES="xinerama >= $XINERAMA_REQUIRED"
3622   EMACS_CHECK_MODULES([XINERAMA], [$XINERAMA_MODULES])
3623   if test $HAVE_XINERAMA = no; then
3624     # Test old way in case pkg-config doesn't have it (older machines).
3625     AC_CHECK_HEADER(X11/extensions/Xinerama.h,
3626       [AC_CHECK_LIB(Xinerama, XineramaQueryExtension, HAVE_XINERAMA=yes)])
3627     if test $HAVE_XINERAMA = yes; then
3628       XINERAMA_LIBS=-lXinerama
3629     fi
3630   fi
3631   if test $HAVE_XINERAMA = yes; then
3632     AC_DEFINE(HAVE_XINERAMA, 1, [Define to 1 if you have the Xinerama extension.])
3633   fi
3634 fi
3635 AC_SUBST(XINERAMA_CFLAGS)
3636 AC_SUBST(XINERAMA_LIBS)
3637
3638 ### Use Xfixes (-lXfixes) if available
3639 HAVE_XFIXES=no
3640 if test "${HAVE_X11}" = "yes"; then
3641   XFIXES_REQUIRED=4.0.0
3642   XFIXES_MODULES="xfixes >= $XFIXES_REQUIRED"
3643   EMACS_CHECK_MODULES([XFIXES], [$XFIXES_MODULES])
3644   if test $HAVE_XFIXES = no; then
3645     # Test old way in case pkg-config doesn't have it (older machines).
3646     AC_CHECK_HEADER(X11/extensions/Xfixes.h,
3647       [AC_CHECK_LIB(Xfixes, XFixesHideCursor, HAVE_XFIXES=yes)])
3648     if test $HAVE_XFIXES = yes; then
3649       XFIXES_LIBS=-lXfixes
3650     fi
3651   fi
3652   if test $HAVE_XFIXES = yes; then
3653     AC_DEFINE(HAVE_XFIXES, 1, [Define to 1 if you have the Xfixes extension.])
3654   fi
3655 fi
3656 AC_SUBST(XFIXES_CFLAGS)
3657 AC_SUBST(XFIXES_LIBS)
3658
3659 ### Use libxml (-lxml2) if available
3660 ### mingw32 doesn't use -lxml2, since it loads the library dynamically.
3661 HAVE_LIBXML2=no
3662 if test "${with_xml2}" != "no"; then
3663   ### I'm not sure what the version number should be, so I just guessed.
3664   EMACS_CHECK_MODULES([LIBXML2], [libxml-2.0 > 2.6.17])
3665   # Built-in libxml2 on OS X 10.8 lacks libxml-2.0.pc.
3666   if test "${HAVE_LIBXML2}" != "yes" && test "$opsys" = "darwin"; then
3667     SAVE_CPPFLAGS="$CPPFLAGS"
3668     if test -z "$xcsdkdir" -a -n "$XCRUN" -a ! -d /usr/include; then
3669       dnl /usr/include is not found.  Try Xcode SDK dir if it is sane.
3670       xcsdkdir=`$XCRUN --show-sdk-path 2>/dev/null`
3671       case $xcsdkdir in
3672         *[[\\\"\#\$\&\'\`$am_lf\ \      ]]*)
3673         xcsdkdir="" ;;
3674       esac
3675     fi
3676     CPPFLAGS="$CPPFLAGS -I$xcsdkdir/usr/include/libxml2"
3677     AC_CHECK_HEADER(libxml/HTMLparser.h,
3678       [AC_CHECK_DECL(HTML_PARSE_RECOVER, HAVE_LIBXML2=yes, ,
3679                      [#include <libxml/HTMLparser.h>])])
3680     CPPFLAGS="$SAVE_CPPFLAGS"
3681     if test "${HAVE_LIBXML2}" = "yes"; then
3682       LIBXML2_CFLAGS="-I'$xcsdkdir/usr/include/libxml2'"
3683       LIBXML2_LIBS="-lxml2"
3684     fi
3685   fi
3686   if test "${HAVE_LIBXML2}" = "yes"; then
3687     if test "${opsys}" != "mingw32"; then
3688       AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no,
3689         [$LIBXML2_LIBS])
3690     else
3691       LIBXML2_LIBS=""
3692     fi
3693     if test "${HAVE_LIBXML2}" = "yes"; then
3694       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
3695     else
3696       LIBXML2_LIBS=""
3697       LIBXML2_CFLAGS=""
3698     fi
3699   fi
3700 fi
3701 AC_SUBST(LIBXML2_LIBS)
3702 AC_SUBST(LIBXML2_CFLAGS)
3703
3704 # If netdb.h doesn't declare h_errno, we must declare it by hand.
3705 # On MinGW, that is provided by nt/inc/sys/socket.h and w32.c.
3706 if test "${opsys}" = "mingw32"; then
3707   emacs_cv_netdb_declares_h_errno=yes
3708 fi
3709 AC_CACHE_CHECK(whether netdb declares h_errno,
3710                emacs_cv_netdb_declares_h_errno,
3711 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
3712   [[return h_errno;]])],
3713   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
3714 if test $emacs_cv_netdb_declares_h_errno = yes; then
3715   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
3716 fi
3717
3718 # Check for mail-locking functions in a "mail" library.  Probably this should
3719 # have the same check as for liblockfile below.
3720 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
3721 if test $have_mail = yes; then
3722   LIBS_MAIL=-lmail
3723   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the 'mail' library (-lmail).])
3724
3725   OLD_LIBS=$LIBS
3726   LIBS="$LIBS_MAIL $LIBS"
3727   AC_CHECK_FUNCS(touchlock)
3728   LIBS=$OLD_LIBS
3729 else
3730   LIBS_MAIL=
3731 fi
3732 dnl Debian, at least:
3733 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
3734 if test $have_lockfile = yes; then
3735    LIBS_MAIL=-llockfile
3736    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the 'lockfile' library (-llockfile).])
3737 else
3738 # If we have the shared liblockfile, assume we must use it for mail
3739 # locking (e.g. Debian).  If we couldn't link against liblockfile
3740 # (no liblockfile.a installed), ensure that we don't need to.
3741   dnl This works for files generally, not just executables.
3742   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
3743   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
3744                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
3745   if test $ac_cv_prog_liblockfile = yes; then
3746     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
3747 This probably means that movemail could lose mail.
3748 There may be a 'development' package to install containing liblockfile.])
3749   fi
3750 fi
3751 AC_CHECK_HEADERS_ONCE(maillock.h)
3752 AC_SUBST(LIBS_MAIL)
3753
3754 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
3755 ## interlock access to the mail spool.  The alternative is a lock file named
3756 ## /usr/spool/mail/$USER.lock.
3757 mail_lock=no
3758 case "$opsys" in
3759   aix4-2) mail_lock="lockf" ;;
3760
3761   gnu|freebsd|dragonfly|netbsd|openbsd|darwin) mail_lock="flock" ;;
3762
3763   ## On GNU/Linux systems, both methods are used by various mail programs.
3764   ## I assume most people are using newer mailers that have heard of flock.
3765   ## Change this if you need to.
3766   ## Debian contains a patch which says: "On Debian/GNU/Linux systems,
3767   ## configure gets the right answers, and that means *NOT* using flock.
3768   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
3769   ## for details." and then uses '#ifdef DEBIAN'.  Unfortunately the
3770   ## Debian maintainer hasn't provided a clean fix for Emacs.
3771   ## movemail.c will use 'maillock' when MAILDIR, HAVE_LIBMAIL and
3772   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
3773   ## correct logic.  -- fx
3774   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
3775   ## liblockfile is a Free Software replacement for libmail, used on
3776   ## Debian systems and elsewhere. -rfr.
3777   gnu-*)
3778     mail_lock="flock"
3779     if test $have_mail = yes || test $have_lockfile = yes; then
3780       test $ac_cv_header_maillock_h = yes && mail_lock=no
3781     fi
3782     ;;
3783
3784   mingw32)
3785     mail_lock="none-needed" ;;
3786 esac
3787
3788 BLESSMAIL_TARGET=
3789 case "$mail_lock" in
3790   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
3791
3792   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
3793
3794   none-needed) ;;
3795
3796   *) BLESSMAIL_TARGET="need-blessmail" ;;
3797 esac
3798 AC_SUBST(BLESSMAIL_TARGET)
3799
3800 OLD_LIBS=$LIBS
3801 LIBS="$LIB_PTHREAD $LIB_MATH $LIBS"
3802 AC_CHECK_FUNCS(accept4 fchdir gethostname \
3803 getrusage get_current_dir_name \
3804 lrand48 random rint \
3805 select getpagesize setlocale newlocale \
3806 getrlimit setrlimit shutdown getaddrinfo \
3807 pthread_sigmask strsignal setitimer \
3808 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
3809 gai_strerror sync \
3810 getpwent endpwent getgrent endgrent \
3811 cfmakeraw cfsetspeed copysign __executable_start log2)
3812 LIBS=$OLD_LIBS
3813
3814 dnl No need to check for posix_memalign if aligned_alloc works.
3815 AC_CHECK_FUNCS([aligned_alloc posix_memalign], [break])
3816 AC_CHECK_DECLS([aligned_alloc], [], [], [[#include <stdlib.h>]])
3817
3818 dnl Cannot use AC_CHECK_FUNCS
3819 AC_CACHE_CHECK([for __builtin_unwind_init],
3820                emacs_cv_func___builtin_unwind_init,
3821 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
3822                 emacs_cv_func___builtin_unwind_init=yes,
3823                 emacs_cv_func___builtin_unwind_init=no)])
3824 if test $emacs_cv_func___builtin_unwind_init = yes; then
3825   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
3826             [Define to 1 if you have the '__builtin_unwind_init' function.])
3827 fi
3828
3829 AC_CHECK_HEADERS_ONCE(sys/un.h)
3830
3831 AC_FUNC_FSEEKO
3832
3833 # UNIX98 PTYs.
3834 AC_CHECK_FUNCS(grantpt)
3835
3836 # PTY-related GNU extensions.
3837 AC_CHECK_FUNCS(getpt posix_openpt)
3838
3839 # Check this now, so that we will NOT find the above functions in ncurses.
3840 # That is because we have not set up to link ncurses in lib-src.
3841 # It's better to believe a function is not available
3842 # than to expect to find it in ncurses.
3843 # Also we need tputs and friends to be able to build at all.
3844 AC_MSG_CHECKING([for library containing tputs])
3845 # Run a test program that contains a call to tputs, a call that is
3846 # never executed.  This tests whether a pre-'main' dynamic linker
3847 # works with the library.  It's too much trouble to actually call
3848 # tputs in the test program, due to portability hassles.  When
3849 # cross-compiling, assume the test program will run if it links.
3850 AC_DEFUN([tputs_link_source], [
3851   AC_LANG_SOURCE(
3852      [[extern void tputs (const char *, int, int (*)(int));
3853        int main (int argc, char **argv)
3854        {
3855           if (argc == 10000)
3856             tputs (argv[0], 0, 0);
3857           return 0;
3858        }]])
3859 ])
3860 if test "${opsys}" = "mingw32"; then
3861   msg='none required'
3862 else
3863   # Maybe curses should be tried earlier?
3864   # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
3865   for tputs_library in '' tinfo ncurses terminfo termcap curses; do
3866     OLIBS=$LIBS
3867     if test -z "$tputs_library"; then
3868       LIBS_TERMCAP=
3869       msg='none required'
3870     else
3871       LIBS_TERMCAP=-l$tputs_library
3872       msg=$LIBS_TERMCAP
3873       LIBS="$LIBS_TERMCAP $LIBS"
3874     fi
3875     AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
3876       [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
3877     LIBS=$OLIBS
3878     if test "X$msg" != Xno; then
3879       break
3880     fi
3881   done
3882 fi
3883 AC_MSG_RESULT([$msg])
3884 if test "X$msg" = Xno; then
3885   AC_MSG_ERROR([The required function 'tputs' was not found in any library.
3886 The following libraries were tried (in order):
3887   libtinfo, libncurses, libterminfo, libtermcap, libcurses
3888 Please try installing whichever of these libraries is most appropriate
3889 for your system, together with its header files.
3890 For example, a libncurses-dev(el) or similar package.])
3891 fi
3892
3893 ## Use termcap instead of terminfo?
3894 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
3895 TERMINFO=yes
3896 ## FIXME?  In the cases below where we unconditionally set
3897 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
3898 ## if that was found above to have tputs.
3899 ## Should we use the gnu* logic everywhere?
3900 case "$opsys" in
3901   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
3902   ##  The ncurses library has been moved out of the System framework in
3903   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
3904   ##  option to use it.
3905   darwin) LIBS_TERMCAP="-lncurses" ;;
3906
3907   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
3908
3909   freebsd)
3910     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
3911     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
3912     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
3913 [[#if __FreeBSD_version < 400000
3914 fail;
3915 #endif
3916 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
3917
3918     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
3919
3920     if test $emacs_cv_freebsd_terminfo = yes; then
3921       LIBS_TERMCAP="-lncurses"
3922     else
3923       TERMINFO=no
3924       LIBS_TERMCAP="-ltermcap"
3925     fi
3926     ;;
3927
3928   mingw32)
3929     TERMINFO=no
3930     LIBS_TERMCAP=
3931     ;;
3932
3933   netbsd)
3934     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
3935       TERMINFO=no
3936       LIBS_TERMCAP="-ltermcap"
3937     fi
3938     ;;
3939
3940   openbsd | dragonfly) LIBS_TERMCAP="-lncurses" ;;
3941
3942   ## hpux: Make sure we get select from libc rather than from libcurses
3943   ##  because libcurses on HPUX 10.10 has a broken version of select.
3944   ##  We used to use -lc -lcurses, but this may be cleaner.
3945   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
3946   # set that way, now it uses the default).  Isn't this a contradiction?
3947   hpux*) LIBS_TERMCAP="-ltermcap" ;;
3948
3949 esac
3950
3951 TERMCAP_OBJ=tparam.o
3952 if test $TERMINFO = yes; then
3953   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
3954   TERMCAP_OBJ=terminfo.o
3955 fi
3956 if test "X$LIBS_TERMCAP" = "X-lncurses"; then
3957   AC_DEFINE(USE_NCURSES, 1, [Define to 1 if you use ncurses.])
3958 fi
3959 AC_SUBST(LIBS_TERMCAP)
3960 AC_SUBST(TERMCAP_OBJ)
3961
3962 # GNU/Linux-specific timer functions.
3963 AC_CACHE_CHECK([for timerfd interface], [emacs_cv_have_timerfd],
3964   [AC_COMPILE_IFELSE(
3965      [AC_LANG_PROGRAM([[#include <sys/timerfd.h>
3966                       ]],
3967                       [[timerfd_create (CLOCK_REALTIME,
3968                                         TFD_CLOEXEC | TFD_NONBLOCK);
3969                         timerfd_settime (0, TFD_TIMER_ABSTIME, 0, 0);]])],
3970      [emacs_cv_have_timerfd=yes],
3971      [emacs_cv_have_timerfd=no])])
3972 if test "$emacs_cv_have_timerfd" = yes; then
3973   AC_DEFINE([HAVE_TIMERFD], 1,
3974     [Define to 1 if timerfd functions are supported as in GNU/Linux.])
3975 fi
3976
3977 # Alternate stack for signal handlers.
3978 AC_CACHE_CHECK([whether signals can be handled on alternate stack],
3979                [emacs_cv_alternate_stack],
3980   [AC_COMPILE_IFELSE(
3981      [AC_LANG_PROGRAM([[#include <signal.h>
3982                       ]],
3983                       [[stack_t ss;
3984                         struct sigaction sa;
3985                         ss.ss_sp = malloc (SIGSTKSZ);
3986                         ss.ss_size = SIGSTKSZ;
3987                         sa.sa_flags = SA_SIGINFO | SA_ONSTACK;
3988                         sigaltstack (&ss, 0);
3989                         sigaction (SIGSEGV, &sa, 0);]])],
3990      [emacs_cv_alternate_stack=yes],
3991      [emacs_cv_alternate_stack=no])])
3992
3993 # Do we need the Hesiod library to provide the support routines?
3994 dnl FIXME?  Should we be skipping this on Darwin too?
3995 LIBHESIOD=
3996 LIBRESOLV=
3997 if test "$with_hesiod" != no ; then
3998   # Don't set $LIBS here -- see comments above.  FIXME which comments?
3999   resolv=no
4000   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
4001      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
4002                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
4003   if test "$resolv" = yes ; then
4004     RESOLVLIB=-lresolv
4005   else
4006     RESOLVLIB=
4007   fi
4008   hesiod=no
4009   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
4010         hesiod=yes, :, $RESOLVLIB)])
4011
4012   if test x"$hesiod" = xyes; then
4013     LIBHESIOD=-lhesiod
4014     LIBRESOLV=$RESOLVLIB
4015   fi
4016 fi
4017 AC_SUBST(LIBHESIOD)
4018 AC_SUBST(LIBRESOLV)
4019
4020 # These tell us which Kerberos-related libraries to use.
4021 COM_ERRLIB=
4022 CRYPTOLIB=
4023 KRB5LIB=
4024 DESLIB=
4025 KRB4LIB=
4026
4027 if test "${with_kerberos}" != no; then
4028   OLD_LIBS=$LIBS
4029   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
4030   if test $have_com_err = yes; then
4031     COM_ERRLIB=-lcom_err
4032     LIBS="$COM_ERRLIB $LIBS"
4033   fi
4034   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
4035   if test $have_crypto = yes; then
4036     CRYPTOLIB=-lcrypto
4037     LIBS="$CRYPTOLIB $LIBS"
4038   fi
4039   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
4040   if test $have_k5crypto = yes; then
4041     CRYPTOLIB=-lk5crypto
4042     LIBS="$CRYPTOLIB $LIBS"
4043   fi
4044   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
4045   if test $have_krb5=yes; then
4046     KRB5LIB=-lkrb5
4047     LIBS="$KRB5LIB $LIBS"
4048   fi
4049   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
4050   if test "${with_kerberos5}" = no; then
4051     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
4052     if test $have_des425 = yes; then
4053       DESLIB=-ldes425
4054       LIBS="$DESLIB $LIBS"
4055     else
4056       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
4057       if test $have_des = yes; then
4058         DESLIB=-ldes
4059         LIBS="$DESLIB $LIBS"
4060       fi
4061     fi
4062     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
4063     if test $have_krb4 = yes; then
4064       KRB4LIB=-lkrb4
4065       LIBS="$KRB4LIB $LIBS"
4066     else
4067       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
4068       if test $have_krb = yes; then
4069         KRB4LIB=-lkrb
4070         LIBS="$KRB4LIB $LIBS"
4071       fi
4072     fi
4073   fi
4074
4075   if test "${with_kerberos5}" != no; then
4076     AC_CHECK_HEADERS(krb5.h,
4077       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
4078                         [#include <krb5.h>])])
4079   else
4080     AC_CHECK_HEADERS(krb.h,,
4081                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
4082                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
4083   fi
4084   AC_CHECK_HEADERS(com_err.h)
4085   LIBS=$OLD_LIBS
4086 fi
4087
4088 AC_SUBST(COM_ERRLIB)
4089 AC_SUBST(CRYPTOLIB)
4090 AC_SUBST(KRB5LIB)
4091 AC_SUBST(DESLIB)
4092 AC_SUBST(KRB4LIB)
4093
4094 AC_CHECK_HEADERS(valgrind/valgrind.h)
4095
4096 AC_CHECK_MEMBERS([struct unipair.unicode], [], [], [[#include <linux/kd.h>]])
4097
4098 AC_CHECK_FUNCS_ONCE(tzset)
4099
4100 ok_so_far=yes
4101 AC_CHECK_FUNC(socket, , ok_so_far=no)
4102 if test $ok_so_far = yes; then
4103   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
4104 fi
4105 if test $ok_so_far = yes; then
4106   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
4107 fi
4108 if test $ok_so_far = yes; then
4109 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
4110   AC_DEFINE(HAVE_INET_SOCKETS, 1,
4111             [Define to 1 if you have inet sockets.])
4112 fi
4113
4114 AC_FUNC_FORK
4115
4116 AC_CHECK_FUNCS(snprintf)
4117
4118 dnl Check for glib.  This differs from other library checks in that
4119 dnl Emacs need not link to glib unless some other library is already
4120 dnl linking to glib.  Although glib provides no facilities that Emacs
4121 dnl needs for its own purposes, when glib is present Emacs needs to
4122 dnl use primitives like g_main_context_query to avoid clashing with
4123 dnl glib at a low level.
4124 dnl
4125 dnl Check this late, since it depends on $GTK_CFLAGS etc.
4126 XGSELOBJ=
4127 OLDCFLAGS="$CFLAGS"
4128 OLDLIBS="$LIBS"
4129 CFLAGS="$CFLAGS $GTK_CFLAGS $RSVG_CFLAGS $DBUS_CFLAGS $SETTINGS_CFLAGS"
4130 LIBS="$LIBS $GTK_LIBS $RSVG_LIBS $DBUS_LIBS $SETTINGS_LIBS"
4131 CFLAGS="$CFLAGS $NOTIFY_CFLAGS $CAIRO_CFLAGS"
4132 LIBS="$LIBS $NOTIFY_LIBS $CAIRO_LIBS"
4133 AC_MSG_CHECKING([whether GLib is linked in])
4134 AC_LINK_IFELSE([AC_LANG_PROGRAM(
4135         [[#include <glib.h>
4136         ]],
4137         [[g_print ("Hello world");]])],
4138      [links_glib=yes],
4139      [links_glib=no])
4140 AC_MSG_RESULT([$links_glib])
4141 if test "${links_glib}" = "yes"; then
4142   AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if GLib is linked in.])
4143   if test "$HAVE_NS" = no;then
4144     XGSELOBJ=xgselect.o
4145   fi
4146 fi
4147 CFLAGS="$OLDCFLAGS"
4148 LIBS="$OLDLIBS"
4149 AC_SUBST(XGSELOBJ)
4150
4151 dnl Adapted from Haible's version.
4152 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
4153   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
4154     [[char* cs = nl_langinfo(CODESET);]])],
4155     emacs_cv_langinfo_codeset=yes,
4156     emacs_cv_langinfo_codeset=no)
4157   ])
4158 if test $emacs_cv_langinfo_codeset = yes; then
4159   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
4160     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
4161 fi
4162
4163 AC_TYPE_MBSTATE_T
4164
4165 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
4166 dnl how the tty code is related to POSIX and/or other versions of termios.
4167 dnl The following looks like a useful start.
4168 dnl
4169 dnl AC_SYS_POSIX_TERMIOS
4170 dnl if test $ac_cv_sys_posix_termios = yes; then
4171 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
4172 dnl                                and macros for terminal control.])
4173 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
4174 dnl fi
4175
4176 dnl Turned on June 1996 supposing nobody will mind it.
4177 dnl MinGW emulates passwd database, so this feature doesn't make sense there.
4178 if test "${opsys}" != "mingw32"; then
4179    AC_DEFINE(AMPERSAND_FULL_NAME, 1, [Define to use the convention that &
4180      in the full name stands for the login id.])
4181 fi
4182
4183 dnl Everybody supports this, except MS.
4184 dnl Seems like the kind of thing we should be testing for, though.
4185 ## Note: PTYs are broken on darwin <6.  Use at your own risk.
4186 if test "${opsys}" != "mingw32"; then
4187   AC_DEFINE(HAVE_PTYS, 1, [Define if the system supports pty devices.])
4188 fi
4189
4190 dnl Everybody supports this, except MS-DOS.
4191 dnl Seems like the kind of thing we should be testing for, though.
4192 dnl Compare with HAVE_INET_SOCKETS (which is unused...) above.
4193 AC_DEFINE(HAVE_SOCKETS, 1, [Define if the system supports
4194   4.2-compatible sockets.])
4195
4196 AH_TEMPLATE(INTERNAL_TERMINAL, [This is substituted when $TERM is "internal".])
4197
4198 AH_TEMPLATE(NULL_DEVICE, [Name of the file to open to get
4199   a null file, or a data sink.])
4200 if test "${opsys}" = "mingw32"; then
4201   AC_DEFINE(NULL_DEVICE, ["NUL:"])
4202 else
4203   AC_DEFINE(NULL_DEVICE, ["/dev/null"])
4204 fi
4205
4206 if test "${opsys}" = "mingw32"; then
4207   SEPCHAR=';'
4208 else
4209   SEPCHAR=':'
4210 fi
4211 AC_DEFINE_UNQUOTED(SEPCHAR, ['$SEPCHAR'], [Character that separates PATH elements.])
4212 dnl This is for MinGW, and is used in test/Makefile.in.
4213 dnl The MSYS Bash has heuristics for replacing ':' with ';' when it
4214 dnl decides that a command-line argument to be passed to a MinGW program
4215 dnl is a PATH-style list of directories.  But that heuristics plays it
4216 dnl safe, and only does the replacement when it is _absolutely_ sure it
4217 dnl sees a colon-separated list of file names; e.g. ":." is left alone,
4218 dnl which breaks in-tree builds.  So we do this manually instead.
4219 dnl Note that we cannot rely on PATH_SEPARATOR, as that one will always
4220 dnl be computed as ':' in MSYS Bash.
4221 AC_SUBST(SEPCHAR)
4222
4223 dnl Everybody supports this, except MS-DOS.
4224 AC_DEFINE(subprocesses, 1, [Define to enable asynchronous subprocesses.])
4225
4226 AC_DEFINE(USER_FULL_NAME, [pw->pw_gecos], [How to get a user's full name.])
4227
4228
4229 AC_DEFINE(DIRECTORY_SEP, ['/'],
4230   [Character that separates directories in a file name.])
4231
4232 if test "${opsys}" = "mingw32"; then
4233   AC_DEFINE(IS_DEVICE_SEP(_c_), [((_c_) == ':')],
4234     [Returns true if character is a device separator.])
4235
4236   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == '/' || (_c_) == '\\')],
4237     [Returns true if character is a directory separator.])
4238
4239   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_) || IS_DEVICE_SEP(_c_))],
4240     [Returns true if character is any form of separator.])
4241 else
4242   AC_DEFINE(IS_DEVICE_SEP(_c_), 0,
4243     [Returns true if character is a device separator.])
4244
4245   AC_DEFINE(IS_DIRECTORY_SEP(_c_), [((_c_) == DIRECTORY_SEP)],
4246     [Returns true if character is a directory separator.])
4247
4248   AC_DEFINE(IS_ANY_SEP(_c_), [(IS_DIRECTORY_SEP (_c_))],
4249     [Returns true if character is any form of separator.])
4250 fi
4251
4252 AH_TEMPLATE(NO_EDITRES, [Define if XEditRes should not be used.])
4253
4254 case $opsys in
4255   aix4-2)
4256     dnl Unfortunately without libXmu we cannot support EditRes.
4257     if test "x$ac_cv_search_XmuConvertStandardSelection" = xno; then
4258       AC_DEFINE(NO_EDITRES, 1)
4259     fi
4260     ;;
4261
4262   hpux*)
4263     dnl Assar Westerlund <assar@sics.se> says this is necessary for
4264     dnl HP-UX 10.20, and that it works for HP-UX 0 as well.
4265     AC_DEFINE(NO_EDITRES, 1)
4266     ;;
4267 esac
4268
4269
4270 case $opsys in
4271   sol2* | unixware )
4272     dnl Some SVr4s don't define NSIG in sys/signal.h for ANSI environments;
4273     dnl instead, there's a system variable _sys_nsig.  Unfortunately, we
4274     dnl need the constant to dimension an array.  So wire in the appropriate
4275     dnl value here.
4276     AC_DEFINE(NSIG_MINIMUM, 32, [Minimum value of NSIG.])
4277     ;;
4278 esac
4279
4280 emacs_broken_SIGIO=no
4281
4282 case $opsys in
4283   dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
4284   dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
4285   hpux* | nacl | openbsd | sol2* | unixware )
4286     emacs_broken_SIGIO=yes
4287     ;;
4288
4289   aix4-2)
4290     dnl On AIX Emacs uses the gmalloc.c malloc implementation.  But given
4291     dnl the way this system works, libc functions that return malloced
4292     dnl memory use the libc malloc implementation. Calling xfree or
4293     dnl xrealloc on the results of such functions results in a crash.
4294     dnl
4295     dnl One solution for this could be to define SYSTEM_MALLOC in configure,
4296     dnl but that does not currently work on this system.
4297     dnl
4298     dnl It is possible to completely override the malloc implementation on
4299     dnl AIX, but that involves putting the malloc functions in a shared
4300     dnl library and setting the MALLOCTYPE environment variable to point to
4301     dnl that shared library.
4302     dnl
4303     dnl Emacs currently calls xrealloc on the results of get_current_dir name,
4304     dnl to avoid a crash just use the Emacs implementation for that function.
4305     dnl
4306     dnl FIXME We could change the AC_CHECK_FUNCS call near the start
4307     dnl of this file, so that we do not check for get_current_dir_name
4308     dnl on AIX.  But that might be fragile if something else ends
4309     dnl up testing for get_current_dir_name as a dependency.
4310     AC_DEFINE(BROKEN_GET_CURRENT_DIR_NAME, 1, [Define if
4311       get_current_dir_name should not be used.])
4312     ;;
4313
4314   freebsd)
4315     dnl Circumvent a bug in FreeBSD.  In the following sequence of
4316     dnl writes/reads on a PTY, read(2) returns bogus data:
4317     dnl
4318     dnl write(2)  1022 bytes
4319     dnl write(2)   954 bytes, get EAGAIN
4320     dnl read(2)   1024 bytes in process_read_output
4321     dnl read(2)     11 bytes in process_read_output
4322     dnl
4323     dnl That is, read(2) returns more bytes than have ever been written
4324     dnl successfully.  The 1033 bytes read are the 1022 bytes written
4325     dnl successfully after processing (for example with CRs added if the
4326     dnl terminal is set up that way which it is here).  The same bytes will
4327     dnl be seen again in a later read(2), without the CRs.
4328     AC_DEFINE(BROKEN_PTY_READ_AFTER_EAGAIN, 1, [Define on FreeBSD to
4329       work around an issue when reading from a PTY.])
4330     ;;
4331 esac
4332
4333 case $opsys in
4334   gnu-* | sol2-10 )
4335     dnl FIXME Can't we test if this exists (eg /proc/$$)?
4336     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
4337   ;;
4338 esac
4339
4340 case $opsys in
4341   darwin | dragonfly | freebsd | netbsd | openbsd )
4342     AC_DEFINE(DONT_REOPEN_PTY, 1, [Define if process.c does not need to
4343       close a pty to make it a controlling terminal (it is already a
4344       controlling terminal of the subprocess, because we did ioctl TIOCSCTTY).])
4345   ;;
4346 esac
4347
4348 dnl FIXME Surely we can test for this rather than hard-code it.
4349 case $opsys in
4350   netbsd | openbsd) sound_device="/dev/audio" ;;
4351   *) sound_device="/dev/dsp" ;;
4352 esac
4353
4354 dnl Used in sound.c
4355 AC_DEFINE_UNQUOTED(DEFAULT_SOUND_DEVICE, "$sound_device",
4356   [Name of the default sound device.])
4357
4358
4359 dnl Emacs can read input using SIGIO and buffering characters itself,
4360 dnl or using CBREAK mode and making C-g cause SIGINT.
4361 dnl The choice is controlled by the variable interrupt_input.
4362 dnl
4363 dnl Define INTERRUPT_INPUT to make interrupt_input = 1 the default (use SIGIO)
4364 dnl
4365 dnl Emacs uses the presence of the USABLE_SIGIO macro
4366 dnl to indicate whether or not signal-driven I/O is possible.  It uses
4367 dnl INTERRUPT_INPUT to decide whether to use it by default.
4368 dnl
4369 dnl SIGIO can be used only on systems that implement it (4.2 and 4.3).
4370 dnl CBREAK mode has two disadvantages
4371 dnl 1) At least in 4.2, it is impossible to handle the Meta key properly.
4372 dnl I hear that in system V this problem does not exist.
4373 dnl 2) Control-G causes output to be discarded.
4374 dnl I do not know whether this can be fixed in system V.
4375 dnl
4376 dnl Another method of doing input is planned but not implemented.
4377 dnl It would have Emacs fork off a separate process
4378 dnl to read the input and send it to the true Emacs process
4379 dnl through a pipe.
4380 case $opsys in
4381   darwin | gnu-linux | gnu-kfreebsd )
4382     AC_DEFINE(INTERRUPT_INPUT, 1, [Define to read input using SIGIO.])
4383   ;;
4384 esac
4385
4386
4387 dnl If the system's imake configuration file defines 'NeedWidePrototypes'
4388 dnl as 'NO', we must define NARROWPROTO manually.  Such a define is
4389 dnl generated in the Makefile generated by 'xmkmf'.  If we don't define
4390 dnl NARROWPROTO, we will see the wrong function prototypes for X functions
4391 dnl taking float or double parameters.
4392 case $opsys in
4393   cygwin|gnu|gnu-linux|gnu-kfreebsd|freebsd|netbsd|openbsd)
4394     AC_DEFINE(NARROWPROTO, 1, [Define if system's imake configuration
4395       file defines 'NeedWidePrototypes' as 'NO'.])
4396   ;;
4397 esac
4398
4399
4400 dnl Used in process.c, this must be a loop, even if it only runs once.
4401 AH_TEMPLATE(PTY_ITERATION, [How to iterate over PTYs.])
4402 dnl Only used if !PTY_ITERATION.  Iterate from FIRST_PTY_LETTER to z,
4403 dnl trying suffixes 0-16.
4404 AH_TEMPLATE(FIRST_PTY_LETTER, [Letter to use in finding device name of
4405   first PTY, if PTYs are supported.])
4406 AH_TEMPLATE(PTY_OPEN, [How to open a PTY, if non-standard.])
4407 AH_TEMPLATE(PTY_NAME_SPRINTF, [How to get the device name of the control
4408   end of a PTY, if non-standard.])
4409 AH_TEMPLATE(PTY_TTY_NAME_SPRINTF, [How to get device name of the tty
4410   end of a PTY, if non-standard.])
4411
4412 case $opsys in
4413   aix4-2 )
4414     AC_DEFINE(PTY_ITERATION, [int c; for (c = 0; !c ; c++)])
4415     dnl You allocate a pty by opening /dev/ptc to get the master side.
4416     dnl To get the name of the slave side, you just ttyname() the master side.
4417     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
4418     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
4419     ;;
4420
4421   cygwin )
4422     AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4423     dnl multi-line AC_DEFINEs are hard. :(
4424     AC_DEFINE(PTY_OPEN, [ do { int dummy; sigset_t blocked, procmask; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, &procmask); if (-1 == openpty (&fd, &dummy, pty_name, 0, 0)) fd = -1; pthread_sigmask (SIG_SETMASK, &procmask, 0); if (fd >= 0) emacs_close (dummy); } while (false)])
4425     AC_DEFINE(PTY_NAME_SPRINTF, [])
4426     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [])
4427     ;;
4428
4429   gnu | openbsd )
4430     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4431     ;;
4432
4433   gnu-linux | gnu-kfreebsd | dragonfly | freebsd | netbsd | darwin | nacl )
4434     dnl if HAVE_GRANTPT
4435     if test "x$ac_cv_func_grantpt" = xyes; then
4436       AC_DEFINE(UNIX98_PTYS, 1, [Define if the system has Unix98 PTYs.])
4437       AC_DEFINE(PTY_ITERATION, [int i; for (i = 0; i < 1; i++)])
4438       dnl Note that grantpt and unlockpt may fork.  We must block SIGCHLD
4439       dnl to prevent sigchld_handler from intercepting the child's death.
4440       AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptyname = 0; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); if (grantpt (fd) != -1 && unlockpt (fd) != -1) ptyname = ptsname(fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (!ptyname) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4441       dnl if HAVE_POSIX_OPENPT
4442       if test "x$ac_cv_func_posix_openpt" = xyes; then
4443         AC_DEFINE(PTY_OPEN, [do { fd = posix_openpt (O_RDWR | O_CLOEXEC | O_NOCTTY); if (fd < 0 && errno == EINVAL) fd = posix_openpt (O_RDWR | O_NOCTTY); } while (false)])
4444         AC_DEFINE(PTY_NAME_SPRINTF, [])
4445       dnl if HAVE_GETPT
4446       elif test "x$ac_cv_func_getpt" = xyes; then
4447         AC_DEFINE(PTY_OPEN, [fd = getpt ()])
4448         AC_DEFINE(PTY_NAME_SPRINTF, [])
4449       else
4450         AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4451       fi
4452     else
4453       AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4454     fi
4455     ;;
4456
4457   hpux*)
4458     AC_DEFINE(FIRST_PTY_LETTER, ['p'])
4459     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
4460     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
4461     ;;
4462
4463   sol2* )
4464     dnl On SysVr4, grantpt(3) forks a subprocess, so do not use
4465     dnl O_CLOEXEC when opening the pty, and keep the SIGCHLD handler
4466     dnl from intercepting that death.  If any child but grantpt's should die
4467     dnl within, it should be caught after sigrelse(2).
4468     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4469     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1 || unlockpt (fd) == -1 || !(ptyname = ptsname (fd))) { emacs_close (fd); return -1; } snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4470     ;;
4471
4472   unixware )
4473     dnl Comments are as per sol2*.
4474     AC_DEFINE(PTY_OPEN, [fd = open (pty_name, O_RDWR | O_NONBLOCK)])
4475     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [{ char *ptsname (int), *ptyname; int grantpt_result; sigset_t blocked; sigemptyset (&blocked); sigaddset (&blocked, SIGCHLD); pthread_sigmask (SIG_BLOCK, &blocked, 0); grantpt_result = grantpt (fd); pthread_sigmask (SIG_UNBLOCK, &blocked, 0); if (grantpt_result == -1) fatal("could not grant slave pty"); if (unlockpt(fd) == -1) fatal("could not unlock slave pty"); if (!(ptyname = ptsname(fd))) fatal ("could not enable slave pty"); snprintf (pty_name, PTY_NAME_SIZE, "%s", ptyname); }])
4476     ;;
4477 esac
4478
4479
4480 case $opsys in
4481   sol2* | unixware )
4482     dnl This change means that we don't loop through allocate_pty too
4483     dnl many times in the (rare) event of a failure.
4484     AC_DEFINE(FIRST_PTY_LETTER, ['z'])
4485     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptmx");])
4486     dnl Push various streams modules onto a PTY channel.  Used in process.c.
4487     AC_DEFINE(SETUP_SLAVE_PTY, [if (ioctl (forkin, I_PUSH, "ptem") == -1) fatal ("ioctl I_PUSH ptem"); if (ioctl (forkin, I_PUSH, "ldterm") == -1) fatal ("ioctl I_PUSH ldterm"); if (ioctl (forkin, I_PUSH, "ttcompat") == -1) fatal ("ioctl I_PUSH ttcompat");], [How to set up a slave PTY, if needed.])
4488     ;;
4489 esac
4490
4491
4492 AH_TEMPLATE(SIGNALS_VIA_CHARACTERS, [Make process_send_signal work by
4493 "typing" a signal character on the pty.])
4494
4495 case $opsys in
4496   dnl Perry Smith <pedz@ddivt1.austin.ibm.com> says this is correct for AIX.
4497   aix4-2 | cygwin | gnu | dragonfly | freebsd | netbsd | openbsd | darwin )
4498     AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4499     ;;
4500
4501   dnl 21 Jun 06: Eric Hanchrow <offby1@blarg.net> says this works.
4502   dnl FIXME Does gnu-kfreebsd have linux/version.h?  It seems unlikely...
4503   gnu-linux | gnu-kfreebsd )
4504
4505     AC_MSG_CHECKING([for signals via characters])
4506     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4507 #include <linux/version.h>
4508 #if LINUX_VERSION_CODE < 0x20400
4509 # error "Linux version too old"
4510 #endif
4511       ]], [[]])], emacs_signals_via_chars=yes, emacs_signals_via_chars=no)
4512
4513     AC_MSG_RESULT([$emacs_signals_via_chars])
4514     test $emacs_signals_via_chars = yes && AC_DEFINE(SIGNALS_VIA_CHARACTERS, 1)
4515     ;;
4516 esac
4517
4518
4519 AH_TEMPLATE(TAB3, [Undocumented.])
4520
4521 case $opsys in
4522   darwin) AC_DEFINE(TAB3, OXTABS) ;;
4523
4524   gnu | dragonfly | freebsd | netbsd | openbsd )
4525     AC_DEFINE(TABDLY, OXTABS, [Undocumented.])
4526     AC_DEFINE(TAB3, OXTABS)
4527     ;;
4528
4529   gnu-linux | gnu-kfreebsd )
4530     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4531 #ifndef __ia64__
4532 # error "not ia64"
4533 #endif
4534       ]], [[]])], AC_DEFINE(GC_MARK_SECONDARY_STACK(),
4535         [do { extern void *__libc_ia64_register_backing_store_base; __builtin_ia64_flushrs (); mark_memory (__libc_ia64_register_backing_store_base, __builtin_ia64_bsp ());} while (false)],
4536         [Mark a secondary stack, like the register stack on the ia64.]), [])
4537     ;;
4538
4539   hpux*)
4540     AC_DEFINE(RUN_TIME_REMAP, 1, [Define if emacs.c needs to call
4541       run_time_remap; for HPUX.])
4542     ;;
4543 esac
4544
4545
4546 dnl This won't be used automatically yet.  We also need to know, at least,
4547 dnl that the stack is continuous.
4548 AH_TEMPLATE(GC_SETJMP_WORKS, [Define if setjmp is known to save all
4549   registers relevant for conservative garbage collection in the jmp_buf.])
4550
4551
4552 case $opsys in
4553   dnl Not all the architectures are tested, but there are Debian packages
4554   dnl for SCM and/or Guile on them, so the technique must work.  See also
4555   dnl comments in alloc.c concerning setjmp and gcc.
4556   dnl Fixme: it's probably safe to just use the GCC conditional below.
4557   gnu-linux | gnu-kfreebsd )
4558     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4559 #if defined __i386__ || defined __sparc__ || defined __mc68000__ \
4560   || defined __alpha__ || defined __mips__ || defined __s390__ \
4561   || defined __arm__ || defined __powerpc__ || defined __amd64__ \
4562   || defined __ia64__ || defined __sh__
4563 /* ok */
4564 #else
4565 # error "setjmp not known to work on this arch"
4566 #endif
4567     ]], [[]])], AC_DEFINE(GC_SETJMP_WORKS, 1))
4568     ;;
4569 esac
4570
4571
4572 if test x$GCC = xyes; then
4573    dnl GC_SETJMP_WORKS is nearly always appropriate for GCC.
4574    AC_DEFINE(GC_SETJMP_WORKS, 1)
4575 else
4576   case $opsys in
4577     aix* | dragonfly | freebsd | netbsd | openbsd | sol2* )
4578       AC_DEFINE(GC_SETJMP_WORKS, 1)
4579       ;;
4580   esac
4581 fi                              dnl GCC?
4582
4583 dnl In a weird quirk, MS runtime uses _setjmp and longjmp.
4584 AC_CACHE_CHECK([for _setjmp], [emacs_cv_func__setjmp],
4585   [AC_LINK_IFELSE(
4586      [AC_LANG_PROGRAM(
4587        [[#include <setjmp.h>
4588          #ifdef __MINGW32__
4589          # define _longjmp longjmp
4590          #endif
4591        ]],
4592        [[jmp_buf j;
4593          if (! _setjmp (j))
4594            _longjmp (j, 1);]])],
4595      [emacs_cv_func__setjmp=yes],
4596      [emacs_cv_func__setjmp=no])])
4597 if test $emacs_cv_func__setjmp = yes; then
4598   AC_DEFINE([HAVE__SETJMP], 1, [Define to 1 if _setjmp and _longjmp work.])
4599 fi
4600
4601 # We need to preserve signal mask to handle C stack overflows.
4602 AC_CACHE_CHECK([for sigsetjmp], [emacs_cv_func_sigsetjmp],
4603   [AC_LINK_IFELSE(
4604      [AC_LANG_PROGRAM(
4605        [[#include <setjmp.h>
4606        ]],
4607        [[sigjmp_buf j;
4608          if (! sigsetjmp (j, 1))
4609            siglongjmp (j, 1);]])],
4610      [emacs_cv_func_sigsetjmp=yes],
4611      [emacs_cv_func_sigsetjmp=no])])
4612 if test $emacs_cv_func_sigsetjmp = yes; then
4613   AC_DEFINE([HAVE_SIGSETJMP], 1,
4614     [Define to 1 if sigsetjmp and siglongjmp work.])
4615 fi
4616
4617 case $emacs_cv_func_sigsetjmp,$emacs_cv_alternate_stack,$opsys in
4618   yes,yes,* | *,*,mingw32)
4619     AC_DEFINE([HAVE_STACK_OVERFLOW_HANDLING], 1,
4620       [Define to 1 if C stack overflow can be handled in some cases.]);;
4621 esac
4622
4623 case $opsys in
4624   sol2* | unixware )
4625     dnl TIOCGPGRP is broken in SysVr4, so we can't send signals to PTY
4626     dnl subprocesses the usual way.  But TIOCSIGNAL does work for PTYs,
4627     dnl and this is all we need.
4628     AC_DEFINE(TIOCSIGSEND, TIOCSIGNAL, [Some platforms redefine this.])
4629     ;;
4630 esac
4631
4632
4633 case $opsys in
4634   hpux* | sol2* )
4635     dnl Used in xfaces.c.
4636     AC_DEFINE(XOS_NEEDS_TIME_H, 1, [Compensate for a bug in Xos.h on
4637       some systems, where it requires time.h.])
4638     ;;
4639 esac
4640
4641
4642 dnl Define symbols to identify the version of Unix this is.
4643 dnl Define all the symbols that apply correctly.
4644 AH_TEMPLATE(DOS_NT, [Define if the system is MS DOS or MS Windows.])
4645 AH_TEMPLATE(MSDOS, [Define if the system is MS DOS.])
4646 AH_TEMPLATE(USG, [Define if the system is compatible with System III.])
4647 AH_TEMPLATE(USG5_4, [Define if the system is compatible with System V Release 4.])
4648
4649 case $opsys in
4650   aix4-2)
4651     AC_DEFINE(USG, [])
4652     dnl This symbol should be defined on AIX Version 3  ???????
4653     AC_PREPROC_IFELSE([AC_LANG_PROGRAM([[
4654 #ifndef _AIX
4655 # error "_AIX not defined"
4656 #endif
4657     ]], [[]])], [], AC_DEFINE(_AIX, [], [Define if the system is AIX.]))
4658     ;;
4659
4660   cygwin)
4661     AC_DEFINE(CYGWIN, 1, [Define if the system is Cygwin.])
4662     ;;
4663
4664   darwin)
4665     dnl Not __APPLE__, as this may not be defined on non-OSX Darwin.
4666     dnl Not DARWIN, because Panther and lower CoreFoundation.h use DARWIN to
4667     dnl distinguish OS X from pure Darwin.
4668     AC_DEFINE(DARWIN_OS, [], [Define if the system is Darwin.])
4669     ;;
4670
4671   gnu-linux | gnu-kfreebsd )
4672     AC_DEFINE(USG, [])
4673     AC_DEFINE(GNU_LINUX, [], [Define if ths system is compatible with GNU/Linux.])
4674     ;;
4675
4676   hpux*)
4677     AC_DEFINE(USG, [])
4678     AC_DEFINE(HPUX, [], [Define if the system is HPUX.])
4679     ;;
4680
4681   mingw32)
4682     AC_DEFINE(DOS_NT, [])
4683     AC_DEFINE(WINDOWSNT, 1, [Define if compiling for native MS Windows.])
4684     if test "x$ac_enable_checking" != "x" ; then
4685       AC_DEFINE(EMACSDEBUG, 1, [Define to 1 to enable w32 debug facilities.])
4686     fi
4687     ;;
4688
4689   sol2*)
4690     AC_DEFINE(USG, [])
4691     AC_DEFINE(USG5_4, [])
4692     AC_DEFINE(SOLARIS2, [], [Define if the system is Solaris.])
4693     ;;
4694
4695   unixware)
4696     AC_DEFINE(USG, [])
4697     AC_DEFINE(USG5_4, [])
4698     ;;
4699 esac
4700
4701 AC_CACHE_CHECK([for usable FIONREAD], [emacs_cv_usable_FIONREAD],
4702   [case $opsys in
4703      aix4-2 | nacl)
4704        dnl BUILD 9008 - FIONREAD problem still exists in X-Windows.
4705        emacs_cv_usable_FIONREAD=no
4706        ;;
4707
4708      mingw32)
4709        emacs_cv_usable_FIONREAD=yes
4710        ;;
4711
4712      *)
4713        AC_COMPILE_IFELSE(
4714          [AC_LANG_PROGRAM([[#include <sys/types.h>
4715                             #include <sys/ioctl.h>
4716                             #ifdef USG5_4
4717                             # include <sys/filio.h>
4718                             #endif
4719                           ]],
4720                           [[int foo = ioctl (0, FIONREAD, &foo);]])],
4721          [emacs_cv_usable_FIONREAD=yes],
4722          [emacs_cv_usable_FIONREAD=no])
4723        ;;
4724    esac])
4725 if test $emacs_cv_usable_FIONREAD = yes; then
4726   AC_DEFINE([USABLE_FIONREAD], [1], [Define to 1 if FIONREAD is usable.])
4727
4728   if test $emacs_broken_SIGIO = no; then
4729     AC_CACHE_CHECK([for usable SIGIO], [emacs_cv_usable_SIGIO],
4730       [AC_COMPILE_IFELSE(
4731          [AC_LANG_PROGRAM([[#include <fcntl.h>
4732                             #include <signal.h>
4733                           ]],
4734                           [[int foo = SIGIO | F_SETFL | FASYNC;]])],
4735          [emacs_cv_usable_SIGIO=yes],
4736          [emacs_cv_usable_SIGIO=no])],
4737       [emacs_cv_usable_SIGIO=yes],
4738       [emacs_cv_usable_SIGIO=no])
4739     if test $emacs_cv_usable_SIGIO = yes; then
4740       AC_DEFINE([USABLE_SIGIO], [1], [Define to 1 if SIGIO is usable.])
4741     fi
4742   fi
4743 fi
4744
4745 case $opsys in
4746   hpux11)
4747     dnl It works to open the pty's tty in the parent (Emacs), then
4748     dnl close and reopen it in the child.
4749     AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
4750       works to open a pty's tty in the parent process, then close and
4751       reopen it in the child.])
4752     ;;
4753
4754   sol2-10)
4755     AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
4756       on Solaris.])
4757     ;;
4758 esac
4759
4760 # Set up the CFLAGS for real compilation, so we can substitute it.
4761 CFLAGS="$REAL_CFLAGS"
4762 CPPFLAGS="$REAL_CPPFLAGS"
4763 LIBS="$REAL_LIBS"
4764
4765 ## Hack to detect a buggy GCC version.
4766 if test "$GCC" = yes && \
4767    $CC --version 2> /dev/null | grep 'gcc.* 4.5.0' >/dev/null; then
4768   case $CFLAGS in
4769     *-fno-optimize-sibling-calls*) ;;
4770     *-O@<:@23@:>@*)
4771       AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS.]);;
4772   esac
4773 fi
4774
4775 version=$PACKAGE_VERSION
4776
4777 copyright="Copyright (C) 2016 Free Software Foundation, Inc."
4778 AC_DEFINE_UNQUOTED(COPYRIGHT, ["$copyright"],
4779   [Short copyright string for this version of Emacs.])
4780 AC_SUBST(copyright)
4781
4782 ### Specify what sort of things we'll be editing into Makefile and config.h.
4783 ### Use configuration here uncanonicalized to avoid exceeding size limits.
4784 AC_SUBST(version)
4785 AC_SUBST(configuration)
4786 ## Unused?
4787 AC_SUBST(canonical)
4788 AC_SUBST(srcdir)
4789 AC_SUBST(prefix)
4790 AC_SUBST(exec_prefix)
4791 AC_SUBST(bindir)
4792 AC_SUBST(datadir)
4793 AC_SUBST(sharedstatedir)
4794 AC_SUBST(libexecdir)
4795 AC_SUBST(mandir)
4796 AC_SUBST(infodir)
4797 AC_SUBST(lispdir)
4798 AC_SUBST(standardlisppath)
4799 AC_SUBST(locallisppath)
4800 AC_SUBST(lisppath)
4801 AC_SUBST(x_default_search_path)
4802 AC_SUBST(etcdir)
4803 AC_SUBST(archlibdir)
4804 AC_SUBST(etcdocdir)
4805 AC_SUBST(bitmapdir)
4806 AC_SUBST(gamedir)
4807 AC_SUBST(gameuser)
4808 AC_SUBST(gamegroup)
4809 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
4810 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
4811 ## end of LIBX_BASE, but nothing ever set it.
4812 AC_SUBST(LD_SWITCH_X_SITE)
4813 AC_SUBST(C_SWITCH_X_SITE)
4814 AC_SUBST(GNUSTEP_CFLAGS)
4815 AC_SUBST(CFLAGS)
4816 ## Used in lwlib/Makefile.in.
4817 AC_SUBST(X_TOOLKIT_TYPE)
4818 AC_SUBST(ns_appdir)
4819 AC_SUBST(ns_appbindir)
4820 AC_SUBST(ns_appresdir)
4821 AC_SUBST(ns_appsrc)
4822 AC_SUBST(GNU_OBJC_CFLAGS)
4823 AC_SUBST(OTHER_FILES)
4824
4825 if test -n "${term_header}"; then
4826     AC_DEFINE_UNQUOTED(TERM_HEADER, "${term_header}",
4827         [Define to the header for the built-in window system.])
4828 fi
4829
4830 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
4831                    [Define to the canonical Emacs configuration name.])
4832 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${emacs_config_options}",
4833                    [Define to the options passed to configure.])
4834 AH_TEMPLATE(config_opsysfile, [Some platforms that do not use configure
4835   define this to include extra configuration information.])
4836
4837 case $opsys in
4838   mingw32)
4839     AC_DEFINE(config_opsysfile, <ms-w32.h>, [])
4840     ;;
4841 esac
4842
4843 XMENU_OBJ=
4844 XOBJ=
4845 FONT_OBJ=
4846 if test "${HAVE_X_WINDOWS}" = "yes" ; then
4847   AC_DEFINE(HAVE_X_WINDOWS, 1,
4848             [Define to 1 if you want to use the X window system.])
4849   XMENU_OBJ=xmenu.o
4850   XOBJ="xterm.o xfns.o xselect.o xrdb.o xsmfns.o xsettings.o"
4851   FONT_OBJ=xfont.o
4852   if test "$HAVE_CAIRO" = "yes"; then
4853     FONT_OBJ="ftfont.o ftcrfont.o"
4854   elif test "$HAVE_XFT" = "yes"; then
4855     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
4856   elif test "$HAVE_FREETYPE" = "yes"; then
4857     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
4858   fi
4859   AC_SUBST(FONT_OBJ)
4860 fi
4861 AC_SUBST(XMENU_OBJ)
4862 AC_SUBST(XOBJ)
4863 AC_SUBST(FONT_OBJ)
4864
4865 WIDGET_OBJ=
4866 MOTIF_LIBW=
4867 if test "${USE_X_TOOLKIT}" != "none" ; then
4868   WIDGET_OBJ=widget.o
4869   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
4870   if test "${USE_X_TOOLKIT}" = "LUCID"; then
4871     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
4872   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
4873     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
4874     MOTIF_LIBW=-lXm
4875     case "$opsys" in
4876       gnu-linux)
4877         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
4878         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
4879         ;;
4880
4881       unixware)
4882         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
4883         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
4884         MOTIF_LIBW="MOTIF_LIBW -lXimp"
4885         ;;
4886
4887       aix4-2)
4888         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
4889         MOTIF_LIBW="$MOTIF_LIBW -li18n"
4890         ;;
4891     esac
4892     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
4893   fi
4894 fi
4895 AC_SUBST(WIDGET_OBJ)
4896
4897 TOOLKIT_LIBW=
4898 case "$USE_X_TOOLKIT" in
4899   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
4900   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
4901   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
4902 esac
4903 if test "$HAVE_XWIDGETS" = "yes"; then
4904   TOOLKIT_LIBW="$TOOLKIT_LIBW -lXcomposite"
4905 fi
4906 AC_SUBST(TOOLKIT_LIBW)
4907
4908 if test "${opsys}" != "mingw32"; then
4909   if test "$USE_X_TOOLKIT" = "none"; then
4910     LIBXT_OTHER="\$(LIBXSM)"
4911   else
4912     LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
4913   fi
4914 fi
4915 AC_SUBST(LIBXT_OTHER)
4916
4917 if test "${HAVE_X11}" = "yes" ; then
4918   AC_DEFINE(HAVE_X11, 1,
4919             [Define to 1 if you want to use version 11 of X windows.])
4920   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
4921 else
4922   LIBX_OTHER=
4923 fi
4924 AC_SUBST(LIBX_OTHER)
4925
4926 if test "$HAVE_GTK" = yes || test "$HAVE_X11" != yes; then
4927   LIBXMENU=
4928 elif test "$USE_X_TOOLKIT" = none; then
4929   LIBXMENU='$(oldXMenudir)/libXMenu11.a'
4930 else
4931   LIBXMENU='$(lwlibdir)/liblw.a'
4932 fi
4933 AC_SUBST(LIBXMENU)
4934
4935 AC_CACHE_CHECK([for struct alignment],
4936   [emacs_cv_struct_alignment],
4937   [AC_COMPILE_IFELSE(
4938      [AC_LANG_PROGRAM([[#include <stddef.h>
4939                         struct __attribute__ ((aligned (8))) s { char c; };
4940                         struct t { char c; struct s s; };
4941                         char verify[offsetof (struct t, s) == 8 ? 1 : -1];
4942                       ]])],
4943      [emacs_cv_struct_alignment=yes],
4944      [emacs_cv_struct_alignment=no])])
4945 if test "$emacs_cv_struct_alignment" = yes; then
4946   AC_DEFINE([HAVE_STRUCT_ATTRIBUTE_ALIGNED], 1,
4947     [Define to 1 if 'struct __attribute__ ((aligned (N)))' aligns the
4948      structure to an N-byte boundary.])
4949 fi
4950
4951 if test "${GNU_MALLOC}" = "yes" ; then
4952   AC_DEFINE(GNU_MALLOC, 1,
4953             [Define to 1 if you want to use the GNU memory allocator.])
4954 fi
4955
4956 RALLOC_OBJ=
4957 if test "${REL_ALLOC}" = "yes" ; then
4958   AC_DEFINE(REL_ALLOC, 1,
4959             [Define REL_ALLOC if you want to use the relocating allocator for
4960              buffer space.])
4961
4962   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
4963 fi
4964 AC_SUBST(RALLOC_OBJ)
4965
4966 if test "$opsys" = "cygwin"; then
4967   CYGWIN_OBJ="cygw32.o"
4968   ## Cygwin differs because of its unexec().
4969   PRE_ALLOC_OBJ=
4970   POST_ALLOC_OBJ=lastfile.o
4971 elif test "$opsys" = "mingw32"; then
4972   CYGWIN_OBJ=
4973   PRE_ALLOC_OBJ=
4974   POST_ALLOC_OBJ=lastfile.o
4975 else
4976   CYGWIN_OBJ=
4977   PRE_ALLOC_OBJ=lastfile.o
4978   POST_ALLOC_OBJ=
4979 fi
4980 AC_SUBST(CYGWIN_OBJ)
4981 AC_SUBST(PRE_ALLOC_OBJ)
4982 AC_SUBST(POST_ALLOC_OBJ)
4983
4984 dnl Call this 'FORTIFY_SOUR' so that it sorts before the 'FORTIFY_SOURCE'
4985 dnl verbatim defined above.  The tricky name is apropos, as this hack
4986 dnl makes Fortify go sour!
4987 AH_VERBATIM([FORTIFY_SOUR],
4988 [/* Without the following workaround, Emacs runs slowly on OS X 10.8.
4989    The workaround disables some useful run-time checking, so it
4990    should be conditional to the platforms with the performance bug.
4991    Perhaps Apple will fix this some day; also see m4/extern-inline.m4.  */
4992 #if defined __APPLE__ && defined __GNUC__
4993 # ifndef _DONT_USE_CTYPE_INLINE_
4994 #  define _DONT_USE_CTYPE_INLINE_
4995 # endif
4996 # ifndef _FORTIFY_SOURCE
4997 #  define _FORTIFY_SOURCE 0
4998 # endif
4999 #endif
5000 ])
5001
5002 # If user asks to omit features, disable optional features that gnulib
5003 # might otherwise enable.
5004 if test "$with_features" = no && test "$enable_acl" != yes; then
5005   enable_acl=no
5006 fi
5007
5008 # Configure gnulib.  Although this does not affect CFLAGS or LIBS permanently.
5009 # it temporarily reverts them to their pre-pkg-config values,
5010 # because gnulib needs to work with both src (which uses the
5011 # pkg-config stuff) and lib-src (which does not).  For example, gnulib
5012 # may need to determine whether LIB_CLOCK_GETTIME should contain -lrt,
5013 # and it therefore needs to run in an environment where LIBS does not
5014 # already contain -lrt merely because 'pkg-config --libs' printed '-lrt'
5015 # for some package unrelated to lib-src.
5016 SAVE_CFLAGS=$CFLAGS
5017 SAVE_LIBS=$LIBS
5018 CFLAGS=$pre_PKG_CONFIG_CFLAGS
5019 LIBS="$LIB_PTHREAD $pre_PKG_CONFIG_LIBS"
5020 gl_ASSERT_NO_GNULIB_POSIXCHECK
5021 gl_ASSERT_NO_GNULIB_TESTS
5022 gl_INIT
5023 CFLAGS=$SAVE_CFLAGS
5024 LIBS=$SAVE_LIBS
5025
5026 if test "${opsys}" = "mingw32"; then
5027   CPPFLAGS="$CPPFLAGS -DUSE_CRT_DLL=1 -I \${abs_top_srcdir}/nt/inc"
5028   # Remove unneeded switches from the value of CC that goes to Makefiles
5029   CC=`AS_ECHO(["$CC"]) | sed -e "s,$GCC_TEST_OPTIONS,,"`
5030 fi
5031
5032 case "$opsys" in
5033   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
5034
5035   cygwin) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000" ;;
5036
5037   darwin)
5038    ## The -headerpad option tells ld (see man page) to leave room at the
5039    ## end of the header for adding load commands.  Needed for dumping.
5040    ## 0x1000 is enough for roughly 52 load commands on the x86_64
5041    ## architecture (where they are 78 bytes each). The actual number of
5042    ## load commands added is not consistent but normally ranges from
5043    ## about 14 to about 34. Setting it high gets us plenty of slop and
5044    ## only costs about 1.5K of wasted binary space.
5045    headerpad_extra=1000
5046    if test "$HAVE_NS" = "yes"; then
5047      libs_nsgui="-framework AppKit"
5048      if test "$NS_IMPL_COCOA" = "yes"; then
5049         libs_nsgui="$libs_nsgui -framework IOKit"
5050      fi
5051    else
5052      libs_nsgui=
5053    fi
5054    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
5055
5056    ## This is here because src/Makefile.in did some extra fiddling around
5057    ## with LD_SWITCH_SYSTEM.  It seems cleaner to put this in
5058    ## LD_SWITCH_SYSTEM_TEMACS instead,
5059    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
5060      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
5061    ;;
5062
5063   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
5064   ## find X at run-time.
5065   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
5066   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
5067   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
5068   ## had different values in configure (in ac_link) and src/Makefile.in.
5069   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
5070   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
5071
5072   mingw32)
5073    ## Is it any better under MinGW64 to relocate emacs into higher addresses?
5074    case "$canonical" in
5075      x86_64-*-*) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x400000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5076      *) LD_SWITCH_SYSTEM_TEMACS="-Wl,-stack,0x00800000 -Wl,-heap,0x00100000 -Wl,-image-base,0x01000000 -Wl,-entry,__start -Wl,-Map,./temacs.map" ;;
5077    esac
5078    ;;
5079
5080   *) LD_SWITCH_SYSTEM_TEMACS= ;;
5081 esac
5082
5083 # -nopie fixes a temacs segfault on Gentoo, OpenBSD, and other systems
5084 # with "hardened" GCC configurations for some reason (Bug#18784).
5085 # We don't know why -nopie works, but not segfaulting is better than
5086 # segfaulting.  Use ac_c_werror_flag=yes when trying -nopie, otherwise
5087 # clang keeps warning that it does not understand -nopie, and pre-4.6
5088 # GCC has a similar problem (Bug#20338).
5089 AC_CACHE_CHECK([whether $CC accepts -nopie],
5090   [emacs_cv_prog_cc_nopie],
5091   [emacs_save_c_werror_flag=$ac_c_werror_flag
5092    emacs_save_LDFLAGS=$LDFLAGS
5093    ac_c_werror_flag=yes
5094    LDFLAGS="$LDFLAGS -nopie"
5095    AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
5096      [emacs_cv_prog_cc_nopie=yes],
5097      [emacs_cv_prog_cc_nopie=no])
5098    ac_c_werror_flag=$emacs_save_c_werror_flag
5099    LDFLAGS=$emacs_save_LDFLAGS])
5100 if test "$emacs_cv_prog_cc_nopie" = yes; then
5101   LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -nopie"
5102 fi
5103
5104 if test x$ac_enable_profiling != x ; then
5105   case $opsys in
5106     *freebsd | gnu-linux) ;;
5107     *) LD_SWITCH_SYSTEM_TEMACS="$LD_SWITCH_SYSTEM_TEMACS -pg" ;;
5108   esac
5109 fi
5110
5111 LD_SWITCH_SYSTEM_TEMACS="$LDFLAGS_NOCOMBRELOC $LD_SWITCH_SYSTEM_TEMACS"
5112
5113 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
5114
5115 ## Common for all window systems
5116 if test "$window_system" != "none"; then
5117   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
5118   AC_DEFINE(POLL_FOR_INPUT, 1, [Define if you poll periodically to detect C-g.])
5119   WINDOW_SYSTEM_OBJ="fontset.o fringe.o image.o"
5120 fi
5121
5122 AC_SUBST(WINDOW_SYSTEM_OBJ)
5123
5124 AH_TOP([/* GNU Emacs site configuration template file.
5125
5126 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2016
5127   Free Software Foundation, Inc.
5128
5129 This file is part of GNU Emacs.
5130
5131 GNU Emacs is free software: you can redistribute it and/or modify
5132 it under the terms of the GNU General Public License as published by
5133 the Free Software Foundation, either version 3 of the License, or
5134 (at your option) any later version.
5135
5136 GNU Emacs is distributed in the hope that it will be useful,
5137 but WITHOUT ANY WARRANTY; without even the implied warranty of
5138 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
5139 GNU General Public License for more details.
5140
5141 You should have received a copy of the GNU General Public License
5142 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
5143
5144
5145 /* No code in Emacs #includes config.h twice, but some bits of code
5146    intended to work with other packages as well (like gmalloc.c)
5147    think they can include it as many times as they like.  */
5148 #ifndef EMACS_CONFIG_H
5149 #define EMACS_CONFIG_H
5150 ])dnl
5151
5152 AH_BOTTOM([#include <conf_post.h>
5153
5154 #endif /* EMACS_CONFIG_H */
5155
5156 /*
5157 Local Variables:
5158 mode: c
5159 End:
5160 */
5161 ])dnl
5162
5163 #### Report on what we decided to do.
5164 #### Report GTK as a toolkit, even if it doesn't use Xt.
5165 #### It makes printing result more understandable as using GTK sets
5166 #### toolkit_scroll_bars to yes by default.
5167 if test "${HAVE_GTK}" = "yes"; then
5168   USE_X_TOOLKIT="$USE_GTK_TOOLKIT"
5169 fi
5170
5171 if test $USE_ACL -ne 0; then
5172   ACL_SUMMARY="yes $LIB_ACL"
5173 else
5174   ACL_SUMMARY=no
5175 fi
5176
5177 emacs_standard_dirs='Standard dirs'
5178 AS_ECHO(["
5179 Configured for '${canonical}'.
5180
5181   Where should the build process find the source code?    ${srcdir}
5182   What compiler should emacs be built with?               ${CC} ${CFLAGS}
5183   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
5184   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
5185   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
5186   What window system should Emacs use?                    ${window_system}
5187   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}
5188   Where do we find X Windows header files?                ${x_includes:-$emacs_standard_dirs}
5189   Where do we find X Windows libraries?                   ${x_libraries:-$emacs_standard_dirs}"])
5190
5191 optsep=
5192 emacs_config_features=
5193 for opt in XAW3D XPM JPEG TIFF GIF PNG RSVG CAIRO IMAGEMAGICK SOUND GPM DBUS \
5194   GCONF GSETTINGS NOTIFY ACL LIBSELINUX GNUTLS LIBXML2 FREETYPE M17N_FLT \
5195   LIBOTF XFT ZLIB TOOLKIT_SCROLL_BARS X_TOOLKIT X11 NS MODULES \
5196   XWIDGETS; do
5197
5198     case $opt in
5199       NOTIFY|ACL) eval val=\${${opt}_SUMMARY} ;;
5200       TOOLKIT_SCROLL_BARS|X_TOOLKIT) eval val=\${USE_$opt} ;;
5201       *) eval val=\${HAVE_$opt} ;;
5202     esac
5203     case x$val in
5204       xno|xnone|x) continue ;;
5205     esac
5206     case $opt in
5207       X_TOOLKIT)
5208         case $val in
5209           GTK*|LUCID|MOTIF) opt=$val ;;
5210           *) continue ;;
5211         esac
5212       ;;
5213     esac
5214     AS_VAR_APPEND([emacs_config_features], ["$optsep$opt"])
5215     optsep=' '
5216 done
5217 AC_DEFINE_UNQUOTED(EMACS_CONFIG_FEATURES, "${emacs_config_features}",
5218   [Summary of some of the main features enabled by configure.])
5219
5220 AS_ECHO(["  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}
5221   Does Emacs use -lXpm?                                   ${HAVE_XPM}
5222   Does Emacs use -ljpeg?                                  ${HAVE_JPEG}
5223   Does Emacs use -ltiff?                                  ${HAVE_TIFF}
5224   Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF
5225   Does Emacs use a png library?                           ${HAVE_PNG} $LIBPNG
5226   Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}
5227   Does Emacs use cairo?                                   ${HAVE_CAIRO}
5228   Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}
5229   Does Emacs support sound?                               ${HAVE_SOUND}
5230   Does Emacs use -lgpm?                                   ${HAVE_GPM}
5231   Does Emacs use -ldbus?                                  ${HAVE_DBUS}
5232   Does Emacs use -lgconf?                                 ${HAVE_GCONF}
5233   Does Emacs use GSettings?                               ${HAVE_GSETTINGS}
5234   Does Emacs use a file notification library?             ${NOTIFY_SUMMARY}
5235   Does Emacs use access control lists?                    ${ACL_SUMMARY}
5236   Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}
5237   Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}
5238   Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}
5239   Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}
5240   Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}
5241   Does Emacs use -lotf?                                   ${HAVE_LIBOTF}
5242   Does Emacs use -lxft?                                   ${HAVE_XFT}
5243   Does Emacs directly use zlib?                           ${HAVE_ZLIB}
5244   Does Emacs have dynamic modules support?                ${HAVE_MODULES}
5245   Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}
5246   Does Emacs support Xwidgets (requires gtk3)?            ${HAVE_XWIDGETS}
5247 "])
5248
5249 if test -n "${EMACSDATA}"; then
5250    AS_ECHO(["  Environment variable EMACSDATA set to:                  $EMACSDATA"])
5251 fi
5252 if test -n "${EMACSDOC}"; then
5253    AS_ECHO(["  Environment variable EMACSDOC set to:                   $EMACSDOC"])
5254 fi
5255
5256 echo
5257
5258 if test "$HAVE_NS" = "yes"; then
5259    echo
5260    AS_ECHO(["You must run \"${MAKE-make} install\" in order to test the built application.
5261 The installed application will go to nextstep/Emacs.app and can be
5262 run or moved from there."])
5263    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
5264       echo "The application will be fully self-contained."
5265     else
5266       AS_ECHO(["The lisp resources for the application will be installed under ${prefix}.
5267 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
5268 to run if these resources are not installed."])
5269    fi
5270    echo
5271 fi
5272
5273 if test "${opsys}" = "cygwin"; then
5274   case `uname -r` in
5275     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
5276            echo
5277            ;;
5278   esac
5279 fi
5280
5281 # Remove any trailing slashes in these variables.
5282 case $prefix in
5283   */) prefix=`AS_DIRNAME(["$prefix."])`;;
5284 esac
5285 case $exec_prefix in
5286   */) exec_prefix=`AS_DIRNAME(["$exec_prefix."])`;;
5287 esac
5288
5289 if test "$HAVE_NS" = "yes"; then
5290   if test "$NS_IMPL_GNUSTEP" = yes; then
5291     AC_CONFIG_FILES([nextstep/GNUstep/Emacs.base/Resources/Info-gnustep.plist:nextstep/templates/Info-gnustep.plist.in \
5292       nextstep/GNUstep/Emacs.base/Resources/Emacs.desktop:nextstep/templates/Emacs.desktop.in])
5293     ns_check_file=Resources/Info-gnustep.plist
5294   else
5295     AC_CONFIG_FILES([nextstep/Cocoa/Emacs.base/Contents/Info.plist:nextstep/templates/Info.plist.in \
5296       nextstep/Cocoa/Emacs.base/Contents/Resources/English.lproj/InfoPlist.strings:nextstep/templates/InfoPlist.strings.in])
5297     ns_check_file=Contents/Info.plist
5298   fi
5299   AC_SUBST(ns_check_file)
5300 fi
5301
5302 dnl config.status treats $srcdir specially, so I think this is ok...
5303 AC_CONFIG_FILES([$srcdir/doc/man/emacs.1])
5304
5305 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
5306 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
5307 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
5308 dnl (else you get "no 'Makefile.am' found for any configure output").
5309 dnl This will work, but you get a config.status that is not quite right
5310 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
5311 dnl That doesn't have any obvious consequences for Emacs, but on the whole
5312 dnl it seems better to just live with the duplication.
5313 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile nextstep/Makefile nt/Makefile"
5314
5315 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
5316        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
5317        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
5318        leim/Makefile nextstep/Makefile nt/Makefile])
5319
5320 dnl test/ is not present in release tarfiles.
5321 opt_makefile=test/Makefile
5322
5323 if test -f "$srcdir/$opt_makefile.in"; then
5324   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
5325   dnl Again, it's best not to use a variable.  Though you can add
5326   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
5327   AC_CONFIG_FILES([test/Makefile])
5328 fi
5329
5330
5331 dnl The admin/ directory used to be excluded from tarfiles.
5332 if test -d $srcdir/admin; then
5333   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES admin/charsets/Makefile admin/unidata/Makefile admin/grammars/Makefile"
5334   AC_CONFIG_FILES([admin/charsets/Makefile])
5335   AC_CONFIG_FILES([admin/unidata/Makefile])
5336   AC_CONFIG_FILES([admin/grammars/Makefile])
5337 fi                              dnl -d admin
5338
5339
5340 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
5341
5342 AC_SUBST(SUBDIR_MAKEFILES_IN)
5343
5344 dnl You might wonder (I did) why epaths.h is generated by running make,
5345 dnl rather than just letting configure generate it from epaths.in.
5346 dnl One reason is that the various paths are not fully expanded (see above);
5347 dnl eg gamedir=${prefix}/var/games/emacs.
5348 dnl Secondly, the GNU Coding standards require that one should be able
5349 dnl to run 'make prefix=/some/where/else' and override the values set
5350 dnl by configure.  This also explains the 'move-if-change' test and
5351 dnl the use of force in the 'epaths-force' rule in Makefile.in.
5352 AC_CONFIG_COMMANDS([src/epaths.h], [
5353 if test "${opsys}" = "mingw32"; then
5354   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force-w32
5355 else
5356   ${MAKE-make} MAKEFILE_NAME=do-not-make-Makefile epaths-force
5357 fi || AC_MSG_ERROR(['src/epaths.h' could not be made.])
5358 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS" opsys="$opsys"])
5359
5360 dnl NB we have to cheat and use the ac_... version because abs_top_srcdir
5361 dnl is not yet set, sigh.  Or we could use ../$srcdir/src/.gdbinit,
5362 dnl or a symlink?
5363 AC_CONFIG_COMMANDS([src/.gdbinit], [
5364 if test ! -f src/.gdbinit && test -f "$srcdir/src/.gdbinit"; then
5365   AS_ECHO(["source $ac_abs_top_srcdir/src/.gdbinit"]) > src/.gdbinit
5366 fi
5367 ])
5368
5369 dnl Perhaps this would be better named doc-emacs-emacsver.texi?
5370 dnl See comments for etc-refcards-emacsver.tex.
5371 dnl Since we get a doc/emacs directory generated anyway, for the Makefile,
5372 dnl it is not quite the same.  But we are generating in $srcdir.
5373 AC_CONFIG_COMMANDS([doc/emacs/emacsver.texi], [
5374 ${MAKE-make} -s --no-print-directory -C doc/emacs doc-emacsver || \
5375 AC_MSG_ERROR(['doc/emacs/emacsver.texi' could not be made.])
5376 ])
5377
5378 dnl If we give this the more natural name, etc/refcards/emacsver.texi,
5379 dnl then a directory etc/refcards is created in the build directory,
5380 dnl which is probably harmless, but confusing (in out-of-tree builds).
5381 dnl (If we were to generate etc/refcards/Makefile, this might change.)
5382 dnl It is really $srcdir/etc/refcards/emacsver.tex that we generate.
5383 AC_CONFIG_COMMANDS([etc-refcards-emacsver.tex], [
5384 ${MAKE-make} -s MAKEFILE_NAME=do-not-make-Makefile etc-emacsver || \
5385 AC_MSG_ERROR(['etc/refcards/emacsver.tex' could not be made.])
5386 ])
5387
5388 AC_OUTPUT
5389
5390 test "$MAKE" = make || AC_MSG_NOTICE([Now you can run '$MAKE'.])