code.delx.au - gnu-emacs/blob - lisp/mail/sendmail.el

   1 ;;; sendmail.el --- mail sending commands for Emacs.
   2
   3 ;; Copyright (C) 1985, 1986, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; This mode provides mail-sending facilities from within Emacs.  It is
  27 ;; documented in the Emacs user's manual.
  28
  29 ;;; Code:
  30
  31 ;;;###autoload
  32 (defvar mail-self-blind nil "\
  33 Non-nil means insert BCC to self in messages to be sent.
  34 This is done when the message is initialized,
  35 so you can remove or alter the BCC field to override the default.")
  36
  37 ;;;###autoload
  38 (defvar mail-interactive nil "\
  39 Non-nil means when sending a message wait for and display errors.
  40 nil means let mailer mail back a message to report errors.")
  41
  42 ;;;###autoload
  43 (defvar mail-yank-ignored-headers "^via:\\|^mail-from:\\|^origin:\\|^status:\\|^remailed\\|^received:\\|^message-id:\\|^summary-line:\\|^to:\\|^subject:\\|^in-reply-to:\\|^return-path:" "\
  44 Delete these headers from old message when it's inserted in a reply.")
  45
  46 ;; Useful to set in site-init.el
  47 ;;;###autoload
  48 (defvar send-mail-function 'sendmail-send-it "\
  49 Function to call to send the current buffer as mail.
  50 The headers are be delimited by a line which is `mail-header-separator'.")
  51
  52 ;;;###autoload
  53 (defvar mail-header-separator "--text follows this line--" "\
  54 *Line used to separate headers from text in messages being composed.")
  55
  56 ;;;###autoload
  57 (defvar mail-archive-file-name nil "\
  58 *Name of file to write all outgoing messages in, or nil for none.
  59 Do not use an rmail file here!  Instead, use its inbox file.")
  60
  61 (defvar mail-default-reply-to nil
  62   "*Address to insert as default Reply-to field of outgoing messages.")
  63
  64 (defvar mail-alias-file nil
  65   "*If non-nil, the name of a file to use instead of `/usr/lib/aliases'.
  66 This file defines aliases to be expanded by the mailer; this is a different
  67 feature from that of defining aliases in `.mailrc' to be expanded in Emacs.
  68 This variable has no effect unless your system uses sendmail as its mailer.")
  69
  70 (defvar mail-aliases t
  71   "Alist of mail address aliases,
  72 or t meaning should be initialized from `~/.mailrc'.
  73 The alias definitions in `~/.mailrc' have this form:
  74     alias ALIAS MEANING")
  75
  76 (defvar mail-yank-prefix nil
  77   "*Prefix insert on lines of yanked message being replied to.
  78 nil means use indentation.")
  79 (defvar mail-indentation-spaces 3
  80   "*Number of spaces to insert at the beginning of each cited line.
  81 Used by `mail-yank-original' via `mail-yank-cite'.")
  82 (defvar mail-yank-hooks '(mail-indent-citation)
  83   "Obsolete hook for modifying a citation just inserted in the mail buffer.
  84 Each hook function can find the citation between (point) and (mark t).
  85 And each hook function should leave point and mark around the citation
  86 text as modified.
  87
  88 This is a normal hook, misnamed for historical reasons.
  89 It is semi-obsolete and mail agents should no longer use it.")
  90
  91 (defvar mail-citation-hook nil
  92   "*Hook for modifying a citation just inserted in the mail buffer.
  93 Each hook function can find the citation between (point) and (mark t).
  94 And each hook function should leave point and mark around the citation
  95 text as modified.
  96
  97 If this hook is entirely empty (nil), a default action is taken
  98 instead of no action.")
  99
 100 (defvar mail-abbrevs-loaded nil)
 101 (defvar mail-mode-map nil)
 102
 103 (autoload 'build-mail-aliases "mailalias"
 104   "Read mail aliases from `~/.mailrc' and set `mail-aliases'."
 105   nil)
 106
 107 (autoload 'expand-mail-aliases "mailalias"
 108   "Expand all mail aliases in suitable header fields found between BEG and END.
 109 Suitable header fields are `To', `Cc' and `Bcc' and their `Resent-' variants.
 110 Optional second arg EXCLUDE may be a regular expression defining text to be
 111 removed from alias expansions."
 112   nil)
 113
 114 ;;;###autoload
 115 (defvar mail-signature nil
 116   "*Text inserted at end of mail buffer when a message is initialized.
 117 If t, it means to insert the contents of the file `~/.signature'.")
 118
 119 (defvar mail-reply-buffer nil)
 120 (defvar mail-send-actions nil
 121   "A list of actions to be performed upon successful sending of a message.")
 122
 123 (defvar mail-default-headers nil
 124   "*A string containing header lines, to be inserted in outgoing messages.
 125 It is inserted before you edit the message,
 126 so you can edit or delete these lines.")
 127
 128 (defvar mail-mode-syntax-table nil
 129   "Syntax table used while in mail mode.")
 130
 131 (if (null mail-mode-syntax-table)
 132     (progn
 133      (setq mail-mode-syntax-table (copy-syntax-table text-mode-syntax-table))
 134      (modify-syntax-entry ?% ". " mail-mode-syntax-table)))
 135
 136 (defun mail-setup (to subject in-reply-to cc replybuffer actions)
 137   (if (eq mail-aliases t)
 138       (progn
 139         (setq mail-aliases nil)
 140         (if (file-exists-p "~/.mailrc")
 141             (build-mail-aliases))))
 142   (setq mail-send-actions actions)
 143   (setq mail-reply-buffer replybuffer)
 144   (goto-char (point-min))
 145   (insert "To: ")
 146   (save-excursion
 147     (if to
 148         ;; Here removed code to extract names from within <...>
 149         ;; on the assumption that mail-strip-quoted-names
 150         ;; has been called and has done so.
 151         (let ((fill-prefix "\t")
 152               (address-start (point)))
 153           (insert to "\n")
 154           (fill-region-as-paragraph address-start (point-max)))
 155       (newline))
 156     (if cc
 157         (let ((fill-prefix "\t")
 158               (address-start (progn (insert "CC: ") (point))))
 159           (insert cc "\n")
 160           (fill-region-as-paragraph address-start (point-max))))
 161     (if in-reply-to
 162         (insert "In-reply-to: " in-reply-to "\n"))
 163     (insert "Subject: " (or subject "") "\n")
 164     (if mail-default-headers
 165         (insert mail-default-headers))
 166     (if mail-default-reply-to
 167         (insert "Reply-to: " mail-default-reply-to "\n"))
 168     (if mail-self-blind
 169         (insert "BCC: " (user-login-name) "\n"))
 170     (if mail-archive-file-name
 171         (insert "FCC: " mail-archive-file-name "\n"))
 172     (insert mail-header-separator "\n")
 173     ;; Insert the signature.  But remember the beginning of the message.
 174     (if to (setq to (point)))
 175     (cond ((eq mail-signature t)
 176            (if (file-exists-p "~/.signature")
 177                (insert-file-contents "~/.signature")))
 178           (mail-signature
 179            (insert mail-signature)))
 180     (goto-char (point-max))
 181     (or (bolp) (newline)))
 182   (if to (goto-char to))
 183   (or to subject in-reply-to
 184       (set-buffer-modified-p nil))
 185   (run-hooks 'mail-setup-hook))
 186
 187 ;;;###autoload
 188 (defun mail-mode ()
 189   "Major mode for editing mail to be sent.
 190 Like Text Mode but with these additional commands:
 191 C-c C-s  mail-send (send the message)    C-c C-c  mail-send-and-exit
 192 C-c C-f  move to a header field (and create it if there isn't):
 193          C-c C-f C-t  move to To:       C-c C-f C-s  move to Subj:
 194          C-c C-f C-b  move to BCC:      C-c C-f C-c  move to CC:
 195 C-c C-t  move to message text.
 196 C-c C-y  mail-yank-original (insert current message, in Rmail).
 197 C-c C-q  mail-fill-yanked-message (fill what was yanked).
 198 C-c C-v  mail-sent-via (add a sent-via field for each To or CC)."
 199   (interactive)
 200   (kill-all-local-variables)
 201   (make-local-variable 'mail-reply-buffer)
 202   (setq mail-reply-buffer nil)
 203   (make-local-variable 'mail-send-actions)
 204   (set-syntax-table mail-mode-syntax-table)
 205   (use-local-map mail-mode-map)
 206   (setq local-abbrev-table text-mode-abbrev-table)
 207   (setq major-mode 'mail-mode)
 208   (setq mode-name "Mail")
 209   (setq buffer-offer-save t)
 210   (make-local-variable 'paragraph-separate)
 211   (make-local-variable 'paragraph-start)
 212   (setq paragraph-start (concat "^" mail-header-separator
 213                                 "$\\|^[ \t]*[-_][-_][-_]+$\\|"
 214                                 paragraph-start))
 215   (setq paragraph-separate (concat "^" mail-header-separator
 216                                    "$\\|^[ \t]*[-_][-_][-_]+$\\|"
 217                                    paragraph-separate))
 218   (run-hooks 'text-mode-hook 'mail-mode-hook))
 219 \f
 220 ;;; Set up keymap.
 221
 222 (if mail-mode-map
 223     nil
 224   (setq mail-mode-map (nconc (make-sparse-keymap) text-mode-map))
 225   (define-key mail-mode-map "\C-c?" 'describe-mode)
 226   (define-key mail-mode-map "\C-c\C-f\C-t" 'mail-to)
 227   (define-key mail-mode-map "\C-c\C-f\C-b" 'mail-bcc)
 228   (define-key mail-mode-map "\C-c\C-f\C-f" 'mail-fcc)
 229   (define-key mail-mode-map "\C-c\C-f\C-c" 'mail-cc)
 230   (define-key mail-mode-map "\C-c\C-f\C-s" 'mail-subject)
 231   (define-key mail-mode-map "\C-c\C-t" 'mail-text)
 232   (define-key mail-mode-map "\C-c\C-y" 'mail-yank-original)
 233   (define-key mail-mode-map "\C-c\C-q" 'mail-fill-yanked-message)
 234   (define-key mail-mode-map "\C-c\C-w" 'mail-signature)
 235   (define-key mail-mode-map "\C-c\C-v" 'mail-sent-via)
 236   (define-key mail-mode-map "\C-c\C-c" 'mail-send-and-exit)
 237   (define-key mail-mode-map "\C-c\C-s" 'mail-send))
 238
 239 (define-key mail-mode-map [menu-bar mail]
 240   (cons "Mail" (make-sparse-keymap "Mail")))
 241
 242 (define-key mail-mode-map [menu-bar mail fill]
 243   '("Fill Citation" . mail-fill-yanked-message))
 244
 245 (define-key mail-mode-map [menu-bar mail yank]
 246   '("Cite Original" . mail-yank-original))
 247
 248 (define-key mail-mode-map [menu-bar mail signature]
 249   '("Insert Signature" . mail-signature))
 250
 251 (define-key mail-mode-map [menu-bar mail cancel]
 252   '("Cancel" . mail-dont-send))
 253
 254 (define-key mail-mode-map [menu-bar mail send-stay]
 255   '("Send, Keep Editing" . mail-send))
 256
 257 (define-key mail-mode-map [menu-bar mail send]
 258   '("Send Message" . mail-send-and-exit))
 259
 260 (define-key mail-mode-map [menu-bar headers]
 261   (cons "Headers" (make-sparse-keymap "Headers")))
 262
 263 (define-key mail-mode-map [menu-bar headers sent-via]
 264   '("Sent Via" . mail-sent-via))
 265
 266 (define-key mail-mode-map [menu-bar headers text]
 267   '("Text" . mail-text))
 268
 269 (define-key mail-mode-map [menu-bar headers bcc]
 270   '("Bcc" . mail-bcc))
 271
 272 (define-key mail-mode-map [menu-bar headers fcc]
 273   '("Fcc" . mail-fcc))
 274
 275 (define-key mail-mode-map [menu-bar headers cc]
 276   '("Cc" . mail-cc))
 277
 278 (define-key mail-mode-map [menu-bar headers subject]
 279   '("Subject" . mail-subject))
 280
 281 (define-key mail-mode-map [menu-bar headers to]
 282   '("To" . mail-to))
 283 \f
 284 (defun mail-send-and-exit (arg)
 285   "Send message like `mail-send', then, if no errors, exit from mail buffer.
 286 Prefix arg means don't delete this window."
 287   (interactive "P")
 288   (mail-send)
 289   (mail-bury arg))
 290
 291 (defun mail-dont-send (arg)
 292   "Don't send the message you have been editing.
 293 Prefix arg means don't delete this window."
 294   (interactive "P")
 295   (mail-bury arg))
 296
 297 (defun mail-bury (arg)
 298   "Bury this mail buffer."
 299   (let ((newbuf (other-buffer (current-buffer))))
 300     (bury-buffer (current-buffer))
 301     (if (and (fboundp 'frame-parameters)
 302              (cdr (assq 'dedicated (frame-parameters)))
 303              (not (null (delq (selected-frame) (visible-frame-list)))))
 304         (delete-frame (selected-frame))
 305       (if (and (not arg)
 306                (not (one-window-p))
 307                (save-excursion
 308                  (set-buffer (window-buffer (next-window (selected-window) 'not)))
 309                  (eq major-mode 'rmail-mode)))
 310           (delete-window)
 311         (switch-to-buffer newbuf)))))
 312
 313 (defun mail-send ()
 314   "Send the message in the current buffer.
 315 If `mail-interactive' is non-nil, wait for success indication
 316 or error messages, and inform user.
 317 Otherwise any failure is reported in a message back to
 318 the user from the mailer."
 319   (interactive)
 320   (if (if buffer-file-name
 321           (y-or-n-p "Send buffer contents as mail message? ")
 322         (or (buffer-modified-p)
 323             (y-or-n-p "Message already sent; resend? ")))
 324       (progn
 325         (message "Sending...")
 326         (run-hooks 'mail-send-hook)
 327         (funcall send-mail-function)
 328         ;; Now perform actions on successful sending.
 329         (while mail-send-actions
 330           (condition-case nil
 331               (apply (car (car mail-send-actions))
 332                      (cdr (car mail-send-actions)))
 333             (error))
 334           (setq mail-send-actions (cdr mail-send-actions)))
 335         (message "Sending...done")
 336         ;; If buffer has no file, mark it as unmodified and delete autosave.
 337         (if (not buffer-file-name)
 338             (progn
 339               (set-buffer-modified-p nil)
 340               (delete-auto-save-file-if-necessary t))))))
 341
 342 (defun sendmail-send-it ()
 343   (let ((errbuf (if mail-interactive
 344                     (generate-new-buffer " sendmail errors")
 345                   0))
 346         (tembuf (generate-new-buffer " sendmail temp"))
 347         (case-fold-search nil)
 348         delimline
 349         (mailbuf (current-buffer)))
 350     (unwind-protect
 351         (save-excursion
 352           (set-buffer tembuf)
 353           (erase-buffer)
 354           (insert-buffer-substring mailbuf)
 355           (goto-char (point-max))
 356           ;; require one newline at the end.
 357           (or (= (preceding-char) ?\n)
 358               (insert ?\n))
 359           ;; Change header-delimiter to be what sendmail expects.
 360           (goto-char (point-min))
 361           (re-search-forward
 362             (concat "^" (regexp-quote mail-header-separator) "\n"))
 363           (replace-match "\n")
 364           (backward-char 1)
 365           (setq delimline (point-marker))
 366           (if mail-aliases
 367               (expand-mail-aliases (point-min) delimline))
 368           (goto-char (point-min))
 369           ;; ignore any blank lines in the header
 370           (while (and (re-search-forward "\n\n\n*" delimline t)
 371                       (< (point) delimline))
 372             (replace-match "\n"))
 373           (let ((case-fold-search t))
 374             (goto-char (point-min))
 375             (if (re-search-forward "^Sender:" delimline t)
 376                 (error "Sender may not be specified."))
 377             ;; Find and handle any FCC fields.
 378             (goto-char (point-min))
 379             (if (re-search-forward "^FCC:" delimline t)
 380                 (mail-do-fcc delimline))
 381             ;; If the From is different than current user, insert Sender.
 382             (goto-char (point-min))
 383             (and (re-search-forward "^From:"  delimline t)
 384                  (progn
 385                    (require 'mail-utils)
 386                    (not (string-equal
 387                          (mail-strip-quoted-names
 388                           (save-restriction
 389                             (narrow-to-region (point-min) delimline)
 390                             (mail-fetch-field "From")))
 391                          (user-login-name))))
 392                  (progn
 393                    (forward-line 1)
 394                    (insert "Sender: " (user-login-name) "\n")))
 395             ;; "S:" is an abbreviation for "Subject:".
 396             (goto-char (point-min))
 397             (if (re-search-forward "^S:" delimline t)
 398                 (replace-match "Subject:"))
 399             ;; Don't send out a blank subject line
 400             (goto-char (point-min))
 401             (if (re-search-forward "^Subject:[ \t]*\n" delimline t)
 402                 (replace-match ""))
 403             (if mail-interactive
 404                 (save-excursion
 405                   (set-buffer errbuf)
 406                   (erase-buffer))))
 407           (apply 'call-process-region
 408                  (append (list (point-min) (point-max)
 409                                (if (boundp 'sendmail-program)
 410                                    sendmail-program
 411                                  "/usr/lib/sendmail")
 412                                nil errbuf nil
 413                                "-oi" "-t")
 414                          ;; Always specify who from,
 415                          ;; since some systems have broken sendmails.
 416                          (list "-f" (user-login-name))
 417 ;;;                      ;; Don't say "from root" if running under su.
 418 ;;;                      (and (equal (user-real-login-name) "root")
 419 ;;;                           (list "-f" (user-login-name)))
 420                          (and mail-alias-file
 421                               (list (concat "-oA" mail-alias-file)))
 422                          ;; These mean "report errors by mail"
 423                          ;; and "deliver in background".
 424                          (if (null mail-interactive) '("-oem" "-odb"))))
 425           (if mail-interactive
 426               (save-excursion
 427                 (set-buffer errbuf)
 428                 (goto-char (point-min))
 429                 (while (re-search-forward "\n\n* *" nil t)
 430                   (replace-match "; "))
 431                 (if (not (zerop (buffer-size)))
 432                     (error "Sending...failed to %s"
 433                            (buffer-substring (point-min) (point-max)))))))
 434       (kill-buffer tembuf)
 435       (if (bufferp errbuf)
 436           (kill-buffer errbuf)))))
 437
 438 (defun mail-do-fcc (header-end)
 439   (let (fcc-list
 440         (rmailbuf (current-buffer))
 441         (time (current-time))
 442         (tembuf (generate-new-buffer " rmail output"))
 443         (case-fold-search t))
 444     (save-excursion
 445       (goto-char (point-min))
 446       (while (re-search-forward "^FCC:[ \t]*" header-end t)
 447         (setq fcc-list (cons (buffer-substring (point)
 448                                                (progn
 449                                                  (end-of-line)
 450                                                  (skip-chars-backward " \t")
 451                                                  (point)))
 452                              fcc-list))
 453         (delete-region (match-beginning 0)
 454                        (progn (forward-line 1) (point))))
 455       (set-buffer tembuf)
 456       (erase-buffer)
 457       ;; This initial newline is written out if the fcc file already exists.
 458       (insert "\nFrom " (user-login-name) " "
 459               (current-time-string time) "\n")
 460       ;; Insert the time zone before the year.
 461       (forward-char -1)
 462       (forward-word -1)
 463       (require 'mail-utils)
 464       (insert (mail-rfc822-time-zone time) " ")
 465       (goto-char (point-max))
 466       (insert-buffer-substring rmailbuf)
 467       ;; Make sure messages are separated.
 468       (goto-char (point-max))
 469       (insert ?\n)
 470       (goto-char 2)
 471       ;; ``Quote'' "^From " as ">From "
 472       ;;  (note that this isn't really quoting, as there is no requirement
 473       ;;   that "^[>]+From " be quoted in the same transparent way.)
 474       (let ((case-fold-search nil))
 475         (while (search-forward "\nFrom " nil t)
 476           (forward-char -5)
 477           (insert ?>)))
 478       (while fcc-list
 479         (let ((buffer (get-file-buffer (car fcc-list))))
 480           (if buffer
 481               ;; File is present in a buffer => append to that buffer.
 482               (let ((curbuf (current-buffer))
 483                     (beg (point-min)) (end (point-max))
 484                     (beg2 (save-excursion (goto-char (point-min))
 485                                           (forward-line 2) (point))))
 486                 (save-excursion
 487                   (set-buffer buffer)
 488                   ;; Keep the end of the accessible portion at the same place
 489                   ;; unless it is the end of the buffer.
 490                   (let ((max (if (/= (1+ (buffer-size)) (point-max))
 491                                  (point-max))))
 492                     (unwind-protect
 493                         ;; Code below lifted from rmailout.el
 494                         ;; function rmail-output-to-rmail-file:
 495                         (let ((buffer-read-only nil)
 496                               (msg (and (boundp 'rmail-current-message)
 497                                         rmail-current-message)))
 498                           ;; If MSG is non-nil, buffer is in RMAIL mode.
 499                           (if msg
 500                               (progn
 501                                 (rmail-maybe-set-message-counters)
 502                                 (widen)
 503                                 (narrow-to-region (point-max) (point-max))
 504                                 (insert "\C-l\n0, unseen,,\n*** EOOH ***\n"
 505                                         "From: " (user-login-name) "\n"
 506                                         "Date: " (mail-rfc822-date) "\n")
 507                                 (insert-buffer-substring curbuf beg2 end)
 508                                 (insert "\n\C-_")
 509                                 (goto-char (point-min))
 510                                 (widen)
 511                                 (search-backward "\n\^_")
 512                                 (narrow-to-region (point) (point-max))
 513                                 (rmail-count-new-messages t)
 514                                 (rmail-show-message msg)
 515                                 (setq max nil))
 516                             ;; Output file not in rmail mode
 517                             ;; => just insert at the end.
 518                             (narrow-to-region (point-min) (1+ (buffer-size)))
 519                             (goto-char (point-max))
 520                             (insert-buffer-substring curbuf beg end)))
 521                       (if max (narrow-to-region (point-min) max))))))
 522             ;; Else append to the file directly.
 523             (write-region
 524              ;; Include a blank line before if file already exists.
 525
 526              (if (file-exists-p (car fcc-list)) (point-min) (1+ (point-min)))
 527              (point-max) (car fcc-list) t)))
 528         (setq fcc-list (cdr fcc-list))))
 529     (kill-buffer tembuf)))
 530
 531 (defun mail-sent-via ()
 532   "Make a Sent-via header line from each To or CC header line."
 533   (interactive)
 534   (save-excursion
 535     (goto-char (point-min))
 536     ;; find the header-separator
 537     (search-forward (concat "\n" mail-header-separator "\n"))
 538     (forward-line -1)
 539     ;; put a marker at the end of the header
 540     (let ((end (point-marker))
 541           (case-fold-search t)
 542           to-line)
 543       (goto-char (point-min))
 544       ;; search for the To: lines and make Sent-via: lines from them
 545       ;; search for the next To: line
 546       (while (re-search-forward "^\\(to\\|cc\\):" end t)
 547         ;; Grab this line plus all its continuations, sans the `to:'.
 548         (let ((to-line
 549                (buffer-substring (point)
 550                                  (progn
 551                                    (if (re-search-forward "^[^ \t\n]" end t)
 552                                        (backward-char 1)
 553                                      (goto-char end))
 554                                    (point)))))
 555           ;; Insert a copy, with altered header field name.
 556           (insert-before-markers "Sent-via:" to-line))))))
 557 \f
 558 (defun mail-to ()
 559   "Move point to end of To-field."
 560   (interactive)
 561   (expand-abbrev)
 562   (mail-position-on-field "To"))
 563
 564 (defun mail-subject ()
 565   "Move point to end of Subject-field."
 566   (interactive)
 567   (expand-abbrev)
 568   (mail-position-on-field "Subject"))
 569
 570 (defun mail-cc ()
 571   "Move point to end of CC-field.  Create a CC field if none."
 572   (interactive)
 573   (expand-abbrev)
 574   (or (mail-position-on-field "cc" t)
 575       (progn (mail-position-on-field "to")
 576              (insert "\nCC: "))))
 577
 578 (defun mail-bcc ()
 579   "Move point to end of BCC-field.  Create a BCC field if none."
 580   (interactive)
 581   (expand-abbrev)
 582   (or (mail-position-on-field "bcc" t)
 583       (progn (mail-position-on-field "to")
 584              (insert "\nBCC: "))))
 585
 586 (defun mail-fcc ()
 587   "Add a new FCC field, with file name completion."
 588   (interactive)
 589   (expand-abbrev)
 590   (or (mail-position-on-field "fcc" t)  ;Put new field after exiting FCC.
 591       (mail-position-on-field "to"))
 592   (insert "\nFCC: " (read-file-name "Folder carbon copy: ")))
 593
 594 (defun mail-position-on-field (field &optional soft)
 595   (let (end
 596         (case-fold-search t))
 597     (goto-char (point-min))
 598     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "\n"))
 599     (setq end (match-beginning 0))
 600     (goto-char (point-min))
 601     (if (re-search-forward (concat "^" (regexp-quote field) ":") end t)
 602         (progn
 603           (re-search-forward "^[^ \t]" nil 'move)
 604           (beginning-of-line)
 605           (skip-chars-backward "\n")
 606           t)
 607       (or soft
 608           (progn (goto-char end)
 609                  (insert field ": \n")
 610                  (skip-chars-backward "\n")))
 611       nil)))
 612
 613 (defun mail-text ()
 614   "Move point to beginning of text field."
 615   (interactive)
 616   (goto-char (point-min))
 617   (search-forward (concat "\n" mail-header-separator "\n")))
 618 \f
 619 (defun mail-signature (atpoint)
 620   "Sign letter with contents of `mail-signature-file'."
 621   (interactive "P")
 622   (save-excursion
 623     (or atpoint
 624         (goto-char (point-max)))
 625     (skip-chars-backward " \t\n")
 626     (end-of-line)
 627     (or atpoint
 628         (delete-region (point) (point-max)))
 629     (insert "\n\n")
 630     (insert-file-contents (expand-file-name "~/.signature"))))
 631
 632 (defun mail-fill-yanked-message (&optional justifyp)
 633   "Fill the paragraphs of a message yanked into this one.
 634 Numeric argument means justify as well."
 635   (interactive "P")
 636   (save-excursion
 637     (goto-char (point-min))
 638     (search-forward (concat "\n" mail-header-separator "\n") nil t)
 639     (fill-individual-paragraphs (point)
 640                                 (point-max)
 641                                 justifyp
 642                                 t)))
 643
 644 (defun mail-indent-citation ()
 645   "Modify text just inserted from a message to be cited.
 646 The inserted text should be the region.
 647 When this function returns, the region is again around the modified text.
 648
 649 Normally, indent each nonblank line `mail-indentation-spaces' spaces.
 650 However, if `mail-yank-prefix' is non-nil, insert that prefix on each line."
 651   (let ((start (point)))
 652     (mail-yank-clear-headers start (mark t))
 653     (if (null mail-yank-prefix)
 654         (indent-rigidly start (mark t) mail-indentation-spaces)
 655       (save-excursion
 656         (goto-char start)
 657         (while (< (point) (mark t))
 658           (insert mail-yank-prefix)
 659           (forward-line 1))))))
 660
 661 (defun mail-yank-original (arg)
 662   "Insert the message being replied to, if any (in rmail).
 663 Puts point before the text and mark after.
 664 Normally, indents each nonblank line ARG spaces (default 3).
 665 However, if `mail-yank-prefix' is non-nil, insert that prefix on each line.
 666
 667 Just \\[universal-argument] as argument means don't indent, insert no prefix,
 668 and don't delete any header fields."
 669   (interactive "P")
 670   (if mail-reply-buffer
 671       (let ((start (point)))
 672         (delete-windows-on mail-reply-buffer)
 673         (insert-buffer mail-reply-buffer)
 674         (if (consp arg)
 675             nil
 676           (goto-char start)
 677           (let ((mail-indentation-spaces (if arg (prefix-numeric-value arg)
 678                                            mail-indentation-spaces)))
 679             (if mail-citation-hook
 680                 (run-hooks 'mail-citation-hook)
 681               (run-hooks 'mail-yank-hooks))))
 682         ;; This is like exchange-point-and-mark, but doesn't activate the mark.
 683         ;; It is cleaner to avoid activation, even though the command
 684         ;; loop would deactivate the mark because we inserted text.
 685         (goto-char (prog1 (mark t)
 686                      (set-marker (mark-marker) (point) (current-buffer))))
 687         (if (not (eolp)) (insert ?\n)))))
 688
 689 (defun mail-yank-clear-headers (start end)
 690   (save-excursion
 691     (goto-char start)
 692     (if (search-forward "\n\n" end t)
 693         (save-restriction
 694           (narrow-to-region start (point))
 695           (goto-char start)
 696           (while (let ((case-fold-search t))
 697                    (re-search-forward mail-yank-ignored-headers nil t))
 698             (beginning-of-line)
 699             (delete-region (point)
 700                            (progn (re-search-forward "\n[^ \t]")
 701                                   (forward-char -1)
 702                                   (point))))))))
 703 \f
 704 ;; Put these last, to reduce chance of lossage from quitting in middle of loading the file.
 705
 706 ;;;###autoload
 707 (defun mail (&optional noerase to subject in-reply-to cc replybuffer actions)
 708   "Edit a message to be sent.  Prefix arg means resume editing (don't erase).
 709 When this function returns, the buffer `*mail*' is selected.
 710 The value is t if the message was newly initialized; otherwise, nil.
 711
 712 By default, the signature file `~/.signature' is inserted at the end;
 713 see the variable `mail-signature'.
 714
 715 \\<mail-mode-map>
 716 While editing message, type \\[mail-send-and-exit] to send the message and exit.
 717
 718 Various special commands starting with C-c are available in sendmail mode
 719 to move to message header fields:
 720 \\{mail-mode-map}
 721
 722 If `mail-self-blind' is non-nil, a BCC to yourself is inserted
 723 when the message is initialized.
 724
 725 If `mail-default-reply-to' is non-nil, it should be an address (a string);
 726 a Reply-to: field with that address is inserted.
 727
 728 If `mail-archive-file-name' is non-nil, an FCC field with that file name
 729 is inserted.
 730
 731 If `mail-setup-hook' is bound, its value is called with no arguments
 732 after the message is initialized.  It can add more default fields.
 733
 734 When calling from a program, the second through fifth arguments
 735  TO, SUBJECT, IN-REPLY-TO and CC specify if non-nil
 736  the initial contents of those header fields.
 737  These arguments should not have final newlines.
 738 The sixth argument REPLYBUFFER is a buffer whose contents
 739  should be yanked if the user types C-c C-y.
 740 The seventh argument ACTIONS is a list of actions to take
 741  if/when the message is sent.  Each action looks like (FUNCTION . ARGS);
 742  when the message is sent, we apply FUNCTION to ARGS.
 743  This is how Rmail arranges to mark messages `answered'."
 744   (interactive "P")
 745 ;;; This is commented out because I found it was confusing in practice.
 746 ;;; It is easy enough to rename *mail* by hand with rename-buffer
 747 ;;; if you want to have multiple mail buffers.
 748 ;;; And then you can control which messages to save. --rms.
 749 ;;;  (let ((index 1)
 750 ;;;     buffer)
 751 ;;;    ;; If requested, look for a mail buffer that is modified and go to it.
 752 ;;;    (if noerase
 753 ;;;     (progn
 754 ;;;       (while (and (setq buffer
 755 ;;;                         (get-buffer (if (= 1 index) "*mail*"
 756 ;;;                                       (format "*mail*<%d>" index))))
 757 ;;;                   (not (buffer-modified-p buffer)))
 758 ;;;         (setq index (1+ index)))
 759 ;;;       (if buffer (switch-to-buffer buffer)
 760 ;;;         ;; If none exists, start a new message.
 761 ;;;         ;; This will never re-use an existing unmodified mail buffer
 762 ;;;         ;; (since index is not 1 anymore).  Perhaps it should.
 763 ;;;         (setq noerase nil))))
 764 ;;;    ;; Unless we found a modified message and are happy, start a new message.
 765 ;;;    (if (not noerase)
 766 ;;;     (progn
 767 ;;;       ;; Look for existing unmodified mail buffer.
 768 ;;;       (while (and (setq buffer
 769 ;;;                         (get-buffer (if (= 1 index) "*mail*"
 770 ;;;                                       (format "*mail*<%d>" index))))
 771 ;;;                   (buffer-modified-p buffer))
 772 ;;;         (setq index (1+ index)))
 773 ;;;       ;; If none, make a new one.
 774 ;;;       (or buffer
 775 ;;;           (setq buffer (generate-new-buffer "*mail*")))
 776 ;;;       ;; Go there and initialize it.
 777 ;;;       (switch-to-buffer buffer)
 778 ;;;       (erase-buffer)
 779 ;;;          (setq default-directory (expand-file-name "~/"))
 780 ;;;          (auto-save-mode auto-save-default)
 781 ;;;          (mail-mode)
 782 ;;;          (mail-setup to subject in-reply-to cc replybuffer actions)
 783 ;;;       (if (and buffer-auto-save-file-name
 784 ;;;                (file-exists-p buffer-auto-save-file-name))
 785 ;;;           (message "Auto save file for draft message exists; consider M-x mail-recover"))
 786 ;;;          t))
 787   (switch-to-buffer "*mail*")
 788   (setq default-directory (expand-file-name "~/"))
 789   (auto-save-mode auto-save-default)
 790   (mail-mode)
 791   (let (initialized)
 792     (and (not noerase)
 793          (or (not (buffer-modified-p))
 794              (y-or-n-p "Unsent message being composed; erase it? "))
 795          (progn (erase-buffer)
 796                 (mail-setup to subject in-reply-to cc replybuffer actions)
 797                 (setq initialized t)))
 798     (if (and buffer-auto-save-file-name
 799              (file-exists-p buffer-auto-save-file-name))
 800         (message "Auto save file for draft message exists; consider M-x mail-recover"))
 801     initialized))
 802
 803 (defun mail-recover ()
 804   "Reread contents of current buffer from its last auto-save file."
 805   (interactive)
 806   (let ((file-name (make-auto-save-file-name)))
 807     (cond ((save-window-excursion
 808              (if (not (eq system-type 'vax-vms))
 809                  (with-output-to-temp-buffer "*Directory*"
 810                    (buffer-disable-undo standard-output)
 811                    (call-process "ls" nil standard-output nil "-l" file-name)))
 812              (yes-or-no-p (format "Recover auto save file %s? " file-name)))
 813            (let ((buffer-read-only nil))
 814              (erase-buffer)
 815              (insert-file-contents file-name nil)))
 816           (t (error "mail-recover cancelled.")))))
 817
 818 ;;;###autoload
 819 (defun mail-other-window (&optional noerase to subject in-reply-to cc replybuffer sendactions)
 820   "Like `mail' command, but display mail buffer in another window."
 821   (interactive "P")
 822   (let ((pop-up-windows t))
 823     (pop-to-buffer "*mail*"))
 824   (mail noerase to subject in-reply-to cc replybuffer sendactions))
 825
 826 ;;;###autoload
 827 (defun mail-other-frame (&optional noerase to subject in-reply-to cc replybuffer sendactions)
 828   "Like `mail' command, but display mail buffer in another frame."
 829   (interactive "P")
 830   (let ((pop-up-frames t))
 831     (pop-to-buffer "*mail*"))
 832   (mail noerase to subject in-reply-to cc replybuffer sendactions))
 833
 834 ;;; Do not execute these when sendmail.el is loaded,
 835 ;;; only in loaddefs.el.
 836 ;;;###autoload (define-key ctl-x-map "m" 'mail)
 837 ;;;###autoload (define-key ctl-x-4-map "m" 'mail-other-window)
 838 ;;;###autoload (define-key ctl-x-5-map "m" 'mail-other-frame)
 839
 840 ;;; Do not add anything but external entries on this page.
 841
 842 (provide 'sendmail)
 843
 844 ;;; sendmail.el ends here