code.delx.au - gnu-emacs/blob - lisp/net/tramp-cache.el

   1 ;;; tramp-cache.el --- file information caching for Tramp
   2
   3 ;; Copyright (C) 2000, 2005-2013 Free Software Foundation, Inc.
   4
   5 ;; Author: Daniel Pittman <daniel@inanna.danann.net>
   6 ;;         Michael Albinus <michael.albinus@gmx.de>
   7 ;; Keywords: comm, processes
   8 ;; Package: tramp
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; An implementation of information caching for remote files.
  28
  29 ;; Each connection, identified by a vector [method user host
  30 ;; localname] or by a process, has a unique cache. We distinguish 3
  31 ;; kind of caches, depending on the key:
  32 ;;
  33 ;; - localname is NIL.  This are reusable properties.  Examples:
  34 ;;   "remote-shell" identifies the POSIX shell to be called on the
  35 ;;   remote host, or "perl" is the command to be called on the remote
  36 ;;   host when starting a Perl script.  These properties are saved in
  37 ;;   the file `tramp-persistency-file-name'.
  38 ;;
  39 ;; - localname is a string.  This are temporary properties, which are
  40 ;;   related to the file localname is referring to.  Examples:
  41 ;;   "file-exists-p" is t or nil, depending on the file existence, or
  42 ;;   "file-attributes" caches the result of the function
  43 ;;   `file-attributes'.  These entries have a timestamp, and they
  44 ;;   expire after `remote-file-name-inhibit-cache' seconds if this
  45 ;;   variable is set.
  46 ;;
  47 ;; - The key is a process.  This are temporary properties related to
  48 ;;   an open connection.  Examples: "scripts" keeps shell script
  49 ;;   definitions already sent to the remote shell, "last-cmd-time" is
  50 ;;   the time stamp a command has been sent to the remote process.
  51
  52 ;;; Code:
  53
  54 (require 'tramp)
  55 (autoload 'time-stamp-string "time-stamp")
  56
  57 ;;; -- Cache --
  58
  59 ;;;###tramp-autoload
  60 (defvar tramp-cache-data (make-hash-table :test 'equal)
  61   "Hash table for remote files properties.")
  62
  63 ;;;###tramp-autoload
  64 (defcustom tramp-connection-properties nil
  65   "List of static connection properties.
  66 Every entry has the form (REGEXP PROPERTY VALUE).  The regexp
  67 matches remote file names.  It can be nil.  PROPERTY is a string,
  68 and VALUE the corresponding value.  They are used, if there is no
  69 matching entry for PROPERTY in `tramp-cache-data'."
  70   :group 'tramp
  71   :version "24.4"
  72   :type '(repeat (list (choice :tag "File Name regexp" regexp (const nil))
  73                        (choice :tag "        Property" string)
  74                        (choice :tag "           Value" sexp))))
  75
  76 (defcustom tramp-persistency-file-name
  77   (cond
  78    ;; GNU Emacs.
  79    ((and (fboundp 'locate-user-emacs-file))
  80     (expand-file-name (tramp-compat-funcall 'locate-user-emacs-file "tramp")))
  81    ((and (boundp 'user-emacs-directory)
  82          (stringp (symbol-value 'user-emacs-directory))
  83          (file-directory-p (symbol-value 'user-emacs-directory)))
  84     (expand-file-name "tramp" (symbol-value 'user-emacs-directory)))
  85    ((and (not (featurep 'xemacs)) (file-directory-p "~/.emacs.d/"))
  86     "~/.emacs.d/tramp")
  87    ;; XEmacs.
  88    ((and (boundp 'user-init-directory)
  89          (stringp (symbol-value 'user-init-directory))
  90          (file-directory-p (symbol-value 'user-init-directory)))
  91     (expand-file-name "tramp" (symbol-value 'user-init-directory)))
  92    ((and (featurep 'xemacs) (file-directory-p "~/.xemacs/"))
  93     "~/.xemacs/tramp")
  94    ;; For users without `~/.emacs.d/' or `~/.xemacs/'.
  95    (t "~/.tramp"))
  96   "File which keeps connection history for Tramp connections."
  97   :group 'tramp
  98   :type 'file)
  99
 100 (defvar tramp-cache-data-changed nil
 101   "Whether persistent cache data have been changed.")
 102
 103 (defun tramp-get-hash-table (key)
 104   "Returns the hash table for KEY.
 105 If it doesn't exist yet, it is created and initialized with
 106 matching entries of `tramp-connection-properties'."
 107   (or (gethash key tramp-cache-data)
 108       (let ((hash
 109              (puthash key (make-hash-table :test 'equal) tramp-cache-data)))
 110         (when (vectorp key)
 111           (dolist (elt tramp-connection-properties)
 112             (when (string-match
 113                    (or (nth 0 elt) "")
 114                    (tramp-make-tramp-file-name
 115                     (aref key 0) (aref key 1) (aref key 2) nil))
 116               (tramp-set-connection-property key (nth 1 elt) (nth 2 elt)))))
 117         hash)))
 118
 119 ;;;###tramp-autoload
 120 (defun tramp-get-file-property (key file property default)
 121   "Get the PROPERTY of FILE from the cache context of KEY.
 122 Returns DEFAULT if not set."
 123   ;; Unify localname.
 124   (setq key (copy-sequence key))
 125   (aset key 3 (tramp-run-real-handler 'directory-file-name (list file)))
 126   (let* ((hash (tramp-get-hash-table key))
 127          (value (when (hash-table-p hash) (gethash property hash))))
 128     (if
 129         ;; We take the value only if there is any, and
 130         ;; `remote-file-name-inhibit-cache' indicates that it is still
 131         ;; valid.  Otherwise, DEFAULT is set.
 132         (and (consp value)
 133              (or (null remote-file-name-inhibit-cache)
 134                  (and (integerp remote-file-name-inhibit-cache)
 135                       (<=
 136                        (tramp-time-diff (current-time) (car value))
 137                        remote-file-name-inhibit-cache))
 138                  (and (consp remote-file-name-inhibit-cache)
 139                       (tramp-time-less-p
 140                        remote-file-name-inhibit-cache (car value)))))
 141         (setq value (cdr value))
 142       (setq value default))
 143
 144     (tramp-message key 8 "%s %s %s" file property value)
 145     (when (>= tramp-verbose 10)
 146       (let* ((var (intern (concat "tramp-cache-get-count-" property)))
 147              (val (or (ignore-errors (symbol-value var)) 0)))
 148         (set var (1+ val))))
 149     value))
 150
 151 ;;;###tramp-autoload
 152 (defun tramp-set-file-property (key file property value)
 153   "Set the PROPERTY of FILE to VALUE, in the cache context of KEY.
 154 Returns VALUE."
 155   ;; Unify localname.
 156   (setq key (copy-sequence key))
 157   (aset key 3 (tramp-run-real-handler 'directory-file-name (list file)))
 158   (let ((hash (tramp-get-hash-table key)))
 159     ;; We put the timestamp there.
 160     (puthash property (cons (current-time) value) hash)
 161     (tramp-message key 8 "%s %s %s" file property value)
 162     (when (>= tramp-verbose 10)
 163       (let* ((var (intern (concat "tramp-cache-set-count-" property)))
 164              (val (or (ignore-errors (symbol-value var)) 0)))
 165         (set var (1+ val))))
 166     value))
 167
 168 ;;;###tramp-autoload
 169 (defun tramp-flush-file-property (key file)
 170   "Remove all properties of FILE in the cache context of KEY."
 171   ;; Remove file property of symlinks.
 172   (let ((truename (tramp-get-file-property key file "file-truename" nil)))
 173     (when (and (stringp truename)
 174                (not (string-equal file truename)))
 175       (tramp-flush-file-property key truename)))
 176   ;; Unify localname.
 177   (setq key (copy-sequence key))
 178   (aset key 3 (tramp-run-real-handler 'directory-file-name (list file)))
 179   (tramp-message key 8 "%s" file)
 180   (remhash key tramp-cache-data))
 181
 182 ;;;###tramp-autoload
 183 (defun tramp-flush-directory-property (key directory)
 184   "Remove all properties of DIRECTORY in the cache context of KEY.
 185 Remove also properties of all files in subdirectories."
 186   (let ((directory (tramp-run-real-handler
 187                     'directory-file-name (list directory))))
 188     (tramp-message key 8 "%s" directory)
 189     (maphash
 190      (lambda (key value)
 191        (when (and (stringp (tramp-file-name-localname key))
 192                   (string-match directory (tramp-file-name-localname key)))
 193          (remhash key tramp-cache-data)))
 194      tramp-cache-data)))
 195
 196 ;; Reverting or killing a buffer should also flush file properties.
 197 ;; They could have been changed outside Tramp.  In eshell, "ls" would
 198 ;; not show proper directory contents when a file has been copied or
 199 ;; deleted before.
 200 (defun tramp-flush-file-function ()
 201   "Flush all Tramp cache properties from `buffer-file-name'."
 202   (let ((bfn (if (stringp (buffer-file-name))
 203                  (buffer-file-name)
 204                default-directory)))
 205     (when (tramp-tramp-file-p bfn)
 206       (with-parsed-tramp-file-name bfn nil
 207         (tramp-flush-file-property v localname)))))
 208
 209 (add-hook 'before-revert-hook 'tramp-flush-file-function)
 210 (add-hook 'eshell-pre-command-hook 'tramp-flush-file-function)
 211 (add-hook 'kill-buffer-hook 'tramp-flush-file-function)
 212 (add-hook 'tramp-cache-unload-hook
 213           (lambda ()
 214             (remove-hook 'before-revert-hook
 215                          'tramp-flush-file-function)
 216             (remove-hook 'eshell-pre-command-hook
 217                          'tramp-flush-file-function)
 218             (remove-hook 'kill-buffer-hook
 219                          'tramp-flush-file-function)))
 220
 221 ;;; -- Properties --
 222
 223 ;;;###tramp-autoload
 224 (defun tramp-get-connection-property (key property default)
 225   "Get the named PROPERTY for the connection.
 226 KEY identifies the connection, it is either a process or a vector.
 227 If the value is not set for the connection, returns DEFAULT."
 228   ;; Unify key by removing localname from vector.  Work with a copy in
 229   ;; order to avoid side effects.
 230   (when (vectorp key)
 231     (setq key (copy-sequence key))
 232     (aset key 3 nil))
 233   (let* ((hash (tramp-get-hash-table key))
 234          (value (if (hash-table-p hash)
 235                     (gethash property hash default)
 236                   default)))
 237     (tramp-message key 7 "%s %s" property value)
 238     value))
 239
 240 ;;;###tramp-autoload
 241 (defun tramp-set-connection-property (key property value)
 242   "Set the named PROPERTY of a connection to VALUE.
 243 KEY identifies the connection, it is either a process or a vector.
 244 PROPERTY is set persistent when KEY is a vector."
 245   ;; Unify key by removing localname from vector.  Work with a copy in
 246   ;; order to avoid side effects.
 247   (when (vectorp key)
 248     (setq key (copy-sequence key))
 249     (aset key 3 nil))
 250   (let ((hash (tramp-get-hash-table key)))
 251     (puthash property value hash)
 252     (setq tramp-cache-data-changed t)
 253     (tramp-message key 7 "%s %s" property value)
 254     value))
 255
 256 ;;;###tramp-autoload
 257 (defun tramp-connection-property-p (key property)
 258   "Check whether named PROPERTY of a connection is defined.
 259 KEY identifies the connection, it is either a process or a vector."
 260   (not (eq (tramp-get-connection-property key property 'undef) 'undef)))
 261
 262 ;;;###tramp-autoload
 263 (defun tramp-flush-connection-property (key)
 264   "Remove all properties identified by KEY.
 265 KEY identifies the connection, it is either a process or a vector."
 266   ;; Unify key by removing localname from vector.  Work with a copy in
 267   ;; order to avoid side effects.
 268   (when (vectorp key)
 269     (setq key (copy-sequence key))
 270     (aset key 3 nil))
 271   (tramp-message
 272    key 7 "%s %s" key
 273    (let ((hash (gethash key tramp-cache-data))
 274          properties)
 275      (when (hash-table-p hash)
 276        (maphash (lambda (x y) (add-to-list 'properties x 'append)) hash))
 277      properties))
 278   (setq tramp-cache-data-changed t)
 279   (remhash key tramp-cache-data))
 280
 281 ;;;###tramp-autoload
 282 (defun tramp-cache-print (table)
 283   "Print hash table TABLE."
 284   (when (hash-table-p table)
 285     (let (result)
 286       (maphash
 287        (lambda (key value)
 288          (let ((tmp (format
 289                      "(%s %s)"
 290                      (if (processp key)
 291                          (prin1-to-string (prin1-to-string key))
 292                        (prin1-to-string key))
 293                      (if (hash-table-p value)
 294                          (tramp-cache-print value)
 295                        (if (bufferp value)
 296                            (prin1-to-string (prin1-to-string value))
 297                          (prin1-to-string value))))))
 298            (setq result (if result (concat result " " tmp) tmp))))
 299        table)
 300       result)))
 301
 302 ;;;###tramp-autoload
 303 (defun tramp-list-connections ()
 304   "Return a list of all known connection vectors according to `tramp-cache'."
 305     (let (result)
 306       (maphash
 307        (lambda (key value)
 308          (when (and (vectorp key) (null (aref key 3)))
 309            (add-to-list 'result key)))
 310        tramp-cache-data)
 311       result))
 312
 313 (defun tramp-dump-connection-properties ()
 314   "Write persistent connection properties into file `tramp-persistency-file-name'."
 315   ;; We shouldn't fail, otherwise (X)Emacs might not be able to be closed.
 316   (ignore-errors
 317     (when (and (hash-table-p tramp-cache-data)
 318                (not (zerop (hash-table-count tramp-cache-data)))
 319                tramp-cache-data-changed
 320                (stringp tramp-persistency-file-name))
 321       (let ((cache (copy-hash-table tramp-cache-data))
 322             print-length print-level)
 323         ;; Remove temporary data.  If there is the key "login-as", we
 324         ;; don't save either, because all other properties might
 325         ;; depend on the login name, and we want to give the
 326         ;; possibility to use another login name later on.
 327         (maphash
 328          (lambda (key value)
 329            (if (and (vectorp key)
 330                     (not (tramp-file-name-localname key))
 331                     (not (gethash "login-as" value)))
 332                (progn
 333                  (remhash "process-name" value)
 334                  (remhash "process-buffer" value)
 335                  (remhash "first-password-request" value))
 336              (remhash key cache)))
 337          cache)
 338         ;; Dump it.
 339         (with-temp-buffer
 340           (insert
 341            ";; -*- emacs-lisp -*-"
 342            ;; `time-stamp-string' might not exist in all (X)Emacs flavors.
 343            (condition-case nil
 344                (progn
 345                  (format
 346                   " <%s %s>\n"
 347                   (time-stamp-string "%02y/%02m/%02d %02H:%02M:%02S")
 348                   tramp-persistency-file-name))
 349              (error "\n"))
 350            ";; Tramp connection history.  Don't change this file.\n"
 351            ";; You can delete it, forcing Tramp to reapply the checks.\n\n"
 352            (with-output-to-string
 353              (pp (read (format "(%s)" (tramp-cache-print cache))))))
 354           (write-region
 355            (point-min) (point-max) tramp-persistency-file-name))))))
 356
 357 (unless noninteractive
 358   (add-hook 'kill-emacs-hook 'tramp-dump-connection-properties))
 359 (add-hook 'tramp-cache-unload-hook
 360           (lambda ()
 361             (remove-hook 'kill-emacs-hook
 362                          'tramp-dump-connection-properties)))
 363
 364 ;;;###tramp-autoload
 365 (defun tramp-parse-connection-properties (method)
 366   "Return a list of (user host) tuples allowed to access for METHOD.
 367 This function is added always in `tramp-get-completion-function'
 368 for all methods.  Resulting data are derived from connection history."
 369   (let (res)
 370     (maphash
 371      (lambda (key value)
 372        (if (and (vectorp key)
 373                 (string-equal method (tramp-file-name-method key))
 374                 (not (tramp-file-name-localname key)))
 375            (push (list (tramp-file-name-user key)
 376                        (tramp-file-name-host key))
 377                  res)))
 378      tramp-cache-data)
 379     res))
 380
 381 ;; Read persistent connection history.
 382 (when (and (stringp tramp-persistency-file-name)
 383            (zerop (hash-table-count tramp-cache-data))
 384            ;; When "emacs -Q" has been called, both variables are nil.
 385            ;; We do not load the persistency file then, in order to
 386            ;; have a clean test environment.
 387            (or (and (boundp 'init-file-user) (symbol-value 'init-file-user))
 388                (and (boundp 'site-run-file) (symbol-value 'site-run-file))))
 389   (condition-case err
 390       (with-temp-buffer
 391         (insert-file-contents tramp-persistency-file-name)
 392         (let ((list (read (current-buffer)))
 393               element key item)
 394           (while (setq element (pop list))
 395             (setq key (pop element))
 396             (while (setq item (pop element))
 397               ;; We set only values which are not contained in
 398               ;; `tramp-connection-properties'.  The cache is
 399               ;; initialized properly by side effect.
 400               (unless (tramp-connection-property-p key (car item))
 401                 (tramp-set-connection-property key (pop item) (car item))))))
 402         (setq tramp-cache-data-changed nil))
 403     (file-error
 404      ;; Most likely because the file doesn't exist yet.  No message.
 405      (clrhash tramp-cache-data))
 406     (error
 407      ;; File is corrupted.
 408      (message "Tramp persistency file '%s' is corrupted: %s"
 409               tramp-persistency-file-name (error-message-string err))
 410      (clrhash tramp-cache-data))))
 411
 412 (add-hook 'tramp-unload-hook
 413           (lambda ()
 414             (unload-feature 'tramp-cache 'force)))
 415
 416 (provide 'tramp-cache)
 417
 418 ;;; tramp-cache.el ends here