code.delx.au - gnu-emacs/blob - lisp/gnus/mm-decode.el

   1 ;;; mm-decode.el --- Functions for decoding MIME things
   2
   3 ;; Copyright (C) 1998, 1999, 2000, 2001, 2002, 2003, 2004,
   4 ;;   2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;;      MORIOKA Tomohiko <morioka@jaist.ac.jp>
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 ;; For Emacs < 22.2.
  30 (eval-and-compile
  31   (unless (fboundp 'declare-function) (defmacro declare-function (&rest r))))
  32
  33 (require 'mail-parse)
  34 (require 'mailcap)
  35 (require 'mm-bodies)
  36 (require 'gnus-util)
  37 (eval-when-compile (require 'cl)
  38                    (require 'term))
  39
  40 (eval-and-compile
  41   (autoload 'mm-inline-partial "mm-partial")
  42   (autoload 'mm-inline-external-body "mm-extern")
  43   (autoload 'mm-extern-cache-contents "mm-extern")
  44   (autoload 'mm-insert-inline "mm-view"))
  45
  46 (defvar gnus-current-window-configuration)
  47
  48 (add-hook 'gnus-exit-gnus-hook 'mm-destroy-postponed-undisplay-list)
  49
  50 (defgroup mime-display ()
  51   "Display of MIME in mail and news articles."
  52   :link '(custom-manual "(emacs-mime)Display Customization")
  53   :version "21.1"
  54   :group 'mail
  55   :group 'news
  56   :group 'multimedia)
  57
  58 (defgroup mime-security ()
  59   "MIME security in mail and news articles."
  60   :link '(custom-manual "(emacs-mime)Display Customization")
  61   :group 'mail
  62   :group 'news
  63   :group 'multimedia)
  64
  65 ;;; Convenience macros.
  66
  67 (defmacro mm-handle-buffer (handle)
  68   `(nth 0 ,handle))
  69 (defmacro mm-handle-type (handle)
  70   `(nth 1 ,handle))
  71 (defsubst mm-handle-media-type (handle)
  72   (if (stringp (car handle))
  73       (car handle)
  74     (car (mm-handle-type handle))))
  75 (defsubst mm-handle-media-supertype (handle)
  76   (car (split-string (mm-handle-media-type handle) "/")))
  77 (defsubst mm-handle-media-subtype (handle)
  78   (cadr (split-string (mm-handle-media-type handle) "/")))
  79 (defmacro mm-handle-encoding (handle)
  80   `(nth 2 ,handle))
  81 (defmacro mm-handle-undisplayer (handle)
  82   `(nth 3 ,handle))
  83 (defmacro mm-handle-set-undisplayer (handle function)
  84   `(setcar (nthcdr 3 ,handle) ,function))
  85 (defmacro mm-handle-disposition (handle)
  86   `(nth 4 ,handle))
  87 (defmacro mm-handle-description (handle)
  88   `(nth 5 ,handle))
  89 (defmacro mm-handle-cache (handle)
  90   `(nth 6 ,handle))
  91 (defmacro mm-handle-set-cache (handle contents)
  92   `(setcar (nthcdr 6 ,handle) ,contents))
  93 (defmacro mm-handle-id (handle)
  94   `(nth 7 ,handle))
  95 (defmacro mm-handle-multipart-original-buffer (handle)
  96   `(get-text-property 0 'buffer (car ,handle)))
  97 (defmacro mm-handle-multipart-from (handle)
  98   `(get-text-property 0 'from (car ,handle)))
  99 (defmacro mm-handle-multipart-ctl-parameter (handle parameter)
 100   `(get-text-property 0 ,parameter (car ,handle)))
 101
 102 (defmacro mm-make-handle (&optional buffer type encoding undisplayer
 103                                     disposition description cache
 104                                     id)
 105   `(list ,buffer ,type ,encoding ,undisplayer
 106          ,disposition ,description ,cache ,id))
 107
 108 (defcustom mm-text-html-renderer
 109   (cond ((executable-find "w3m")
 110          (if (locate-library "w3m")
 111              'w3m
 112            'w3m-standalone))
 113         ((executable-find "links") 'links)
 114         ((executable-find "lynx") 'lynx)
 115         ((locate-library "w3") 'w3)
 116         ((locate-library "html2text") 'html2text)
 117         (t nil))
 118   "Render of HTML contents.
 119 It is one of defined renderer types, or a rendering function.
 120 The defined renderer types are:
 121 `w3m'  : use emacs-w3m;
 122 `w3m-standalone': use w3m;
 123 `links': use links;
 124 `lynx' : use lynx;
 125 `w3'   : use Emacs/W3;
 126 `html2text' : use html2text;
 127 nil    : use external viewer (default web browser)."
 128   :version "23.0" ;; No Gnus
 129   :type '(choice (const w3)
 130                  (const w3m :tag "emacs-w3m")
 131                  (const w3m-standalone :tag "standalone w3m" )
 132                  (const links)
 133                  (const lynx)
 134                  (const html2text)
 135                  (const nil :tag "External viewer")
 136                  (function))
 137   :group 'mime-display)
 138
 139 (defvar mm-inline-text-html-renderer nil
 140   "Function used for rendering inline HTML contents.
 141 It is suggested to customize `mm-text-html-renderer' instead.")
 142
 143 (defcustom mm-inline-text-html-with-images nil
 144   "If non-nil, Gnus will allow retrieving images in HTML contents with
 145 the <img> tags.  It has no effect on Emacs/w3.  See also the
 146 documentation for the `mm-w3m-safe-url-regexp' variable."
 147   :version "22.1"
 148   :type 'boolean
 149   :group 'mime-display)
 150
 151 (defcustom mm-w3m-safe-url-regexp "\\`cid:"
 152   "Regexp matching URLs which are considered to be safe.
 153 Some HTML mails might contain a nasty trick used by spammers, using
 154 the <img> tag which is far more evil than the [Click Here!] button.
 155 It is most likely intended to check whether the ominous spam mail has
 156 reached your eyes or not, in which case the spammer knows for sure
 157 that your email address is valid.  It is done by embedding an
 158 identifier string into a URL that you might automatically retrieve
 159 when displaying the image.  The default value is \"\\\\`cid:\" which only
 160 matches parts embedded to the Multipart/Related type MIME contents and
 161 Gnus will never connect to the spammer's site arbitrarily.  You may
 162 set this variable to nil if you consider all urls to be safe."
 163   :version "22.1"
 164   :type '(choice (regexp :tag "Regexp")
 165                  (const :tag "All URLs are safe" nil))
 166   :group 'mime-display)
 167
 168 (defcustom mm-inline-text-html-with-w3m-keymap t
 169   "If non-nil, use emacs-w3m command keys in the article buffer."
 170   :version "22.1"
 171   :type 'boolean
 172   :group 'mime-display)
 173
 174 (defcustom mm-enable-external t
 175   "Indicate whether external MIME handlers should be used.
 176
 177 If t, all defined external MIME handlers are used.  If nil, files are saved by
 178 `mailcap-save-binary-file'.  If it is the symbol `ask', you are prompted
 179 before the external MIME handler is invoked."
 180   :version "22.1"
 181   :type '(choice (const :tag "Always" t)
 182                  (const :tag "Never" nil)
 183                  (const :tag "Ask" ask))
 184   :group 'mime-display)
 185
 186 (defcustom mm-inline-media-tests
 187   '(("image/p?jpeg"
 188      mm-inline-image
 189      (lambda (handle)
 190        (mm-valid-and-fit-image-p 'jpeg handle)))
 191     ("image/png"
 192      mm-inline-image
 193      (lambda (handle)
 194        (mm-valid-and-fit-image-p 'png handle)))
 195     ("image/gif"
 196      mm-inline-image
 197      (lambda (handle)
 198        (mm-valid-and-fit-image-p 'gif handle)))
 199     ("image/tiff"
 200      mm-inline-image
 201      (lambda (handle)
 202        (mm-valid-and-fit-image-p 'tiff handle)) )
 203     ("image/xbm"
 204      mm-inline-image
 205      (lambda (handle)
 206        (mm-valid-and-fit-image-p 'xbm handle)))
 207     ("image/x-xbitmap"
 208      mm-inline-image
 209      (lambda (handle)
 210        (mm-valid-and-fit-image-p 'xbm handle)))
 211     ("image/xpm"
 212      mm-inline-image
 213      (lambda (handle)
 214        (mm-valid-and-fit-image-p 'xpm handle)))
 215     ("image/x-xpixmap"
 216      mm-inline-image
 217      (lambda (handle)
 218        (mm-valid-and-fit-image-p 'xpm handle)))
 219     ("image/bmp"
 220      mm-inline-image
 221      (lambda (handle)
 222        (mm-valid-and-fit-image-p 'bmp handle)))
 223     ("image/x-portable-bitmap"
 224      mm-inline-image
 225      (lambda (handle)
 226        (mm-valid-and-fit-image-p 'pbm handle)))
 227     ("text/plain" mm-inline-text identity)
 228     ("text/enriched" mm-inline-text identity)
 229     ("text/richtext" mm-inline-text identity)
 230     ("text/x-patch" mm-display-patch-inline
 231      (lambda (handle)
 232        ;; If the diff-mode.el package is installed, the function is
 233        ;; autoloaded.  Checking (locate-library "diff-mode") would be trying
 234        ;; to cater to broken installations.  OTOH checking the function
 235        ;; makes it possible to install another package which provides an
 236        ;; alternative implementation of diff-mode.  --Stef
 237        (fboundp 'diff-mode)))
 238     ;; In case mime.types uses x-diff (as does Debian's mime-support-3.40).
 239     ("text/x-diff" mm-display-patch-inline
 240      (lambda (handle) (fboundp 'diff-mode)))
 241     ("application/emacs-lisp" mm-display-elisp-inline identity)
 242     ("application/x-emacs-lisp" mm-display-elisp-inline identity)
 243     ("text/dns" mm-display-dns-inline identity)
 244     ("text/html"
 245      mm-inline-text-html
 246      (lambda (handle)
 247        (or mm-inline-text-html-renderer
 248            mm-text-html-renderer)))
 249     ("text/x-vcard"
 250      mm-inline-text-vcard
 251      (lambda (handle)
 252        (or (featurep 'vcard)
 253            (locate-library "vcard"))))
 254     ("message/delivery-status" mm-inline-text identity)
 255     ("message/rfc822" mm-inline-message identity)
 256     ("message/partial" mm-inline-partial identity)
 257     ("message/external-body" mm-inline-external-body identity)
 258     ("text/.*" mm-inline-text identity)
 259     ("audio/wav" mm-inline-audio
 260      (lambda (handle)
 261        (and (or (featurep 'nas-sound) (featurep 'native-sound))
 262             (device-sound-enabled-p))))
 263     ("audio/au"
 264      mm-inline-audio
 265      (lambda (handle)
 266        (and (or (featurep 'nas-sound) (featurep 'native-sound))
 267             (device-sound-enabled-p))))
 268     ("application/pgp-signature" ignore identity)
 269     ("application/x-pkcs7-signature" ignore identity)
 270     ("application/pkcs7-signature" ignore identity)
 271     ("application/x-pkcs7-mime" ignore identity)
 272     ("application/pkcs7-mime" ignore identity)
 273     ("multipart/alternative" ignore identity)
 274     ("multipart/mixed" ignore identity)
 275     ("multipart/related" ignore identity)
 276     ;; Disable audio and image
 277     ("audio/.*" ignore ignore)
 278     ("image/.*" ignore ignore)
 279     ;; Default to displaying as text
 280     (".*" mm-inline-text mm-readable-p))
 281   "Alist of media types/tests saying whether types can be displayed inline."
 282   :type '(repeat (list (regexp :tag "MIME type")
 283                        (function :tag "Display function")
 284                        (function :tag "Display test")))
 285   :group 'mime-display)
 286
 287 (defcustom mm-inlined-types
 288   '("image/.*" "text/.*" "message/delivery-status" "message/rfc822"
 289     "message/partial" "message/external-body" "application/emacs-lisp"
 290     "application/x-emacs-lisp"
 291     "application/pgp-signature" "application/x-pkcs7-signature"
 292     "application/pkcs7-signature" "application/x-pkcs7-mime"
 293     "application/pkcs7-mime"
 294     ;; Mutt still uses this even though it has already been withdrawn.
 295     "application/pgp")
 296   "List of media types that are to be displayed inline.
 297 See also `mm-inline-media-tests', which says how to display a media
 298 type inline."
 299   :type '(repeat regexp)
 300   :group 'mime-display)
 301
 302 (defcustom mm-keep-viewer-alive-types
 303   '("application/postscript" "application/msword" "application/vnd.ms-excel"
 304     "application/pdf" "application/x-dvi")
 305   "List of media types for which the external viewer will not be killed
 306 when selecting a different article."
 307   :version "22.1"
 308   :type '(repeat regexp)
 309   :group 'mime-display)
 310
 311 (defcustom mm-automatic-display
 312   '("text/plain" "text/enriched" "text/richtext" "text/html" "text/x-verbatim"
 313     "text/x-vcard" "image/.*" "message/delivery-status" "multipart/.*"
 314     "message/rfc822" "text/x-patch" "text/dns" "application/pgp-signature"
 315     "application/emacs-lisp" "application/x-emacs-lisp"
 316     "application/x-pkcs7-signature"
 317     "application/pkcs7-signature" "application/x-pkcs7-mime"
 318     "application/pkcs7-mime"
 319     ;; Mutt still uses this even though it has already been withdrawn.
 320     "application/pgp\\'")
 321   "A list of MIME types to be displayed automatically."
 322   :type '(repeat regexp)
 323   :group 'mime-display)
 324
 325 (defcustom mm-attachment-override-types '("text/x-vcard"
 326                                           "application/pkcs7-mime"
 327                                           "application/x-pkcs7-mime"
 328                                           "application/pkcs7-signature"
 329                                           "application/x-pkcs7-signature")
 330   "Types to have \"attachment\" ignored if they can be displayed inline."
 331   :type '(repeat regexp)
 332   :group 'mime-display)
 333
 334 (defcustom mm-inline-override-types nil
 335   "Types to be treated as attachments even if they can be displayed inline."
 336   :type '(repeat regexp)
 337   :group 'mime-display)
 338
 339 (defcustom mm-automatic-external-display nil
 340   "List of MIME type regexps that will be displayed externally automatically."
 341   :type '(repeat regexp)
 342   :group 'mime-display)
 343
 344 (defcustom mm-discouraged-alternatives nil
 345   "List of MIME types that are discouraged when viewing multipart/alternative.
 346 Viewing agents are supposed to view the last possible part of a message,
 347 as that is supposed to be the richest.  However, users may prefer other
 348 types instead, and this list says what types are most unwanted.  If,
 349 for instance, text/html parts are very unwanted, and text/richtext are
 350 somewhat unwanted, then the value of this variable should be set
 351 to:
 352
 353  (\"text/html\" \"text/richtext\")
 354
 355 Adding \"image/.*\" might also be useful.  Spammers use it as the
 356 prefered part of multipart/alternative messages.  See also
 357 `gnus-buttonized-mime-types', to which adding \"multipart/alternative\"
 358 enables you to choose manually one of two types those mails include."
 359   :type '(repeat regexp) ;; See `mm-preferred-alternative-precedence'.
 360   :group 'mime-display)
 361
 362 (defcustom mm-tmp-directory
 363   (if (fboundp 'temp-directory)
 364       (temp-directory)
 365     (if (boundp 'temporary-file-directory)
 366         temporary-file-directory
 367       "/tmp/"))
 368   "Where mm will store its temporary files."
 369   :type 'directory
 370   :group 'mime-display)
 371
 372 (defcustom mm-inline-large-images nil
 373   "If non-nil, then all images fit in the buffer."
 374   :type 'boolean
 375   :group 'mime-display)
 376
 377 (defcustom mm-file-name-rewrite-functions
 378   '(mm-file-name-delete-control mm-file-name-delete-gotchas)
 379   "List of functions used for rewriting file names of MIME parts.
 380 Each function takes a file name as input and returns a file name.
 381
 382 Ready-made functions include `mm-file-name-delete-control',
 383 `mm-file-name-delete-gotchas' (you should not remove these two
 384 functions), `mm-file-name-delete-whitespace',
 385 `mm-file-name-trim-whitespace', `mm-file-name-collapse-whitespace',
 386 `mm-file-name-replace-whitespace', `capitalize', `downcase',
 387 `upcase', and `upcase-initials'."
 388   :type '(list (set :inline t
 389                     (const mm-file-name-delete-control)
 390                     (const mm-file-name-delete-gotchas)
 391                     (const mm-file-name-delete-whitespace)
 392                     (const mm-file-name-trim-whitespace)
 393                     (const mm-file-name-collapse-whitespace)
 394                     (const mm-file-name-replace-whitespace)
 395                     (const capitalize)
 396                     (const downcase)
 397                     (const upcase)
 398                     (const upcase-initials)
 399                (repeat :inline t
 400                        :tag "Function"
 401                        function)))
 402   :version "23.1" ;; No Gnus
 403   :group 'mime-display)
 404
 405
 406 (defvar mm-path-name-rewrite-functions nil
 407   "*List of functions for rewriting the full file names of MIME parts.
 408 This is used when viewing parts externally, and is meant for
 409 transforming the absolute name so that non-compliant programs can find
 410 the file where it's saved.
 411
 412 Each function takes a file name as input and returns a file name.")
 413
 414 (defvar mm-file-name-replace-whitespace nil
 415   "String used for replacing whitespace characters; default is `\"_\"'.")
 416
 417 (defcustom mm-default-directory nil
 418   "The default directory where mm will save files.
 419 If not set, `default-directory' will be used."
 420   :type '(choice directory (const :tag "Default" nil))
 421   :group 'mime-display)
 422
 423 (defcustom mm-attachment-file-modes 384
 424   "Set the mode bits of saved attachments to this integer."
 425   :version "22.1"
 426   :type 'integer
 427   :group 'mime-display)
 428
 429 (defcustom mm-external-terminal-program "xterm"
 430   "The program to start an external terminal."
 431   :version "22.1"
 432   :type 'string
 433   :group 'mime-display)
 434
 435 ;;; Internal variables.
 436
 437 (defvar mm-last-shell-command "")
 438 (defvar mm-content-id-alist nil)
 439 (defvar mm-postponed-undisplay-list nil)
 440
 441 ;; According to RFC2046, in particular, in a digest, the default
 442 ;; Content-Type value for a body part is changed from "text/plain" to
 443 ;; "message/rfc822".
 444 (defvar mm-dissect-default-type "text/plain")
 445
 446 (autoload 'mml2015-verify "mml2015")
 447 (autoload 'mml2015-verify-test "mml2015")
 448 (autoload 'mml-smime-verify "mml-smime")
 449 (autoload 'mml-smime-verify-test "mml-smime")
 450
 451 (defvar mm-verify-function-alist
 452   '(("application/pgp-signature" mml2015-verify "PGP" mml2015-verify-test)
 453     ("application/x-gnus-pgp-signature" mm-uu-pgp-signed-extract-1 "PGP"
 454      mm-uu-pgp-signed-test)
 455     ("application/pkcs7-signature" mml-smime-verify "S/MIME"
 456      mml-smime-verify-test)
 457     ("application/x-pkcs7-signature" mml-smime-verify "S/MIME"
 458      mml-smime-verify-test)))
 459
 460 (defcustom mm-verify-option 'never
 461   "Option of verifying signed parts.
 462 `never', not verify; `always', always verify;
 463 `known', only verify known protocols.  Otherwise, ask user.
 464
 465 When set to `always' or `known', you should add
 466 \"multipart/signed\" to `gnus-buttonized-mime-types' to see
 467 result of the verification."
 468   :version "22.1"
 469   :type '(choice (item always)
 470                  (item never)
 471                  (item :tag "only known protocols" known)
 472                  (item :tag "ask" nil))
 473   :group 'mime-security)
 474
 475 (autoload 'mml2015-decrypt "mml2015")
 476 (autoload 'mml2015-decrypt-test "mml2015")
 477
 478 (defvar mm-decrypt-function-alist
 479   '(("application/pgp-encrypted" mml2015-decrypt "PGP" mml2015-decrypt-test)
 480     ("application/x-gnus-pgp-encrypted" mm-uu-pgp-encrypted-extract-1 "PGP"
 481      mm-uu-pgp-encrypted-test)))
 482
 483 (defcustom mm-decrypt-option nil
 484   "Option of decrypting encrypted parts.
 485 `never', not decrypt; `always', always decrypt;
 486 `known', only decrypt known protocols.  Otherwise, ask user."
 487   :version "22.1"
 488   :type '(choice (item always)
 489                  (item never)
 490                  (item :tag "only known protocols" known)
 491                  (item :tag "ask" nil))
 492   :group 'mime-security)
 493
 494 (defvar mm-viewer-completion-map
 495   (let ((map (make-sparse-keymap 'mm-viewer-completion-map)))
 496     (set-keymap-parent map minibuffer-local-completion-map)
 497     ;; Should we bind other key to minibuffer-complete-word?
 498     (define-key map " " 'self-insert-command)
 499     map)
 500   "Keymap for input viewer with completion.")
 501
 502 (defvar mm-viewer-completion-map
 503   (let ((map (make-sparse-keymap 'mm-viewer-completion-map)))
 504     (set-keymap-parent map minibuffer-local-completion-map)
 505     ;; Should we bind other key to minibuffer-complete-word?
 506     (define-key map " " 'self-insert-command)
 507     map)
 508   "Keymap for input viewer with completion.")
 509
 510 ;;; The functions.
 511
 512 (defun mm-alist-to-plist (alist)
 513   "Convert association list ALIST into the equivalent property-list form.
 514 The plist is returned.  This converts from
 515
 516 \((a . 1) (b . 2) (c . 3))
 517
 518 into
 519
 520 \(a 1 b 2 c 3)
 521
 522 The original alist is not modified.  See also `destructive-alist-to-plist'."
 523   (let (plist)
 524     (while alist
 525       (let ((el (car alist)))
 526         (setq plist (cons (cdr el) (cons (car el) plist))))
 527       (setq alist (cdr alist)))
 528     (nreverse plist)))
 529
 530 (defun mm-keep-viewer-alive-p (handle)
 531   "Say whether external viewer for HANDLE should stay alive."
 532   (let ((types mm-keep-viewer-alive-types)
 533         (type (mm-handle-media-type handle))
 534         ty)
 535     (catch 'found
 536       (while (setq ty (pop types))
 537         (when (string-match ty type)
 538           (throw 'found t))))))
 539
 540 (defun mm-handle-set-external-undisplayer (handle function)
 541   "Set the undisplayer for HANDLE to FUNCTION.
 542 Postpone undisplaying of viewers for types in
 543 `mm-keep-viewer-alive-types'."
 544   (if (mm-keep-viewer-alive-p handle)
 545       (let ((new-handle (copy-sequence handle)))
 546         (mm-handle-set-undisplayer new-handle function)
 547         (mm-handle-set-undisplayer handle nil)
 548         (push new-handle mm-postponed-undisplay-list))
 549     (mm-handle-set-undisplayer handle function)))
 550
 551 (defun mm-destroy-postponed-undisplay-list ()
 552   (when mm-postponed-undisplay-list
 553     (message "Destroying external MIME viewers")
 554     (mm-destroy-parts mm-postponed-undisplay-list)))
 555
 556 (defun mm-dissect-buffer (&optional no-strict-mime loose-mime from)
 557   "Dissect the current buffer and return a list of MIME handles."
 558   (save-excursion
 559     (let (ct ctl type subtype cte cd description id result)
 560       (save-restriction
 561         (mail-narrow-to-head)
 562         (when (or no-strict-mime
 563                   loose-mime
 564                   (mail-fetch-field "mime-version"))
 565           (setq ct (mail-fetch-field "content-type")
 566                 ctl (and ct (mail-header-parse-content-type ct))
 567                 cte (mail-fetch-field "content-transfer-encoding")
 568                 cd (mail-fetch-field "content-disposition")
 569                 description (mail-fetch-field "content-description")
 570                 id (mail-fetch-field "content-id"))
 571           (unless from
 572             (setq from (mail-fetch-field "from")))
 573           ;; FIXME: In some circumstances, this code is running within
 574           ;; an unibyte macro.  mail-extract-address-components
 575           ;; creates unibyte buffers. This `if', though not a perfect
 576           ;; solution, avoids most of them.
 577           (if from
 578               (setq from (cadr (mail-extract-address-components from))))
 579           (if description
 580               (setq description (mail-decode-encoded-word-string
 581                                  description)))))
 582       (if (or (not ctl)
 583               (not (string-match "/" (car ctl))))
 584           (mm-dissect-singlepart
 585            (list mm-dissect-default-type)
 586            (and cte (intern (downcase (mail-header-strip cte))))
 587            no-strict-mime
 588            (and cd (mail-header-parse-content-disposition cd))
 589            description)
 590         (setq type (split-string (car ctl) "/"))
 591         (setq subtype (cadr type)
 592               type (car type))
 593         (setq
 594          result
 595          (cond
 596           ((equal type "multipart")
 597            (let ((mm-dissect-default-type (if (equal subtype "digest")
 598                                               "message/rfc822"
 599                                             "text/plain"))
 600                  (start (cdr (assq 'start (cdr ctl)))))
 601              (add-text-properties 0 (length (car ctl))
 602                                   (mm-alist-to-plist (cdr ctl)) (car ctl))
 603
 604              ;; what really needs to be done here is a way to link a
 605              ;; MIME handle back to it's parent MIME handle (in a multilevel
 606              ;; MIME article).  That would probably require changing
 607              ;; the mm-handle API so we simply store the multipart buffer
 608              ;; name as a text property of the "multipart/whatever" string.
 609              (add-text-properties 0 (length (car ctl))
 610                                   (list 'buffer (mm-copy-to-buffer)
 611                                         'from from
 612                                         'start start)
 613                                   (car ctl))
 614              (cons (car ctl) (mm-dissect-multipart ctl from))))
 615           (t
 616            (mm-possibly-verify-or-decrypt
 617             (mm-dissect-singlepart
 618              ctl
 619              (and cte (intern (downcase (mail-header-strip cte))))
 620              no-strict-mime
 621              (and cd (mail-header-parse-content-disposition cd))
 622              description id)
 623             ctl))))
 624         (when id
 625           (when (string-match " *<\\(.*\\)> *" id)
 626             (setq id (match-string 1 id)))
 627           (push (cons id result) mm-content-id-alist))
 628         result))))
 629
 630 (defun mm-dissect-singlepart (ctl cte &optional force cdl description id)
 631   (when (or force
 632             (if (equal "text/plain" (car ctl))
 633                 (assoc 'format ctl)
 634               t))
 635     (mm-make-handle
 636      (mm-copy-to-buffer) ctl cte nil cdl description nil id)))
 637
 638 (defun mm-dissect-multipart (ctl from)
 639   (goto-char (point-min))
 640   (let* ((boundary (concat "\n--" (mail-content-type-get ctl 'boundary)))
 641          (close-delimiter (concat (regexp-quote boundary) "--[ \t]*$"))
 642          start parts
 643          (end (save-excursion
 644                 (goto-char (point-max))
 645                 (if (re-search-backward close-delimiter nil t)
 646                     (match-beginning 0)
 647                   (point-max)))))
 648     (setq boundary (concat (regexp-quote boundary) "[ \t]*$"))
 649     (while (and (< (point) end) (re-search-forward boundary end t))
 650       (goto-char (match-beginning 0))
 651       (when start
 652         (save-excursion
 653           (save-restriction
 654             (narrow-to-region start (point))
 655             (setq parts (nconc (list (mm-dissect-buffer t nil from)) parts)))))
 656       (end-of-line 2)
 657       (or (looking-at boundary)
 658           (forward-line 1))
 659       (setq start (point)))
 660     (when (and start (< start end))
 661       (save-excursion
 662         (save-restriction
 663           (narrow-to-region start end)
 664           (setq parts (nconc (list (mm-dissect-buffer t nil from)) parts)))))
 665     (mm-possibly-verify-or-decrypt (nreverse parts) ctl)))
 666
 667 (defun mm-copy-to-buffer ()
 668   "Copy the contents of the current buffer to a fresh buffer."
 669   (let ((obuf (current-buffer))
 670         (mb (mm-multibyte-p))
 671         beg)
 672     (goto-char (point-min))
 673     (search-forward-regexp "^\n" nil t)
 674     (setq beg (point))
 675     (with-current-buffer
 676           (generate-new-buffer " *mm*")
 677       ;; Preserve the data's unibyteness (for url-insert-file-contents).
 678       (mm-set-buffer-multibyte mb)
 679       (insert-buffer-substring obuf beg)
 680       (current-buffer))))
 681
 682 (defun mm-display-parts (handle &optional no-default)
 683   (if (stringp (car handle))
 684       (mapcar 'mm-display-parts (cdr handle))
 685     (if (bufferp (car handle))
 686         (save-restriction
 687           (narrow-to-region (point) (point))
 688           (mm-display-part handle)
 689           (goto-char (point-max)))
 690       (mapcar 'mm-display-parts handle))))
 691
 692 (defun mm-display-part (handle &optional no-default)
 693   "Display the MIME part represented by HANDLE.
 694 Returns nil if the part is removed; inline if displayed inline;
 695 external if displayed external."
 696   (save-excursion
 697     (mailcap-parse-mailcaps)
 698     (if (mm-handle-displayed-p handle)
 699         (mm-remove-part handle)
 700       (let* ((ehandle (if (equal (mm-handle-media-type handle)
 701                                  "message/external-body")
 702                           (progn
 703                             (unless (mm-handle-cache handle)
 704                               (mm-extern-cache-contents handle))
 705                             (mm-handle-cache handle))
 706                         handle))
 707              (type (mm-handle-media-type ehandle))
 708              (method (mailcap-mime-info type))
 709              (filename (or (mail-content-type-get
 710                             (mm-handle-disposition handle) 'filename)
 711                            (mail-content-type-get
 712                             (mm-handle-type handle) 'name)
 713                            "<file>"))
 714              (external mm-enable-external))
 715         (if (and (mm-inlinable-p ehandle)
 716                  (mm-inlined-p ehandle))
 717             (progn
 718               (forward-line 1)
 719               (mm-display-inline handle)
 720               'inline)
 721           (when (or method
 722                     (not no-default))
 723             (if (and (not method)
 724                      (equal "text" (car (split-string type "/"))))
 725                 (progn
 726                   (forward-line 1)
 727                   (mm-insert-inline handle (mm-get-part handle))
 728                   'inline)
 729               (setq external
 730                     (and method ;; If nil, we always use "save".
 731                        (stringp method) ;; 'mailcap-save-binary-file
 732                        (or (eq mm-enable-external t)
 733                            (and (eq mm-enable-external 'ask)
 734                                 (y-or-n-p
 735                                  (concat
 736                                   "Display part (" type
 737                                   ") using external program"
 738                                   ;; Can non-string method ever happen?
 739                                   (if (stringp method)
 740                                       (concat
 741                                        " \"" (format method filename) "\"")
 742                                     "")
 743                                     "? "))))))
 744               (if external
 745                   (mm-display-external
 746                    handle (or method 'mailcap-save-binary-file))
 747                 (mm-display-external
 748                  handle 'mailcap-save-binary-file)))))))))
 749
 750 (declare-function gnus-configure-windows "gnus-win" (setting &optional force))
 751
 752 (defun mm-display-external (handle method)
 753   "Display HANDLE using METHOD."
 754   (let ((outbuf (current-buffer)))
 755     (mm-with-unibyte-buffer
 756       (if (functionp method)
 757           (let ((cur (current-buffer)))
 758             (if (eq method 'mailcap-save-binary-file)
 759                 (progn
 760                   (set-buffer (generate-new-buffer " *mm*"))
 761                   (setq method nil))
 762               (mm-insert-part handle)
 763               (mm-add-meta-html-tag handle)
 764               (let ((win (get-buffer-window cur t)))
 765                 (when win
 766                   (select-window win)))
 767               (switch-to-buffer (generate-new-buffer " *mm*")))
 768             (buffer-disable-undo)
 769             (mm-set-buffer-file-coding-system mm-binary-coding-system)
 770             (insert-buffer-substring cur)
 771             (goto-char (point-min))
 772             (when method
 773               (message "Viewing with %s" method))
 774             (let ((mm (current-buffer))
 775                   (non-viewer (assq 'non-viewer
 776                                     (mailcap-mime-info
 777                                      (mm-handle-media-type handle) t))))
 778               (unwind-protect
 779                   (if method
 780                       (funcall method)
 781                     (mm-save-part handle))
 782                 (when (and (not non-viewer)
 783                            method)
 784                   (mm-handle-set-undisplayer handle mm)))))
 785         ;; The function is a string to be executed.
 786         (mm-insert-part handle)
 787         (mm-add-meta-html-tag handle)
 788         (let* ((dir (mm-make-temp-file
 789                      (expand-file-name "emm." mm-tmp-directory) 'dir))
 790                (filename (or
 791                           (mail-content-type-get
 792                            (mm-handle-disposition handle) 'filename)
 793                           (mail-content-type-get
 794                            (mm-handle-type handle) 'name)))
 795                (mime-info (mailcap-mime-info
 796                            (mm-handle-media-type handle) t))
 797                (needsterm (or (assoc "needsterm" mime-info)
 798                               (assoc "needsterminal" mime-info)))
 799                (copiousoutput (assoc "copiousoutput" mime-info))
 800                file buffer)
 801           ;; We create a private sub-directory where we store our files.
 802           (set-file-modes dir 448)
 803           (if filename
 804               (setq file (expand-file-name
 805                           (gnus-map-function mm-file-name-rewrite-functions
 806                                              (file-name-nondirectory filename))
 807                           dir))
 808             ;; Use nametemplate (defined in RFC1524) if it is specified
 809             ;; in mailcap.
 810             (let ((suffix (cdr (assoc "nametemplate" mime-info))))
 811               (if (and suffix
 812                        (string-match "\\`%s\\(\\..+\\)\\'" suffix))
 813                   (setq suffix (match-string 1 suffix))
 814                 ;; Otherwise, use a suffix according to
 815                 ;; `mailcap-mime-extensions'.
 816                 (setq suffix (car (rassoc (mm-handle-media-type handle)
 817                                           mailcap-mime-extensions))))
 818               (setq file (mm-make-temp-file (expand-file-name "mm." dir)
 819                                             nil suffix))))
 820           (let ((coding-system-for-write mm-binary-coding-system))
 821             (write-region (point-min) (point-max) file nil 'nomesg))
 822           (message "Viewing with %s" method)
 823           (cond
 824            (needsterm
 825             (let ((command (mm-mailcap-command
 826                             method file (mm-handle-type handle))))
 827               (unwind-protect
 828                   (if window-system
 829                       (start-process "*display*" nil
 830                                      mm-external-terminal-program
 831                                      "-e" shell-file-name
 832                                      shell-command-switch command)
 833                     (require 'term)
 834                     (require 'gnus-win)
 835                     (set-buffer
 836                      (setq buffer
 837                            (make-term "display"
 838                                       shell-file-name
 839                                       nil
 840                                       shell-command-switch command)))
 841                     (term-mode)
 842                     (term-char-mode)
 843                     (set-process-sentinel
 844                      (get-buffer-process buffer)
 845                      `(lambda (process state)
 846                         (if (eq 'exit (process-status process))
 847                             (gnus-configure-windows
 848                              ',gnus-current-window-configuration))))
 849                     (gnus-configure-windows 'display-term))
 850                 (mm-handle-set-external-undisplayer handle (cons file buffer)))
 851               (message "Displaying %s..." command))
 852             'external)
 853            (copiousoutput
 854             (with-current-buffer outbuf
 855               (forward-line 1)
 856               (mm-insert-inline
 857                handle
 858                (unwind-protect
 859                    (progn
 860                      (call-process shell-file-name nil
 861                                    (setq buffer
 862                                          (generate-new-buffer " *mm*"))
 863                                    nil
 864                                    shell-command-switch
 865                                    (mm-mailcap-command
 866                                     method file (mm-handle-type handle)))
 867                      (if (buffer-live-p buffer)
 868                          (with-current-buffer buffer
 869                            (buffer-string))))
 870                  (progn
 871                    (ignore-errors (delete-file file))
 872                    (ignore-errors (delete-directory
 873                                    (file-name-directory file)))
 874                    (ignore-errors (kill-buffer buffer))))))
 875             'inline)
 876            (t
 877             ;; Deleting the temp file should be postponed for some wrappers,
 878             ;; shell scripts, and so on, which might exit right after having
 879             ;; started a viewer command as a background job.
 880             (let ((command (mm-mailcap-command
 881                             method file (mm-handle-type handle))))
 882               (unwind-protect
 883                   (progn
 884                     (start-process "*display*"
 885                                    (setq buffer
 886                                          (generate-new-buffer " *mm*"))
 887                                    shell-file-name
 888                                    shell-command-switch command)
 889                     (set-process-sentinel
 890                      (get-buffer-process buffer)
 891                      (lexical-let ;; Don't use `let'.
 892                          ;; Function used to remove temp file and directory.
 893                          ((fn `(lambda nil
 894                                  ;; Don't use `ignore-errors'.
 895                                  (condition-case nil
 896                                      (delete-file ,file)
 897                                    (error))
 898                                  (condition-case nil
 899                                      (delete-directory
 900                                       ,(file-name-directory file))
 901                                    (error))))
 902                           ;; Form uses to kill the process buffer and
 903                           ;; remove the undisplayer.
 904                           (fm `(progn
 905                                  (kill-buffer ,buffer)
 906                                  ,(macroexpand
 907                                    (list 'mm-handle-set-undisplayer
 908                                          (list 'quote handle)
 909                                          nil))))
 910                           ;; Message to be issued when the process exits.
 911                           (done (format "Displaying %s...done" command))
 912                           ;; In particular, the timer object (which is
 913                           ;; a vector in Emacs but is a list in XEmacs)
 914                           ;; requires that it is lexically scoped.
 915                           (timer (run-at-time 2.0 nil 'ignore)))
 916                        (if (featurep 'xemacs)
 917                            (lambda (process state)
 918                              (when (eq 'exit (process-status process))
 919                                (if (memq timer itimer-list)
 920                                    (set-itimer-function timer fn)
 921                                  (funcall fn))
 922                                (ignore-errors (eval fm))
 923                                (message "%s" done)))
 924                          (lambda (process state)
 925                            (when (eq 'exit (process-status process))
 926                              (if (memq timer timer-list)
 927                                  (timer-set-function timer fn)
 928                                (funcall fn))
 929                              (ignore-errors (eval fm))
 930                              (message "%s" done)))))))
 931                 (mm-handle-set-external-undisplayer
 932                  handle (cons file buffer)))
 933               (message "Displaying %s..." command))
 934             'external)))))))
 935
 936 (defun mm-mailcap-command (method file type-list)
 937   (let ((ctl (cdr type-list))
 938         (beg 0)
 939         (uses-stdin t)
 940         out sub total)
 941     (while (string-match "%{\\([^}]+\\)}\\|'%s'\\|\"%s\"\\|%s\\|%t\\|%%"
 942                          method beg)
 943       (push (substring method beg (match-beginning 0)) out)
 944       (setq beg (match-end 0)
 945             total (match-string 0 method)
 946             sub (match-string 1 method))
 947       (cond
 948        ((string= total "%%")
 949         (push "%" out))
 950        ((or (string= total "%s")
 951             ;; We do our own quoting.
 952             (string= total "'%s'")
 953             (string= total "\"%s\""))
 954         (setq uses-stdin nil)
 955         (push (shell-quote-argument
 956                (gnus-map-function mm-path-name-rewrite-functions file)) out))
 957        ((string= total "%t")
 958         (push (shell-quote-argument (car type-list)) out))
 959        (t
 960         (push (shell-quote-argument (or (cdr (assq (intern sub) ctl)) "")) out))))
 961     (push (substring method beg (length method)) out)
 962     (when uses-stdin
 963       (push "<" out)
 964       (push (shell-quote-argument
 965              (gnus-map-function mm-path-name-rewrite-functions file))
 966             out))
 967     (mapconcat 'identity (nreverse out) "")))
 968
 969 (defun mm-remove-parts (handles)
 970   "Remove the displayed MIME parts represented by HANDLES."
 971   (if (and (listp handles)
 972            (bufferp (car handles)))
 973       (mm-remove-part handles)
 974     (let (handle)
 975       (while (setq handle (pop handles))
 976         (cond
 977          ((stringp handle)
 978           (when (buffer-live-p (get-text-property 0 'buffer handle))
 979             (kill-buffer (get-text-property 0 'buffer handle))))
 980          ((and (listp handle)
 981                (stringp (car handle)))
 982           (mm-remove-parts (cdr handle)))
 983          (t
 984           (mm-remove-part handle)))))))
 985
 986 (defun mm-destroy-parts (handles)
 987   "Remove the displayed MIME parts represented by HANDLES."
 988   (if (and (listp handles)
 989            (bufferp (car handles)))
 990       (mm-destroy-part handles)
 991     (let (handle)
 992       (while (setq handle (pop handles))
 993         (cond
 994          ((stringp handle)
 995           (when (buffer-live-p (get-text-property 0 'buffer handle))
 996             (kill-buffer (get-text-property 0 'buffer handle))))
 997          ((and (listp handle)
 998                (stringp (car handle)))
 999           (mm-destroy-parts handle))
1000          (t
1001           (mm-destroy-part handle)))))))
1002
1003 (defun mm-remove-part (handle)
1004   "Remove the displayed MIME part represented by HANDLE."
1005   (when (listp handle)
1006     (let ((object (mm-handle-undisplayer handle)))
1007       (ignore-errors
1008         (cond
1009          ;; Internally displayed part.
1010          ((mm-annotationp object)
1011           (if (featurep 'xemacs)
1012               (delete-annotation object)))
1013          ((or (functionp object)
1014               (and (listp object)
1015                    (eq (car object) 'lambda)))
1016           (funcall object))
1017          ;; Externally displayed part.
1018          ((consp object)
1019           (condition-case ()
1020               (while (get-buffer-process (cdr object))
1021                 (interrupt-process (get-buffer-process (cdr object)))
1022                 (message "Waiting for external displayer to die...")
1023                 (sit-for 1))
1024             (quit)
1025             (error))
1026           (ignore-errors (and (cdr object) (kill-buffer (cdr object))))
1027           (message "Waiting for external displayer to die...done")
1028           (ignore-errors (delete-file (car object)))
1029           (ignore-errors (delete-directory (file-name-directory
1030                                             (car object)))))
1031          ((bufferp object)
1032           (when (buffer-live-p object)
1033             (kill-buffer object)))))
1034       (mm-handle-set-undisplayer handle nil))))
1035
1036 (defun mm-display-inline (handle)
1037   (let* ((type (mm-handle-media-type handle))
1038          (function (cadr (mm-assoc-string-match mm-inline-media-tests type))))
1039     (funcall function handle)
1040     (goto-char (point-min))))
1041
1042 (defun mm-assoc-string-match (alist type)
1043   (dolist (elem alist)
1044     (when (string-match (car elem) type)
1045       (return elem))))
1046
1047 (defun mm-automatic-display-p (handle)
1048   "Say whether the user wants HANDLE to be displayed automatically."
1049   (let ((methods mm-automatic-display)
1050         (type (mm-handle-media-type handle))
1051         method result)
1052     (while (setq method (pop methods))
1053       (when (and (not (mm-inline-override-p handle))
1054                  (string-match method type))
1055         (setq result t
1056               methods nil)))
1057     result))
1058
1059 (defun mm-inlinable-p (handle &optional type)
1060   "Say whether HANDLE can be displayed inline.
1061 TYPE is the mime-type of the object; it defaults to the one given
1062 in HANDLE."
1063   (unless type (setq type (mm-handle-media-type handle)))
1064   (let ((alist mm-inline-media-tests)
1065         test)
1066     (while alist
1067       (when (string-match (caar alist) type)
1068         (setq test (caddar alist)
1069               alist nil)
1070         (setq test (funcall test handle)))
1071       (pop alist))
1072     test))
1073
1074 (defun mm-inlined-p (handle)
1075   "Say whether the user wants HANDLE to be displayed inline."
1076   (let ((methods mm-inlined-types)
1077         (type (mm-handle-media-type handle))
1078         method result)
1079     (while (setq method (pop methods))
1080       (when (and (not (mm-inline-override-p handle))
1081                  (string-match method type))
1082         (setq result t
1083               methods nil)))
1084     result))
1085
1086 (defun mm-attachment-override-p (handle)
1087   "Say whether HANDLE should have attachment behavior overridden."
1088   (let ((types mm-attachment-override-types)
1089         (type (mm-handle-media-type handle))
1090         ty)
1091     (catch 'found
1092       (while (setq ty (pop types))
1093         (when (and (string-match ty type)
1094                    (mm-inlinable-p handle))
1095           (throw 'found t))))))
1096
1097 (defun mm-inline-override-p (handle)
1098   "Say whether HANDLE should have inline behavior overridden."
1099   (let ((types mm-inline-override-types)
1100         (type (mm-handle-media-type handle))
1101         ty)
1102     (catch 'found
1103       (while (setq ty (pop types))
1104         (when (string-match ty type)
1105           (throw 'found t))))))
1106
1107 (defun mm-automatic-external-display-p (type)
1108   "Return the user-defined method for TYPE."
1109   (let ((methods mm-automatic-external-display)
1110         method result)
1111     (while (setq method (pop methods))
1112       (when (string-match method type)
1113         (setq result t
1114               methods nil)))
1115     result))
1116
1117 (defun mm-destroy-part (handle)
1118   "Destroy the data structures connected to HANDLE."
1119   (when (listp handle)
1120     (mm-remove-part handle)
1121     (when (buffer-live-p (mm-handle-buffer handle))
1122       (kill-buffer (mm-handle-buffer handle)))))
1123
1124 (defun mm-handle-displayed-p (handle)
1125   "Say whether HANDLE is displayed or not."
1126   (mm-handle-undisplayer handle))
1127
1128 ;;;
1129 ;;; Functions for outputting parts
1130 ;;;
1131
1132 (defmacro mm-with-part (handle &rest forms)
1133   "Run FORMS in the temp buffer containing the contents of HANDLE."
1134   ;; The handle-buffer's content is a sequence of bytes, not a sequence of
1135   ;; chars, so the buffer should be unibyte.  It may happen that the
1136   ;; handle-buffer is multibyte for some reason, in which case now is a good
1137   ;; time to adjust it, since we know at this point that it should
1138   ;; be unibyte.
1139   `(let* ((handle ,handle))
1140      (with-temp-buffer
1141        (mm-disable-multibyte)
1142        (insert-buffer-substring (mm-handle-buffer handle))
1143        (mm-decode-content-transfer-encoding
1144         (mm-handle-encoding handle)
1145         (mm-handle-media-type handle))
1146        ,@forms)))
1147 (put 'mm-with-part 'lisp-indent-function 1)
1148 (put 'mm-with-part 'edebug-form-spec '(body))
1149
1150 (defun mm-get-part (handle &optional no-cache)
1151   "Return the contents of HANDLE as a string.
1152 If NO-CACHE is non-nil, cached contents of a message/external-body part
1153 are ignored."
1154   (if (and (not no-cache)
1155            (equal (mm-handle-media-type handle) "message/external-body"))
1156       (progn
1157         (unless (mm-handle-cache handle)
1158           (mm-extern-cache-contents handle))
1159         (with-current-buffer (mm-handle-buffer (mm-handle-cache handle))
1160           (buffer-string)))
1161     (mm-with-part handle
1162       (buffer-string))))
1163
1164 (defun mm-insert-part (handle &optional no-cache)
1165   "Insert the contents of HANDLE in the current buffer.
1166 If NO-CACHE is non-nil, cached contents of a message/external-body part
1167 are ignored."
1168   (let ((text (cond ((eq (mail-content-type-get (mm-handle-type handle)
1169                                                 'charset)
1170                          'gnus-decoded)
1171                      (with-current-buffer (mm-handle-buffer handle)
1172                        (buffer-string)))
1173                     ((mm-multibyte-p)
1174                      (mm-string-to-multibyte (mm-get-part handle no-cache)))
1175                     (t
1176                      (mm-get-part handle no-cache)))))
1177     (save-restriction
1178       (widen)
1179       (goto-char
1180        (prog1
1181            (point)
1182          (if (and (eq (get-char-property (max (point-min) (1- (point))) 'face)
1183                       'mm-uu-extract)
1184                   (eq (get-char-property 0 'face text) 'mm-uu-extract))
1185              ;; Separate the extracted parts that have the same faces.
1186              (insert "\n" text)
1187            (insert text)))))))
1188
1189 (defun mm-file-name-delete-whitespace (file-name)
1190   "Remove all whitespace characters from FILE-NAME."
1191   (while (string-match "\\s-+" file-name)
1192     (setq file-name (replace-match "" t t file-name)))
1193   file-name)
1194
1195 (defun mm-file-name-trim-whitespace (file-name)
1196   "Remove leading and trailing whitespace characters from FILE-NAME."
1197   (when (string-match "\\`\\s-+" file-name)
1198     (setq file-name (substring file-name (match-end 0))))
1199   (when (string-match "\\s-+\\'" file-name)
1200     (setq file-name (substring file-name 0 (match-beginning 0))))
1201   file-name)
1202
1203 (defun mm-file-name-collapse-whitespace (file-name)
1204   "Collapse multiple whitespace characters in FILE-NAME."
1205   (while (string-match "\\s-\\s-+" file-name)
1206     (setq file-name (replace-match " " t t file-name)))
1207   file-name)
1208
1209 (defun mm-file-name-replace-whitespace (file-name)
1210   "Replace whitespace characters in FILE-NAME with underscores.
1211 Set the option `mm-file-name-replace-whitespace' to any other
1212 string if you do not like underscores."
1213   (let ((s (or mm-file-name-replace-whitespace "_")))
1214     (while (string-match "\\s-" file-name)
1215       (setq file-name (replace-match s t t file-name))))
1216   file-name)
1217
1218 (defun mm-file-name-delete-control (filename)
1219   "Delete control characters from FILENAME."
1220   (gnus-replace-in-string filename "[\x00-\x1f\x7f]" ""))
1221
1222 (defun mm-file-name-delete-gotchas (filename)
1223   "Delete shell gotchas from FILENAME."
1224   (setq filename (gnus-replace-in-string filename "[<>|]" ""))
1225   (gnus-replace-in-string filename "^[.-]+" ""))
1226
1227 (defun mm-save-part (handle &optional prompt)
1228   "Write HANDLE to a file.
1229 PROMPT overrides the default one used to ask user for a file name."
1230   (let ((filename (or (mail-content-type-get
1231                        (mm-handle-disposition handle) 'filename)
1232                       (mail-content-type-get
1233                        (mm-handle-type handle) 'name)))
1234         file)
1235     (when filename
1236       (setq filename (gnus-map-function mm-file-name-rewrite-functions
1237                                         (file-name-nondirectory filename))))
1238     (setq file
1239           (read-file-name (or prompt "Save MIME part to: ")
1240                           (or mm-default-directory default-directory)
1241                           nil nil (or filename "")))
1242     (setq mm-default-directory (file-name-directory file))
1243     (and (or (not (file-exists-p file))
1244              (yes-or-no-p (format "File %s already exists; overwrite? "
1245                                   file)))
1246          (progn
1247            (mm-save-part-to-file handle file)
1248            file))))
1249
1250 (defun mm-add-meta-html-tag (handle &optional charset)
1251   "Add meta html tag to specify CHARSET of HANDLE in the current buffer.
1252 CHARSET defaults to the one HANDLE specifies.  Existing meta tag that
1253 specifies charset will not be modified.  Return t if meta tag is added
1254 or replaced."
1255   (when (equal (mm-handle-media-type handle) "text/html")
1256     (when (or charset
1257               (setq charset (mail-content-type-get (mm-handle-type handle)
1258                                                    'charset)))
1259       (setq charset (format "\
1260 <meta http-equiv=\"Content-Type\" content=\"text/html; charset=%s\">" charset))
1261       (let ((case-fold-search t))
1262         (goto-char (point-min))
1263         (if (re-search-forward "\
1264 <meta\\s-+http-equiv=[\"']?content-type[\"']?\\s-+content=[\"']\
1265 text/\\(\\sw+\\)\\(?:\;\\s-*charset=\\(.+?\\)\\)?[\"'][^>]*>" nil t)
1266             (if (and (match-beginning 2)
1267                      (string-match "\\`html\\'" (match-string 1)))
1268                 ;; Don't modify existing meta tag.
1269                 nil
1270               ;; Replace it with the one specifying charset.
1271               (replace-match charset)
1272               t)
1273           (if (re-search-forward "<head>\\s-*" nil t)
1274               (insert charset "\n")
1275             (re-search-forward "<html\\(?:\\s-+[^>]+\\|\\s-*\\)>\\s-*" nil t)
1276             (insert "<head>\n" charset "\n</head>\n"))
1277           t)))))
1278
1279 (defun mm-save-part-to-file (handle file)
1280   (mm-with-unibyte-buffer
1281     (mm-insert-part handle)
1282     (mm-add-meta-html-tag handle)
1283     (let ((current-file-modes (default-file-modes)))
1284       (set-default-file-modes mm-attachment-file-modes)
1285       (unwind-protect
1286           ;; Don't re-compress .gz & al.  Arguably we should make
1287           ;; `file-name-handler-alist' nil, but that would chop
1288           ;; ange-ftp, which is reasonable to use here.
1289           (mm-write-region (point-min) (point-max) file nil nil nil 'binary t)
1290         (set-default-file-modes current-file-modes)))))
1291
1292 (defun mm-pipe-part (handle)
1293   "Pipe HANDLE to a process."
1294   (let* ((name (mail-content-type-get (mm-handle-type handle) 'name))
1295          (command
1296           (read-string "Shell command on MIME part: " mm-last-shell-command)))
1297     (mm-with-unibyte-buffer
1298       (mm-insert-part handle)
1299       (mm-add-meta-html-tag handle)
1300       (let ((coding-system-for-write 'binary))
1301         (shell-command-on-region (point-min) (point-max) command nil)))))
1302
1303 (defun mm-interactively-view-part (handle)
1304   "Display HANDLE using METHOD."
1305   (let* ((type (mm-handle-media-type handle))
1306          (methods
1307           (mapcar (lambda (i) (list (cdr (assoc 'viewer i))))
1308                   (mailcap-mime-info type 'all)))
1309          (method (let ((minibuffer-local-completion-map
1310                         mm-viewer-completion-map))
1311                    (completing-read "Viewer: " methods))))
1312     (when (string= method "")
1313       (error "No method given"))
1314     (if (string-match "^[^% \t]+$" method)
1315         (setq method (concat method " %s")))
1316     (mm-display-external handle method)))
1317
1318 (defun mm-preferred-alternative (handles &optional preferred)
1319   "Say which of HANDLES are preferred."
1320   (let ((prec (if preferred (list preferred)
1321                 (mm-preferred-alternative-precedence handles)))
1322         p h result type handle)
1323     (while (setq p (pop prec))
1324       (setq h handles)
1325       (while h
1326         (setq handle (car h))
1327         (setq type (mm-handle-media-type handle))
1328         (when (and (equal p type)
1329                    (mm-automatic-display-p handle)
1330                    (or (stringp (car handle))
1331                        (not (mm-handle-disposition handle))
1332                        (equal (car (mm-handle-disposition handle))
1333                               "inline")))
1334           (setq result handle
1335                 h nil
1336                 prec nil))
1337         (pop h)))
1338     result))
1339
1340 (defun mm-preferred-alternative-precedence (handles)
1341   "Return the precedence based on HANDLES and `mm-discouraged-alternatives'."
1342   (let ((seq (nreverse (mapcar #'mm-handle-media-type
1343                                handles))))
1344     (dolist (disc (reverse mm-discouraged-alternatives))
1345       (dolist (elem (copy-sequence seq))
1346         (when (string-match disc elem)
1347           (setq seq (nconc (delete elem seq) (list elem))))))
1348     seq))
1349
1350 (defun mm-get-content-id (id)
1351   "Return the handle(s) referred to by ID."
1352   (cdr (assoc id mm-content-id-alist)))
1353
1354 (defconst mm-image-type-regexps
1355   '(("/\\*.*XPM.\\*/" . xpm)
1356     ("P[1-6]" . pbm)
1357     ("GIF8" . gif)
1358     ("\377\330" . jpeg)
1359     ("\211PNG\r\n" . png)
1360     ("#define" . xbm)
1361     ("\\(MM\0\\*\\)\\|\\(II\\*\0\\)" . tiff)
1362     ("%!PS" . postscript))
1363   "Alist of (REGEXP . IMAGE-TYPE) pairs used to auto-detect image types.
1364 When the first bytes of an image file match REGEXP, it is assumed to
1365 be of image type IMAGE-TYPE.")
1366
1367 ;; Steal from image.el. image-type-from-data suffers multi-line matching bug.
1368 (defun mm-image-type-from-buffer ()
1369   "Determine the image type from data in the current buffer.
1370 Value is a symbol specifying the image type or nil if type cannot
1371 be determined."
1372   (let ((types mm-image-type-regexps)
1373         type)
1374     (goto-char (point-min))
1375     (while (and types (null type))
1376       (let ((regexp (car (car types)))
1377             (image-type (cdr (car types))))
1378         (when (looking-at regexp)
1379           (setq type image-type))
1380         (setq types (cdr types))))
1381     type))
1382
1383 (defun mm-get-image (handle)
1384   "Return an image instance based on HANDLE."
1385   (let ((type (mm-handle-media-subtype handle))
1386         spec)
1387     ;; Allow some common translations.
1388     (setq type
1389           (cond
1390            ((equal type "x-pixmap")
1391             "xpm")
1392            ((equal type "x-xbitmap")
1393             "xbm")
1394            ((equal type "x-portable-bitmap")
1395             "pbm")
1396            (t type)))
1397     (or (mm-handle-cache handle)
1398         (mm-with-unibyte-buffer
1399           (mm-insert-part handle)
1400           (prog1
1401               (setq spec
1402                     (ignore-errors
1403                       ;; Avoid testing `make-glyph' since W3 may define
1404                       ;; a bogus version of it.
1405                       (if (fboundp 'create-image)
1406                           (create-image (buffer-string)
1407                                         (or (mm-image-type-from-buffer)
1408                                             (intern type))
1409                                         'data-p)
1410                         (mm-create-image-xemacs type))))
1411             (mm-handle-set-cache handle spec))))))
1412
1413 (defun mm-create-image-xemacs (type)
1414   (when (featurep 'xemacs)
1415     (cond
1416      ((equal type "xbm")
1417       ;; xbm images require special handling, since
1418       ;; the only way to create glyphs from these
1419       ;; (without a ton of work) is to write them
1420       ;; out to a file, and then create a file
1421       ;; specifier.
1422       (let ((file (mm-make-temp-file
1423                    (expand-file-name "emm" mm-tmp-directory)
1424                    nil ".xbm")))
1425         (unwind-protect
1426             (progn
1427               (write-region (point-min) (point-max) file)
1428               (make-glyph (list (cons 'x file))))
1429           (ignore-errors
1430             (delete-file file)))))
1431      (t
1432       (make-glyph
1433        (vector
1434         (or (mm-image-type-from-buffer)
1435             (intern type))
1436         :data (buffer-string)))))))
1437
1438 (defun mm-image-fit-p (handle)
1439   "Say whether the image in HANDLE will fit the current window."
1440   (let ((image (mm-get-image handle)))
1441     (or (not image)
1442         (if (featurep 'xemacs)
1443             ;; XEmacs' glyphs can actually tell us about their width, so
1444             ;; lets be nice and smart about them.
1445             (or mm-inline-large-images
1446                 (and (<= (glyph-width image) (window-pixel-width))
1447                      (<= (glyph-height image) (window-pixel-height))))
1448           (let* ((size (image-size image))
1449                  (w (car size))
1450                  (h (cdr size)))
1451             (or mm-inline-large-images
1452                 (and (<= h (1- (window-height))) ; Don't include mode line.
1453                      (<= w (window-width)))))))))
1454
1455 (defun mm-valid-image-format-p (format)
1456   "Say whether FORMAT can be displayed natively by Emacs."
1457   (cond
1458    ;; Handle XEmacs
1459    ((fboundp 'valid-image-instantiator-format-p)
1460     (valid-image-instantiator-format-p format))
1461    ;; Handle Emacs 21
1462    ((fboundp 'image-type-available-p)
1463     (and (display-graphic-p)
1464          (image-type-available-p format)))
1465    ;; Nobody else can do images yet.
1466    (t
1467     nil)))
1468
1469 (defun mm-valid-and-fit-image-p (format handle)
1470   "Say whether FORMAT can be displayed natively and HANDLE fits the window."
1471   (and (mm-valid-image-format-p format)
1472        (mm-image-fit-p handle)))
1473
1474 (defun mm-find-part-by-type (handles type &optional notp recursive)
1475   "Search in HANDLES for part with TYPE.
1476 If NOTP, returns first non-matching part.
1477 If RECURSIVE, search recursively."
1478   (let (handle)
1479     (while handles
1480       (if (and recursive (stringp (caar handles)))
1481           (if (setq handle (mm-find-part-by-type (cdar handles) type
1482                                                  notp recursive))
1483               (setq handles nil))
1484         (if (if notp
1485                 (not (equal (mm-handle-media-type (car handles)) type))
1486               (equal (mm-handle-media-type (car handles)) type))
1487             (setq handle (car handles)
1488                   handles nil)))
1489       (setq handles (cdr handles)))
1490     handle))
1491
1492 (defun mm-find-raw-part-by-type (ctl type &optional notp)
1493   (goto-char (point-min))
1494   (let* ((boundary (concat "--" (mm-handle-multipart-ctl-parameter ctl
1495                                                                    'boundary)))
1496          (close-delimiter (concat "^" (regexp-quote boundary) "--[ \t]*$"))
1497          start
1498          (end (save-excursion
1499                 (goto-char (point-max))
1500                 (if (re-search-backward close-delimiter nil t)
1501                     (match-beginning 0)
1502                   (point-max))))
1503          result)
1504     (setq boundary (concat "^" (regexp-quote boundary) "[ \t]*$"))
1505     (while (and (not result)
1506                 (re-search-forward boundary end t))
1507       (goto-char (match-beginning 0))
1508       (when start
1509         (save-excursion
1510           (save-restriction
1511             (narrow-to-region start (1- (point)))
1512             (when (let* ((ct (mail-fetch-field "content-type"))
1513                          (ctl (and ct (mail-header-parse-content-type ct))))
1514                     (if notp
1515                         (not (equal (car ctl) type))
1516                       (equal (car ctl) type)))
1517               (setq result (buffer-string))))))
1518       (forward-line 1)
1519       (setq start (point)))
1520     (when (and (not result) start)
1521       (save-excursion
1522         (save-restriction
1523           (narrow-to-region start end)
1524           (when (let* ((ct (mail-fetch-field "content-type"))
1525                        (ctl (and ct (mail-header-parse-content-type ct))))
1526                   (if notp
1527                       (not (equal (car ctl) type))
1528                     (equal (car ctl) type)))
1529             (setq result (buffer-string))))))
1530     result))
1531
1532 (defvar mm-security-handle nil)
1533
1534 (defsubst mm-set-handle-multipart-parameter (handle parameter value)
1535   ;; HANDLE could be a CTL.
1536   (when handle
1537     (put-text-property 0 (length (car handle)) parameter value
1538                        (car handle))))
1539
1540 (autoload 'mm-view-pkcs7 "mm-view")
1541
1542 (defun mm-possibly-verify-or-decrypt (parts ctl)
1543   (let ((type (car ctl))
1544         (subtype (cadr (split-string (car ctl) "/")))
1545         (mm-security-handle ctl) ;; (car CTL) is the type.
1546         protocol func functest)
1547     (cond
1548      ((or (equal type "application/x-pkcs7-mime")
1549           (equal type "application/pkcs7-mime"))
1550       (with-temp-buffer
1551         (when (and (cond
1552                     ((eq mm-decrypt-option 'never) nil)
1553                     ((eq mm-decrypt-option 'always) t)
1554                     ((eq mm-decrypt-option 'known) t)
1555                     (t (y-or-n-p
1556                         (format "Decrypt (S/MIME) part? "))))
1557                    (mm-view-pkcs7 parts))
1558           (setq parts (mm-dissect-buffer t)))))
1559      ((equal subtype "signed")
1560       (unless (and (setq protocol
1561                          (mm-handle-multipart-ctl-parameter ctl 'protocol))
1562                    (not (equal protocol "multipart/mixed")))
1563         ;; The message is broken or draft-ietf-openpgp-multsig-01.
1564         (let ((protocols mm-verify-function-alist))
1565           (while protocols
1566             (if (and (or (not (setq functest (nth 3 (car protocols))))
1567                          (funcall functest parts ctl))
1568                      (mm-find-part-by-type parts (caar protocols) nil t))
1569                 (setq protocol (caar protocols)
1570                       protocols nil)
1571               (setq protocols (cdr protocols))))))
1572       (setq func (nth 1 (assoc protocol mm-verify-function-alist)))
1573       (when (cond
1574              ((eq mm-verify-option 'never) nil)
1575              ((eq mm-verify-option 'always) t)
1576              ((eq mm-verify-option 'known)
1577               (and func
1578                    (or (not (setq functest
1579                                   (nth 3 (assoc protocol
1580                                                 mm-verify-function-alist))))
1581                        (funcall functest parts ctl))))
1582              (t
1583               (y-or-n-p
1584                (format "Verify signed (%s) part? "
1585                        (or (nth 2 (assoc protocol mm-verify-function-alist))
1586                            (format "protocol=%s" protocol))))))
1587         (save-excursion
1588           (if func
1589               (setq parts (funcall func parts ctl))
1590             (mm-set-handle-multipart-parameter
1591              mm-security-handle 'gnus-details
1592              (format "Unknown sign protocol (%s)" protocol))))))
1593      ((equal subtype "encrypted")
1594       (unless (setq protocol
1595                     (mm-handle-multipart-ctl-parameter ctl 'protocol))
1596         ;; The message is broken.
1597         (let ((parts parts))
1598           (while parts
1599             (if (assoc (mm-handle-media-type (car parts))
1600                        mm-decrypt-function-alist)
1601                 (setq protocol (mm-handle-media-type (car parts))
1602                       parts nil)
1603               (setq parts (cdr parts))))))
1604       (setq func (nth 1 (assoc protocol mm-decrypt-function-alist)))
1605       (when (cond
1606              ((eq mm-decrypt-option 'never) nil)
1607              ((eq mm-decrypt-option 'always) t)
1608              ((eq mm-decrypt-option 'known)
1609               (and func
1610                    (or (not (setq functest
1611                                   (nth 3 (assoc protocol
1612                                                 mm-decrypt-function-alist))))
1613                        (funcall functest parts ctl))))
1614              (t
1615               (y-or-n-p
1616                (format "Decrypt (%s) part? "
1617                        (or (nth 2 (assoc protocol mm-decrypt-function-alist))
1618                            (format "protocol=%s" protocol))))))
1619         (save-excursion
1620           (if func
1621               (setq parts (funcall func parts ctl))
1622             (mm-set-handle-multipart-parameter
1623              mm-security-handle 'gnus-details
1624              (format "Unknown encrypt protocol (%s)" protocol))))))
1625      (t nil))
1626     parts))
1627
1628 (defun mm-multiple-handles (handles)
1629   (and (listp handles)
1630        (> (length handles) 1)
1631        (or (listp (car handles))
1632            (stringp (car handles)))))
1633
1634 (defun mm-complicated-handles (handles)
1635   (and (listp (car handles))
1636        (> (length handles) 1)))
1637
1638 (defun mm-merge-handles (handles1 handles2)
1639   (append
1640    (if (listp (car handles1))
1641        handles1
1642      (list handles1))
1643    (if (listp (car handles2))
1644        handles2
1645      (list handles2))))
1646
1647 (defun mm-readable-p (handle)
1648   "Say whether the content of HANDLE is readable."
1649   (and (< (with-current-buffer (mm-handle-buffer handle)
1650             (buffer-size)) 10000)
1651        (mm-with-unibyte-buffer
1652          (mm-insert-part handle)
1653          (and (eq (mm-body-7-or-8) '7bit)
1654               (not (mm-long-lines-p 76))))))
1655
1656 (provide 'mm-decode)
1657
1658 ;; arch-tag: 4f35d360-56b8-4030-9388-3ed82d359b9b
1659 ;;; mm-decode.el ends here