code.delx.au - gnu-emacs/blob - lisp/edmacro.el

   1 ;;; edmacro.el --- keyboard macro editor
   2
   3 ;; Copyright (C) 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Dave Gillespie <daveg@synaptics.com>
   6 ;; Maintainer: Dave Gillespie <daveg@synaptics.com>
   7 ;; Version: 2.01
   8 ;; Keywords: abbrev
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;;; Usage:
  30 ;;
  31 ;; The `C-x C-k' (`edit-kbd-macro') command edits a keyboard macro
  32 ;; in a special buffer.  It prompts you to type a key sequence,
  33 ;; which should be one of:
  34 ;;
  35 ;;  * RET or `C-x e' (call-last-kbd-macro), to edit the most
  36 ;;    recently defined keyboard macro.
  37 ;;
  38 ;;  * `M-x' followed by a command name, to edit a named command
  39 ;;    whose definition is a keyboard macro.
  40 ;;
  41 ;;  * `C-h l' (view-lossage), to edit the 100 most recent keystrokes
  42 ;;    and install them as the "current" macro.
  43 ;;
  44 ;;  * any key sequence whose definition is a keyboard macro.
  45 ;;
  46 ;; This file includes a version of `insert-kbd-macro' that uses the
  47 ;; more readable format defined by these routines.
  48 ;;
  49 ;; Also, the `read-kbd-macro' command parses the region as
  50 ;; a keyboard macro, and installs it as the "current" macro.
  51 ;; This and `format-kbd-macro' can also be called directly as
  52 ;; Lisp functions.
  53
  54 ;; Type `C-h m', or see the documentation for `edmacro-mode' below,
  55 ;; for information about the format of written keyboard macros.
  56
  57 ;; `edit-kbd-macro' formats the macro with one command per line,
  58 ;; including the command names as comments on the right.  If the
  59 ;; formatter gets confused about which keymap was used for the
  60 ;; characters, the command-name comments will be wrong but that
  61 ;; won't hurt anything.
  62
  63 ;; With a prefix argument, `edit-kbd-macro' will format the
  64 ;; macro in a more concise way that omits the comments.
  65
  66 ;; This package requires GNU Emacs 19 or later, and daveg's CL
  67 ;; package 2.02 or later.  (CL 2.02 comes standard starting with
  68 ;; Emacs 19.18.)  This package does not work with Emacs 18 or
  69 ;; Lucid Emacs.
  70
  71 ;;; Code:
  72 \f
  73 (eval-when-compile
  74  (require 'cl))
  75
  76 (require 'kmacro)
  77
  78 ;;; The user-level commands for editing macros.
  79
  80 ;;;###autoload
  81 (defvar edmacro-eight-bits nil
  82   "*Non-nil if edit-kbd-macro should leave 8-bit characters intact.
  83 Default nil means to write characters above \\177 in octal notation.")
  84
  85 (defvar edmacro-mode-map nil)
  86 (unless edmacro-mode-map
  87   (setq edmacro-mode-map (make-sparse-keymap))
  88   (define-key edmacro-mode-map "\C-c\C-c" 'edmacro-finish-edit)
  89   (define-key edmacro-mode-map "\C-c\C-q" 'edmacro-insert-key))
  90
  91 (defvar edmacro-store-hook)
  92 (defvar edmacro-finish-hook)
  93 (defvar edmacro-original-buffer)
  94
  95 ;;;###autoload
  96 (defun edit-kbd-macro (keys &optional prefix finish-hook store-hook)
  97   "Edit a keyboard macro.
  98 At the prompt, type any key sequence which is bound to a keyboard macro.
  99 Or, type `C-x e' or RET to edit the last keyboard macro, `C-h l' to edit
 100 the last 100 keystrokes as a keyboard macro, or `M-x' to edit a macro by
 101 its command name.
 102 With a prefix argument, format the macro in a more concise way."
 103   (interactive "kKeyboard macro to edit (C-x e, M-x, C-h l, or keys): \nP")
 104   (when keys
 105     (let ((cmd (if (arrayp keys) (key-binding keys) keys))
 106           (mac nil) (mac-counter nil) (mac-format nil)
 107           kmacro)
 108       (cond (store-hook
 109              (setq mac keys)
 110              (setq cmd nil))
 111             ((or (memq cmd '(call-last-kbd-macro kmacro-call-macro
 112                              kmacro-end-or-call-macro kmacro-end-and-call-macro))
 113                  (member keys '("\r" [return])))
 114              (or last-kbd-macro
 115                  (y-or-n-p "No keyboard macro defined.  Create one? ")
 116                  (keyboard-quit))
 117              (setq mac (or last-kbd-macro ""))
 118              (setq keys nil)
 119              (setq cmd 'last-kbd-macro))
 120             ((eq cmd 'execute-extended-command)
 121              (setq cmd (read-command "Name of keyboard macro to edit: "))
 122              (if (string-equal cmd "")
 123                  (error "No command name given"))
 124              (setq keys nil)
 125              (setq mac (symbol-function cmd)))
 126             ((memq cmd '(view-lossage electric-view-lossage))
 127              (setq mac (recent-keys))
 128              (setq keys nil)
 129              (setq cmd 'last-kbd-macro))
 130             ((null cmd)
 131              (error "Key sequence %s is not defined" (key-description keys)))
 132             ((symbolp cmd)
 133              (setq mac (symbol-function cmd)))
 134             (t
 135              (setq mac cmd)
 136              (setq cmd nil)))
 137       (when (setq kmacro (kmacro-extract-lambda mac))
 138         (setq mac (car kmacro)
 139               mac-counter (nth 1 kmacro)
 140               mac-format (nth 2 kmacro)))
 141       (unless (arrayp mac)
 142         (error "Key sequence %s is not a keyboard macro"
 143                (key-description keys)))
 144       (message "Formatting keyboard macro...")
 145       (let* ((oldbuf (current-buffer))
 146              (mmac (edmacro-fix-menu-commands mac))
 147              (fmt (edmacro-format-keys mmac 1))
 148              (fmtv (edmacro-format-keys mmac (not prefix)))
 149              (buf (get-buffer-create "*Edit Macro*")))
 150         (message "Formatting keyboard macro...done")
 151         (switch-to-buffer buf)
 152         (kill-all-local-variables)
 153         (use-local-map edmacro-mode-map)
 154         (setq buffer-read-only nil)
 155         (setq major-mode 'edmacro-mode)
 156         (setq mode-name "Edit Macro")
 157         (set (make-local-variable 'edmacro-original-buffer) oldbuf)
 158         (set (make-local-variable 'edmacro-finish-hook) finish-hook)
 159         (set (make-local-variable 'edmacro-store-hook) store-hook)
 160         (erase-buffer)
 161         (insert ";; Keyboard Macro Editor.  Press C-c C-c to finish; "
 162                 "press C-x k RET to cancel.\n")
 163         (insert ";; Original keys: " fmt "\n")
 164         (unless store-hook
 165           (insert "\nCommand: " (if cmd (symbol-name cmd) "none") "\n")
 166           (let ((gkeys (where-is-internal (or cmd mac) '(keymap))))
 167             (if (and keys (not (member keys gkeys)))
 168                 (setq gkeys (cons keys gkeys)))
 169             (if gkeys
 170                 (while gkeys
 171                   (insert "Key: " (edmacro-format-keys (pop gkeys) 1) "\n"))
 172               (insert "Key: none\n")))
 173           (when (and mac-counter mac-format)
 174             (insert (format "Counter: %d\nFormat: \"%s\"\n" mac-counter mac-format))))
 175         (insert "\nMacro:\n\n")
 176         (save-excursion
 177           (insert fmtv "\n"))
 178         (recenter '(4))
 179         (when (eq mac mmac)
 180           (set-buffer-modified-p nil))
 181         (run-hooks 'edmacro-format-hook)))))
 182
 183 ;;; The next two commands are provided for convenience and backward
 184 ;;; compatibility.
 185
 186 ;;;###autoload
 187 (defun edit-last-kbd-macro (&optional prefix)
 188   "Edit the most recently defined keyboard macro."
 189   (interactive "P")
 190   (edit-kbd-macro 'call-last-kbd-macro prefix))
 191
 192 ;;;###autoload
 193 (defun edit-named-kbd-macro (&optional prefix)
 194   "Edit a keyboard macro which has been given a name by `name-last-kbd-macro'."
 195   (interactive "P")
 196   (edit-kbd-macro 'execute-extended-command prefix))
 197
 198 ;;;###autoload
 199 (defun read-kbd-macro (start &optional end)
 200   "Read the region as a keyboard macro definition.
 201 The region is interpreted as spelled-out keystrokes, e.g., \"M-x abc RET\".
 202 See documentation for `edmacro-mode' for details.
 203 Leading/trailing \"C-x (\" and \"C-x )\" in the text are allowed and ignored.
 204 The resulting macro is installed as the \"current\" keyboard macro.
 205
 206 In Lisp, may also be called with a single STRING argument in which case
 207 the result is returned rather than being installed as the current macro.
 208 The result will be a string if possible, otherwise an event vector.
 209 Second argument NEED-VECTOR means to return an event vector always."
 210   (interactive "r")
 211   (if (stringp start)
 212       (edmacro-parse-keys start end)
 213     (setq last-kbd-macro (edmacro-parse-keys (buffer-substring start end)))))
 214
 215 ;;;###autoload
 216 (defun format-kbd-macro (&optional macro verbose)
 217   "Return the keyboard macro MACRO as a human-readable string.
 218 This string is suitable for passing to `read-kbd-macro'.
 219 Second argument VERBOSE means to put one command per line with comments.
 220 If VERBOSE is `1', put everything on one line.  If VERBOSE is omitted
 221 or nil, use a compact 80-column format."
 222   (and macro (symbolp macro) (setq macro (symbol-function macro)))
 223   (edmacro-format-keys (or macro last-kbd-macro) verbose))
 224 \f
 225 ;;; Commands for *Edit Macro* buffer.
 226
 227 (defun edmacro-finish-edit ()
 228   (interactive)
 229   (unless (eq major-mode 'edmacro-mode)
 230     (error
 231      "This command is valid only in buffers created by `edit-kbd-macro'"))
 232   (run-hooks 'edmacro-finish-hook)
 233   (let ((cmd nil) (keys nil) (no-keys nil)
 234         (mac-counter nil) (mac-format nil) (kmacro nil)
 235         (top (point-min)))
 236     (goto-char top)
 237     (let ((case-fold-search nil))
 238       (while (cond ((looking-at "[ \t]*\\($\\|;;\\|REM[ \t\n]\\)")
 239                     t)
 240                    ((looking-at "Command:[ \t]*\\([^ \t\n]*\\)[ \t]*$")
 241                     (when edmacro-store-hook
 242                       (error "\"Command\" line not allowed in this context"))
 243                     (let ((str (buffer-substring (match-beginning 1)
 244                                                  (match-end 1))))
 245                       (unless (equal str "")
 246                         (setq cmd (and (not (equal str "none"))
 247                                        (intern str)))
 248                         (and (fboundp cmd) (not (arrayp (symbol-function cmd)))
 249                              (not (setq kmacro (get cmd 'kmacro)))
 250                              (not (y-or-n-p
 251                                    (format "Command %s is already defined; %s"
 252                                            cmd "proceed? ")))
 253                              (keyboard-quit))))
 254                     t)
 255                    ((looking-at "Key:\\(.*\\)$")
 256                     (when edmacro-store-hook
 257                       (error "\"Key\" line not allowed in this context"))
 258                     (let ((key (edmacro-parse-keys
 259                                 (buffer-substring (match-beginning 1)
 260                                                   (match-end 1)))))
 261                       (unless (equal key "")
 262                         (if (equal key "none")
 263                             (setq no-keys t)
 264                           (push key keys)
 265                           (let ((b (key-binding key)))
 266                             (and b (commandp b) (not (arrayp b))
 267                                  (not (kmacro-extract-lambda b))
 268                                  (or (not (fboundp b))
 269                                      (not (arrayp (symbol-function b))))
 270                                  (not (y-or-n-p
 271                                        (format "Key %s is already defined; %s"
 272                                                (edmacro-format-keys key 1)
 273                                                "proceed? ")))
 274                                  (keyboard-quit))))))
 275                     t)
 276                    ((looking-at "Counter:[ \t]*\\([^ \t\n]*\\)[ \t]*$")
 277                     (when edmacro-store-hook
 278                       (error "\"Counter\" line not allowed in this context"))
 279                     (let ((str (buffer-substring (match-beginning 1)
 280                                                  (match-end 1))))
 281                       (unless (equal str "")
 282                         (setq mac-counter (string-to-int str))))
 283                     t)
 284                    ((looking-at "Format:[ \t]*\"\\([^\n]*\\)\"[ \t]*$")
 285                     (when edmacro-store-hook
 286                       (error "\"Format\" line not allowed in this context"))
 287                     (let ((str (buffer-substring (match-beginning 1)
 288                                                  (match-end 1))))
 289                       (unless (equal str "")
 290                         (setq mac-format str)))
 291                     t)
 292                    ((looking-at "Macro:[ \t\n]*")
 293                     (goto-char (match-end 0))
 294                     nil)
 295                    ((eobp) nil)
 296                    (t (error "Expected a `Macro:' line")))
 297         (forward-line 1))
 298       (setq top (point)))
 299     (let* ((buf (current-buffer))
 300            (str (buffer-substring top (point-max)))
 301            (modp (buffer-modified-p))
 302            (obuf edmacro-original-buffer)
 303            (store-hook edmacro-store-hook)
 304            (finish-hook edmacro-finish-hook))
 305       (unless (or cmd keys store-hook (equal str ""))
 306         (error "No command name or keys specified"))
 307       (when modp
 308         (when (buffer-name obuf)
 309           (set-buffer obuf))
 310         (message "Compiling keyboard macro...")
 311         (let ((mac (edmacro-parse-keys str)))
 312           (message "Compiling keyboard macro...done")
 313           (if store-hook
 314               (funcall store-hook mac)
 315             (when (eq cmd 'last-kbd-macro)
 316               (setq last-kbd-macro (and (> (length mac) 0) mac))
 317               (setq cmd nil))
 318             (when cmd
 319               (if (= (length mac) 0)
 320                   (fmakunbound cmd)
 321                 (fset cmd
 322                       (if (and mac-counter mac-format)
 323                           (kmacro-lambda-form mac mac-counter mac-format)
 324                         mac))))
 325             (if no-keys
 326                 (when cmd
 327                   (loop for key in (where-is-internal cmd '(keymap)) do
 328                         (global-unset-key key)))
 329               (when keys
 330                 (if (= (length mac) 0)
 331                     (loop for key in keys do (global-unset-key key))
 332                   (loop for key in keys do
 333                         (global-set-key key
 334                                         (or cmd
 335                                             (if (and mac-counter mac-format)
 336                                                 (kmacro-lambda-form mac mac-counter mac-format)
 337                                               mac))))))))))
 338       (kill-buffer buf)
 339       (when (buffer-name obuf)
 340         (switch-to-buffer obuf))
 341       (when finish-hook
 342         (funcall finish-hook)))))
 343
 344 (defun edmacro-insert-key (key)
 345   "Insert the written name of a key in the buffer."
 346   (interactive "kKey to insert: ")
 347   (if (bolp)
 348       (insert (edmacro-format-keys key t) "\n")
 349     (insert (edmacro-format-keys key) " ")))
 350
 351 (defun edmacro-mode ()
 352   "\\<edmacro-mode-map>Keyboard Macro Editing mode.  Press
 353 \\[edmacro-finish-edit] to save and exit.
 354 To abort the edit, just kill this buffer with \\[kill-buffer] RET.
 355
 356 Press \\[edmacro-insert-key] to insert the name of any key by typing the key.
 357
 358 The editing buffer contains a \"Command:\" line and any number of
 359 \"Key:\" lines at the top.  These are followed by a \"Macro:\" line
 360 and the macro itself as spelled-out keystrokes: `C-x C-f foo RET'.
 361
 362 The \"Command:\" line specifies the command name to which the macro
 363 is bound, or \"none\" for no command name.  Write \"last-kbd-macro\"
 364 to refer to the current keyboard macro (as used by \\[call-last-kbd-macro]).
 365
 366 The \"Key:\" lines specify key sequences to which the macro is bound,
 367 or \"none\" for no key bindings.
 368
 369 You can edit these lines to change the places where the new macro
 370 is stored.
 371
 372
 373 Format of keyboard macros during editing:
 374
 375 Text is divided into \"words\" separated by whitespace.  Except for
 376 the words described below, the characters of each word go directly
 377 as characters of the macro.  The whitespace that separates words
 378 is ignored.  Whitespace in the macro must be written explicitly,
 379 as in \"foo SPC bar RET\".
 380
 381  * The special words RET, SPC, TAB, DEL, LFD, ESC, and NUL represent
 382    special control characters.  The words must be written in uppercase.
 383
 384  * A word in angle brackets, e.g., <return>, <down>, or <f1>, represents
 385    a function key.  (Note that in the standard configuration, the
 386    function key <return> and the control key RET are synonymous.)
 387    You can use angle brackets on the words RET, SPC, etc., but they
 388    are not required there.
 389
 390  * Keys can be written by their ASCII code, using a backslash followed
 391    by up to six octal digits.  This is the only way to represent keys
 392    with codes above \\377.
 393
 394  * One or more prefixes M- (meta), C- (control), S- (shift), A- (alt),
 395    H- (hyper), and s- (super) may precede a character or key notation.
 396    For function keys, the prefixes may go inside or outside of the
 397    brackets:  C-<down> = <C-down>.  The prefixes may be written in
 398    any order:  M-C-x = C-M-x.
 399
 400    Prefixes are not allowed on multi-key words, e.g., C-abc, except
 401    that the Meta prefix is allowed on a sequence of digits and optional
 402    minus sign:  M--123 = M-- M-1 M-2 M-3.
 403
 404  * The `^' notation for control characters also works:  ^M = C-m.
 405
 406  * Double angle brackets enclose command names:  <<next-line>> is
 407    shorthand for M-x next-line RET.
 408
 409  * Finally, REM or ;; causes the rest of the line to be ignored as a
 410    comment.
 411
 412 Any word may be prefixed by a multiplier in the form of a decimal
 413 number and `*':  3*<right> = <right> <right> <right>, and
 414 10*foo = foofoofoofoofoofoofoofoofoofoo.
 415
 416 Multiple text keys can normally be strung together to form a word,
 417 but you may need to add whitespace if the word would look like one
 418 of the above notations:  `; ; ;' is a keyboard macro with three
 419 semicolons, but `;;;' is a comment.  Likewise, `\\ 1 2 3' is four
 420 keys but `\\123' is a single key written in octal, and `< right >'
 421 is seven keys but `<right>' is a single function key.  When in
 422 doubt, use whitespace."
 423   (interactive)
 424   (error "This mode can be enabled only by `edit-kbd-macro'"))
 425 (put 'edmacro-mode 'mode-class 'special)
 426 \f
 427 ;;; Formatting a keyboard macro as human-readable text.
 428
 429 (defun edmacro-format-keys (macro &optional verbose)
 430   (setq macro (edmacro-fix-menu-commands macro))
 431   (let* ((maps (append (current-minor-mode-maps)
 432                        (if (current-local-map)
 433                            (list (current-local-map)))
 434                        (list (current-global-map))))
 435          (pkeys '(end-macro ?0 ?1 ?2 ?3 ?4 ?5 ?6 ?7 ?8 ?9 ?- ?\C-u
 436                   ?\M-- ?\M-0 ?\M-1 ?\M-2 ?\M-3 ?\M-4 ?\M-5 ?\M-6
 437                   ?\M-7 ?\M-8 ?\M-9))
 438          (mdigs (nthcdr 13 pkeys))
 439          (maxkey (if edmacro-eight-bits 255 127))
 440          (case-fold-search nil)
 441          (res-words '("NUL" "TAB" "LFD" "RET" "ESC" "SPC" "DEL" "REM"))
 442          (rest-mac (vconcat macro [end-macro]))
 443          (res "")
 444          (len 0)
 445          (one-line (eq verbose 1)))
 446     (if one-line (setq verbose nil))
 447     (when (stringp macro)
 448       (loop for i below (length macro) do
 449             (when (>= (aref rest-mac i) 128)
 450               (incf (aref rest-mac i) (- ?\M-\^@ 128)))))
 451     (while (not (eq (aref rest-mac 0) 'end-macro))
 452       (let* ((prefix
 453               (or (and (integerp (aref rest-mac 0))
 454                        (memq (aref rest-mac 0) mdigs)
 455                        (memq (key-binding (edmacro-subseq rest-mac 0 1))
 456                              '(digit-argument negative-argument))
 457                        (let ((i 1))
 458                          (while (memq (aref rest-mac i) (cdr mdigs))
 459                            (incf i))
 460                          (and (not (memq (aref rest-mac i) pkeys))
 461                               (prog1 (vconcat "M-" (edmacro-subseq rest-mac 0 i) " ")
 462                                 (callf edmacro-subseq rest-mac i)))))
 463                   (and (eq (aref rest-mac 0) ?\C-u)
 464                        (eq (key-binding [?\C-u]) 'universal-argument)
 465                        (let ((i 1))
 466                          (while (eq (aref rest-mac i) ?\C-u)
 467                            (incf i))
 468                          (and (not (memq (aref rest-mac i) pkeys))
 469                               (prog1 (loop repeat i concat "C-u ")
 470                                 (callf edmacro-subseq rest-mac i)))))
 471                   (and (eq (aref rest-mac 0) ?\C-u)
 472                        (eq (key-binding [?\C-u]) 'universal-argument)
 473                        (let ((i 1))
 474                          (when (eq (aref rest-mac i) ?-)
 475                            (incf i))
 476                          (while (memq (aref rest-mac i)
 477                                       '(?0 ?1 ?2 ?3 ?4 ?5 ?6 ?7 ?8 ?9))
 478                            (incf i))
 479                          (and (not (memq (aref rest-mac i) pkeys))
 480                               (prog1 (vconcat "C-u " (edmacro-subseq rest-mac 1 i) " ")
 481                                 (callf edmacro-subseq rest-mac i)))))))
 482              (bind-len (apply 'max 1
 483                               (loop for map in maps
 484                                     for b = (lookup-key map rest-mac)
 485                                     when b collect b)))
 486              (key (edmacro-subseq rest-mac 0 bind-len))
 487              (fkey nil) tlen tkey
 488              (bind (or (loop for map in maps for b = (lookup-key map key)
 489                              thereis (and (not (integerp b)) b))
 490                        (and (setq fkey (lookup-key function-key-map rest-mac))
 491                             (setq tlen fkey tkey (edmacro-subseq rest-mac 0 tlen)
 492                                   fkey (lookup-key function-key-map tkey))
 493                             (loop for map in maps
 494                                   for b = (lookup-key map fkey)
 495                                   when (and (not (integerp b)) b)
 496                                   do (setq bind-len tlen key tkey)
 497                                   and return b
 498                                   finally do (setq fkey nil)))))
 499              (first (aref key 0))
 500              (text (loop for i from bind-len below (length rest-mac)
 501                          for ch = (aref rest-mac i)
 502                          while (and (integerp ch)
 503                                     (> ch 32) (< ch maxkey) (/= ch 92)
 504                                     (eq (key-binding (char-to-string ch))
 505                                         'self-insert-command)
 506                                     (or (> i (- (length rest-mac) 2))
 507                                         (not (eq ch (aref rest-mac (+ i 1))))
 508                                         (not (eq ch (aref rest-mac (+ i 2))))))
 509                          finally return i))
 510              desc)
 511         (if (stringp bind) (setq bind nil))
 512         (cond ((and (eq bind 'self-insert-command) (not prefix)
 513                     (> text 1) (integerp first)
 514                     (> first 32) (<= first maxkey) (/= first 92)
 515                     (progn
 516                       (if (> text 30) (setq text 30))
 517                       (setq desc (concat (edmacro-subseq rest-mac 0 text)))
 518                       (when (string-match "^[ACHMsS]-." desc)
 519                         (setq text 2)
 520                         (callf substring desc 0 2))
 521                       (not (string-match
 522                             "^;;\\|^<.*>$\\|^\\\\[0-9]+$\\|^[0-9]+\\*."
 523                             desc))))
 524                (when (or (string-match "^\\^.$" desc)
 525                          (member desc res-words))
 526                  (setq desc (mapconcat 'char-to-string desc " ")))
 527                (when verbose
 528                  (setq bind (format "%s * %d" bind text)))
 529                (setq bind-len text))
 530               ((and (eq bind 'execute-extended-command)
 531                     (> text bind-len)
 532                     (memq (aref rest-mac text) '(return 13))
 533                     (progn
 534                       (setq desc (concat (edmacro-subseq rest-mac bind-len text)))
 535                       (commandp (intern-soft desc))))
 536                (if (commandp (intern-soft desc)) (setq bind desc))
 537                (setq desc (format "<<%s>>" desc))
 538                (setq bind-len (1+ text)))
 539               (t
 540                (setq desc (mapconcat
 541                            (function
 542                             (lambda (ch)
 543                               (cond
 544                                ((integerp ch)
 545                                 (concat
 546                                  (loop for pf across "ACHMsS"
 547                                        for bit in '(?\A-\^@ ?\C-\^@ ?\H-\^@
 548                                                     ?\M-\^@ ?\s-\^@ ?\S-\^@)
 549                                        when (/= (logand ch bit) 0)
 550                                        concat (format "%c-" pf))
 551                                  (let ((ch2 (logand ch (1- (lsh 1 18)))))
 552                                    (cond ((<= ch2 32)
 553                                           (case ch2
 554                                             (0 "NUL") (9 "TAB") (10 "LFD")
 555                                             (13 "RET") (27 "ESC") (32 "SPC")
 556                                             (t
 557                                              (format "C-%c"
 558                                                      (+ (if (<= ch2 26) 96 64)
 559                                                         ch2)))))
 560                                          ((= ch2 127) "DEL")
 561                                          ((<= ch2 maxkey) (char-to-string ch2))
 562                                          (t (format "\\%o" ch2))))))
 563                                ((symbolp ch)
 564                                 (format "<%s>" ch))
 565                                (t
 566                                 (error "Unrecognized item in macro: %s" ch)))))
 567                            (or fkey key) " "))))
 568         (if prefix
 569             (setq desc (concat (edmacro-sanitize-for-string prefix) desc)))
 570         (unless (string-match " " desc)
 571           (let ((times 1) (pos bind-len))
 572             (while (not (edmacro-mismatch rest-mac rest-mac
 573                                           0 bind-len pos (+ bind-len pos)))
 574               (incf times)
 575               (incf pos bind-len))
 576             (when (> times 1)
 577               (setq desc (format "%d*%s" times desc))
 578               (setq bind-len (* bind-len times)))))
 579         (setq rest-mac (edmacro-subseq rest-mac bind-len))
 580         (if verbose
 581             (progn
 582               (unless (equal res "") (callf concat res "\n"))
 583               (callf concat res desc)
 584               (when (and bind (or (stringp bind) (symbolp bind)))
 585                 (callf concat res
 586                   (make-string (max (- 3 (/ (length desc) 8)) 1) 9)
 587                   ";; " (if (stringp bind) bind (symbol-name bind))))
 588               (setq len 0))
 589           (if (and (> (+ len (length desc) 2) 72) (not one-line))
 590               (progn
 591                 (callf concat res "\n ")
 592                 (setq len 1))
 593             (unless (equal res "")
 594               (callf concat res " ")
 595               (incf len)))
 596           (callf concat res desc)
 597           (incf len (length desc)))))
 598     res))
 599
 600 (defun edmacro-mismatch (cl-seq1 cl-seq2 cl-start1 cl-end1 cl-start2 cl-end2)
 601   "Compare SEQ1 with SEQ2, return index of first mismatching element.
 602 Return nil if the sequences match.  If one sequence is a prefix of the
 603 other, the return value indicates the end of the shorted sequence."
 604   (let (cl-test cl-test-not cl-key cl-from-end)
 605     (or cl-end1 (setq cl-end1 (length cl-seq1)))
 606     (or cl-end2 (setq cl-end2 (length cl-seq2)))
 607     (if cl-from-end
 608         (progn
 609           (while (and (< cl-start1 cl-end1) (< cl-start2 cl-end2)
 610                       (cl-check-match (elt cl-seq1 (1- cl-end1))
 611                                       (elt cl-seq2 (1- cl-end2))))
 612             (setq cl-end1 (1- cl-end1) cl-end2 (1- cl-end2)))
 613           (and (or (< cl-start1 cl-end1) (< cl-start2 cl-end2))
 614                (1- cl-end1)))
 615       (let ((cl-p1 (and (listp cl-seq1) (nthcdr cl-start1 cl-seq1)))
 616             (cl-p2 (and (listp cl-seq2) (nthcdr cl-start2 cl-seq2))))
 617         (while (and (< cl-start1 cl-end1) (< cl-start2 cl-end2)
 618                     (cl-check-match (if cl-p1 (car cl-p1)
 619                                       (aref cl-seq1 cl-start1))
 620                                     (if cl-p2 (car cl-p2)
 621                                       (aref cl-seq2 cl-start2))))
 622           (setq cl-p1 (cdr cl-p1) cl-p2 (cdr cl-p2)
 623                 cl-start1 (1+ cl-start1) cl-start2 (1+ cl-start2)))
 624         (and (or (< cl-start1 cl-end1) (< cl-start2 cl-end2))
 625              cl-start1)))))
 626
 627 (defun edmacro-subseq (seq start &optional end)
 628   "Return the subsequence of SEQ from START to END.
 629 If END is omitted, it defaults to the length of the sequence.
 630 If START or END is negative, it counts from the end."
 631   (if (stringp seq) (substring seq start end)
 632     (let (len)
 633       (and end (< end 0) (setq end (+ end (setq len (length seq)))))
 634       (if (< start 0) (setq start (+ start (or len (setq len (length seq))))))
 635       (cond ((listp seq)
 636              (if (> start 0) (setq seq (nthcdr start seq)))
 637              (if end
 638                  (let ((res nil))
 639                    (while (>= (setq end (1- end)) start)
 640                      (push (pop seq) res))
 641                    (nreverse res))
 642                (copy-sequence seq)))
 643             (t
 644              (or end (setq end (or len (length seq))))
 645              (let ((res (make-vector (max (- end start) 0) nil))
 646                    (i 0))
 647                (while (< start end)
 648                  (aset res i (aref seq start))
 649                  (setq i (1+ i) start (1+ start)))
 650                res))))))
 651
 652 (defun edmacro-sanitize-for-string (seq)
 653   "Convert a key sequence vector into a string.
 654 The string represents the same events; Meta is indicated by bit 7.
 655 This function assumes that the events can be stored in a string."
 656   (setq seq (copy-sequence seq))
 657   (loop for i below (length seq) do
 658         (when (< (aref seq i) 0)
 659           (setf (aref seq i) (logand (aref seq i) 127))))
 660   seq)
 661
 662 (defun edmacro-fix-menu-commands (macro &optional noerror)
 663   (if (vectorp macro)
 664       (let (result)
 665         ;; Make a list of the elements.
 666         (setq macro (append macro nil))
 667         (dolist (ev macro)
 668           (cond ((atom ev)
 669                  (push ev result))
 670                 ((eq (car ev) 'help-echo))
 671                 ((equal ev '(menu-bar))
 672                  (push 'menu-bar result))
 673                 ((equal (cadadr ev) '(menu-bar))
 674                  (push (vector 'menu-bar (car ev)) result))
 675                 ;; It would be nice to do pop-up menus, too, but not enough
 676                 ;; info is recorded in macros to make this possible.
 677                 (noerror
 678                  ;; Just ignore mouse events.
 679                  nil)
 680                 (t
 681                  (error "Macros with mouse clicks are not %s"
 682                         "supported by this command"))))
 683         ;; Reverse them again and make them back into a vector.
 684         (vconcat (nreverse result)))
 685     macro))
 686 \f
 687 ;;; Parsing a human-readable keyboard macro.
 688
 689 (defun edmacro-parse-keys (string &optional need-vector)
 690   (let ((case-fold-search nil)
 691         (pos 0)
 692         (res []))
 693     (while (and (< pos (length string))
 694                 (string-match "[^ \t\n\f]+" string pos))
 695       (let ((word (substring string (match-beginning 0) (match-end 0)))
 696             (key nil)
 697             (times 1))
 698         (setq pos (match-end 0))
 699         (when (string-match "\\([0-9]+\\)\\*." word)
 700           (setq times (string-to-int (substring word 0 (match-end 1))))
 701           (setq word (substring word (1+ (match-end 1)))))
 702         (cond ((string-match "^<<.+>>$" word)
 703                (setq key (vconcat (if (eq (key-binding [?\M-x])
 704                                           'execute-extended-command)
 705                                       [?\M-x]
 706                                     (or (car (where-is-internal
 707                                               'execute-extended-command))
 708                                         [?\M-x]))
 709                                   (substring word 2 -2) "\r")))
 710               ((and (string-match "^\\(\\([ACHMsS]-\\)*\\)<\\(.+\\)>$" word)
 711                     (progn
 712                       (setq word (concat (substring word (match-beginning 1)
 713                                                     (match-end 1))
 714                                          (substring word (match-beginning 3)
 715                                                     (match-end 3))))
 716                       (not (string-match
 717                             "\\<\\(NUL\\|RET\\|LFD\\|ESC\\|SPC\\|DEL\\)$"
 718                             word))))
 719                (setq key (list (intern word))))
 720               ((or (equal word "REM") (string-match "^;;" word))
 721                (setq pos (string-match "$" string pos)))
 722               (t
 723                (let ((orig-word word) (prefix 0) (bits 0))
 724                  (while (string-match "^[ACHMsS]-." word)
 725                    (incf bits (cdr (assq (aref word 0)
 726                                          '((?A . ?\A-\^@) (?C . ?\C-\^@)
 727                                            (?H . ?\H-\^@) (?M . ?\M-\^@)
 728                                            (?s . ?\s-\^@) (?S . ?\S-\^@)))))
 729                    (incf prefix 2)
 730                    (callf substring word 2))
 731                  (when (string-match "^\\^.$" word)
 732                    (incf bits ?\C-\^@)
 733                    (incf prefix)
 734                    (callf substring word 1))
 735                  (let ((found (assoc word '(("NUL" . "\0") ("RET" . "\r")
 736                                             ("LFD" . "\n") ("TAB" . "\t")
 737                                             ("ESC" . "\e") ("SPC" . " ")
 738                                             ("DEL" . "\177")))))
 739                    (when found (setq word (cdr found))))
 740                  (when (string-match "^\\\\[0-7]+$" word)
 741                    (loop for ch across word
 742                          for n = 0 then (+ (* n 8) ch -48)
 743                          finally do (setq word (vector n))))
 744                  (cond ((= bits 0)
 745                         (setq key word))
 746                        ((and (= bits ?\M-\^@) (stringp word)
 747                              (string-match "^-?[0-9]+$" word))
 748                         (setq key (loop for x across word collect (+ x bits))))
 749                        ((/= (length word) 1)
 750                         (error "%s must prefix a single character, not %s"
 751                                (substring orig-word 0 prefix) word))
 752                        ((and (/= (logand bits ?\C-\^@) 0) (stringp word)
 753                              ;; We used to accept . and ? here,
 754                              ;; but . is simply wrong,
 755                              ;; and C-? is not used (we use DEL instead).
 756                              (string-match "[@-_a-z]" word))
 757                         (setq key (list (+ bits (- ?\C-\^@)
 758                                            (logand (aref word 0) 31)))))
 759                        (t
 760                         (setq key (list (+ bits (aref word 0)))))))))
 761         (when key
 762           (loop repeat times do (callf vconcat res key)))))
 763     (when (and (>= (length res) 4)
 764                (eq (aref res 0) ?\C-x)
 765                (eq (aref res 1) ?\()
 766                (eq (aref res (- (length res) 2)) ?\C-x)
 767                (eq (aref res (- (length res) 1)) ?\)))
 768       (setq res (edmacro-subseq res 2 -2)))
 769     (if (and (not need-vector)
 770              (loop for ch across res
 771                    always (and (char-valid-p ch)
 772                                (let ((ch2 (logand ch (lognot ?\M-\^@))))
 773                                  (and (>= ch2 0) (<= ch2 127))))))
 774         (concat (loop for ch across res
 775                       collect (if (= (logand ch ?\M-\^@) 0)
 776                                   ch (+ ch 128))))
 777       res)))
 778
 779 (provide 'edmacro)
 780
 781 ;;; arch-tag: 726807b4-3ae6-49de-b0ae-b9590973e0d7
 782 ;;; edmacro.el ends here