code.delx.au - gnu-emacs/blob - lisp/locate.el

   1 ;;; locate.el --- interface to the locate command
   2
   3 ;; Copyright (C) 1996, 1998, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Peter Breton <pbreton@cs.umb.edu>
   6 ;; Keywords: unix files
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Search a database of files and use dired commands on
  28 ;; the result.
  29 ;;
  30 \f
  31 ;;;;; Building a database of files ;;;;;;;;;
  32 ;;
  33 ;; You can create a simple files database with a port of the Unix find command
  34 ;; and one of the various Windows NT various scheduling utilities,
  35 ;; for example the AT command from the NT Resource Kit, WinCron which is
  36 ;; included with Microsoft FrontPage, or the shareware NTCron program.
  37 ;;
  38 ;; To set up a function which searches the files database, do something
  39 ;; like this:
  40 ;;
  41 ;; (defvar locate-fcodes-file       "c:/users/peter/fcodes")
  42 ;; (defvar locate-make-command-line 'nt-locate-make-command-line)
  43 ;;
  44 ;; (defun nt-locate-make-command-line (arg)
  45 ;;  (list "grep" "-i" arg locate-fcodes-file))
  46 ;;
  47 ;;;;;;;; ADVICE For dired-make-relative: ;;;;;;;;;
  48 ;;
  49 ;; For certain dired commands to work right, you should also include the
  50 ;; following in your _emacs/.emacs:
  51 ;;
  52 ;; (defadvice dired-make-relative (before set-no-error activate)
  53 ;;   "For locate mode and Windows, don't return errors"
  54 ;;   (if (and (eq   major-mode  'locate-mode)
  55 ;;         (memq system-type (list 'windows-nt 'ms-dos)))
  56 ;;       (ad-set-arg 2 t)
  57 ;;     ))
  58 ;;
  59 ;; Otherwise, `dired-make-relative' will give error messages like
  60 ;; "FILENAME: not in directory tree growing at /"
  61 \f
  62 ;;; Commentary:
  63 ;;
  64 ;; Locate.el provides an interface to a program which searches a
  65 ;; database of file names. By default, this program is the GNU locate
  66 ;; command, but it could also be the BSD-style find command, or even a
  67 ;; user specified command.
  68 ;;
  69 ;; To use the BSD-style "fast find", or any other shell command of the
  70 ;; form
  71 ;;
  72 ;;   SHELLPROGRAM  Name-to-find
  73 ;;
  74 ;; set the variable `locate-command' in your .emacs file.
  75 ;;
  76 ;;   To use a more complicated expression, create a function which
  77 ;; takes a string (the name to find) as input and returns a list.
  78 ;; The first element should be the command to be executed, the remaining
  79 ;; elements should be the arguments (including the name to find). Then put
  80 ;;
  81 ;; (setq locate-make-command-line 'my-locate-command-line)
  82 ;;
  83 ;; in your .emacs, using the name of your function in place of
  84 ;; my-locate-command-line.
  85 ;;
  86 ;; You should make sure that whichever command you use works correctly
  87 ;; from a shell prompt. GNU locate and BSD find expect the file databases
  88 ;; to either be in standard places or located via environment variables.
  89 ;; If the latter, make sure these environment variables are set in
  90 ;; your emacs process.
  91 ;;
  92 ;; Locate-mode assumes that each line output from the locate-command
  93 ;; consists exactly of a file name, possibly preceded or trailed by
  94 ;; whitespace. If your file database has other information on the line (for
  95 ;; example, the file size), you will need to redefine the function
  96 ;; `locate-get-file-positions' to return a list consisting of the first
  97 ;; character in the file name and the last character in the file name.
  98 ;;
  99 ;; To use locate-mode, simply type M-x locate and then the string
 100 ;; you wish to find. You can use almost all of the dired commands in
 101 ;; the resulting *Locate* buffer.  It is worth noting that your commands
 102 ;; do not, of course, affect the file database. For example, if you
 103 ;; compress a file in the locate buffer, the actual file will be
 104 ;; compressed, but the entry in the file database will not be
 105 ;; affected. Consequently, the database and the filesystem will be out
 106 ;; of sync until the next time the database is updated.
 107 ;;
 108 ;; The command `locate-with-filter' keeps only lines matching a
 109 ;; regular expression; this is often useful to constrain a big search.
 110 ;;
 111 \f
 112 ;;; Code:
 113
 114 (eval-when-compile
 115   (require 'dired))
 116
 117 ;; Variables
 118
 119 (defvar locate-current-filter nil)
 120
 121 (defgroup locate nil
 122   "Interface to the locate command."
 123   :prefix "locate-"
 124   :group 'external)
 125
 126 (defcustom locate-command "locate"
 127   "*The executable program used to search a database of files."
 128   :type 'string
 129   :group 'locate)
 130
 131 (defvar locate-history-list nil
 132   "The history list used by the \\[locate] command.")
 133
 134 (defvar locate-grep-history-list nil
 135   "The history list used by the \\[locate-with-filter] command.")
 136
 137 (defcustom locate-make-command-line 'locate-default-make-command-line
 138   "*Function used to create the locate command line."
 139   :type 'function
 140   :group 'locate)
 141
 142 (defcustom locate-buffer-name "*Locate*"
 143   "*Name of the buffer to show results from the \\[locate] command."
 144   :type 'string
 145   :group 'locate)
 146
 147 (defcustom locate-fcodes-file nil
 148   "*File name for the database of file names."
 149   :type '(choice file (const nil))
 150   :group 'locate)
 151
 152 (defcustom locate-header-face nil
 153   "*Face used to highlight the locate header."
 154   :type 'face
 155   :group 'locate)
 156
 157 (defcustom locate-update-command "updatedb"
 158   "The command used to update the locate database."
 159   :type 'string
 160   :group 'locate)
 161
 162 (defcustom locate-prompt-for-command nil
 163   "If non-nil, the default behavior of the locate command is to prompt for a command to run.
 164 Otherwise, that behavior is invoked via a prefix argument."
 165   :group 'locate
 166   :type 'boolean
 167   )
 168
 169 ;; Functions
 170
 171 (defun locate-default-make-command-line (search-string)
 172   (list locate-command search-string))
 173
 174 (defun locate-word-at-point ()
 175   (let ((pt (point)))
 176     (buffer-substring-no-properties
 177      (save-excursion
 178        (skip-chars-backward "-a-zA-Z0-9.")
 179        (point))
 180      (save-excursion
 181        (skip-chars-forward "-a-zA-Z0-9.")
 182        (skip-chars-backward "." pt)
 183        (point)))))
 184
 185 ;;;###autoload
 186 (defun locate (search-string &optional filter)
 187   "Run the program `locate', putting results in `*Locate*' buffer.
 188 With prefix arg, prompt for the locate command to run."
 189   (interactive
 190       (list
 191        (if (or (and current-prefix-arg
 192                     (not locate-prompt-for-command))
 193                (and (not current-prefix-arg) locate-prompt-for-command))
 194            (let ((locate-cmd (funcall locate-make-command-line "")))
 195              (read-from-minibuffer
 196               "Run locate (like this): "
 197               (cons
 198                (concat (car locate-cmd) "  "
 199                        (mapconcat 'identity (cdr locate-cmd) " "))
 200                        (+ 2 (length (car locate-cmd))))
 201               nil nil 'locate-history-list))
 202          (let* ((default (locate-word-at-point))
 203                (input
 204                 (read-from-minibuffer
 205                  (if  (> (length default) 0)
 206                      (format "Locate (default `%s'): " default)
 207                    (format "Locate: "))
 208                  nil nil nil 'locate-history-list default t)))
 209                (and (equal input "") default
 210                     (setq input default))
 211                input))))
 212   (if (equal search-string "")
 213       (error "Please specify a filename to search for."))
 214   (let* ((locate-cmd-list (funcall locate-make-command-line search-string))
 215          (locate-cmd (car locate-cmd-list))
 216          (locate-cmd-args (cdr locate-cmd-list))
 217          (run-locate-command
 218           (or (and current-prefix-arg (not locate-prompt-for-command))
 219               (and (not current-prefix-arg) locate-prompt-for-command)))
 220          )
 221
 222     ;; Find the Locate buffer
 223     (save-window-excursion
 224       (set-buffer (get-buffer-create locate-buffer-name))
 225       (locate-mode)
 226       (erase-buffer)
 227
 228       (setq locate-current-filter filter)
 229
 230       (if run-locate-command
 231           (shell-command search-string locate-buffer-name)
 232         (apply 'call-process locate-cmd nil t nil locate-cmd-args))
 233
 234       (and filter
 235           (locate-filter-output filter))
 236
 237       (locate-do-setup search-string)
 238       )
 239     (and (not (string-equal (buffer-name) locate-buffer-name))
 240         (switch-to-buffer-other-window locate-buffer-name))
 241
 242     (run-hooks 'dired-mode-hook)
 243     (run-hooks 'locate-post-command-hook)
 244     )
 245   )
 246
 247 ;;;###autoload
 248 (defun locate-with-filter (search-string filter)
 249   "Run the locate command with a filter.
 250
 251 The filter is a regular expression. Only results matching the filter are
 252 shown; this is often useful to constrain a big search."
 253   (interactive
 254    (list (read-from-minibuffer "Locate: " nil nil
 255                                nil 'locate-history-list)
 256          (read-from-minibuffer "Filter: " nil nil
 257                                nil 'locate-grep-history-list)))
 258   (locate search-string filter))
 259
 260 (defun locate-filter-output (filter)
 261   "Filter output from the locate command."
 262   (goto-char (point-min))
 263   (delete-non-matching-lines filter))
 264
 265 (defvar locate-mode-map nil
 266   "Local keymap for Locate mode buffers.")
 267 (if locate-mode-map
 268     nil
 269
 270    (require 'dired)
 271
 272    (setq locate-mode-map (copy-keymap dired-mode-map))
 273
 274    ;; Undefine Useless Dired Menu bars
 275    (define-key locate-mode-map [menu-bar Dired]   'undefined)
 276    (define-key locate-mode-map [menu-bar subdir]  'undefined)
 277
 278    (define-key locate-mode-map [menu-bar mark executables] 'undefined)
 279    (define-key locate-mode-map [menu-bar mark directory]   'undefined)
 280    (define-key locate-mode-map [menu-bar mark directories] 'undefined)
 281    (define-key locate-mode-map [menu-bar mark symlinks]    'undefined)
 282
 283    (define-key locate-mode-map [mouse-2]   'locate-mouse-view-file)
 284    (define-key locate-mode-map "\C-c\C-t"  'locate-tags)
 285
 286    (define-key locate-mode-map "U"       'dired-unmark-all-files)
 287    (define-key locate-mode-map "V"       'locate-find-directory)
 288 )
 289
 290 ;; This variable is used to indent the lines and then to search for
 291 ;; the file name
 292 (defconst locate-filename-indentation 4
 293   "The amount of indentation for each file.")
 294
 295 (defun locate-get-file-positions ()
 296   (save-excursion
 297     (end-of-line)
 298     (let ((eol (point)))
 299       (beginning-of-line)
 300
 301       ;; Assumes names end at the end of the line
 302       (forward-char locate-filename-indentation)
 303       (list (point) eol))))
 304
 305 ;; From SQL-mode
 306 (defun locate-current-line-number ()
 307   "Return the current line number, as an integer."
 308   (+ (count-lines (point-min) (point))
 309      (if (eq (current-column) 0)
 310          1
 311        0)))
 312
 313 (defun locate-get-filename ()
 314   (let ((pos    (locate-get-file-positions))
 315         (lineno (locate-current-line-number)))
 316     (and (not (eq lineno 1))
 317          (not (eq lineno 2))
 318          (buffer-substring (elt pos 0) (elt pos 1)))))
 319
 320 (defun locate-mouse-view-file (event)
 321   "In Locate mode, view a file, using the mouse."
 322   (interactive "@e")
 323   (save-excursion
 324     (goto-char (posn-point (event-start event)))
 325     (view-file (locate-get-filename))))
 326
 327 ;; Define a mode for locate
 328 ;; Default directory is set to "/" so that dired commands, which
 329 ;; expect to be in a tree, will work properly
 330 (defun locate-mode ()
 331   "Major mode for the `*Locate*' buffer made by \\[locate]."
 332   (kill-all-local-variables)
 333   ;; Avoid clobbering this variables
 334   (make-local-variable 'dired-subdir-alist)
 335   (use-local-map             locate-mode-map)
 336   (setq major-mode          'locate-mode
 337         mode-name           "Locate"
 338         default-directory   "/")
 339   (dired-alist-add-1 default-directory (point-min-marker))
 340   (make-local-variable 'dired-move-to-filename-regexp)
 341   ;; This should support both Unix and Windoze style names
 342   (setq dired-move-to-filename-regexp
 343         (concat "."
 344                 (make-string (1- locate-filename-indentation) ?\ )
 345                 "\\(/\\|[A-Za-z]:\\)"))
 346   (make-local-variable 'dired-actual-switches)
 347   (setq dired-actual-switches "")
 348   (make-local-variable 'dired-permission-flags-regexp)
 349   (setq dired-permission-flags-regexp
 350         (concat "^.\\("
 351                 (make-string (1- locate-filename-indentation) ?\ )
 352                 "\\)"))
 353   (make-local-variable 'revert-buffer-function)
 354   (setq revert-buffer-function 'locate-update)
 355   (run-hooks 'locate-mode-hook))
 356
 357 (defun locate-do-setup (search-string)
 358   (goto-char (point-min))
 359   (save-excursion
 360
 361     ;; Nothing returned from locate command?
 362     (and (eobp)
 363          (progn
 364            (kill-buffer locate-buffer-name)
 365            (if locate-current-filter
 366                (error "Locate: no match for %s in database using filter %s"
 367                       search-string locate-current-filter)
 368              (error "Locate: no match for %s in database" search-string))))
 369
 370     (locate-insert-header search-string)
 371
 372     (while (not (eobp))
 373       (insert-char ?\  locate-filename-indentation t)
 374       (locate-set-properties)
 375       (forward-line 1)))
 376   (goto-char (point-min)))
 377
 378 (defun locate-set-properties ()
 379   (save-excursion
 380     (let ((pos (locate-get-file-positions)))
 381       (dired-insert-set-properties (elt pos 0) (elt pos 1)))))
 382
 383 (defun locate-insert-header (search-string)
 384   (let ((locate-format-string "Matches for %s")
 385         (locate-regexp-match
 386          (concat " *Matches for \\(" (regexp-quote search-string) "\\)"))
 387         (locate-format-args (list search-string))
 388         )
 389
 390     (and locate-fcodes-file
 391         (setq locate-format-string
 392               (concat locate-format-string " in %s")
 393               locate-regexp-match
 394               (concat locate-regexp-match
 395                       " in \\("
 396                       (regexp-quote locate-fcodes-file)
 397                       "\\)")
 398               locate-format-args
 399               (append (list locate-fcodes-file) locate-format-args)))
 400
 401     (and locate-current-filter
 402         (setq locate-format-string
 403               (concat locate-format-string " using filter %s")
 404               locate-regexp-match
 405               (concat locate-regexp-match
 406                       " using filter "
 407                       "\\("
 408                       (regexp-quote locate-current-filter)
 409                       "\\)")
 410               locate-format-args
 411               (append (list locate-current-filter) locate-format-args)))
 412
 413     (setq locate-format-string
 414           (concat locate-format-string ":\n\n")
 415           locate-regexp-match
 416           (concat locate-regexp-match ":\n"))
 417
 418     (insert (apply 'format locate-format-string (reverse locate-format-args)))
 419
 420     (save-excursion
 421       (goto-char (point-min))
 422       (if (not (looking-at locate-regexp-match))
 423           nil
 424         (add-text-properties (match-beginning 1) (match-end 1)
 425                              (list 'face locate-header-face))
 426         (and (match-beginning 2)
 427              (add-text-properties (match-beginning 2) (match-end 2)
 428                                   (list 'face locate-header-face)))
 429         (and (match-beginning 3)
 430              (add-text-properties (match-beginning 3) (match-end 3)
 431                                   (list 'face locate-header-face)))
 432         ))))
 433
 434 (defun locate-tags ()
 435   "Visit a tags table in `*Locate*' mode."
 436   (interactive)
 437   (let ((tags-table (locate-get-filename)))
 438     (and (y-or-n-p (format "Visit tags table %s? " tags-table))
 439          (visit-tags-table tags-table))))
 440
 441 ;; From Stephen Eglen <stephen@cns.ed.ac.uk>
 442 (defun locate-update (ignore1 ignore2)
 443   "Update the locate database.
 444 Database is updated using the shell command in `locate-update-command'."
 445   (let ((str (car locate-history-list)))
 446     (cond ((yes-or-no-p "Update locate database (may take a few seconds)? ")
 447            (shell-command locate-update-command)
 448            (locate str)))))
 449
 450 ;;; Modified three functions from `dired.el':
 451 ;;;   dired-find-directory,
 452 ;;;   dired-find-directory-other-window
 453 ;;;   dired-get-filename
 454
 455 (defun locate-find-directory ()
 456   "Visit the directory of the file mentioned on this line."
 457   (interactive)
 458   (let ((directory-name (locate-get-dirname)))
 459     (if (file-directory-p directory-name)
 460         (find-file directory-name)
 461       (if (file-symlink-p directory-name)
 462           (error "Directory is a symlink to a nonexistent target")
 463         (error "Directory no longer exists; run `updatedb' to update database")))))
 464
 465 (defun locate-find-directory-other-window ()
 466   "Visit the directory of the file named on this line in other window."
 467   (interactive)
 468   (find-file-other-window (locate-get-dirname)))
 469
 470 (defun locate-get-dirname ()
 471   "Return the directory name of the file mentioned on this line."
 472   (let (file (filepos (locate-get-file-positions)))
 473     (if (setq file (buffer-substring (nth 0 filepos) (nth 1 filepos)))
 474         (progn
 475           ;; Get rid of the mouse-face property that file names have.
 476           (set-text-properties 0 (length file) nil file)
 477           (setq file (file-name-directory file))
 478           ;; Unquote names quoted by ls or by dired-insert-directory.
 479           ;; Using read to unquote is much faster than substituting
 480           ;; \007 (4 chars) -> ^G  (1 char) etc. in a lisp loop.
 481           (setq file
 482                 (read
 483                  (concat "\""
 484                          ;; some ls -b don't escape quotes, argh!
 485                          ;; This is not needed for GNU ls, though.
 486                          (or (dired-string-replace-match
 487                               "\\([^\\]\\|\\`\\)\"" file "\\1\\\\\"" nil t)
 488                              file)
 489                          "\"")))))
 490     (and file buffer-file-coding-system
 491          (not file-name-coding-system)
 492          (setq file (encode-coding-string file buffer-file-coding-system)))
 493     file))
 494
 495 ;; Only for GNU locate
 496 (defun locate-in-alternate-database  (search-string database)
 497   "Run the GNU locate command, using an alternate database."
 498   (interactive
 499       (list
 500        (progn
 501          ;; (require 'locate)
 502          (read-from-minibuffer "Locate: " nil nil
 503                                nil 'locate-history-list))
 504        (read-file-name "Locate using Database: " )
 505        ))
 506   (or (file-exists-p database)
 507       (error "Database file %s does not exist" database))
 508   (let ((locate-make-command-line
 509          (function (lambda (string)
 510                      (cons locate-command
 511                            (list (concat "--database="
 512                                          (expand-file-name database))
 513                                  string))))))
 514     (locate search-string)))
 515
 516 (provide 'locate)
 517
 518 ;;; locate.el ends here