code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/lisp.el

   1 ;;; lisp.el --- Lisp editing commands for Emacs
   2
   3 ;; Copyright (C) 1985, 86, 1994, 2000, 2004  Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: lisp, languages
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; Lisp editing commands to go with Lisp major mode.  More-or-less
  28 ;; applicable in other modes too.
  29
  30 ;;; Code:
  31
  32 ;; Note that this variable is used by non-lisp modes too.
  33 (defcustom defun-prompt-regexp nil
  34   "*If non-nil, a regexp to ignore before the character that starts a defun.
  35 This is only necessary if the opening paren or brace is not in column 0.
  36 See function `beginning-of-defun'.
  37
  38 Setting this variable automatically makes it local to the current buffer."
  39   :type '(choice (const nil)
  40                  regexp)
  41   :group 'lisp)
  42 (make-variable-buffer-local 'defun-prompt-regexp)
  43
  44 (defcustom parens-require-spaces t
  45   "Non-nil means `insert-parentheses' should insert whitespace as needed."
  46   :type 'boolean
  47   :group 'lisp)
  48
  49 (defvar forward-sexp-function nil
  50   "If non-nil, `forward-sexp' delegates to this function.
  51 Should take the same arguments and behave similarly to `forward-sexp'.")
  52
  53 (defun forward-sexp (&optional arg)
  54   "Move forward across one balanced expression (sexp).
  55 With ARG, do it that many times.  Negative arg -N means
  56 move backward across N balanced expressions."
  57   (interactive "p")
  58   (or arg (setq arg 1))
  59   (if forward-sexp-function
  60       (funcall forward-sexp-function arg)
  61     (goto-char (or (scan-sexps (point) arg) (buffer-end arg)))
  62     (if (< arg 0) (backward-prefix-chars))))
  63
  64 (defun backward-sexp (&optional arg)
  65   "Move backward across one balanced expression (sexp).
  66 With ARG, do it that many times.  Negative arg -N means
  67 move forward across N balanced expressions."
  68   (interactive "p")
  69   (or arg (setq arg 1))
  70   (forward-sexp (- arg)))
  71
  72 (defun mark-sexp (&optional arg)
  73   "Set mark ARG sexps from point.
  74 The place mark goes is the same place \\[forward-sexp] would
  75 move to with the same argument.
  76 If this command is repeated, it marks the next ARG sexps after the ones
  77 already marked."
  78   (interactive "p")
  79   (cond ((and (eq last-command this-command) (mark t))
  80          (set-mark
  81           (save-excursion
  82            (goto-char (mark))
  83            (forward-sexp (or arg 1))
  84            (point))))
  85         (t
  86          (push-mark
  87           (save-excursion
  88             (forward-sexp (or arg 1))
  89             (point))
  90           nil t))))
  91
  92 (defun forward-list (&optional arg)
  93   "Move forward across one balanced group of parentheses.
  94 With ARG, do it that many times.
  95 Negative arg -N means move backward across N groups of parentheses."
  96   (interactive "p")
  97   (or arg (setq arg 1))
  98   (goto-char (or (scan-lists (point) arg 0) (buffer-end arg))))
  99
 100 (defun backward-list (&optional arg)
 101   "Move backward across one balanced group of parentheses.
 102 With ARG, do it that many times.
 103 Negative arg -N means move forward across N groups of parentheses."
 104   (interactive "p")
 105   (or arg (setq arg 1))
 106   (forward-list (- arg)))
 107
 108 (defun down-list (&optional arg)
 109   "Move forward down one level of parentheses.
 110 With ARG, do this that many times.
 111 A negative argument means move backward but still go down a level."
 112   (interactive "p")
 113   (or arg (setq arg 1))
 114   (let ((inc (if (> arg 0) 1 -1)))
 115     (while (/= arg 0)
 116       (goto-char (or (scan-lists (point) inc -1) (buffer-end arg)))
 117       (setq arg (- arg inc)))))
 118
 119 (defun backward-up-list (&optional arg)
 120   "Move backward out of one level of parentheses.
 121 With ARG, do this that many times.
 122 A negative argument means move forward but still to a less deep spot."
 123   (interactive "p")
 124   (up-list (- (or arg 1))))
 125
 126 (defun up-list (&optional arg)
 127   "Move forward out of one level of parentheses.
 128 With ARG, do this that many times.
 129 A negative argument means move backward but still to a less deep spot."
 130   (interactive "p")
 131   (or arg (setq arg 1))
 132   (let ((inc (if (> arg 0) 1 -1)))
 133     (while (/= arg 0)
 134       (goto-char (or (scan-lists (point) inc 1) (buffer-end arg)))
 135       (setq arg (- arg inc)))))
 136
 137 (defun kill-sexp (&optional arg)
 138   "Kill the sexp (balanced expression) following the cursor.
 139 With ARG, kill that many sexps after the cursor.
 140 Negative arg -N means kill N sexps before the cursor."
 141   (interactive "p")
 142   (let ((opoint (point)))
 143     (forward-sexp (or arg 1))
 144     (kill-region opoint (point))))
 145
 146 (defun backward-kill-sexp (&optional arg)
 147   "Kill the sexp (balanced expression) preceding the cursor.
 148 With ARG, kill that many sexps before the cursor.
 149 Negative arg -N means kill N sexps after the cursor."
 150   (interactive "p")
 151   (kill-sexp (- (or arg 1))))
 152 \f
 153 (defvar beginning-of-defun-function nil
 154   "If non-nil, function for `beginning-of-defun-raw' to call.
 155 This is used to find the beginning of the defun instead of using the
 156 normal recipe (see `beginning-of-defun').  Major modes can define this
 157 if defining `defun-prompt-regexp' is not sufficient to handle the mode's
 158 needs.
 159
 160 The function (of no args) should go to the line on which the current
 161 defun starts, and return non-nil, or should return nil if it can't
 162 find the beginning.")
 163
 164 (defun beginning-of-defun (&optional arg)
 165   "Move backward to the beginning of a defun.
 166 With ARG, do it that many times.  Negative arg -N
 167 means move forward to Nth following beginning of defun.
 168 Returns t unless search stops due to beginning or end of buffer.
 169
 170 Normally a defun starts when there is a char with open-parenthesis
 171 syntax at the beginning of a line.  If `defun-prompt-regexp' is
 172 non-nil, then a string which matches that regexp may precede the
 173 open-parenthesis, and point ends up at the beginning of the line.
 174
 175 If variable `beginning-of-defun-function' is non-nil, its value
 176 is called as a function to find the defun's beginning."
 177   (interactive "p")
 178   (and (eq this-command 'beginning-of-defun)
 179        (or (eq last-command 'beginning-of-defun) (push-mark)))
 180   (and (beginning-of-defun-raw arg)
 181        (progn (beginning-of-line) t)))
 182
 183 (defun beginning-of-defun-raw (&optional arg)
 184   "Move point to the character that starts a defun.
 185 This is identical to function `beginning-of-defun', except that point
 186 does not move to the beginning of the line when `defun-prompt-regexp'
 187 is non-nil.
 188
 189 If variable `beginning-of-defun-function' is non-nil, its value
 190 is called as a function to find the defun's beginning."
 191   (interactive "p")
 192   (if beginning-of-defun-function
 193       (if (> (setq arg (or arg 1)) 0)
 194           (dotimes (i arg)
 195             (funcall beginning-of-defun-function))
 196         ;; Better not call end-of-defun-function directly, in case
 197         ;; it's not defined.
 198         (end-of-defun (- arg)))
 199     (and arg (< arg 0) (not (eobp)) (forward-char 1))
 200     (and (re-search-backward (if defun-prompt-regexp
 201                                  (concat (if open-paren-in-column-0-is-defun-start
 202                                              "^\\s(\\|" "")
 203                                          "\\(?:" defun-prompt-regexp "\\)\\s(")
 204                                "^\\s(")
 205                              nil 'move (or arg 1))
 206          (progn (goto-char (1- (match-end 0)))) t)))
 207
 208 (defvar end-of-defun-function nil
 209   "If non-nil, function for function `end-of-defun' to call.
 210 This is used to find the end of the defun instead of using the normal
 211 recipe (see `end-of-defun').  Major modes can define this if the
 212 normal method is not appropriate.")
 213
 214 (defun buffer-end (arg)
 215   (if (> arg 0) (point-max) (point-min)))
 216
 217 (defun end-of-defun (&optional arg)
 218   "Move forward to next end of defun.  With argument, do it that many times.
 219 Negative argument -N means move back to Nth preceding end of defun.
 220
 221 An end of a defun occurs right after the close-parenthesis that
 222 matches the open-parenthesis that starts a defun; see function
 223 `beginning-of-defun'.
 224
 225 If variable `end-of-defun-function' is non-nil, its value
 226 is called as a function to find the defun's end."
 227   (interactive "p")
 228   (and (eq this-command 'end-of-defun)
 229        (or (eq last-command 'end-of-defun) (push-mark)))
 230   (if (or (null arg) (= arg 0)) (setq arg 1))
 231   (if end-of-defun-function
 232       (if (> arg 0)
 233           (dotimes (i arg)
 234             (funcall end-of-defun-function))
 235         ;; Better not call beginning-of-defun-function
 236         ;; directly, in case it's not defined.
 237         (beginning-of-defun (- arg)))
 238     (let ((first t))
 239       (while (and (> arg 0) (< (point) (point-max)))
 240         (let ((pos (point)))
 241           (while (progn
 242                    (if (and first
 243                             (progn
 244                               (end-of-line 1)
 245                               (beginning-of-defun-raw 1)))
 246                        nil
 247                      (or (bobp) (forward-char -1))
 248                      (beginning-of-defun-raw -1))
 249                    (setq first nil)
 250                    (forward-list 1)
 251                    (skip-chars-forward " \t")
 252                    (if (looking-at "\\s<\\|\n")
 253                        (forward-line 1))
 254                    (<= (point) pos))))
 255         (setq arg (1- arg)))
 256       (while (< arg 0)
 257         (let ((pos (point)))
 258           (beginning-of-defun-raw 1)
 259           (forward-sexp 1)
 260           (forward-line 1)
 261           (if (>= (point) pos)
 262               (if (beginning-of-defun-raw 2)
 263                   (progn
 264                     (forward-list 1)
 265                     (skip-chars-forward " \t")
 266                     (if (looking-at "\\s<\\|\n")
 267                         (forward-line 1)))
 268                 (goto-char (point-min)))))
 269         (setq arg (1+ arg))))))
 270
 271 (defun mark-defun ()
 272   "Put mark at end of this defun, point at beginning.
 273 The defun marked is the one that contains point or follows point.
 274 If this command is repeated, marks more defuns after the ones
 275 already marked."
 276   (interactive)
 277   (cond ((and (eq last-command this-command) (mark t))
 278          (set-mark
 279           (save-excursion
 280             (goto-char (mark))
 281             (end-of-defun)
 282             (point))))
 283         (t
 284          (let ((opoint (point))
 285                beg end)
 286            (push-mark opoint)
 287            ;; Try first in this order for the sake of languages with nested
 288            ;; functions where several can end at the same place as with
 289            ;; the offside rule, e.g. Python.
 290            (beginning-of-defun)
 291            (setq beg (point))
 292            (end-of-defun)
 293            (setq end (point))
 294            (while (looking-at "^\n")
 295              (forward-line 1))
 296            (if (> (point) opoint)
 297                (progn
 298                  ;; We got the right defun.
 299                  (push-mark beg nil t)
 300                  (goto-char end)
 301                  (exchange-point-and-mark))
 302              ;; beginning-of-defun moved back one defun
 303              ;; so we got the wrong one.
 304              (goto-char opoint)
 305              (end-of-defun)
 306              (push-mark (point) nil t)
 307              (beginning-of-defun))
 308            (re-search-backward "^\n" (- (point) 1) t)))))
 309
 310 (defun narrow-to-defun (&optional arg)
 311   "Make text outside current defun invisible.
 312 The defun visible is the one that contains point or follows point.
 313 Optional ARG is ignored."
 314   (interactive)
 315   (save-excursion
 316     (widen)
 317     (let ((opoint (point))
 318           beg end)
 319       ;; Try first in this order for the sake of languages with nested
 320       ;; functions where several can end at the same place as with
 321       ;; the offside rule, e.g. Python.
 322       (beginning-of-defun)
 323       (setq beg (point))
 324       (end-of-defun)
 325       (setq end (point))
 326       (while (looking-at "^\n")
 327         (forward-line 1))
 328       (unless (> (point) opoint)
 329         ;; beginning-of-defun moved back one defun
 330         ;; so we got the wrong one.
 331         (goto-char opoint)
 332         (end-of-defun)
 333         (setq end (point))
 334         (beginning-of-defun)
 335         (setq beg (point)))
 336       (goto-char end)
 337       (re-search-backward "^\n" (- (point) 1) t)
 338       (narrow-to-region beg end))))
 339
 340 (defvar insert-pair-alist
 341   '((?\( ?\)) (?\[ ?\]) (?\{ ?\}) (?\< ?\>) (?\" ?\") (?\' ?\') (?\` ?\'))
 342   "Alist of paired characters inserted by `insert-pair'.
 343 Each element looks like (OPEN-CHAR CLOSE-CHAR) or (COMMAND-CHAR
 344 OPEN-CHAR CLOSE-CHAR).  The characters OPEN-CHAR and CLOSE-CHAR
 345 of the pair whose key is equal to the last input character with
 346 or without modifiers, are inserted by `insert-pair'.")
 347
 348 (defun insert-pair (&optional arg open close)
 349   "Enclose following ARG sexps in a pair of OPEN and CLOSE characters.
 350 Leave point after the first character.
 351 A negative ARG encloses the preceding ARG sexps instead.
 352 No argument is equivalent to zero: just insert characters
 353 and leave point between.
 354 If `parens-require-spaces' is non-nil, this command also inserts a space
 355 before and after, depending on the surrounding characters.
 356 If region is active, insert enclosing characters at region boundaries.
 357
 358 If arguments OPEN and CLOSE are nil, the character pair is found
 359 from the variable `insert-pair-alist' according to the last input
 360 character with or without modifiers.  If no character pair is
 361 found in the variable `insert-pair-alist', then the last input
 362 character is inserted ARG times."
 363   (interactive "P")
 364   (if (not (and open close))
 365       (let ((pair (or (assq last-command-char insert-pair-alist)
 366                       (assq (event-basic-type last-command-event)
 367                             insert-pair-alist))))
 368         (if pair
 369             (if (nth 2 pair)
 370                 (setq open (nth 1 pair) close (nth 2 pair))
 371               (setq open (nth 0 pair) close (nth 1 pair))))))
 372   (if (and open close)
 373       (if (and transient-mark-mode mark-active)
 374           (progn
 375             (save-excursion (goto-char (region-end))       (insert close))
 376             (save-excursion (goto-char (region-beginning)) (insert open)))
 377         (if arg (setq arg (prefix-numeric-value arg))
 378           (setq arg 0))
 379         (cond ((> arg 0) (skip-chars-forward " \t"))
 380               ((< arg 0) (forward-sexp arg) (setq arg (- arg))))
 381         (and parens-require-spaces
 382              (not (bobp))
 383              (memq (char-syntax (preceding-char)) (list ?w ?_ (char-syntax close)))
 384              (insert " "))
 385         (insert open)
 386         (save-excursion
 387           (or (eq arg 0) (forward-sexp arg))
 388           (insert close)
 389           (and parens-require-spaces
 390                (not (eobp))
 391                (memq (char-syntax (following-char)) (list ?w ?_ (char-syntax open)))
 392                (insert " "))))
 393     (insert-char (event-basic-type last-command-event)
 394                  (prefix-numeric-value arg))))
 395
 396 (defun insert-parentheses (&optional arg)
 397   "Enclose following ARG sexps in parentheses.  Leave point after open-paren.
 398 A negative ARG encloses the preceding ARG sexps instead.
 399 No argument is equivalent to zero: just insert `()' and leave point between.
 400 If `parens-require-spaces' is non-nil, this command also inserts a space
 401 before and after, depending on the surrounding characters.
 402 If region is active, insert enclosing characters at region boundaries."
 403   (interactive "P")
 404   (insert-pair arg ?\( ?\)))
 405
 406 (defun delete-pair ()
 407   "Delete a pair of characters enclosing the sexp that follows point."
 408   (interactive)
 409   (save-excursion (forward-sexp 1) (delete-char -1))
 410   (delete-char 1))
 411
 412 (defun raise-sexp (&optional arg)
 413   "Raise ARG sexps higher up the tree."
 414   (interactive "p")
 415   (let ((s (if (and transient-mark-mode mark-active)
 416                (buffer-substring (region-beginning) (region-end))
 417              (buffer-substring
 418               (point)
 419               (save-excursion (forward-sexp arg) (point))))))
 420     (backward-up-list 1)
 421     (delete-region (point) (save-excursion (forward-sexp 1) (point)))
 422     (save-excursion (insert s))))
 423
 424 (defun move-past-close-and-reindent ()
 425   "Move past next `)', delete indentation before it, then indent after it."
 426   (interactive)
 427   (up-list 1)
 428   (forward-char -1)
 429   (while (save-excursion                ; this is my contribution
 430            (let ((before-paren (point)))
 431              (back-to-indentation)
 432              (and (= (point) before-paren)
 433                   (progn
 434                     ;; Move to end of previous line.
 435                     (beginning-of-line)
 436                     (forward-char -1)
 437                     ;; Verify it doesn't end within a string or comment.
 438                     (let ((end (point))
 439                           state)
 440                       (beginning-of-line)
 441                       ;; Get state at start of line.
 442                       (setq state  (list 0 nil nil
 443                                          (null (calculate-lisp-indent))
 444                                          nil nil nil nil
 445                                          nil))
 446                       ;; Parse state across the line to get state at end.
 447                       (setq state (parse-partial-sexp (point) end nil nil
 448                                                       state))
 449                       ;; Check not in string or comment.
 450                       (and (not (elt state 3)) (not (elt state 4))))))))
 451     (delete-indentation))
 452   (forward-char 1)
 453   (newline-and-indent))
 454
 455 (defun check-parens ()                  ; lame name?
 456   "Check for unbalanced parentheses in the current buffer.
 457 More accurately, check the narrowed part of the buffer for unbalanced
 458 expressions (\"sexps\") in general.  This is done according to the
 459 current syntax table and will find unbalanced brackets or quotes as
 460 appropriate.  (See Info node `(emacs)Lists and Sexps'.)  If imbalance
 461 is found, an error is signalled and point is left at the first
 462 unbalanced character."
 463   (interactive)
 464   (condition-case data
 465       ;; Buffer can't have more than (point-max) sexps.
 466       (scan-sexps (point-min) (point-max))
 467     (scan-error (goto-char (nth 2 data))
 468                 ;; Could print (nth 1 data), which is either
 469                 ;; "Containing expression ends prematurely" or
 470                 ;; "Unbalanced parentheses", but those may not be so
 471                 ;; accurate/helpful, e.g. quotes may actually be
 472                 ;; mismatched.
 473                 (error "Unmatched bracket or quote"))
 474     (error (cond ((eq 'scan-error (car data))
 475                   (goto-char (nth 2 data))
 476                   (error "Unmatched bracket or quote"))
 477                  (t (signal (car data) (cdr data)))))))
 478 \f
 479 (defun lisp-complete-symbol (&optional predicate)
 480   "Perform completion on Lisp symbol preceding point.
 481 Compare that symbol against the known Lisp symbols.
 482 If no characters can be completed, display a list of possible completions.
 483 Repeating the command at that point scrolls the list.
 484
 485 When called from a program, optional arg PREDICATE is a predicate
 486 determining which symbols are considered, e.g. `commandp'.
 487 If PREDICATE is nil, the context determines which symbols are
 488 considered.  If the symbol starts just after an open-parenthesis, only
 489 symbols with function definitions are considered.  Otherwise, all
 490 symbols with function definitions, values or properties are
 491 considered."
 492   (interactive)
 493
 494   (let ((window (get-buffer-window "*Completions*")))
 495     (if (and (eq last-command this-command)
 496              window (window-live-p window) (window-buffer window)
 497              (buffer-name (window-buffer window)))
 498         ;; If this command was repeated, and
 499         ;; there's a fresh completion window with a live buffer,
 500         ;; and this command is repeated, scroll that window.
 501         (with-current-buffer (window-buffer window)
 502           (if (pos-visible-in-window-p (point-max) window)
 503               (set-window-start window (point-min))
 504             (save-selected-window
 505               (select-window window)
 506               (scroll-up))))
 507
 508       ;; Do completion.
 509       (let* ((end (point))
 510              (beg (with-syntax-table emacs-lisp-mode-syntax-table
 511                     (save-excursion
 512                       (backward-sexp 1)
 513                       (while (= (char-syntax (following-char)) ?\')
 514                         (forward-char 1))
 515                       (point))))
 516              (pattern (buffer-substring-no-properties beg end))
 517              (predicate
 518               (or predicate
 519                   (save-excursion
 520                     (goto-char beg)
 521                     (if (not (eq (char-before) ?\())
 522                         (lambda (sym)   ;why not just nil ?   -sm
 523                           (or (boundp sym) (fboundp sym)
 524                               (symbol-plist sym)))
 525                       ;; Looks like a funcall position.  Let's double check.
 526                       (if (condition-case nil
 527                               (progn (up-list -2) (forward-char 1)
 528                                      (eq (char-after) ?\())
 529                             (error nil))
 530                           ;; If the first element of the parent list is an open
 531                           ;; parenthesis we are probably not in a funcall position.
 532                           ;; Maybe a `let' varlist or something.
 533                           nil
 534                         ;; Else, we assume that a function name is expected.
 535                         'fboundp)))))
 536              (completion (try-completion pattern obarray predicate)))
 537         (cond ((eq completion t))
 538               ((null completion)
 539                (message "Can't find completion for \"%s\"" pattern)
 540                (ding))
 541               ((not (string= pattern completion))
 542                (delete-region beg end)
 543                (insert completion))
 544               (t
 545                (message "Making completion list...")
 546                (let ((list (all-completions pattern obarray predicate)))
 547                  (setq list (sort list 'string<))
 548                  (or (eq predicate 'fboundp)
 549                      (let (new)
 550                        (while list
 551                          (setq new (cons (if (fboundp (intern (car list)))
 552                                              (list (car list) " <f>")
 553                                            (car list))
 554                                          new))
 555                          (setq list (cdr list)))
 556                        (setq list (nreverse new))))
 557                  (with-output-to-temp-buffer "*Completions*"
 558                    (display-completion-list list)))
 559                (message "Making completion list...%s" "done")))))))
 560
 561 ;;; arch-tag: aa7fa8a4-2e6f-4e9b-9cd9-fef06340e67e
 562 ;;; lisp.el ends here