code.delx.au - gnu-emacs/blob - lisp/buff-menu.el

   1 ;;; buff-menu.el --- buffer menu main function and support functions.
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;; Edit, delete, or change attributes of all currently active Emacs
  26 ;; buffers from a list summarizing their state.  A good way to browse
  27 ;; any special or scratch buffers you have loaded, since you can't find
  28 ;; them by filename.  The single entry point is `Buffer-menu-mode',
  29 ;; normally bound to C-x C-b.
  30
  31 ;;; Change Log:
  32
  33 ;; Merged by esr with recent mods to Emacs 19 buff-menu, 23 Mar 1993
  34 ;;
  35 ;; Modified by Bob Weiner, Motorola, Inc., 4/14/89
  36 ;;
  37 ;; Added optional backup argument to 'Buffer-menu-unmark' to make it undelete
  38 ;; current entry and then move to previous one.
  39 ;;
  40 ;; Based on FSF code dating back to 1985.
  41
  42 ;;; Code:
  43
  44 ;;;Not needed, now that q is now just quit and Buffer-menu-select is v.
  45 ;;;(defvar Buffer-menu-window-config nil
  46 ;;;  "Window configuration saved from entry to `buffer-menu'.")
  47
  48 ; Put buffer *Buffer List* into proper mode right away
  49 ; so that from now on even list-buffers is enough to get a buffer menu.
  50
  51 (defvar Buffer-menu-buffer-column nil)
  52
  53 (defvar Buffer-menu-mode-map nil "")
  54
  55 (if Buffer-menu-mode-map
  56     ()
  57   (setq Buffer-menu-mode-map (make-keymap))
  58   (suppress-keymap Buffer-menu-mode-map t)
  59   (define-key Buffer-menu-mode-map "q" 'Buffer-menu-quit)
  60   (define-key Buffer-menu-mode-map "v" 'Buffer-menu-select)
  61   (define-key Buffer-menu-mode-map "2" 'Buffer-menu-2-window)
  62   (define-key Buffer-menu-mode-map "1" 'Buffer-menu-1-window)
  63   (define-key Buffer-menu-mode-map "f" 'Buffer-menu-this-window)
  64   (define-key Buffer-menu-mode-map "o" 'Buffer-menu-other-window)
  65   (define-key Buffer-menu-mode-map "\C-o" 'Buffer-menu-switch-other-window)
  66   (define-key Buffer-menu-mode-map "s" 'Buffer-menu-save)
  67   (define-key Buffer-menu-mode-map "d" 'Buffer-menu-delete)
  68   (define-key Buffer-menu-mode-map "k" 'Buffer-menu-delete)
  69   (define-key Buffer-menu-mode-map "\C-d" 'Buffer-menu-delete-backwards)
  70   (define-key Buffer-menu-mode-map "\C-k" 'Buffer-menu-delete)
  71   (define-key Buffer-menu-mode-map "x" 'Buffer-menu-execute)
  72   (define-key Buffer-menu-mode-map " " 'next-line)
  73   (define-key Buffer-menu-mode-map "n" 'next-line)
  74   (define-key Buffer-menu-mode-map "p" 'previous-line)
  75   (define-key Buffer-menu-mode-map "\177" 'Buffer-menu-backup-unmark)
  76   (define-key Buffer-menu-mode-map "~" 'Buffer-menu-not-modified)
  77   (define-key Buffer-menu-mode-map "?" 'describe-mode)
  78   (define-key Buffer-menu-mode-map "u" 'Buffer-menu-unmark)
  79   (define-key Buffer-menu-mode-map "m" 'Buffer-menu-mark)
  80   (define-key Buffer-menu-mode-map "t" 'Buffer-menu-visit-tags-table)
  81   (define-key Buffer-menu-mode-map "%" 'Buffer-menu-toggle-read-only)
  82   (define-key Buffer-menu-mode-map "g" 'revert-buffer)
  83   (define-key Buffer-menu-mode-map [mouse-2] 'Buffer-menu-mouse-select)
  84 )
  85
  86 ;; Buffer Menu mode is suitable only for specially formatted data.
  87 (put 'Buffer-menu-mode 'mode-class 'special)
  88
  89 (defun Buffer-menu-mode ()
  90   "Major mode for editing a list of buffers.
  91 Each line describes one of the buffers in Emacs.
  92 Letters do not insert themselves; instead, they are commands.
  93 \\<Buffer-menu-mode-map>
  94 \\[Buffer-menu-mouse-select] -- select buffer you click on, in place of the buffer menu.
  95 \\[Buffer-menu-this-window] -- select current line's buffer in place of the buffer menu.
  96 \\[Buffer-menu-other-window] -- select that buffer in another window,
  97   so the buffer menu buffer remains visible in its window.
  98 \\[Buffer-menu-switch-other-window] -- make another window display that buffer.
  99 \\[Buffer-menu-mark] -- mark current line's buffer to be displayed.
 100 \\[Buffer-menu-select] -- select current line's buffer.
 101   Also show buffers marked with m, in other windows.
 102 \\[Buffer-menu-1-window] -- select that buffer in full-frame window.
 103 \\[Buffer-menu-2-window] -- select that buffer in one window,
 104   together with buffer selected before this one in another window.
 105 \\[Buffer-menu-visit-tags-table] -- visit-tags-table this buffer.
 106 \\[Buffer-menu-not-modified] -- clear modified-flag on that buffer.
 107 \\[Buffer-menu-save] -- mark that buffer to be saved, and move down.
 108 \\[Buffer-menu-delete] -- mark that buffer to be deleted, and move down.
 109 \\[Buffer-menu-delete-backwards] -- mark that buffer to be deleted, and move up.
 110 \\[Buffer-menu-execute] -- delete or save marked buffers.
 111 \\[Buffer-menu-unmark] -- remove all kinds of marks from current line.
 112   With prefix argument, also move up one line.
 113 \\[Buffer-menu-backup-unmark] -- back up a line and remove marks.
 114 \\[Buffer-menu-toggle-read-only] -- toggle read-only status of buffer on this line."
 115   (kill-all-local-variables)
 116   (use-local-map Buffer-menu-mode-map)
 117   (setq major-mode 'Buffer-menu-mode)
 118   (setq mode-name "Buffer Menu")
 119   (save-excursion
 120     (goto-char (point-min))
 121     (search-forward "Buffer")
 122     (backward-word 1)
 123     (setq Buffer-menu-buffer-column (current-column))
 124     (forward-line 2)
 125     (while (not (eobp))
 126       (let ((where (Buffer-menu-buffer-name-position)))
 127         (put-text-property (car where) (cdr where) 'mouse-face 'highlight))
 128       (forward-line 1)))
 129   (make-local-variable 'revert-buffer-function)
 130   (setq revert-buffer-function 'Buffer-menu-revert-function)
 131   (setq truncate-lines t)
 132   (setq buffer-read-only t)
 133   (run-hooks 'buffer-menu-mode-hook))
 134
 135 (defun Buffer-menu-revert-function (ignore1 ignore2)
 136   (list-buffers))
 137 \f
 138 (defun Buffer-menu-buffer (error-if-non-existent-p)
 139   "Return buffer described by this line of buffer menu."
 140   (let* ((where (Buffer-menu-buffer-name-position))
 141          (string (buffer-substring (car where) (cdr where))))
 142     (or (get-buffer string)
 143         (if error-if-non-existent-p
 144             (error "No buffer named \"%s\"" string)
 145           nil))))
 146
 147 ;; Find the start and end positions of the buffer name on this line.
 148 ;; Returns a cons (START . END).
 149 (defun Buffer-menu-buffer-name-position ()
 150   (save-excursion
 151     (beginning-of-line)
 152     (forward-char Buffer-menu-buffer-column)
 153     (let ((start (point)))
 154       (re-search-forward "\t\\|  ")
 155       (skip-chars-backward " \t")
 156       (cons start (point)))))
 157 \f
 158 (defun buffer-menu (&optional arg)
 159   "Make a menu of buffers so you can save, delete or select them.
 160 With argument, show only buffers that are visiting files.
 161 Type ? after invocation to get help on commands available.
 162 Type q immediately to make the buffer menu go away and to restore
 163 previous window configuration."
 164   (interactive "P")
 165 ;;;  (setq Buffer-menu-window-config (current-window-configuration))
 166   (list-buffers arg)
 167   (pop-to-buffer "*Buffer List*")
 168   (forward-line 2)
 169   (message
 170    "Commands: d, s, x, u; f, o, 1, 2, m, v; ~, %%; q to quit; ? for help."))
 171
 172 (defun Buffer-menu-quit ()
 173   "Quit the buffer menu."
 174   (interactive)
 175   (let ((buffer (current-buffer)))
 176     ;; Restore previous window configuration before displaying
 177     ;; selected buffers.
 178     (switch-to-buffer (other-buffer))
 179     (bury-buffer buffer)))
 180
 181 (defun Buffer-menu-mark ()
 182   "Mark buffer on this line for being displayed by \\<Buffer-menu-mode-map>\\[Buffer-menu-select] command."
 183   (interactive)
 184   (beginning-of-line)
 185   (if (looking-at " [-M]")
 186       (ding)
 187     (let ((buffer-read-only nil))
 188       (delete-char 1)
 189       (insert ?>)
 190       (forward-line 1))))
 191
 192 (defun Buffer-menu-unmark (&optional backup)
 193   "Cancel all requested operations on buffer on this line and move down.
 194 Optional ARG means move up."
 195   (interactive "P")
 196   (beginning-of-line)
 197   (if (looking-at " [-M]")
 198       (ding)
 199     (let* ((buf (Buffer-menu-buffer t))
 200            (mod (buffer-modified-p buf))
 201            (readonly (save-excursion (set-buffer buf) buffer-read-only))
 202            (buffer-read-only nil))
 203       (delete-char 3)
 204       (insert (if readonly (if mod " *%" "  %") (if mod " * " "   ")))))
 205   (forward-line (if backup -1 1)))
 206
 207 (defun Buffer-menu-backup-unmark ()
 208   "Move up and cancel all requested operations on buffer on line above."
 209   (interactive)
 210   (forward-line -1)
 211   (Buffer-menu-unmark)
 212   (forward-line -1))
 213
 214 (defun Buffer-menu-delete ()
 215   "Mark buffer on this line to be deleted by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command."
 216   (interactive)
 217   (beginning-of-line)
 218   (if (looking-at " [-M]")              ;header lines
 219       (ding)
 220     (let ((buffer-read-only nil))
 221       (delete-char 1)
 222       (insert ?D)
 223       (forward-line 1))))
 224
 225 (defun Buffer-menu-delete-backwards ()
 226   "Mark buffer on this line to be deleted by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command
 227 and then move up one line"
 228   (interactive)
 229   (Buffer-menu-delete)
 230   (forward-line -2)
 231   (if (looking-at " [-M]") (forward-line 1)))
 232
 233 (defun Buffer-menu-save ()
 234   "Mark buffer on this line to be saved by \\<Buffer-menu-mode-map>\\[Buffer-menu-execute] command."
 235   (interactive)
 236   (beginning-of-line)
 237   (forward-char 1)
 238   (if (looking-at " [-M]")              ;header lines
 239       (ding)
 240     (let ((buffer-read-only nil))
 241       (delete-char 1)
 242       (insert ?S)
 243       (forward-line 1))))
 244
 245 (defun Buffer-menu-not-modified ()
 246   "Mark buffer on this line as unmodified (no changes to save)."
 247   (interactive)
 248   (save-excursion
 249     (set-buffer (Buffer-menu-buffer t))
 250     (set-buffer-modified-p nil))
 251   (save-excursion
 252    (beginning-of-line)
 253    (forward-char 1)
 254    (if (looking-at "\\*")
 255        (let ((buffer-read-only nil))
 256          (delete-char 1)
 257          (insert ? )))))
 258
 259 (defun Buffer-menu-execute ()
 260   "Save and/or delete buffers marked with \\<Buffer-menu-mode-map>\\[Buffer-menu-save] or \\<Buffer-menu-mode-map>\\[Buffer-menu-delete] commands."
 261   (interactive)
 262   (save-excursion
 263     (goto-char (point-min))
 264     (forward-line 1)
 265     (while (re-search-forward "^.S" nil t)
 266       (let ((modp nil))
 267         (save-excursion
 268           (set-buffer (Buffer-menu-buffer t))
 269           (save-buffer)
 270           (setq modp (buffer-modified-p)))
 271         (let ((buffer-read-only nil))
 272           (delete-char -1)
 273           (insert (if modp ?* ? ))))))
 274   (save-excursion
 275     (goto-char (point-min))
 276     (forward-line 1)
 277     (let ((buff-menu-buffer (current-buffer))
 278           (buffer-read-only nil))
 279       (while (search-forward "\nD" nil t)
 280         (forward-char -1)
 281         (let ((buf (Buffer-menu-buffer nil)))
 282           (or (eq buf nil)
 283               (eq buf buff-menu-buffer)
 284               (save-excursion (kill-buffer buf))))
 285         (if (Buffer-menu-buffer nil)
 286             (progn (delete-char 1)
 287                    (insert ? ))
 288           (delete-region (point) (progn (forward-line 1) (point)))
 289           (forward-char -1))))))
 290
 291 (defun Buffer-menu-select ()
 292   "Select this line's buffer; also display buffers marked with `>'.
 293 You can mark buffers with the \\<Buffer-menu-mode-map>\\[Buffer-menu-mark] command."
 294   (interactive)
 295   (let ((buff (Buffer-menu-buffer t))
 296         (menu (current-buffer))
 297         (others ())
 298         tem)
 299     (goto-char (point-min))
 300     (while (search-forward "\n>" nil t)
 301       (setq tem (Buffer-menu-buffer t))
 302       (let ((buffer-read-only nil))
 303         (delete-char -1)
 304         (insert ?\ ))
 305       (or (eq tem buff) (memq tem others) (setq others (cons tem others))))
 306     (setq others (nreverse others)
 307           tem (/ (1- (frame-height)) (1+ (length others))))
 308     (delete-other-windows)
 309     (switch-to-buffer buff)
 310     (or (eq menu buff)
 311         (bury-buffer menu))
 312     (if (equal (length others) 0)
 313         (progn
 314 ;;;       ;; Restore previous window configuration before displaying
 315 ;;;       ;; selected buffers.
 316 ;;;       (if Buffer-menu-window-config
 317 ;;;           (progn
 318 ;;;             (set-window-configuration Buffer-menu-window-config)
 319 ;;;             (setq Buffer-menu-window-config nil)))
 320           (switch-to-buffer buff))
 321       (while others
 322         (split-window nil tem)
 323         (other-window 1)
 324         (switch-to-buffer (car others))
 325         (setq others (cdr others)))
 326       (other-window 1)                          ;back to the beginning!
 327 )))
 328
 329 \f
 330 (defun Buffer-menu-visit-tags-table ()
 331   "Visit the tags table in the buffer on this line.  See `visit-tags-table'."
 332   (interactive)
 333   (let ((file (buffer-file-name (Buffer-menu-buffer t))))
 334     (if file
 335         (visit-tags-table file)
 336       (error "Specified buffer has no file"))))
 337
 338 (defun Buffer-menu-1-window ()
 339   "Select this line's buffer, alone, in full frame."
 340   (interactive)
 341   (switch-to-buffer (Buffer-menu-buffer t))
 342   (bury-buffer (other-buffer))
 343   (delete-other-windows))
 344
 345 (defun Buffer-menu-mouse-select (event)
 346   "Select the buffer whose line you click on."
 347   (interactive "e")
 348   (let (buffer)
 349     (save-excursion
 350       (set-buffer (window-buffer (posn-window (event-end event))))
 351       (save-excursion
 352         (goto-char (posn-point (event-end event)))
 353         (setq buffer (Buffer-menu-buffer t))))
 354     (select-window (posn-window (event-end event)))
 355     (if (and (window-dedicated-p (selected-window))
 356              (eq (selected-window) (frame-root-window)))
 357         (switch-to-buffer-other-frame buffer)
 358       (switch-to-buffer buffer))))
 359
 360 (defun Buffer-menu-this-window ()
 361   "Select this line's buffer in this window."
 362   (interactive)
 363   (switch-to-buffer (Buffer-menu-buffer t)))
 364
 365 (defun Buffer-menu-other-window ()
 366   "Select this line's buffer in other window, leaving buffer menu visible."
 367   (interactive)
 368   (switch-to-buffer-other-window (Buffer-menu-buffer t)))
 369
 370 (defun Buffer-menu-switch-other-window ()
 371   "Make the other window select this line's buffer.
 372 The current window remains selected."
 373   (interactive)
 374   (display-buffer (Buffer-menu-buffer t)))
 375
 376 (defun Buffer-menu-2-window ()
 377   "Select this line's buffer, with previous buffer in second window."
 378   (interactive)
 379   (let ((buff (Buffer-menu-buffer t))
 380         (menu (current-buffer))
 381         (pop-up-windows t))
 382     (delete-other-windows)
 383     (switch-to-buffer (other-buffer))
 384     (pop-to-buffer buff)
 385     (bury-buffer menu)))
 386
 387 (defun Buffer-menu-toggle-read-only ()
 388   "Toggle read-only status of buffer on this line, perhaps via version control."
 389   (interactive)
 390   (let (char)
 391     (save-excursion
 392       (set-buffer (Buffer-menu-buffer t))
 393       (vc-toggle-read-only)
 394       (setq char (if buffer-read-only ?% ? )))
 395     (save-excursion
 396       (beginning-of-line)
 397       (forward-char 2)
 398       (if (/= (following-char) char)
 399           (let (buffer-read-only)
 400             (delete-char 1)
 401             (insert char))))))
 402
 403 ;;; buff-menu.el ends here