code.delx.au - gnu-emacs/blob - lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985, 1986, 1993, 1994, 1998, 1999, 2000, 2001,
   4 ;;   2002, 2003, 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software: you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation, either version 3 of the License, or
  14 ;; (at your option) any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 ;;; Commentary:
  25
  26 ;; This file contains those help commands which are complicated, and
  27 ;; which may not be used in every session.  For example
  28 ;; `describe-function' will probably be heavily used when doing elisp
  29 ;; programming, but not if just editing C files.  Simpler help commands
  30 ;; are in help.el
  31
  32 ;;; Code:
  33
  34 (require 'help-mode)
  35
  36 ;; Functions
  37
  38 ;;;###autoload
  39 (defun describe-function (function)
  40   "Display the full documentation of FUNCTION (a symbol)."
  41   (interactive
  42    (let ((fn (function-called-at-point))
  43          (enable-recursive-minibuffers t)
  44          val)
  45      (setq val (completing-read (if fn
  46                                     (format "Describe function (default %s): " fn)
  47                                   "Describe function: ")
  48                                 obarray 'fboundp t nil nil
  49                                 (and fn (symbol-name fn))))
  50      (list (if (equal val "")
  51                fn (intern val)))))
  52   (if (null function)
  53       (message "You didn't specify a function")
  54     (help-setup-xref (list #'describe-function function) (interactive-p))
  55     (save-excursion
  56       (with-help-window (help-buffer)
  57         (prin1 function)
  58         ;; Use " is " instead of a colon so that
  59         ;; it is easier to get out the function name using forward-sexp.
  60         (princ " is ")
  61         (describe-function-1 function)
  62         (with-current-buffer standard-output
  63           ;; Return the text we displayed.
  64           (buffer-string))))))
  65
  66 (defun help-split-fundoc (docstring def)
  67   "Split a function DOCSTRING into the actual doc and the usage info.
  68 Return (USAGE . DOC) or nil if there's no usage info.
  69 DEF is the function whose usage we're looking for in DOCSTRING."
  70   ;; Functions can get the calling sequence at the end of the doc string.
  71   ;; In cases where `function' has been fset to a subr we can't search for
  72   ;; function's name in the doc string so we use `fn' as the anonymous
  73   ;; function name instead.
  74   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
  75     (cons (format "(%s%s"
  76                   ;; Replace `fn' with the actual function name.
  77                   (if (consp def) "anonymous" def)
  78                   (match-string 1 docstring))
  79           (substring docstring 0 (match-beginning 0)))))
  80
  81 (defun help-add-fundoc-usage (docstring arglist)
  82   "Add the usage info to DOCSTRING.
  83 If DOCSTRING already has a usage info, then just return it unchanged.
  84 The usage info is built from ARGLIST.  DOCSTRING can be nil.
  85 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
  86   (unless (stringp docstring) (setq docstring "Not documented"))
  87   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring) (eq arglist t))
  88       docstring
  89     (concat docstring
  90             (if (string-match "\n?\n\\'" docstring)
  91                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
  92               "\n\n")
  93             (if (and (stringp arglist)
  94                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
  95                 (concat "(fn" (match-string 1 arglist) ")")
  96               (format "%S" (help-make-usage 'fn arglist))))))
  97
  98 (defun help-function-arglist (def)
  99   ;; Handle symbols aliased to other symbols.
 100   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 101   ;; If definition is a macro, find the function inside it.
 102   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 103   (cond
 104    ((byte-code-function-p def) (aref def 0))
 105    ((eq (car-safe def) 'lambda) (nth 1 def))
 106    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 107     "[Arg list not available until function definition is loaded.]")
 108    (t t)))
 109
 110 (defun help-make-usage (function arglist)
 111   (cons (if (symbolp function) function 'anonymous)
 112         (mapcar (lambda (arg)
 113                   (if (not (symbolp arg))
 114                       (if (and (consp arg) (symbolp (car arg)))
 115                           ;; CL style default values for optional args.
 116                           (cons (intern (upcase (symbol-name (car arg))))
 117                                 (cdr arg))
 118                         arg)
 119                     (let ((name (symbol-name arg)))
 120                       (if (string-match "\\`&" name) arg
 121                         (intern (upcase name))))))
 122                 arglist)))
 123
 124 ;; Could be this, if we make symbol-file do the work below.
 125 ;; (defun help-C-file-name (subr-or-var kind)
 126 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 127 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 128 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 129 ;;               (subr-name subr-or-var))
 130 ;;             (if (eq kind 'var) 'defvar 'defun)))
 131 ;;;###autoload
 132 (defun help-C-file-name (subr-or-var kind)
 133   "Return the name of the C file where SUBR-OR-VAR is defined.
 134 KIND should be `var' for a variable or `subr' for a subroutine."
 135   (let ((docbuf (get-buffer-create " *DOC*"))
 136         (name (if (eq 'var kind)
 137                   (concat "V" (symbol-name subr-or-var))
 138                 (concat "F" (subr-name subr-or-var)))))
 139     (with-current-buffer docbuf
 140       (goto-char (point-min))
 141       (if (eobp)
 142           (insert-file-contents-literally
 143            (expand-file-name internal-doc-file-name doc-directory)))
 144       (let ((file (catch 'loop
 145                     (while t
 146                       (let ((pnt (search-forward (concat "\1f" name "\n"))))
 147                         (re-search-backward "\1fS\\(.*\\)")
 148                         (let ((file (match-string 1)))
 149                           (if (member file build-files)
 150                               (throw 'loop file)
 151                             (goto-char pnt))))))))
 152         (if (string-match "^ns.*\\(\\.o\\|obj\\)\\'" file)
 153             (setq file (replace-match ".m" t t file 1))
 154           (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 155               (setq file (replace-match ".c" t t file))))
 156         (if (string-match "\\.\\(c\\|m\\)\\'" file)
 157             (concat "src/" file)
 158           file)))))
 159
 160 (defface help-argument-name '((((supports :slant italic)) :inherit italic))
 161   "Face to highlight argument names in *Help* buffers."
 162   :group 'help)
 163
 164 (defun help-default-arg-highlight (arg)
 165   "Default function to highlight arguments in *Help* buffers.
 166 It returns ARG in face `help-argument-name'; ARG is also
 167 downcased if it displays differently than the default
 168 face (according to `face-differs-from-default-p')."
 169   (propertize (if (face-differs-from-default-p 'help-argument-name)
 170                   (downcase arg)
 171                 arg)
 172               'face 'help-argument-name))
 173
 174 (defun help-do-arg-highlight (doc args)
 175   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 176     (modify-syntax-entry ?\- "w")
 177     (dolist (arg args doc)
 178       (setq doc (replace-regexp-in-string
 179                  ;; This is heuristic, but covers all common cases
 180                  ;; except ARG1-ARG2
 181                  (concat "\\<"                   ; beginning of word
 182                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 183                          "\\("
 184                          (regexp-quote arg)
 185                          "\\)"
 186                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 187                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 188                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 189                          "\\>")                  ; end of word
 190                  (help-default-arg-highlight arg)
 191                  doc t t 1)))))
 192
 193 (defun help-highlight-arguments (usage doc &rest args)
 194   (when usage
 195     (with-temp-buffer
 196       (insert usage)
 197       (goto-char (point-min))
 198       (let ((case-fold-search nil)
 199             (next (not (or args (looking-at "\\["))))
 200             (opt nil))
 201         ;; Make a list of all arguments
 202         (skip-chars-forward "^ ")
 203         (while next
 204           (or opt (not (looking-at " &")) (setq opt t))
 205           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 206               (setq next nil)
 207             (setq args (cons (match-string 2) args))
 208             (when (and opt (string= (match-string 1) "("))
 209               ;; A pesky CL-style optional argument with default value,
 210               ;; so let's skip over it
 211               (search-backward "(")
 212               (goto-char (scan-sexps (point) 1)))))
 213         ;; Highlight aguments in the USAGE string
 214         (setq usage (help-do-arg-highlight (buffer-string) args))
 215         ;; Highlight arguments in the DOC string
 216         (setq doc (and doc (help-do-arg-highlight doc args))))))
 217   ;; Return value is like the one from help-split-fundoc, but highlighted
 218   (cons usage doc))
 219
 220 ;; The following function was compiled from the former functions
 221 ;; `describe-simplify-lib-file-name' and `find-source-lisp-file' with
 222 ;; some excerpts from `describe-function-1' and `describe-variable'.
 223 ;; The only additional twists provided are (1) locate the defining file
 224 ;; for autoloaded functions, and (2) give preference to files in the
 225 ;; "install directory" (directories found via `load-path') rather than
 226 ;; to files in the "compile directory" (directories found by searching
 227 ;; the loaddefs.el file).  We autoload it because it's also used by
 228 ;; `describe-face' (instead of `describe-simplify-lib-file-name').
 229
 230 ;;;###autoload
 231 (defun find-lisp-object-file-name (object type)
 232   "Guess the file that defined the Lisp object OBJECT, of type TYPE.
 233 OBJECT should be a symbol associated with a function, variable, or face;
 234   alternatively, it can be a function definition.
 235 If TYPE is `variable', search for a variable definition.
 236 If TYPE is `face', search for a face definition.
 237 If TYPE is the value returned by `symbol-function' for a function symbol,
 238  search for a function definition.
 239
 240 The return value is the absolute name of a readable file where OBJECT is
 241 defined.  If several such files exist, preference is given to a file
 242 found via `load-path'.  The return value can also be `C-source', which
 243 means that OBJECT is a function or variable defined in C.  If no
 244 suitable file is found, return nil."
 245   (let* ((autoloaded (eq (car-safe type) 'autoload))
 246          (file-name (or (and autoloaded (nth 1 type))
 247                         (symbol-file
 248                          object (if (memq type (list 'defvar 'defface))
 249                                     type
 250                                   'defun)))))
 251     (cond
 252      (autoloaded
 253       ;; An autoloaded function: Locate the file since `symbol-function'
 254       ;; has only returned a bare string here.
 255       (setq file-name
 256             (locate-file file-name load-path '(".el" ".elc") 'readable)))
 257      ((and (stringp file-name)
 258            (string-match "[.]*loaddefs.el\\'" file-name))
 259       ;; An autoloaded variable or face.  Visit loaddefs.el in a buffer
 260       ;; and try to extract the defining file.  The following form is
 261       ;; from `describe-function-1' and `describe-variable'.
 262       (let ((location
 263              (condition-case nil
 264                  (find-function-search-for-symbol object nil file-name)
 265                (error nil))))
 266         (when location
 267           (with-current-buffer (car location)
 268             (goto-char (cdr location))
 269             (when (re-search-backward
 270                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 271               (setq file-name
 272                     (locate-file
 273                      (match-string-no-properties 1)
 274                      load-path nil 'readable))))))))
 275
 276     (cond
 277      ((and (not file-name) (subrp type))
 278       ;; A built-in function.  The form is from `describe-function-1'.
 279       (if (get-buffer " *DOC*")
 280           (help-C-file-name type 'subr)
 281         'C-source))
 282      ((and (not file-name) (symbolp object)
 283            (integerp (get object 'variable-documentation)))
 284       ;; A variable defined in C.  The form is from `describe-variable'.
 285       (if (get-buffer " *DOC*")
 286           (help-C-file-name object 'var)
 287         'C-source))
 288      ((not (stringp file-name))
 289       ;; If we don't have a file-name string by now, we lost.
 290       nil)
 291      ((let ((lib-name
 292              (if (string-match "[.]elc\\'" file-name)
 293                  (substring-no-properties file-name 0 -1)
 294                file-name)))
 295         ;; When the Elisp source file can be found in the install
 296         ;; directory return the name of that file - `file-name' should
 297         ;; have become an absolute file name ny now.
 298         (and (file-readable-p lib-name) lib-name)))
 299      ((let* ((lib-name (file-name-nondirectory file-name))
 300              ;; The next form is from `describe-simplify-lib-file-name'.
 301              (file-name
 302               ;; Try converting the absolute file name to a library
 303               ;; name, convert that back to a file name and see if we
 304               ;; get the original one.  If so, they are equivalent.
 305               (if (equal file-name (locate-file lib-name load-path '("")))
 306                   (if (string-match "[.]elc\\'" lib-name)
 307                       (substring-no-properties lib-name 0 -1)
 308                     lib-name)
 309                 file-name))
 310              ;; The next three forms are from `find-source-lisp-file'.
 311              (elc-file (locate-file
 312                         (concat file-name
 313                                 (if (string-match "\\.el\\'" file-name)
 314                                     "c"
 315                                   ".elc"))
 316                         load-path nil 'readable))
 317              (str (when elc-file
 318                     (with-temp-buffer
 319                       (insert-file-contents-literally elc-file nil 0 256)
 320                       (buffer-string))))
 321              (src-file (and str
 322                             (string-match ";;; from file \\(.*\\.el\\)" str)
 323                             (match-string 1 str))))
 324         (and src-file (file-readable-p src-file) src-file))))))
 325
 326 (declare-function ad-get-advice-info "advice" (function))
 327
 328 ;;;###autoload
 329 (defun describe-function-1 (function)
 330   (let* ((advised (and (symbolp function) (featurep 'advice)
 331                        (ad-get-advice-info function)))
 332          ;; If the function is advised, use the symbol that has the
 333          ;; real definition, if that symbol is already set up.
 334          (real-function
 335           (or (and advised
 336                    (let ((origname (cdr (assq 'origname advised))))
 337                      (and (fboundp origname) origname)))
 338               function))
 339          ;; Get the real definition.
 340          (def (if (symbolp real-function)
 341                   (symbol-function real-function)
 342                 function))
 343          file-name string
 344          (beg (if (commandp def) "an interactive " "a "))
 345          (pt1 (with-current-buffer (help-buffer) (point)))
 346          errtype)
 347     (setq string
 348           (cond ((or (stringp def)
 349                      (vectorp def))
 350                  "a keyboard macro")
 351                 ((subrp def)
 352                  (if (eq 'unevalled (cdr (subr-arity def)))
 353                      (concat beg "special form")
 354                    (concat beg "built-in function")))
 355                 ((byte-code-function-p def)
 356                  (concat beg "compiled Lisp function"))
 357                 ((symbolp def)
 358                  (while (and (fboundp def)
 359                              (symbolp (symbol-function def)))
 360                    (setq def (symbol-function def)))
 361                  ;; Handle (defalias 'foo 'bar), where bar is undefined.
 362                  (or (fboundp def) (setq errtype 'alias))
 363                  (format "an alias for `%s'" def))
 364                 ((eq (car-safe def) 'lambda)
 365                  (concat beg "Lisp function"))
 366                 ((eq (car-safe def) 'macro)
 367                  "a Lisp macro")
 368                 ((eq (car-safe def) 'autoload)
 369                  (format "%s autoloaded %s"
 370                          (if (commandp def) "an interactive" "an")
 371                          (if (eq (nth 4 def) 'keymap) "keymap"
 372                            (if (nth 4 def) "Lisp macro" "Lisp function"))))
 373                 ((keymapp def)
 374                  (let ((is-full nil)
 375                        (elts (cdr-safe def)))
 376                    (while elts
 377                      (if (char-table-p (car-safe elts))
 378                          (setq is-full t
 379                                elts nil))
 380                      (setq elts (cdr-safe elts)))
 381                    (if is-full
 382                        "a full keymap"
 383                      "a sparse keymap")))
 384                 (t "")))
 385     (princ string)
 386     (if (eq errtype 'alias)
 387         (princ ",\nwhich is not defined.  Please make a bug report.")
 388       (with-current-buffer standard-output
 389         (save-excursion
 390           (save-match-data
 391             (when (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 392               (help-xref-button 1 'help-function def)))))
 393
 394       (setq file-name (find-lisp-object-file-name function def))
 395       (when file-name
 396         (princ " in `")
 397         ;; We used to add .el to the file name,
 398         ;; but that's completely wrong when the user used load-file.
 399         (princ (if (eq file-name 'C-source) "C source code" file-name))
 400         (princ "'")
 401         ;; Make a hyperlink to the library.
 402         (with-current-buffer standard-output
 403           (save-excursion
 404             (re-search-backward "`\\([^`']+\\)'" nil t)
 405             (help-xref-button 1 'help-function-def real-function file-name))))
 406       (princ ".")
 407       (with-current-buffer (help-buffer)
 408         (fill-region-as-paragraph (save-excursion (goto-char pt1) (forward-line 0) (point))
 409                                   (point)))
 410       (terpri)(terpri)
 411       (when (commandp function)
 412         (let ((pt2 (with-current-buffer (help-buffer) (point))))
 413           (if (and (eq function 'self-insert-command)
 414                    (eq (key-binding "a") 'self-insert-command)
 415                    (eq (key-binding "b") 'self-insert-command)
 416                    (eq (key-binding "c") 'self-insert-command))
 417               (princ "It is bound to many ordinary text characters.\n")
 418             (let* ((remapped (command-remapping function))
 419                    (keys (where-is-internal
 420                           (or remapped function) overriding-local-map nil nil))
 421                    non-modified-keys)
 422               ;; Which non-control non-meta keys run this command?
 423               (dolist (key keys)
 424                 (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 425                     (push key non-modified-keys)))
 426               (when remapped
 427                 (princ "It is remapped to `")
 428                 (princ (symbol-name remapped))
 429                 (princ "'"))
 430
 431               (when keys
 432                 (princ (if remapped ", which is bound to " "It is bound to "))
 433                 ;; If lots of ordinary text characters run this command,
 434                 ;; don't mention them one by one.
 435                 (if (< (length non-modified-keys) 10)
 436                     (princ (mapconcat 'key-description keys ", "))
 437                   (dolist (key non-modified-keys)
 438                     (setq keys (delq key keys)))
 439                   (if keys
 440                       (progn
 441                         (princ (mapconcat 'key-description keys ", "))
 442                         (princ ", and many ordinary text characters"))
 443                     (princ "many ordinary text characters"))))
 444               (when (or remapped keys non-modified-keys)
 445                 (princ ".")
 446                 (terpri))))
 447           (with-current-buffer (help-buffer) (fill-region-as-paragraph pt2 (point)))
 448           (terpri)))
 449       (let* ((arglist (help-function-arglist def))
 450              (doc (documentation function))
 451              (usage (help-split-fundoc doc function)))
 452         (with-current-buffer standard-output
 453           ;; If definition is a keymap, skip arglist note.
 454           (unless (keymapp function)
 455             (let* ((use (cond
 456                          (usage (setq doc (cdr usage)) (car usage))
 457                          ((listp arglist)
 458                           (format "%S" (help-make-usage function arglist)))
 459                          ((stringp arglist) arglist)
 460                          ;; Maybe the arglist is in the docstring of a symbol
 461                          ;; this one is aliased to.
 462                          ((let ((fun real-function))
 463                             (while (and (symbolp fun)
 464                                         (setq fun (symbol-function fun))
 465                                         (not (setq usage (help-split-fundoc
 466                                                           (documentation fun)
 467                                                           function)))))
 468                             usage)
 469                           (car usage))
 470                          ((or (stringp def)
 471                               (vectorp def))
 472                           (format "\nMacro: %s" (format-kbd-macro def)))
 473                          (t "[Missing arglist.  Please make a bug report.]")))
 474                    (high (help-highlight-arguments use doc)))
 475               (let ((fill-begin (point)))
 476                 (insert (car high) "\n")
 477                 (fill-region fill-begin (point)))
 478               (setq doc (cdr high))))
 479           (let* ((obsolete (and
 480                             ;; function might be a lambda construct.
 481                             (symbolp function)
 482                             (get function 'byte-obsolete-info)))
 483                  (use (car obsolete)))
 484             (when obsolete
 485               (princ "\nThis function is obsolete")
 486               (when (nth 2 obsolete)
 487                 (insert (format " since %s" (nth 2 obsolete))))
 488               (insert (cond ((stringp use) (concat ";\n" use))
 489                             (use (format ";\nuse `%s' instead." use))
 490                             (t "."))
 491                       "\n"))
 492             (insert "\n"
 493                     (or doc "Not documented."))))))))
 494
 495 \f
 496 ;; Variables
 497
 498 ;;;###autoload
 499 (defun variable-at-point (&optional any-symbol)
 500   "Return the bound variable symbol found at or before point.
 501 Return 0 if there is no such symbol.
 502 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 503   (with-syntax-table emacs-lisp-mode-syntax-table
 504     (or (condition-case ()
 505             (save-excursion
 506               (or (not (zerop (skip-syntax-backward "_w")))
 507                   (eq (char-syntax (following-char)) ?w)
 508                   (eq (char-syntax (following-char)) ?_)
 509                   (forward-sexp -1))
 510               (skip-chars-forward "'")
 511               (let ((obj (read (current-buffer))))
 512                 (and (symbolp obj) (boundp obj) obj)))
 513           (error nil))
 514         (let* ((str (find-tag-default))
 515                (sym (if str (intern-soft str))))
 516           (if (and sym (or any-symbol (boundp sym)))
 517               sym
 518             (save-match-data
 519               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 520                 (setq sym (intern-soft (match-string 1 str)))
 521                 (and (or any-symbol (boundp sym)) sym)))))
 522         0)))
 523
 524 (defun describe-variable-custom-version-info (variable)
 525   (let ((custom-version (get variable 'custom-version))
 526         (cpv (get variable 'custom-package-version))
 527         (output nil))
 528     (if custom-version
 529         (setq output
 530               (format "This variable was introduced, or its default value was changed, in\nversion %s of Emacs.\n"
 531                       custom-version))
 532       (when cpv
 533         (let* ((package (car-safe cpv))
 534                (version (if (listp (cdr-safe cpv))
 535                             (car (cdr-safe cpv))
 536                           (cdr-safe cpv)))
 537                (pkg-versions (assq package customize-package-emacs-version-alist))
 538                (emacsv (cdr (assoc version pkg-versions))))
 539           (if (and package version)
 540               (setq output
 541                     (format (concat "This variable was introduced, or its default value was changed, in\nversion %s of the %s package"
 542                                     (if emacsv
 543                                         (format " that is part of Emacs %s" emacsv))
 544                                     ".\n")
 545                             version package))))))
 546     output))
 547
 548 ;;;###autoload
 549 (defun describe-variable (variable &optional buffer frame)
 550   "Display the full documentation of VARIABLE (a symbol).
 551 Returns the documentation as a string, also.
 552 If VARIABLE has a buffer-local value in BUFFER or FRAME
 553 \(default to the current buffer and current frame),
 554 it is displayed along with the global value."
 555   (interactive
 556    (let ((v (variable-at-point))
 557          (enable-recursive-minibuffers t)
 558          val)
 559      (setq val (completing-read (if (symbolp v)
 560                                     (format
 561                                      "Describe variable (default %s): " v)
 562                                   "Describe variable: ")
 563                                 obarray
 564                                 '(lambda (vv)
 565                                    (or (boundp vv)
 566                                        (get vv 'variable-documentation)))
 567                                 t nil nil
 568                                 (if (symbolp v) (symbol-name v))))
 569      (list (if (equal val "")
 570                v (intern val)))))
 571   (let (file-name)
 572     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 573     (unless (frame-live-p frame) (setq frame (selected-frame)))
 574     (if (not (symbolp variable))
 575         (message "You did not specify a variable")
 576       (save-excursion
 577         (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 578               val val-start-pos locus)
 579           ;; Extract the value before setting up the output buffer,
 580           ;; in case `buffer' *is* the output buffer.
 581           (unless valvoid
 582             (with-selected-frame frame
 583               (with-current-buffer buffer
 584                 (setq val (symbol-value variable)
 585                       locus (variable-binding-locus variable)))))
 586           (help-setup-xref (list #'describe-variable variable buffer)
 587                            (interactive-p))
 588           (with-help-window (help-buffer)
 589             (with-current-buffer buffer
 590               (prin1 variable)
 591               (setq file-name (find-lisp-object-file-name variable 'defvar))
 592
 593               (if file-name
 594                   (progn
 595                     (princ " is a variable defined in `")
 596                     (princ (if (eq file-name 'C-source) "C source code" file-name))
 597                     (princ "'.\n")
 598                     (with-current-buffer standard-output
 599                       (save-excursion
 600                         (re-search-backward "`\\([^`']+\\)'" nil t)
 601                         (help-xref-button 1 'help-variable-def
 602                                           variable file-name)))
 603                     (if valvoid
 604                         (princ "It is void as a variable.")
 605                       (princ "Its ")))
 606                 (if valvoid
 607                     (princ " is void as a variable.")
 608                   (princ "'s "))))
 609             (if valvoid
 610                 nil
 611               (with-current-buffer standard-output
 612                 (setq val-start-pos (point))
 613                 (princ "value is ")
 614                 (terpri)
 615                 (let ((from (point)))
 616                   (pp val)
 617                   ;; Hyperlinks in variable's value are quite frequently
 618                   ;; inappropriate e.g C-h v <RET> features <RET>
 619                   ;; (help-xref-on-pp from (point))
 620                   (if (< (point) (+ from 20))
 621                       (delete-region (1- from) from)))))
 622             (terpri)
 623
 624             (when locus
 625               (if (bufferp locus)
 626                   (princ (format "%socal in buffer %s; "
 627                                  (if (get variable 'permanent-local)
 628                                      "Permanently l" "L")
 629                                  (buffer-name)))
 630                 (princ (format "It is a frame-local variable; ")))
 631               (if (not (default-boundp variable))
 632                   (princ "globally void")
 633                 (let ((val (default-value variable)))
 634                   (with-current-buffer standard-output
 635                     (princ "global value is ")
 636                     (terpri)
 637                     ;; Fixme: pp can take an age if you happen to
 638                     ;; ask for a very large expression.  We should
 639                     ;; probably print it raw once and check it's a
 640                     ;; sensible size before prettyprinting.  -- fx
 641                     (let ((from (point)))
 642                       (pp val)
 643                       ;; See previous comment for this function.
 644                       ;; (help-xref-on-pp from (point))
 645                       (if (< (point) (+ from 20))
 646                           (delete-region (1- from) from))))))
 647               (terpri))
 648
 649             ;; If the value is large, move it to the end.
 650             (with-current-buffer standard-output
 651               (when (> (count-lines (point-min) (point-max)) 10)
 652                 ;; Note that setting the syntax table like below
 653                 ;; makes forward-sexp move over a `'s' at the end
 654                 ;; of a symbol.
 655                 (set-syntax-table emacs-lisp-mode-syntax-table)
 656                 (goto-char val-start-pos)
 657                 ;; The line below previously read as
 658                 ;; (delete-region (point) (progn (end-of-line) (point)))
 659                 ;; which suppressed display of the buffer local value for
 660                 ;; large values.
 661                 (when (looking-at "value is") (replace-match ""))
 662                 (save-excursion
 663                   (insert "\n\nValue:")
 664                   (set (make-local-variable 'help-button-cache)
 665                        (point-marker)))
 666                 (insert "value is shown ")
 667                 (insert-button "below"
 668                                'action help-button-cache
 669                                'follow-link t
 670                                'help-echo "mouse-2, RET: show value")
 671                 (insert ".\n")))
 672             (terpri)
 673
 674             (let* ((alias (condition-case nil
 675                               (indirect-variable variable)
 676                             (error variable)))
 677                    (obsolete (get variable 'byte-obsolete-variable))
 678                    (use (car obsolete))
 679                    (safe-var (get variable 'safe-local-variable))
 680                    (doc (or (documentation-property variable 'variable-documentation)
 681                             (documentation-property alias 'variable-documentation)))
 682                    (extra-line nil))
 683               ;; Add a note for variables that have been make-var-buffer-local.
 684               (when (and (local-variable-if-set-p variable)
 685                          (or (not (local-variable-p variable))
 686                              (with-temp-buffer
 687                                (local-variable-if-set-p variable))))
 688                 (setq extra-line t)
 689                 (princ "  Automatically becomes buffer-local when set in any fashion.\n"))
 690
 691               ;; Mention if it's an alias
 692               (unless (eq alias variable)
 693                 (setq extra-line t)
 694                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 695
 696               (when obsolete
 697                 (setq extra-line t)
 698                 (princ "  This variable is obsolete")
 699                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 700                 (princ (cond ((stringp use) (concat ";\n  " use))
 701                              (use (format ";\n  use `%s' instead." (car obsolete)))
 702                              (t ".")))
 703                 (terpri))
 704               (when safe-var
 705                 (setq extra-line t)
 706                 (princ "  This variable is safe as a file local variable ")
 707                 (princ "if its value\n  satisfies the predicate ")
 708                 (princ (if (byte-code-function-p safe-var)
 709                            "which is byte-compiled expression.\n"
 710                          (format "`%s'.\n" safe-var))))
 711
 712               (if extra-line (terpri))
 713               (princ "Documentation:\n")
 714               (with-current-buffer standard-output
 715                 (insert (or doc "Not documented as a variable."))))
 716
 717             ;; Make a link to customize if this variable can be customized.
 718             (when (custom-variable-p variable)
 719               (let ((customize-label "customize"))
 720                 (terpri)
 721                 (terpri)
 722                 (princ (concat "You can " customize-label " this variable."))
 723                 (with-current-buffer standard-output
 724                   (save-excursion
 725                     (re-search-backward
 726                      (concat "\\(" customize-label "\\)") nil t)
 727                     (help-xref-button 1 'help-customize-variable variable))))
 728               ;; Note variable's version or package version
 729               (let ((output (describe-variable-custom-version-info variable)))
 730                 (when output
 731                   (terpri)
 732                   (terpri)
 733                   (princ output))))
 734
 735             (save-excursion
 736               (set-buffer standard-output)
 737               ;; Return the text we displayed.
 738               (buffer-string))))))))
 739
 740
 741 ;;;###autoload
 742 (defun describe-syntax (&optional buffer)
 743   "Describe the syntax specifications in the syntax table of BUFFER.
 744 The descriptions are inserted in a help buffer, which is then displayed.
 745 BUFFER defaults to the current buffer."
 746   (interactive)
 747   (setq buffer (or buffer (current-buffer)))
 748   (help-setup-xref (list #'describe-syntax buffer) (interactive-p))
 749   (with-help-window (help-buffer)
 750     (let ((table (with-current-buffer buffer (syntax-table))))
 751       (with-current-buffer standard-output
 752         (describe-vector table 'internal-describe-syntax-value)
 753         (while (setq table (char-table-parent table))
 754           (insert "\nThe parent syntax table is:")
 755           (describe-vector table 'internal-describe-syntax-value))))))
 756
 757 (defun help-describe-category-set (value)
 758   (insert (cond
 759            ((null value) "default")
 760            ((char-table-p value) "deeper char-table ...")
 761            (t (condition-case err
 762                   (category-set-mnemonics value)
 763                 (error "invalid"))))))
 764
 765 ;;;###autoload
 766 (defun describe-categories (&optional buffer)
 767   "Describe the category specifications in the current category table.
 768 The descriptions are inserted in a buffer, which is then displayed.
 769 If BUFFER is non-nil, then describe BUFFER's category table instead.
 770 BUFFER should be a buffer or a buffer name."
 771   (interactive)
 772   (setq buffer (or buffer (current-buffer)))
 773   (help-setup-xref (list #'describe-categories buffer) (interactive-p))
 774   (with-help-window (help-buffer)
 775     (let ((table (with-current-buffer buffer (category-table))))
 776       (with-current-buffer standard-output
 777         (describe-vector table 'help-describe-category-set)
 778         (let ((docs (char-table-extra-slot table 0)))
 779           (if (or (not (vectorp docs)) (/= (length docs) 95))
 780               (insert "Invalid first extra slot in this char table\n")
 781             (insert "Meanings of mnemonic characters are:\n")
 782             (dotimes (i 95)
 783               (let ((elt (aref docs i)))
 784                 (when elt
 785                   (insert (+ i ?\s) ": " elt "\n"))))
 786             (while (setq table (char-table-parent table))
 787               (insert "\nThe parent category table is:")
 788               (describe-vector table 'help-describe-category-set))))))))
 789
 790 (provide 'help-fns)
 791
 792 ;; arch-tag: 9e10331c-ae81-4d13-965d-c4819aaab0b3
 793 ;;; help-fns.el ends here