code.delx.au - gnu-emacs/blob - lisp/calendar/lunar.el

   1 ;;; lunar.el --- calendar functions for phases of the moon
   2
   3 ;; Copyright (C) 1992, 1993, 1995, 1997, 2001, 2002, 2003, 2004, 2005,
   4 ;;   2006  Free Software Foundation, Inc.
   5
   6 ;; Author: Edward M. Reingold <reingold@cs.uiuc.edu>
   7 ;; Maintainer: Glenn Morris <rgm@gnu.org>
   8 ;; Keywords: calendar
   9 ;; Human-Keywords: moon, lunar phases, calendar, diary
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This collection of functions implements lunar phases for calendar.el and
  31 ;; diary.el.
  32
  33 ;; Based on ``Astronomical Formulae for Calculators,'' 3rd ed., by Jean Meeus,
  34 ;; Willmann-Bell, Inc., 1985 and ``Astronomical Algorithms'' by Jean Meeus,
  35 ;; Willmann-Bell, Inc., 1991.
  36 ;;
  37 ;; WARNING: The calculations will be accurate only to within a few minutes.
  38
  39 ;; The author would be delighted to have an astronomically more sophisticated
  40 ;; person rewrite the code for the lunar calculations in this file!
  41
  42 ;; Technical details of all the calendrical calculations can be found in
  43 ;; ``Calendrical Calculations: The Millennium Edition'' by Edward M. Reingold
  44 ;; and Nachum Dershowitz, Cambridge University Press (2001).
  45
  46 ;; Comments, corrections, and improvements should be sent to
  47 ;;  Edward M. Reingold               Department of Computer Science
  48 ;;  (217) 333-6733                   University of Illinois at Urbana-Champaign
  49 ;;  reingold@cs.uiuc.edu             1304 West Springfield Avenue
  50 ;;                                   Urbana, Illinois 61801
  51
  52 ;;; Code:
  53
  54 (defvar date)
  55 (defvar displayed-month)
  56 (defvar displayed-year)
  57
  58 (if (fboundp 'atan)
  59     (require 'lisp-float-type)
  60   (error "Lunar calculations impossible since floating point is unavailable"))
  61
  62 (require 'solar)
  63
  64 (defun lunar-phase-list (month year)
  65   "List of lunar phases for three months starting with Gregorian MONTH, YEAR."
  66   (let ((end-month month)
  67         (end-year year)
  68         (start-month month)
  69         (start-year year))
  70     (increment-calendar-month end-month end-year 3)
  71     (increment-calendar-month start-month start-year -1)
  72     (let* ((end-date (list (list end-month 1 end-year)))
  73            (start-date (list (list start-month
  74                                    (calendar-last-day-of-month
  75                                     start-month start-year)
  76                                    start-year)))
  77            (index (* 4
  78                      (truncate
  79                       (* 12.3685
  80                          (+ year
  81                             ( / (calendar-day-number (list month 1 year))
  82                                 366.0)
  83                             -1900)))))
  84            (new-moon (lunar-phase index))
  85            (list))
  86       (while (calendar-date-compare new-moon end-date)
  87         (if (calendar-date-compare start-date new-moon)
  88             (setq list (append list (list new-moon))))
  89         (setq index (1+ index))
  90         (setq new-moon (lunar-phase index)))
  91       list)))
  92
  93 (defun lunar-phase (index)
  94   "Local date and time of lunar phase INDEX.
  95 Integer below INDEX/4 gives the lunation number, counting from Jan 1, 1900;
  96 remainder mod 4 gives the phase: 0 new moon, 1 first quarter, 2 full moon,
  97 3 last quarter."
  98   (let* ((phase (mod index 4))
  99          (index (/ index 4.0))
 100          (time (/ index 1236.85))
 101          (date (+ (calendar-absolute-from-gregorian '(1 0.5 1900))
 102                   0.75933
 103                   (* 29.53058868 index)
 104                   (* 0.0001178 time time)
 105                   (* -0.000000155 time time time)
 106                   (* 0.00033
 107                      (solar-sin-degrees (+ 166.56
 108                                            (* 132.87 time)
 109                                            (* -0.009173 time time))))))
 110          (sun-anomaly (mod
 111                        (+ 359.2242
 112                           (* 29.105356 index)
 113                           (* -0.0000333 time time)
 114                           (* -0.00000347 time time time))
 115                        360.0))
 116          (moon-anomaly (mod
 117                         (+ 306.0253
 118                            (* 385.81691806 index)
 119                            (* 0.0107306 time time)
 120                            (* 0.00001236 time time time))
 121                         360.0))
 122          (moon-lat (mod
 123                     (+ 21.2964
 124                        (* 390.67050646 index)
 125                        (* -0.0016528 time time)
 126                        (* -0.00000239 time time time))
 127                     360.0))
 128          (adjustment
 129           (if (memq phase '(0 2))
 130               (+ (* (- 0.1734 (* 0.000393 time))
 131                     (solar-sin-degrees sun-anomaly))
 132                  (* 0.0021 (solar-sin-degrees (* 2 sun-anomaly)))
 133                  (* -0.4068 (solar-sin-degrees moon-anomaly))
 134                  (* 0.0161 (solar-sin-degrees (* 2 moon-anomaly)))
 135                  (* -0.0004 (solar-sin-degrees (* 3 moon-anomaly)))
 136                  (* 0.0104 (solar-sin-degrees (* 2 moon-lat)))
 137                  (* -0.0051 (solar-sin-degrees (+ sun-anomaly moon-anomaly)))
 138                  (* -0.0074 (solar-sin-degrees (- sun-anomaly moon-anomaly)))
 139                  (* 0.0004 (solar-sin-degrees (+ (* 2 moon-lat) sun-anomaly)))
 140                  (* -0.0004 (solar-sin-degrees (- (* 2 moon-lat) sun-anomaly)))
 141                  (* -0.0006 (solar-sin-degrees
 142                              (+ (* 2 moon-lat) moon-anomaly)))
 143                  (* 0.0010 (solar-sin-degrees (- (* 2 moon-lat) moon-anomaly)))
 144                  (* 0.0005 (solar-sin-degrees
 145                             (+ (* 2 moon-anomaly) sun-anomaly))))
 146             (+ (* (- 0.1721 (* 0.0004 time))
 147                   (solar-sin-degrees sun-anomaly))
 148                (* 0.0021 (solar-sin-degrees (* 2 sun-anomaly)))
 149                (* -0.6280 (solar-sin-degrees moon-anomaly))
 150                (* 0.0089 (solar-sin-degrees (* 2 moon-anomaly)))
 151                (* -0.0004 (solar-sin-degrees (* 3 moon-anomaly)))
 152                (* 0.0079 (solar-sin-degrees (* 2 moon-lat)))
 153                (* -0.0119 (solar-sin-degrees (+ sun-anomaly moon-anomaly)))
 154                (* -0.0047 (solar-sin-degrees (- sun-anomaly moon-anomaly)))
 155                (* 0.0003 (solar-sin-degrees (+ (* 2 moon-lat) sun-anomaly)))
 156                (* -0.0004 (solar-sin-degrees (- (* 2 moon-lat) sun-anomaly)))
 157                (* -0.0006 (solar-sin-degrees (+ (* 2 moon-lat) moon-anomaly)))
 158                (* 0.0021 (solar-sin-degrees (- (* 2 moon-lat) moon-anomaly)))
 159                (* 0.0003 (solar-sin-degrees
 160                           (+ (* 2 moon-anomaly) sun-anomaly)))
 161                (* 0.0004 (solar-sin-degrees
 162                           (- sun-anomaly (* 2 moon-anomaly))))
 163                (* -0.0003 (solar-sin-degrees
 164                           (+ (* 2 sun-anomaly) moon-anomaly))))))
 165          (adj (+ 0.0028
 166                  (* -0.0004 (solar-cosine-degrees
 167                              sun-anomaly))
 168                  (* 0.0003 (solar-cosine-degrees
 169                             moon-anomaly))))
 170          (adjustment (cond ((= phase 1) (+ adjustment adj))
 171                            ((= phase 2) (- adjustment adj))
 172                            (t adjustment)))
 173          (date (+ date adjustment))
 174          (date (+ date (/ (- calendar-time-zone
 175                              (solar-ephemeris-correction
 176                               (extract-calendar-year
 177                                (calendar-gregorian-from-absolute
 178                                 (truncate date)))))
 179                           60.0 24.0)))
 180          (time (* 24 (- date (truncate date))))
 181          (date (calendar-gregorian-from-absolute (truncate date)))
 182          (adj (dst-adjust-time date time)))
 183     (list (car adj) (apply 'solar-time-string (cdr adj)) phase)))
 184
 185 (defun lunar-phase-name (phase)
 186   "Name of lunar PHASE.
 187 0 = new moon, 1 = first quarter, 2 = full moon, 3 = last quarter."
 188   (cond ((= 0 phase) "New Moon")
 189         ((= 1 phase) "First Quarter Moon")
 190         ((= 2 phase) "Full Moon")
 191         ((= 3 phase) "Last Quarter Moon")))
 192
 193 (defun calendar-phases-of-moon ()
 194   "Create a buffer with the lunar phases for the current calendar window."
 195   (interactive)
 196   (message "Computing phases of the moon...")
 197   (let ((m1 displayed-month)
 198         (y1 displayed-year)
 199         (m2 displayed-month)
 200         (y2 displayed-year))
 201     (increment-calendar-month m1 y1 -1)
 202     (increment-calendar-month m2 y2 1)
 203     (set-buffer (get-buffer-create lunar-phases-buffer))
 204     (setq buffer-read-only nil)
 205     (calendar-set-mode-line
 206      (if (= y1 y2)
 207          (format "Phases of the Moon from %s to %s, %d%%-"
 208                  (calendar-month-name m1) (calendar-month-name m2) y2)
 209        (format "Phases of the Moon from %s, %d to %s, %d%%-"
 210                (calendar-month-name m1) y1 (calendar-month-name m2) y2)))
 211     (erase-buffer)
 212     (insert
 213      (mapconcat
 214       '(lambda (x)
 215          (let ((date (car x))
 216                (time (car (cdr x)))
 217                (phase (car (cdr (cdr x)))))
 218            (concat (calendar-date-string date)
 219                    ": "
 220                    (lunar-phase-name phase)
 221                    " "
 222                    time)))
 223       (lunar-phase-list m1 y1) "\n"))
 224     (goto-char (point-min))
 225     (set-buffer-modified-p nil)
 226     (setq buffer-read-only t)
 227     (display-buffer lunar-phases-buffer)
 228     (message "Computing phases of the moon...done")))
 229
 230 ;;;###autoload
 231 (defun phases-of-moon (&optional arg)
 232   "Display the quarters of the moon for last month, this month, and next month.
 233 If called with an optional prefix argument, prompts for month and year.
 234
 235 This function is suitable for execution in a .emacs file."
 236   (interactive "P")
 237   (save-excursion
 238     (let* ((date (if arg
 239                      (calendar-read-date t)
 240                    (calendar-current-date)))
 241            (displayed-month (extract-calendar-month date))
 242            (displayed-year (extract-calendar-year date)))
 243       (calendar-phases-of-moon))))
 244
 245 (defun diary-phases-of-moon (&optional mark)
 246 "Moon phases diary entry.
 247
 248 An optional parameter MARK specifies a face or single-character string to
 249 use when highlighting the day in the calendar."
 250   (let* ((index (* 4
 251                    (truncate
 252                     (* 12.3685
 253                        (+ (extract-calendar-year date)
 254                           ( / (calendar-day-number date)
 255                               366.0)
 256                           -1900)))))
 257          (phase (lunar-phase index)))
 258     (while (calendar-date-compare phase (list date))
 259       (setq index (1+ index))
 260       (setq phase (lunar-phase index)))
 261     (if (calendar-date-equal (car phase) date)
 262         (cons mark (concat (lunar-phase-name (car (cdr (cdr phase)))) " "
 263                 (car (cdr phase)))))))
 264
 265
 266 ;;  For the Chinese calendar the calculations for the new moon need to be more
 267 ;;  accurate than those above, so we use more terms in the approximation.
 268
 269 (defun lunar-new-moon-time (k)
 270   "Astronomical (Julian) day number of K th new moon."
 271   (let* ((T (/ k 1236.85))
 272          (T2 (* T T))
 273          (T3 (* T T T))
 274          (T4 (* T2 T2))
 275          (JDE (+ 2451550.09765
 276                  (* 29.530588853 k)
 277                  (* 0.0001337 T2)
 278                  (* -0.000000150 T3)
 279                  (* 0.00000000073 T4)))
 280          (E (- 1 (* 0.002516 T) (* 0.0000074 T2)))
 281          (sun-anomaly (+ 2.5534
 282                          (* 29.10535669 k)
 283                          (* -0.0000218 T2)
 284                          (* -0.00000011 T3)))
 285          (moon-anomaly (+ 201.5643
 286                           (* 385.81693528 k)
 287                           (* 0.0107438 T2)
 288                           (* 0.00001239 T3)
 289                           (* -0.000000058 T4)))
 290          (moon-argument (+ 160.7108
 291                            (* 390.67050274 k)
 292                            (* -0.0016341 T2)
 293                            (* -0.00000227 T3)
 294                            (* 0.000000011 T4)))
 295          (omega (+ 124.7746
 296                    (* -1.56375580 k)
 297                    (* 0.0020691 T2)
 298                    (* 0.00000215 T3)))
 299          (A1  (+ 299.77 (*  0.107408 k) (* -0.009173 T2)))
 300          (A2  (+ 251.88 (*  0.016321 k)))
 301          (A3  (+ 251.83 (* 26.641886 k)))
 302          (A4  (+ 349.42 (* 36.412478 k)))
 303          (A5  (+  84.66 (* 18.206239 k)))
 304          (A6  (+ 141.74 (* 53.303771 k)))
 305          (A7  (+ 207.14 (*  2.453732 k)))
 306          (A8  (+ 154.84 (*  7.306860 k)))
 307          (A9  (+  34.52 (* 27.261239 k)))
 308          (A10 (+ 207.19 (*  0.121824 k)))
 309          (A11 (+ 291.34 (*  1.844379 k)))
 310          (A12 (+ 161.72 (* 24.198154 k)))
 311          (A13 (+ 239.56 (* 25.513099 k)))
 312          (A14 (+ 331.55 (*  3.592518 k)))
 313          (correction
 314             (+ (* -0.40720   (solar-sin-degrees moon-anomaly))
 315                (*  0.17241 E (solar-sin-degrees sun-anomaly))
 316                (*  0.01608   (solar-sin-degrees (* 2 moon-anomaly)))
 317                (*  0.01039   (solar-sin-degrees (* 2 moon-argument)))
 318                (*  0.00739 E (solar-sin-degrees (- moon-anomaly sun-anomaly)))
 319                (* -0.00514 E (solar-sin-degrees (+ moon-anomaly sun-anomaly)))
 320                (*  0.00208 E E (solar-sin-degrees (* 2 sun-anomaly)))
 321                (* -0.00111   (solar-sin-degrees
 322                                (- moon-anomaly (* 2 moon-argument))))
 323                (* -0.00057   (solar-sin-degrees
 324                                (+ moon-anomaly (* 2 moon-argument))))
 325                (*  0.00056 E (solar-sin-degrees
 326                                (+ (* 2 moon-anomaly) sun-anomaly)))
 327                (* -0.00042   (solar-sin-degrees (* 3 moon-anomaly)))
 328                (*  0.00042 E (solar-sin-degrees
 329                                (+ sun-anomaly (* 2 moon-argument))))
 330                (*  0.00038 E (solar-sin-degrees
 331                                (- sun-anomaly (* 2 moon-argument))))
 332                (* -0.00024 E (solar-sin-degrees
 333                                (- (* 2 moon-anomaly) sun-anomaly)))
 334                (* -0.00017   (solar-sin-degrees omega))
 335                (* -0.00007   (solar-sin-degrees
 336                                (+ moon-anomaly (* 2 sun-anomaly))))
 337                (*  0.00004   (solar-sin-degrees
 338                                (- (* 2 moon-anomaly) (* 2 moon-argument))))
 339                (*  0.00004   (solar-sin-degrees (* 3 sun-anomaly)))
 340                (*  0.00003   (solar-sin-degrees (+ moon-anomaly sun-anomaly
 341                                                    (* -2 moon-argument))))
 342                (*  0.00003   (solar-sin-degrees
 343                                (+ (* 2 moon-anomaly) (* 2 moon-argument))))
 344                (* -0.00003   (solar-sin-degrees (+ moon-anomaly sun-anomaly
 345                                                    (* 2 moon-argument))))
 346                (*  0.00003   (solar-sin-degrees (- moon-anomaly sun-anomaly
 347                                                    (* -2 moon-argument))))
 348                (* -0.00002   (solar-sin-degrees (- moon-anomaly sun-anomaly
 349                                                    (* 2 moon-argument))))
 350                (* -0.00002   (solar-sin-degrees
 351                                (+ (* 3 moon-anomaly) sun-anomaly)))
 352                (*  0.00002   (solar-sin-degrees (* 4 moon-anomaly)))))
 353          (additional
 354             (+ (* 0.000325 (solar-sin-degrees A1))
 355                (* 0.000165 (solar-sin-degrees A2))
 356                (* 0.000164 (solar-sin-degrees A3))
 357                (* 0.000126 (solar-sin-degrees A4))
 358                (* 0.000110 (solar-sin-degrees A5))
 359                (* 0.000062 (solar-sin-degrees A6))
 360                (* 0.000060 (solar-sin-degrees A7))
 361                (* 0.000056 (solar-sin-degrees A8))
 362                (* 0.000047 (solar-sin-degrees A9))
 363                (* 0.000042 (solar-sin-degrees A10))
 364                (* 0.000040 (solar-sin-degrees A11))
 365                (* 0.000037 (solar-sin-degrees A12))
 366                (* 0.000035 (solar-sin-degrees A13))
 367                (* 0.000023 (solar-sin-degrees A14))))
 368          (newJDE (+ JDE correction additional)))
 369     (+ newJDE
 370        (- (solar-ephemeris-correction
 371            (extract-calendar-year
 372             (calendar-gregorian-from-absolute
 373              (floor (calendar-absolute-from-astro newJDE))))))
 374        (/ calendar-time-zone 60.0 24.0))))
 375
 376 (defun lunar-new-moon-on-or-after (d)
 377   "Astronomical (Julian) day number of first new moon on or after astronomical
 378 \(Julian) day number d.  The fractional part is the time of day.
 379
 380 The date and time are local time, including any daylight savings rules,
 381 as governed by the values of calendar-daylight-savings-starts,
 382 calendar-daylight-savings-starts-time, calendar-daylight-savings-ends,
 383 calendar-daylight-savings-ends-time, calendar-daylight-time-offset, and
 384 calendar-time-zone."
 385   (let* ((date (calendar-gregorian-from-absolute
 386                 (floor (calendar-absolute-from-astro d))))
 387          (year (+ (extract-calendar-year date)
 388                   (/ (calendar-day-number date) 365.25)))
 389          (k (floor (* (- year 2000.0) 12.3685)))
 390          (date (lunar-new-moon-time k)))
 391     (while (< date d)
 392       (setq k (1+ k))
 393       (setq date (lunar-new-moon-time k)))
 394     (let* ((a-date (calendar-absolute-from-astro date))
 395            (time (* 24 (- a-date (truncate a-date))))
 396            (date (calendar-gregorian-from-absolute (truncate a-date)))
 397            (adj (dst-adjust-time date time)))
 398       (calendar-astro-from-absolute
 399        (+ (calendar-absolute-from-gregorian (car adj))
 400           (/ (car (cdr adj)) 24.0))))))
 401
 402 (provide 'lunar)
 403
 404 ;;; arch-tag: 72f0b8a4-7bcc-4a1b-b67a-ff53c4a1d222
 405 ;;; lunar.el ends here