code.delx.au - gnu-emacs/blob - lisp/tool-bar.el

   1 ;;; tool-bar.el --- setting up the tool bar
   2 ;;
   3 ;; Copyright (C) 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5 ;;
   6 ;; Author: Dave Love <fx@gnu.org>
   7 ;; Keywords: mouse frames
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; Provides `tool-bar-mode' to control display of the tool-bar and
  27 ;; bindings for the global tool bar with convenience functions
  28 ;; `tool-bar-add-item' and `tool-bar-add-item-from-menu'.
  29
  30 ;; The normal global binding for [tool-bar] (below) uses the value of
  31 ;; `tool-bar-map' as the actual keymap to define the tool bar.  Modes
  32 ;; may either bind items under the [tool-bar] prefix key of the local
  33 ;; map to add to the global bar or may set `tool-bar-map'
  34 ;; buffer-locally to override it.  (Some items are removed from the
  35 ;; global bar in modes which have `special' as their `mode-class'
  36 ;; property.)
  37
  38 ;; Todo: Somehow make tool bars easily customizable by the naive?
  39
  40 ;;; Code:
  41
  42 ;; The autoload cookie doesn't work when preloading.
  43 ;; Deleting it means invoking this command won't work
  44 ;; when you are on a tty.  I hope that won't cause too much trouble -- rms.
  45 (define-minor-mode tool-bar-mode
  46   "Toggle use of the tool bar.
  47 With numeric ARG, display the tool bar if and only if ARG is positive.
  48
  49 See `tool-bar-add-item' and `tool-bar-add-item-from-menu' for
  50 conveniently adding tool bar items."
  51   :init-value nil
  52   :global t
  53   :group 'mouse
  54   :group 'frames
  55   (and (display-images-p)
  56        (modify-all-frames-parameters (list (cons 'tool-bar-lines
  57                                                  (if tool-bar-mode 1 0))))
  58        (if (and tool-bar-mode
  59                 (display-graphic-p))
  60            (tool-bar-setup))))
  61
  62 ;;;###autoload
  63 ;; Used in the Show/Hide menu, to have the toggle reflect the current frame.
  64 (defun toggle-tool-bar-mode-from-frame (&optional arg)
  65   "Toggle tool bar on or off, based on the status of the current frame.
  66 See `tool-bar-mode' for more information."
  67   (interactive (list (or current-prefix-arg 'toggle)))
  68   (if (eq arg 'toggle)
  69       (tool-bar-mode (if (> (frame-parameter nil 'tool-bar-lines) 0) 0 1))
  70     (tool-bar-mode arg)))
  71
  72 ;;;###autoload
  73 ;; We want to pretend the toolbar by standard is on, as this will make
  74 ;; customize consider disabling the toolbar a customization, and save
  75 ;; that.  We could do this for real by setting :init-value above, but
  76 ;; that would turn on the toolbar in MS Windows where it is currently
  77 ;; useless, and it would overwrite disabling the tool bar from X
  78 ;; resources.  If anyone want to implement this in a cleaner way,
  79 ;; please do so.
  80 ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2002-02-21.
  81 (put 'tool-bar-mode 'standard-value '(t))
  82
  83 (defvar tool-bar-map (make-sparse-keymap)
  84   "Keymap for the tool bar.
  85 Define this locally to override the global tool bar.")
  86
  87 (global-set-key [tool-bar]
  88                 '(menu-item "tool bar" ignore
  89                             :filter tool-bar-make-keymap))
  90
  91 (defun tool-bar-make-keymap (&optional ignore)
  92   "Generate an actual keymap from `tool-bar-map'.
  93 Its main job is to figure out which images to use based on the display's
  94 color capability and based on the available image libraries."
  95   (mapcar (lambda (bind)
  96             (let (image-exp plist)
  97               (when (and (eq (car-safe (cdr-safe bind)) 'menu-item)
  98                          ;; For the format of menu-items, see node
  99                          ;; `Extended Menu Items' in the Elisp manual.
 100                          (setq plist (nthcdr (if (consp (nth 4 bind)) 5 4)
 101                                              bind))
 102                          (setq image-exp (plist-get plist :image))
 103                          (consp image-exp)
 104                          (not (eq (car image-exp) 'image))
 105                          (fboundp (car image-exp)))
 106                 (if (not (display-images-p))
 107                     (setq bind nil)
 108                   (let ((image (eval image-exp)))
 109                     (unless (image-mask-p image)
 110                       (setq image (append image '(:mask heuristic))))
 111                     (setq bind (copy-sequence bind)
 112                           plist (nthcdr (if (consp (nth 4 bind)) 5 4)
 113                                         bind))
 114                     (plist-put plist :image image))))
 115               bind))
 116           tool-bar-map))
 117
 118 (defconst tool-bar-find-image-cache (make-hash-table :weakness t :test 'equal))
 119
 120 (defun tool-bar-find-image (specs)
 121   "Like `find-image' but with caching."
 122   (or (gethash specs tool-bar-find-image-cache)
 123       (puthash specs (find-image specs) tool-bar-find-image-cache)))
 124
 125 ;;;###autoload
 126 (defun tool-bar-add-item (icon def key &rest props)
 127   "Add an item to the tool bar.
 128 ICON names the image, DEF is the key definition and KEY is a symbol
 129 for the fake function key in the menu keymap.  Remaining arguments
 130 PROPS are additional items to add to the menu item specification.  See
 131 Info node `(elisp)Tool Bar'.  Items are added from left to right.
 132
 133 ICON is the base name of a file containing the image to use.  The
 134 function will first try to use low-color/ICON.xpm if display-color-cells
 135 is less or equal to 256, then ICON.xpm, then ICON.pbm, and finally
 136 ICON.xbm, using `find-image'.
 137
 138 Use this function only to make bindings in the global value of `tool-bar-map'.
 139 To define items in any other map, use `tool-bar-local-item'."
 140   (apply 'tool-bar-local-item icon def key tool-bar-map props))
 141
 142 ;;;###autoload
 143 (defun tool-bar-local-item (icon def key map &rest props)
 144   "Add an item to the tool bar in map MAP.
 145 ICON names the image, DEF is the key definition and KEY is a symbol
 146 for the fake function key in the menu keymap.  Remaining arguments
 147 PROPS are additional items to add to the menu item specification.  See
 148 Info node `(elisp)Tool Bar'.  Items are added from left to right.
 149
 150 ICON is the base name of a file containing the image to use.  The
 151 function will first try to use low-color/ICON.xpm if `display-color-cells'
 152 is less or equal to 256, then ICON.xpm, then ICON.pbm, and finally
 153 ICON.xbm, using `find-image'."
 154   (let* ((fg (face-attribute 'tool-bar :foreground))
 155          (bg (face-attribute 'tool-bar :background))
 156          (colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
 157                         (if (eq bg 'unspecified) nil (list :background bg))))
 158          (xpm-spec (list :type 'xpm :file (concat icon ".xpm")))
 159          (xpm-lo-spec (if (> (display-color-cells) 256)
 160                           nil
 161                         (list :type 'xpm :file
 162                               (concat "low-color/" icon ".xpm"))))
 163          (pbm-spec (append (list :type 'pbm :file
 164                                  (concat icon ".pbm")) colors))
 165          (xbm-spec (append (list :type 'xbm :file
 166                                  (concat icon ".xbm")) colors))
 167          (image-exp `(tool-bar-find-image
 168                       (if (display-color-p)
 169                           ',(list xpm-lo-spec xpm-spec pbm-spec xbm-spec)
 170                         ',(list pbm-spec xbm-spec xpm-lo-spec xpm-spec)))))
 171
 172     (define-key-after map (vector key)
 173       `(menu-item ,(symbol-name key) ,def :image ,image-exp ,@props))))
 174
 175 ;;;###autoload
 176 (defun tool-bar-add-item-from-menu (command icon &optional map &rest props)
 177   "Define tool bar binding for COMMAND in keymap MAP using the given ICON.
 178 This makes a binding for COMMAND in `tool-bar-map', copying its
 179 binding from the menu bar in MAP (which defaults to `global-map'), but
 180 modifies the binding by adding an image specification for ICON.  It
 181 finds ICON just like `tool-bar-add-item'.  PROPS are additional
 182 properties to add to the binding.
 183
 184 MAP must contain appropriate binding for `[menu-bar]' which holds a keymap.
 185
 186 Use this function only to make bindings in the global value of `tool-bar-map'.
 187 To define items in any other map, use `tool-bar-local-item-from-menu'."
 188   (apply 'tool-bar-local-item-from-menu command icon
 189          (default-value 'tool-bar-map) map props))
 190
 191 ;;;###autoload
 192 (defun tool-bar-local-item-from-menu (command icon in-map &optional from-map &rest props)
 193   "Define local tool bar binding for COMMAND using the given ICON.
 194 This makes a binding for COMMAND in IN-MAP, copying its binding from
 195 the menu bar in FROM-MAP (which defaults to `global-map'), but
 196 modifies the binding by adding an image specification for ICON.  It
 197 finds ICON just like `tool-bar-add-item'.  PROPS are additional
 198 properties to add to the binding.
 199
 200 FROM-MAP must contain appropriate binding for `[menu-bar]' which
 201 holds a keymap."
 202   (unless from-map
 203     (setq from-map global-map))
 204   (let* ((menu-bar-map (lookup-key from-map [menu-bar]))
 205          (keys (where-is-internal command menu-bar-map))
 206          (fg (face-attribute 'tool-bar :foreground))
 207          (bg (face-attribute 'tool-bar :background))
 208          (colors (nconc (if (eq fg 'unspecified) nil (list :foreground fg))
 209                         (if (eq bg 'unspecified) nil (list :background bg))))
 210          (xpm-spec (list :type 'xpm :file (concat icon ".xpm")))
 211          (xpm-lo-spec (if (> (display-color-cells) 256)
 212                           nil
 213                         (list :type 'xpm :file
 214                               (concat "low-color/" icon ".xpm"))))
 215          (pbm-spec (append (list :type 'pbm :file
 216                                  (concat icon ".pbm")) colors))
 217          (xbm-spec (append (list :type 'xbm :file
 218                                  (concat icon ".xbm")) colors))
 219          (image-exp `(tool-bar-find-image
 220                       (if (display-color-p)
 221                           ',(list xpm-lo-spec xpm-spec pbm-spec xbm-spec)
 222                         ',(list pbm-spec xbm-spec xpm-lo-spec xpm-spec))))
 223          submap key)
 224     ;; We'll pick up the last valid entry in the list of keys if
 225     ;; there's more than one.
 226     (dolist (k keys)
 227       ;; We're looking for a binding of the command in a submap of
 228       ;; the menu bar map, so the key sequence must be two or more
 229       ;; long.
 230       (if (and (vectorp k)
 231                (> (length k) 1))
 232           (let ((m (lookup-key menu-bar-map (substring k 0 -1)))
 233                 ;; Last element in the bound key sequence:
 234                 (kk (aref k (1- (length k)))))
 235             (if (and (keymapp m)
 236                      (symbolp kk))
 237                 (setq submap m
 238                       key kk)))))
 239     (when (and (symbolp submap) (boundp submap))
 240       (setq submap (eval submap)))
 241     (let ((defn (assq key (cdr submap))))
 242       (if (eq (cadr defn) 'menu-item)
 243           (define-key-after in-map (vector key)
 244             (append (cdr defn) (list :image image-exp) props))
 245         (setq defn (cdr defn))
 246         (define-key-after in-map (vector key)
 247           (let ((rest (cdr defn)))
 248             ;; If the rest of the definition starts
 249             ;; with a list of menu cache info, get rid of that.
 250             (if (and (consp rest) (consp (car rest)))
 251                 (setq rest (cdr rest)))
 252             (append `(menu-item ,(car defn) ,rest)
 253                     (list :image image-exp) props)))))))
 254
 255 ;;; Set up some global items.  Additions/deletions up for grabs.
 256
 257 (defvar tool-bar-setup nil
 258   "Set to t if the tool-bar has been set up by `tool-bar-setup'.")
 259
 260 (defun tool-bar-setup (&optional frame)
 261   (unless tool-bar-setup
 262     (with-selected-frame (or frame (selected-frame))
 263       ;; People say it's bad to have EXIT on the tool bar, since users
 264       ;; might inadvertently click that button.
 265       ;;(tool-bar-add-item-from-menu 'save-buffers-kill-emacs "exit")
 266       (tool-bar-add-item-from-menu 'find-file "new")
 267       (tool-bar-add-item-from-menu 'menu-find-file-existing "open")
 268       (tool-bar-add-item-from-menu 'dired "diropen")
 269       (tool-bar-add-item-from-menu 'kill-this-buffer "close")
 270       (tool-bar-add-item-from-menu 'save-buffer "save" nil
 271                                    :visible '(or buffer-file-name
 272                                                  (not (eq 'special
 273                                                           (get major-mode
 274                                                                'mode-class)))))
 275       (tool-bar-add-item-from-menu 'write-file "saveas" nil
 276                                    :visible '(or buffer-file-name
 277                                                  (not (eq 'special
 278                                                           (get major-mode
 279                                                                'mode-class)))))
 280       (tool-bar-add-item-from-menu 'undo "undo" nil
 281                                    :visible '(not (eq 'special (get major-mode
 282                                                                     'mode-class))))
 283       (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [cut])
 284                                    "cut" nil
 285                                    :visible '(not (eq 'special (get major-mode
 286                                                                     'mode-class))))
 287       (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [copy])
 288                                    "copy")
 289       (tool-bar-add-item-from-menu (lookup-key menu-bar-edit-menu [paste])
 290                                    "paste" nil
 291                                    :visible '(not (eq 'special (get major-mode
 292                                                                     'mode-class))))
 293       (tool-bar-add-item-from-menu 'nonincremental-search-forward "search")
 294       ;;(tool-bar-add-item-from-menu 'ispell-buffer "spell")
 295
 296       ;; There's no icon appropriate for News and we need a command rather
 297       ;; than a lambda for Read Mail.
 298       ;;(tool-bar-add-item-from-menu 'compose-mail "mail/compose")
 299
 300       (tool-bar-add-item-from-menu 'print-buffer "print")
 301
 302       ;; tool-bar-add-item-from-menu itself operates on
 303       ;; (default-value 'tool-bar-map), but when we don't use that function,
 304       ;; we must explicitly operate on the default value.
 305
 306       (let ((tool-bar-map (default-value 'tool-bar-map)))
 307         (tool-bar-add-item "preferences" 'customize 'customize
 308                            :help "Edit preferences (customize)")
 309
 310         (tool-bar-add-item "help" (lambda ()
 311                                     (interactive)
 312                                     (popup-menu menu-bar-help-menu))
 313                            'help
 314                            :help "Pop up the Help menu"))
 315       (setq tool-bar-setup t))))
 316
 317
 318 (provide 'tool-bar)
 319 ;; arch-tag: 15f30f0a-d0d7-4d50-bbb7-f48fd0c8582f
 320 ;;; tool-bar.el ends here