code.delx.au - gnu-emacs/blob - lisp/autorevert.el

   1 ;;; autorevert.el --- revert buffers when files on disk change
   2
   3 ;; Copyright (C) 1997, 1998, 1999, 2001 Free Software Foundation, Inc.
   4
   5 ;; Author: Anders Lindgren <andersl@andersl.com>
   6 ;; Keywords: convenience
   7 ;; Created: 1997-06-01
   8 ;; Date: 1999-11-30
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Introduction:
  30 ;;
  31 ;; Whenever a file that Emacs is editing has been changed by another
  32 ;; program the user normally has to execute the command `revert-buffer'
  33 ;; to load the new content of the file into Emacs.
  34 ;;
  35 ;; This package contains two minor modes: Global Auto-Revert Mode and
  36 ;; Auto-Revert Mode.  Both modes automatically revert buffers
  37 ;; whenever the corresponding files have been changed on disk.
  38 ;;
  39 ;; Auto-Revert Mode can be activated for individual buffers.
  40 ;; Global Auto-Revert Mode applies to all file buffers.
  41 ;;
  42 ;; Both modes operate by checking the time stamp of all files at
  43 ;; intervals of `auto-revert-interval'.  The default is every five
  44 ;; seconds.  The check is aborted whenever the user actually uses
  45 ;; Emacs.  You should never even notice that this package is active
  46 ;; (except that your buffers will be reverted, of course).
  47
  48 ;; Usage:
  49 ;;
  50 ;; Go to the appropriate buffer and press:
  51 ;;   M-x auto-revert-mode RET
  52 ;;
  53 ;; To activate Global Auto-Revert Mode, press:
  54 ;;   M-x global-auto-revert-mode RET
  55 ;;
  56 ;; To activate Global Auto-Revert Mode every time Emacs is started
  57 ;; customise the option `global-auto-revert-mode' or the following
  58 ;; line could be added to your ~/.emacs:
  59 ;;   (global-auto-revert-mode 1)
  60 ;;
  61 ;; The function `turn-on-auto-revert-mode' could be added to any major
  62 ;; mode hook to activate Auto-Revert Mode for all buffers in that
  63 ;; mode.  For example, the following line will activate Auto-Revert
  64 ;; Mode in all C mode buffers:
  65 ;;
  66 ;; (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)
  67
  68 ;;; Code:
  69
  70 ;; Dependencies:
  71
  72 (require 'timer)
  73
  74 (eval-when-compile (require 'cl))
  75
  76
  77 ;; Custom Group:
  78 ;;
  79 ;; The two modes will be placed next to Auto Save Mode under the
  80 ;; Files group under Emacs.
  81
  82 (defgroup auto-revert nil
  83   "Revert individual buffers when files on disk change.
  84
  85 Auto-Revert Mode can be activated for individual buffer.
  86 Global Auto-Revert Mode applies to all buffers."
  87   :group 'files
  88   :group 'convenience)
  89
  90
  91 ;; Variables:
  92
  93 ;; Autoload for the benefit of `make-mode-line-mouse-sensitive'.
  94 ;;;###autoload
  95 (defvar auto-revert-mode nil
  96   "*Non-nil when Auto-Revert Mode is active.
  97 Never set this variable directly, use the command `auto-revert-mode' instead.")
  98 (put 'auto-revert-mode 'permanent-local t)
  99
 100 (defvar auto-revert-timer nil
 101   "Timer used by Auto-Revert Mode.")
 102
 103 (defcustom auto-revert-interval 5
 104   "Time, in seconds, between Auto-Revert Mode file checks.
 105 The value may be an integer or floating point number.
 106
 107 If a timer is already active, there are two ways to make sure
 108 that the new value will take effect immediately.  You can set
 109 this variable through Custom or you can call the command
 110 `auto-revert-set-timer' after setting the variable.  Otherwise,
 111 the new value will take effect the first time Auto Revert Mode
 112 calls `auto-revert-set-timer' for internal reasons or in your
 113 next editing session."
 114   :group 'auto-revert
 115   :type 'number
 116   :set (lambda (variable value)
 117          (set-default variable value)
 118          (and (boundp 'auto-revert-timer)
 119               auto-revert-timer
 120               (auto-revert-set-timer))))
 121
 122 (defcustom auto-revert-stop-on-user-input t
 123   "When non-nil Auto-Revert Mode stops checking files on user input."
 124   :group 'auto-revert
 125   :type 'boolean)
 126
 127 (defcustom auto-revert-verbose t
 128   "When nil, Auto-Revert Mode will not generate any messages.
 129 When non-nil, a message is generated whenever a file is reverted."
 130   :group 'auto-revert
 131   :type 'boolean)
 132
 133 (defcustom auto-revert-mode-text " ARev"
 134   "String to display in the mode line when Auto-Revert Mode is active.
 135
 136 \(When the string is not empty, make sure that it has a leading space.)"
 137   :tag "Auto Revert Mode Text"          ; To separate it from `global-...'
 138   :group 'auto-revert
 139   :type 'string)
 140
 141 (defcustom auto-revert-mode-hook nil
 142   "Functions to run when Auto-Revert Mode is activated."
 143   :tag "Auto Revert Mode Hook"          ; To separate it from `global-...'
 144   :group 'auto-revert
 145   :type 'hook)
 146
 147 (defcustom global-auto-revert-mode-text ""
 148   "String to display when Global Auto-Revert Mode is active.
 149
 150 The default is nothing since when this mode is active this text doesn't
 151 vary over time, or between buffers.  Hence mode line text
 152 would only waste precious space."
 153   :group 'auto-revert
 154   :type 'string)
 155
 156 (defcustom global-auto-revert-mode-hook nil
 157   "Hook called when Global Auto-Revert Mode is activated."
 158   :group 'auto-revert
 159   :type 'hook)
 160
 161 (defcustom global-auto-revert-non-file-buffers nil
 162   "When nil only file buffers are reverted by Global Auto-Revert Mode.
 163
 164 When non-nil, both file buffers and buffers with a custom
 165 `revert-buffer-function' and a `buffer-stale-function' are
 166 reverted by Global Auto-Revert Mode.
 167
 168 Use this option with care since it could lead to excessive reverts.
 169 Note also that for some non-file buffers the check whether the
 170 buffer needs updating may be imperfect, due to efficiency
 171 considerations, and may not take all information listed in the
 172 buffer into account.  Hence, a non-nil value for this option does
 173 not necessarily make manual updates useless for non-file buffers."
 174   :group 'auto-revert
 175   :type 'boolean)
 176
 177 (defcustom global-auto-revert-ignore-modes '()
 178   "List of major modes Global Auto-Revert Mode should not check."
 179   :group 'auto-revert
 180   :type '(repeat sexp))
 181
 182 (defcustom auto-revert-load-hook nil
 183   "Functions to run when Auto-Revert Mode is first loaded."
 184   :tag "Load Hook"
 185   :group 'auto-revert
 186   :type 'hook)
 187
 188 (defcustom auto-revert-check-vc-info nil
 189   "If non-nil Auto Revert Mode reliably updates version control info.
 190 Auto Revert Mode updates version control info whenever the buffer
 191 needs reverting, regardless of the value of this variable.
 192 However, the version control state can change without changes to
 193 the work file.  If the change is made from the current Emacs
 194 session, all info is updated.  But if, for instance, a new
 195 version is checked in from outside the current Emacs session, the
 196 version control number in the mode line, as well as other version
 197 control related information, may not be properly updated.  If you
 198 are worried about this, set this variable to a non-nil value.
 199
 200 This currently works by automatically updating the version
 201 control info every `auto-revert-interval' seconds.  Nevertheless,
 202 it should not cause excessive CPU usage on a reasonably fast
 203 machine, if it does not apply to too many version controlled
 204 buffers.  CPU usage depends on the version control system"
 205   :group 'auto-revert
 206   :type 'boolean
 207   :version "21.4")
 208
 209 (defvar global-auto-revert-ignore-buffer nil
 210   "*When non-nil, Global Auto-Revert Mode will not revert this buffer.
 211
 212 This variable becomes buffer local when set in any fashion.")
 213 (make-variable-buffer-local 'global-auto-revert-ignore-buffer)
 214
 215 ;; Internal variables:
 216
 217 (defvar auto-revert-buffer-list '()
 218   "List of buffers in Auto-Revert Mode.
 219
 220 Note that only Auto-Revert Mode, never Global Auto-Revert Mode, adds
 221 buffers to this list.
 222
 223 The timer function `auto-revert-buffers' is responsible for purging
 224 the list of old buffers.")
 225
 226 (defvar auto-revert-remaining-buffers '()
 227   "Buffers not checked when user input stopped execution.")
 228
 229
 230 ;; Functions:
 231
 232 ;;;###autoload
 233 (define-minor-mode auto-revert-mode
 234   "Toggle reverting buffer when file on disk changes.
 235
 236 With arg, turn Auto Revert mode on if and only if arg is positive.
 237 This is a minor mode that affects only the current buffer.
 238 Use `global-auto-revert-mode' to automatically revert all buffers."
 239   nil auto-revert-mode-text nil
 240   (if auto-revert-mode
 241       (if (not (memq (current-buffer) auto-revert-buffer-list))
 242           (push (current-buffer) auto-revert-buffer-list))
 243     (setq auto-revert-buffer-list
 244           (delq (current-buffer) auto-revert-buffer-list)))
 245   (auto-revert-set-timer)
 246   (when auto-revert-mode
 247     (auto-revert-buffers)))
 248
 249
 250 ;;;###autoload
 251 (defun turn-on-auto-revert-mode ()
 252   "Turn on Auto-Revert Mode.
 253
 254 This function is designed to be added to hooks, for example:
 255   (add-hook 'c-mode-hook 'turn-on-auto-revert-mode)"
 256   (auto-revert-mode 1))
 257
 258
 259 ;;;###autoload
 260 (define-minor-mode global-auto-revert-mode
 261   "Revert any buffer when file on disk changes.
 262
 263 With arg, turn Auto Revert mode on globally if and only if arg is positive.
 264 This is a minor mode that affects all buffers.
 265 Use `auto-revert-mode' to revert a particular buffer."
 266   :global t :group 'auto-revert :lighter global-auto-revert-mode-text
 267   (auto-revert-set-timer)
 268   (when global-auto-revert-mode
 269     (auto-revert-buffers)))
 270
 271
 272 (defun auto-revert-set-timer ()
 273   "Restart or cancel the timer used by Auto-Revert Mode.
 274 If such a timer is active, cancel it.  Start a new timer if
 275 Global Auto-Revert Mode is active or if Auto-Revert Mode is active
 276 in some buffer.  Restarting the timer ensures that Auto-Revert Mode
 277 will use an up-to-date value of `auto-revert-interval'"
 278   (interactive)
 279   (if (timerp auto-revert-timer)
 280       (cancel-timer auto-revert-timer))
 281   (setq auto-revert-timer
 282         (if (or global-auto-revert-mode auto-revert-buffer-list)
 283             (run-with-timer auto-revert-interval
 284                             auto-revert-interval
 285                             'auto-revert-buffers)
 286           nil)))
 287
 288 (defun auto-revert-active-p ()
 289   "Check if auto-revert is active (in current buffer or globally)."
 290   (or auto-revert-mode
 291       (and
 292        global-auto-revert-mode
 293        (not global-auto-revert-ignore-buffer)
 294        (not (memq major-mode
 295                   global-auto-revert-ignore-modes)))))
 296
 297 (defun auto-revert-handler ()
 298   "Revert current buffer, if appropriate.
 299 This is an internal function used by Auto-Revert Mode."
 300   (unless (buffer-modified-p)
 301     (let (revert)
 302       (or (and (buffer-file-name)
 303                (file-readable-p (buffer-file-name))
 304                (not (verify-visited-file-modtime (current-buffer)))
 305                (setq revert t))
 306           (and (or auto-revert-mode global-auto-revert-non-file-buffers)
 307                revert-buffer-function
 308                (boundp 'buffer-stale-function)
 309                (functionp buffer-stale-function)
 310                (setq revert (funcall buffer-stale-function t))))
 311       (when revert
 312         (when (and auto-revert-verbose
 313                    (not (eq revert 'fast)))
 314           (message "Reverting buffer `%s'." (buffer-name)))
 315         (revert-buffer 'ignore-auto 'dont-ask 'preserve-modes))
 316       ;; `preserve-modes' avoids changing the (minor) modes.  But we
 317       ;; do want to reset the mode for VC, so we do it manually.
 318       (when (or revert auto-revert-check-vc-info)
 319         (vc-find-file-hook)))))
 320
 321 (defun auto-revert-buffers ()
 322   "Revert buffers as specified by Auto-Revert and Global Auto-Revert Mode.
 323
 324 Should `global-auto-revert-mode' be active all file buffers are checked.
 325
 326 Should `auto-revert-mode' be active in some buffers, those buffers
 327 are checked.
 328
 329 Non-file buffers that have a custom `revert-buffer-function' and
 330 a `buffer-stale-function' are reverted either when Auto-Revert
 331 Mode is active in that buffer, or when the variable
 332 `global-auto-revert-non-file-buffers' is non-nil and Global
 333 Auto-Revert Mode is active.
 334
 335 This function stops whenever there is user input.  The buffers not
 336 checked are stored in the variable `auto-revert-remaining-buffers'.
 337
 338 To avoid starvation, the buffers in `auto-revert-remaining-buffers'
 339 are checked first the next time this function is called.
 340
 341 This function is also responsible for removing buffers no longer in
 342 Auto-Revert mode from `auto-revert-buffer-list', and for canceling
 343 the timer when no buffers need to be checked."
 344   (let ((bufs (if global-auto-revert-mode
 345                   (buffer-list)
 346                 auto-revert-buffer-list))
 347         (remaining '())
 348         (new '()))
 349     ;; Partition `bufs' into two halves depending on whether or not
 350     ;; the buffers are in `auto-revert-remaining-buffers'.  The two
 351     ;; halves are then re-joined with the "remaining" buffers at the
 352     ;; head of the list.
 353     (dolist (buf auto-revert-remaining-buffers)
 354       (if (memq buf bufs)
 355           (push buf remaining)))
 356     (dolist (buf bufs)
 357       (if (not (memq buf remaining))
 358           (push buf new)))
 359     (setq bufs (nreverse (nconc new remaining)))
 360     (while (and bufs
 361                 (not (and auto-revert-stop-on-user-input
 362                           (input-pending-p))))
 363       (let ((buf (car bufs)))
 364         (if (buffer-name buf)           ; Buffer still alive?
 365             (with-current-buffer buf
 366               ;; Test if someone has turned off Auto-Revert Mode in a
 367               ;; non-standard way, for example by changing major mode.
 368               (if (and (not auto-revert-mode)
 369                        (memq buf auto-revert-buffer-list))
 370                   (setq auto-revert-buffer-list
 371                         (delq buf auto-revert-buffer-list)))
 372               (when (auto-revert-active-p) (auto-revert-handler)))
 373           ;; Remove dead buffer from `auto-revert-buffer-list'.
 374           (setq auto-revert-buffer-list
 375                 (delq buf auto-revert-buffer-list))))
 376       (setq bufs (cdr bufs)))
 377     (setq auto-revert-remaining-buffers bufs)
 378     ;; Check if we should cancel the timer.
 379     (when (and (not global-auto-revert-mode)
 380                (null auto-revert-buffer-list))
 381       (cancel-timer auto-revert-timer)
 382       (setq auto-revert-timer nil))))
 383
 384
 385 ;; The end:
 386 (provide 'autorevert)
 387
 388 (run-hooks 'auto-revert-load-hook)
 389
 390 ;;; arch-tag: f6bcb07b-4841-477e-9e44-b18678e58876
 391 ;;; autorevert.el ends here