code.delx.au - gnu-emacs/blob - lisp/view.el

   1 ;;; view.el --- peruse file or buffer without editing.
   2
   3 ;; Copyright (C) 1985, 1989, 1994, 1995, 1997 Free Software Foundation, Inc.
   4
   5 ;; Author: K. Shane Hartman
   6 ;; Maintainer: Inge Frick <inge@nada.kth.se>
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package provides the `view' minor mode documented in the Emacs
  28 ;; user's manual.
  29 ;; View mode entry and exit is done through the functions view-mode-enter
  30 ;; and view-mode-exit.  Use these functions to enter or exit view-mode from
  31 ;; emacs lisp programs.
  32 ;; We use both view- and View- as prefix for symbols.  View- is used as
  33 ;; prefix for commands that have a key binding.  view- is used for commands
  34 ;; without key binding.  The purpose of this is to make it easier for a
  35 ;; user to use command name completion.
  36
  37 ;;; Suggested key bindings:
  38 ;;
  39 ;; (define-key ctl-x-4-map "v" 'view-file-other-window)  ; ^x4v
  40 ;; (define-key ctl-x-5-map "v" 'view-file-other-frame)  ; ^x5v
  41 ;;
  42 ;; You could also bind view-file, view-buffer, view-buffer-other-window and
  43 ;; view-buffer-other-frame to keys.
  44
  45 ;;; Code:
  46
  47 (defgroup view nil
  48   "Peruse file or buffer without editing."
  49   :link '(function-link view-mode)
  50   :link '(custom-manual "(emacs)Misc File Ops")
  51   :group 'wp
  52   :group 'editing)
  53
  54 (defcustom view-read-only nil
  55   "*Non-nil means buffers visiting files read-only, do it in view mode."
  56   :type 'boolean
  57   :group 'view)
  58
  59 (defcustom view-highlight-face 'highlight
  60    "*The face used for highlighting the match found by View mode search."
  61    :type 'face
  62    :group 'view)
  63
  64 ;; `view-mode-auto-exit' is replaced by the following option variable which
  65 ;; only says if scrolling past buffer end should leave view mode or not, it
  66 ;; doesn't say if leaving view mode should restore windows or not.  The latter
  67 ;; is now controlled by the presence of a value in `view-return-to-alist'.
  68 (defcustom view-scroll-auto-exit nil
  69   "*Non-nil means scrolling past the end of buffer exits View mode.
  70 nil means attempting to scroll past the end of the buffer,
  71 only rings the bell and gives a message on how to leave."
  72   :type 'boolean
  73   :group 'view)
  74
  75 (defcustom view-try-extend-at-buffer-end nil
  76  "*Non-nil means try load more of file when reaching end of buffer.
  77 This variable is mainly intended to be temporarily set to non-nil by
  78 the F command in view-mode, but you can set it to t if you want the action
  79 for all scroll commands in view mode."
  80   :type 'boolean
  81   :group 'view)
  82
  83 (defcustom view-remove-frame-by-deleting nil
  84   "*Determine how View mode removes a frame no longer needed.
  85 If nil, make an icon of the frame.  If non-nil, delete the frame."
  86   :type 'boolean
  87   :group 'view)
  88
  89 (defcustom view-exits-all-viewing-windows nil
  90   "*Non-nil means restore all windows used to view buffer.
  91 Commands that restore windows when finished viewing a buffer, apply to all
  92 windows that display the buffer and have restore information in
  93 `view-return-to-alist'.
  94 If `view-exits-all-viewing-windows' is nil, only the selected window is
  95 considered for restoring."
  96   :type 'boolean
  97   :group 'view)
  98
  99 ;;;###autoload
 100 (defvar view-mode nil
 101   "Non-nil if View mode is enabled.
 102 Don't change this variable directly, you must change it by one of the
 103 functions that enable or disable view mode.")
 104 ;;;###autoload
 105 (make-variable-buffer-local 'view-mode)
 106
 107 (defcustom view-mode-hook nil
 108   "Normal hook run when starting to view a buffer or file."
 109   :type 'hook
 110   :group 'view)
 111
 112 (defvar view-old-buffer-read-only nil)
 113 (make-variable-buffer-local 'view-old-buffer-read-only)
 114
 115 (defvar view-old-Helper-return-blurb)
 116 (make-variable-buffer-local 'view-old-Helper-return-blurb)
 117
 118 (defvar view-page-size nil
 119   "Default number of lines to scroll by View page commands.
 120 If nil then the local value of this is initially set to window size.")
 121 (make-variable-buffer-local 'view-page-size)
 122
 123 (defvar view-half-page-size nil
 124   "Default number of lines to scroll by View half page commands.
 125 If nil then the local value of this is initially set to half window size.")
 126 (make-variable-buffer-local 'view-half-page-size)
 127
 128 (defvar view-last-regexp nil)
 129 (make-variable-buffer-local 'view-last-regexp) ; Global is better???
 130
 131 (defvar view-return-to-alist nil
 132   "What to do with used windows and where to go when finished viewing buffer.
 133 This is local in each buffer being viewed.
 134 It is added to by `view-mode-enter' when starting to view a buffer and
 135 subtracted from by `view-mode-exit' when finished viewing the buffer.
 136
 137 See RETURN-TO-ALIST argument of function `view-mode-exit' for the format of
 138 `view-return-to-alist'.")
 139 (make-variable-buffer-local 'view-return-to-alist)
 140
 141 (defvar view-exit-action nil
 142   "nil or a function with one argument (a buffer) called when finished viewing.
 143 This is local in each buffer being viewed.
 144 The \\[view-file] and \\[view-file-other-window] commands may set this to
 145 `kill-buffer'.")
 146 (make-variable-buffer-local 'view-exit-action)
 147
 148 (defvar view-no-disable-on-exit nil
 149   "If non-nil, View mode \"exit\" commands don't actually disable View mode.
 150 Instead, these commands just switch buffers or windows.
 151 This is set in certain buffers by specialized features such as help commands
 152 that use View mode automatically.")
 153
 154 (defvar view-overlay nil
 155   "Overlay used to display where a search operation found its match.
 156 This is local in each buffer, once it is used.")
 157 (make-variable-buffer-local 'view-overlay)
 158
 159 (or (assq 'view-mode minor-mode-alist)
 160     (setq minor-mode-alist
 161           (cons '(view-mode " View") minor-mode-alist)))
 162
 163 ;; Define keymap inside defvar to make it easier to load changes.
 164 ;; Some redundant "less"-like key bindings below have been commented out.
 165 (defvar view-mode-map
 166   (let ((map (make-sparse-keymap)))
 167     (define-key map "C" 'View-kill-and-leave)
 168     (define-key map "c" 'View-leave)
 169     (define-key map "Q" 'View-quit-all)
 170     (define-key map "E" 'View-exit-and-edit)
 171 ;    (define-key map "v" 'View-exit)
 172     (define-key map "e" 'View-exit)
 173     (define-key map "q" 'View-quit)
 174 ;    (define-key map "N" 'View-search-last-regexp-backward)
 175     (define-key map "p" 'View-search-last-regexp-backward)
 176     (define-key map "n" 'View-search-last-regexp-forward)
 177 ;    (define-key map "?" 'View-search-regexp-backward) ; Less does this.
 178     (define-key map "\\" 'View-search-regexp-backward)
 179     (define-key map "/" 'View-search-regexp-forward)
 180     (define-key map "r" 'isearch-backward)
 181     (define-key map "s" 'isearch-forward)
 182     (define-key map "m" 'point-to-register)
 183     (define-key map "'" 'register-to-point)
 184     (define-key map "x" 'exchange-point-and-mark)
 185     (define-key map "@" 'View-back-to-mark)
 186     (define-key map "." 'set-mark-command)
 187     (define-key map "%" 'View-goto-percent)
 188 ;    (define-key map "G" 'View-goto-line-last)
 189     (define-key map "g" 'View-goto-line)
 190     (define-key map "=" 'what-line)
 191     (define-key map "F" 'View-revert-buffer-scroll-page-forward)
 192 ;    (define-key map "k" 'View-scroll-line-backward)
 193     (define-key map "y" 'View-scroll-line-backward)
 194 ;    (define-key map "j" 'View-scroll-line-forward)
 195     (define-key map "\n" 'View-scroll-line-forward)
 196     (define-key map "\r" 'View-scroll-line-forward)
 197     (define-key map "u" 'View-scroll-half-page-backward)
 198     (define-key map "d" 'View-scroll-half-page-forward)
 199     (define-key map "z" 'View-scroll-page-forward-set-page-size)
 200     (define-key map "w" 'View-scroll-page-backward-set-page-size)
 201 ;    (define-key map "b" 'View-scroll-page-backward)
 202     (define-key map "\C-?" 'View-scroll-page-backward)
 203 ;    (define-key map "f" 'View-scroll-page-forward)
 204     (define-key map " " 'View-scroll-page-forward)
 205     (define-key map "o" 'View-scroll-to-buffer-end)
 206     (define-key map ">" 'end-of-buffer)
 207     (define-key map "<" 'beginning-of-buffer)
 208     (define-key map "-" 'negative-argument)
 209     (define-key map "9" 'digit-argument)
 210     (define-key map "8" 'digit-argument)
 211     (define-key map "7" 'digit-argument)
 212     (define-key map "6" 'digit-argument)
 213     (define-key map "5" 'digit-argument)
 214     (define-key map "4" 'digit-argument)
 215     (define-key map "3" 'digit-argument)
 216     (define-key map "2" 'digit-argument)
 217     (define-key map "1" 'digit-argument)
 218     (define-key map "0" 'digit-argument)
 219     (define-key map "H" 'describe-mode)
 220     (define-key map "?" 'describe-mode) ; Maybe do as less instead?
 221     (define-key map "h" 'describe-mode)
 222     map))
 223
 224 (or (assq 'view-mode minor-mode-map-alist)
 225     (setq minor-mode-map-alist
 226           (cons (cons 'view-mode view-mode-map) minor-mode-map-alist)))
 227
 228 ;;; Commands that enter or exit view mode.
 229
 230 ;;;###autoload
 231 (defun view-file (file-name)
 232   "View FILE in View mode, returning to previous buffer when done.
 233 Emacs commands editing the buffer contents are not available; instead,
 234 a special set of commands (mostly letters and punctuation)
 235 are defined for moving around in the buffer.
 236 Space scrolls forward, Delete scrolls backward.
 237 For list of all View commands, type H or h while viewing.
 238
 239 This command runs the normal hook `view-mode-hook'."
 240   (interactive "fView file: ")
 241   (let ((had-a-buf (get-file-buffer file-name)))
 242     (view-buffer (find-file-noselect file-name)
 243                  (and (not had-a-buf) 'kill-buffer))))
 244
 245 ;;;###autoload
 246 (defun view-file-other-window (file-name)
 247   "View FILE in View mode in another window.
 248 Return that window to its previous buffer when done.
 249 Emacs commands editing the buffer contents are not available; instead,
 250 a special set of commands (mostly letters and punctuation)
 251 are defined for moving around in the buffer.
 252 Space scrolls forward, Delete scrolls backward.
 253 For list of all View commands, type H or h while viewing.
 254
 255 This command runs the normal hook `view-mode-hook'."
 256   (interactive "fIn other window view file: ")
 257   (let ((had-a-buf (get-file-buffer file-name)))
 258     (view-buffer-other-window (find-file-noselect file-name) nil
 259                               (and (not had-a-buf) 'kill-buffer))))
 260
 261 ;;;###autoload
 262 (defun view-file-other-frame (file-name)
 263   "View FILE in View mode in another frame.
 264 Maybe delete other frame and/or return to previous buffer when done.
 265 Emacs commands editing the buffer contents are not available; instead,
 266 a special set of commands (mostly letters and punctuation)
 267 are defined for moving around in the buffer.
 268 Space scrolls forward, Delete scrolls backward.
 269 For list of all View commands, type H or h while viewing.
 270
 271 This command runs the normal hook `view-mode-hook'."
 272   (interactive "fIn other frame view file: ")
 273   (let ((had-a-buf (get-file-buffer file-name)))
 274     (view-buffer-other-frame (find-file-noselect file-name) nil
 275                              (and (not had-a-buf) 'kill-buffer))))
 276
 277
 278 ;;;###autoload
 279 (defun view-buffer (buffer-name &optional exit-action)
 280   "View BUFFER in View mode, returning to previous buffer when done.
 281 Emacs commands editing the buffer contents are not available; instead,
 282 a special set of commands (mostly letters and punctuation)
 283 are defined for moving around in the buffer.
 284 Space scrolls forward, Delete scrolls backward.
 285 For list of all View commands, type H or h while viewing.
 286
 287 This command runs the normal hook `view-mode-hook'.
 288
 289 Optional argument EXIT-ACTION is either nil or a function with buffer as
 290 argument.  This function is called when finished viewing buffer.
 291 Use this argument instead of explicitly setting `view-exit-action'."
 292
 293   (interactive "bView buffer: ")
 294   (let ((undo-window (list (window-buffer) (window-start) (window-point))))
 295     (switch-to-buffer buffer-name)
 296     (view-mode-enter (cons (selected-window) (cons nil undo-window))
 297                      exit-action)))
 298
 299 ;;;###autoload
 300 (defun view-buffer-other-window
 301   (buffer-name &optional not-return exit-action)
 302   "View BUFFER in View mode in another window.
 303 Return to previous buffer when done, unless optional NOT-RETURN is non-nil.
 304 Emacs commands editing the buffer contents are not available; instead,
 305 a special set of commands (mostly letters and punctuation)
 306 are defined for moving around in the buffer.
 307 Space scrolls forward, Delete scrolls backward.
 308 For list of all View commands, type H or h while viewing.
 309
 310 This command runs the normal hook `view-mode-hook'.
 311
 312 Optional argument EXIT-ACTION is either nil or a function with buffer as
 313 argument.  This function is called when finished viewing buffer.
 314 Use this argument instead of explicitly setting `view-exit-action'."
 315   (interactive "bIn other window view buffer:\nP")
 316   (let* ((win                           ; This window will be selected by
 317           (get-lru-window))             ; switch-to-buffer-other-window below.
 318          (return-to
 319           (and (not not-return)
 320                (cons (selected-window)
 321                      (if (eq win (selected-window))
 322                          t                      ; Has to make new window.
 323                        (list
 324                         (window-buffer win)     ; Other windows old buffer.
 325                         (window-start win)
 326                         (window-point win)))))))
 327     (switch-to-buffer-other-window buffer-name)
 328     (view-mode-enter (and return-to (cons (selected-window) return-to))
 329                      exit-action)))
 330
 331 ;;;###autoload
 332 (defun view-buffer-other-frame
 333   (buffer-name &optional not-return exit-action)
 334   "View BUFFER in View mode in another frame.
 335 Return to previous buffer when done, unless optional NOT-RETURN is non-nil.
 336 Emacs commands editing the buffer contents are not available; instead,
 337 a special set of commands (mostly letters and punctuation)
 338 are defined for moving around in the buffer.
 339 Space scrolls forward, Delete scrolls backward.
 340 For list of all View commands, type H or h while viewing.
 341
 342 This command runs the normal hook `view-mode-hook'.
 343
 344 Optional argument EXIT-ACTION is either nil or a function with buffer as
 345 argument.  This function is called when finished viewing buffer.
 346 Use this argument instead of explicitly setting `view-exit-action'."
 347   (interactive "bView buffer in other frame: \nP")
 348   (let ((return-to
 349          (and (not not-return) (cons (selected-window) t)))) ; Old window.
 350     (switch-to-buffer-other-frame buffer-name)
 351     (view-mode-enter (and return-to (cons (selected-window) return-to))
 352                      exit-action)))
 353
 354 ;;;###autoload
 355 (defun view-mode (&optional arg)
 356   ;; In the following documentation string we have to use some explicit key
 357   ;; bindings instead of using the \\[] construction.  The reason for this
 358   ;; is that most commands have more than one key binding.
 359   "Toggle View mode, a minor mode for viewing text but not editing it.
 360 With arg, turn View mode on iff arg is positive.
 361
 362 Emacs commands that do not change the buffer contents are available as usual.
 363 Kill commands insert text in kill buffers but do not delete.  Other commands
 364 \(among them most letters and punctuation) beep and tell that the buffer is
 365 read-only.
 366 \\<view-mode-map>
 367 The following additional commands are provided.  Most commands take prefix
 368 arguments.  Page commands default to \"page size\" lines which is almost a whole
 369 window full, or number of lines set by \\[View-scroll-page-forward-set-page-size] or \\[View-scroll-page-backward-set-page-size].  Half page commands default to
 370 and set \"half page size\" lines which initially is half a window full.  Search
 371 commands default to a repeat count of one.
 372
 373 H, h, ?  This message.
 374 Digits  provide prefix arguments.
 375 \\[negative-argument]   negative prefix argument.
 376 \\[beginning-of-buffer] move to the beginning of buffer.
 377 >       move to the end of buffer.
 378 \\[View-scroll-to-buffer-end]   scroll so that buffer end is at last line of window.
 379 SPC     scroll forward prefix (default \"page size\") lines.
 380 DEL     scroll backward prefix (default \"page size\") lines.
 381 \\[View-scroll-page-forward-set-page-size]      like  \\[View-scroll-page-forward]  except prefix sets \"page size\".
 382 \\[View-scroll-page-backward-set-page-size]     like  \\[View-scroll-page-backward]  except prefix sets \"page size\".
 383 \\[View-scroll-half-page-forward]       scroll forward (and if prefix set) \"half page size\" lines.
 384 \\[View-scroll-half-page-backward]      scroll backward (and if prefix set) \"half page size\" lines.
 385 RET, LFD  scroll forward prefix (default one) line(s).
 386 y       scroll backward prefix (default one) line(s).
 387 \\[View-revert-buffer-scroll-page-forward]      revert-buffer if necessary and scroll forward.
 388           Use this to view a changing file.
 389 \\[what-line]   prints the current line number.
 390 \\[View-goto-percent]   goes prefix argument (default 100) percent into buffer.
 391 \\[View-goto-line]      goes to line given by prefix argument (default first line).
 392 .       set the mark.
 393 x       exchanges point and mark.
 394 \\[View-back-to-mark]   return to mark and pops mark ring.
 395           Mark ring is pushed at start of every successful search and when
 396           jump to line occurs.  The mark is set on jump to buffer start or end.
 397 \\[point-to-register]   save current position in character register.
 398 '       go to position saved in character register.
 399 s       do forward incremental search.
 400 r       do reverse incremental search.
 401 \\[View-search-regexp-forward]  searches forward for regular expression, starting after current page.
 402           ! and @ have a special meaning at the beginning of the regexp.
 403           ! means search for a line with no match for regexp.  @ means start
 404           search at beginning (end for backward search) of buffer.
 405 \\      searches backward for regular expression, starting before current page.
 406 \\[View-search-last-regexp-forward]     searches forward for last regular expression.
 407 p       searches backward for last regular expression.
 408 \\[View-quit]   quit View mode, trying to restore window and buffer to previous state.
 409           \\[View-quit] is the normal way to leave view mode.
 410 \\[View-exit]   exit View mode but stay in current buffer.  Use this if you started
 411           viewing a buffer (file) and find out you want to edit it.
 412 \\[View-exit-and-edit]  exit View mode and make the current buffer editable.
 413 \\[View-quit-all]       quit View mode, trying to restore windows and buffer to previous state.
 414 \\[View-leave]  quit View mode and maybe switch buffers, but don't kill this buffer.
 415 \\[View-kill-and-leave] quit View mode, kill current buffer and go back to other buffer.
 416
 417 The effect of \\[View-leave] , \\[View-quit] and \\[View-kill-and-leave] depends on how view-mode was entered.  If it was
 418 entered by view-file, view-file-other-window or view-file-other-frame (\\[view-file],
 419 \\[view-file-other-window], \\[view-file-other-frame] or the dired mode v command), then \\[View-quit] will try to kill the
 420 current buffer.  If view-mode was entered from another buffer as is done by
 421 View-buffer, View-buffer-other-window, View-buffer-other frame, View-file,
 422 View-file-other-window or View-file-other-frame then \\[view-leave] , \\[view-quit] and \\[view-kill-and-leave] will return
 423 to that buffer.
 424
 425 Entry to view-mode runs the normal hook `view-mode-hook'."
 426   (interactive "P")
 427   (unless (and arg                      ; Do nothing if already OK.
 428                (if (> (prefix-numeric-value arg) 0) view-mode (not view-mode)))
 429     (if view-mode (view-mode-disable)
 430       (view-mode-enable))))
 431
 432 (defun view-mode-enable ()
 433   "Turn on View mode."
 434   ;; Always leave view mode before changing major mode.
 435   ;; This is to guarantee that the buffer-read-only variable is restored.
 436   (make-local-hook 'change-major-mode-hook)
 437   (add-hook 'change-major-mode-hook 'view-mode-disable nil t)
 438   (setq view-mode t
 439         view-page-size (view-page-size-default view-page-size)
 440         view-half-page-size (or view-half-page-size (/ (view-window-size) 2))
 441         view-old-buffer-read-only buffer-read-only
 442         buffer-read-only t
 443         view-old-Helper-return-blurb (and (boundp 'Helper-return-blurb)
 444                                           Helper-return-blurb)
 445         Helper-return-blurb
 446         (format "continue viewing %s"
 447                 (if (buffer-file-name)
 448                     (file-name-nondirectory (buffer-file-name))
 449                   (buffer-name))))
 450   (run-hooks 'view-mode-hook))
 451
 452 (defun view-mode-disable ()
 453   "Turn off View mode."
 454   (remove-hook 'change-major-mode-hook 'view-mode-disable t)
 455   (and view-overlay (delete-overlay view-overlay))
 456   (setq view-mode nil
 457         Helper-return-blurb view-old-Helper-return-blurb
 458         buffer-read-only view-old-buffer-read-only))
 459
 460 ;;;###autoload
 461 (defun view-mode-enter (&optional return-to exit-action) "\
 462 Enter View mode and set up exit from view mode depending on optional arguments.
 463 If RETURN-TO is non-nil it is added as an element to the buffer local alist
 464 `view-return-to-alist'.
 465 Save EXIT-ACTION in buffer local variable `view-exit-action'.
 466 It should be either nil or a function that takes a buffer as argument.
 467 This function will be called by `view-mode-exit'.
 468
 469 RETURN-TO is either nil, meaning do nothing when exiting view mode, or
 470 it has the format (WINDOW OLD-WINDOW . OLD-BUF-INFO).
 471 WINDOW is a window used for viewing.
 472 OLD-WINDOW is nil or the window to select after viewing.
 473 OLD-BUF-INFO tells what to do with WINDOW when exiting.  It is one of:
 474 1) nil       Do nothing.
 475 2) t         Delete WINDOW or, if it is the only window, its frame.
 476 3) (OLD-BUFF START POINT)  Display buffer OLD-BUFF with displayed text
 477                            starting at START and point at POINT in WINDOW.
 478 4) quit-window   Do quit-window in WINDOW.
 479
 480 For list of all View commands, type H or h while viewing.
 481
 482 This function runs the normal hook `view-mode-hook'."
 483   (if return-to
 484       (let ((entry (assq (car return-to) view-return-to-alist)))
 485         (if entry (setcdr entry (cdr return-to))
 486           (setq view-return-to-alist (cons return-to view-return-to-alist)))))
 487   (if exit-action (setq view-exit-action exit-action))
 488   (unless view-mode                     ; Do nothing if already in view mode.
 489     (view-mode-enable)
 490     (force-mode-line-update)
 491     (message "%s"
 492              (substitute-command-keys "\
 493 Type \\[help-command] for help, \\[describe-mode] for commands, \\[View-quit] to quit."))))
 494
 495 (defun view-mode-exit (&optional return-to-alist exit-action all-win)
 496   "Exit View mode in various ways, depending on optional arguments.
 497 RETURN-TO-ALIST, EXIT-ACTION and ALL-WIN determine what to do after exit.
 498 EXIT-ACTION is nil or a function that is called with current buffer as
 499 argument.
 500 RETURN-TO-ALIST is an alist that for some of the windows displaying the
 501 current buffer, associate information on what to do with those windows.
 502 If ALL-WIN or the variable `view-exits-all-viewing-windows' is non-nil,
 503 then all windows on RETURN-TO-ALIST are restored to their old state.
 504 Otherwise only the selected window is affected (if it is on RETURN-TO-ALIST).
 505
 506 Elements of RETURN-TO-ALIST have the format (WINDOW OLD-WINDOW . OLD-BUF-INFO).
 507 WINDOW is a window displaying the current buffer.
 508 OLD-WINDOW is nil or a window to select after viewing.
 509 OLD-BUF-INFO is information on what to do with WINDOW and is one of:
 510 1) nil       Do nothing.
 511 2) t         Delete WINDOW or, if it is the only window, its frame.
 512 3) (OLD-BUF START POINT)  Display buffer OLD-BUF with displayed text
 513                           starting at START and point at POINT in WINDOW.
 514 4) quit-window   Do quit-window in WINDOW.
 515
 516 If one of the WINDOW in RETURN-TO-ALIST is the selected window and the
 517 corresponding OLD-WINDOW is a live window, then select OLD-WINDOW."
 518   (setq all-win
 519         (and return-to-alist (or all-win view-exits-all-viewing-windows)))
 520   (if view-mode         ; Only do something if in view mode.
 521       (let* ((buffer (current-buffer))
 522              window
 523              (sel-old (assq (selected-window) return-to-alist))
 524              (alist (cond
 525                      (all-win           ; Try to restore all windows.
 526                       (append return-to-alist nil)) ; Copy.
 527                      (sel-old           ; Only selected window.
 528                       (list sel-old))))
 529              (old-window (if sel-old (car (cdr sel-old)))))
 530         (if all-win                     ; Follow chains of old-windows.
 531             (let ((c (length alist)) a)
 532               (while (and (> c 0)       ; Safety if mutually refering windows.
 533                           (or (not (window-live-p old-window))
 534                               (eq buffer (window-buffer old-window)))
 535                           (setq a (assq old-window alist)))
 536                 (setq c (1- c))
 537                 (setq old-window (car (cdr a))))
 538               (if (or (zerop c) (not (window-live-p old-window)))
 539                   (setq old-window (selected-window)))))
 540         (or view-no-disable-on-exit
 541             (view-mode-disable))
 542         (while alist                    ; Restore windows with info.
 543           (if (and (window-live-p (setq window (car (car alist))))
 544                    (eq buffer (window-buffer window)))
 545               (let ((frame (window-frame window))
 546                     (old-buf-info (cdr (cdr (car alist)))))
 547                 (if all-win (select-window window))
 548                 (cond
 549                  ((and (consp old-buf-info) ; Case 3.
 550                        (buffer-live-p (car old-buf-info)))
 551                   (set-window-buffer window (car old-buf-info)) ; old-buf
 552                   (set-window-start window (car (cdr old-buf-info)))
 553                   (set-window-point window (car (cdr (cdr old-buf-info)))))
 554                  ((eq old-buf-info 'quit-window)
 555                   (quit-window)) ; Not case 2, do nothing.
 556                  ((not (eq old-buf-info t)) nil) ; Not case 2, do nothing.
 557                  ((not (one-window-p t)) (delete-window))
 558                  ((not (eq frame (next-frame)))
 559                   ;; Not the only frame, so can safely be removed.
 560                   (if view-remove-frame-by-deleting
 561                       (delete-frame frame)
 562                     (iconify-frame frame))))))
 563           ;; Altering view-return-to-alist causes trouble when
 564           ;; the user deiconifies the frame, then types q again.
 565           ;; If we leave view-return-to-alist unchanged, that
 566           ;; iconifies the frame again, as expected.
 567 ;;;       (setq view-return-to-alist (delete (car alist) view-return-to-alist))
 568           (setq alist (cdr alist)))
 569         (if (window-live-p old-window)  ; still existing window
 570             (select-window old-window))
 571         (when exit-action
 572           (setq view-exit-action nil)
 573           (funcall exit-action buffer))
 574         (force-mode-line-update))))
 575
 576 (defun View-exit ()
 577   "Exit View mode but stay in current buffer."
 578   (interactive)
 579   (view-mode-exit))
 580
 581 ;;;###autoload
 582 (defun View-exit-and-edit ()
 583   "Exit View mode and make the current buffer editable."
 584   (interactive)
 585   (let ((view-old-buffer-read-only nil)
 586         (view-no-disable-on-exit nil))
 587     (view-mode-exit)))
 588
 589 (defun View-leave ()
 590   "Quit View mode and maybe switch buffers, but don't kill this buffer."
 591   (interactive)
 592   (view-mode-exit view-return-to-alist))
 593
 594 (defun View-quit ()
 595   "Quit View mode, trying to restore window and buffer to previous state.
 596 Maybe kill this buffer.  Try to restore selected window to previous state
 597 and go to previous buffer or window."
 598   (interactive)
 599   (view-mode-exit view-return-to-alist view-exit-action))
 600
 601 (defun View-quit-all ()
 602   "Quit View mode, trying to restore windows and buffers to previous state.
 603 Maybe kill current buffer.  Try to restore all windows viewing buffer to
 604 previous state and go to previous buffer or window."
 605   (interactive)
 606   (view-mode-exit view-return-to-alist view-exit-action t))
 607
 608 (defun View-kill-and-leave ()
 609   "Quit View mode, kill current buffer and return to previous buffer."
 610   (interactive)
 611   (view-mode-exit view-return-to-alist (or view-exit-action 'kill-buffer) t))
 612
 613
 614 ;;; Some help routines.
 615
 616 (defun view-window-size ()
 617   ;; Window height excluding mode line.
 618   (1- (window-height)))
 619
 620 ;(defun view-last-command (&optional who what)
 621 ;  (setq view-last-command-entry this-command)
 622 ;  (setq view-last-command who)
 623 ;  (setq view-last-command-argument what))
 624
 625 ;(defun View-repeat-last-command ()
 626 ;  "Repeat last command issued in View mode."
 627 ;  (interactive)
 628 ;  (if (and view-last-command
 629 ;          (eq view-last-command-entry last-command))
 630 ;      (funcall view-last-command view-last-command-argument))
 631 ;  (setq this-command view-last-command-entry))
 632
 633 (defun view-recenter ()
 634   ;; Center point in window.
 635   (recenter (/ (view-window-size) 2)))
 636
 637 (defun view-page-size-default (lines)
 638   ;; Get page size.
 639   (let ((default (- (view-window-size) next-screen-context-lines)))
 640     (if (or (null lines) (zerop (setq lines (prefix-numeric-value lines))))
 641         default
 642       (min (abs lines) default))))
 643
 644 (defun view-set-half-page-size-default (lines)
 645   ;; Get and maybe set half page size.
 646   (if (not lines) view-half-page-size
 647     (setq view-half-page-size
 648           (if (zerop (setq lines (prefix-numeric-value lines)))
 649               (/ (view-window-size) 2)
 650             (view-page-size-default lines)))))
 651
 652
 653 ;;; Commands for moving around in the buffer.
 654
 655 (defun View-goto-percent (&optional percent)
 656   "Move to end (or prefix PERCENT) of buffer in View mode.
 657 Display is centered at point.
 658 Also set the mark at the position where point was."
 659   (interactive "P")
 660   (push-mark)
 661   (goto-char
 662    (if percent
 663        (+ (point-min)
 664           (floor (* (- (point-max) (point-min)) 0.01
 665                     (max 0 (min 100 (prefix-numeric-value percent))))))
 666      (point-max)))
 667   (view-recenter))
 668
 669 ;(defun View-goto-line-last (&optional line)
 670 ;"Move to last (or prefix LINE) line in View mode.
 671 ;Display is centered at LINE.
 672 ;Sets mark at starting position and pushes mark ring."
 673 ;  (interactive "P")
 674 ;  (push-mark)
 675 ;  (if line (goto-line (prefix-numeric-value line))
 676 ;    (goto-char (point-max))
 677 ;    (beginning-of-line))
 678 ;  (view-recenter))
 679
 680 (defun View-goto-line (&optional line)
 681   "Move to first (or prefix LINE) line in View mode.
 682 Display is centered at LINE.
 683 Also set the mark at the position where point was."
 684   (interactive "p")
 685   (push-mark)
 686   (goto-line line)
 687   (view-recenter))
 688
 689 (defun View-scroll-to-buffer-end ()
 690   "Scroll backward or forward so that buffer end is at last line of window."
 691   (interactive)
 692   (let ((p (if (pos-visible-in-window-p (point-max)) (point))))
 693     (goto-char (point-max))
 694     (recenter -1)
 695     (and p (goto-char p))))
 696
 697 (defun view-scroll-lines (lines backward default maxdefault)
 698   ;; This function does the job for all the scrolling commands.
 699   ;; Scroll forward LINES lines.  If BACKWARD is true scroll backwards.
 700   ;; If LINES is negative scroll in the other direction.  If LINES is 0 or nil,
 701   ;; scroll DEFAULT lines.  If MAXDEFAULT is true then scroll no more than a
 702   ;; window full.
 703   (if (or (null lines) (zerop (setq lines (prefix-numeric-value lines))))
 704       (setq lines default))
 705   (when (< lines 0)
 706     (setq backward (not backward)) (setq lines (- lines)))
 707   (setq default (view-page-size-default nil)) ; Max scrolled at a time.
 708   (if maxdefault (setq lines (min lines default)))
 709   (cond
 710    (backward (scroll-down lines))
 711    ((view-really-at-end)
 712     (if view-scroll-auto-exit (View-quit)
 713       (ding)
 714       (view-end-message)))
 715    (t (while (> lines default)
 716         (scroll-up default)
 717         (setq lines (- lines default))
 718         (if (view-really-at-end) (setq lines 0)))
 719       (scroll-up lines)
 720       (if (view-really-at-end) (view-end-message))
 721       (move-to-window-line -1)
 722       (beginning-of-line))))
 723
 724 (defun view-really-at-end ()
 725   ;; Return true if buffer end visible.  Maybe revert buffer and test.
 726   (and (pos-visible-in-window-p (point-max))
 727        (let ((buf (current-buffer))
 728              (bufname (buffer-name))
 729              (file (buffer-file-name)))
 730          (or (not view-try-extend-at-buffer-end)
 731              (null file)
 732              (verify-visited-file-modtime buf)
 733              (not (file-exists-p file))
 734              (when (buffer-modified-p buf)
 735                (setq file (file-name-nondirectory file))
 736                (not (yes-or-no-p
 737                      (format
 738                       "File %s changed on disk.  Discard your edits%s? "
 739                       file
 740                       (if (string= bufname file) ""
 741                         (concat " in " bufname))))))
 742              (progn
 743                (revert-buffer t t t)
 744                (pos-visible-in-window-p (point-max)))))))
 745
 746 (defun view-end-message ()
 747   ;; Tell that we are at end of buffer.
 748   (goto-char (point-max))
 749   (if view-return-to-alist
 750       (message "End of buffer.  Type %s to quit viewing."
 751                (substitute-command-keys
 752                 (if view-scroll-auto-exit "\\[View-scroll-page-forward]"
 753                   "\\[View-quit]")))
 754     (message "End of buffer")))
 755
 756 (defun View-scroll-page-forward (&optional lines)
 757   "Scroll \"page size\" or prefix LINES lines forward in View mode.
 758 Exit if end of text is visible and `view-scroll-auto-exit' is non-nil.
 759 \"page size\" is whole window full, or number of lines set by
 760 \\[View-scroll-page-forward-set-page-size] or
 761 \\[View-scroll-page-backward-set-page-size].
 762 If LINES is more than a window-full, only the last window-full is shown."
 763   (interactive "P")
 764   (view-scroll-lines lines nil view-page-size nil))
 765
 766 (defun View-scroll-page-backward (&optional lines)
 767   "Scroll \"page size\" or prefix LINES lines backward in View mode.
 768 See also `View-scroll-page-forward'."
 769   (interactive "P")
 770   (view-scroll-lines lines t view-page-size nil))
 771
 772 (defun View-scroll-page-forward-set-page-size (&optional lines)
 773   "Scroll forward LINES lines in View mode, setting the \"page size\".
 774 This is the number of lines which \\[View-scroll-page-forward] and
 775 \\[View-scroll-page-backward] scroll by default.
 776 If LINES is omitted or = 0, sets \"page size\" to window height and
 777 scrolls forward that much, otherwise scrolls forward LINES lines and sets
 778 \"page size\" to the minimum of window height and the absolute value of LINES.
 779 See also `View-scroll-page-forward'."
 780   (interactive "P")
 781   (view-scroll-lines lines nil
 782                      (setq view-page-size (view-page-size-default lines))
 783                      nil))
 784
 785 (defun View-scroll-page-backward-set-page-size (&optional lines)
 786   "Scroll backward prefix LINES lines in View mode, setting the \"page size\".
 787 See also `View-scroll-page-forward-set-page-size'."
 788   (interactive "P")
 789   (view-scroll-lines lines t
 790                      (setq view-page-size (view-page-size-default lines))
 791                      nil))
 792
 793 (defun View-scroll-line-forward (&optional lines)
 794   "Scroll forward one line (or prefix LINES lines) in View mode.
 795 See also `View-scroll-page-forward,' but note that scrolling is limited
 796 to minimum of LINES and one window-full."
 797   (interactive "P")
 798   (view-scroll-lines lines nil 1 t))
 799
 800 (defun View-scroll-line-backward (&optional lines)
 801   "Scroll backward one line (or prefix LINES lines) in View mode.
 802 See also `View-scroll-line-forward'."
 803   (interactive "P")
 804   (view-scroll-lines lines t 1 t))
 805
 806 (defun View-scroll-half-page-forward (&optional lines)
 807   "Scroll forward a \"half page\" (or prefix LINES) lines in View mode.
 808 If LINES is not omitted, the \"half page size\" is set to the minimum of
 809 window height and the absolute value of LINES.
 810 LINES=0 resets \"half page size\" to half window height."
 811   (interactive "P")
 812   (view-scroll-lines lines nil (view-set-half-page-size-default lines) t))
 813
 814 (defun View-scroll-half-page-backward (&optional lines)
 815   "Scroll backward a \"half page\" (or prefix LINES) lines in View mode.
 816 See also `View-scroll-half-page-forward'."
 817   (interactive "P")
 818   (view-scroll-lines lines t (view-set-half-page-size-default lines) t))
 819
 820 (defun View-revert-buffer-scroll-page-forward (&optional lines)
 821   "Scroll forward, reverting buffer if needed, in View mode.
 822 If buffer has not been changed and the corresponding file is newer, first
 823 revert the buffer, then scroll.
 824 This command is useful if you are viewing a changing file.
 825
 826 The prefix argument LINES says how many lines to scroll.
 827 If you don't specify a prefix argument, it uses the number of lines set by
 828 \\[View-scroll-page-forward-set-page-size] or
 829 \\[View-scroll-page-backward-set-page-size].
 830 If LINES is more than a window-full, only the last window-full is shown."
 831   (interactive "P")
 832   (let ((view-mode-auto-exit nil)
 833         (view-try-extend-at-buffer-end t))
 834     (view-scroll-lines lines nil view-page-size nil)))
 835
 836 (defun View-back-to-mark (&optional ignore)
 837   "Return to last mark set in View mode, else beginning of file.
 838 Display that line at the center of the window.
 839 This command pops the mark ring, so that successive
 840 invocations return to earlier marks."
 841   (interactive)
 842   (goto-char (or (mark t) (point-min)))
 843   (pop-mark)
 844   (view-recenter))
 845
 846 (defun View-search-regexp-forward (n regexp)
 847   "Search forward for first (or prefix Nth) occurrence of REGEXP in View mode.
 848
 849 Displays line found at center of window.  Sets mark at starting position and
 850 pushes mark ring.
 851
 852 Characters @ and ! are special at the beginning of REGEXP.  They modify
 853 the search rather than become part of the pattern searched for.
 854 @ means search all the buffer i.e. start search at the beginning of buffer.
 855 ! means search for a line that contains no match for the pattern.
 856 If REGEXP is empty or only consist of these control characters, then
 857 an earlier remembered REGEXP is used, otherwise REGEXP is remembered
 858 for use by later search commands.
 859
 860 The variable `view-highlight-face' controls the face that is used
 861 for highlighting the match that is found."
 862   (interactive "p\nsSearch forward (regexp): ")
 863   (view-search n regexp))
 864
 865 (defun View-search-regexp-backward (n regexp)
 866   "Search backward for first (or prefix Nth) occurrence of REGEXP in View mode.
 867
 868 Displays line found at center of window.  Sets mark at starting position and
 869 pushes mark ring.
 870
 871 Characters @ and ! are special at the beginning of REGEXP.  They modify
 872 the search rather than become part of the pattern searched for.
 873 @ means search all the buffer i.e. start search at the end of buffer.
 874 ! means search for a line that contains no match for the pattern.
 875 If REGEXP is empty or only consist of these control characters, then
 876 an earlier remembered REGEXP is used, otherwise REGEXP is remembered
 877 for use by later search commands.
 878
 879 The variable `view-highlight-face' controls the face that is used
 880 for highlighting the match that is found."
 881   (interactive "p\nsSearch backward (regexp): ")
 882   (view-search (- n) regexp))
 883
 884 (defun View-search-last-regexp-forward (n) "\
 885 Search forward for first (or prefix Nth) instance of last regexp in View mode.
 886 Displays line found at center of window.  Sets mark at starting position and
 887 pushes mark ring.
 888
 889 The variable `view-highlight-face' controls the face that is used
 890 for highlighting the match that is found."
 891   (interactive "p")
 892   (view-search n nil))
 893
 894 (defun View-search-last-regexp-backward (n) "\
 895 Search backward for first (or prefix Nth) instance of last regexp in View mode.
 896 Displays line found at center of window.  Sets mark at starting position and
 897 pushes mark ring.
 898
 899 The variable `view-highlight-face' controls the face that is used
 900 for highlighting the match that is found."
 901   (interactive "p")
 902   (view-search (- n) nil))
 903
 904 (defun view-search (times regexp)
 905   ;; This function does the job for all the View-search- commands.
 906   ;; Search for the TIMESt match for REGEXP. If TIMES is negative
 907   ;; search backwards. If REGEXP is nil use `view-last-regexp'.
 908   ;; Charcters "!" and "@" have a special meaning at the beginning of
 909   ;; REGEXP and are removed from REGEXP before the search "!" means
 910   ;; search for lines with no match for REGEXP.  "@" means search in
 911   ;; the whole buffer, don't start searching from the present point.
 912   (let (where no end ln)
 913     (cond
 914      ((and regexp (> (length regexp) 0)
 915            (or (not (memq (string-to-char regexp) '(?! ?@)))
 916                (progn
 917                  (if (member (substring regexp 0 2) '("!@" "@!"))
 918                      (setq end t no t ln 2)
 919                    (setq no (not (setq end (eq ?@ (string-to-char regexp))))
 920                          ln 1))
 921                  (> (length (setq regexp (substring regexp ln))) 0))))
 922       (setq view-last-regexp (if no (list regexp) regexp)))
 923      ((consp view-last-regexp)
 924       (setq regexp (car view-last-regexp))
 925       (unless (setq no (not no)) (setq view-last-regexp regexp)))
 926      (view-last-regexp (setq regexp view-last-regexp)
 927                        (if no (setq view-last-regexp (list regexp))))
 928      (t (error "No previous View-mode search")))
 929     (save-excursion
 930       (if end (goto-char (if (< times 0) (point-max) (point-min)))
 931         (move-to-window-line (if (< times 0) 0 -1)))
 932       (if (if no (view-search-no-match-lines times regexp)
 933             (re-search-forward regexp nil t times))
 934           (setq where (point))))
 935     (if where
 936         (progn
 937           (push-mark)
 938           (goto-char where)
 939           (if view-overlay
 940               (move-overlay view-overlay (match-beginning 0) (match-end 0))
 941             (setq view-overlay
 942                   (make-overlay (match-beginning 0) (match-end 0))))
 943           (overlay-put view-overlay 'face view-highlight-face)
 944           (beginning-of-line)
 945           (view-recenter))
 946       (message "Can't find occurrence %d of %s%s"
 947                times (if no "no " "") regexp)
 948       (sit-for 4))))
 949
 950 (defun view-search-no-match-lines (times regexp)
 951   ;; Search for the TIMESt occurrence of line with no match for REGEXP.
 952   (let ((back (and (< times 0) (setq times (- times)) -1))
 953         n)
 954     (while (> times 0)
 955       (save-excursion (beginning-of-line (if back (- times) (1+ times)))
 956                       (setq n (point)))
 957       (setq times
 958             (cond
 959              ((< (count-lines (point) n) times) -1) ; Not enough lines.
 960              ((or (null (re-search-forward regexp nil t back))
 961                   (if back (and (< (match-end 0) n)
 962                                 (> (count-lines (match-end 0) n) 1))
 963                     (and (< n (match-beginning 0))
 964                          (> (count-lines n (match-beginning 0)) 1))))
 965               0)                        ; No match within lines.
 966              (back (count-lines (max n (match-beginning 0)) (match-end 0)))
 967              (t (count-lines (match-beginning 0) (min n (match-end 0))))))
 968       (goto-char n))
 969     (and (zerop times) (looking-at "^.*$"))))
 970
 971
 972 (provide 'view)
 973
 974 ;;; view.el ends here