code.delx.au - gnu-emacs/blob - lisp/frame.el

   1 ;;; frame.el --- multi-frame management independent of window systems
   2
   3 ;; Copyright (C) 1993, 1994, 1996, 1997, 2000, 2001, 2002, 2003,
   4 ;;   2004, 2005 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (defvar frame-creation-function-alist
  31   (list (cons nil
  32               (if (fboundp 'tty-create-frame-with-faces)
  33                   'tty-create-frame-with-faces
  34                 (function
  35                  (lambda (parameters)
  36                    (error "Can't create multiple frames without a window system"))))))
  37   "Alist of window-system dependent functions to call to create a new frame.
  38 The window system startup file should add its frame creation
  39 function to this list, which should take an alist of parameters
  40 as its argument.")
  41
  42 (defvar window-system-default-frame-alist nil
  43   "Alist of window-system dependent default frame parameters.
  44 These may be set in your init file, like this:
  45
  46     ;; Disable menubar and toolbar on the console, but enable them under X.
  47     (setq window-system-default-frame-alist
  48           '((x (menu-bar-lines . 1) (tool-bar-lines . 1))
  49             (nil (menu-bar-lines . 0) (tool-bar-lines . 0))))
  50
  51 Also see `default-frame-alist'.")
  52
  53 ;; The initial value given here used to ask for a minibuffer.
  54 ;; But that's not necessary, because the default is to have one.
  55 ;; By not specifying it here, we let an X resource specify it.
  56 (defcustom initial-frame-alist nil
  57   "*Alist of frame parameters for creating the initial X window frame.
  58 You can set this in your `.emacs' file; for example,
  59  (setq initial-frame-alist '((top . 1) (left . 1) (width . 80) (height . 55)))
  60 Parameters specified here supersede the values given in `default-frame-alist'.
  61
  62 If the value calls for a frame without a minibuffer, and you have not created
  63 a minibuffer frame on your own, one is created according to
  64 `minibuffer-frame-alist'.
  65
  66 You can specify geometry-related options for just the initial frame
  67 by setting this variable in your `.emacs' file; however, they won't
  68 take effect until Emacs reads `.emacs', which happens after first creating
  69 the frame.  If you want the frame to have the proper geometry as soon
  70 as it appears, you need to use this three-step process:
  71 * Specify X resources to give the geometry you want.
  72 * Set `default-frame-alist' to override these options so that they
  73   don't affect subsequent frames.
  74 * Set `initial-frame-alist' in a way that matches the X resources,
  75   to override what you put in `default-frame-alist'."
  76   :type '(repeat (cons :format "%v"
  77                        (symbol :tag "Parameter")
  78                        (sexp :tag "Value")))
  79   :group 'frames)
  80
  81 (defcustom minibuffer-frame-alist '((width . 80) (height . 2))
  82   "*Alist of frame parameters for initially creating a minibuffer frame.
  83 You can set this in your `.emacs' file; for example,
  84  (setq minibuffer-frame-alist
  85    '((top . 1) (left . 1) (width . 80) (height . 2)))
  86 Parameters specified here supersede the values given in
  87 `default-frame-alist', for a minibuffer frame."
  88   :type '(repeat (cons :format "%v"
  89                        (symbol :tag "Parameter")
  90                        (sexp :tag "Value")))
  91   :group 'frames)
  92
  93 (defcustom pop-up-frame-alist nil
  94   "*Alist of frame parameters used when creating pop-up frames.
  95 Pop-up frames are used for completions, help, and the like.
  96 This variable can be set in your init file, like this:
  97   (setq pop-up-frame-alist '((width . 80) (height . 20)))
  98 These supersede the values given in `default-frame-alist',
  99 for pop-up frames."
 100   :type '(repeat (cons :format "%v"
 101                        (symbol :tag "Parameter")
 102                        (sexp :tag "Value")))
 103   :group 'frames)
 104
 105 (setq pop-up-frame-function
 106       ;; Using `function' here caused some sort of problem.
 107       '(lambda ()
 108          (make-frame pop-up-frame-alist)))
 109
 110 (defcustom special-display-frame-alist
 111   '((height . 14) (width . 80) (unsplittable . t))
 112   "*Alist of frame parameters used when creating special frames.
 113 Special frames are used for buffers whose names are in
 114 `special-display-buffer-names' and for buffers whose names match
 115 one of the regular expressions in `special-display-regexps'.
 116 This variable can be set in your init file, like this:
 117   (setq special-display-frame-alist '((width . 80) (height . 20)))
 118 These supersede the values given in `default-frame-alist'."
 119   :type '(repeat (cons :format "%v"
 120                          (symbol :tag "Parameter")
 121                          (sexp :tag "Value")))
 122   :group 'frames)
 123
 124 (defun special-display-popup-frame (buffer &optional args)
 125   "Display BUFFER in its own frame, reusing an existing window if any.
 126 Return the window chosen.
 127 Currently we do not insist on selecting the window within its frame.
 128 If ARGS is an alist, use it as a list of frame parameter specs.
 129 If ARGS is a list whose car is a symbol,
 130 use (car ARGS) as a function to do the work.
 131 Pass it BUFFER as first arg, and (cdr ARGS) gives the rest of the args."
 132   (if (and args (symbolp (car args)))
 133       (apply (car args) buffer (cdr args))
 134     (let ((window (get-buffer-window buffer 0)))
 135       (or
 136        ;; If we have a window already, make it visible.
 137        (when window
 138          (let ((frame (window-frame window)))
 139            (make-frame-visible frame)
 140            (raise-frame frame)
 141            window))
 142        ;; Reuse the current window if the user requested it.
 143        (when (cdr (assq 'same-window args))
 144          (condition-case nil
 145              (progn (switch-to-buffer buffer) (selected-window))
 146            (error nil)))
 147        ;; Stay on the same frame if requested.
 148        (when (or (cdr (assq 'same-frame args)) (cdr (assq 'same-window args)))
 149          (let* ((pop-up-frames nil) (pop-up-windows t)
 150                 special-display-regexps special-display-buffer-names
 151                 (window (display-buffer buffer)))
 152            ;; Only do it if this is a new window:
 153            ;; (set-window-dedicated-p window t)
 154            window))
 155        ;; If no window yet, make one in a new frame.
 156        (let ((frame
 157               (with-current-buffer buffer
 158                 (make-frame (append args special-display-frame-alist)))))
 159          (set-window-buffer (frame-selected-window frame) buffer)
 160          (set-window-dedicated-p (frame-selected-window frame) t)
 161          (frame-selected-window frame))))))
 162
 163 (defun handle-delete-frame (event)
 164   "Handle delete-frame events from the X server."
 165   (interactive "e")
 166   (let ((frame (posn-window (event-start event)))
 167         (i 0)
 168         (tail (frame-list)))
 169     (while tail
 170       (and (frame-visible-p (car tail))
 171            (not (eq (car tail) frame))
 172           (setq i (1+ i)))
 173       (setq tail (cdr tail)))
 174     (if (> i 0)
 175         (delete-frame frame t)
 176       ;; Gildea@x.org says it is ok to ask questions before terminating.
 177       (save-buffers-kill-emacs))))
 178 \f
 179 ;;;; Arrangement of frames at startup
 180
 181 ;; 1) Load the window system startup file from the lisp library and read the
 182 ;; high-priority arguments (-q and the like).  The window system startup
 183 ;; file should create any frames specified in the window system defaults.
 184 ;;
 185 ;; 2) If no frames have been opened, we open an initial text frame.
 186 ;;
 187 ;; 3) Once the init file is done, we apply any newly set parameters
 188 ;; in initial-frame-alist to the frame.
 189
 190 ;; These are now called explicitly at the proper times,
 191 ;; since that is easier to understand.
 192 ;; Actually using hooks within Emacs is bad for future maintenance. --rms.
 193 ;; (add-hook 'before-init-hook 'frame-initialize)
 194 ;; (add-hook 'window-setup-hook 'frame-notice-user-settings)
 195
 196 ;; If we create the initial frame, this is it.
 197 (defvar frame-initial-frame nil)
 198
 199 ;; Record the parameters used in frame-initialize to make the initial frame.
 200 (defvar frame-initial-frame-alist)
 201
 202 (defvar frame-initial-geometry-arguments nil)
 203
 204 ;; startup.el calls this function before loading the user's init
 205 ;; file - if there is no frame with a minibuffer open now, create
 206 ;; one to display messages while loading the init file.
 207 (defun frame-initialize ()
 208   "Create an initial frame if necessary."
 209   ;; Are we actually running under a window system at all?
 210   (if (and initial-window-system
 211            (not noninteractive)
 212            (not (eq initial-window-system 'pc)))
 213       (progn
 214         ;; Turn on special-display processing only if there's a window system.
 215         (setq special-display-function 'special-display-popup-frame)
 216
 217         ;; If there is no frame with a minibuffer besides the terminal
 218         ;; frame, then we need to create the opening frame.  Make sure
 219         ;; it has a minibuffer, but let initial-frame-alist omit the
 220         ;; minibuffer spec.
 221         (or (delq terminal-frame (minibuffer-frame-list))
 222             (progn
 223               (setq frame-initial-frame-alist
 224                     (append initial-frame-alist default-frame-alist nil))
 225               (or (assq 'horizontal-scroll-bars frame-initial-frame-alist)
 226                   (setq frame-initial-frame-alist
 227                         (cons '(horizontal-scroll-bars . t)
 228                               frame-initial-frame-alist)))
 229               (setq frame-initial-frame-alist
 230                     (cons (cons 'window-system initial-window-system)
 231                           frame-initial-frame-alist))
 232               (setq default-minibuffer-frame
 233                     (setq frame-initial-frame
 234                           (make-frame frame-initial-frame-alist)))
 235               ;; Delete any specifications for window geometry parameters
 236               ;; so that we won't reapply them in frame-notice-user-settings.
 237               ;; It would be wrong to reapply them then,
 238               ;; because that would override explicit user resizing.
 239               (setq initial-frame-alist
 240                     (frame-remove-geometry-params initial-frame-alist))))
 241         ;; At this point, we know that we have a frame open, so we
 242         ;; can delete the terminal frame.
 243         (delete-frame terminal-frame)
 244         (setq terminal-frame nil))))
 245
 246 (defvar frame-notice-user-settings t
 247   "Non-nil means function `frame-notice-user-settings' wasn't run yet.")
 248
 249 ;; startup.el calls this function after loading the user's init
 250 ;; file.  Now default-frame-alist and initial-frame-alist contain
 251 ;; information to which we must react; do what needs to be done.
 252 (defun frame-notice-user-settings ()
 253   "Act on user's init file settings of frame parameters.
 254 React to settings of `default-frame-alist', `initial-frame-alist' there."
 255   ;; Make menu-bar-mode and default-frame-alist consistent.
 256   (when (boundp 'menu-bar-mode)
 257     (let ((default (assq 'menu-bar-lines default-frame-alist)))
 258       (if default
 259           (setq menu-bar-mode (not (eq (cdr default) 0)))
 260         (setq default-frame-alist
 261               (cons (cons 'menu-bar-lines (if menu-bar-mode 1 0))
 262                     default-frame-alist)))))
 263
 264   ;; Make tool-bar-mode and default-frame-alist consistent.  Don't do
 265   ;; it in batch mode since that would leave a tool-bar-lines
 266   ;; parameter in default-frame-alist in a dumped Emacs, which is not
 267   ;; what we want.
 268   (when (and (boundp 'tool-bar-mode)
 269              (not noninteractive))
 270     (let ((default (assq 'tool-bar-lines default-frame-alist)))
 271       (if default
 272           (setq tool-bar-mode (not (eq (cdr default) 0)))
 273         (setq default-frame-alist
 274               (cons (cons 'tool-bar-lines (if tool-bar-mode 1 0))
 275                     default-frame-alist)))))
 276
 277   ;; Creating and deleting frames may shift the selected frame around,
 278   ;; and thus the current buffer.  Protect against that.  We don't
 279   ;; want to use save-excursion here, because that may also try to set
 280   ;; the buffer of the selected window, which fails when the selected
 281   ;; window is the minibuffer.
 282   (let ((old-buffer (current-buffer)))
 283
 284     (when (and frame-notice-user-settings
 285                (null frame-initial-frame))
 286       ;; This case happens when we don't have a window system, and
 287       ;; also for MS-DOS frames.
 288       (let ((parms (frame-parameters frame-initial-frame)))
 289         ;; Don't change the frame names.
 290         (setq parms (delq (assq 'name parms) parms))
 291         ;; Can't modify the minibuffer parameter, so don't try.
 292         (setq parms (delq (assq 'minibuffer parms) parms))
 293         (modify-frame-parameters nil
 294                                  (if (null initial-window-system)
 295                                      (append initial-frame-alist
 296                                              default-frame-alist
 297                                              parms
 298                                              nil)
 299                                    ;; initial-frame-alist and
 300                                    ;; default-frame-alist were already
 301                                    ;; applied in pc-win.el.
 302                                    parms))
 303         (if (null initial-window-system) ;; MS-DOS does this differently in pc-win.el
 304             (let ((newparms (frame-parameters))
 305                   (frame (selected-frame)))
 306               (tty-handle-reverse-video frame newparms)
 307               ;; If we changed the background color, we need to update
 308               ;; the background-mode parameter, and maybe some faces,
 309               ;; too.
 310               (when (assq 'background-color newparms)
 311                 (unless (or (assq 'background-mode initial-frame-alist)
 312                             (assq 'background-mode default-frame-alist))
 313                   (frame-set-background-mode frame))
 314                 (face-set-after-frame-default frame))))))
 315
 316     ;; If the initial frame is still around, apply initial-frame-alist
 317     ;; and default-frame-alist to it.
 318     (when (frame-live-p frame-initial-frame)
 319
 320       ;; When tool-bar has been switched off, correct the frame size
 321       ;; by the lines added in x-create-frame for the tool-bar and
 322       ;; switch `tool-bar-mode' off.
 323       (when (display-graphic-p)
 324         (let ((tool-bar-lines (or (assq 'tool-bar-lines initial-frame-alist)
 325                                   (assq 'tool-bar-lines default-frame-alist))))
 326           (when (and tool-bar-originally-present
 327                      (or (null tool-bar-lines)
 328                          (null (cdr tool-bar-lines))
 329                          (eq 0 (cdr tool-bar-lines))))
 330             (let* ((char-height (frame-char-height frame-initial-frame))
 331                    (image-height tool-bar-images-pixel-height)
 332                    (margin (cond ((and (consp tool-bar-button-margin)
 333                                        (integerp (cdr tool-bar-button-margin))
 334                                        (> tool-bar-button-margin 0))
 335                                   (cdr tool-bar-button-margin))
 336                                  ((and (integerp tool-bar-button-margin)
 337                                        (> tool-bar-button-margin 0))
 338                                   tool-bar-button-margin)
 339                                  (t 0)))
 340                    (relief (if (and (integerp tool-bar-button-relief)
 341                                     (> tool-bar-button-relief 0))
 342                                tool-bar-button-relief 3))
 343                    (lines (/ (+ image-height
 344                                 (* 2 margin)
 345                                 (* 2 relief)
 346                                 (1- char-height))
 347                              char-height))
 348                    (height (frame-parameter frame-initial-frame 'height))
 349                    (newparms (list (cons 'height (- height lines))))
 350                    (initial-top (cdr (assq 'top
 351                                            frame-initial-geometry-arguments)))
 352                    (top (frame-parameter frame-initial-frame 'top)))
 353               (when (and (consp initial-top) (eq '- (car initial-top)))
 354                 (let ((adjusted-top
 355                        (cond ((and (consp top)
 356                                    (eq '+ (car top)))
 357                               (list '+
 358                                     (+ (cadr top)
 359                                        (* lines char-height))))
 360                              ((and (consp top)
 361                                    (eq '- (car top)))
 362                               (list '-
 363                                     (- (cadr top)
 364                                        (* lines char-height))))
 365                              (t (+ top (* lines char-height))))))
 366                   (setq newparms
 367                         (append newparms
 368                                 `((top . ,adjusted-top))
 369                                 nil))))
 370               (modify-frame-parameters frame-initial-frame newparms)
 371               (tool-bar-mode -1)))))
 372
 373       ;; The initial frame we create above always has a minibuffer.
 374       ;; If the user wants to remove it, or make it a minibuffer-only
 375       ;; frame, then we'll have to delete the current frame and make a
 376       ;; new one; you can't remove or add a root window to/from an
 377       ;; existing frame.
 378       ;;
 379       ;; NOTE: default-frame-alist was nil when we created the
 380       ;; existing frame.  We need to explicitly include
 381       ;; default-frame-alist in the parameters of the screen we
 382       ;; create here, so that its new value, gleaned from the user's
 383       ;; .emacs file, will be applied to the existing screen.
 384       (if (not (eq (cdr (or (assq 'minibuffer initial-frame-alist)
 385                             (assq 'minibuffer default-frame-alist)
 386                             '(minibuffer . t)))
 387                    t))
 388           ;; Create the new frame.
 389           (let (parms new)
 390             ;; If the frame isn't visible yet, wait till it is.
 391             ;; If the user has to position the window,
 392             ;; Emacs doesn't know its real position until
 393             ;; the frame is seen to be visible.
 394             (while (not (cdr (assq 'visibility
 395                                    (frame-parameters frame-initial-frame))))
 396               (sleep-for 1))
 397             (setq parms (frame-parameters frame-initial-frame))
 398
 399             ;; Get rid of `name' unless it was specified explicitly before.
 400             (or (assq 'name frame-initial-frame-alist)
 401                 (setq parms (delq (assq 'name parms) parms)))
 402
 403             (setq parms (append initial-frame-alist
 404                                 default-frame-alist
 405                                 parms
 406                                 nil))
 407
 408             ;; Get rid of `reverse', because that was handled
 409             ;; when we first made the frame.
 410             (setq parms (cons '(reverse) (delq (assq 'reverse parms) parms)))
 411
 412             (if (assq 'height frame-initial-geometry-arguments)
 413                 (setq parms (assq-delete-all 'height parms)))
 414             (if (assq 'width frame-initial-geometry-arguments)
 415                 (setq parms (assq-delete-all 'width parms)))
 416             (if (assq 'left frame-initial-geometry-arguments)
 417                 (setq parms (assq-delete-all 'left parms)))
 418             (if (assq 'top frame-initial-geometry-arguments)
 419                 (setq parms (assq-delete-all 'top parms)))
 420             (setq new
 421                   (make-frame
 422                    ;; Use the geometry args that created the existing
 423                    ;; frame, rather than the parms we get for it.
 424                    (append frame-initial-geometry-arguments
 425                            '((user-size . t) (user-position . t))
 426                            parms)))
 427             ;; The initial frame, which we are about to delete, may be
 428             ;; the only frame with a minibuffer.  If it is, create a
 429             ;; new one.
 430             (or (delq frame-initial-frame (minibuffer-frame-list))
 431                 (make-initial-minibuffer-frame nil))
 432
 433             ;; If the initial frame is serving as a surrogate
 434             ;; minibuffer frame for any frames, we need to wean them
 435             ;; onto a new frame.  The default-minibuffer-frame
 436             ;; variable must be handled similarly.
 437             (let ((users-of-initial
 438                    (filtered-frame-list
 439                     (function (lambda (frame)
 440                                 (and (not (eq frame frame-initial-frame))
 441                                      (eq (window-frame
 442                                           (minibuffer-window frame))
 443                                          frame-initial-frame)))))))
 444               (if (or users-of-initial
 445                       (eq default-minibuffer-frame frame-initial-frame))
 446
 447                   ;; Choose an appropriate frame.  Prefer frames which
 448                   ;; are only minibuffers.
 449                   (let* ((new-surrogate
 450                           (car
 451                            (or (filtered-frame-list
 452                                 (function
 453                                  (lambda (frame)
 454                                    (eq (cdr (assq 'minibuffer
 455                                                   (frame-parameters frame)))
 456                                        'only))))
 457                                (minibuffer-frame-list))))
 458                          (new-minibuffer (minibuffer-window new-surrogate)))
 459
 460                     (if (eq default-minibuffer-frame frame-initial-frame)
 461                         (setq default-minibuffer-frame new-surrogate))
 462
 463                     ;; Wean the frames using frame-initial-frame as
 464                     ;; their minibuffer frame.
 465                     (mapcar
 466                      (function
 467                       (lambda (frame)
 468                         (modify-frame-parameters
 469                          frame (list (cons 'minibuffer new-minibuffer)))))
 470                      users-of-initial))))
 471
 472            ;; Redirect events enqueued at this frame to the new frame.
 473             ;; Is this a good idea?
 474             (redirect-frame-focus frame-initial-frame new)
 475
 476             ;; Finally, get rid of the old frame.
 477             (delete-frame frame-initial-frame t))
 478
 479         ;; Otherwise, we don't need all that rigamarole; just apply
 480         ;; the new parameters.
 481         (let (newparms allparms tail)
 482           (setq allparms (append initial-frame-alist
 483                                  default-frame-alist nil))
 484           (if (assq 'height frame-initial-geometry-arguments)
 485               (setq allparms (assq-delete-all 'height allparms)))
 486           (if (assq 'width frame-initial-geometry-arguments)
 487               (setq allparms (assq-delete-all 'width allparms)))
 488           (if (assq 'left frame-initial-geometry-arguments)
 489               (setq allparms (assq-delete-all 'left allparms)))
 490           (if (assq 'top frame-initial-geometry-arguments)
 491               (setq allparms (assq-delete-all 'top allparms)))
 492           (setq tail allparms)
 493           ;; Find just the parms that have changed since we first
 494           ;; made this frame.  Those are the ones actually set by
 495           ;; the init file.  For those parms whose values we already knew
 496           ;; (such as those spec'd by command line options)
 497           ;; it is undesirable to specify the parm again
 498           ;; once the user has seen the frame and been able to alter it
 499           ;; manually.
 500           (while tail
 501             (let (newval oldval)
 502               (setq oldval (assq (car (car tail))
 503                                  frame-initial-frame-alist))
 504               (setq newval (cdr (assq (car (car tail)) allparms)))
 505               (or (and oldval (eq (cdr oldval) newval))
 506                   (setq newparms
 507                         (cons (cons (car (car tail)) newval) newparms))))
 508             (setq tail (cdr tail)))
 509           (setq newparms (nreverse newparms))
 510           (modify-frame-parameters frame-initial-frame
 511                                    newparms)
 512           ;; If we changed the background color,
 513           ;; we need to update the background-mode parameter
 514           ;; and maybe some faces too.
 515           (when (assq 'background-color newparms)
 516             (unless (assq 'background-mode newparms)
 517               (frame-set-background-mode frame-initial-frame))
 518             (face-set-after-frame-default frame-initial-frame)))))
 519
 520     ;; Restore the original buffer.
 521     (set-buffer old-buffer)
 522
 523     ;; Make sure the initial frame can be GC'd if it is ever deleted.
 524     ;; Make sure frame-notice-user-settings does nothing if called twice.
 525     (setq frame-notice-user-settings nil)
 526     (setq frame-initial-frame nil)))
 527
 528 (defun make-initial-minibuffer-frame (display)
 529   (let ((parms (append minibuffer-frame-alist '((minibuffer . only)))))
 530     (if display
 531         (make-frame-on-display display parms)
 532       (make-frame parms))))
 533
 534 ;;;; Creation of additional frames, and other frame miscellanea
 535
 536 (defun modify-all-frames-parameters (alist)
 537   "Modify all current and future frames' parameters according to ALIST.
 538 This changes `default-frame-alist' and possibly `initial-frame-alist'.
 539 See help of `modify-frame-parameters' for more information."
 540   (let (element)                        ;; temp
 541     (dolist (frame (frame-list))
 542       (modify-frame-parameters frame alist))
 543
 544     (dolist (pair alist)                ;; conses to add/replace
 545       ;; initial-frame-alist needs setting only when
 546       ;; frame-notice-user-settings is true
 547       (and frame-notice-user-settings
 548            (setq element (assoc (car pair) initial-frame-alist))
 549            (setq initial-frame-alist (delq element initial-frame-alist)))
 550       (and (setq element (assoc (car pair) default-frame-alist))
 551            (setq default-frame-alist (delq element default-frame-alist)))))
 552   (and frame-notice-user-settings
 553        (setq initial-frame-alist (append initial-frame-alist alist)))
 554   (setq default-frame-alist (append default-frame-alist alist)))
 555
 556 (defun get-other-frame ()
 557   "Return some frame other than the current frame.
 558 Create one if necessary.  Note that the minibuffer frame, if separate,
 559 is not considered (see `next-frame')."
 560   (let ((s (if (equal (next-frame (selected-frame)) (selected-frame))
 561                (make-frame)
 562              (next-frame (selected-frame)))))
 563     s))
 564
 565 (defun next-multiframe-window ()
 566   "Select the next window, regardless of which frame it is on."
 567   (interactive)
 568   (select-window (next-window (selected-window)
 569                               (> (minibuffer-depth) 0)
 570                               0))
 571   (select-frame-set-input-focus (selected-frame)))
 572
 573 (defun previous-multiframe-window ()
 574   "Select the previous window, regardless of which frame it is on."
 575   (interactive)
 576   (select-window (previous-window (selected-window)
 577                                   (> (minibuffer-depth) 0)
 578                                   0))
 579   (select-frame-set-input-focus (selected-frame)))
 580
 581 (defun make-frame-on-display (display &optional parameters)
 582   "Make a frame on X display DISPLAY.
 583 The optional second argument PARAMETERS specifies additional frame parameters."
 584   (interactive "sMake frame on display: ")
 585   (or (string-match "\\`[^:]*:[0-9]+\\(\\.[0-9]+\\)?\\'" display)
 586       (error "Invalid display, not HOST:SERVER or HOST:SERVER.SCREEN"))
 587   (when (and (boundp 'x-initialized) (not x-initialized))
 588     (setq x-display-name display)
 589     (x-initialize-window-system))
 590   (make-frame `((window-system . x) (display . ,display) . ,parameters)))
 591
 592 (defun make-frame-on-tty (device type &optional parameters)
 593   "Make a frame on terminal DEVICE which is of type TYPE (e.g., \"xterm\").
 594 The optional third argument PARAMETERS specifies additional frame parameters."
 595   (interactive "fOpen frame on tty device: \nsTerminal type of %s: ")
 596   (unless device
 597     (error "Invalid terminal device"))
 598   (unless type
 599     (error "Invalid terminal type"))
 600   (make-frame `((window-system . nil) (tty . ,device) (tty-type . ,type) . ,parameters)))
 601
 602 (defun make-frame-command ()
 603   "Make a new frame, and select it if the terminal displays only one frame."
 604   (interactive)
 605   (if (and window-system (not (eq window-system 'pc)))
 606       (make-frame)
 607     (select-frame (make-frame))))
 608
 609 (defvar before-make-frame-hook nil
 610   "Functions to run before a frame is created.")
 611
 612 (defvar after-make-frame-functions nil
 613   "Functions to run after a frame is created.
 614 The functions are run with one arg, the newly created frame.")
 615
 616 (defvar after-setting-font-hook nil
 617   "Functions to run after a frame's font has been changed.")
 618
 619 ;; Alias, kept temporarily.
 620 (define-obsolete-function-alias 'new-frame 'make-frame "22.1")
 621
 622 (defun make-frame (&optional parameters)
 623   "Return a newly created frame displaying the current buffer.
 624 Optional argument PARAMETERS is an alist of parameters for the new frame.
 625 Each element of PARAMETERS should have the form (NAME . VALUE), for example:
 626
 627  (name . STRING)        The frame should be named STRING.
 628
 629  (width . NUMBER)       The frame should be NUMBER characters in width.
 630  (height . NUMBER)      The frame should be NUMBER text lines high.
 631
 632 You cannot specify either `width' or `height', you must use neither or both.
 633
 634  (minibuffer . t)       The frame should have a minibuffer.
 635  (minibuffer . nil)     The frame should have no minibuffer.
 636  (minibuffer . only)    The frame should contain only a minibuffer.
 637  (minibuffer . WINDOW)  The frame should use WINDOW as its minibuffer window.
 638
 639  (window-system . nil)  The frame should be displayed on a terminal device.
 640  (window-system . x)    The frame should be displayed in an X window.
 641
 642  (device . ID)          The frame should use the display device identified by ID.
 643
 644 Before the frame is created (via `frame-creation-function-alist'), functions on the
 645 hook `before-make-frame-hook' are run.  After the frame is created, functions
 646 on `after-make-frame-functions' are run with one arg, the newly created frame.
 647
 648 This function itself does not make the new frame the selected frame.
 649 The previously selected frame remains selected.  However, the
 650 window system may select the new frame for its own reasons, for
 651 instance if the frame appears under the mouse pointer and your
 652 setup is for focus to follow the pointer."
 653   (interactive)
 654   (let* ((w (cond
 655              ((assq 'device parameters)
 656               (let ((type (display-live-p (cdr (assq 'device parameters)))))
 657                 (cond
 658                  ((eq type t) nil)
 659                  ((eq type nil) (error "Display %s does not exist" (cdr (assq 'device parameters))))
 660                  (t type))))
 661              ((assq 'window-system parameters)
 662               (cdr (assq 'window-system parameters)))
 663              (t window-system)))
 664          (frame-creation-function (cdr (assq w frame-creation-function-alist)))
 665          frame)
 666     (unless frame-creation-function
 667       (error "Don't know how to create a frame on window system %s" w))
 668     (run-hooks 'before-make-frame-hook)
 669     (setq frame (funcall frame-creation-function (append parameters (cdr (assq w window-system-default-frame-alist)))))
 670     (run-hook-with-args 'after-make-frame-functions frame)
 671     frame))
 672
 673 (defun filtered-frame-list (predicate)
 674   "Return a list of all live frames which satisfy PREDICATE."
 675   (let* ((frames (frame-list))
 676          (list frames))
 677     (while (consp frames)
 678       (unless (funcall predicate (car frames))
 679         (setcar frames nil))
 680       (setq frames (cdr frames)))
 681     (delq nil list)))
 682
 683 (defun minibuffer-frame-list ()
 684   "Return a list of all frames with their own minibuffers."
 685   (filtered-frame-list
 686    (function (lambda (frame)
 687                (eq frame (window-frame (minibuffer-window frame)))))))
 688
 689 (defun frames-on-display-list (&optional display)
 690   "Return a list of all frames on DISPLAY.
 691
 692 DISPLAY should be a display identifier (an integer), but it may
 693 also be a name of a display, a string of the form HOST:SERVER.SCREEN.
 694
 695 If DISPLAY is omitted or nil, it defaults to the selected frame's display."
 696   (let* ((display (or display (frame-display)))
 697          (func #'(lambda (frame)
 698                    (or (eq (frame-display frame) display)
 699                        (equal (frame-parameter frame 'display) display)))))
 700     (filtered-frame-list func)))
 701
 702 (defun framep-on-display (&optional display)
 703   "Return the type of frames on DISPLAY.
 704 DISPLAY may be a display id, a display name or a frame.  If it is
 705 a frame, its type is returned.
 706 If DISPLAY is omitted or nil, it defaults to the selected frame's display.
 707 All frames on a given display are of the same type."
 708   (or (display-live-p display)
 709       (framep display)
 710       (framep (car (frames-on-display-list display)))))
 711
 712 (defun frame-remove-geometry-params (param-list)
 713   "Return the parameter list PARAM-LIST, but with geometry specs removed.
 714 This deletes all bindings in PARAM-LIST for `top', `left', `width',
 715 `height', `user-size' and `user-position' parameters.
 716 Emacs uses this to avoid overriding explicit moves and resizings from
 717 the user during startup."
 718   (setq param-list (cons nil param-list))
 719   (let ((tail param-list))
 720     (while (consp (cdr tail))
 721       (if (and (consp (car (cdr tail)))
 722                (memq (car (car (cdr tail)))
 723                      '(height width top left user-position user-size)))
 724           (progn
 725             (setq frame-initial-geometry-arguments
 726                   (cons (car (cdr tail)) frame-initial-geometry-arguments))
 727             (setcdr tail (cdr (cdr tail))))
 728         (setq tail (cdr tail)))))
 729   (setq frame-initial-geometry-arguments
 730         (nreverse frame-initial-geometry-arguments))
 731   (cdr param-list))
 732
 733 (defcustom focus-follows-mouse t
 734   "*Non-nil if window system changes focus when you move the mouse.
 735 You should set this variable to tell Emacs how your window manager
 736 handles focus, since there is no way in general for Emacs to find out
 737 automatically."
 738   :type 'boolean
 739   :group 'frames
 740   :version "20.3")
 741
 742 (defun select-frame-set-input-focus (frame)
 743   "Select FRAME, raise it, and set input focus, if possible."
 744     (select-frame frame)
 745     (raise-frame frame)
 746     ;; Ensure, if possible, that frame gets input focus.
 747     (cond ((eq (window-system frame) 'x)
 748            (x-focus-frame frame))
 749           ((eq (window-system frame) 'w32)
 750            (w32-focus-frame frame)))
 751     (cond (focus-follows-mouse
 752            (set-mouse-position (selected-frame) (1- (frame-width)) 0))))
 753
 754 (defun other-frame (arg)
 755   "Select the ARG'th different visible frame on current display, and raise it.
 756 All frames are arranged in a cyclic order.
 757 This command selects the frame ARG steps away in that order.
 758 A negative ARG moves in the opposite order.
 759
 760 To make this command work properly, you must tell Emacs
 761 how the system (or the window manager) generally handles
 762 focus-switching between windows.  If moving the mouse onto a window
 763 selects it (gives it focus), set `focus-follows-mouse' to t.
 764 Otherwise, that variable should be nil."
 765   (interactive "p")
 766   (let ((frame (selected-frame)))
 767     (while (> arg 0)
 768       (setq frame (next-frame frame))
 769       (while (not (eq (frame-visible-p frame) t))
 770         (setq frame (next-frame frame)))
 771       (setq arg (1- arg)))
 772     (while (< arg 0)
 773       (setq frame (previous-frame frame))
 774       (while (not (eq (frame-visible-p frame) t))
 775         (setq frame (previous-frame frame)))
 776       (setq arg (1+ arg)))
 777     (select-frame-set-input-focus frame)))
 778
 779 (defun iconify-or-deiconify-frame ()
 780   "Iconify the selected frame, or deiconify if it's currently an icon."
 781   (interactive)
 782   (if (eq (cdr (assq 'visibility (frame-parameters))) t)
 783       (iconify-frame)
 784     (make-frame-visible)))
 785
 786 (defun suspend-frame ()
 787   "Do whatever is right to suspend the current frame.
 788 Calls `suspend-emacs' if invoked from the controlling terminal,
 789 `suspend-tty' from a secondary terminal, and
 790 `iconify-or-deiconify-frame' from an X frame."
 791   (interactive)
 792   (let ((type (framep (selected-frame))))
 793     (cond
 794      ((eq type 'x) (iconify-or-deiconify-frame))
 795      ((eq type t)
 796       (if (display-controlling-tty-p)
 797           (suspend-emacs)
 798         (suspend-tty)))
 799      (t (suspend-emacs)))))
 800
 801
 802 (defun make-frame-names-alist ()
 803   (let* ((current-frame (selected-frame))
 804          (falist
 805           (cons
 806            (cons (frame-parameter current-frame 'name) current-frame) nil))
 807          (frame (next-frame nil t)))
 808     (while (not (eq frame current-frame))
 809       (progn
 810         (setq falist (cons (cons (frame-parameter frame 'name) frame) falist))
 811         (setq frame (next-frame frame t))))
 812     falist))
 813
 814 (defvar frame-name-history nil)
 815 (defun select-frame-by-name (name)
 816   "Select the frame on the current terminal whose name is NAME and raise it.
 817 If there is no frame by that name, signal an error."
 818   (interactive
 819    (let* ((frame-names-alist (make-frame-names-alist))
 820            (default (car (car frame-names-alist)))
 821            (input (completing-read
 822                    (format "Select Frame (default %s): " default)
 823                    frame-names-alist nil t nil 'frame-name-history)))
 824      (if (= (length input) 0)
 825          (list default)
 826        (list input))))
 827   (let* ((frame-names-alist (make-frame-names-alist))
 828          (frame (cdr (assoc name frame-names-alist))))
 829     (or frame
 830         (error "There is no frame named `%s'" name))
 831     (make-frame-visible frame)
 832     (raise-frame frame)
 833     (select-frame frame)
 834     ;; Ensure, if possible, that frame gets input focus.
 835     (cond ((eq (window-system frame) 'x)
 836            (x-focus-frame frame))
 837           ((eq (window-system frame) 'w32)
 838            (w32-focus-frame frame)))
 839     (when focus-follows-mouse
 840       (set-mouse-position frame (1- (frame-width frame)) 0))))
 841 \f
 842 ;;;; Frame configurations
 843
 844 (defun current-frame-configuration ()
 845   "Return a list describing the positions and states of all frames.
 846 Its car is `frame-configuration'.
 847 Each element of the cdr is a list of the form (FRAME ALIST WINDOW-CONFIG),
 848 where
 849   FRAME is a frame object,
 850   ALIST is an association list specifying some of FRAME's parameters, and
 851   WINDOW-CONFIG is a window configuration object for FRAME."
 852   (cons 'frame-configuration
 853         (mapcar (function
 854                  (lambda (frame)
 855                    (list frame
 856                          (frame-parameters frame)
 857                          (current-window-configuration frame))))
 858                 (frame-list))))
 859
 860 (defun set-frame-configuration (configuration &optional nodelete)
 861   "Restore the frames to the state described by CONFIGURATION.
 862 Each frame listed in CONFIGURATION has its position, size, window
 863 configuration, and other parameters set as specified in CONFIGURATION.
 864 However, this function does not restore deleted frames.
 865
 866 Ordinarily, this function deletes all existing frames not
 867 listed in CONFIGURATION.  But if optional second argument NODELETE
 868 is given and non-nil, the unwanted frames are iconified instead."
 869   (or (frame-configuration-p configuration)
 870       (signal 'wrong-type-argument
 871               (list 'frame-configuration-p configuration)))
 872   (let ((config-alist (cdr configuration))
 873         frames-to-delete)
 874     (mapcar (function
 875              (lambda (frame)
 876                (let ((parameters (assq frame config-alist)))
 877                  (if parameters
 878                      (progn
 879                        (modify-frame-parameters
 880                         frame
 881                         ;; Since we can't set a frame's minibuffer status,
 882                         ;; we might as well omit the parameter altogether.
 883                         (let* ((parms (nth 1 parameters))
 884                                (mini (assq 'minibuffer parms)))
 885                           (if mini (setq parms (delq mini parms)))
 886                           parms))
 887                        (set-window-configuration (nth 2 parameters)))
 888                    (setq frames-to-delete (cons frame frames-to-delete))))))
 889             (frame-list))
 890     (if nodelete
 891         ;; Note: making frames invisible here was tried
 892         ;; but led to some strange behavior--each time the frame
 893         ;; was made visible again, the window manager asked afresh
 894         ;; for where to put it.
 895         (mapcar 'iconify-frame frames-to-delete)
 896       (mapcar 'delete-frame frames-to-delete))))
 897 \f
 898 ;;;; Convenience functions for accessing and interactively changing
 899 ;;;; frame parameters.
 900
 901 (defun frame-height (&optional frame)
 902   "Return number of lines available for display on FRAME.
 903 If FRAME is omitted, describe the currently selected frame."
 904   (cdr (assq 'height (frame-parameters frame))))
 905
 906 (defun frame-width (&optional frame)
 907   "Return number of columns available for display on FRAME.
 908 If FRAME is omitted, describe the currently selected frame."
 909   (cdr (assq 'width (frame-parameters frame))))
 910
 911 (defalias 'set-default-font 'set-frame-font)
 912 (defun set-frame-font (font-name &optional keep-size)
 913   "Set the font of the selected frame to FONT-NAME.
 914 When called interactively, prompt for the name of the font to use.
 915 To get the frame's current default font, use `frame-parameters'.
 916
 917 The default behavior is to keep the numbers of lines and columns in
 918 the frame, thus may change its pixel size.  If optional KEEP-SIZE is
 919 non-nil (interactively, prefix argument) the current frame size (in
 920 pixels) is kept by adjusting the numbers of the lines and columns."
 921   (interactive
 922    (let* ((completion-ignore-case t)
 923           (font (completing-read "Font name: "
 924                          (mapcar #'list
 925                                  ;; x-list-fonts will fail with an error
 926                                  ;; if this frame doesn't support fonts.
 927                                  (x-list-fonts "*" nil (selected-frame)))
 928                          nil nil nil nil
 929                          (frame-parameter nil 'font))))
 930      (list font current-prefix-arg)))
 931   (let (fht fwd)
 932     (if keep-size
 933         (setq fht (* (frame-parameter nil 'height) (frame-char-height))
 934               fwd (* (frame-parameter nil 'width)  (frame-char-width))))
 935     (modify-frame-parameters (selected-frame)
 936                              (list (cons 'font font-name)))
 937     (if keep-size
 938         (modify-frame-parameters
 939          (selected-frame)
 940          (list (cons 'height (round fht (frame-char-height)))
 941                (cons 'width (round fwd (frame-char-width)))))))
 942   (run-hooks 'after-setting-font-hook 'after-setting-font-hooks))
 943
 944 (defun set-frame-parameter (frame parameter value)
 945   (modify-frame-parameters frame (list (cons parameter value))))
 946
 947 (defun set-background-color (color-name)
 948   "Set the background color of the selected frame to COLOR-NAME.
 949 When called interactively, prompt for the name of the color to use.
 950 To get the frame's current background color, use `frame-parameters'."
 951   (interactive (list (facemenu-read-color)))
 952   (modify-frame-parameters (selected-frame)
 953                            (list (cons 'background-color color-name)))
 954   (or window-system
 955       (face-set-after-frame-default (selected-frame))))
 956
 957 (defun set-foreground-color (color-name)
 958   "Set the foreground color of the selected frame to COLOR-NAME.
 959 When called interactively, prompt for the name of the color to use.
 960 To get the frame's current foreground color, use `frame-parameters'."
 961   (interactive (list (facemenu-read-color)))
 962   (modify-frame-parameters (selected-frame)
 963                            (list (cons 'foreground-color color-name)))
 964   (or window-system
 965       (face-set-after-frame-default (selected-frame))))
 966
 967 (defun set-cursor-color (color-name)
 968   "Set the text cursor color of the selected frame to COLOR-NAME.
 969 When called interactively, prompt for the name of the color to use.
 970 To get the frame's current cursor color, use `frame-parameters'."
 971   (interactive (list (facemenu-read-color)))
 972   (modify-frame-parameters (selected-frame)
 973                            (list (cons 'cursor-color color-name))))
 974
 975 (defun set-mouse-color (color-name)
 976   "Set the color of the mouse pointer of the selected frame to COLOR-NAME.
 977 When called interactively, prompt for the name of the color to use.
 978 To get the frame's current mouse color, use `frame-parameters'."
 979   (interactive (list (facemenu-read-color)))
 980   (modify-frame-parameters (selected-frame)
 981                            (list (cons 'mouse-color
 982                                        (or color-name
 983                                            (cdr (assq 'mouse-color
 984                                                       (frame-parameters))))))))
 985
 986 (defun set-border-color (color-name)
 987   "Set the color of the border of the selected frame to COLOR-NAME.
 988 When called interactively, prompt for the name of the color to use.
 989 To get the frame's current border color, use `frame-parameters'."
 990   (interactive (list (facemenu-read-color)))
 991   (modify-frame-parameters (selected-frame)
 992                            (list (cons 'border-color color-name))))
 993
 994 (defun auto-raise-mode (arg)
 995   "Toggle whether or not the selected frame should auto-raise.
 996 With arg, turn auto-raise mode on if and only if arg is positive.
 997 Note that this controls Emacs's own auto-raise feature.
 998 Some window managers allow you to enable auto-raise for certain windows.
 999 You can use that for Emacs windows if you wish, but if you do,
1000 that is beyond the control of Emacs and this command has no effect on it."
1001   (interactive "P")
1002   (if (null arg)
1003       (setq arg
1004             (if (cdr (assq 'auto-raise (frame-parameters (selected-frame))))
1005                 -1 1)))
1006   (if (> arg 0)
1007       (raise-frame (selected-frame)))
1008   (modify-frame-parameters (selected-frame)
1009                            (list (cons 'auto-raise (> arg 0)))))
1010
1011 (defun auto-lower-mode (arg)
1012   "Toggle whether or not the selected frame should auto-lower.
1013 With arg, turn auto-lower mode on if and only if arg is positive.
1014 Note that this controls Emacs's own auto-lower feature.
1015 Some window managers allow you to enable auto-lower for certain windows.
1016 You can use that for Emacs windows if you wish, but if you do,
1017 that is beyond the control of Emacs and this command has no effect on it."
1018   (interactive "P")
1019   (if (null arg)
1020       (setq arg
1021             (if (cdr (assq 'auto-lower (frame-parameters (selected-frame))))
1022                 -1 1)))
1023   (modify-frame-parameters (selected-frame)
1024                            (list (cons 'auto-lower (> arg 0)))))
1025 (defun set-frame-name (name)
1026   "Set the name of the selected frame to NAME.
1027 When called interactively, prompt for the name of the frame.
1028 The frame name is displayed on the modeline if the terminal displays only
1029 one frame, otherwise the name is displayed on the frame's caption bar."
1030   (interactive "sFrame name: ")
1031   (modify-frame-parameters (selected-frame)
1032                            (list (cons 'name name))))
1033
1034 (defun frame-current-scroll-bars (&optional frame)
1035   "Return the current scroll-bar settings in frame FRAME.
1036 Value is a cons (VERTICAL . HORIZ0NTAL) where VERTICAL specifies the
1037 current location of the vertical scroll-bars (left, right, or nil),
1038 and HORIZONTAL specifies the current location of the horizontal scroll
1039 bars (top, bottom, or nil)."
1040   (let ((vert (frame-parameter frame 'vertical-scroll-bars))
1041         (hor nil))
1042     (unless (memq vert '(left right nil))
1043       (setq vert default-frame-scroll-bars))
1044     (cons vert hor)))
1045 \f
1046 ;;;; Frame/display capabilities.
1047 (defun selected-display ()
1048   "Return the display that is now selected."
1049   (frame-display (selected-frame)))
1050
1051 (defun display-mouse-p (&optional display)
1052   "Return non-nil if DISPLAY has a mouse available.
1053 DISPLAY can be a display name, a frame, or nil (meaning the selected
1054 frame's display)."
1055   (let ((frame-type (framep-on-display display)))
1056     (cond
1057      ((eq frame-type 'pc)
1058       (msdos-mouse-p))
1059      ((eq system-type 'windows-nt)
1060       (with-no-warnings
1061        (> w32-num-mouse-buttons 0)))
1062      ((memq frame-type '(x mac))
1063       t)    ;; We assume X and Mac *always* have a pointing device
1064      (t
1065       (or (and (featurep 'xt-mouse)
1066                xterm-mouse-mode)
1067           ;; t-mouse is distributed with the GPM package.  It doesn't have
1068           ;; a toggle.
1069           (featurep 't-mouse))))))
1070
1071 (defun display-popup-menus-p (&optional display)
1072   "Return non-nil if popup menus are supported on DISPLAY.
1073 DISPLAY can be a display name, a frame, or nil (meaning the selected
1074 frame's display).
1075 Support for popup menus requires that the mouse be available."
1076   (and
1077    (let ((frame-type (framep-on-display display)))
1078      (memq frame-type '(x w32 pc mac)))
1079    (display-mouse-p display)))
1080
1081 (defun display-graphic-p (&optional display)
1082   "Return non-nil if DISPLAY is a graphic display.
1083 Graphical displays are those which are capable of displaying several
1084 frames and several different fonts at once.  This is true for displays
1085 that use a window system such as X, and false for text-only terminals.
1086 DISPLAY can be a display name, a frame, or nil (meaning the selected
1087 frame's display)."
1088   (not (null (memq (framep-on-display display) '(x w32 mac)))))
1089
1090 (defun display-images-p (&optional display)
1091   "Return non-nil if DISPLAY can display images.
1092
1093 DISPLAY can be a display name, a frame, or nil (meaning the selected
1094 frame's display)."
1095   (and (display-graphic-p display)
1096        (fboundp 'image-mask-p)
1097        (fboundp 'image-size)))
1098
1099 (defalias 'display-multi-frame-p 'display-graphic-p)
1100 (defalias 'display-multi-font-p 'display-graphic-p)
1101
1102 (defun display-selections-p (&optional display)
1103   "Return non-nil if DISPLAY supports selections.
1104 A selection is a way to transfer text or other data between programs
1105 via special system buffers called `selection' or `cut buffer' or
1106 `clipboard'.
1107 DISPLAY can be a display name, a frame, or nil (meaning the selected
1108 frame's display)."
1109   (let ((frame-type (framep-on-display display)))
1110     (cond
1111      ((eq frame-type 'pc)
1112       ;; MS-DOG frames support selections when Emacs runs inside
1113       ;; the Windows' DOS Box.
1114       (with-no-warnings
1115        (not (null dos-windows-version))))
1116      ((memq frame-type '(x w32 mac))
1117       t)    ;; FIXME?
1118      (t
1119       nil))))
1120
1121 (defun display-screens (&optional display)
1122   "Return the number of screens associated with DISPLAY."
1123   (let ((frame-type (framep-on-display display)))
1124     (cond
1125      ((memq frame-type '(x w32))
1126       (x-display-screens display))
1127      (t ;; FIXME: is this correct for the Mac?
1128       1))))
1129
1130 (defun display-pixel-height (&optional display)
1131   "Return the height of DISPLAY's screen in pixels.
1132 For character terminals, each character counts as a single pixel."
1133   (let ((frame-type (framep-on-display display)))
1134     (cond
1135      ((memq frame-type '(x w32 mac))
1136       (x-display-pixel-height display))
1137      (t
1138       (frame-height (if (framep display) display (selected-frame)))))))
1139
1140 (defun display-pixel-width (&optional display)
1141   "Return the width of DISPLAY's screen in pixels.
1142 For character terminals, each character counts as a single pixel."
1143   (let ((frame-type (framep-on-display display)))
1144     (cond
1145      ((memq frame-type '(x w32 mac))
1146       (x-display-pixel-width display))
1147      (t
1148       (frame-width (if (framep display) display (selected-frame)))))))
1149
1150 (defun display-mm-height (&optional display)
1151   "Return the height of DISPLAY's screen in millimeters.
1152 If the information is unavailable, value is nil."
1153   (and (memq (framep-on-display display) '(x w32 mac))
1154        (x-display-mm-height display)))
1155
1156 (defun display-mm-width (&optional display)
1157   "Return the width of DISPLAY's screen in millimeters.
1158 If the information is unavailable, value is nil."
1159   (and (memq (framep-on-display display) '(x w32 mac))
1160        (x-display-mm-width display)))
1161
1162 (defun display-backing-store (&optional display)
1163   "Return the backing store capability of DISPLAY's screen.
1164 The value may be `always', `when-mapped', `not-useful', or nil if
1165 the question is inapplicable to a certain kind of display."
1166   (let ((frame-type (framep-on-display display)))
1167     (cond
1168      ((memq frame-type '(x w32 mac))
1169       (x-display-backing-store display))
1170      (t
1171       'not-useful))))
1172
1173 (defun display-save-under (&optional display)
1174   "Return non-nil if DISPLAY's screen supports the SaveUnder feature."
1175   (let ((frame-type (framep-on-display display)))
1176     (cond
1177      ((memq frame-type '(x w32 mac))
1178       (x-display-save-under display))
1179      (t
1180       'not-useful))))
1181
1182 (defun display-planes (&optional display)
1183   "Return the number of planes supported by DISPLAY."
1184   (let ((frame-type (framep-on-display display)))
1185     (cond
1186      ((memq frame-type '(x w32 mac))
1187       (x-display-planes display))
1188      ((eq frame-type 'pc)
1189       4)
1190      (t
1191       (truncate (log (length (tty-color-alist)) 2))))))
1192
1193 (defun display-color-cells (&optional display)
1194   "Return the number of color cells supported by DISPLAY."
1195   (let ((frame-type (framep-on-display display)))
1196     (cond
1197      ((memq frame-type '(x w32 mac))
1198       (x-display-color-cells display))
1199      ((eq frame-type 'pc)
1200       16)
1201      (t
1202       (tty-display-color-cells display)))))
1203
1204 (defun display-visual-class (&optional display)
1205   "Returns the visual class of DISPLAY.
1206 The value is one of the symbols `static-gray', `gray-scale',
1207 `static-color', `pseudo-color', `true-color', or `direct-color'."
1208   (let ((frame-type (framep-on-display display)))
1209     (cond
1210      ((memq frame-type '(x w32 mac))
1211       (x-display-visual-class display))
1212      ((and (memq frame-type '(pc t))
1213            (tty-display-color-p display))
1214       'static-color)
1215      (t
1216       'static-gray))))
1217
1218 \f
1219 ;;;; Aliases for backward compatibility with Emacs 18.
1220 (define-obsolete-function-alias 'screen-height 'frame-height) ;before 19.15
1221 (define-obsolete-function-alias 'screen-width 'frame-width) ;before 19.15
1222
1223 (defun set-screen-width (cols &optional pretend)
1224   "Change the size of the screen to COLS columns.
1225 Optional second arg non-nil means that redisplay should use COLS columns
1226 but that the idea of the actual width of the frame should not be changed.
1227 This function is provided only for compatibility with Emacs 18."
1228   (set-frame-width (selected-frame) cols pretend))
1229
1230 (defun set-screen-height (lines &optional pretend)
1231   "Change the height of the screen to LINES lines.
1232 Optional second arg non-nil means that redisplay should use LINES lines
1233 but that the idea of the actual height of the screen should not be changed.
1234 This function is provided only for compatibility with Emacs 18."
1235   (set-frame-height (selected-frame) lines pretend))
1236
1237 (defun delete-other-frames (&optional frame)
1238   "Delete all frames except FRAME.
1239 If FRAME uses another frame's minibuffer, the minibuffer frame is
1240 left untouched.  FRAME nil or omitted means use the selected frame."
1241   (interactive)
1242   (unless frame
1243     (setq frame (selected-frame)))
1244   (let* ((mini-frame (window-frame (minibuffer-window frame)))
1245          (frames (delq mini-frame (delq frame (frame-list)))))
1246     ;; Delete mon-minibuffer-only frames first, because `delete-frame'
1247     ;; signals an error when trying to delete a mini-frame that's
1248     ;; still in use by another frame.
1249     (dolist (frame frames)
1250       (unless (eq (frame-parameter frame 'minibuffer) 'only)
1251         (delete-frame frame)))
1252     ;; Delete minibuffer-only frames.
1253     (dolist (frame frames)
1254       (when (eq (frame-parameter frame 'minibuffer) 'only)
1255         (delete-frame frame)))))
1256
1257 (make-obsolete 'set-screen-width 'set-frame-width) ;before 19.15
1258 (make-obsolete 'set-screen-height 'set-frame-height) ;before 19.15
1259
1260 ;; miscellaneous obsolescence declarations
1261 (define-obsolete-variable-alias 'delete-frame-hook
1262     'delete-frame-functions "22.1")
1263
1264 \f
1265 ;; Highlighting trailing whitespace.
1266
1267 (make-variable-buffer-local 'show-trailing-whitespace)
1268
1269 (defcustom show-trailing-whitespace nil
1270   "*Non-nil means highlight trailing whitespace.
1271 This is done in the face `trailing-whitespace'."
1272   :tag "Highlight trailing whitespace."
1273   :type 'boolean
1274   :group 'whitespace-faces)
1275
1276
1277 \f
1278 ;; Scrolling
1279
1280 (defgroup scrolling nil
1281   "Scrolling windows."
1282   :version "21.1"
1283   :group 'frames)
1284
1285 (defcustom auto-hscroll-mode t
1286   "*Allow or disallow automatic scrolling windows horizontally.
1287 If non-nil, windows are automatically scrolled horizontally to make
1288 point visible."
1289   :version "21.1"
1290   :type 'boolean
1291   :group 'scrolling)
1292 (defvaralias 'automatic-hscrolling 'auto-hscroll-mode)
1293
1294 \f
1295 ;; Blinking cursor
1296
1297 (defgroup cursor nil
1298   "Displaying text cursors."
1299   :version "21.1"
1300   :group 'frames)
1301
1302 (defcustom blink-cursor-delay 0.5
1303   "*Seconds of idle time after which cursor starts to blink."
1304   :tag "Delay in seconds."
1305   :type 'number
1306   :group 'cursor)
1307
1308 (defcustom blink-cursor-interval 0.5
1309   "*Length of cursor blink interval in seconds."
1310   :tag "Blink interval in seconds."
1311   :type 'number
1312   :group 'cursor)
1313
1314 (defvar blink-cursor-idle-timer nil
1315   "Timer started after `blink-cursor-delay' seconds of Emacs idle time.
1316 The function `blink-cursor-start' is called when the timer fires.")
1317
1318 (defvar blink-cursor-timer nil
1319   "Timer started from `blink-cursor-start'.
1320 This timer calls `blink-cursor-timer-function' every
1321 `blink-cursor-interval' seconds.")
1322
1323 (define-minor-mode blink-cursor-mode
1324   "Toggle blinking cursor mode.
1325 With a numeric argument, turn blinking cursor mode on iff ARG is positive.
1326 When blinking cursor mode is enabled, the cursor of the selected
1327 window blinks.
1328
1329 Note that this command is effective only when Emacs
1330 displays through a window system, because then Emacs does its own
1331 cursor display.  On a text-only terminal, this is not implemented."
1332   :init-value (not (or noninteractive
1333                        no-blinking-cursor
1334                        (eq system-type 'ms-dos)
1335                        (not (memq initial-window-system '(x w32)))))
1336   :initialize 'custom-initialize-safe-default
1337   :group 'cursor
1338   :global t
1339   (if blink-cursor-idle-timer (cancel-timer blink-cursor-idle-timer))
1340   (if blink-cursor-timer (cancel-timer blink-cursor-timer))
1341   (setq blink-cursor-idle-timer nil
1342         blink-cursor-timer nil)
1343   (if blink-cursor-mode
1344       (progn
1345         ;; Hide the cursor.
1346         ;;(internal-show-cursor nil nil)
1347         (setq blink-cursor-idle-timer
1348               (run-with-idle-timer blink-cursor-delay
1349                                    blink-cursor-delay
1350                                    'blink-cursor-start)))
1351     (internal-show-cursor nil t)))
1352
1353 (define-obsolete-variable-alias 'blink-cursor 'blink-cursor-mode "22.1")
1354
1355 (defun blink-cursor-start ()
1356   "Timer function called from the timer `blink-cursor-idle-timer'.
1357 This starts the timer `blink-cursor-timer', which makes the cursor blink
1358 if appropriate.  It also arranges to cancel that timer when the next
1359 command starts, by installing a pre-command hook."
1360   (when (null blink-cursor-timer)
1361     (add-hook 'pre-command-hook 'blink-cursor-end)
1362     (internal-show-cursor nil nil)
1363     (setq blink-cursor-timer
1364           (run-with-timer blink-cursor-interval blink-cursor-interval
1365                           'blink-cursor-timer-function))))
1366
1367 (defun blink-cursor-timer-function ()
1368   "Timer function of timer `blink-cursor-timer'."
1369   (internal-show-cursor nil (not (internal-show-cursor-p))))
1370
1371 (defun blink-cursor-end ()
1372   "Stop cursor blinking.
1373 This is installed as a pre-command hook by `blink-cursor-start'.
1374 When run, it cancels the timer `blink-cursor-timer' and removes
1375 itself as a pre-command hook."
1376   (remove-hook 'pre-command-hook 'blink-cursor-end)
1377   (internal-show-cursor nil t)
1378   (cancel-timer blink-cursor-timer)
1379   (setq blink-cursor-timer nil))
1380
1381
1382 \f
1383 ;; Hourglass pointer
1384
1385 (defcustom display-hourglass t
1386   "*Non-nil means show an hourglass pointer when running under a window system."
1387   :tag "Hourglass pointer"
1388   :type 'boolean
1389   :group 'cursor)
1390
1391 (defcustom hourglass-delay 1
1392   "*Seconds to wait before displaying an hourglass pointer."
1393   :tag "Hourglass delay"
1394   :type 'number
1395   :group 'cursor)
1396
1397 \f
1398 (defcustom cursor-in-non-selected-windows t
1399   "*Non-nil means show a hollow box cursor in non-selected windows.
1400 If nil, don't show a cursor except in the selected window.
1401 Use Custom to set this variable to get the display updated."
1402   :tag "Cursor in non-selected windows"
1403   :type 'boolean
1404   :group 'cursor
1405   :set #'(lambda (symbol value)
1406            (set-default symbol value)
1407            (force-mode-line-update t)))
1408
1409 \f
1410 ;;;; Key bindings
1411
1412 (define-key ctl-x-5-map "2" 'make-frame-command)
1413 (define-key ctl-x-5-map "1" 'delete-other-frames)
1414 (define-key ctl-x-5-map "0" 'delete-frame)
1415 (define-key ctl-x-5-map "o" 'other-frame)
1416
1417 (substitute-key-definition 'suspend-emacs 'suspend-frame global-map)
1418
1419
1420 (defun terminal-id (terminal)
1421   "Return the numerical id of terminal TERMINAL.
1422
1423 TERMINAL can be a terminal id, a frame, or nil (meaning the
1424 selected frame's terminal)."
1425   (cond
1426    ((integerp terminal)
1427     terminal)
1428    ((or (null terminal) (framep terminal))
1429     (frame-display terminal))
1430    (t
1431     (error "Invalid argument %s in `terminal-id'" terminal))))
1432
1433 (defvar terminal-parameter-alist nil
1434   "An alist of terminal parameter alists.")
1435
1436 (defun terminal-parameters (&optional terminal)
1437   "Return the paramater-alist of terminal TERMINAL.
1438 It is a list of elements of the form (PARM . VALUE), where PARM is a symbol.
1439
1440 TERMINAL can be a terminal id, a frame, or nil (meaning the
1441 selected frame's terminal)."
1442   (cdr (assq (terminal-id terminal) terminal-parameter-alist)))
1443
1444 (defun terminal-parameter (terminal parameter)
1445   "Return TERMINAL's value for parameter PARAMETER.
1446
1447 TERMINAL can be a terminal id, a frame, or nil (meaning the
1448 selected frame's terminal)."
1449   (cdr (assq parameter (cdr (assq (terminal-id terminal) terminal-parameter-alist)))))
1450
1451 (defun set-terminal-parameter (terminal parameter value)
1452   "Set TERMINAL's value for parameter PARAMETER to VALUE.
1453 Returns the previous value of PARAMETER.
1454
1455 TERMINAL can be a terminal id, a frame, or nil (meaning the
1456 selected frame's terminal)."
1457   (setq terminal (terminal-id terminal))
1458   (let* ((alist (assq terminal terminal-parameter-alist))
1459          (pair (assq parameter (cdr alist)))
1460          (result (cdr pair)))
1461     (cond
1462      (pair (setcdr pair value))
1463      (alist (setcdr alist (cons (cons parameter value) (cdr alist))))
1464      (t (setq terminal-parameter-alist
1465               (cons (cons terminal
1466                           (cons (cons parameter value)
1467                                 nil))
1468                     terminal-parameter-alist))))
1469     result))
1470
1471 (defun terminal-handle-delete-frame (frame)
1472   "Clean up terminal parameters of FRAME, if it's the last frame on its terminal."
1473   ;; XXX We assume that the display is closed immediately after the
1474   ;; last frame is deleted on it.  It would be better to create a hook
1475   ;; called `delete-display-functions', and use it instead.
1476   (when (and (frame-live-p frame)
1477              (= 1 (length (frames-on-display-list (frame-display frame)))))
1478     (setq terminal-parameter-alist
1479           (assq-delete-all (frame-display frame) terminal-parameter-alist))))
1480
1481 (add-hook 'delete-frame-functions 'terminal-handle-delete-frame)
1482
1483 (provide 'frame)
1484
1485 ;; arch-tag: 82979c70-b8f2-4306-b2ad-ddbd6b328b56
1486 ;;; frame.el ends here