code.delx.au - gnu-emacs/blob - lisp/mail/emacsbug.el

   1 ;;; emacsbug.el --- command to report Emacs bugs to appropriate mailing list.
   2
   3 ;; Copyright (C) 1985, 1994, 1997, 1998 Free Software Foundation, Inc.
   4
   5 ;; Author: K. Shane Hartman
   6 ;; Maintainer: FSF
   7 ;; Keywords: maint mail
   8
   9 ;; Not fully installed because it can work only on Internet hosts.
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; `M-x report-emacs-bug ' starts an email note to the Emacs maintainers
  30 ;; describing a problem.  Here's how it's done...
  31
  32 ;;; Code:
  33
  34 ;; >> This should be an address which is accessible to your machine,
  35 ;; >> otherwise you can't use this file.  It will only work on the
  36 ;; >> internet with this address.
  37
  38 (require 'sendmail)
  39
  40 (defgroup emacsbug nil
  41   "Sending Emacs bug reports."
  42   :group 'maint
  43   :group 'mail)
  44
  45 (defcustom report-emacs-bug-address "bug-gnu-emacs@gnu.org"
  46   "*Address of mailing list for GNU Emacs bugs."
  47   :group 'emacsbug
  48   :type 'string)
  49
  50 (defcustom report-emacs-bug-pretest-address "emacs-pretest-bug@gnu.org"
  51   "*Address of mailing list for GNU Emacs pretest bugs."
  52   :group 'emacsbug
  53   :type 'string)
  54
  55 (defvar report-emacs-bug-orig-text nil
  56   "The automatically-created initial text of bug report.")
  57
  58 (defcustom report-emacs-bug-no-confirmation nil
  59   "*If non-nil, suppress the confirmations asked for the sake of novice users."
  60   :group 'emacsbug
  61   :type 'boolean)
  62
  63 (defcustom report-emacs-bug-no-explanations nil
  64   "*If non-nil, suppress the explanations given for the sake of novice users."
  65   :group 'emacsbug
  66   :type 'boolean)
  67
  68 ;;;###autoload
  69 (defun report-emacs-bug (topic &optional recent-keys)
  70   "Report a bug in GNU Emacs.
  71 Prompts for bug subject.  Leaves you in a mail buffer."
  72   ;; This strange form ensures that (recent-keys) is the value before
  73   ;; the bug subject string is read.
  74   (interactive (reverse (list (recent-keys) (read-string "Bug Subject: "))))
  75   (let (user-point message-end-point)
  76     (setq message-end-point
  77           (with-current-buffer (get-buffer "*Messages*")
  78             (point-max-marker)))
  79     (compose-mail (if (string-match "\\..*\\..*\\." emacs-version)
  80                       ;; If there are four numbers in emacs-version,
  81                       ;; this is a pretest version.
  82                       report-emacs-bug-pretest-address
  83                     report-emacs-bug-address)
  84                   topic)
  85     ;; The rest of this does not execute
  86     ;; if the user was asked to confirm and said no.
  87     (rfc822-goto-eoh)
  88     (forward-line 1)
  89
  90     (let ((signature (buffer-substring (point) (point-max))))
  91       ;; Discourage users to write non-English text.
  92       (set-buffer-multibyte nil)
  93       (delete-region (point) (point-max))
  94       (insert signature))
  95     (unless report-emacs-bug-no-explanations
  96       ;; Insert warnings for novice users.
  97       (insert "This bug report will be sent to the Free Software Foundation,\n")
  98       (let ((pos (point)))
  99         (insert " not to your local site managers!!")
 100         (put-text-property pos (point) 'face 'highlight))
 101       (insert "\nPlease write in ")
 102       (let ((pos (point)))
 103         (insert "English")
 104         (put-text-property pos (point) 'face 'highlight))
 105       (insert ", because the Emacs maintainers do not have
 106 translators to read other languages for them.\n\n"))
 107
 108     (insert "In " (emacs-version) "\n")
 109     (if (and system-configuration-options
 110              (not (equal system-configuration-options "")))
 111         (insert "configured using `configure "
 112                 system-configuration-options "'\n"))
 113     (insert "\n")
 114     (insert "Please describe exactly what actions triggered the bug\n"
 115             "and the precise symptoms of the bug:\n\n")
 116     (setq user-point (point))
 117     (insert "\n\n\n"
 118             "Recent input:\n")
 119     (let ((before-keys (point)))
 120       (insert (mapconcat (lambda (key)
 121                            (if (or (integerp key)
 122                                    (symbolp key)
 123                                    (listp key))
 124                                (single-key-description key)
 125                              (prin1-to-string key nil)))
 126                          (or recent-keys (recent-keys))
 127                          " "))
 128       (save-restriction
 129         (narrow-to-region before-keys (point))
 130         (goto-char before-keys)
 131         (while (progn (move-to-column 50) (not (eobp)))
 132           (search-forward " " nil t)
 133           (insert "\n"))))
 134     (let ((message-buf (get-buffer "*Messages*")))
 135       (if message-buf
 136           (let (beg-pos
 137                 (end-pos message-end-point))
 138             (with-current-buffer message-buf
 139               (goto-char end-pos)
 140               (forward-line -10)
 141               (setq beg-pos (point)))
 142             (insert "\n\nRecent messages:\n")
 143             (insert-buffer-substring message-buf beg-pos end-pos))))
 144     ;; This is so the user has to type something
 145     ;; in order to send easily.
 146     (use-local-map (nconc (make-sparse-keymap) (current-local-map)))
 147     (define-key (current-local-map) "\C-c\C-i" 'report-emacs-bug-info)
 148     (with-output-to-temp-buffer "*Bug Help*"
 149       (if (eq mail-user-agent 'sendmail-user-agent)
 150           (princ (substitute-command-keys
 151                   "Type \\[mail-send-and-exit] to send the bug report.\n")))
 152       (princ (substitute-command-keys
 153               "Type \\[kill-buffer] RET to cancel (don't send it).\n"))
 154       (terpri)
 155       (princ (substitute-command-keys
 156               "Type \\[report-emacs-bug-info] to visit in Info the Emacs Manual section
 157 about when and how to write a bug report,
 158 and what information to supply so that the bug can be fixed.
 159 Type SPC to scroll through this section and its subsections.")))
 160     ;; Make it less likely people will send empty messages.
 161     (make-local-variable 'mail-send-hook)
 162     (add-hook 'mail-send-hook 'report-emacs-bug-hook)
 163     (save-excursion
 164       (goto-char (point-max))
 165       (skip-chars-backward " \t\n")
 166       (make-local-variable 'report-emacs-bug-orig-text)
 167       (setq report-emacs-bug-orig-text (buffer-substring (point-min) (point))))
 168     (goto-char user-point)))
 169
 170 (defun report-emacs-bug-info ()
 171   "Go to the Info node on reporting Emacs bugs."
 172   (interactive)
 173   (info)
 174   (Info-directory)
 175   (Info-menu "emacs")
 176   (Info-goto-node "Bugs"))
 177
 178 (defun report-emacs-bug-hook ()
 179   (save-excursion
 180     (goto-char (point-max))
 181     (skip-chars-backward " \t\n")
 182     (if (and (= (- (point) (point-min))
 183                 (length report-emacs-bug-orig-text))
 184              (equal (buffer-substring (point-min) (point))
 185                     report-emacs-bug-orig-text))
 186         (error "No text entered in bug report"))
 187
 188     ;; Check the buffer contents and reject non-English letters.
 189     (save-excursion
 190       (goto-char (point-min))
 191       (skip-chars-forward "\0-\177")
 192       (if (not (eobp))
 193           (if (or report-emacs-bug-no-confirmation
 194                   (y-or-n-p "Convert non-ASCII letters to hexadecimal? "))
 195               (while (progn (skip-chars-forward "\0-\177")
 196                             (not (eobp)))
 197                 (let ((ch (following-char)))
 198                   (delete-char 1)
 199                   (insert (format "=%02x" ch)))))))
 200
 201     ;; The last warning for novice users.
 202     (if (or report-emacs-bug-no-confirmation
 203             (yes-or-no-p
 204              "Send this bug report to the Emacs maintainers? "))
 205         ;; Just send the current mail.
 206         nil
 207       (goto-char (point-min))
 208       (if (search-forward "To: ")
 209           (let ((pos (point)))
 210             (end-of-line)
 211             (delete-region pos (point))))
 212       (kill-local-variable 'mail-send-hook)
 213       (with-output-to-temp-buffer "*Bug Help*"
 214         (princ (substitute-command-keys "\
 215 You invoked the command M-x report-emacs-bug,
 216 but you decided not to mail the bug report to the Emacs maintainers.
 217
 218 If you want to mail it to someone else instead,
 219 please insert the proper e-mail address after \"To: \",
 220 and send the mail again using \\[mail-send-and-exit].")))
 221       (error "M-x report-emacs-bug was cancelled, please read *Bug Help* buffer"))
 222     ))
 223
 224 (provide 'emacsbug)
 225
 226 ;;; emacsbug.el ends here