code.delx.au - gnu-emacs/blob - lisp/gnus/gnus-msg.el

   1 ;;; gnus-msg.el --- mail and post interface for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Masanobu UMEDA <umerin@flab.flab.fujitsu.junet>
   6 ;;      Lars Magne Ingebrigtsen <larsi@gnus.org>
   7 ;; Keywords: news
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl))
  31
  32 (require 'gnus)
  33 (require 'gnus-ems)
  34 (require 'message)
  35 (require 'gnus-art)
  36 (require 'gnus-util)
  37
  38 (defcustom gnus-post-method 'current
  39   "*Preferred method for posting USENET news.
  40
  41 If this variable is `current' (which is the default), Gnus will use
  42 the \"current\" select method when posting.  If it is `native', Gnus
  43 will use the native select method when posting.
  44
  45 This method will not be used in mail groups and the like, only in
  46 \"real\" newsgroups.
  47
  48 If not `native' nor `current', the value must be a valid method as discussed
  49 in the documentation of `gnus-select-method'.  It can also be a list of
  50 methods.  If that is the case, the user will be queried for what select
  51 method to use when posting."
  52   :group 'gnus-group-foreign
  53   :link '(custom-manual "(gnus)Posting Server")
  54   :type `(choice (const native)
  55                  (const current)
  56                  (sexp :tag "Methods" ,gnus-select-method)))
  57
  58 (defcustom gnus-outgoing-message-group nil
  59   "*All outgoing messages will be put in this group.
  60 If you want to store all your outgoing mail and articles in the group
  61 \"nnml:archive\", you set this variable to that value.  This variable
  62 can also be a list of group names.
  63
  64 If you want to have greater control over what group to put each
  65 message in, you can set this variable to a function that checks the
  66 current newsgroup name and then returns a suitable group name (or list
  67 of names)."
  68   :group 'gnus-message
  69   :type '(choice (string :tag "Group")
  70                  (function)))
  71
  72 (defcustom gnus-mailing-list-groups nil
  73   "*If non-nil a regexp matching groups that are really mailing lists.
  74 This is useful when you're reading a mailing list that has been
  75 gatewayed to a newsgroup, and you want to followup to an article in
  76 the group."
  77   :group 'gnus-message
  78   :type '(choice (regexp)
  79                  (const nil)))
  80
  81 (defcustom gnus-add-to-list nil
  82   "*If non-nil, add a `to-list' parameter automatically."
  83   :group 'gnus-message
  84   :type 'boolean)
  85
  86 (defcustom gnus-crosspost-complaint
  87   "Hi,
  88
  89 You posted the article below with the following Newsgroups header:
  90
  91 Newsgroups: %s
  92
  93 The %s group, at least, was an inappropriate recipient
  94 of this message.  Please trim your Newsgroups header to exclude this
  95 group before posting in the future.
  96
  97 Thank you.
  98
  99 "
 100   "Format string to be inserted when complaining about crossposts.
 101 The first %s will be replaced by the Newsgroups header;
 102 the second with the current group name."
 103   :group 'gnus-message
 104   :type 'string)
 105
 106 (defcustom gnus-message-setup-hook nil
 107   "Hook run after setting up a message buffer."
 108   :group 'gnus-message
 109   :type 'hook)
 110
 111 (defcustom gnus-bug-create-help-buffer t
 112   "*Should we create the *Gnus Help Bug* buffer?"
 113   :group 'gnus-message
 114   :type 'boolean)
 115
 116 (defcustom gnus-posting-styles nil
 117   "*Alist of styles to use when posting.
 118 See Info node `(gnus)Posting Styles'."
 119   :group 'gnus-message
 120   :link '(custom-manual "(gnus)Posting Styles")
 121   :type '(repeat (cons (choice (regexp)
 122                                (variable)
 123                                (list (const header)
 124                                      (string :tag "Header")
 125                                      (regexp :tag "Regexp"))
 126                                (function)
 127                                (sexp))
 128                        (repeat (list
 129                                 (choice (const signature)
 130                                         (const signature-file)
 131                                         (const organization)
 132                                         (const address)
 133                                         (const x-face-file)
 134                                         (const name)
 135                                         (const body)
 136                                         (symbol)
 137                                         (string :tag "Header"))
 138                                 (choice (string)
 139                                         (function)
 140                                         (variable)
 141                                         (sexp)))))))
 142
 143 (defcustom gnus-gcc-mark-as-read nil
 144   "If non-nil, automatically mark Gcc articles as read."
 145   :version "22.1"
 146   :group 'gnus-message
 147   :type 'boolean)
 148
 149 (make-obsolete-variable 'gnus-inews-mark-gcc-as-read
 150                         'gnus-gcc-mark-as-read)
 151
 152 (defcustom gnus-gcc-externalize-attachments nil
 153   "Should local-file attachments be included as external parts in Gcc copies?
 154 If it is `all', attach files as external parts;
 155 if a regexp and matches the Gcc group name, attach files as external parts;
 156 if nil, attach files as normal parts."
 157   :version "22.1"
 158   :group 'gnus-message
 159   :type '(choice (const nil :tag "None")
 160                  (const all :tag "Any")
 161                  (string :tag "Regexp")))
 162
 163 (gnus-define-group-parameter
 164  posting-charset-alist
 165  :type list
 166  :function-document
 167  "Return the permitted unencoded charsets for posting of GROUP."
 168  :variable gnus-group-posting-charset-alist
 169  :variable-default
 170   '(("^\\(no\\|fr\\)\\.[^,]*\\(,[ \t\n]*\\(no\\|fr\\)\\.[^,]*\\)*$" iso-8859-1 (iso-8859-1))
 171     ("^\\(fido7\\|relcom\\)\\.[^,]*\\(,[ \t\n]*\\(fido7\\|relcom\\)\\.[^,]*\\)*$" koi8-r (koi8-r))
 172     (message-this-is-mail nil nil)
 173     (message-this-is-news nil t))
 174  :variable-document
 175   "Alist of regexps and permitted unencoded charsets for posting.
 176 Each element of the alist has the form (TEST HEADER BODY-LIST), where
 177 TEST is either a regular expression matching the newsgroup header or a
 178 variable to query,
 179 HEADER is the charset which may be left unencoded in the header (nil
 180 means encode all charsets),
 181 BODY-LIST is a list of charsets which may be encoded using 8bit
 182 content-transfer encoding in the body, or one of the special values
 183 nil (always encode using quoted-printable) or t (always use 8bit).
 184
 185 Note that any value other than nil for HEADER infringes some RFCs, so
 186 use this option with care."
 187  :variable-group gnus-charset
 188  :variable-type
 189  '(repeat (list :tag "Permitted unencoded charsets"
 190                 (choice :tag "Where"
 191                         (regexp :tag "Group")
 192                         (const :tag "Mail message" :value message-this-is-mail)
 193                         (const :tag "News article" :value message-this-is-news))
 194                 (choice :tag "Header"
 195                         (const :tag "None" nil)
 196                         (symbol :tag "Charset"))
 197                 (choice :tag "Body"
 198                         (const :tag "Any" :value t)
 199                         (const :tag "None" :value nil)
 200                         (repeat :tag "Charsets"
 201                                 (symbol :tag "Charset")))))
 202  :parameter-type '(choice :tag "Permitted unencoded charsets"
 203                           :value nil
 204                           (repeat (symbol)))
 205  :parameter-document       "\
 206 List of charsets that are permitted to be unencoded.")
 207
 208 (defcustom gnus-debug-files
 209   '("gnus.el" "gnus-sum.el" "gnus-group.el"
 210     "gnus-art.el" "gnus-start.el" "gnus-async.el"
 211     "gnus-msg.el" "gnus-score.el" "gnus-win.el" "gnus-topic.el"
 212     "gnus-agent.el" "gnus-cache.el" "gnus-srvr.el"
 213     "mm-util.el" "mm-decode.el" "nnmail.el" "message.el")
 214   "Files whose variables will be reported in `gnus-bug'."
 215   :version "22.1"
 216   :group 'gnus-message
 217   :type '(repeat (string :tag "File")))
 218
 219 (defcustom gnus-debug-exclude-variables
 220   '(mm-mime-mule-charset-alist
 221     nnmail-split-fancy message-minibuffer-local-map)
 222   "Variables that should not be reported in `gnus-bug'."
 223   :version "22.1"
 224   :group 'gnus-message
 225   :type '(repeat (symbol :tag "Variable")))
 226
 227 (defcustom gnus-discouraged-post-methods
 228   '(nndraft nnml nnimap nnmaildir nnmh nnfolder nndir)
 229   "A list of back ends that are not used in \"real\" newsgroups.
 230 This variable is used only when `gnus-post-method' is `current'."
 231   :version "22.1"
 232   :group 'gnus-group-foreign
 233   :type '(repeat (symbol :tag "Back end")))
 234
 235 (defcustom gnus-message-replysign
 236   nil
 237   "Automatically sign replies to signed messages.
 238 See also the `mml-default-sign-method' variable."
 239   :group 'gnus-message
 240   :type 'boolean)
 241
 242 (defcustom gnus-message-replyencrypt
 243   nil
 244   "Automatically encrypt replies to encrypted messages.
 245 See also the `mml-default-encrypt-method' variable."
 246   :group 'gnus-message
 247   :type 'boolean)
 248
 249 (defcustom gnus-message-replysignencrypted
 250   t
 251   "Setting this causes automatically encrypted messages to also be signed."
 252   :group 'gnus-message
 253   :type 'boolean)
 254
 255 (defcustom gnus-confirm-mail-reply-to-news nil
 256   "If non-nil, Gnus requests confirmation when replying to news.
 257 This is done because new users often reply by mistake when reading
 258 news.
 259 This can also be a function receiving the group name as the only
 260 parameter which should return non-nil iff a confirmation is needed, or
 261 a regexp, in which case a confirmation is asked for iff the group name
 262 matches the regexp."
 263   :version "22.1"
 264   :group 'gnus-message
 265   :type '(choice (const :tag "No" nil)
 266                  (const :tag "Yes" t)
 267                  (regexp :tag "Iff group matches regexp")
 268                  (function :tag "Iff function evaluates to non-nil")))
 269
 270 (defcustom gnus-confirm-treat-mail-like-news
 271   nil
 272   "If non-nil, Gnus will treat mail like news with regard to confirmation
 273 when replying by mail.  See the `gnus-confirm-mail-reply-to-news' variable
 274 for fine-tuning this.
 275 If nil, Gnus will never ask for confirmation if replying to mail."
 276   :version "22.1"
 277   :group 'gnus-message
 278   :type 'boolean)
 279
 280 (defcustom gnus-summary-resend-default-address t
 281   "If non-nil, Gnus tries to suggest a default address to resend to.
 282 If nil, the address field will always be empty after invoking
 283 `gnus-summary-resend-message'."
 284   :version "22.1"
 285   :group 'gnus-message
 286   :type 'boolean)
 287
 288 ;;; Internal variables.
 289
 290 (defvar gnus-inhibit-posting-styles nil
 291   "Inhibit the use of posting styles.")
 292
 293 (defvar gnus-article-yanked-articles nil)
 294 (defvar gnus-message-buffer "*Mail Gnus*")
 295 (defvar gnus-article-copy nil)
 296 (defvar gnus-check-before-posting nil)
 297 (defvar gnus-last-posting-server nil)
 298 (defvar gnus-message-group-art nil)
 299
 300 (defvar gnus-msg-force-broken-reply-to nil)
 301
 302 (defconst gnus-bug-message
 303   "Sending a bug report to the Gnus Towers.
 304 ========================================
 305
 306 The buffer below is a mail buffer.  When you press `C-c C-c', it will
 307 be sent to the Gnus Bug Exterminators.
 308
 309 The thing near the bottom of the buffer is how the environment
 310 settings will be included in the mail.  Please do not delete that.
 311 They will tell the Bug People what your environment is, so that it
 312 will be easier to locate the bugs.
 313
 314 If you have found a bug that makes Emacs go \"beep\", set
 315 debug-on-error to t (`M-x set-variable RET debug-on-error RET t RET')
 316 and include the backtrace in your bug report.
 317
 318 Please describe the bug in annoying, painstaking detail.
 319
 320 Thank you for your help in stamping out bugs.
 321 ")
 322
 323 (eval-and-compile
 324   (autoload 'gnus-uu-post-news "gnus-uu" nil t)
 325   (autoload 'news-setup "rnewspost")
 326   (autoload 'news-reply-mode "rnewspost")
 327   (autoload 'rmail-dont-reply-to "mail-utils")
 328   (autoload 'rmail-output "rmailout"))
 329
 330 \f
 331 ;;;
 332 ;;; Gnus Posting Functions
 333 ;;;
 334
 335 (gnus-define-keys (gnus-summary-send-map "S" gnus-summary-mode-map)
 336   "p" gnus-summary-post-news
 337   "i" gnus-summary-news-other-window
 338   "f" gnus-summary-followup
 339   "F" gnus-summary-followup-with-original
 340   "c" gnus-summary-cancel-article
 341   "s" gnus-summary-supersede-article
 342   "r" gnus-summary-reply
 343   "y" gnus-summary-yank-message
 344   "R" gnus-summary-reply-with-original
 345   "w" gnus-summary-wide-reply
 346   "W" gnus-summary-wide-reply-with-original
 347   "v" gnus-summary-very-wide-reply
 348   "V" gnus-summary-very-wide-reply-with-original
 349   "n" gnus-summary-followup-to-mail
 350   "N" gnus-summary-followup-to-mail-with-original
 351   "m" gnus-summary-mail-other-window
 352   "u" gnus-uu-post-news
 353   "\M-c" gnus-summary-mail-crosspost-complaint
 354   "Br" gnus-summary-reply-broken-reply-to
 355   "BR" gnus-summary-reply-broken-reply-to-with-original
 356   "om" gnus-summary-mail-forward
 357   "op" gnus-summary-post-forward
 358   "Om" gnus-uu-digest-mail-forward
 359   "Op" gnus-uu-digest-post-forward)
 360
 361 (gnus-define-keys (gnus-send-bounce-map "D" gnus-summary-send-map)
 362   "b" gnus-summary-resend-bounced-mail
 363   ;; "c" gnus-summary-send-draft
 364   "r" gnus-summary-resend-message
 365   "e" gnus-summary-resend-message-edit)
 366
 367 ;;; Internal functions.
 368
 369 (defun gnus-inews-make-draft ()
 370   `(lambda ()
 371      (gnus-inews-make-draft-meta-information
 372       ,gnus-newsgroup-name ',gnus-article-reply)))
 373
 374 (defvar gnus-article-reply nil)
 375 (defmacro gnus-setup-message (config &rest forms)
 376   (let ((winconf (make-symbol "gnus-setup-message-winconf"))
 377         (buffer (make-symbol "gnus-setup-message-buffer"))
 378         (article (make-symbol "gnus-setup-message-article"))
 379         (yanked (make-symbol "gnus-setup-yanked-articles"))
 380         (group (make-symbol "gnus-setup-message-group")))
 381     `(let ((,winconf (current-window-configuration))
 382            (,buffer (buffer-name (current-buffer)))
 383            (,article gnus-article-reply)
 384            (,yanked gnus-article-yanked-articles)
 385            (,group gnus-newsgroup-name)
 386            (message-header-setup-hook
 387             (copy-sequence message-header-setup-hook))
 388            (mbl mml-buffer-list)
 389            (message-mode-hook (copy-sequence message-mode-hook)))
 390        (setq mml-buffer-list nil)
 391        (add-hook 'message-header-setup-hook 'gnus-inews-insert-gcc)
 392        (add-hook 'message-header-setup-hook 'gnus-inews-insert-archive-gcc)
 393        ;; #### FIXME: for a reason that I did not manage to identify yet,
 394        ;; the variable `gnus-newsgroup-name' does not honor a dynamically
 395        ;; scoped or setq'ed value from a caller like `C-u gnus-summary-mail'.
 396        ;; After evaluation of @forms below, it gets the value we actually want
 397        ;; to override, and the posting styles are used. For that reason, I've
 398        ;; added an optional argument to `gnus-configure-posting-styles' to
 399        ;; make sure that the correct value for the group name is used. -- drv
 400        (add-hook 'message-mode-hook
 401                  (if (memq ,config '(reply-yank reply))
 402                      (lambda ()
 403                        (gnus-configure-posting-styles ,group))
 404                    (lambda ()
 405                      ;; There may be an old " *gnus article copy*" buffer.
 406                      (let (gnus-article-copy)
 407                        (gnus-configure-posting-styles ,group)))))
 408        (gnus-pull ',(intern gnus-draft-meta-information-header)
 409                   message-required-headers)
 410        (when (and ,group
 411                   (not (string= ,group "")))
 412          (push (cons
 413                 (intern gnus-draft-meta-information-header)
 414                 (gnus-inews-make-draft))
 415                message-required-headers))
 416        (unwind-protect
 417            (progn
 418              ,@forms)
 419          (gnus-inews-add-send-actions ,winconf ,buffer ,article ,config
 420                                       ,yanked)
 421          (setq gnus-message-buffer (current-buffer))
 422          (set (make-local-variable 'gnus-message-group-art)
 423               (cons ,group ,article))
 424          (set (make-local-variable 'gnus-newsgroup-name) ,group)
 425          (gnus-run-hooks 'gnus-message-setup-hook)
 426          (if (eq major-mode 'message-mode)
 427              (let ((mbl1 mml-buffer-list))
 428                (setq mml-buffer-list mbl)  ;; Global value
 429                (set (make-local-variable 'mml-buffer-list) mbl1);; Local value
 430                (gnus-make-local-hook 'kill-buffer-hook)
 431                (gnus-make-local-hook 'change-major-mode-hook)
 432                (add-hook 'change-major-mode-hook 'mml-destroy-buffers nil t)
 433                (add-hook 'kill-buffer-hook 'mml-destroy-buffers t t))
 434            (mml-destroy-buffers)
 435            (setq mml-buffer-list mbl)))
 436        (message-hide-headers)
 437        (gnus-add-buffer)
 438        (gnus-configure-windows ,config t)
 439        (run-hooks 'post-command-hook)
 440        (set-buffer-modified-p nil))))
 441
 442 (defun gnus-inews-make-draft-meta-information (group article)
 443   (concat "(\"" group "\" "
 444           (if article (number-to-string
 445                        (if (listp article)
 446                            (car article)
 447                          article)) "\"\"")
 448           ")"))
 449
 450 ;;;###autoload
 451 (defun gnus-msg-mail (&optional to subject other-headers continue
 452                                 switch-action yank-action send-actions)
 453   "Start editing a mail message to be sent.
 454 Like `message-mail', but with Gnus paraphernalia, particularly the
 455 Gcc: header for archiving purposes."
 456   (interactive)
 457   (let ((buf (current-buffer))
 458         mail-buf)
 459     (gnus-setup-message 'message
 460       (message-mail to subject other-headers continue
 461                     nil yank-action send-actions))
 462     (when switch-action
 463       (setq mail-buf (current-buffer))
 464       (switch-to-buffer buf)
 465       (apply switch-action mail-buf nil)))
 466   ;; COMPOSEFUNC should return t if succeed.  Undocumented ???
 467   t)
 468
 469 ;;;###autoload
 470 (defun gnus-button-mailto (address)
 471   "Mail to ADDRESS."
 472   (set-buffer (gnus-copy-article-buffer))
 473   (gnus-setup-message 'message
 474     (message-reply address)))
 475
 476 ;;;###autoload
 477 (defun gnus-button-reply (&optional to-address wide)
 478   "Like `message-reply'."
 479   (interactive)
 480   (gnus-setup-message 'message
 481     (message-reply to-address wide)))
 482
 483 ;;;###autoload
 484 (define-mail-user-agent 'gnus-user-agent
 485   'gnus-msg-mail 'message-send-and-exit
 486   'message-kill-buffer 'message-send-hook)
 487
 488 (defun gnus-setup-posting-charset (group)
 489   (let ((alist gnus-group-posting-charset-alist)
 490         (group (or group ""))
 491         elem)
 492     (when group
 493       (catch 'found
 494         (while (setq elem (pop alist))
 495           (when (or (and (stringp (car elem))
 496                          (string-match (car elem) group))
 497                     (and (functionp (car elem))
 498                          (funcall (car elem) group))
 499                     (and (symbolp (car elem))
 500                          (symbol-value (car elem))))
 501             (throw 'found (cons (cadr elem) (caddr elem)))))))))
 502
 503 (defun gnus-inews-add-send-actions (winconf buffer article
 504                                             &optional config yanked)
 505   (gnus-make-local-hook 'message-sent-hook)
 506   (add-hook 'message-sent-hook (if gnus-agent 'gnus-agent-possibly-do-gcc
 507                                  'gnus-inews-do-gcc) nil t)
 508   (when gnus-agent
 509     (gnus-make-local-hook 'message-header-hook)
 510     (add-hook 'message-header-hook 'gnus-agent-possibly-save-gcc nil t))
 511   (setq message-post-method
 512         `(lambda (arg)
 513            (gnus-post-method arg ,gnus-newsgroup-name)))
 514   (setq message-newsreader (setq message-mailer (gnus-extended-version)))
 515   (message-add-action
 516    `(when (gnus-buffer-exists-p ,buffer)
 517       (set-window-configuration ,winconf))
 518    'exit 'postpone 'kill)
 519   (let ((to-be-marked (cond
 520                        (yanked
 521                         (mapcar
 522                          (lambda (x) (if (listp x) (car x) x)) yanked))
 523                        (article (if (listp article) article (list article)))
 524                        (t nil))))
 525     (message-add-action
 526      `(when (gnus-buffer-exists-p ,buffer)
 527         (save-excursion
 528           (set-buffer ,buffer)
 529           ,(when to-be-marked
 530              (if (eq config 'forward)
 531                  `(gnus-summary-mark-article-as-forwarded ',to-be-marked)
 532                `(gnus-summary-mark-article-as-replied ',to-be-marked)))))
 533      'send)))
 534
 535 (put 'gnus-setup-message 'lisp-indent-function 1)
 536 (put 'gnus-setup-message 'edebug-form-spec '(form body))
 537
 538 ;;; Post news commands of Gnus group mode and summary mode
 539
 540 (defun gnus-group-mail (&optional arg)
 541   "Start composing a mail.
 542 If ARG, use the group under the point to find a posting style.
 543 If ARG is 1, prompt for a group name to find the posting style."
 544   (interactive "P")
 545   ;; We can't `let' gnus-newsgroup-name here, since that leads
 546   ;; to local variables leaking.
 547   (let ((group gnus-newsgroup-name)
 548         ;; make sure last viewed article doesn't affect posting styles:
 549         (gnus-article-copy)
 550         (buffer (current-buffer)))
 551     (unwind-protect
 552         (progn
 553           (setq gnus-newsgroup-name
 554                 (if arg
 555                     (if (= 1 (prefix-numeric-value arg))
 556                         (completing-read "Use posting style of group: "
 557                                          gnus-active-hashtb nil
 558                                          (gnus-read-active-file-p))
 559                       (gnus-group-group-name))
 560                   ""))
 561           ;; #### see comment in gnus-setup-message -- drv
 562           (gnus-setup-message 'message (message-mail)))
 563       (save-excursion
 564         (set-buffer buffer)
 565         (setq gnus-newsgroup-name group)))))
 566
 567 (defun gnus-group-news (&optional arg)
 568   "Start composing a news.
 569 If ARG, post to group under point.
 570 If ARG is 1, prompt for group name to post to.
 571
 572 This function prepares a news even when using mail groups.  This is useful
 573 for posting messages to mail groups without actually sending them over the
 574 network.  The corresponding back end must have a 'request-post method."
 575   (interactive "P")
 576   ;; We can't `let' gnus-newsgroup-name here, since that leads
 577   ;; to local variables leaking.
 578   (let ((group gnus-newsgroup-name)
 579         ;; make sure last viewed article doesn't affect posting styles:
 580         (gnus-article-copy)
 581         (buffer (current-buffer)))
 582     (unwind-protect
 583         (progn
 584           (setq gnus-newsgroup-name
 585                 (if arg
 586                     (if (= 1 (prefix-numeric-value arg))
 587                         (completing-read "Use group: "
 588                                          gnus-active-hashtb nil
 589                                          (gnus-read-active-file-p))
 590                       (gnus-group-group-name))
 591                   ""))
 592           ;; #### see comment in gnus-setup-message -- drv
 593           (gnus-setup-message 'message
 594             (message-news (gnus-group-real-name gnus-newsgroup-name))))
 595       (save-excursion
 596         (set-buffer buffer)
 597         (setq gnus-newsgroup-name group)))))
 598
 599 (defun gnus-group-post-news (&optional arg)
 600   "Start composing a message (a news by default).
 601 If ARG, post to group under point.  If ARG is 1, prompt for group name.
 602 Depending on the selected group, the message might be either a mail or
 603 a news."
 604   (interactive "P")
 605   ;; Bind this variable here to make message mode hooks work ok.
 606   (let ((gnus-newsgroup-name
 607          (if arg
 608              (if (= 1 (prefix-numeric-value arg))
 609                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 610                                   (gnus-read-active-file-p))
 611                (gnus-group-group-name))
 612            ""))
 613         ;; make sure last viewed article doesn't affect posting styles:
 614         (gnus-article-copy))
 615     (gnus-post-news 'post gnus-newsgroup-name nil nil nil nil
 616                     (string= gnus-newsgroup-name ""))))
 617
 618 (defun gnus-summary-mail-other-window (&optional arg)
 619   "Start composing a mail in another window.
 620 Use the posting of the current group by default.
 621 If ARG, don't do that.  If ARG is 1, prompt for group name to find the
 622 posting style."
 623   (interactive "P")
 624   ;; We can't `let' gnus-newsgroup-name here, since that leads
 625   ;; to local variables leaking.
 626   (let ((group gnus-newsgroup-name)
 627         ;; make sure last viewed article doesn't affect posting styles:
 628         (gnus-article-copy)
 629         (buffer (current-buffer)))
 630     (unwind-protect
 631         (progn
 632           (setq gnus-newsgroup-name
 633                 (if arg
 634                     (if (= 1 (prefix-numeric-value arg))
 635                         (completing-read "Use group: "
 636                                          gnus-active-hashtb nil
 637                                          (gnus-read-active-file-p))
 638                       "")
 639                   gnus-newsgroup-name))
 640           ;; #### see comment in gnus-setup-message -- drv
 641           (gnus-setup-message 'message (message-mail)))
 642       (save-excursion
 643         (set-buffer buffer)
 644         (setq gnus-newsgroup-name group)))))
 645
 646 (defun gnus-summary-news-other-window (&optional arg)
 647   "Start composing a news in another window.
 648 Post to the current group by default.
 649 If ARG, don't do that.  If ARG is 1, prompt for group name to post to.
 650
 651 This function prepares a news even when using mail groups.  This is useful
 652 for posting messages to mail groups without actually sending them over the
 653 network.  The corresponding back end must have a 'request-post method."
 654   (interactive "P")
 655   ;; We can't `let' gnus-newsgroup-name here, since that leads
 656   ;; to local variables leaking.
 657   (let ((group gnus-newsgroup-name)
 658         ;; make sure last viewed article doesn't affect posting styles:
 659         (gnus-article-copy)
 660         (buffer (current-buffer)))
 661     (unwind-protect
 662         (progn
 663           (setq gnus-newsgroup-name
 664                 (if arg
 665                     (if (= 1 (prefix-numeric-value arg))
 666                         (completing-read "Use group: "
 667                                          gnus-active-hashtb nil
 668                                          (gnus-read-active-file-p))
 669                       "")
 670                   gnus-newsgroup-name))
 671           ;; #### see comment in gnus-setup-message -- drv
 672           (gnus-setup-message 'message
 673             (progn
 674               (message-news (gnus-group-real-name gnus-newsgroup-name))
 675               (set (make-local-variable 'gnus-discouraged-post-methods)
 676                    (delq
 677                     (car (gnus-find-method-for-group gnus-newsgroup-name))
 678                     (copy-sequence gnus-discouraged-post-methods))))))
 679       (save-excursion
 680         (set-buffer buffer)
 681         (setq gnus-newsgroup-name group)))))
 682
 683 (defun gnus-summary-post-news (&optional arg)
 684   "Start composing a message.  Post to the current group by default.
 685 If ARG, don't do that.  If ARG is 1, prompt for a group name to post to.
 686 Depending on the selected group, the message might be either a mail or
 687 a news."
 688   (interactive "P")
 689   ;; Bind this variable here to make message mode hooks work ok.
 690   (let ((gnus-newsgroup-name
 691          (if arg
 692              (if (= 1 (prefix-numeric-value arg))
 693                  (completing-read "Newsgroup: " gnus-active-hashtb nil
 694                                   (gnus-read-active-file-p))
 695                "")
 696            gnus-newsgroup-name))
 697         ;; make sure last viewed article doesn't affect posting styles:
 698         (gnus-article-copy))
 699     (gnus-post-news 'post gnus-newsgroup-name)))
 700
 701
 702 (defun gnus-summary-followup (yank &optional force-news)
 703   "Compose a followup to an article.
 704 If prefix argument YANK is non-nil, the original article is yanked
 705 automatically.
 706 YANK is a list of elements, where the car of each element is the
 707 article number, and the cdr is the string to be yanked."
 708   (interactive
 709    (list (and current-prefix-arg
 710               (gnus-summary-work-articles 1))))
 711   (when yank
 712     (gnus-summary-goto-subject
 713      (if (listp (car yank))
 714          (caar yank)
 715        (car yank))))
 716   (save-window-excursion
 717     (gnus-summary-select-article))
 718   (let ((headers (gnus-summary-article-header (gnus-summary-article-number)))
 719         (gnus-newsgroup-name gnus-newsgroup-name))
 720     ;; Send a followup.
 721     (gnus-post-news nil gnus-newsgroup-name
 722                     headers gnus-article-buffer
 723                     yank nil force-news)
 724     (gnus-summary-handle-replysign)))
 725
 726 (defun gnus-summary-followup-with-original (n &optional force-news)
 727   "Compose a followup to an article and include the original article.
 728 The text in the region will be yanked.  If the region isn't
 729 active, the entire article will be yanked."
 730   (interactive "P")
 731   (gnus-summary-followup (gnus-summary-work-articles n) force-news))
 732
 733 (defun gnus-summary-followup-to-mail (&optional arg)
 734   "Followup to the current mail message via news."
 735   (interactive
 736    (list (and current-prefix-arg
 737               (gnus-summary-work-articles 1))))
 738   (gnus-summary-followup arg t))
 739
 740 (defun gnus-summary-followup-to-mail-with-original (&optional arg)
 741   "Followup to the current mail message via news."
 742   (interactive "P")
 743   (gnus-summary-followup (gnus-summary-work-articles arg) t))
 744
 745 (defun gnus-inews-yank-articles (articles)
 746   (let (beg article yank-string)
 747     (message-goto-body)
 748     (while (setq article (pop articles))
 749       (when (listp article)
 750         (setq yank-string (nth 1 article)
 751               article (nth 0 article)))
 752       (save-window-excursion
 753         (set-buffer gnus-summary-buffer)
 754         (gnus-summary-select-article nil nil nil article)
 755         (gnus-summary-remove-process-mark article))
 756       (gnus-copy-article-buffer nil yank-string)
 757       (let ((message-reply-buffer gnus-article-copy)
 758             (message-reply-headers
 759              ;; The headers are decoded.
 760              (with-current-buffer gnus-article-copy
 761                (save-restriction
 762                  (nnheader-narrow-to-headers)
 763                  (nnheader-parse-naked-head)))))
 764         (message-yank-original)
 765         (setq beg (or beg (mark t))))
 766       (when articles
 767         (insert "\n")))
 768     (push-mark)
 769     (goto-char beg)))
 770
 771 (defun gnus-summary-cancel-article (&optional n symp)
 772   "Cancel an article you posted.
 773 Uses the process-prefix convention.  If given the symbolic
 774 prefix `a', cancel using the standard posting method; if not
 775 post using the current select method."
 776   (interactive (gnus-interactive "P\ny"))
 777   (let ((articles (gnus-summary-work-articles n))
 778         (message-post-method
 779          `(lambda (arg)
 780             (gnus-post-method (eq ',symp 'a) ,gnus-newsgroup-name)))
 781         article)
 782     (while (setq article (pop articles))
 783       (when (gnus-summary-select-article t nil nil article)
 784         (when (gnus-eval-in-buffer-window gnus-original-article-buffer
 785                 (message-cancel-news))
 786           (gnus-summary-mark-as-read article gnus-canceled-mark)
 787           (gnus-cache-remove-article 1))
 788         (gnus-article-hide-headers-if-wanted))
 789       (gnus-summary-remove-process-mark article))))
 790
 791 (defun gnus-summary-supersede-article ()
 792   "Compose an article that will supersede a previous article.
 793 This is done simply by taking the old article and adding a Supersedes
 794 header line with the old Message-ID."
 795   (interactive)
 796   (let ((article (gnus-summary-article-number)))
 797     (gnus-setup-message 'reply-yank
 798       (gnus-summary-select-article t)
 799       (set-buffer gnus-original-article-buffer)
 800       (message-supersede)
 801       (push
 802        `((lambda ()
 803            (when (gnus-buffer-exists-p ,gnus-summary-buffer)
 804              (save-excursion
 805                (set-buffer ,gnus-summary-buffer)
 806                (gnus-cache-possibly-remove-article ,article nil nil nil t)
 807                (gnus-summary-mark-as-read ,article gnus-canceled-mark)))))
 808        message-send-actions))))
 809
 810 \f
 811
 812 (defun gnus-copy-article-buffer (&optional article-buffer yank-string)
 813   ;; make a copy of the article buffer with all text properties removed
 814   ;; this copy is in the buffer gnus-article-copy.
 815   ;; if ARTICLE-BUFFER is nil, gnus-article-buffer is used
 816   ;; this buffer should be passed to all mail/news reply/post routines.
 817   (setq gnus-article-copy (gnus-get-buffer-create " *gnus article copy*"))
 818   (save-excursion
 819     (set-buffer gnus-article-copy)
 820     (mm-enable-multibyte))
 821   (let ((article-buffer (or article-buffer gnus-article-buffer))
 822         end beg)
 823     (if (not (and (get-buffer article-buffer)
 824                   (gnus-buffer-exists-p article-buffer)))
 825         (error "Can't find any article buffer")
 826       (save-excursion
 827         (set-buffer article-buffer)
 828         (let ((gnus-newsgroup-charset (or gnus-article-charset
 829                                           gnus-newsgroup-charset))
 830               (gnus-newsgroup-ignored-charsets
 831                (or gnus-article-ignored-charsets
 832                    gnus-newsgroup-ignored-charsets)))
 833           (save-restriction
 834             ;; Copy over the (displayed) article buffer, delete
 835             ;; hidden text and remove text properties.
 836             (widen)
 837             (copy-to-buffer gnus-article-copy (point-min) (point-max))
 838             (set-buffer gnus-article-copy)
 839             (when yank-string
 840               (message-goto-body)
 841               (delete-region (point) (point-max))
 842               (insert yank-string))
 843             (gnus-article-delete-text-of-type 'annotation)
 844             (gnus-remove-text-with-property 'gnus-prev)
 845             (gnus-remove-text-with-property 'gnus-next)
 846             (gnus-remove-text-with-property 'gnus-decoration)
 847             (insert
 848              (prog1
 849                  (buffer-substring-no-properties (point-min) (point-max))
 850                (erase-buffer)))
 851             ;; Find the original headers.
 852             (set-buffer gnus-original-article-buffer)
 853             (goto-char (point-min))
 854             (while (looking-at message-unix-mail-delimiter)
 855               (forward-line 1))
 856             (let ((mail-header-separator ""))
 857               (setq beg (point)
 858                     end (or (message-goto-body)
 859                             ;; There may be just a header.
 860                             (point-max))))
 861             ;; Delete the headers from the displayed articles.
 862             (set-buffer gnus-article-copy)
 863             (let ((mail-header-separator ""))
 864               (delete-region (goto-char (point-min))
 865                              (or (message-goto-body) (point-max))))
 866             ;; Insert the original article headers.
 867             (insert-buffer-substring gnus-original-article-buffer beg end)
 868             ;; Decode charsets.
 869             (let ((gnus-article-decode-hook
 870                    (delq 'article-decode-charset
 871                          (copy-sequence gnus-article-decode-hook)))
 872                   (rfc2047-quote-decoded-words-containing-tspecials t))
 873               (run-hooks 'gnus-article-decode-hook)))))
 874       gnus-article-copy)))
 875
 876 (defun gnus-post-news (post &optional group header article-buffer yank subject
 877                             force-news)
 878   (when article-buffer
 879     (gnus-copy-article-buffer))
 880   (let ((gnus-article-reply (and article-buffer (gnus-summary-article-number)))
 881         (gnus-article-yanked-articles yank)
 882         (add-to-list gnus-add-to-list))
 883     (gnus-setup-message (cond (yank 'reply-yank)
 884                               (article-buffer 'reply)
 885                               (t 'message))
 886       (let* ((group (or group gnus-newsgroup-name))
 887              (charset (gnus-group-name-charset nil group))
 888              (pgroup group)
 889              to-address to-group mailing-list to-list
 890              newsgroup-p)
 891         (when group
 892           (setq to-address (gnus-parameter-to-address group)
 893                 to-group (gnus-group-find-parameter group 'to-group)
 894                 to-list (gnus-parameter-to-list group)
 895                 newsgroup-p (gnus-group-find-parameter group 'newsgroup)
 896                 mailing-list (when gnus-mailing-list-groups
 897                                (string-match gnus-mailing-list-groups group))
 898                 group (gnus-group-name-decode (gnus-group-real-name group)
 899                                               charset)))
 900         (if (or (and to-group
 901                      (gnus-news-group-p to-group))
 902                 newsgroup-p
 903                 force-news
 904                 (and (gnus-news-group-p
 905                       (or pgroup gnus-newsgroup-name)
 906                       (or header gnus-current-article))
 907                      (not mailing-list)
 908                      (not to-list)
 909                      (not to-address)))
 910             ;; This is news.
 911             (if post
 912                 (message-news
 913                  (or to-group
 914                      (and (not (gnus-virtual-group-p pgroup)) group)))
 915               (set-buffer gnus-article-copy)
 916               (gnus-msg-treat-broken-reply-to)
 917               (message-followup (if (or newsgroup-p force-news)
 918                                     (if (save-restriction
 919                                           (article-narrow-to-head)
 920                                           (message-fetch-field "newsgroups"))
 921                                         nil
 922                                       "")
 923                                   to-group)))
 924           ;; The is mail.
 925           (if post
 926               (progn
 927                 (message-mail (or to-address to-list))
 928                 ;; Arrange for mail groups that have no `to-address' to
 929                 ;; get that when the user sends off the mail.
 930                 (when (and (not to-list)
 931                            (not to-address)
 932                            add-to-list)
 933                   (push (list 'gnus-inews-add-to-address pgroup)
 934                         message-send-actions)))
 935             (set-buffer gnus-article-copy)
 936             (gnus-msg-treat-broken-reply-to)
 937             (message-wide-reply to-address)))
 938         (when yank
 939           (gnus-inews-yank-articles yank))))))
 940
 941 (defun gnus-msg-treat-broken-reply-to (&optional force)
 942   "Remove the Reply-to header if broken-reply-to."
 943   (when (or force
 944             (gnus-group-find-parameter
 945              gnus-newsgroup-name 'broken-reply-to))
 946     (save-restriction
 947       (message-narrow-to-head)
 948       (message-remove-header "reply-to"))))
 949
 950 (defun gnus-post-method (arg group &optional silent)
 951   "Return the posting method based on GROUP and ARG.
 952 If SILENT, don't prompt the user."
 953   (let ((gnus-post-method (or (gnus-parameter-post-method group)
 954                               gnus-post-method))
 955         (group-method (gnus-find-method-for-group group)))
 956     (cond
 957      ;; If the group-method is nil (which shouldn't happen) we use
 958      ;; the default method.
 959      ((null group-method)
 960       (or (and (listp gnus-post-method) ;If not current/native/nil
 961                (not (listp (car gnus-post-method))) ; and not a list of methods
 962                gnus-post-method)        ;then use it.
 963           gnus-select-method
 964           message-post-method))
 965      ;; We want the inverse of the default
 966      ((and arg (not (eq arg 0)))
 967       (if (eq gnus-post-method 'current)
 968           gnus-select-method
 969         group-method))
 970      ;; We query the user for a post method.
 971      ((or arg
 972           (and (listp gnus-post-method)
 973                (listp (car gnus-post-method))))
 974       (let* ((methods
 975               ;; Collect all methods we know about.
 976               (append
 977                (when (listp gnus-post-method)
 978                  (if (listp (car gnus-post-method))
 979                      gnus-post-method
 980                    (list gnus-post-method)))
 981                gnus-secondary-select-methods
 982                (mapcar 'cdr gnus-server-alist)
 983                (mapcar 'car gnus-opened-servers)
 984                (list gnus-select-method)
 985                (list group-method)))
 986              method-alist post-methods method)
 987         ;; Weed out all mail methods.
 988         (while methods
 989           (setq method (gnus-server-get-method "" (pop methods)))
 990           (when (and (or (gnus-method-option-p method 'post)
 991                          (gnus-method-option-p method 'post-mail))
 992                      (not (member method post-methods)))
 993             (push method post-methods)))
 994         ;; Create a name-method alist.
 995         (setq method-alist
 996               (mapcar
 997                (lambda (m)
 998                  (if (equal (cadr m) "")
 999                      (list (symbol-name (car m)) m)
1000                    (list (concat (cadr m) " (" (symbol-name (car m)) ")") m)))
1001                post-methods))
1002         ;; Query the user.
1003         (cadr
1004          (assoc
1005           (setq gnus-last-posting-server
1006                 (if (and silent
1007                          gnus-last-posting-server)
1008                     ;; Just use the last value.
1009                     gnus-last-posting-server
1010                   (completing-read
1011                    "Posting method: " method-alist nil t
1012                    (cons (or gnus-last-posting-server "") 0))))
1013           method-alist))))
1014      ;; Override normal method.
1015      ((and (eq gnus-post-method 'current)
1016            (not (memq (car group-method) gnus-discouraged-post-methods))
1017            (gnus-get-function group-method 'request-post t))
1018       (assert (not arg))
1019       group-method)
1020      ;; Use gnus-post-method.
1021      ((listp gnus-post-method)          ;A method...
1022       (assert (not (listp (car gnus-post-method)))) ;... not a list of methods.
1023       gnus-post-method)
1024      ;; Use the normal select method (nil or native).
1025      (t gnus-select-method))))
1026
1027 \f
1028
1029 (defun gnus-extended-version ()
1030   "Stringified Gnus version and Emacs version.
1031 See the variable `gnus-user-agent'."
1032   (interactive)
1033   (let* ((float-output-format nil)
1034          (gnus-v
1035           (concat "Gnus/"
1036                   (prin1-to-string (gnus-continuum-version gnus-version) t)
1037                   " (" gnus-version ")"))
1038          (emacs-v (gnus-emacs-version)))
1039     (if (stringp gnus-user-agent)
1040         gnus-user-agent
1041       (concat gnus-v
1042               (when emacs-v
1043                 (concat " " emacs-v))))))
1044
1045 \f
1046 ;;;
1047 ;;; Gnus Mail Functions
1048 ;;;
1049
1050 ;;; Mail reply commands of Gnus summary mode
1051
1052 (defun gnus-summary-reply (&optional yank wide very-wide)
1053   "Start composing a mail reply to the current message.
1054 If prefix argument YANK is non-nil, the original article is yanked
1055 automatically.
1056 If WIDE, make a wide reply.
1057 If VERY-WIDE, make a very wide reply."
1058   (interactive
1059    (list (and current-prefix-arg
1060               (gnus-summary-work-articles 1))))
1061   ;; Allow user to require confirmation before replying by mail to the
1062   ;; author of a news article (or mail message).
1063   (when (or
1064             (not (or (gnus-news-group-p gnus-newsgroup-name)
1065                      gnus-confirm-treat-mail-like-news))
1066             (not (cond ((stringp gnus-confirm-mail-reply-to-news)
1067                         (string-match gnus-confirm-mail-reply-to-news
1068                                       gnus-newsgroup-name))
1069                        ((functionp gnus-confirm-mail-reply-to-news)
1070                         (funcall gnus-confirm-mail-reply-to-news gnus-newsgroup-name))
1071                        (t gnus-confirm-mail-reply-to-news)))
1072             (y-or-n-p "Really reply by mail to article author? "))
1073     (let* ((article
1074             (if (listp (car yank))
1075                 (caar yank)
1076               (car yank)))
1077            (gnus-article-reply (or article (gnus-summary-article-number)))
1078            (gnus-article-yanked-articles yank)
1079            (headers ""))
1080       ;; Stripping headers should be specified with mail-yank-ignored-headers.
1081       (when yank
1082         (gnus-summary-goto-subject article))
1083       (gnus-setup-message (if yank 'reply-yank 'reply)
1084         (if (not very-wide)
1085             (gnus-summary-select-article)
1086           (dolist (article very-wide)
1087             (gnus-summary-select-article nil nil nil article)
1088             (save-excursion
1089               (set-buffer (gnus-copy-article-buffer))
1090               (gnus-msg-treat-broken-reply-to)
1091               (save-restriction
1092                 (message-narrow-to-head)
1093                 (setq headers (concat headers (buffer-string)))))))
1094         (set-buffer (gnus-copy-article-buffer))
1095         (gnus-msg-treat-broken-reply-to gnus-msg-force-broken-reply-to)
1096         (save-restriction
1097           (message-narrow-to-head)
1098           (when very-wide
1099             (erase-buffer)
1100             (insert headers))
1101           (goto-char (point-max)))
1102         (mml-quote-region (point) (point-max))
1103         (message-reply nil wide)
1104         (when yank
1105           (gnus-inews-yank-articles yank))
1106         (gnus-summary-handle-replysign)))))
1107
1108 (defun gnus-summary-handle-replysign ()
1109   "Check the various replysign variables and take action accordingly."
1110   (when (or gnus-message-replysign gnus-message-replyencrypt)
1111     (let (signed encrypted)
1112       (save-excursion
1113         (set-buffer gnus-article-buffer)
1114         (setq signed (memq 'signed gnus-article-wash-types))
1115         (setq encrypted (memq 'encrypted gnus-article-wash-types)))
1116       (cond ((and gnus-message-replyencrypt encrypted)
1117              (mml-secure-message mml-default-encrypt-method
1118                                  (if gnus-message-replysignencrypted
1119                                      'signencrypt
1120                                    'encrypt)))
1121             ((and gnus-message-replysign signed)
1122              (mml-secure-message mml-default-sign-method 'sign))))))
1123
1124 (defun gnus-summary-reply-with-original (n &optional wide)
1125   "Start composing a reply mail to the current message.
1126 The original article will be yanked."
1127   (interactive "P")
1128   (gnus-summary-reply (gnus-summary-work-articles n) wide))
1129
1130 (defun gnus-summary-reply-broken-reply-to (&optional yank wide very-wide)
1131   "Like `gnus-summary-reply' except removing reply-to field.
1132 If prefix argument YANK is non-nil, the original article is yanked
1133 automatically.
1134 If WIDE, make a wide reply.
1135 If VERY-WIDE, make a very wide reply."
1136   (interactive
1137    (list (and current-prefix-arg
1138               (gnus-summary-work-articles 1))))
1139   (let ((gnus-msg-force-broken-reply-to t))
1140     (gnus-summary-reply yank wide very-wide)))
1141
1142 (defun gnus-summary-reply-broken-reply-to-with-original (n &optional wide)
1143   "Like `gnus-summary-reply-with-original' except removing reply-to field.
1144 The original article will be yanked."
1145   (interactive "P")
1146   (gnus-summary-reply-broken-reply-to (gnus-summary-work-articles n) wide))
1147
1148 (defun gnus-summary-wide-reply (&optional yank)
1149   "Start composing a wide reply mail to the current message.
1150 If prefix argument YANK is non-nil, the original article is yanked
1151 automatically."
1152   (interactive
1153    (list (and current-prefix-arg
1154               (gnus-summary-work-articles 1))))
1155   (gnus-summary-reply yank t))
1156
1157 (defun gnus-summary-wide-reply-with-original (n)
1158   "Start composing a wide reply mail to the current message.
1159 The original article will be yanked.
1160 Uses the process/prefix convention."
1161   (interactive "P")
1162   (gnus-summary-reply-with-original n t))
1163
1164 (defun gnus-summary-very-wide-reply (&optional yank)
1165   "Start composing a very wide reply mail to the current message.
1166 If prefix argument YANK is non-nil, the original article is yanked
1167 automatically."
1168   (interactive
1169    (list (and current-prefix-arg
1170               (gnus-summary-work-articles 1))))
1171   (gnus-summary-reply yank t (gnus-summary-work-articles yank)))
1172
1173 (defun gnus-summary-very-wide-reply-with-original (n)
1174   "Start composing a very wide reply mail to the current message.
1175 The original article will be yanked."
1176   (interactive "P")
1177   (gnus-summary-reply
1178    (gnus-summary-work-articles n) t (gnus-summary-work-articles n)))
1179
1180 (defun gnus-summary-mail-forward (&optional arg post)
1181   "Forward the current message(s) to another user.
1182 If process marks exist, forward all marked messages;
1183 if ARG is nil, see `message-forward-as-mime' and `message-forward-show-mml';
1184 if ARG is 1, decode the message and forward directly inline;
1185 if ARG is 2, forward message as an rfc822 MIME section;
1186 if ARG is 3, decode message and forward as an rfc822 MIME section;
1187 if ARG is 4, forward message directly inline;
1188 otherwise, use flipped `message-forward-as-mime'.
1189 If POST, post instead of mail.
1190 For the `inline' alternatives, also see the variable
1191 `message-forward-ignored-headers'."
1192   (interactive "P")
1193   (if (cdr (gnus-summary-work-articles nil))
1194       ;; Process marks are given.
1195       (gnus-uu-digest-mail-forward arg post)
1196     ;; No process marks.
1197     (let ((message-forward-as-mime message-forward-as-mime)
1198           (message-forward-show-mml message-forward-show-mml))
1199       (cond
1200        ((null arg))
1201        ((eq arg 1)
1202         (setq message-forward-as-mime nil
1203               message-forward-show-mml t))
1204        ((eq arg 2)
1205         (setq message-forward-as-mime t
1206               message-forward-show-mml nil))
1207        ((eq arg 3)
1208         (setq message-forward-as-mime t
1209               message-forward-show-mml t))
1210        ((eq arg 4)
1211         (setq message-forward-as-mime nil
1212               message-forward-show-mml nil))
1213        (t
1214         (setq message-forward-as-mime (not message-forward-as-mime))))
1215       (let* ((gnus-article-reply (gnus-summary-article-number))
1216              (gnus-article-yanked-articles (list gnus-article-reply)))
1217         (gnus-setup-message 'forward
1218           (gnus-summary-select-article)
1219           (let ((mail-parse-charset
1220                  (or (and (gnus-buffer-live-p gnus-article-buffer)
1221                           (with-current-buffer gnus-article-buffer
1222                             gnus-article-charset))
1223                      gnus-newsgroup-charset))
1224                 (mail-parse-ignored-charsets
1225                  gnus-newsgroup-ignored-charsets))
1226             (set-buffer gnus-original-article-buffer)
1227             (message-forward post)))))))
1228
1229 (defun gnus-summary-resend-message (address n)
1230   "Resend the current article to ADDRESS."
1231   (interactive
1232    (list (message-read-from-minibuffer
1233           "Resend message(s) to: "
1234           (when (and gnus-summary-resend-default-address
1235                      (gnus-buffer-live-p gnus-original-article-buffer))
1236             ;; If some other article is currently selected, the
1237             ;; initial-contents is wrong. Whatever, it is just the
1238             ;; initial-contents.
1239             (with-current-buffer gnus-original-article-buffer
1240               (nnmail-fetch-field "to"))))
1241          current-prefix-arg))
1242   (let ((articles (gnus-summary-work-articles n))
1243         article)
1244     (while (setq article (pop articles))
1245       (gnus-summary-select-article nil nil nil article)
1246       (save-excursion
1247         (set-buffer gnus-original-article-buffer)
1248         (message-resend address))
1249       (gnus-summary-mark-article-as-forwarded article))))
1250
1251 ;; From: Matthieu Moy <Matthieu.Moy@imag.fr>
1252 (defun gnus-summary-resend-message-edit ()
1253   "Resend an article that has already been sent.
1254 A new buffer will be created to allow the user to modify body and
1255 contents of the message, and then, everything will happen as when
1256 composing a new message."
1257   (interactive)
1258   (let ((article (gnus-summary-article-number)))
1259     (gnus-setup-message 'reply-yank
1260       (gnus-summary-select-article t)
1261       (set-buffer gnus-original-article-buffer)
1262       (let ((cur (current-buffer))
1263             (to (message-fetch-field "to")))
1264         ;; Get a normal message buffer.
1265         (message-pop-to-buffer (message-buffer-name "Resend" to))
1266         (insert-buffer-substring cur)
1267         (mime-to-mml)
1268         (message-narrow-to-head-1)
1269         ;; Gnus will generate a new one when sending.
1270         (message-remove-header "Message-ID")
1271         (message-remove-header message-ignored-resent-headers t)
1272         ;; Remove unwanted headers.
1273         (goto-char (point-max))
1274         (insert mail-header-separator)
1275         (goto-char (point-min))
1276         (when (re-search-forward "^To:\\|^Newsgroups:" nil 'move)
1277           (forward-char 1))
1278         (widen)))))
1279
1280 (defun gnus-summary-post-forward (&optional arg)
1281   "Forward the current article to a newsgroup.
1282 See `gnus-summary-mail-forward' for ARG."
1283   (interactive "P")
1284   (gnus-summary-mail-forward arg t))
1285
1286 (defvar gnus-nastygram-message
1287   "The following article was inappropriately posted to %s.\n\n"
1288   "Format string to insert in nastygrams.
1289 The current group name will be inserted at \"%s\".")
1290
1291 (defun gnus-summary-mail-nastygram (n)
1292   "Send a nastygram to the author of the current article."
1293   (interactive "P")
1294   (when (or gnus-expert-user
1295             (gnus-y-or-n-p
1296              "Really send a nastygram to the author of the current article? "))
1297     (let ((group gnus-newsgroup-name))
1298       (gnus-summary-reply-with-original n)
1299       (set-buffer gnus-message-buffer)
1300       (message-goto-body)
1301       (insert (format gnus-nastygram-message group))
1302       (message-send-and-exit))))
1303
1304 (defun gnus-summary-mail-crosspost-complaint (n)
1305   "Send a complaint about crossposting to the current article(s)."
1306   (interactive "P")
1307   (let ((articles (gnus-summary-work-articles n))
1308         article)
1309     (while (setq article (pop articles))
1310       (set-buffer gnus-summary-buffer)
1311       (gnus-summary-goto-subject article)
1312       (let ((group (gnus-group-real-name gnus-newsgroup-name))
1313             newsgroups followup-to)
1314         (gnus-summary-select-article)
1315         (set-buffer gnus-original-article-buffer)
1316         (if (and (<= (length (message-tokenize-header
1317                               (setq newsgroups
1318                                     (mail-fetch-field "newsgroups"))
1319                               ", "))
1320                      1)
1321                  (or (not (setq followup-to (mail-fetch-field "followup-to")))
1322                      (not (member group (message-tokenize-header
1323                                          followup-to ", ")))))
1324             (if followup-to
1325                 (gnus-message 1 "Followup-to restricted")
1326               (gnus-message 1 "Not a crossposted article"))
1327           (set-buffer gnus-summary-buffer)
1328           (gnus-summary-reply-with-original 1)
1329           (set-buffer gnus-message-buffer)
1330           (message-goto-body)
1331           (insert (format gnus-crosspost-complaint newsgroups group))
1332           (message-goto-subject)
1333           (re-search-forward " *$")
1334           (replace-match " (crosspost notification)" t t)
1335           (gnus-deactivate-mark)
1336           (when (gnus-y-or-n-p "Send this complaint? ")
1337             (message-send-and-exit)))))))
1338
1339 (defun gnus-mail-parse-comma-list ()
1340   (let (accumulated
1341         beg)
1342     (skip-chars-forward " ")
1343     (while (not (eobp))
1344       (setq beg (point))
1345       (skip-chars-forward "^,")
1346       (while (zerop
1347               (save-excursion
1348                 (save-restriction
1349                   (let ((i 0))
1350                     (narrow-to-region beg (point))
1351                     (goto-char beg)
1352                     (logand (progn
1353                               (while (search-forward "\"" nil t)
1354                                 (incf i))
1355                               (if (zerop i) 2 i))
1356                             2)))))
1357         (skip-chars-forward ",")
1358         (skip-chars-forward "^,"))
1359       (skip-chars-backward " ")
1360       (push (buffer-substring beg (point))
1361             accumulated)
1362       (skip-chars-forward "^,")
1363       (skip-chars-forward ", "))
1364     accumulated))
1365
1366 (defun gnus-inews-add-to-address (group)
1367   (let ((to-address (mail-fetch-field "to")))
1368     (when (and to-address
1369                (gnus-alive-p))
1370       ;; This mail group doesn't have a `to-list', so we add one
1371       ;; here.  Magic!
1372       (when (gnus-y-or-n-p
1373              (format "Do you want to add this as `to-list': %s? " to-address))
1374         (gnus-group-add-parameter group (cons 'to-list to-address))))))
1375
1376 (defun gnus-put-message ()
1377   "Put the current message in some group and return to Gnus."
1378   (interactive)
1379   (let ((reply gnus-article-reply)
1380         (winconf gnus-prev-winconf)
1381         (group gnus-newsgroup-name))
1382     (unless (and group
1383                  (not (gnus-group-read-only-p group)))
1384       (setq group (read-string "Put in group: " nil (gnus-writable-groups))))
1385
1386     (when (gnus-gethash group gnus-newsrc-hashtb)
1387       (error "No such group: %s" group))
1388     (save-excursion
1389       (save-restriction
1390         (widen)
1391         (message-narrow-to-headers)
1392         (let ((gnus-deletable-headers nil))
1393           (message-generate-headers
1394            (if (message-news-p)
1395                message-required-news-headers
1396              message-required-mail-headers)))
1397         (goto-char (point-max))
1398         (if (string-match " " group)
1399             (insert "Gcc: \"" group "\"\n")
1400           (insert "Gcc: " group "\n"))
1401         (widen)))
1402     (gnus-inews-do-gcc)
1403     (when (and (get-buffer gnus-group-buffer)
1404                (gnus-buffer-exists-p (car-safe reply))
1405                (cdr reply))
1406       (set-buffer (car reply))
1407       (gnus-summary-mark-article-as-replied (cdr reply)))
1408     (when winconf
1409       (set-window-configuration winconf))))
1410
1411 (defun gnus-article-mail (yank)
1412   "Send a reply to the address near point.
1413 If YANK is non-nil, include the original article."
1414   (interactive "P")
1415   (let ((address
1416          (buffer-substring
1417           (save-excursion (re-search-backward "[ \t\n]" nil t) (1+ (point)))
1418           (save-excursion (re-search-forward "[ \t\n]" nil t) (1- (point))))))
1419     (when address
1420       (gnus-msg-mail address)
1421       (when yank
1422         (gnus-inews-yank-articles (list (cdr gnus-article-current)))))))
1423
1424 (defvar nntp-server-type)
1425 (defun gnus-bug ()
1426   "Send a bug report to the Gnus maintainers."
1427   (interactive)
1428   (unless (gnus-alive-p)
1429     (error "Gnus has been shut down"))
1430   (gnus-setup-message (if (message-mail-user-agent) 'message 'bug)
1431     (unless (message-mail-user-agent)
1432       (delete-other-windows)
1433       (when gnus-bug-create-help-buffer
1434         (switch-to-buffer "*Gnus Help Bug*")
1435         (erase-buffer)
1436         (insert gnus-bug-message)
1437         (goto-char (point-min)))
1438       (message-pop-to-buffer "*Gnus Bug*"))
1439     (let ((message-this-is-mail t))
1440       (message-setup `((To . ,gnus-maintainer) (Subject . ""))))
1441     (when gnus-bug-create-help-buffer
1442       (push `(gnus-bug-kill-buffer) message-send-actions))
1443     (goto-char (point-min))
1444     (re-search-forward (concat "^" (regexp-quote mail-header-separator) "$"))
1445     (forward-line 1)
1446     (insert (gnus-version) "\n"
1447             (emacs-version) "\n")
1448     (when (and (boundp 'nntp-server-type)
1449                (stringp nntp-server-type))
1450       (insert nntp-server-type))
1451     (insert "\n\n\n\n\n")
1452     (let (text)
1453       (save-excursion
1454         (set-buffer (gnus-get-buffer-create " *gnus environment info*"))
1455         (erase-buffer)
1456         (gnus-debug)
1457         (setq text (buffer-string)))
1458       (insert "<#part type=application/emacs-lisp disposition=inline description=\"User settings\">\n" text "\n<#/part>"))
1459     (goto-char (point-min))
1460     (search-forward "Subject: " nil t)
1461     (message "")))
1462
1463 (defun gnus-bug-kill-buffer ()
1464   (when (get-buffer "*Gnus Help Bug*")
1465     (kill-buffer "*Gnus Help Bug*")))
1466
1467 (defun gnus-summary-yank-message (buffer n)
1468   "Yank the current article into a composed message."
1469   (interactive
1470    (list (completing-read "Buffer: " (mapcar 'list (message-buffers)) nil t)
1471          current-prefix-arg))
1472   (gnus-summary-iterate n
1473     (let ((gnus-inhibit-treatment t))
1474       (gnus-summary-select-article))
1475     (save-excursion
1476       (set-buffer buffer)
1477       (message-yank-buffer gnus-article-buffer))))
1478
1479 (defun gnus-debug ()
1480   "Attempts to go through the Gnus source file and report what variables have been changed.
1481 The source file has to be in the Emacs load path."
1482   (interactive)
1483   (let ((files gnus-debug-files)
1484         (point (point))
1485         file expr olist sym)
1486     (gnus-message 4 "Please wait while we snoop your variables...")
1487     (sit-for 0)
1488     ;; Go through all the files looking for non-default values for variables.
1489     (save-excursion
1490       (set-buffer (gnus-get-buffer-create " *gnus bug info*"))
1491       (while files
1492         (erase-buffer)
1493         (when (and (setq file (locate-library (pop files)))
1494                    (file-exists-p file))
1495           (insert-file-contents file)
1496           (goto-char (point-min))
1497           (if (not (re-search-forward "^;;* *Internal variables" nil t))
1498               (gnus-message 4 "Malformed sources in file %s" file)
1499             (narrow-to-region (point-min) (point))
1500             (goto-char (point-min))
1501             (while (setq expr (ignore-errors (read (current-buffer))))
1502               (ignore-errors
1503                 (and (or (eq (car expr) 'defvar)
1504                          (eq (car expr) 'defcustom))
1505                      (stringp (nth 3 expr))
1506                      (not (memq (nth 1 expr) gnus-debug-exclude-variables))
1507                      (or (not (boundp (nth 1 expr)))
1508                          (not (equal (eval (nth 2 expr))
1509                                      (symbol-value (nth 1 expr)))))
1510                      (push (nth 1 expr) olist)))))))
1511       (kill-buffer (current-buffer)))
1512     (when (setq olist (nreverse olist))
1513       (insert "------------------ Environment follows ------------------\n\n"))
1514     (while olist
1515       (if (boundp (car olist))
1516           (ignore-errors
1517            (gnus-pp
1518             `(setq ,(car olist)
1519                    ,(if (or (consp (setq sym (symbol-value (car olist))))
1520                             (and (symbolp sym)
1521                                  (not (or (eq sym nil)
1522                                           (eq sym t)))))
1523                         (list 'quote (symbol-value (car olist)))
1524                       (symbol-value (car olist))))))
1525         (insert ";; (makeunbound '" (symbol-name (car olist)) ")\n"))
1526       (setq olist (cdr olist)))
1527     (insert "\n\n")
1528     ;; Remove any control chars - they seem to cause trouble for some
1529     ;; mailers.  (Byte-compiled output from the stuff above.)
1530     (goto-char point)
1531     (while (re-search-forward (mm-string-as-multibyte
1532                                "[\000-\010\013-\037\200-\237]") nil t)
1533       (replace-match (format "\\%03o" (string-to-char (match-string 0)))
1534                      t t))))
1535
1536 ;;; Treatment of rejected articles.
1537 ;;; Bounced mail.
1538
1539 (defun gnus-summary-resend-bounced-mail (&optional fetch)
1540   "Re-mail the current message.
1541 This only makes sense if the current message is a bounce message that
1542 contains some mail you have written which has been bounced back to
1543 you.
1544 If FETCH, try to fetch the article that this is a reply to, if indeed
1545 this is a reply."
1546   (interactive "P")
1547   (gnus-summary-select-article t)
1548   (set-buffer gnus-original-article-buffer)
1549   (gnus-setup-message 'compose-bounce
1550     (let* ((references (mail-fetch-field "references"))
1551            (parent (and references (gnus-parent-id references))))
1552       (message-bounce)
1553       ;; If there are references, we fetch the article we answered to.
1554       (and fetch parent
1555            (gnus-summary-refer-article parent)
1556            (gnus-summary-show-all-headers)))))
1557
1558 ;;; Gcc handling.
1559
1560 (defun gnus-inews-group-method (group)
1561   (cond
1562    ;; If the group doesn't exist, we assume
1563    ;; it's an archive group...
1564    ((and (null (gnus-get-info group))
1565          (eq (car (gnus-server-to-method gnus-message-archive-method))
1566              (car (gnus-server-to-method (gnus-group-method group)))))
1567     gnus-message-archive-method)
1568    ;; Use the method.
1569    ((gnus-info-method (gnus-get-info group))
1570     (gnus-info-method (gnus-get-info group)))
1571    ;; Find the method.
1572    (t (gnus-server-to-method (gnus-group-method group)))))
1573
1574 ;; Do Gcc handling, which copied the message over to some group.
1575 (defun gnus-inews-do-gcc (&optional gcc)
1576   (interactive)
1577   (save-excursion
1578     (save-restriction
1579       (message-narrow-to-headers)
1580       (let ((gcc (or gcc (mail-fetch-field "gcc" nil t)))
1581             (cur (current-buffer))
1582             groups group method group-art
1583             mml-externalize-attachments)
1584         (when gcc
1585           (message-remove-header "gcc")
1586           (widen)
1587           (setq groups (message-unquote-tokens
1588                         (message-tokenize-header gcc " ,")))
1589           ;; Copy the article over to some group(s).
1590           (while (setq group (pop groups))
1591             (unless (gnus-check-server
1592                      (setq method (gnus-inews-group-method group)))
1593               (error "Can't open server %s" (if (stringp method) method
1594                                               (car method))))
1595             (unless (gnus-request-group group nil method)
1596               (gnus-request-create-group group method))
1597             (setq mml-externalize-attachments
1598                   (if (stringp gnus-gcc-externalize-attachments)
1599                       (string-match gnus-gcc-externalize-attachments group)
1600                     gnus-gcc-externalize-attachments))
1601             (save-excursion
1602               (nnheader-set-temp-buffer " *acc*")
1603               (insert-buffer-substring cur)
1604               (message-encode-message-body)
1605               (save-restriction
1606                 (message-narrow-to-headers)
1607                 (let* ((mail-parse-charset message-default-charset)
1608                        (newsgroups-field (save-restriction
1609                                            (message-narrow-to-headers-or-head)
1610                                            (message-fetch-field "Newsgroups")))
1611                        (followup-field (save-restriction
1612                                          (message-narrow-to-headers-or-head)
1613                                          (message-fetch-field "Followup-To")))
1614                        ;; BUG: We really need to get the charset for
1615                        ;; each name in the Newsgroups and Followup-To
1616                        ;; lines to allow crossposting between group
1617                        ;; namess with incompatible character sets.
1618                        ;; -- Per Abrahamsen <abraham@dina.kvl.dk> 2001-10-08.
1619                        (group-field-charset
1620                         (gnus-group-name-charset
1621                          method (or newsgroups-field "")))
1622                        (followup-field-charset
1623                         (gnus-group-name-charset
1624                          method (or followup-field "")))
1625                        (rfc2047-header-encoding-alist
1626                         (append
1627                          (when group-field-charset
1628                            (list (cons "Newsgroups" group-field-charset)))
1629                          (when followup-field-charset
1630                            (list (cons "Followup-To" followup-field-charset)))
1631                          rfc2047-header-encoding-alist)))
1632                   (mail-encode-encoded-word-buffer)))
1633               (goto-char (point-min))
1634               (when (re-search-forward
1635                      (concat "^" (regexp-quote mail-header-separator) "$")
1636                      nil t)
1637                 (replace-match "" t t ))
1638               (unless (setq group-art
1639                             (gnus-request-accept-article group method t t))
1640                 (gnus-message 1 "Couldn't store article in group %s: %s"
1641                               group (gnus-status-message method))
1642                 (sit-for 2))
1643               (when (and group-art
1644                          ;; FIXME: Should gcc-mark-as-read work when
1645                          ;; Gnus is not running?
1646                          (gnus-alive-p)
1647                          (or gnus-gcc-mark-as-read
1648                              (and
1649                               (boundp 'gnus-inews-mark-gcc-as-read)
1650                               (symbol-value 'gnus-inews-mark-gcc-as-read))))
1651                 (gnus-group-mark-article-read group (cdr group-art)))
1652               (kill-buffer (current-buffer)))))))))
1653
1654 (defun gnus-inews-insert-gcc ()
1655   "Insert Gcc headers based on `gnus-outgoing-message-group'."
1656   (save-excursion
1657     (save-restriction
1658       (message-narrow-to-headers)
1659       (let* ((group gnus-outgoing-message-group)
1660              (gcc (cond
1661                    ((functionp group)
1662                     (funcall group))
1663                    ((or (stringp group) (list group))
1664                     group))))
1665         (when gcc
1666           (insert "Gcc: "
1667                   (if (stringp gcc)
1668                       (if (string-match " " gcc)
1669                           (concat "\"" gcc "\"")
1670                         gcc)
1671                     (mapconcat (lambda (group)
1672                                  (if (string-match " " group)
1673                                      (concat "\"" group "\"")
1674                                    group))
1675                                gcc " "))
1676                   "\n"))))))
1677
1678 (defun gnus-inews-insert-archive-gcc (&optional group)
1679   "Insert the Gcc to say where the article is to be archived."
1680   (let* ((var gnus-message-archive-group)
1681          (group (or group gnus-newsgroup-name ""))
1682          (gcc-self-val
1683           (and gnus-newsgroup-name
1684                (not (equal gnus-newsgroup-name ""))
1685                (gnus-group-find-parameter
1686                 gnus-newsgroup-name 'gcc-self)))
1687          result
1688          (groups
1689           (cond
1690            ((null gnus-message-archive-method)
1691             ;; Ignore.
1692             nil)
1693            ((stringp var)
1694             ;; Just a single group.
1695             (list var))
1696            ((null var)
1697             ;; We don't want this.
1698             nil)
1699            ((and (listp var) (stringp (car var)))
1700             ;; A list of groups.
1701             var)
1702            ((functionp var)
1703             ;; A function.
1704             (funcall var group))
1705            (t
1706             ;; An alist of regexps/functions/forms.
1707             (while (and var
1708                         (not
1709                          (setq result
1710                                (cond
1711                                 ((stringp (caar var))
1712                                  ;; Regexp.
1713                                  (when (string-match (caar var) group)
1714                                    (cdar var)))
1715                                 ((functionp (car var))
1716                                  ;; Function.
1717                                  (funcall (car var) group))
1718                                 (t
1719                                  (eval (car var)))))))
1720               (setq var (cdr var)))
1721             result)))
1722          name)
1723     (when (or groups gcc-self-val)
1724       (when (stringp groups)
1725         (setq groups (list groups)))
1726       (save-excursion
1727         (save-restriction
1728           (message-narrow-to-headers)
1729           (goto-char (point-max))
1730           (insert "Gcc: ")
1731           (if gcc-self-val
1732               ;; Use the `gcc-self' param value instead.
1733               (progn
1734                 (insert
1735                  (if (stringp gcc-self-val)
1736                      (if (string-match " " gcc-self-val)
1737                          (concat "\"" gcc-self-val "\"")
1738                        gcc-self-val)
1739                    ;; In nndoc groups, we use the parent group name
1740                    ;; instead of the current group.
1741                    (let ((group (or (gnus-group-find-parameter
1742                                      gnus-newsgroup-name 'parent-group)
1743                                     group)))
1744                      (if (string-match " " group)
1745                          (concat "\"" group "\"")
1746                        group))))
1747                 (if (not (eq gcc-self-val 'none))
1748                     (insert "\n")
1749                   (gnus-delete-line)))
1750             ;; Use the list of groups.
1751             (while (setq name (pop groups))
1752               (let ((str (if (string-match ":" name)
1753                              name
1754                            (gnus-group-prefixed-name
1755                             name gnus-message-archive-method))))
1756                 (insert (if (string-match " " str)
1757                             (concat "\"" str "\"")
1758                           str)))
1759               (when groups
1760                 (insert " ")))
1761             (insert "\n")))))))
1762
1763 (defun gnus-mailing-list-followup-to ()
1764   "Look at the headers in the current buffer and return a Mail-Followup-To address."
1765   (let ((x-been-there (gnus-fetch-original-field "x-beenthere"))
1766         (list-post (gnus-fetch-original-field "list-post")))
1767     (when (and list-post
1768                (string-match "mailto:\\([^>]+\\)" list-post))
1769       (setq list-post (match-string 1 list-post)))
1770     (or list-post
1771         x-been-there)))
1772
1773 ;;; Posting styles.
1774
1775 (defun gnus-configure-posting-styles (&optional group-name)
1776   "Configure posting styles according to `gnus-posting-styles'."
1777   (unless gnus-inhibit-posting-styles
1778     (let ((group (or group-name gnus-newsgroup-name ""))
1779           (styles gnus-posting-styles)
1780           style match attribute value v results
1781           filep name address element)
1782       ;; If the group has a posting-style parameter, add it at the end with a
1783       ;; regexp matching everything, to be sure it takes precedence over all
1784       ;; the others.
1785       (when gnus-newsgroup-name
1786         (let ((tmp-style (gnus-group-find-parameter group 'posting-style t)))
1787           (when tmp-style
1788             (setq styles (append styles (list (cons ".*" tmp-style)))))))
1789       ;; Go through all styles and look for matches.
1790       (dolist (style styles)
1791         (setq match (pop style))
1792         (goto-char (point-min))
1793         (when (cond
1794                ((stringp match)
1795                 ;; Regexp string match on the group name.
1796                 (string-match match group))
1797                ((eq match 'header)
1798                 ;; Obsolete format of header match.
1799                 (and (gnus-buffer-live-p gnus-article-copy)
1800                      (with-current-buffer gnus-article-copy
1801                        (save-restriction
1802                          (nnheader-narrow-to-headers)
1803                          (let ((header (message-fetch-field (pop style))))
1804                            (and header
1805                                 (string-match (pop style) header)))))))
1806                ((or (symbolp match)
1807                     (functionp match))
1808                 (cond
1809                  ((functionp match)
1810                   ;; Function to be called.
1811                   (funcall match))
1812                  ((boundp match)
1813                   ;; Variable to be checked.
1814                   (symbol-value match))))
1815                ((listp match)
1816                 (cond
1817                  ((eq (car match) 'header)
1818                   ;; New format of header match.
1819                   (and (gnus-buffer-live-p gnus-article-copy)
1820                        (with-current-buffer gnus-article-copy
1821                          (save-restriction
1822                            (nnheader-narrow-to-headers)
1823                            (let ((header (message-fetch-field (nth 1 match))))
1824                              (and header
1825                                   (string-match (nth 2 match) header)))))))
1826                  (t
1827                   ;; This is a form to be evaled.
1828                   (eval match)))))
1829           ;; We have a match, so we set the variables.
1830           (dolist (attribute style)
1831             (setq element (pop attribute)
1832                   filep nil)
1833             (setq value
1834                   (cond
1835                    ((eq (car attribute) :file)
1836                     (setq filep t)
1837                     (cadr attribute))
1838                    ((eq (car attribute) :value)
1839                     (cadr attribute))
1840                    (t
1841                     (car attribute))))
1842             ;; We get the value.
1843             (setq v
1844                   (cond
1845                    ((stringp value)
1846                     value)
1847                    ((or (symbolp value)
1848                         (functionp value))
1849                     (cond ((functionp value)
1850                            (funcall value))
1851                           ((boundp value)
1852                            (symbol-value value))))
1853                    ((listp value)
1854                     (eval value))))
1855             ;; Translate obsolescent value.
1856             (cond
1857              ((eq element 'signature-file)
1858               (setq element 'signature
1859                     filep t))
1860              ((eq element 'x-face-file)
1861               (setq element 'x-face
1862                     filep t)))
1863             ;; Get the contents of file elems.
1864             (when (and filep v)
1865               (setq v (with-temp-buffer
1866                         (insert-file-contents v)
1867                         (buffer-substring
1868                          (point-min)
1869                          (progn
1870                            (goto-char (point-max))
1871                            (if (zerop (skip-chars-backward "\n"))
1872                                (point)
1873                              (1+ (point))))))))
1874             (setq results (delq (assoc element results) results))
1875             (push (cons element v) results))))
1876       ;; Now we have all the styles, so we insert them.
1877       (setq name (assq 'name results)
1878             address (assq 'address results))
1879       (setq results (delq name (delq address results)))
1880       (gnus-make-local-hook 'message-setup-hook)
1881       (setq results (sort results (lambda (x y)
1882                                     (string-lessp (car x) (car y)))))
1883       (dolist (result results)
1884         (add-hook 'message-setup-hook
1885                   (cond
1886                    ((eq 'eval (car result))
1887                     'ignore)
1888                    ((eq 'body (car result))
1889                     `(lambda ()
1890                        (save-excursion
1891                          (message-goto-body)
1892                          (insert ,(cdr result)))))
1893                    ((eq 'signature (car result))
1894                     (set (make-local-variable 'message-signature) nil)
1895                     (set (make-local-variable 'message-signature-file) nil)
1896                     (if (not (cdr result))
1897                         'ignore
1898                       `(lambda ()
1899                          (save-excursion
1900                            (let ((message-signature ,(cdr result)))
1901                              (when message-signature
1902                                (message-insert-signature)))))))
1903                    (t
1904                     (let ((header
1905                            (if (symbolp (car result))
1906                                (capitalize (symbol-name (car result)))
1907                              (car result))))
1908                       `(lambda ()
1909                          (save-excursion
1910                            (message-remove-header ,header)
1911                            (let ((value ,(cdr result)))
1912                              (when value
1913                                (message-goto-eoh)
1914                                (insert ,header ": " value)
1915                                (unless (bolp)
1916                                  (insert "\n")))))))))
1917                   nil 'local))
1918       (when (or name address)
1919         (add-hook 'message-setup-hook
1920                   `(lambda ()
1921                      (set (make-local-variable 'user-mail-address)
1922                           ,(or (cdr address) user-mail-address))
1923                      (let ((user-full-name ,(or (cdr name) (user-full-name)))
1924                            (user-mail-address
1925                             ,(or (cdr address) user-mail-address)))
1926                        (save-excursion
1927                          (message-remove-header "From")
1928                          (message-goto-eoh)
1929                          (insert "From: " (message-make-from) "\n"))))
1930                   nil 'local)))))
1931
1932 ;;; Allow redefinition of functions.
1933
1934 (gnus-ems-redefine)
1935
1936 (provide 'gnus-msg)
1937
1938 ;;; arch-tag: 9f22b2f5-1c0a-49de-916e-4c88e984852b
1939 ;;; gnus-msg.el ends here