code.delx.au - gnu-emacs/blob - lisp/cmuscheme.el

   1 ;;; cmuscheme.el --- Scheme process in a buffer. Adapted from tea.el
   2
   3 ;; Copyright (C) 1988, 1994, 1997, 2004  Free Software Foundation, Inc.
   4
   5 ;; Author: Olin Shivers <olin.shivers@cs.cmu.edu>
   6 ;; Maintainer: FSF
   7 ;; Keywords: processes, lisp
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;    This is a customisation of comint-mode (see comint.el)
  29 ;;
  30 ;; Written by Olin Shivers (olin.shivers@cs.cmu.edu). With bits and pieces
  31 ;; lifted from scheme.el, shell.el, clisp.el, newclisp.el, cobol.el, et al..
  32 ;; 8/88
  33 ;;
  34 ;; Please send me bug reports, bug fixes, and extensions, so that I can
  35 ;; merge them into the master source.
  36 ;;
  37 ;; The changelog is at the end of this file.
  38 ;;
  39 ;; NOTE: MIT Cscheme, when invoked with the -emacs flag, has a special user
  40 ;; interface that communicates process state back to the superior emacs by
  41 ;; outputting special control sequences. The gnumacs package, xscheme.el, has
  42 ;; lots and lots of special purpose code to read these control sequences, and
  43 ;; so is very tightly integrated with the cscheme process. The cscheme
  44 ;; interrupt handler and debugger read single character commands in cbreak
  45 ;; mode; when this happens, xscheme.el switches to special keymaps that bind
  46 ;; the single letter command keys to emacs functions that directly send the
  47 ;; character to the scheme process.  Cmuscheme mode does *not* provide this
  48 ;; functionality. If you are a cscheme user, you may prefer to use the
  49 ;; xscheme.el/cscheme -emacs interaction.
  50 ;;
  51 ;; Here's a summary of the pros and cons, as I see them.
  52 ;; xscheme: Tightly integrated with inferior cscheme process!  A few commands
  53 ;;           not in cmuscheme. But. Integration is a bit of a hack.  Input
  54 ;;           history only keeps the immediately prior input. Bizarre
  55 ;;           keybindings.
  56 ;;
  57 ;; cmuscheme: Not tightly integrated with inferior cscheme process.  But.
  58 ;;            Carefully integrated functionality with the entire suite of
  59 ;;            comint-derived CMU process modes. Keybindings reminiscent of
  60 ;;            Zwei and Hemlock. Good input history. A few commands not in
  61 ;;            xscheme.
  62 ;;
  63 ;; It's a tradeoff. Pay your money; take your choice. If you use a Scheme
  64 ;; that isn't Cscheme, of course, there isn't a choice. Xscheme.el is *very*
  65 ;; Cscheme-specific; you must use cmuscheme.el.  Interested parties are
  66 ;; invited to port xscheme functionality on top of comint mode...
  67
  68 ;;; CHANGE LOG
  69 ;;; ===========================================================================
  70 ;;; 8/88 Olin
  71 ;;; Created.
  72 ;;;
  73 ;;; 2/15/89 Olin
  74 ;;; Removed -emacs flag from process invocation. It's only useful for
  75 ;;; cscheme, and makes cscheme assume it's running under xscheme.el,
  76 ;;; which messes things up royally. A bug.
  77 ;;;
  78 ;;; 5/22/90 Olin
  79 ;;; - Upgraded to use comint-send-string and comint-send-region.
  80 ;;; - run-scheme now offers to let you edit the command line if
  81 ;;;   you invoke it with a prefix-arg. M-x scheme is redundant, and
  82 ;;;   has been removed.
  83 ;;; - Explicit references to process "scheme" have been replaced with
  84 ;;;   (scheme-proc). This allows better handling of multiple process bufs.
  85 ;;; - Added scheme-send-last-sexp, bound to C-x C-e. A gnu convention.
  86 ;;; - Have not added process query facility a la cmulisp.el's lisp-show-arglist
  87 ;;;   and friends, but interested hackers might find a useful application
  88 ;;;   of this facility.
  89 ;;;
  90 ;;; 3/12/90 Olin
  91 ;;; - scheme-load-file and scheme-compile-file no longer switch-to-scheme.
  92 ;;;   Tale suggested this.
  93
  94 ;;; Code:
  95
  96 (require 'scheme)
  97 (require 'comint)
  98
  99
 100 (defgroup cmuscheme nil
 101   "Run a scheme process in a buffer."
 102   :group 'scheme)
 103
 104 ;;; INFERIOR SCHEME MODE STUFF
 105 ;;;============================================================================
 106
 107 (defcustom inferior-scheme-mode-hook nil
 108   "*Hook for customising inferior-scheme mode."
 109   :type 'hook
 110   :group 'cmuscheme)
 111
 112 (defvar inferior-scheme-mode-map
 113   (let ((m (make-sparse-keymap)))
 114     (define-key m "\M-\C-x" 'scheme-send-definition) ;gnu convention
 115     (define-key m "\C-x\C-e" 'scheme-send-last-sexp)
 116     (define-key m "\C-c\C-l" 'scheme-load-file)
 117     (define-key m "\C-c\C-k" 'scheme-compile-file)
 118     (scheme-mode-commands m)
 119     m))
 120
 121 ;; Install the process communication commands in the scheme-mode keymap.
 122 (define-key scheme-mode-map "\M-\C-x" 'scheme-send-definition);gnu convention
 123 (define-key scheme-mode-map "\C-x\C-e" 'scheme-send-last-sexp);gnu convention
 124 (define-key scheme-mode-map "\C-c\C-e" 'scheme-send-definition)
 125 (define-key scheme-mode-map "\C-c\M-e" 'scheme-send-definition-and-go)
 126 (define-key scheme-mode-map "\C-c\C-r" 'scheme-send-region)
 127 (define-key scheme-mode-map "\C-c\M-r" 'scheme-send-region-and-go)
 128 (define-key scheme-mode-map "\C-c\M-c" 'scheme-compile-definition)
 129 (define-key scheme-mode-map "\C-c\C-c" 'scheme-compile-definition-and-go)
 130 (define-key scheme-mode-map "\C-c\C-t" 'scheme-trace-procedure)
 131 (define-key scheme-mode-map "\C-c\C-x" 'scheme-expand-current-form)
 132 (define-key scheme-mode-map "\C-c\C-z" 'switch-to-scheme)
 133 (define-key scheme-mode-map "\C-c\C-l" 'scheme-load-file)
 134 (define-key scheme-mode-map "\C-c\C-k" 'scheme-compile-file) ;k for "kompile"
 135
 136 (let ((map (lookup-key scheme-mode-map [menu-bar scheme])))
 137   (define-key map [separator-eval] '("--"))
 138   (define-key map [compile-file]
 139     '("Compile Scheme File" . scheme-compile-file))
 140   (define-key map [load-file]
 141     '("Load Scheme File" . scheme-load-file))
 142   (define-key map [switch]
 143     '("Switch to Scheme" . switch-to-scheme))
 144   (define-key map [com-def-go]
 145     '("Compile Definition & Go" . scheme-compile-definition-and-go))
 146   (define-key map [com-def]
 147     '("Compile Definition" . scheme-compile-definition))
 148   (define-key map [exp-form]
 149     '("Expand current form" . scheme-expand-current-form))
 150   (define-key map [trace-proc]
 151     '("Trace procedure" . scheme-trace-procedure))
 152   (define-key map [send-def-go]
 153     '("Evaluate Last Definition & Go" . scheme-send-definition-and-go))
 154   (define-key map [send-def]
 155     '("Evaluate Last Definition" . scheme-send-definition))
 156   (define-key map [send-region-go]
 157     '("Evaluate Region & Go" . scheme-send-region-and-go))
 158   (define-key map [send-region]
 159     '("Evaluate Region" . scheme-send-region))
 160   (define-key map [send-sexp]
 161     '("Evaluate Last S-expression" . scheme-send-last-sexp))
 162   )
 163
 164 (defvar scheme-buffer)
 165
 166 (define-derived-mode inferior-scheme-mode comint-mode "Inferior Scheme"
 167   "Major mode for interacting with an inferior Scheme process.
 168
 169 The following commands are available:
 170 \\{inferior-scheme-mode-map}
 171
 172 A Scheme process can be fired up with M-x run-scheme.
 173
 174 Customisation: Entry to this mode runs the hooks on comint-mode-hook and
 175 inferior-scheme-mode-hook (in that order).
 176
 177 You can send text to the inferior Scheme process from other buffers containing
 178 Scheme source.
 179     switch-to-scheme switches the current buffer to the Scheme process buffer.
 180     scheme-send-definition sends the current definition to the Scheme process.
 181     scheme-compile-definition compiles the current definition.
 182     scheme-send-region sends the current region to the Scheme process.
 183     scheme-compile-region compiles the current region.
 184
 185     scheme-send-definition-and-go, scheme-compile-definition-and-go,
 186         scheme-send-region-and-go, and scheme-compile-region-and-go
 187         switch to the Scheme process buffer after sending their text.
 188 For information on running multiple processes in multiple buffers, see
 189 documentation for variable scheme-buffer.
 190
 191 Commands:
 192 Return after the end of the process' output sends the text from the
 193     end of process to point.
 194 Return before the end of the process' output copies the sexp ending at point
 195     to the end of the process' output, and sends it.
 196 Delete converts tabs to spaces as it moves back.
 197 Tab indents for Scheme; with argument, shifts rest
 198     of expression rigidly with the current line.
 199 C-M-q does Tab on each line starting within following expression.
 200 Paragraphs are separated only by blank lines.  Semicolons start comments.
 201 If you accidentally suspend your process, use \\[comint-continue-subjob]
 202 to continue it."
 203   ;; Customise in inferior-scheme-mode-hook
 204   (setq comint-prompt-regexp "^[^>\n]*>+ *") ; OK for cscheme, oaklisp, T,...
 205   (scheme-mode-variables)
 206   (setq mode-line-process '(":%s"))
 207   (setq comint-input-filter (function scheme-input-filter))
 208   (setq comint-get-old-input (function scheme-get-old-input)))
 209
 210 (defcustom inferior-scheme-filter-regexp "\\`\\s *\\S ?\\S ?\\s *\\'"
 211   "*Input matching this regexp are not saved on the history list.
 212 Defaults to a regexp ignoring all inputs of 0, 1, or 2 letters."
 213   :type 'regexp
 214   :group 'cmuscheme)
 215
 216 (defun scheme-input-filter (str)
 217   "Don't save anything matching `inferior-scheme-filter-regexp'."
 218   (not (string-match inferior-scheme-filter-regexp str)))
 219
 220 (defun scheme-get-old-input ()
 221   "Snarf the sexp ending at point."
 222   (save-excursion
 223     (let ((end (point)))
 224       (backward-sexp)
 225       (buffer-substring (point) end))))
 226
 227 (defun scheme-args-to-list (string)
 228   (let ((where (string-match "[ \t]" string)))
 229     (cond ((null where) (list string))
 230           ((not (= where 0))
 231            (cons (substring string 0 where)
 232                  (scheme-args-to-list (substring string (+ 1 where)
 233                                                  (length string)))))
 234           (t (let ((pos (string-match "[^ \t]" string)))
 235                (if (null pos)
 236                    nil
 237                  (scheme-args-to-list (substring string pos
 238                                                  (length string)))))))))
 239
 240 ;;;###autoload
 241 (defun run-scheme (cmd)
 242   "Run an inferior Scheme process, input and output via buffer `*scheme*'.
 243 If there is a process already running in `*scheme*', switch to that buffer.
 244 With argument, allows you to edit the command line (default is value
 245 of `scheme-program-name').
 246 If a file `~/.emacs_SCHEMENAME' exists, it is given as initial input.
 247 Note that this may lose due to a timing error if the Scheme processor
 248 discards input when it starts up.
 249 Runs the hook `inferior-scheme-mode-hook' \(after the `comint-mode-hook'
 250 is run).
 251 \(Type \\[describe-mode] in the process buffer for a list of commands.)"
 252
 253   (interactive (list (if current-prefix-arg
 254                          (read-string "Run Scheme: " scheme-program-name)
 255                          scheme-program-name)))
 256   (if (not (comint-check-proc "*scheme*"))
 257       (let ((cmdlist (scheme-args-to-list cmd)))
 258         (set-buffer (apply 'make-comint "scheme" (car cmdlist)
 259                            (scheme-start-file (car cmdlist)) (cdr cmdlist)))
 260         (inferior-scheme-mode)))
 261   (setq scheme-program-name cmd)
 262   (setq scheme-buffer "*scheme*")
 263   (pop-to-buffer "*scheme*"))
 264 ;;;###autoload (add-hook 'same-window-buffer-names "*scheme*")
 265
 266 (defun scheme-start-file (prog)
 267   "Return the name of the start file corresponding to PROG.
 268 Search in the directories \"~\" and \"~/.emacs.d\", in this
 269 order.  Return nil if no start file found."
 270   (let* ((name (concat ".emacs_" (file-name-nondirectory prog)))
 271          (start-file (concat "~/" name)))
 272     (if (file-exists-p start-file)
 273         start-file
 274       (let ((start-file (concat user-emacs-directory name)))
 275         (and (file-exists-p start-file) start-file)))))
 276
 277 (defun scheme-send-region (start end)
 278   "Send the current region to the inferior Scheme process."
 279   (interactive "r")
 280   (comint-send-region (scheme-proc) start end)
 281   (comint-send-string (scheme-proc) "\n"))
 282
 283 (defun scheme-send-definition ()
 284   "Send the current definition to the inferior Scheme process."
 285   (interactive)
 286   (save-excursion
 287    (end-of-defun)
 288    (let ((end (point)))
 289      (beginning-of-defun)
 290      (scheme-send-region (point) end))))
 291
 292 (defun scheme-send-last-sexp ()
 293   "Send the previous sexp to the inferior Scheme process."
 294   (interactive)
 295   (scheme-send-region (save-excursion (backward-sexp) (point)) (point)))
 296
 297 (defcustom scheme-compile-exp-command "(compile '%s)"
 298   "*Template for issuing commands to compile arbitrary Scheme expressions."
 299   :type 'string
 300   :group 'cmuscheme)
 301
 302 (defun scheme-compile-region (start end)
 303   "Compile the current region in the inferior Scheme process.
 304 \(A BEGIN is wrapped around the region: (BEGIN <region>))"
 305   (interactive "r")
 306   (comint-send-string (scheme-proc) (format scheme-compile-exp-command
 307                                             (format "(begin %s)"
 308                                                     (buffer-substring start end))))
 309   (comint-send-string (scheme-proc) "\n"))
 310
 311 (defun scheme-compile-definition ()
 312   "Compile the current definition in the inferior Scheme process."
 313   (interactive)
 314   (save-excursion
 315    (end-of-defun)
 316    (let ((end (point)))
 317      (beginning-of-defun)
 318      (scheme-compile-region (point) end))))
 319
 320 (defcustom scheme-trace-command "(trace %s)"
 321   "*Template for issuing commands to trace a Scheme procedure.
 322 Some Scheme implementations might require more elaborate commands here.
 323 For PLT-Scheme, e.g., one should use
 324
 325    (setq scheme-trace-command \"(begin (require (lib \\\"trace.ss\\\")) (trace %s))\")
 326
 327 For Scheme 48 and Scsh use \",trace %s\"."
 328   :type 'string
 329   :group 'cmuscheme)
 330
 331 (defcustom scheme-untrace-command "(untrace %s)"
 332   "*Template for switching off tracing of a Scheme procedure.
 333 Scheme 48 and Scsh users should set this variable to \",untrace %s\"."
 334
 335   :type 'string
 336   :group 'cmuscheme)
 337
 338 (defun scheme-trace-procedure (proc &optional untrace)
 339   "Trace procedure PROC in the inferior Scheme process.
 340 With a prefix argument switch off tracing of procedure PROC."
 341   (interactive
 342    (list (let ((current (symbol-at-point))
 343                (action (if current-prefix-arg "Untrace" "Trace")))
 344            (if current
 345                (read-string (format "%s procedure [%s]: " action current) nil nil (symbol-name current))
 346              (read-string (format "%s procedure: " action))))
 347          current-prefix-arg))
 348   (when (= (length proc) 0)
 349     (error "Invalid procedure name"))
 350   (comint-send-string (scheme-proc)
 351                       (format
 352                        (if untrace scheme-untrace-command scheme-trace-command)
 353                        proc))
 354   (comint-send-string (scheme-proc) "\n"))
 355
 356 (defcustom scheme-macro-expand-command "(expand %s)"
 357   "*Template for macro-expanding a Scheme form.
 358 For Scheme 48 and Scsh use \",expand %s\"."
 359   :type 'string
 360   :group 'cmuscheme)
 361
 362 (defun scheme-expand-current-form ()
 363   "Macro-expand the form at point in the inferior Scheme process."
 364   (interactive)
 365   (let ((current-form (scheme-form-at-point)))
 366     (if current-form
 367         (progn
 368           (comint-send-string (scheme-proc)
 369                               (format
 370                                scheme-macro-expand-command
 371                                current-form))
 372           (comint-send-string (scheme-proc) "\n"))
 373       (error "Not at a form"))))
 374
 375 (defun scheme-form-at-point ()
 376   (let ((next-sexp (thing-at-point 'sexp)))
 377     (if (and next-sexp (string-equal (substring next-sexp 0 1) "("))
 378         next-sexp
 379       (save-excursion
 380         (backward-up-list)
 381         (scheme-form-at-point)))))
 382
 383 (defun switch-to-scheme (eob-p)
 384   "Switch to the scheme process buffer.
 385 With argument, position cursor at end of buffer."
 386   (interactive "P")
 387   (if (or (and scheme-buffer (get-buffer scheme-buffer))
 388           (scheme-interactively-start-process))
 389       (pop-to-buffer scheme-buffer)
 390     (error "No current process buffer.  See variable `scheme-buffer'"))
 391   (when eob-p
 392     (push-mark)
 393     (goto-char (point-max))))
 394
 395 (defun scheme-send-region-and-go (start end)
 396   "Send the current region to the inferior Scheme process.
 397 Then switch to the process buffer."
 398   (interactive "r")
 399   (scheme-send-region start end)
 400   (switch-to-scheme t))
 401
 402 (defun scheme-send-definition-and-go ()
 403   "Send the current definition to the inferior Scheme.
 404 Then switch to the process buffer."
 405   (interactive)
 406   (scheme-send-definition)
 407   (switch-to-scheme t))
 408
 409 (defun scheme-compile-definition-and-go ()
 410   "Compile the current definition in the inferior Scheme.
 411 Then switch to the process buffer."
 412   (interactive)
 413   (scheme-compile-definition)
 414   (switch-to-scheme t))
 415
 416 (defun scheme-compile-region-and-go (start end)
 417   "Compile the current region in the inferior Scheme.
 418 Then switch to the process buffer."
 419   (interactive "r")
 420   (scheme-compile-region start end)
 421   (switch-to-scheme t))
 422
 423 (defcustom scheme-source-modes '(scheme-mode)
 424   "*Used to determine if a buffer contains Scheme source code.
 425 If it's loaded into a buffer that is in one of these major modes, it's
 426 considered a scheme source file by `scheme-load-file' and `scheme-compile-file'.
 427 Used by these commands to determine defaults."
 428   :type '(repeat function)
 429   :group 'cmuscheme)
 430
 431 (defvar scheme-prev-l/c-dir/file nil
 432   "Caches the last (directory . file) pair.
 433 Caches the last pair used in the last `scheme-load-file' or
 434 `scheme-compile-file' command. Used for determining the default in the
 435 next one.")
 436
 437 (defun scheme-load-file (file-name)
 438   "Load a Scheme file FILE-NAME into the inferior Scheme process."
 439   (interactive (comint-get-source "Load Scheme file: " scheme-prev-l/c-dir/file
 440                                   scheme-source-modes t)) ; t because `load'
 441                                                           ; needs an exact name
 442   (comint-check-source file-name) ; Check to see if buffer needs saved.
 443   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 444                                        (file-name-nondirectory file-name)))
 445   (comint-send-string (scheme-proc) (concat "(load \""
 446                                             file-name
 447                                             "\"\)\n")))
 448
 449 (defun scheme-compile-file (file-name)
 450   "Compile a Scheme file FILE-NAME in the inferior Scheme process."
 451   (interactive (comint-get-source "Compile Scheme file: "
 452                                   scheme-prev-l/c-dir/file
 453                                   scheme-source-modes
 454                                   nil)) ; nil because COMPILE doesn't
 455                                         ; need an exact name.
 456   (comint-check-source file-name) ; Check to see if buffer needs saved.
 457   (setq scheme-prev-l/c-dir/file (cons (file-name-directory    file-name)
 458                                        (file-name-nondirectory file-name)))
 459   (comint-send-string (scheme-proc) (concat "(compile-file \""
 460                                             file-name
 461                                             "\"\)\n")))
 462
 463 \f
 464 (defvar scheme-buffer nil "*The current scheme process buffer.
 465
 466 MULTIPLE PROCESS SUPPORT
 467 ===========================================================================
 468 Cmuscheme.el supports, in a fairly simple fashion, running multiple Scheme
 469 processes.  To run multiple Scheme processes, you start the first up with
 470 \\[run-scheme].  It will be in a buffer named *scheme*.  Rename this buffer
 471 with \\[rename-buffer].  You may now start up a new process with another
 472 \\[run-scheme].  It will be in a new buffer, named *scheme*.  You can
 473 switch between the different process buffers with \\[switch-to-buffer].
 474
 475 Commands that send text from source buffers to Scheme processes --
 476 like `scheme-send-definition' or `scheme-compile-region' -- have to choose a
 477 process to send to, when you have more than one Scheme process around.  This
 478 is determined by the global variable `scheme-buffer'.  Suppose you
 479 have three inferior Schemes running:
 480     Buffer      Process
 481     foo         scheme
 482     bar         scheme<2>
 483     *scheme*    scheme<3>
 484 If you do a \\[scheme-send-definition-and-go] command on some Scheme source
 485 code, what process do you send it to?
 486
 487 - If you're in a process buffer (foo, bar, or *scheme*),
 488   you send it to that process.
 489 - If you're in some other buffer (e.g., a source file), you
 490   send it to the process attached to buffer `scheme-buffer'.
 491 This process selection is performed by function `scheme-proc'.
 492
 493 Whenever \\[run-scheme] fires up a new process, it resets `scheme-buffer'
 494 to be the new process's buffer.  If you only run one process, this will
 495 do the right thing.  If you run multiple processes, you can change
 496 `scheme-buffer' to another process buffer with \\[set-variable].
 497
 498 More sophisticated approaches are, of course, possible.  If you find yourself
 499 needing to switch back and forth between multiple processes frequently,
 500 you may wish to consider ilisp.el, a larger, more sophisticated package
 501 for running inferior Lisp and Scheme processes.  The approach taken here is
 502 for a minimal, simple implementation.  Feel free to extend it.")
 503
 504 (defun scheme-proc ()
 505   "Return the current Scheme process, starting one if necessary.
 506 See variable `scheme-buffer'."
 507   (unless (and scheme-buffer
 508                (get-buffer scheme-buffer)
 509                (comint-check-proc scheme-buffer))
 510     (scheme-interactively-start-process))
 511   (or (scheme-get-process)
 512       (error "No current process.  See variable `scheme-buffer'")))
 513
 514 (defun scheme-get-process ()
 515   "Return the current Scheme process or nil if none is running."
 516   (get-buffer-process (if (eq major-mode 'inferior-scheme-mode)
 517                           (current-buffer)
 518                         scheme-buffer)))
 519
 520 (defun scheme-interactively-start-process (&optional cmd)
 521   "Start an inferior Scheme process.  Return the process started.
 522 Since this command is run implicitly, always ask the user for the
 523 command to run."
 524   (save-window-excursion
 525     (run-scheme (read-string "Run Scheme: " scheme-program-name))))
 526
 527 ;;; Do the user's customisation...
 528
 529 (defcustom cmuscheme-load-hook nil
 530   "This hook is run when cmuscheme is loaded in.
 531 This is a good place to put keybindings."
 532   :type 'hook
 533   :group 'cmuscheme)
 534
 535 (run-hooks 'cmuscheme-load-hook)
 536
 537 (provide 'cmuscheme)
 538
 539 ;; arch-tag: e8795f4a-c496-45a2-97b4-8e0f2a2c57d2
 540 ;;; cmuscheme.el ends here