code.delx.au - gnu-emacs/blob - lisp/progmodes/elisp-mode.el

   1 ;;; elisp-mode.el --- Emacs Lisp mode  -*- lexical-binding:t -*-
   2
   3 ;; Copyright (C) 1985-1986, 1999-2015 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: emacs-devel@gnu.org
   6 ;; Keywords: lisp, languages
   7 ;; Package: emacs
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; The major mode for editing Emacs Lisp code.
  27 ;; This mode is documented in the Emacs manual.
  28
  29 ;;; Code:
  30
  31 (require 'cl-generic)
  32 (require 'lisp-mode)
  33 (eval-when-compile (require 'cl-lib))
  34
  35 (define-abbrev-table 'emacs-lisp-mode-abbrev-table ()
  36   "Abbrev table for Emacs Lisp mode.
  37 It has `lisp-mode-abbrev-table' as its parent."
  38   :parents (list lisp-mode-abbrev-table))
  39
  40 (defvar emacs-lisp-mode-syntax-table
  41   (let ((table (make-syntax-table lisp--mode-syntax-table)))
  42     (modify-syntax-entry ?\[ "(]  " table)
  43     (modify-syntax-entry ?\] ")[  " table)
  44     table)
  45   "Syntax table used in `emacs-lisp-mode'.")
  46
  47 (defvar emacs-lisp-mode-map
  48   (let ((map (make-sparse-keymap "Emacs-Lisp"))
  49         (menu-map (make-sparse-keymap "Emacs-Lisp"))
  50         (lint-map (make-sparse-keymap))
  51         (prof-map (make-sparse-keymap))
  52         (tracing-map (make-sparse-keymap)))
  53     (set-keymap-parent map lisp-mode-shared-map)
  54     (define-key map "\e\t" 'completion-at-point)
  55     (define-key map "\e\C-x" 'eval-defun)
  56     (define-key map "\e\C-q" 'indent-pp-sexp)
  57     (bindings--define-key map [menu-bar emacs-lisp]
  58       (cons "Emacs-Lisp" menu-map))
  59     (bindings--define-key menu-map [eldoc]
  60       '(menu-item "Auto-Display Documentation Strings" eldoc-mode
  61                   :button (:toggle . (bound-and-true-p eldoc-mode))
  62                   :help "Display the documentation string for the item under cursor"))
  63     (bindings--define-key menu-map [checkdoc]
  64       '(menu-item "Check Documentation Strings" checkdoc
  65                   :help "Check documentation strings for style requirements"))
  66     (bindings--define-key menu-map [re-builder]
  67       '(menu-item "Construct Regexp" re-builder
  68                   :help "Construct a regexp interactively"))
  69     (bindings--define-key menu-map [tracing] (cons "Tracing" tracing-map))
  70     (bindings--define-key tracing-map [tr-a]
  71       '(menu-item "Untrace All" untrace-all
  72                   :help "Untrace all currently traced functions"))
  73     (bindings--define-key tracing-map [tr-uf]
  74       '(menu-item "Untrace Function..." untrace-function
  75                   :help "Untrace function, and possibly activate all remaining advice"))
  76     (bindings--define-key tracing-map [tr-sep] menu-bar-separator)
  77     (bindings--define-key tracing-map [tr-q]
  78       '(menu-item "Trace Function Quietly..." trace-function-background
  79                   :help "Trace the function with trace output going quietly to a buffer"))
  80     (bindings--define-key tracing-map [tr-f]
  81       '(menu-item "Trace Function..." trace-function
  82                   :help "Trace the function given as an argument"))
  83     (bindings--define-key menu-map [profiling] (cons "Profiling" prof-map))
  84     (bindings--define-key prof-map [prof-restall]
  85       '(menu-item "Remove Instrumentation for All Functions" elp-restore-all
  86                   :help "Restore the original definitions of all functions being profiled"))
  87     (bindings--define-key prof-map [prof-restfunc]
  88       '(menu-item "Remove Instrumentation for Function..." elp-restore-function
  89                   :help "Restore an instrumented function to its original definition"))
  90
  91     (bindings--define-key prof-map [sep-rem] menu-bar-separator)
  92     (bindings--define-key prof-map [prof-resall]
  93       '(menu-item "Reset Counters for All Functions" elp-reset-all
  94                   :help "Reset the profiling information for all functions being profiled"))
  95     (bindings--define-key prof-map [prof-resfunc]
  96       '(menu-item "Reset Counters for Function..." elp-reset-function
  97                   :help "Reset the profiling information for a function"))
  98     (bindings--define-key prof-map [prof-res]
  99       '(menu-item "Show Profiling Results" elp-results
 100                   :help "Display current profiling results"))
 101     (bindings--define-key prof-map [prof-pack]
 102       '(menu-item "Instrument Package..." elp-instrument-package
 103                   :help "Instrument for profiling all function that start with a prefix"))
 104     (bindings--define-key prof-map [prof-func]
 105       '(menu-item "Instrument Function..." elp-instrument-function
 106                   :help "Instrument a function for profiling"))
 107     ;; Maybe this should be in a separate submenu from the ELP stuff?
 108     (bindings--define-key prof-map [sep-natprof] menu-bar-separator)
 109     (bindings--define-key prof-map [prof-natprof-stop]
 110       '(menu-item "Stop Native Profiler" profiler-stop
 111                   :help "Stop recording profiling information"
 112                   :enable (and (featurep 'profiler)
 113                                (profiler-running-p))))
 114     (bindings--define-key prof-map [prof-natprof-report]
 115       '(menu-item "Show Profiler Report" profiler-report
 116                   :help "Show the current profiler report"
 117                   :enable (and (featurep 'profiler)
 118                                (profiler-running-p))))
 119     (bindings--define-key prof-map [prof-natprof-start]
 120       '(menu-item "Start Native Profiler..." profiler-start
 121                   :help "Start recording profiling information"))
 122
 123     (bindings--define-key menu-map [lint] (cons "Linting" lint-map))
 124     (bindings--define-key lint-map [lint-di]
 125       '(menu-item "Lint Directory..." elint-directory
 126                   :help "Lint a directory"))
 127     (bindings--define-key lint-map [lint-f]
 128       '(menu-item "Lint File..." elint-file
 129                   :help "Lint a file"))
 130     (bindings--define-key lint-map [lint-b]
 131       '(menu-item "Lint Buffer" elint-current-buffer
 132                   :help "Lint the current buffer"))
 133     (bindings--define-key lint-map [lint-d]
 134       '(menu-item "Lint Defun" elint-defun
 135                   :help "Lint the function at point"))
 136     (bindings--define-key menu-map [edebug-defun]
 137       '(menu-item "Instrument Function for Debugging" edebug-defun
 138                   :help "Evaluate the top level form point is in, stepping through with Edebug"
 139                   :keys "C-u C-M-x"))
 140     (bindings--define-key menu-map [separator-byte] menu-bar-separator)
 141     (bindings--define-key menu-map [disas]
 142       '(menu-item "Disassemble Byte Compiled Object..." disassemble
 143                   :help "Print disassembled code for OBJECT in a buffer"))
 144     (bindings--define-key menu-map [byte-recompile]
 145       '(menu-item "Byte-recompile Directory..." byte-recompile-directory
 146                   :help "Recompile every `.el' file in DIRECTORY that needs recompilation"))
 147     (bindings--define-key menu-map [emacs-byte-compile-and-load]
 148       '(menu-item "Byte-compile and Load" emacs-lisp-byte-compile-and-load
 149                   :help "Byte-compile the current file (if it has changed), then load compiled code"))
 150     (bindings--define-key menu-map [byte-compile]
 151       '(menu-item "Byte-compile This File" emacs-lisp-byte-compile
 152                   :help "Byte compile the file containing the current buffer"))
 153     (bindings--define-key menu-map [separator-eval] menu-bar-separator)
 154     (bindings--define-key menu-map [ielm]
 155       '(menu-item "Interactive Expression Evaluation" ielm
 156                   :help "Interactively evaluate Emacs Lisp expressions"))
 157     (bindings--define-key menu-map [eval-buffer]
 158       '(menu-item "Evaluate Buffer" eval-buffer
 159                   :help "Execute the current buffer as Lisp code"))
 160     (bindings--define-key menu-map [eval-region]
 161       '(menu-item "Evaluate Region" eval-region
 162                   :help "Execute the region as Lisp code"
 163                   :enable mark-active))
 164     (bindings--define-key menu-map [eval-sexp]
 165       '(menu-item "Evaluate Last S-expression" eval-last-sexp
 166                   :help "Evaluate sexp before point; print value in echo area"))
 167     (bindings--define-key menu-map [separator-format] menu-bar-separator)
 168     (bindings--define-key menu-map [comment-region]
 169       '(menu-item "Comment Out Region" comment-region
 170                   :help "Comment or uncomment each line in the region"
 171                   :enable mark-active))
 172     (bindings--define-key menu-map [indent-region]
 173       '(menu-item "Indent Region" indent-region
 174                   :help "Indent each nonblank line in the region"
 175                   :enable mark-active))
 176     (bindings--define-key menu-map [indent-line]
 177       '(menu-item "Indent Line" lisp-indent-line))
 178     map)
 179   "Keymap for Emacs Lisp mode.
 180 All commands in `lisp-mode-shared-map' are inherited by this map.")
 181
 182 (defun emacs-lisp-byte-compile ()
 183   "Byte compile the file containing the current buffer."
 184   (interactive)
 185   (if buffer-file-name
 186       (byte-compile-file buffer-file-name)
 187     (error "The buffer must be saved in a file first")))
 188
 189 (defun emacs-lisp-byte-compile-and-load ()
 190   "Byte-compile the current file (if it has changed), then load compiled code."
 191   (interactive)
 192   (or buffer-file-name
 193       (error "The buffer must be saved in a file first"))
 194   (require 'bytecomp)
 195   ;; Recompile if file or buffer has changed since last compilation.
 196   (if (and (buffer-modified-p)
 197            (y-or-n-p (format "Save buffer %s first? " (buffer-name))))
 198       (save-buffer))
 199   (byte-recompile-file buffer-file-name nil 0 t))
 200
 201 (defun emacs-lisp-macroexpand ()
 202   "Macroexpand the form after point.
 203 Comments in the form will be lost."
 204   (interactive)
 205   (let* ((start (point))
 206          (exp (read (current-buffer)))
 207          ;; Compute it before, since it may signal errors.
 208          (new (macroexpand-1 exp)))
 209     (if (equal exp new)
 210         (message "Not a macro call, nothing to expand")
 211       (delete-region start (point))
 212       (pp new (current-buffer))
 213       (if (bolp) (delete-char -1))
 214       (indent-region start (point)))))
 215
 216 (defcustom emacs-lisp-mode-hook nil
 217   "Hook run when entering Emacs Lisp mode."
 218   :options '(eldoc-mode imenu-add-menubar-index checkdoc-minor-mode)
 219   :type 'hook
 220   :group 'lisp)
 221
 222 ;;;###autoload
 223 (define-derived-mode emacs-lisp-mode prog-mode "Emacs-Lisp"
 224   "Major mode for editing Lisp code to run in Emacs.
 225 Commands:
 226 Delete converts tabs to spaces as it moves back.
 227 Blank lines separate paragraphs.  Semicolons start comments.
 228
 229 \\{emacs-lisp-mode-map}"
 230   :group 'lisp
 231   (defvar xref-find-function)
 232   (defvar xref-identifier-completion-table-function)
 233   (defvar project-search-path-function)
 234   (lisp-mode-variables nil nil 'elisp)
 235   (add-hook 'after-load-functions #'elisp--font-lock-flush-elisp-buffers)
 236   (setq-local electric-pair-text-pairs
 237               (append '((?\` . ?\') (?‘ . ?’)) electric-pair-text-pairs))
 238   (setq-local electric-quote-string t)
 239   (setq imenu-case-fold-search nil)
 240   (add-function :before-until (local 'eldoc-documentation-function)
 241                 #'elisp-eldoc-documentation-function)
 242   (setq-local xref-find-function #'elisp-xref-find)
 243   (setq-local xref-identifier-completion-table-function
 244               #'elisp--xref-identifier-completion-table)
 245   (setq-local project-search-path-function #'elisp-search-path)
 246   (add-hook 'completion-at-point-functions
 247             #'elisp-completion-at-point nil 'local))
 248
 249 ;; Font-locking support.
 250
 251 (defun elisp--font-lock-flush-elisp-buffers (&optional file)
 252   ;; FIXME: Aren't we only ever called from after-load-functions?
 253   ;; Don't flush during load unless called from after-load-functions.
 254   ;; In that case, FILE is non-nil.  It's somehow strange that
 255   ;; load-in-progress is t when an after-load-function is called since
 256   ;; that should run *after* the load...
 257   (when (or (not load-in-progress) file)
 258     ;; FIXME: If the loaded file did not define any macros, there shouldn't
 259     ;; be any need to font-lock-flush all the Elisp buffers.
 260     (dolist (buf (buffer-list))
 261       (with-current-buffer buf
 262         (when (derived-mode-p 'emacs-lisp-mode)
 263           ;; So as to take into account new macros that may have been defined
 264           ;; by the just-loaded file.
 265           (font-lock-flush))))))
 266
 267 ;;; Completion at point for Elisp
 268
 269 (defun elisp--local-variables-1 (vars sexp)
 270   "Return the vars locally bound around the witness, or nil if not found."
 271   (let (res)
 272     (while
 273         (unless
 274             (setq res
 275                   (pcase sexp
 276                     (`(,(or `let `let*) ,bindings)
 277                      (let ((vars vars))
 278                        (when (eq 'let* (car sexp))
 279                          (dolist (binding (cdr (reverse bindings)))
 280                            (push (or (car-safe binding) binding) vars)))
 281                        (elisp--local-variables-1
 282                         vars (car (cdr-safe (car (last bindings)))))))
 283                     (`(,(or `let `let*) ,bindings . ,body)
 284                      (let ((vars vars))
 285                        (dolist (binding bindings)
 286                          (push (or (car-safe binding) binding) vars))
 287                        (elisp--local-variables-1 vars (car (last body)))))
 288                     (`(lambda ,_args)
 289                      ;; FIXME: Look for the witness inside `args'.
 290                      (setq sexp nil))
 291                     (`(lambda ,args . ,body)
 292                      (elisp--local-variables-1
 293                       (append (remq '&optional (remq '&rest args)) vars)
 294                       (car (last body))))
 295                     (`(condition-case ,_ ,e) (elisp--local-variables-1 vars e))
 296                     (`(condition-case ,v ,_ . ,catches)
 297                      (elisp--local-variables-1
 298                       (cons v vars) (cdr (car (last catches)))))
 299                     (`(quote . ,_)
 300                      ;; FIXME: Look for the witness inside sexp.
 301                      (setq sexp nil))
 302                     ;; FIXME: Handle `cond'.
 303                     (`(,_ . ,_)
 304                      (elisp--local-variables-1 vars (car (last sexp))))
 305                     (`elisp--witness--lisp (or vars '(nil)))
 306                     (_ nil)))
 307           ;; We didn't find the witness in the last element so we try to
 308           ;; backtrack to the last-but-one.
 309           (setq sexp (ignore-errors (butlast sexp)))))
 310     res))
 311
 312 (defun elisp--local-variables ()
 313   "Return a list of locally let-bound variables at point."
 314   (save-excursion
 315     (skip-syntax-backward "w_")
 316     (let* ((ppss (syntax-ppss))
 317            (txt (buffer-substring-no-properties (or (car (nth 9 ppss)) (point))
 318                                                 (or (nth 8 ppss) (point))))
 319            (closer ()))
 320       (dolist (p (nth 9 ppss))
 321         (push (cdr (syntax-after p)) closer))
 322       (setq closer (apply #'string closer))
 323       (let* ((sexp (condition-case nil
 324                        (car (read-from-string
 325                              (concat txt "elisp--witness--lisp" closer)))
 326                      ((invalid-read-syntax end-of-file) nil)))
 327              (macroexpand-advice (lambda (expander form &rest args)
 328                                    (condition-case nil
 329                                        (apply expander form args)
 330                                      (error form))))
 331              (sexp
 332               (unwind-protect
 333                   (progn
 334                     (advice-add 'macroexpand :around macroexpand-advice)
 335                     (macroexpand-all sexp))
 336                 (advice-remove 'macroexpand macroexpand-advice)))
 337              (vars (elisp--local-variables-1 nil sexp)))
 338         (delq nil
 339               (mapcar (lambda (var)
 340                         (and (symbolp var)
 341                              (not (string-match (symbol-name var) "\\`[&_]"))
 342                              ;; Eliminate uninterned vars.
 343                              (intern-soft var)
 344                              var))
 345                       vars))))))
 346
 347 (defvar elisp--local-variables-completion-table
 348   ;; Use `defvar' rather than `defconst' since defconst would purecopy this
 349   ;; value, which would doubly fail: it would fail because purecopy can't
 350   ;; handle the recursive bytecode object, and it would fail because it would
 351   ;; move `lastpos' and `lastvars' to pure space where they'd be immutable!
 352   (let ((lastpos nil) (lastvars nil))
 353     (letrec ((hookfun (lambda ()
 354                         (setq lastpos nil)
 355                         (remove-hook 'post-command-hook hookfun))))
 356       (completion-table-dynamic
 357        (lambda (_string)
 358          (save-excursion
 359            (skip-syntax-backward "_w")
 360            (let ((newpos (cons (point) (current-buffer))))
 361              (unless (equal lastpos newpos)
 362                (add-hook 'post-command-hook hookfun)
 363                (setq lastpos newpos)
 364                (setq lastvars
 365                      (mapcar #'symbol-name (elisp--local-variables))))))
 366          lastvars)))))
 367
 368 (defun elisp--expect-function-p (pos)
 369   "Return non-nil if the symbol at point is expected to be a function."
 370   (or
 371    (and (eq (char-before pos) ?')
 372         (eq (char-before (1- pos)) ?#))
 373    (save-excursion
 374      (let ((parent (nth 1 (syntax-ppss pos))))
 375        (when parent
 376          (goto-char parent)
 377          (and
 378           (looking-at (concat "(\\(cl-\\)?"
 379                               (regexp-opt '("declare-function"
 380                                             "function" "defadvice"
 381                                             "callf" "callf2"
 382                                             "defsetf"))
 383                               "[ \t\r\n]+"))
 384           (eq (match-end 0) pos)))))))
 385
 386 (defun elisp--form-quoted-p (pos)
 387   "Return non-nil if the form at POS is not evaluated.
 388 It can be quoted, or be inside a quoted form."
 389   ;; FIXME: Do some macro expansion maybe.
 390   (save-excursion
 391     (let ((state (syntax-ppss pos)))
 392       (or (nth 8 state)   ; Code inside strings usually isn't evaluated.
 393           ;; FIXME: The 9th element is undocumented.
 394           (let ((nesting (cons (point) (reverse (nth 9 state))))
 395                 res)
 396             (while (and nesting (not res))
 397               (goto-char (pop nesting))
 398               (cond
 399                ((or (eq (char-after) ?\[)
 400                     (progn
 401                       (skip-chars-backward " ")
 402                       (memq (char-before) '(?' ?` ?‘))))
 403                 (setq res t))
 404                ((eq (char-before) ?,)
 405                 (setq nesting nil))))
 406             res)))))
 407
 408 ;; FIXME: Support for Company brings in features which straddle eldoc.
 409 ;; We should consolidate this, so that major modes can provide all that
 410 ;; data all at once:
 411 ;; - a function to extract "the reference at point" (may be more complex
 412 ;;     than a mere string, to distinguish various namespaces).
 413 ;; - a function to jump to such a reference.
 414 ;; - a function to show the signature/interface of such a reference.
 415 ;; - a function to build a help-buffer about that reference.
 416 ;; FIXME: Those functions should also be used by the normal completion code in
 417 ;; the *Completions* buffer.
 418
 419 (defun elisp--company-doc-buffer (str)
 420   (let ((symbol (intern-soft str)))
 421     ;; FIXME: we really don't want to "display-buffer and then undo it".
 422     (save-window-excursion
 423       ;; Make sure we don't display it in another frame, otherwise
 424       ;; save-window-excursion won't be able to undo it.
 425       (let ((display-buffer-overriding-action
 426              '(nil . ((inhibit-switch-frame . t)))))
 427         (ignore-errors
 428           (cond
 429            ((fboundp symbol) (describe-function symbol))
 430            ((boundp symbol) (describe-variable symbol))
 431            ((featurep symbol) (describe-package symbol))
 432            ((facep symbol) (describe-face symbol))
 433            (t (signal 'user-error nil)))
 434           (help-buffer))))))
 435
 436 (defun elisp--company-doc-string (str)
 437   (let* ((symbol (intern-soft str))
 438          (doc (if (fboundp symbol)
 439                   (documentation symbol t)
 440                 (documentation-property symbol 'variable-documentation t))))
 441     (and (stringp doc)
 442          (string-match ".*$" doc)
 443          (match-string 0 doc))))
 444
 445 ;; can't (require 'find-func) in a preloaded file
 446 (declare-function find-library-name "find-func" (library))
 447 (declare-function find-function-library "find-func" (function &optional l-o v))
 448
 449 (defun elisp--company-location (str)
 450   (let ((sym (intern-soft str)))
 451     (cond
 452      ((fboundp sym) (find-definition-noselect sym nil))
 453      ((boundp sym) (find-definition-noselect sym 'defvar))
 454      ((featurep sym)
 455       (require 'find-func)
 456       (cons (find-file-noselect (find-library-name
 457                                  (symbol-name sym)))
 458             0))
 459      ((facep sym) (find-definition-noselect sym 'defface)))))
 460
 461 (defun elisp-completion-at-point ()
 462   "Function used for `completion-at-point-functions' in `emacs-lisp-mode'."
 463   (with-syntax-table emacs-lisp-mode-syntax-table
 464     (let* ((pos (point))
 465            (beg (condition-case nil
 466                     (save-excursion
 467                       (backward-sexp 1)
 468                       (skip-chars-forward "`',‘#")
 469                       (point))
 470                   (scan-error pos)))
 471            (end
 472             (unless (or (eq beg (point-max))
 473                         (member (char-syntax (char-after beg))
 474                                 '(?\s ?\" ?\( ?\))))
 475               (condition-case nil
 476                   (save-excursion
 477                     (goto-char beg)
 478                     (forward-sexp 1)
 479                     (skip-chars-backward "'’")
 480                     (when (>= (point) pos)
 481                       (point)))
 482                 (scan-error pos))))
 483            ;; t if in function position.
 484            (funpos (eq (char-before beg) ?\())
 485            (quoted (elisp--form-quoted-p beg)))
 486       (when (and end (or (not (nth 8 (syntax-ppss)))
 487                          (memq (char-before beg) '(?` ?‘))))
 488         (let ((table-etc
 489                (if (or (not funpos) quoted)
 490                    ;; FIXME: We could look at the first element of the list and
 491                    ;; use it to provide a more specific completion table in some
 492                    ;; cases.  E.g. filter out keywords that are not understood by
 493                    ;; the macro/function being called.
 494                    (cond
 495                     ((elisp--expect-function-p beg)
 496                      (list nil obarray
 497                            :predicate #'fboundp
 498                            :company-doc-buffer #'elisp--company-doc-buffer
 499                            :company-docsig #'elisp--company-doc-string
 500                            :company-location #'elisp--company-location))
 501                     (quoted
 502                      (list nil obarray
 503                            ;; Don't include all symbols (bug#16646).
 504                            :predicate (lambda (sym)
 505                                         (or (boundp sym)
 506                                             (fboundp sym)
 507                                             (featurep sym)
 508                                             (symbol-plist sym)))
 509                            :annotation-function
 510                            (lambda (str) (if (fboundp (intern-soft str)) " <f>"))
 511                            :company-doc-buffer #'elisp--company-doc-buffer
 512                            :company-docsig #'elisp--company-doc-string
 513                            :company-location #'elisp--company-location))
 514                     (t
 515                      (list nil (completion-table-merge
 516                                 elisp--local-variables-completion-table
 517                                 (apply-partially #'completion-table-with-predicate
 518                                                  obarray
 519                                                  #'boundp
 520                                                  'strict))
 521                            :company-doc-buffer #'elisp--company-doc-buffer
 522                            :company-docsig #'elisp--company-doc-string
 523                            :company-location #'elisp--company-location)))
 524                  ;; Looks like a funcall position.  Let's double check.
 525                  (save-excursion
 526                    (goto-char (1- beg))
 527                    (let ((parent
 528                           (condition-case nil
 529                               (progn (up-list -1) (forward-char 1)
 530                                      (let ((c (char-after)))
 531                                        (if (eq c ?\() ?\(
 532                                          (if (memq (char-syntax c) '(?w ?_))
 533                                              (read (current-buffer))))))
 534                             (error nil))))
 535                      (pcase parent
 536                        ;; FIXME: Rather than hardcode special cases here,
 537                        ;; we should use something like a symbol-property.
 538                        (`declare
 539                         (list t (mapcar (lambda (x) (symbol-name (car x)))
 540                                         (delete-dups
 541                                          ;; FIXME: We should include some
 542                                          ;; docstring with each entry.
 543                                          (append
 544                                           macro-declarations-alist
 545                                           defun-declarations-alist)))))
 546                        ((and (or `condition-case `condition-case-unless-debug)
 547                              (guard (save-excursion
 548                                       (ignore-errors
 549                                         (forward-sexp 2)
 550                                         (< (point) beg)))))
 551                         (list t obarray
 552                               :predicate (lambda (sym) (get sym 'error-conditions))))
 553                        ((and (or ?\( `let `let*)
 554                              (guard (save-excursion
 555                                       (goto-char (1- beg))
 556                                       (when (eq parent ?\()
 557                                         (up-list -1))
 558                                       (forward-symbol -1)
 559                                       (looking-at "\\_<let\\*?\\_>"))))
 560                         (list t obarray
 561                               :predicate #'boundp
 562                               :company-doc-buffer #'elisp--company-doc-buffer
 563                               :company-docsig #'elisp--company-doc-string
 564                               :company-location #'elisp--company-location))
 565                        (_ (list nil obarray
 566                                 :predicate #'fboundp
 567                                 :company-doc-buffer #'elisp--company-doc-buffer
 568                                 :company-docsig #'elisp--company-doc-string
 569                                 :company-location #'elisp--company-location
 570                                 ))))))))
 571           (nconc (list beg end)
 572                  (if (null (car table-etc))
 573                      (cdr table-etc)
 574                    (cons
 575                     (if (memq (char-syntax (or (char-after end) ?\s))
 576                               '(?\s ?>))
 577                         (cadr table-etc)
 578                       (apply-partially 'completion-table-with-terminator
 579                                        " " (cadr table-etc)))
 580                     (cddr table-etc)))))))))
 581
 582 (define-obsolete-function-alias
 583   'lisp-completion-at-point 'elisp-completion-at-point "25.1")
 584
 585 ;;; Xref backend
 586
 587 (declare-function xref-make-bogus-location "xref" (message))
 588 (declare-function xref-make "xref" (summary location))
 589 (declare-function xref-collect-references "xref" (symbol dir))
 590
 591 (defun elisp-xref-find (action id)
 592   (require 'find-func)
 593   ;; FIXME: use information in source near point to filter results:
 594   ;; (dvc-log-edit ...) - exclude 'feature
 595   ;; (require 'dvc-log-edit) - only 'feature
 596   ;; Semantic may provide additional information
 597   (pcase action
 598     (`definitions
 599       (let ((sym (intern-soft id)))
 600         (when sym
 601           (elisp--xref-find-definitions sym))))
 602     (`references
 603      (elisp--xref-find-references id))
 604     (`apropos
 605      (elisp--xref-find-apropos id))))
 606
 607 ;; WORKAROUND: This is nominally a constant, but the text properties
 608 ;; are not preserved thru dump if use defconst.  See bug#21237.
 609 (defvar elisp--xref-format
 610   (let ((str "(%s %s)"))
 611     (put-text-property 1 3 'face 'font-lock-keyword-face str)
 612     (put-text-property 4 6 'face 'font-lock-function-name-face str)
 613     str))
 614
 615 ;; WORKAROUND: This is nominally a constant, but the text properties
 616 ;; are not preserved thru dump if use defconst.  See bug#21237.
 617 (defvar elisp--xref-format-extra
 618   (let ((str "(%s %s %s)"))
 619     (put-text-property 1 3 'face 'font-lock-keyword-face str)
 620     (put-text-property 4 6 'face 'font-lock-function-name-face str)
 621     str))
 622
 623 (defvar find-feature-regexp);; in find-func.el
 624
 625 (defun elisp--xref-make-xref (type symbol file &optional summary)
 626   "Return an xref for TYPE SYMBOL in FILE.
 627 TYPE must be a type in `find-function-regexp-alist' (use nil for
 628 'defun).  If SUMMARY is non-nil, use it for the summary;
 629 otherwise build the summary from TYPE and SYMBOL."
 630   (xref-make (or summary
 631                  (format elisp--xref-format (or type 'defun) symbol))
 632              (xref-make-elisp-location symbol type file)))
 633
 634 (defvar elisp-xref-find-def-functions nil
 635   "List of functions to be run from `elisp--xref-find-definitions' to add additional xrefs.
 636 Called with one arg; the symbol whose definition is desired.
 637 Each function should return a list of xrefs, or nil; the first
 638 non-nil result supercedes the xrefs produced by
 639 `elisp--xref-find-definitions'.")
 640
 641 ;; FIXME: name should be singular; match xref-find-definition
 642 (defun elisp--xref-find-definitions (symbol)
 643   ;; The file name is not known when `symbol' is defined via interactive eval.
 644   (let (xrefs)
 645
 646     (let ((temp elisp-xref-find-def-functions))
 647       (while (and (null xrefs)
 648                   temp)
 649         (setq xrefs (append xrefs (funcall (pop temp) symbol)))))
 650
 651     (unless xrefs
 652       ;; alphabetical by result type symbol
 653
 654       ;; FIXME: advised function; list of advice functions
 655
 656       ;; Coding system symbols do not appear in ‘load-history’,
 657       ;; so we can’t get a location for them.
 658
 659       (when (and (symbolp symbol)
 660                  (symbol-function symbol)
 661                  (symbolp (symbol-function symbol)))
 662         ;; aliased function
 663         (let* ((alias-symbol symbol)
 664                (alias-file (symbol-file alias-symbol))
 665                (real-symbol  (symbol-function symbol))
 666                (real-file (find-lisp-object-file-name real-symbol 'defun)))
 667
 668           (when real-file
 669             (push (elisp--xref-make-xref nil real-symbol real-file) xrefs))
 670
 671           (when alias-file
 672             (push (elisp--xref-make-xref 'defalias alias-symbol alias-file) xrefs))))
 673
 674       (when (facep symbol)
 675         (let ((file (find-lisp-object-file-name symbol 'defface)))
 676           (when file
 677             (push (elisp--xref-make-xref 'defface symbol file) xrefs))))
 678
 679       (when (fboundp symbol)
 680         (let ((file (find-lisp-object-file-name symbol (symbol-function symbol)))
 681               generic doc)
 682           (when file
 683             (cond
 684              ((eq file 'C-source)
 685               ;; First call to find-lisp-object-file-name for an object
 686               ;; defined in C; the doc strings from the C source have
 687               ;; not been loaded yet.  Second call will return "src/*.c"
 688               ;; in file; handled by 't' case below.
 689               (push (elisp--xref-make-xref nil symbol (help-C-file-name (symbol-function symbol) 'subr)) xrefs))
 690
 691              ((and (setq doc (documentation symbol t))
 692                    ;; This doc string is defined in cl-macs.el cl-defstruct
 693                    (string-match "Constructor for objects of type `\\(.*\\)'" doc))
 694               ;; `symbol' is a name for the default constructor created by
 695               ;; cl-defstruct, so return the location of the cl-defstruct.
 696               (let* ((type-name (match-string 1 doc))
 697                      (type-symbol (intern type-name))
 698                      (file (find-lisp-object-file-name type-symbol 'define-type))
 699                      (summary (format elisp--xref-format-extra
 700                                       'cl-defstruct
 701                                       (concat "(" type-name)
 702                                       (concat "(:constructor " (symbol-name symbol) "))"))))
 703                 (push (elisp--xref-make-xref 'define-type type-symbol file summary) xrefs)
 704                 ))
 705
 706              ((setq generic (cl--generic symbol))
 707               ;; FIXME: move this to elisp-xref-find-def-functions, in cl-generic.el
 708
 709               ;; A generic function. If there is a default method, it
 710               ;; will appear in the method table, with no
 711               ;; specializers.
 712               ;;
 713               ;; If the default method is declared by the cl-defgeneric
 714               ;; declaration, it will have the same location as the
 715               ;; cl-defgeneric, so we want to exclude it from the
 716               ;; result. In this case, it will have a null doc
 717               ;; string. User declarations of default methods may also
 718               ;; have null doc strings, but we hope that is
 719               ;; rare. Perhaps this heuristic will discourage that.
 720               (dolist (method (cl--generic-method-table generic))
 721                 (let* ((info (cl--generic-method-info method));; qual-string combined-args doconly
 722                        (specializers (cl--generic-method-specializers method))
 723                        (non-default nil)
 724                        (met-name (cons symbol specializers))
 725                        (file (find-lisp-object-file-name met-name 'cl-defmethod)))
 726                   (dolist (item specializers)
 727                     ;; default method has all 't' in specializers
 728                     (setq non-default (or non-default (not (equal t item)))))
 729
 730                   (when (and file
 731                              (or non-default
 732                                  (nth 2 info))) ;; assuming only co-located default has null doc string
 733                     (if specializers
 734                         (let ((summary (format elisp--xref-format-extra 'cl-defmethod symbol (nth 1 info))))
 735                           (push (elisp--xref-make-xref 'cl-defmethod met-name file summary) xrefs))
 736
 737                       (let ((summary (format elisp--xref-format-extra 'cl-defmethod symbol "()")))
 738                         (push (elisp--xref-make-xref 'cl-defmethod met-name file summary) xrefs))))
 739                   ))
 740
 741               (if (and (setq doc (documentation symbol t))
 742                        ;; This doc string is created somewhere in
 743                        ;; cl--generic-make-function for an implicit
 744                        ;; defgeneric.
 745                        (string-match "\n\n(fn ARG &rest ARGS)" doc))
 746                   ;; This symbol is an implicitly defined defgeneric, so
 747                   ;; don't return it.
 748                   nil
 749                 (push (elisp--xref-make-xref 'cl-defgeneric symbol file) xrefs))
 750               )
 751
 752              (t
 753               (push (elisp--xref-make-xref nil symbol file) xrefs))
 754              ))))
 755
 756       (when (boundp symbol)
 757         ;; A variable
 758         (let ((file (find-lisp-object-file-name symbol 'defvar)))
 759           (when file
 760             (cond
 761              ((eq file 'C-source)
 762               ;; The doc strings from the C source have not been loaded
 763               ;; yet; help-C-file-name does that.  Second call will
 764               ;; return "src/*.c" in file; handled below.
 765               (push (elisp--xref-make-xref 'defvar symbol (help-C-file-name symbol 'var)) xrefs))
 766
 767              ((string= "src/" (substring file 0 4))
 768               ;; The variable is defined in a C source file; don't check
 769               ;; for define-minor-mode.
 770               (push (elisp--xref-make-xref 'defvar symbol file) xrefs))
 771
 772              ((memq symbol minor-mode-list)
 773               ;; The symbol is a minor mode. These should be defined by
 774               ;; "define-minor-mode", which means the variable and the
 775               ;; function are declared in the same place. So we return only
 776               ;; the function, arbitrarily.
 777               ;;
 778               ;; There is an exception, when the variable is defined in C
 779               ;; code, as for abbrev-mode.
 780               ;;
 781               ;; IMPROVEME: If the user is searching for the identifier at
 782               ;; point, we can determine whether it is a variable or
 783               ;; function by looking at the source code near point.
 784               ;;
 785               ;; IMPROVEME: The user may actually be asking "do any
 786               ;; variables by this name exist"; we need a way to specify
 787               ;; that.
 788               nil)
 789
 790              (t
 791               (push (elisp--xref-make-xref 'defvar symbol file) xrefs))
 792
 793              ))))
 794
 795       (when (featurep symbol)
 796         (let ((file (ignore-errors
 797                       (find-library-name (symbol-name symbol)))))
 798           (when file
 799             (push (elisp--xref-make-xref 'feature symbol file) xrefs))))
 800       );; 'unless xrefs'
 801
 802     xrefs))
 803
 804 (declare-function project-search-path "project")
 805 (declare-function project-current "project")
 806
 807 (defun elisp--xref-find-references (symbol)
 808   "Find all references to SYMBOL (a string) in the current project."
 809   (cl-mapcan
 810    (lambda (dir)
 811      (xref-collect-references symbol dir))
 812    (project-search-path (project-current))))
 813
 814 (defun elisp--xref-find-apropos (regexp)
 815   (apply #'nconc
 816          (let (lst)
 817            (dolist (sym (apropos-internal regexp))
 818             (push (elisp--xref-find-definitions sym) lst))
 819            (nreverse lst))))
 820
 821 (defvar elisp--xref-identifier-completion-table
 822   (apply-partially #'completion-table-with-predicate
 823                    obarray
 824                    (lambda (sym)
 825                      (or (boundp sym)
 826                          (fboundp sym)
 827                          (featurep sym)
 828                          (facep sym)))
 829                    'strict))
 830
 831 (defun elisp--xref-identifier-completion-table ()
 832   elisp--xref-identifier-completion-table)
 833
 834 (cl-defstruct (xref-elisp-location
 835                (:constructor xref-make-elisp-location (symbol type file)))
 836   "Location of an Emacs Lisp symbol definition."
 837   symbol type file)
 838
 839 (cl-defmethod xref-location-marker ((l xref-elisp-location))
 840   (pcase-let (((cl-struct xref-elisp-location symbol type file) l))
 841     (let ((buffer-point (find-function-search-for-symbol symbol type file)))
 842       (with-current-buffer (car buffer-point)
 843         (goto-char (or (cdr buffer-point) (point-min)))
 844         (point-marker)))))
 845
 846 (cl-defmethod xref-location-group ((l xref-elisp-location))
 847   (xref-elisp-location-file l))
 848
 849 (defun elisp-search-path ()
 850   (defvar package-user-dir)
 851   (cons package-user-dir load-path))
 852
 853 ;;; Elisp Interaction mode
 854
 855 (defvar lisp-interaction-mode-map
 856   (let ((map (make-sparse-keymap))
 857         (menu-map (make-sparse-keymap "Lisp-Interaction")))
 858     (set-keymap-parent map lisp-mode-shared-map)
 859     (define-key map "\e\C-x" 'eval-defun)
 860     (define-key map "\e\C-q" 'indent-pp-sexp)
 861     (define-key map "\e\t" 'completion-at-point)
 862     (define-key map "\n" 'eval-print-last-sexp)
 863     (bindings--define-key map [menu-bar lisp-interaction]
 864       (cons "Lisp-Interaction" menu-map))
 865     (bindings--define-key menu-map [eval-defun]
 866       '(menu-item "Evaluate Defun" eval-defun
 867                   :help "Evaluate the top-level form containing point, or after point"))
 868     (bindings--define-key menu-map [eval-print-last-sexp]
 869       '(menu-item "Evaluate and Print" eval-print-last-sexp
 870                   :help "Evaluate sexp before point; print value into current buffer"))
 871     (bindings--define-key menu-map [edebug-defun-lisp-interaction]
 872       '(menu-item "Instrument Function for Debugging" edebug-defun
 873                   :help "Evaluate the top level form point is in, stepping through with Edebug"
 874                   :keys "C-u C-M-x"))
 875     (bindings--define-key menu-map [indent-pp-sexp]
 876       '(menu-item "Indent or Pretty-Print" indent-pp-sexp
 877                   :help "Indent each line of the list starting just after point, or prettyprint it"))
 878     (bindings--define-key menu-map [complete-symbol]
 879       '(menu-item "Complete Lisp Symbol" completion-at-point
 880                   :help "Perform completion on Lisp symbol preceding point"))
 881     map)
 882   "Keymap for Lisp Interaction mode.
 883 All commands in `lisp-mode-shared-map' are inherited by this map.")
 884
 885 (define-derived-mode lisp-interaction-mode emacs-lisp-mode "Lisp Interaction"
 886   "Major mode for typing and evaluating Lisp forms.
 887 Like Lisp mode except that \\[eval-print-last-sexp] evals the Lisp expression
 888 before point, and prints its value into the buffer, advancing point.
 889 Note that printing is controlled by `eval-expression-print-length'
 890 and `eval-expression-print-level'.
 891
 892 Commands:
 893 Delete converts tabs to spaces as it moves back.
 894 Paragraphs are separated only by blank lines.
 895 Semicolons start comments.
 896
 897 \\{lisp-interaction-mode-map}"
 898   :abbrev-table nil)
 899
 900 ;;; Emacs Lisp Byte-Code mode
 901
 902 (eval-and-compile
 903   (defconst emacs-list-byte-code-comment-re
 904     (concat "\\(#\\)@\\([0-9]+\\) "
 905             ;; Make sure it's a docstring and not a lazy-loaded byte-code.
 906             "\\(?:[^(]\\|([^\"]\\)")))
 907
 908 (defun elisp--byte-code-comment (end &optional _point)
 909   "Try to syntactically mark the #@NNN ....^_ docstrings in byte-code files."
 910   (let ((ppss (syntax-ppss)))
 911     (when (and (nth 4 ppss)
 912                (eq (char-after (nth 8 ppss)) ?#))
 913       (let* ((n (save-excursion
 914                   (goto-char (nth 8 ppss))
 915                   (when (looking-at emacs-list-byte-code-comment-re)
 916                     (string-to-number (match-string 2)))))
 917              ;; `maxdiff' tries to make sure the loop below terminates.
 918              (maxdiff n))
 919         (when n
 920           (let* ((bchar (match-end 2))
 921                  (b (position-bytes bchar)))
 922             (goto-char (+ b n))
 923             (while (let ((diff (- (position-bytes (point)) b n)))
 924                      (unless (zerop diff)
 925                        (when (> diff maxdiff) (setq diff maxdiff))
 926                        (forward-char (- diff))
 927                        (setq maxdiff (if (> diff 0) diff
 928                                        (max (1- maxdiff) 1)))
 929                        t))))
 930           (if (<= (point) end)
 931               (put-text-property (1- (point)) (point)
 932                                  'syntax-table
 933                                  (string-to-syntax "> b"))
 934             (goto-char end)))))))
 935
 936 (defun elisp-byte-code-syntax-propertize (start end)
 937   (goto-char start)
 938   (elisp--byte-code-comment end (point))
 939   (funcall
 940    (syntax-propertize-rules
 941     (emacs-list-byte-code-comment-re
 942      (1 (prog1 "< b" (elisp--byte-code-comment end (point))))))
 943    start end))
 944
 945 ;;;###autoload
 946 (add-to-list 'auto-mode-alist '("\\.elc\\'" . elisp-byte-code-mode))
 947 ;;;###autoload
 948 (define-derived-mode elisp-byte-code-mode emacs-lisp-mode
 949   "Elisp-Byte-Code"
 950   "Major mode for *.elc files."
 951   ;; TODO: Add way to disassemble byte-code under point.
 952   (setq-local open-paren-in-column-0-is-defun-start nil)
 953   (setq-local syntax-propertize-function
 954               #'elisp-byte-code-syntax-propertize))
 955
 956
 957 ;;; Globally accessible functionality
 958
 959 (defun eval-print-last-sexp (&optional eval-last-sexp-arg-internal)
 960   "Evaluate sexp before point; print value into current buffer.
 961
 962 Normally, this function truncates long output according to the value
 963 of the variables `eval-expression-print-length' and
 964 `eval-expression-print-level'.  With a prefix argument of zero,
 965 however, there is no such truncation.  Such a prefix argument
 966 also causes integers to be printed in several additional formats
 967 \(octal, hexadecimal, and character).
 968
 969 If `eval-expression-debug-on-error' is non-nil, which is the default,
 970 this command arranges for all errors to enter the debugger."
 971   (interactive "P")
 972   (let ((standard-output (current-buffer)))
 973     (terpri)
 974     (eval-last-sexp (or eval-last-sexp-arg-internal t))
 975     (terpri)))
 976
 977
 978 (defun last-sexp-setup-props (beg end value alt1 alt2)
 979   "Set up text properties for the output of `elisp--eval-last-sexp'.
 980 BEG and END are the start and end of the output in current-buffer.
 981 VALUE is the Lisp value printed, ALT1 and ALT2 are strings for the
 982 alternative printed representations that can be displayed."
 983   (let ((map (make-sparse-keymap)))
 984     (define-key map "\C-m" 'elisp-last-sexp-toggle-display)
 985     (define-key map [down-mouse-2] 'mouse-set-point)
 986     (define-key map [mouse-2] 'elisp-last-sexp-toggle-display)
 987     (add-text-properties
 988      beg end
 989      `(printed-value (,value ,alt1 ,alt2)
 990                      mouse-face highlight
 991                      keymap ,map
 992                      help-echo "RET, mouse-2: toggle abbreviated display"
 993                      rear-nonsticky (mouse-face keymap help-echo
 994                                                 printed-value)))))
 995
 996
 997 (defun elisp-last-sexp-toggle-display (&optional _arg)
 998   "Toggle between abbreviated and unabbreviated printed representations."
 999   (interactive "P")
1000   (save-restriction
1001     (widen)
1002     (let ((value (get-text-property (point) 'printed-value)))
1003       (when value
1004         (let ((beg (or (previous-single-property-change (min (point-max) (1+ (point)))
1005                                                         'printed-value)
1006                        (point)))
1007               (end (or (next-single-char-property-change (point) 'printed-value) (point)))
1008               (standard-output (current-buffer))
1009               (point (point)))
1010           (delete-region beg end)
1011           (insert (nth 1 value))
1012           (or (= beg point)
1013               (setq point (1- (point))))
1014           (last-sexp-setup-props beg (point)
1015                                  (nth 0 value)
1016                                  (nth 2 value)
1017                                  (nth 1 value))
1018           (goto-char (min (point-max) point)))))))
1019
1020 (defun prin1-char (char)                ;FIXME: Move it, e.g. to simple.el.
1021   "Return a string representing CHAR as a character rather than as an integer.
1022 If CHAR is not a character, return nil."
1023   (and (integerp char)
1024        (eventp char)
1025        (let ((c (event-basic-type char))
1026              (mods (event-modifiers char))
1027              string)
1028          ;; Prevent ?A from turning into ?\S-a.
1029          (if (and (memq 'shift mods)
1030                   (zerop (logand char ?\S-\^@))
1031                   (not (let ((case-fold-search nil))
1032                          (char-equal c (upcase c)))))
1033              (setq c (upcase c) mods nil))
1034          ;; What string are we considering using?
1035          (condition-case nil
1036              (setq string
1037                    (concat
1038                     "?"
1039                     (mapconcat
1040                      (lambda (modif)
1041                        (cond ((eq modif 'super) "\\s-")
1042                              (t (string ?\\ (upcase (aref (symbol-name modif) 0)) ?-))))
1043                      mods "")
1044                     (cond
1045                      ((memq c '(?\; ?\( ?\) ?\{ ?\} ?\[ ?\] ?\" ?\' ?\\)) (string ?\\ c))
1046                      ((eq c 127) "\\C-?")
1047                      (t
1048                       (string c)))))
1049            (error nil))
1050          ;; Verify the string reads a CHAR, not to some other character.
1051          ;; If it doesn't, return nil instead.
1052          (and string
1053               (= (car (read-from-string string)) char)
1054               string))))
1055
1056 (defun elisp--preceding-sexp ()
1057   "Return sexp before the point."
1058   (let ((opoint (point))
1059         (left-quote ?‘)
1060         expr)
1061     (save-excursion
1062       (with-syntax-table emacs-lisp-mode-syntax-table
1063         ;; If this sexp appears to be enclosed in `...' or ‘...’
1064         ;; then ignore the surrounding quotes.
1065         (cond ((eq (preceding-char) ?’)
1066                (progn (forward-char -1) (setq opoint (point))))
1067               ((or (eq (following-char) ?\')
1068                    (eq (preceding-char) ?\'))
1069                (setq left-quote ?\`)))
1070         (forward-sexp -1)
1071         ;; If we were after `?\e' (or similar case),
1072         ;; use the whole thing, not just the `e'.
1073         (when (eq (preceding-char) ?\\)
1074           (forward-char -1)
1075           (when (eq (preceding-char) ??)
1076             (forward-char -1)))
1077
1078         ;; Skip over hash table read syntax.
1079         (and (> (point) (1+ (point-min)))
1080              (looking-back "#s" (- (point) 2))
1081              (forward-char -2))
1082
1083         ;; Skip over `#N='s.
1084         (when (eq (preceding-char) ?=)
1085           (let (labeled-p)
1086             (save-excursion
1087               (skip-chars-backward "0-9#=")
1088               (setq labeled-p (looking-at "\\(#[0-9]+=\\)+")))
1089             (when labeled-p
1090               (forward-sexp -1))))
1091
1092         (save-restriction
1093           (if (eq (following-char) left-quote)
1094               ;; vladimir@cs.ualberta.ca 30-Jul-1997: Skip ` in `variable' so
1095               ;; that the value is returned, not the name.
1096               (forward-char))
1097           (when (looking-at ",@?") (goto-char (match-end 0)))
1098           (narrow-to-region (point-min) opoint)
1099           (setq expr (read (current-buffer)))
1100           ;; If it's an (interactive ...) form, it's more useful to show how an
1101           ;; interactive call would use it.
1102           ;; FIXME: Is it really the right place for this?
1103           (when (eq (car-safe expr) 'interactive)
1104                (setq expr
1105                   `(call-interactively
1106                     (lambda (&rest args) ,expr args))))
1107           expr)))))
1108 (define-obsolete-function-alias 'preceding-sexp 'elisp--preceding-sexp "25.1")
1109
1110 (defun elisp--eval-last-sexp (eval-last-sexp-arg-internal)
1111   "Evaluate sexp before point; print value in the echo area.
1112 If EVAL-LAST-SEXP-ARG-INTERNAL is non-nil, print output into
1113 current buffer.  If EVAL-LAST-SEXP-ARG-INTERNAL is `0', print
1114 output with no limit on the length and level of lists, and
1115 include additional formats for integers \(octal, hexadecimal, and
1116 character)."
1117   (let ((standard-output (if eval-last-sexp-arg-internal (current-buffer) t)))
1118     ;; Setup the lexical environment if lexical-binding is enabled.
1119     (elisp--eval-last-sexp-print-value
1120      (eval (eval-sexp-add-defvars (elisp--preceding-sexp)) lexical-binding)
1121      eval-last-sexp-arg-internal)))
1122
1123
1124 (defun elisp--eval-last-sexp-print-value (value &optional eval-last-sexp-arg-internal)
1125   (let ((unabbreviated (let ((print-length nil) (print-level nil))
1126                          (prin1-to-string value)))
1127         (print-length (and (not (zerop (prefix-numeric-value
1128                                         eval-last-sexp-arg-internal)))
1129                            eval-expression-print-length))
1130         (print-level (and (not (zerop (prefix-numeric-value
1131                                        eval-last-sexp-arg-internal)))
1132                           eval-expression-print-level))
1133         (beg (point))
1134         end)
1135     (prog1
1136         (prin1 value)
1137       (let ((str (eval-expression-print-format value)))
1138         (if str (princ str)))
1139       (setq end (point))
1140       (when (and (bufferp standard-output)
1141                  (or (not (null print-length))
1142                      (not (null print-level)))
1143                  (not (string= unabbreviated
1144                                (buffer-substring-no-properties beg end))))
1145         (last-sexp-setup-props beg end value
1146                                unabbreviated
1147                                (buffer-substring-no-properties beg end))
1148         ))))
1149
1150
1151 (defvar elisp--eval-last-sexp-fake-value (make-symbol "t"))
1152
1153 (defun eval-sexp-add-defvars (exp &optional pos)
1154   "Prepend EXP with all the `defvar's that precede it in the buffer.
1155 POS specifies the starting position where EXP was found and defaults to point."
1156   (setq exp (macroexpand-all exp))      ;Eager macro-expansion.
1157   (if (not lexical-binding)
1158       exp
1159     (save-excursion
1160       (unless pos (setq pos (point)))
1161       (let ((vars ()))
1162         (goto-char (point-min))
1163         (while (re-search-forward
1164                 "(def\\(?:var\\|const\\|custom\\)[ \t\n]+\\([^; '()\n\t]+\\)"
1165                 pos t)
1166           (let ((var (intern (match-string 1))))
1167             (and (not (special-variable-p var))
1168                  (save-excursion
1169                    (zerop (car (syntax-ppss (match-beginning 0)))))
1170               (push var vars))))
1171         `(progn ,@(mapcar (lambda (v) `(defvar ,v)) vars) ,exp)))))
1172
1173 (defun eval-last-sexp (eval-last-sexp-arg-internal)
1174   "Evaluate sexp before point; print value in the echo area.
1175 Interactively, with prefix argument, print output into current buffer.
1176
1177 Normally, this function truncates long output according to the value
1178 of the variables `eval-expression-print-length' and
1179 `eval-expression-print-level'.  With a prefix argument of zero,
1180 however, there is no such truncation.  Such a prefix argument
1181 also causes integers to be printed in several additional formats
1182 \(octal, hexadecimal, and character).
1183
1184 If `eval-expression-debug-on-error' is non-nil, which is the default,
1185 this command arranges for all errors to enter the debugger."
1186   (interactive "P")
1187   (if (null eval-expression-debug-on-error)
1188       (elisp--eval-last-sexp eval-last-sexp-arg-internal)
1189     (let ((value
1190            (let ((debug-on-error elisp--eval-last-sexp-fake-value))
1191              (cons (elisp--eval-last-sexp eval-last-sexp-arg-internal)
1192                    debug-on-error))))
1193       (unless (eq (cdr value) elisp--eval-last-sexp-fake-value)
1194         (setq debug-on-error (cdr value)))
1195       (car value))))
1196
1197 (defun elisp--eval-defun-1 (form)
1198   "Treat some expressions specially.
1199 Reset the `defvar' and `defcustom' variables to the initial value.
1200 \(For `defcustom', use the :set function if there is one.)
1201 Reinitialize the face according to the `defface' specification."
1202   ;; The code in edebug-defun should be consistent with this, but not
1203   ;; the same, since this gets a macroexpanded form.
1204   (cond ((not (listp form))
1205          form)
1206         ((and (eq (car form) 'defvar)
1207               (cdr-safe (cdr-safe form))
1208               (boundp (cadr form)))
1209          ;; Force variable to be re-set.
1210          `(progn (defvar ,(nth 1 form) nil ,@(nthcdr 3 form))
1211                  (setq-default ,(nth 1 form) ,(nth 2 form))))
1212         ;; `defcustom' is now macroexpanded to
1213         ;; `custom-declare-variable' with a quoted value arg.
1214         ((and (eq (car form) 'custom-declare-variable)
1215               (default-boundp (eval (nth 1 form) lexical-binding)))
1216          ;; Force variable to be bound, using :set function if specified.
1217          (let ((setfunc (memq :set form)))
1218            (when setfunc
1219              (setq setfunc (car-safe (cdr-safe setfunc)))
1220              (or (functionp setfunc) (setq setfunc nil)))
1221            (funcall (or setfunc 'set-default)
1222                     (eval (nth 1 form) lexical-binding)
1223                     ;; The second arg is an expression that evaluates to
1224                     ;; an expression.  The second evaluation is the one
1225                     ;; normally performed not by normal execution but by
1226                     ;; custom-initialize-set (for example), which does not
1227                     ;; use lexical-binding.
1228                     (eval (eval (nth 2 form) lexical-binding))))
1229          form)
1230         ;; `defface' is macroexpanded to `custom-declare-face'.
1231         ((eq (car form) 'custom-declare-face)
1232          ;; Reset the face.
1233          (let ((face-symbol (eval (nth 1 form) lexical-binding)))
1234            (setq face-new-frame-defaults
1235                  (assq-delete-all face-symbol face-new-frame-defaults))
1236            (put face-symbol 'face-defface-spec nil)
1237            (put face-symbol 'face-override-spec nil))
1238          form)
1239         ((eq (car form) 'progn)
1240          (cons 'progn (mapcar #'elisp--eval-defun-1 (cdr form))))
1241         (t form)))
1242
1243 (defun elisp--eval-defun ()
1244   "Evaluate defun that point is in or before.
1245 The value is displayed in the echo area.
1246 If the current defun is actually a call to `defvar',
1247 then reset the variable using the initial value expression
1248 even if the variable already has some other value.
1249 \(Normally `defvar' does not change the variable's value
1250 if it already has a value.\)
1251
1252 Return the result of evaluation."
1253   ;; FIXME: the print-length/level bindings should only be applied while
1254   ;; printing, not while evaluating.
1255   (let ((debug-on-error eval-expression-debug-on-error)
1256         (print-length eval-expression-print-length)
1257         (print-level eval-expression-print-level))
1258     (save-excursion
1259       ;; Arrange for eval-region to "read" the (possibly) altered form.
1260       ;; eval-region handles recording which file defines a function or
1261       ;; variable.
1262       (let ((standard-output t)
1263             beg end form)
1264         ;; Read the form from the buffer, and record where it ends.
1265         (save-excursion
1266           (end-of-defun)
1267           (beginning-of-defun)
1268           (setq beg (point))
1269           (setq form (read (current-buffer)))
1270           (setq end (point)))
1271         ;; Alter the form if necessary.
1272         (let ((form (eval-sexp-add-defvars
1273                      (elisp--eval-defun-1 (macroexpand form)))))
1274           (eval-region beg end standard-output
1275                        (lambda (_ignore)
1276                          ;; Skipping to the end of the specified region
1277                          ;; will make eval-region return.
1278                          (goto-char end)
1279                          form))))))
1280   (let ((str (eval-expression-print-format (car values))))
1281     (if str (princ str)))
1282   ;; The result of evaluation has been put onto VALUES.  So return it.
1283   (car values))
1284
1285 (defun eval-defun (edebug-it)
1286   "Evaluate the top-level form containing point, or after point.
1287
1288 If the current defun is actually a call to `defvar' or `defcustom',
1289 evaluating it this way resets the variable using its initial value
1290 expression (using the defcustom's :set function if there is one), even
1291 if the variable already has some other value.  \(Normally `defvar' and
1292 `defcustom' do not alter the value if there already is one.)  In an
1293 analogous way, evaluating a `defface' overrides any customizations of
1294 the face, so that it becomes defined exactly as the `defface' expression
1295 says.
1296
1297 If `eval-expression-debug-on-error' is non-nil, which is the default,
1298 this command arranges for all errors to enter the debugger.
1299
1300 With a prefix argument, instrument the code for Edebug.
1301
1302 If acting on a `defun' for FUNCTION, and the function was
1303 instrumented, `Edebug: FUNCTION' is printed in the echo area.  If not
1304 instrumented, just FUNCTION is printed.
1305
1306 If not acting on a `defun', the result of evaluation is displayed in
1307 the echo area.  This display is controlled by the variables
1308 `eval-expression-print-length' and `eval-expression-print-level',
1309 which see."
1310   (interactive "P")
1311   (cond (edebug-it
1312          (require 'edebug)
1313          (eval-defun (not edebug-all-defs)))
1314         (t
1315          (if (null eval-expression-debug-on-error)
1316              (elisp--eval-defun)
1317            (let (new-value value)
1318              (let ((debug-on-error elisp--eval-last-sexp-fake-value))
1319                (setq value (elisp--eval-defun))
1320                (setq new-value debug-on-error))
1321              (unless (eq elisp--eval-last-sexp-fake-value new-value)
1322                (setq debug-on-error new-value))
1323              value)))))
1324
1325 ;;; ElDoc Support
1326
1327 (defvar elisp--eldoc-last-data (make-vector 3 nil)
1328   "Bookkeeping; elements are as follows:
1329   0 - contains the last symbol read from the buffer.
1330   1 - contains the string last displayed in the echo area for variables,
1331       or argument string for functions.
1332   2 - `function' if function args, `variable' if variable documentation.")
1333
1334 (defun elisp-eldoc-documentation-function ()
1335   "`eldoc-documentation-function' (which see) for Emacs Lisp."
1336   (let ((current-symbol (elisp--current-symbol))
1337         (current-fnsym  (elisp--fnsym-in-current-sexp)))
1338     (cond ((null current-fnsym)
1339            nil)
1340           ((eq current-symbol (car current-fnsym))
1341            (or (apply #'elisp-get-fnsym-args-string current-fnsym)
1342                (elisp-get-var-docstring current-symbol)))
1343           (t
1344            (or (elisp-get-var-docstring current-symbol)
1345                (apply #'elisp-get-fnsym-args-string current-fnsym))))))
1346
1347 (defun elisp-get-fnsym-args-string (sym &optional index prefix)
1348   "Return a string containing the parameter list of the function SYM.
1349 If SYM is a subr and no arglist is obtainable from the docstring
1350 or elsewhere, return a 1-line docstring."
1351   (let ((argstring
1352          (cond
1353           ((not (and sym (symbolp sym) (fboundp sym))) nil)
1354           ((and (eq sym (aref elisp--eldoc-last-data 0))
1355                 (eq 'function (aref elisp--eldoc-last-data 2)))
1356            (aref elisp--eldoc-last-data 1))
1357           (t
1358            (let* ((advertised (gethash (indirect-function sym)
1359                                        advertised-signature-table t))
1360                   doc
1361                   (args
1362                    (cond
1363                     ((listp advertised) advertised)
1364                     ((setq doc (help-split-fundoc
1365                                 (condition-case nil (documentation sym t)
1366                                   (invalid-function nil))
1367                                 sym))
1368                      (car doc))
1369                     (t (help-function-arglist sym)))))
1370              ;; Stringify, and store before highlighting, downcasing, etc.
1371              (elisp--last-data-store sym (elisp-function-argstring args)
1372                                     'function))))))
1373     ;; Highlight, truncate.
1374     (if argstring
1375         (elisp--highlight-function-argument
1376          sym argstring index
1377          (or prefix
1378              (concat (propertize (symbol-name sym) 'face
1379                                  (if (functionp sym)
1380                                      'font-lock-function-name-face
1381                                    'font-lock-keyword-face))
1382                      ": "))))))
1383
1384 (defun elisp--highlight-function-argument (sym args index prefix)
1385   "Highlight argument INDEX in ARGS list for function SYM.
1386 In the absence of INDEX, just call `eldoc-docstring-format-sym-doc'."
1387   ;; FIXME: This should probably work on the list representation of `args'
1388   ;; rather than its string representation.
1389   ;; FIXME: This function is much too long, we need to split it up!
1390   (let ((start          nil)
1391         (end            0)
1392         (argument-face  'eldoc-highlight-function-argument)
1393         (args-lst (mapcar (lambda (x)
1394                             (replace-regexp-in-string
1395                              "\\`[(]\\|[)]\\'" "" x))
1396                           (split-string args))))
1397     ;; Find the current argument in the argument string.  We need to
1398     ;; handle `&rest' and informal `...' properly.
1399     ;;
1400     ;; FIXME: What to do with optional arguments, like in
1401     ;;        (defun NAME ARGLIST [DOCSTRING] BODY...) case?
1402     ;;        The problem is there is no robust way to determine if
1403     ;;        the current argument is indeed a docstring.
1404
1405     ;; When `&key' is used finding position based on `index'
1406     ;; would be wrong, so find the arg at point and determine
1407     ;; position in ARGS based on this current arg.
1408     (when (string-match "&key" args)
1409       (let* (case-fold-search
1410              key-have-value
1411              (sym-name (symbol-name sym))
1412              (cur-w (current-word))
1413              (args-lst-ak (cdr (member "&key" args-lst)))
1414              (limit (save-excursion
1415                       (when (re-search-backward sym-name nil t)
1416                         (match-end 0))))
1417              (cur-a (if (and cur-w (string-match ":\\([^ ()]*\\)" cur-w))
1418                         (substring cur-w 1)
1419                       (save-excursion
1420                         (let (split)
1421                           (when (re-search-backward ":\\([^()\n]*\\)" limit t)
1422                             (setq split (split-string (match-string 1) " " t))
1423                             (prog1 (car split)
1424                               (when (cdr split)
1425                                 (setq key-have-value t))))))))
1426              ;; If `cur-a' is not one of `args-lst-ak'
1427              ;; assume user is entering an unknown key
1428              ;; referenced in last position in signature.
1429              (other-key-arg (and (stringp cur-a)
1430                                  args-lst-ak
1431                                  (not (member (upcase cur-a) args-lst-ak))
1432                                  (upcase (car (last args-lst-ak))))))
1433         (unless (string= cur-w sym-name)
1434           ;; The last keyword have already a value
1435           ;; i.e :foo a b and cursor is at b.
1436           ;; If signature have also `&rest'
1437           ;; (assume it is after the `&key' section)
1438           ;; go to the arg after `&rest'.
1439           (if (and key-have-value
1440                    (save-excursion
1441                      (not (re-search-forward ":.*" (point-at-eol) t)))
1442                    (string-match "&rest \\([^ ()]*\\)" args))
1443               (setq index nil ; Skip next block based on positional args.
1444                     start (match-beginning 1)
1445                     end   (match-end 1))
1446             ;; If `cur-a' is nil probably cursor is on a positional arg
1447             ;; before `&key', in this case, exit this block and determine
1448             ;; position with `index'.
1449             (when (and cur-a     ; A keyword arg (dot removed) or nil.
1450                        (or (string-match
1451                             (concat "\\_<" (upcase cur-a) "\\_>") args)
1452                            (string-match
1453                             (concat "\\_<" other-key-arg "\\_>") args)))
1454               (setq index nil ; Skip next block based on positional args.
1455                     start (match-beginning 0)
1456                     end   (match-end 0)))))))
1457     ;; Handle now positional arguments.
1458     (while (and index (>= index 1))
1459       (if (string-match "[^ ()]+" args end)
1460           (progn
1461             (setq start (match-beginning 0)
1462                   end   (match-end 0))
1463             (let ((argument (match-string 0 args)))
1464               (cond ((string= argument "&rest")
1465                      ;; All the rest arguments are the same.
1466                      (setq index 1))
1467                     ((string= argument "&optional"))         ; Skip.
1468                     ((string= argument "&allow-other-keys")) ; Skip.
1469                     ;; Back to index 0 in ARG1 ARG2 ARG2 ARG3 etc...
1470                     ;; like in `setq'.
1471                     ((or (and (string-match-p "\\.\\.\\.\\'" argument)
1472                               (string= argument (car (last args-lst))))
1473                          (and (string-match-p "\\.\\.\\.\\'"
1474                                               (substring args 1 (1- (length args))))
1475                               (= (length (remove "..." args-lst)) 2)
1476                               (> index 1) (eq (logand index 1) 1)))
1477                      (setq index 0))
1478                     (t
1479                      (setq index (1- index))))))
1480         (setq end           (length args)
1481               start         (1- end)
1482               argument-face 'font-lock-warning-face
1483               index         0)))
1484     (let ((doc args))
1485       (when start
1486         (setq doc (copy-sequence args))
1487         (add-text-properties start end (list 'face argument-face) doc))
1488       (setq doc (eldoc-docstring-format-sym-doc prefix doc))
1489       doc)))
1490
1491 ;; Return a string containing a brief (one-line) documentation string for
1492 ;; the variable.
1493 (defun elisp-get-var-docstring (sym)
1494   (cond ((not sym) nil)
1495         ((and (eq sym (aref elisp--eldoc-last-data 0))
1496               (eq 'variable (aref elisp--eldoc-last-data 2)))
1497          (aref elisp--eldoc-last-data 1))
1498         (t
1499          (let ((doc (documentation-property sym 'variable-documentation t)))
1500            (when doc
1501              (let ((doc (eldoc-docstring-format-sym-doc
1502                          sym (elisp--docstring-first-line doc)
1503                          'font-lock-variable-name-face)))
1504                (elisp--last-data-store sym doc 'variable)))))))
1505
1506 (defun elisp--last-data-store (symbol doc type)
1507   (aset elisp--eldoc-last-data 0 symbol)
1508   (aset elisp--eldoc-last-data 1 doc)
1509   (aset elisp--eldoc-last-data 2 type)
1510   doc)
1511
1512 ;; Note that any leading `*' in the docstring (which indicates the variable
1513 ;; is a user option) is removed.
1514 (defun elisp--docstring-first-line (doc)
1515   (and (stringp doc)
1516        (substitute-command-keys
1517         (save-match-data
1518           ;; Don't use "^" in the regexp below since it may match
1519           ;; anywhere in the doc-string.
1520           (let ((start (if (string-match "\\`\\*" doc) (match-end 0) 0)))
1521             (cond ((string-match "\n" doc)
1522                    (substring doc start (match-beginning 0)))
1523                   ((zerop start) doc)
1524                   (t (substring doc start))))))))
1525 \f
1526 ;; Return a list of current function name and argument index.
1527 (defun elisp--fnsym-in-current-sexp ()
1528   (save-excursion
1529     (let ((argument-index (1- (elisp--beginning-of-sexp))))
1530       ;; If we are at the beginning of function name, this will be -1.
1531       (when (< argument-index 0)
1532         (setq argument-index 0))
1533       ;; Don't do anything if current word is inside a string.
1534       (if (= (or (char-after (1- (point))) 0) ?\")
1535           nil
1536         (list (elisp--current-symbol) argument-index)))))
1537
1538 ;; Move to the beginning of current sexp.  Return the number of nested
1539 ;; sexp the point was over or after.
1540 (defun elisp--beginning-of-sexp ()
1541   (let ((parse-sexp-ignore-comments t)
1542         (num-skipped-sexps 0))
1543     (condition-case _
1544         (progn
1545           ;; First account for the case the point is directly over a
1546           ;; beginning of a nested sexp.
1547           (condition-case _
1548               (let ((p (point)))
1549                 (forward-sexp -1)
1550                 (forward-sexp 1)
1551                 (when (< (point) p)
1552                   (setq num-skipped-sexps 1)))
1553             (error))
1554           (while
1555               (let ((p (point)))
1556                 (forward-sexp -1)
1557                 (when (< (point) p)
1558                   (setq num-skipped-sexps (1+ num-skipped-sexps))))))
1559       (error))
1560     num-skipped-sexps))
1561
1562 ;; returns nil unless current word is an interned symbol.
1563 (defun elisp--current-symbol ()
1564   (let ((c (char-after (point))))
1565     (and c
1566          (memq (char-syntax c) '(?w ?_))
1567          (intern-soft (current-word)))))
1568
1569 (defun elisp-function-argstring (arglist)
1570   "Return ARGLIST as a string enclosed by ().
1571 ARGLIST is either a string, or a list of strings or symbols."
1572   (let ((str (cond ((stringp arglist) arglist)
1573                    ((not (listp arglist)) nil)
1574                    (t (help--make-usage-docstring 'toto arglist)))))
1575     (if (and str (string-match "\\`([^ )]+ ?" str))
1576         (replace-match "(" t t str)
1577       str)))
1578
1579 (provide 'elisp-mode)
1580 ;;; elisp-mode.el ends here