code.delx.au - gnu-emacs/blob - lisp/time.el

   1 ;;; time.el --- display time and load in mode line of Emacs.
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  21 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Facilities to display current time/date and a new-mail indicator
  26 ;;; in the Emacs mode line.  The single entry point is `display-time'.
  27
  28 ;;; Code:
  29
  30 (defvar display-time-mail-file nil
  31   "*File name of mail inbox file, for indicating existence of new mail.
  32 Non-nil and not a string means don't check for mail.  nil means use
  33 default, which is system-dependent, and is the same as used by Rmail.")
  34
  35 ;;;###autoload
  36 (defvar display-time-day-and-date nil "\
  37 *Non-nil means \\[display-time] should display day and date as well as time.")
  38
  39 (defvar display-time-process nil)
  40
  41 (defvar display-time-interval 60
  42   "*Seconds between updates of time in the mode line.")
  43
  44 (defvar display-time-24hr-format nil
  45   "*Non-nil indicates time should be displayed as hh:mm, 0 <= hh <= 23.
  46 Nil means 1 <= hh <= 12, and an AM/PM suffix is used.")
  47
  48 (defvar display-time-string nil)
  49
  50 (defvar display-time-hook nil
  51   "* List of functions to be called when the time is updated on the mode line.")
  52
  53 (defvar display-time-server-down-time nil
  54    "Time when mail file's file system was recorded to be down.
  55 If that file system seems to be up, the value is nil.")
  56
  57 ;;;###autoload
  58 (defun display-time ()
  59   "Display current time, load level, and mail flag in mode line of each buffer.
  60 Updates automatically every minute.
  61 If `display-time-day-and-date' is non-nil, the current day and date
  62 are displayed as well.
  63 After each update, `display-time-hook' is run with `run-hooks'."
  64   (interactive)
  65   (let ((live (or (and (eq system-type 'ms-dos) dos-display-time)
  66                   (and display-time-process
  67                        (eq (process-status display-time-process) 'run)))))
  68     (if (not live)
  69         (progn
  70           (if display-time-process
  71               (delete-process display-time-process))
  72           (or global-mode-string (setq global-mode-string '("")))
  73           (or (memq 'display-time-string global-mode-string)
  74               (setq global-mode-string
  75                     (append global-mode-string '(display-time-string))))
  76           (setq display-time-string "")
  77           (if (eq system-type 'ms-dos)
  78               (setq dos-display-time t)
  79             ;; Using a pty is wasteful, and the separate session causes
  80             ;; annoyance sometimes (some systems kill idle sessions).
  81             (progn
  82               (let ((process-connection-type nil))
  83                 (setq display-time-process
  84                       (start-process "display-time" nil
  85                                      (expand-file-name
  86                                       "wakeup" exec-directory)
  87                                      (int-to-string display-time-interval))))
  88               (process-kill-without-query display-time-process)
  89               (set-process-sentinel display-time-process
  90                                     'display-time-sentinel)
  91               (set-process-filter   display-time-process
  92                                     'display-time-filter)))))))
  93
  94 (defun display-time-sentinel (proc reason)
  95   (or (eq (process-status proc) 'run)
  96       (setq display-time-string ""))
  97   ;; Force mode-line updates
  98   (force-mode-line-update t)
  99   (sit-for 0))
 100
 101 (defvar display-time-string-forms
 102   '((if display-time-day-and-date
 103         (format "%s %s %s " dayname monthname day)
 104       "")
 105     (format "%s:%s%s"
 106             (if display-time-24hr-format 24-hours 12-hours)
 107             minutes
 108             (if display-time-24hr-format "" am-pm))
 109     load
 110     (if mail " Mail" ""))
 111   "*A list of expressions governing display of the time in the mode line.
 112 This expression is a list of expressions that can involve the keywords
 113 `load', `day', `month', and `year', `12-hours', `24-hours', `minutes',
 114 `seconds', all numbers in string form, and `monthname', `dayname', `am-pm',
 115 and `time-zone' all alphabetic strings, and `mail' a true/nil value.
 116
 117 For example, the form
 118
 119   '((substring year -2) \"/\" month \"/\" day
 120     \" \" 24-hours \":\" minutes \":\" seconds
 121     (if time-zone \" (\") time-zone (if time-zone \")\")
 122     (if mail \" Mail\" \"\"))
 123
 124 would give mode line times like `94/12/30 21:07:48 (UTC)'.")
 125
 126 (defun display-time-filter (proc string)
 127   (let* ((now (current-time))
 128          (time (current-time-string now))
 129          (load (condition-case ()
 130                    (if (zerop (car (load-average))) ""
 131                      (let ((str (format " %03d" (car (load-average)))))
 132                        (concat (substring str 0 -2) "." (substring str -2))))
 133                  (error "")))
 134          (mail-spool-file (or display-time-mail-file
 135                               (getenv "MAIL")
 136                               (concat rmail-spool-directory
 137                                       (user-login-name))))
 138          (mail (and (stringp mail-spool-file)
 139                     (or (null display-time-server-down-time)
 140                         ;; If have been down for 20 min, try again.
 141                         (> (- (nth 1 (current-time))
 142                               display-time-server-down-time)
 143                            1200))
 144                     (let ((start-time (current-time)))
 145                       (prog1
 146                           (display-time-file-nonempty-p mail-spool-file)
 147                         (if (> (- (nth 1 (current-time)) (nth 1 start-time))
 148                                20)
 149                             ;; Record that mail file is not accessible.
 150                             (setq display-time-server-down-time
 151                                   (nth 1 (current-time)))
 152                           ;; Record that mail file is accessible.
 153                           (setq display-time-server-down-time nil))))))
 154          (24-hours (substring time 11 13))
 155          (hour (string-to-int 24-hours))
 156          (12-hours (int-to-string (1+ (% (+ hour 11) 12))))
 157          (am-pm (if (>= hour 12) "pm" "am"))
 158          (minutes (substring time 14 16))
 159          (seconds (substring time 17 19))
 160          (time-zone (car (cdr (current-time-zone now))))
 161          (day (substring time 8 10))
 162          (year (substring time 20 24))
 163          (monthname (substring time 4 7))
 164          (month
 165           (cdr
 166            (assoc
 167             monthname
 168             '(("Jan" . "1") ("Feb" . "2") ("Mar" . "3") ("Apr" . "4")
 169               ("May" . "5") ("Jun" . "6") ("Jul" . "7") ("Aug" . "8")
 170               ("Sep" . "9") ("Oct" . "10") ("Nov" . "11") ("Dec" . "12")))))
 171          (dayname (substring time 0 3)))
 172     (setq display-time-string
 173           (mapconcat 'eval display-time-string-forms ""))
 174     ;; This is inside the let binding, but we are not going to document
 175     ;; what variables are available.
 176     (run-hooks 'display-time-hook))
 177   (force-mode-line-update)
 178   ;; Do redisplay right now, if no input pending.
 179   (sit-for 0))
 180
 181 (defun display-time-file-nonempty-p (file)
 182   (and (file-exists-p file)
 183        (< 0 (nth 7 (file-attributes (file-chase-links file))))))
 184
 185 ;;; time.el ends here