code.delx.au - gnu-emacs/blob - lisp/mail/emacsbug.el

   1 ;;; emacsbug.el --- command to report Emacs bugs to appropriate mailing list
   2
   3 ;; Copyright (C) 1985, 1994, 1997-1998, 2000-2015 Free Software
   4 ;; Foundation, Inc.
   5
   6 ;; Author: K. Shane Hartman
   7 ;; Maintainer: emacs-devel@gnu.org
   8 ;; Keywords: maint mail
   9 ;; Package: emacs
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25
  26 ;;; Commentary:
  27
  28 ;; `M-x report-emacs-bug' starts an email note to the Emacs maintainers
  29 ;; describing a problem.  You need to be able to send mail from Emacs
  30 ;; to complete the process.  Alternatively, compose the bug report in
  31 ;; Emacs then paste it into your normal mail client.
  32
  33 ;;; Code:
  34
  35 (require 'sendmail)
  36 (require 'message)
  37
  38 (defgroup emacsbug nil
  39   "Sending Emacs bug reports."
  40   :group 'maint
  41   :group 'mail)
  42
  43 (define-obsolete-variable-alias 'report-emacs-bug-pretest-address
  44   'report-emacs-bug-address "24.1")
  45
  46 (defcustom report-emacs-bug-address "bug-gnu-emacs@gnu.org"
  47   "Address of mailing list for GNU Emacs bugs."
  48   :group 'emacsbug
  49   :type 'string)
  50
  51 (defcustom report-emacs-bug-no-confirmation nil
  52   "If non-nil, suppress the confirmations asked for the sake of novice users."
  53   :group 'emacsbug
  54   :type 'boolean)
  55
  56 (defcustom report-emacs-bug-no-explanations nil
  57   "If non-nil, suppress the explanations given for the sake of novice users."
  58   :group 'emacsbug
  59   :type 'boolean)
  60
  61 ;; User options end here.
  62
  63 (defvar report-emacs-bug-orig-text nil
  64   "The automatically-created initial text of the bug report.")
  65
  66 (defvar report-emacs-bug-send-command nil
  67   "Name of the command to send the bug report, as a string.")
  68 (make-variable-buffer-local 'report-emacs-bug-send-command)
  69
  70 (defvar report-emacs-bug-send-hook nil
  71   "Hook run before sending the bug report.")
  72 (make-variable-buffer-local 'report-emacs-bug-send-hook)
  73
  74 (declare-function x-server-vendor "xfns.c" (&optional terminal))
  75 (declare-function x-server-version "xfns.c" (&optional terminal))
  76 (declare-function message-sort-headers "message" ())
  77 (defvar message-strip-special-text-properties)
  78
  79 (defun report-emacs-bug-can-use-osx-open ()
  80   "Return non-nil if the OS X \"open\" command is available for mailing."
  81   (and (featurep 'ns)
  82        (equal (executable-find "open") "/usr/bin/open")
  83        (memq system-type '(darwin))))
  84
  85 ;; FIXME this duplicates much of the logic from browse-url-can-use-xdg-open.
  86 (defun report-emacs-bug-can-use-xdg-email ()
  87   "Return non-nil if the \"xdg-email\" command can be used.
  88 xdg-email is a desktop utility that calls your preferred mail client.
  89 This requires you to be running either Gnome, KDE, or Xfce4."
  90   (and (getenv "DISPLAY")
  91        (executable-find "xdg-email")
  92        (or (getenv "GNOME_DESKTOP_SESSION_ID")
  93            ;; GNOME_DESKTOP_SESSION_ID is deprecated, check on Dbus also.
  94            (condition-case nil
  95                (eq 0 (call-process
  96                       "dbus-send" nil nil nil
  97                                   "--dest=org.gnome.SessionManager"
  98                                   "--print-reply"
  99                                   "/org/gnome/SessionManager"
 100                                   "org.gnome.SessionManager.CanShutdown"))
 101              (error nil))
 102            (equal (getenv "KDE_FULL_SESSION") "true")
 103            ;; FIXME? browse-url-can-use-xdg-open also accepts LXDE.
 104            ;; Is that no good here, or just overlooked?
 105            (condition-case nil
 106                (eq 0 (call-process
 107                       "/bin/sh" nil nil nil
 108                       "-c"
 109                       ;; FIXME use string-match rather than grep.
 110                       "xprop -root _DT_SAVE_MODE|grep xfce4"))
 111              (error nil)))))
 112
 113 (defun report-emacs-bug-insert-to-mailer ()
 114   "Send the message to your preferred mail client.
 115 This requires either the OS X \"open\" command, or the freedesktop
 116 \"xdg-email\" command to be available."
 117   (interactive)
 118   (save-excursion
 119     ;; FIXME? use mail-fetch-field?
 120     (let* ((to (progn
 121                  (goto-char (point-min))
 122                  (forward-line)
 123                  (and (looking-at "^To: \\(.*\\)")
 124                       (match-string-no-properties 1))))
 125            (subject (progn
 126                       (forward-line)
 127                       (and (looking-at "^Subject: \\(.*\\)")
 128                            (match-string-no-properties 1))))
 129            (body (progn
 130                    (forward-line 2)
 131                    (if (> (point-max) (point))
 132                        (buffer-substring-no-properties (point) (point-max))))))
 133       (if (and to subject body)
 134           (if (report-emacs-bug-can-use-osx-open)
 135               (start-process "/usr/bin/open" nil "open"
 136                              (concat "mailto:" to
 137                                      "?subject=" (url-hexify-string subject)
 138                                      "&body=" (url-hexify-string body)))
 139             (start-process "xdg-email" nil "xdg-email"
 140                            "--subject" subject
 141                            "--body" body
 142                            (concat "mailto:" to)))
 143         (error "Subject, To or body not found")))))
 144
 145 ;; It's the default mail mode, so it seems OK to use its features.
 146 (autoload 'message-bogus-recipient-p "message")
 147 (autoload 'message-make-address "message")
 148 (defvar message-send-mail-function)
 149 (defvar message-sendmail-envelope-from)
 150
 151 ;;;###autoload
 152 (defun report-emacs-bug (topic &optional unused)
 153   "Report a bug in GNU Emacs.
 154 Prompts for bug subject.  Leaves you in a mail buffer."
 155   (declare (advertised-calling-convention (topic) "24.5"))
 156   (interactive "sBug Subject: ")
 157   ;; The syntax `version;' is preferred to `[version]' because the
 158   ;; latter could be mistakenly stripped by mailing software.
 159   (if (eq system-type 'ms-dos)
 160       (setq topic (concat emacs-version "; " topic))
 161     (when (string-match "^\\(\\([.0-9]+\\)*\\)\\.[0-9]+$" emacs-version)
 162       (setq topic (concat (match-string 1 emacs-version) "; " topic))))
 163   (let ((from-buffer (current-buffer))
 164         (can-insert-mail (or (report-emacs-bug-can-use-xdg-email)
 165                              (report-emacs-bug-can-use-osx-open)))
 166         user-point message-end-point)
 167     (setq message-end-point
 168           (with-current-buffer (messages-buffer)
 169             (point-max-marker)))
 170     (compose-mail report-emacs-bug-address topic)
 171     ;; The rest of this does not execute if the user was asked to
 172     ;; confirm and said no.
 173     (when (eq major-mode 'message-mode)
 174       ;; Message-mode sorts the headers before sending.  We sort now so
 175       ;; that report-emacs-bug-orig-text remains valid.  (Bug#5178)
 176       (message-sort-headers)
 177       ;; Stop message-mode stealing the properties we will add.
 178       (set (make-local-variable 'message-strip-special-text-properties) nil)
 179       ;; Make sure we default to the From: address as envelope when sending
 180       ;; through sendmail.
 181       (when (and (not message-sendmail-envelope-from)
 182                  (message-bogus-recipient-p (message-make-address)))
 183         (set (make-local-variable 'message-sendmail-envelope-from) 'header)))
 184     (rfc822-goto-eoh)
 185     (forward-line 1)
 186     ;; Move the mail signature to the proper place.
 187     (let ((signature (buffer-substring (point) (point-max)))
 188           (inhibit-read-only t))
 189       (delete-region (point) (point-max))
 190       (insert signature)
 191       (backward-char (length signature)))
 192     (unless report-emacs-bug-no-explanations
 193       ;; Insert warnings for novice users.
 194       (if (not (equal "bug-gnu-emacs@gnu.org" report-emacs-bug-address))
 195           (insert (format "The report will be sent to %s.\n\n"
 196                           report-emacs-bug-address))
 197         (insert "This bug report will be sent to the ")
 198         (insert-text-button
 199          "Bug-GNU-Emacs"
 200          'face 'link
 201          'help-echo (concat "mouse-2, RET: Follow this link")
 202          'action (lambda (button)
 203                    (browse-url "http://lists.gnu.org/archive/html/bug-gnu-emacs/"))
 204          'follow-link t)
 205         (insert " mailing list\nand the GNU bug tracker at ")
 206         (insert-text-button
 207          "debbugs.gnu.org"
 208          'face 'link
 209          'help-echo (concat "mouse-2, RET: Follow this link")
 210          'action (lambda (button)
 211                    (browse-url "http://debbugs.gnu.org/"))
 212          'follow-link t)
 213
 214         (insert ".  Please check that
 215 the From: line contains a valid email address.  After a delay of up
 216 to one day, you should receive an acknowledgment at that address.
 217
 218 Please write in English if possible, as the Emacs maintainers
 219 usually do not have translators for other languages.\n\n")))
 220
 221     (insert "Please describe exactly what actions triggered the bug, and\n"
 222             "the precise symptoms of the bug.  If you can, give a recipe\n"
 223             "starting from `emacs -Q':\n\n")
 224     (let ((txt (delete-and-extract-region
 225                 (save-excursion (rfc822-goto-eoh) (line-beginning-position 2))
 226                 (point))))
 227       (insert (propertize "\n" 'display txt)))
 228     (setq user-point (point))
 229     (insert "\n\n")
 230
 231     (insert "If Emacs crashed, and you have the Emacs process in the gdb debugger,\n"
 232             "please include the output from the following gdb commands:\n"
 233             "    `bt full' and `xbacktrace'.\n")
 234
 235     (let ((debug-file (expand-file-name "DEBUG" data-directory)))
 236       (if (file-readable-p debug-file)
 237           (insert "For information about debugging Emacs, please read the file\n"
 238                   debug-file ".\n")))
 239     (let ((txt (delete-and-extract-region (1+ user-point) (point))))
 240       (insert (propertize "\n" 'display txt)))
 241
 242     (insert "\n\nIn " (emacs-version) "\n")
 243     (if (stringp emacs-repository-version)
 244         (insert "Repository revision: " emacs-repository-version "\n"))
 245     (if (fboundp 'x-server-vendor)
 246         (condition-case nil
 247             ;; This is used not only for X11 but also W32 and others.
 248             (insert "Windowing system distributor `" (x-server-vendor)
 249                     "', version "
 250                     (mapconcat 'number-to-string (x-server-version) ".") "\n")
 251           (error t)))
 252     (let ((lsb (with-temp-buffer
 253                  (if (eq 0 (ignore-errors
 254                              (call-process "lsb_release" nil '(t nil)
 255                                            nil "-d")))
 256                      (buffer-string)))))
 257       (if (stringp lsb)
 258           (insert "System " lsb "\n")))
 259     (when (and system-configuration-options
 260                (not (equal system-configuration-options "")))
 261       (insert "Configured using:\n `configure "
 262               system-configuration-options "'\n\n")
 263       (fill-region (line-beginning-position -1) (point)))
 264     (insert "Important settings:\n")
 265     (mapc
 266      (lambda (var)
 267        (let ((val (getenv var)))
 268          (if val (insert (format "  value of $%s: %s\n" var val)))))
 269      '("EMACSDATA" "EMACSDOC" "EMACSLOADPATH" "EMACSPATH"
 270        "LC_ALL" "LC_COLLATE" "LC_CTYPE" "LC_MESSAGES"
 271        "LC_MONETARY" "LC_NUMERIC" "LC_TIME" "LANG" "XMODIFIERS"))
 272     (insert (format "  locale-coding-system: %s\n" locale-coding-system))
 273     ;; Only ~ 0.2% of people from a sample of 3200 changed this from
 274     ;; the default, t.
 275     (or (default-value 'enable-multibyte-characters)
 276         (insert (format "  default enable-multibyte-characters: %s\n"
 277                         (default-value 'enable-multibyte-characters))))
 278     (insert "\n")
 279     (insert (format "Major mode: %s\n"
 280                     (format-mode-line
 281                      (buffer-local-value 'mode-name from-buffer)
 282                      nil nil from-buffer)))
 283     (insert "\n")
 284     (insert "Minor modes in effect:\n")
 285     (dolist (mode minor-mode-list)
 286       (and (boundp mode) (buffer-local-value mode from-buffer)
 287            (insert (format "  %s: %s\n" mode
 288                            (buffer-local-value mode from-buffer)))))
 289     (let ((message-buf (get-buffer "*Messages*")))
 290       (if message-buf
 291           (let (beg-pos
 292                 (end-pos message-end-point))
 293             (with-current-buffer message-buf
 294               (goto-char end-pos)
 295               (forward-line -10)
 296               (setq beg-pos (point)))
 297             (insert "\nRecent messages:\n")
 298             (insert-buffer-substring message-buf beg-pos end-pos))))
 299     ;; After Recent messages, to avoid the messages produced by
 300     ;; list-load-path-shadows.
 301     (unless (looking-back "\n")
 302       (insert "\n"))
 303     (insert "\n")
 304     (insert "Load-path shadows:\n")
 305     (let* ((msg "Checking for load-path shadows...")
 306            (result "done")
 307            (shadows (progn (message "%s" msg)
 308                            (condition-case nil (list-load-path-shadows t)
 309                              (error
 310                               (setq result "error")
 311                               "Error during checking")))))
 312       (message "%s%s" msg result)
 313       (insert (if (zerop (length shadows))
 314                   "None found.\n"
 315                 shadows)))
 316     (insert (format "\nFeatures:\n%s\n" features))
 317     (fill-region (line-beginning-position 0) (point))
 318
 319     (insert (format "\nMemory information:\n"))
 320     (pp (garbage-collect) (current-buffer))
 321
 322     ;; This is so the user has to type something in order to send easily.
 323     (use-local-map (nconc (make-sparse-keymap) (current-local-map)))
 324     (define-key (current-local-map) "\C-c\C-i" 'info-emacs-bug)
 325     (if can-insert-mail
 326         (define-key (current-local-map) "\C-c\M-i"
 327           'report-emacs-bug-insert-to-mailer))
 328     (setq report-emacs-bug-send-command (get mail-user-agent 'sendfunc)
 329           report-emacs-bug-send-hook (get mail-user-agent 'hookvar))
 330     (if report-emacs-bug-send-command
 331         (setq report-emacs-bug-send-command
 332               (symbol-name report-emacs-bug-send-command)))
 333     (unless report-emacs-bug-no-explanations
 334       (with-output-to-temp-buffer "*Bug Help*"
 335         (princ "While in the mail buffer:\n\n")
 336         (if report-emacs-bug-send-command
 337             (princ (substitute-command-keys
 338                     (format "  Type \\[%s] to send the bug report.\n"
 339                             report-emacs-bug-send-command))))
 340         (princ (substitute-command-keys
 341                 "  Type \\[kill-buffer] RET to cancel (don't send it).\n"))
 342         (if can-insert-mail
 343             (princ (substitute-command-keys
 344                     "  Type \\[report-emacs-bug-insert-to-mailer] to copy text to your preferred mail program.\n")))
 345         (terpri)
 346         (princ (substitute-command-keys
 347                 "  Type \\[info-emacs-bug] to visit in Info the Emacs Manual section
 348     about when and how to write a bug report, and what
 349     information you should include to help fix the bug.")))
 350       (shrink-window-if-larger-than-buffer (get-buffer-window "*Bug Help*")))
 351     ;; Make it less likely people will send empty messages.
 352     (if report-emacs-bug-send-hook
 353         (add-hook report-emacs-bug-send-hook 'report-emacs-bug-hook nil t))
 354     (goto-char (point-max))
 355     (skip-chars-backward " \t\n")
 356     (make-local-variable 'report-emacs-bug-orig-text)
 357     (setq report-emacs-bug-orig-text
 358           (buffer-substring-no-properties (point-min) (point)))
 359     (goto-char user-point)))
 360
 361 (define-obsolete-function-alias 'report-emacs-bug-info 'info-emacs-bug "24.3")
 362
 363 (defun report-emacs-bug-hook ()
 364   "Do some checking before sending a bug report."
 365   (save-excursion
 366     (goto-char (point-max))
 367     (skip-chars-backward " \t\n")
 368     (and (= (- (point) (point-min))
 369             (length report-emacs-bug-orig-text))
 370          (string-equal (buffer-substring-no-properties (point-min) (point))
 371                        report-emacs-bug-orig-text)
 372          (error "No text entered in bug report"))
 373     ;; Warning for novice users.
 374     (unless (or report-emacs-bug-no-confirmation
 375                 (yes-or-no-p
 376                  "Send this bug report to the Emacs maintainers? "))
 377       (goto-char (point-min))
 378       (if (search-forward "To: ")
 379           (delete-region (point) (line-end-position)))
 380       (if report-emacs-bug-send-hook
 381           (kill-local-variable report-emacs-bug-send-hook))
 382       (with-output-to-temp-buffer "*Bug Help*"
 383         (princ (substitute-command-keys
 384                 (format "\
 385 You invoked the command M-x report-emacs-bug,
 386 but you decided not to mail the bug report to the Emacs maintainers.
 387
 388 If you want to mail it to someone else instead,
 389 please insert the proper e-mail address after \"To: \",
 390 and send the mail again%s."
 391                         (if report-emacs-bug-send-command
 392                             (format " using \\[%s]"
 393                                     report-emacs-bug-send-command)
 394                           "")))))
 395       (error "M-x report-emacs-bug was canceled, please read *Bug Help* buffer"))
 396     ;; Query the user for the SMTP method, so that we can skip
 397     ;; questions about From header validity if the user is going to
 398     ;; use mailclient, anyway.
 399     (when (or (and (derived-mode-p 'message-mode)
 400                    (eq message-send-mail-function 'sendmail-query-once))
 401               (and (not (derived-mode-p 'message-mode))
 402                    (eq send-mail-function 'sendmail-query-once)))
 403       (sendmail-query-user-about-smtp)
 404       (when (derived-mode-p 'message-mode)
 405         (setq message-send-mail-function (message-default-send-mail-function))))
 406     (or report-emacs-bug-no-confirmation
 407         ;; mailclient.el does not need a valid From
 408         (if (derived-mode-p 'message-mode)
 409             (eq message-send-mail-function 'message-send-mail-with-mailclient)
 410           (eq send-mail-function 'mailclient-send-it))
 411         ;; Not narrowing to the headers, but that's OK.
 412         (let ((from (mail-fetch-field "From")))
 413           (and (or (not from)
 414                    (message-bogus-recipient-p from)
 415                    ;; This is the default user-mail-address.  On today's
 416                    ;; systems, it seems more likely to be wrong than right,
 417                    ;; since most people don't run their own mail server.
 418                    (string-match (format "\\<%s@%s\\>"
 419                                          (regexp-quote (user-login-name))
 420                                          (regexp-quote (system-name)))
 421                                  from))
 422                (not (yes-or-no-p
 423                      (format "Is `%s' really your email address? " from)))
 424                (error "Please edit the From address and try again"))))))
 425
 426
 427 (provide 'emacsbug)
 428
 429 ;;; emacsbug.el ends here