code.delx.au - gnu-emacs/blob - lisp/replace.el

   1 ;;; replace.el --- replace commands for Emacs.
   2
   3 ;; Copyright (C) 1985, 1986, 1987, 1992, 1994, 1996 Free Software Foundation, Inc.
   4
   5 ;; This file is part of GNU Emacs.
   6
   7 ;; GNU Emacs is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation; either version 2, or (at your option)
  10 ;; any later version.
  11
  12 ;; GNU Emacs is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  19 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  20 ;; Boston, MA 02111-1307, USA.
  21
  22 ;;; Commentary:
  23
  24 ;; This package supplies the string and regular-expression replace functions
  25 ;; documented in the Emacs user's manual.
  26
  27 ;;; Code:
  28
  29 (defcustom case-replace t
  30   "*Non-nil means query-replace should preserve case in replacements."
  31   :type 'boolean
  32   :group 'matching)
  33
  34 (defvar query-replace-history nil)
  35
  36 (defvar query-replace-interactive nil
  37   "Non-nil means `query-replace' uses the last search string.
  38 That becomes the \"string to replace\".")
  39
  40 (defun query-replace-read-args (string regexp-flag)
  41   (let (from to)
  42     (if query-replace-interactive
  43         (setq from (car (if regexp-flag regexp-search-ring search-ring)))
  44       (setq from (read-from-minibuffer (format "%s: " string)
  45                                        nil nil nil
  46                                        'query-replace-history nil t)))
  47     (setq to (read-from-minibuffer (format "%s %s with: " string from)
  48                                    nil nil nil
  49                                    'query-replace-history nil t))
  50     (list from to current-prefix-arg)))
  51
  52 (defun query-replace (from-string to-string &optional arg)
  53   "Replace some occurrences of FROM-STRING with TO-STRING.
  54 As each match is found, the user must type a character saying
  55 what to do with it.  For directions, type \\[help-command] at that time.
  56
  57 In Transient Mark mode, if the mark is active, operate on the contents
  58 of the region.  Otherwise, operate from point to the end of the buffer.
  59
  60 If `query-replace-interactive' is non-nil, the last incremental search
  61 string is used as FROM-STRING--you don't have to specify it with the
  62 minibuffer.
  63
  64 Preserves case in each replacement if `case-replace' and `case-fold-search'
  65 are non-nil and FROM-STRING has no uppercase letters.
  66 \(Preserving case means that if the string matched is all caps, or capitalized,
  67 then its replacement is upcased or capitalized.)
  68
  69 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
  70 only matches surrounded by word boundaries.
  71
  72 To customize possible responses, change the \"bindings\" in `query-replace-map'."
  73   (interactive (query-replace-read-args "Query replace" nil))
  74   (perform-replace from-string to-string t nil arg))
  75
  76 (define-key esc-map "%" 'query-replace)
  77
  78 (defun query-replace-regexp (regexp to-string &optional arg)
  79   "Replace some things after point matching REGEXP with TO-STRING.
  80 As each match is found, the user must type a character saying
  81 what to do with it.  For directions, type \\[help-command] at that time.
  82
  83 In Transient Mark mode, if the mark is active, operate on the contents
  84 of the region.  Otherwise, operate from point to the end of the buffer.
  85
  86 If `query-replace-interactive' is non-nil, the last incremental search
  87 regexp is used as REGEXP--you don't have to specify it with the
  88 minibuffer.
  89
  90 Preserves case in each replacement if `case-replace' and `case-fold-search'
  91 are non-nil and REGEXP has no uppercase letters.
  92 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
  93 only matches surrounded by word boundaries.
  94 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
  95 and `\\=\\N' (where N is a digit) stands for
  96  whatever what matched the Nth `\\(...\\)' in REGEXP."
  97   (interactive (query-replace-read-args "Query replace regexp" t))
  98   (perform-replace regexp to-string t t arg))
  99
 100 (defun map-query-replace-regexp (regexp to-strings &optional arg)
 101   "Replace some matches for REGEXP with various strings, in rotation.
 102 The second argument TO-STRINGS contains the replacement strings, separated
 103 by spaces.  This command works like `query-replace-regexp' except
 104 that each successive replacement uses the next successive replacement string,
 105 wrapping around from the last such string to the first.
 106
 107 In Transient Mark mode, if the mark is active, operate on the contents
 108 of the region.  Otherwise, operate from point to the end of the buffer.
 109
 110 Non-interactively, TO-STRINGS may be a list of replacement strings.
 111
 112 If `query-replace-interactive' is non-nil, the last incremental search
 113 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 114
 115 A prefix argument N says to use each replacement string N times
 116 before rotating to the next."
 117   (interactive
 118    (let (from to)
 119      (setq from (if query-replace-interactive
 120                     (car regexp-search-ring)
 121                   (read-from-minibuffer "Map query replace (regexp): "
 122                                         nil nil nil
 123                                         'query-replace-history nil t)))
 124      (setq to (read-from-minibuffer
 125                (format "Query replace %s with (space-separated strings): "
 126                        from)
 127                nil nil nil
 128                'query-replace-history nil t))
 129      (list from to current-prefix-arg)))
 130   (let (replacements)
 131     (if (listp to-strings)
 132         (setq replacements to-strings)
 133       (while (/= (length to-strings) 0)
 134         (if (string-match " " to-strings)
 135             (setq replacements
 136                   (append replacements
 137                           (list (substring to-strings 0
 138                                            (string-match " " to-strings))))
 139                   to-strings (substring to-strings
 140                                        (1+ (string-match " " to-strings))))
 141           (setq replacements (append replacements (list to-strings))
 142                 to-strings ""))))
 143     (perform-replace regexp replacements t t nil arg)))
 144
 145 (defun replace-string (from-string to-string &optional delimited)
 146   "Replace occurrences of FROM-STRING with TO-STRING.
 147 Preserve case in each match if `case-replace' and `case-fold-search'
 148 are non-nil and FROM-STRING has no uppercase letters.
 149 \(Preserving case means that if the string matched is all caps, or capitalized,
 150 then its replacement is upcased or capitalized.)
 151
 152 In Transient Mark mode, if the mark is active, operate on the contents
 153 of the region.  Otherwise, operate from point to the end of the buffer.
 154
 155 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 156 only matches surrounded by word boundaries.
 157
 158 If `query-replace-interactive' is non-nil, the last incremental search
 159 string is used as FROM-STRING--you don't have to specify it with the
 160 minibuffer.
 161
 162 This function is usually the wrong thing to use in a Lisp program.
 163 What you probably want is a loop like this:
 164   (while (search-forward FROM-STRING nil t)
 165     (replace-match TO-STRING nil t))
 166 which will run faster and will not set the mark or print anything.
 167 \(You may need a more complex loop if FROM-STRING can match the null string
 168 and TO-STRING is also null.)"
 169   (interactive (query-replace-read-args "Replace string" nil))
 170   (perform-replace from-string to-string nil nil delimited))
 171
 172 (defun replace-regexp (regexp to-string &optional delimited)
 173   "Replace things after point matching REGEXP with TO-STRING.
 174 Preserve case in each match if `case-replace' and `case-fold-search'
 175 are non-nil and REGEXP has no uppercase letters.
 176 Third arg DELIMITED (prefix arg if interactive), if non-nil, means replace
 177 only matches surrounded by word boundaries.
 178 In TO-STRING, `\\&' stands for whatever matched the whole of REGEXP,
 179 and `\\=\\N' (where N is a digit) stands for
 180  whatever what matched the Nth `\\(...\\)' in REGEXP.
 181
 182 In Transient Mark mode, if the mark is active, operate on the contents
 183 of the region.  Otherwise, operate from point to the end of the buffer.
 184
 185 If `query-replace-interactive' is non-nil, the last incremental search
 186 regexp is used as REGEXP--you don't have to specify it with the minibuffer.
 187
 188 This function is usually the wrong thing to use in a Lisp program.
 189 What you probably want is a loop like this:
 190   (while (re-search-forward REGEXP nil t)
 191     (replace-match TO-STRING nil nil))
 192 which will run faster and will not set the mark or print anything."
 193   (interactive (query-replace-read-args "Replace regexp" t))
 194   (perform-replace regexp to-string nil t delimited))
 195 \f
 196 (defvar regexp-history nil
 197   "History list for some commands that read regular expressions.")
 198
 199 (defalias 'delete-non-matching-lines 'keep-lines)
 200 (defun keep-lines (regexp)
 201   "Delete all lines except those containing matches for REGEXP.
 202 A match split across lines preserves all the lines it lies in.
 203 Applies to all lines after point."
 204   (interactive (list (read-from-minibuffer
 205                       "Keep lines (containing match for regexp): "
 206                       nil nil nil 'regexp-history nil t)))
 207   (save-excursion
 208     (or (bolp) (forward-line 1))
 209     (let ((start (point)))
 210       (while (not (eobp))
 211         ;; Start is first char not preserved by previous match.
 212         (if (not (re-search-forward regexp nil 'move))
 213             (delete-region start (point-max))
 214           (let ((end (save-excursion (goto-char (match-beginning 0))
 215                                      (beginning-of-line)
 216                                      (point))))
 217             ;; Now end is first char preserved by the new match.
 218             (if (< start end)
 219                 (delete-region start end))))
 220         (setq start (save-excursion (forward-line 1)
 221                                     (point)))
 222         ;; If the match was empty, avoid matching again at same place.
 223         (and (not (eobp)) (= (match-beginning 0) (match-end 0))
 224              (forward-char 1))))))
 225
 226 (defalias 'delete-matching-lines 'flush-lines)
 227 (defun flush-lines (regexp)
 228   "Delete lines containing matches for REGEXP.
 229 If a match is split across lines, all the lines it lies in are deleted.
 230 Applies to lines after point."
 231   (interactive (list (read-from-minibuffer
 232                       "Flush lines (containing match for regexp): "
 233                       nil nil nil 'regexp-history nil t)))
 234   (save-excursion
 235     (while (and (not (eobp))
 236                 (re-search-forward regexp nil t))
 237       (delete-region (save-excursion (goto-char (match-beginning 0))
 238                                      (beginning-of-line)
 239                                      (point))
 240                      (progn (forward-line 1) (point))))))
 241
 242 (defalias 'count-matches 'how-many)
 243 (defun how-many (regexp)
 244   "Print number of matches for REGEXP following point."
 245   (interactive (list(read-from-minibuffer
 246                      "How many matches for (regexp): "
 247                      nil nil nil 'regexp-history nil t)))
 248   (let ((count 0) opoint)
 249     (save-excursion
 250      (while (and (not (eobp))
 251                  (progn (setq opoint (point))
 252                         (re-search-forward regexp nil t)))
 253        (if (= opoint (point))
 254            (forward-char 1)
 255          (setq count (1+ count))))
 256      (message "%d occurrences" count))))
 257 \f
 258 (defvar occur-mode-map ())
 259 (if occur-mode-map
 260     ()
 261   (setq occur-mode-map (make-sparse-keymap))
 262   (define-key occur-mode-map [mouse-2] 'occur-mode-mouse-goto)
 263   (define-key occur-mode-map "\C-c\C-c" 'occur-mode-goto-occurrence)
 264   (define-key occur-mode-map "\C-m" 'occur-mode-goto-occurrence)
 265   (define-key occur-mode-map "\M-n" 'occur-next)
 266   (define-key occur-mode-map "\M-p" 'occur-prev)
 267   (define-key occur-mode-map "g" 'revert-buffer))
 268
 269
 270 (defvar occur-buffer nil
 271   "Name of buffer for last occur.")
 272
 273
 274 (defvar occur-nlines nil
 275   "Number of lines of context to show around matching line.")
 276
 277 (defvar occur-command-arguments nil
 278   "Arguments that were given to `occur' when it made this buffer.")
 279
 280 (put 'occur-mode 'mode-class 'special)
 281
 282 (defun occur-mode ()
 283   "Major mode for output from \\[occur].
 284 \\<occur-mode-map>Move point to one of the items in this buffer, then use
 285 \\[occur-mode-goto-occurrence] to go to the occurrence that the item refers to.
 286 Alternatively, click \\[occur-mode-mouse-goto] on an item to go to it.
 287
 288 \\{occur-mode-map}"
 289   (kill-all-local-variables)
 290   (use-local-map occur-mode-map)
 291   (setq major-mode 'occur-mode)
 292   (setq mode-name "Occur")
 293   (make-local-variable 'revert-buffer-function)
 294   (setq revert-buffer-function 'occur-revert-function)
 295   (make-local-variable 'occur-buffer)
 296   (make-local-variable 'occur-nlines)
 297   (make-local-variable 'occur-command-arguments)
 298   (run-hooks 'occur-mode-hook))
 299
 300 ;; Handle revert-buffer for *Occur* buffers.
 301 (defun occur-revert-function (ignore1 ignore2)
 302   (let ((args occur-command-arguments ))
 303     (save-excursion
 304       (set-buffer occur-buffer)
 305       (apply 'occur args))))
 306
 307 (defun occur-mode-mouse-goto (event)
 308   "In Occur mode, go to the occurrence whose line you click on."
 309   (interactive "e")
 310   (let (buffer pos)
 311     (save-excursion
 312       (set-buffer (window-buffer (posn-window (event-end event))))
 313       (save-excursion
 314         (goto-char (posn-point (event-end event)))
 315         (setq pos (occur-mode-find-occurrence))
 316         (setq buffer occur-buffer)))
 317     (pop-to-buffer buffer)
 318     (goto-char (marker-position pos))))
 319
 320 (defun occur-mode-find-occurrence ()
 321   (if (or (null occur-buffer)
 322           (null (buffer-name occur-buffer)))
 323       (progn
 324         (setq occur-buffer nil)
 325         (error "Buffer in which occurrences were found is deleted")))
 326   (let ((pos (get-text-property (point) 'occur)))
 327     (if (null pos)
 328         (error "No occurrence on this line")
 329       pos)))
 330
 331 (defun occur-mode-goto-occurrence ()
 332   "Go to the occurrence the current line describes."
 333   (interactive)
 334   (let ((pos (occur-mode-find-occurrence)))
 335     (pop-to-buffer occur-buffer)
 336     (goto-char (marker-position pos))))
 337
 338 (defun occur-next (&optional n)
 339   "Move to the Nth (default 1) next match in the *Occur* buffer."
 340   (interactive "p")
 341   (if (not n) (setq n 1))
 342   (let ((r))
 343     (while (> n 0)
 344       (if (get-text-property (point) 'occur-point)
 345           (forward-char 1))
 346       (setq r (next-single-property-change (point) 'occur-point))
 347       (if r
 348           (goto-char r)
 349         (error "no more matches"))
 350       (setq n (1- n)))))
 351
 352
 353
 354 (defun occur-prev (&optional n)
 355   "Move to the Nth (default 1) previous match in the *Occur* buffer."
 356   (interactive "p")
 357   (if (not n) (setq n 1))
 358   (let ((r))
 359     (while (> n 0)
 360
 361       (setq r (get-text-property (point) 'occur-point))
 362       (if r (forward-char -1))
 363
 364       (setq r (previous-single-property-change (point) 'occur-point))
 365       (if r
 366           (goto-char (- r 1))
 367         (error "no earlier matches"))
 368
 369       (setq n (1- n)))))
 370 \f
 371 (defcustom list-matching-lines-default-context-lines 0
 372   "*Default number of context lines to include around a `list-matching-lines'
 373 match.  A negative number means to include that many lines before the match.
 374 A positive number means to include that many lines both before and after."
 375   :type 'integer
 376   :group 'matching)
 377
 378 (defalias 'list-matching-lines 'occur)
 379
 380 (defvar list-matching-lines-face 'bold
 381   "*Face used by M-x list-matching-lines to show the text that matches.
 382 If the value is nil, don't highlight the matching portions specially.")
 383
 384 (defun occur (regexp &optional nlines)
 385   "Show all lines in the current buffer containing a match for REGEXP.
 386
 387 If a match spreads across multiple lines, all those lines are shown.
 388
 389 Each line is displayed with NLINES lines before and after, or -NLINES
 390 before if NLINES is negative.
 391 NLINES defaults to `list-matching-lines-default-context-lines'.
 392 Interactively it is the prefix arg.
 393
 394 The lines are shown in a buffer named `*Occur*'.
 395 It serves as a menu to find any of the occurrences in this buffer.
 396 \\<occur-mode-map>\\[describe-mode] in that buffer will explain how.
 397
 398 If REGEXP contains upper case characters (excluding those preceded by `\\'),
 399 the matching is case-sensitive."
 400   (interactive
 401    (list (let* ((default (car regexp-history))
 402                 (input
 403                  (read-from-minibuffer
 404                   (if default
 405                       (format "List lines matching regexp (default `%s'): "
 406                               default)
 407                     "List lines matching regexp: ")
 408                   nil nil nil 'regexp-history nil t)))
 409            (if (string-equal input "")
 410                default
 411              (set-text-properties 0 (length input) nil input)
 412              input))
 413          current-prefix-arg))
 414   (let ((nlines (if nlines
 415                     (prefix-numeric-value nlines)
 416                   list-matching-lines-default-context-lines))
 417         (first t)
 418         ;;flag to prevent printing separator for first match
 419         (occur-num-matches 0)
 420         (buffer (current-buffer))
 421         (dir default-directory)
 422         (linenum 1)
 423         (prevpos
 424          ;;position of most recent match
 425          (point-min))
 426         (case-fold-search  (and case-fold-search
 427                                 (isearch-no-upper-case-p regexp t)))
 428         (final-context-start
 429          ;; Marker to the start of context immediately following
 430          ;; the matched text in *Occur*.
 431          (make-marker)))
 432 ;;;     (save-excursion
 433 ;;;       (beginning-of-line)
 434 ;;;       (setq linenum (1+ (count-lines (point-min) (point))))
 435 ;;;       (setq prevpos (point)))
 436     (save-excursion
 437       (goto-char (point-min))
 438       ;; Check first whether there are any matches at all.
 439       (if (not (re-search-forward regexp nil t))
 440           (message "No matches for `%s'" regexp)
 441         ;; Back up, so the search loop below will find the first match.
 442         (goto-char (match-beginning 0))
 443         (with-output-to-temp-buffer "*Occur*"
 444           (save-excursion
 445             (set-buffer standard-output)
 446             (setq default-directory dir)
 447             ;; We will insert the number of lines, and "lines", later.
 448             (insert " matching ")
 449             (let ((print-escape-newlines t))
 450               (prin1 regexp))
 451             (insert " in buffer " (buffer-name buffer) ?. ?\n)
 452             (occur-mode)
 453             (setq occur-buffer buffer)
 454             (setq occur-nlines nlines)
 455             (setq occur-command-arguments
 456                   (list regexp nlines)))
 457           (if (eq buffer standard-output)
 458               (goto-char (point-max)))
 459           (save-excursion
 460             ;; Find next match, but give up if prev match was at end of buffer.
 461             (while (and (not (= prevpos (point-max)))
 462                         (re-search-forward regexp nil t))
 463               (goto-char (match-beginning 0))
 464               (beginning-of-line)
 465               (save-match-data
 466                 (setq linenum (+ linenum (count-lines prevpos (point)))))
 467               (setq prevpos (point))
 468               (goto-char (match-end 0))
 469               (let* ((start
 470                       ;;start point of text in source buffer to be put
 471                       ;;into *Occur*
 472                       (save-excursion
 473                               (goto-char (match-beginning 0))
 474                               (forward-line (if (< nlines 0)
 475                                                 nlines
 476                                               (- nlines)))
 477                               (point)))
 478                      (end
 479                       ;; end point of text in source buffer to be put
 480                       ;; into *Occur*
 481                       (save-excursion
 482                         (goto-char (match-end 0))
 483                         (if (> nlines 0)
 484                             (forward-line (1+ nlines))
 485                           (forward-line 1))
 486                         (point)))
 487                      (match-beg
 488                       ;; Amount of context before matching text
 489                       (- (match-beginning 0) start))
 490                      (match-len
 491                       ;; Length of matching text
 492                       (- (match-end 0) (match-beginning 0)))
 493                      (tag (format "%5d" linenum))
 494                      (empty (make-string (length tag) ?\ ))
 495                      tem
 496                      ;; Number of lines of context to show for current match.
 497                      occur-marker
 498                      ;; Marker pointing to end of match in source buffer.
 499                      (text-beg
 500                       ;; Marker pointing to start of text for one
 501                       ;; match in *Occur*.
 502                       (make-marker))
 503                      (text-end
 504                       ;; Marker pointing to end of text for one match
 505                       ;; in *Occur*.
 506                       (make-marker))
 507                      )
 508                 (save-excursion
 509                   (setq occur-marker (make-marker))
 510                   (set-marker occur-marker (point))
 511                   (set-buffer standard-output)
 512                   (setq occur-num-matches (1+ occur-num-matches))
 513                   (or first (zerop nlines)
 514                       (insert "--------\n"))
 515                   (setq first nil)
 516
 517                   ;; Insert matching text including context lines from
 518                   ;; source buffer into *Occur*
 519                   (set-marker text-beg (point))
 520                   (insert-buffer-substring buffer start end)
 521                   (set-marker text-end (point))
 522
 523                   ;; Highlight text that was matched.
 524                   (if list-matching-lines-face
 525                       (put-text-property
 526                        (+ (marker-position text-beg) match-beg)
 527                        (+ (marker-position text-beg) match-beg match-len)
 528                        'face list-matching-lines-face))
 529
 530                   ;; `occur-point' property is used by occur-next and
 531                   ;; occur-prev to move between matching lines.
 532                   (put-text-property
 533                    (+ (marker-position text-beg) match-beg match-len)
 534                    (+ (marker-position text-beg) match-beg match-len 1)
 535                    'occur-point t)
 536                   (set-marker final-context-start
 537                               (- (point) (- end (match-end 0))))
 538
 539                   ;; Now go back to the start of the matching text
 540                   ;; adding the space and colon to the start of each line.
 541                   (goto-char (- (point) (- end start)))
 542                   ;; Insert space and colon for lines of context before match.
 543                   (setq tem (if (< linenum nlines)
 544                                 (- nlines linenum)
 545                               nlines))
 546                   (while (> tem 0)
 547                     (insert empty ?:)
 548                     (forward-line 1)
 549                     (setq tem (1- tem)))
 550
 551                   ;; Insert line number and colon for the lines of
 552                   ;; matching text.
 553                   (let ((this-linenum linenum))
 554                     (while (< (point) final-context-start)
 555                       (if (null tag)
 556                           (setq tag (format "%5d" this-linenum)))
 557                       (insert tag ?:)
 558                       (forward-line 1)
 559                       (setq tag nil)
 560                       (setq this-linenum (1+ this-linenum)))
 561                     (while (<= (point) final-context-start)
 562                       (insert empty ?:)
 563                       (forward-line 1)
 564                       (setq this-linenum (1+ this-linenum))))
 565
 566                   ;; Insert space and colon for lines of context after match.
 567                   (while (and (< (point) (point-max)) (< tem nlines))
 568                     (insert empty ?:)
 569                     (forward-line 1)
 570                     (setq tem (1+ tem)))
 571
 572                   ;; Add text properties.  The `occur' prop is used to
 573                   ;; store the marker of the matching text in the
 574                   ;; source buffer.
 575                   (put-text-property (marker-position text-beg)
 576                                      (- (marker-position text-end) 1)
 577                                      'mouse-face 'highlight)
 578                   (put-text-property (marker-position text-beg)
 579                                      (marker-position text-end)
 580                                      'occur occur-marker)
 581                   (goto-char (point-max)))
 582                 (forward-line 1)))
 583             (set-buffer standard-output)
 584             ;; Go back to top of *Occur* and finish off by printing the
 585             ;; number of matching lines.
 586             (goto-char (point-min))
 587             (let ((message-string
 588                    (if (= occur-num-matches 1)
 589                        "1 line"
 590                      (format "%d lines" occur-num-matches))))
 591               (insert message-string)
 592               (if (interactive-p)
 593                   (message "%s matched" message-string)))))))))
 594 \f
 595 ;; It would be nice to use \\[...], but there is no reasonable way
 596 ;; to make that display both SPC and Y.
 597 (defconst query-replace-help
 598   "Type Space or `y' to replace one match, Delete or `n' to skip to next,
 599 RET or `q' to exit, Period to replace one match and exit,
 600 Comma to replace but not move point immediately,
 601 C-r to enter recursive edit (\\[exit-recursive-edit] to get out again),
 602 C-w to delete match and recursive edit,
 603 C-l to clear the screen, redisplay, and offer same replacement again,
 604 ! to replace all remaining matches with no more questions,
 605 ^ to move point back to previous match."
 606   "Help message while in query-replace")
 607
 608 (defvar query-replace-map (make-sparse-keymap)
 609   "Keymap that defines the responses to questions in `query-replace'.
 610 The \"bindings\" in this map are not commands; they are answers.
 611 The valid answers include `act', `skip', `act-and-show',
 612 `exit', `act-and-exit', `edit', `delete-and-edit', `recenter',
 613 `automatic', `backup', `exit-prefix', and `help'.")
 614
 615 (define-key query-replace-map " " 'act)
 616 (define-key query-replace-map "\d" 'skip)
 617 (define-key query-replace-map [delete] 'skip)
 618 (define-key query-replace-map [backspace] 'skip)
 619 (define-key query-replace-map "y" 'act)
 620 (define-key query-replace-map "n" 'skip)
 621 (define-key query-replace-map "Y" 'act)
 622 (define-key query-replace-map "N" 'skip)
 623 (define-key query-replace-map "," 'act-and-show)
 624 (define-key query-replace-map "q" 'exit)
 625 (define-key query-replace-map "\r" 'exit)
 626 (define-key query-replace-map [return] 'exit)
 627 (define-key query-replace-map "." 'act-and-exit)
 628 (define-key query-replace-map "\C-r" 'edit)
 629 (define-key query-replace-map "\C-w" 'delete-and-edit)
 630 (define-key query-replace-map "\C-l" 'recenter)
 631 (define-key query-replace-map "!" 'automatic)
 632 (define-key query-replace-map "^" 'backup)
 633 (define-key query-replace-map "\C-h" 'help)
 634 (define-key query-replace-map [f1] 'help)
 635 (define-key query-replace-map [help] 'help)
 636 (define-key query-replace-map "?" 'help)
 637 (define-key query-replace-map "\C-g" 'quit)
 638 (define-key query-replace-map "\C-]" 'quit)
 639 (define-key query-replace-map "\e" 'exit-prefix)
 640 (define-key query-replace-map [escape] 'exit-prefix)
 641
 642 (defun perform-replace (from-string replacements
 643                         query-flag regexp-flag delimited-flag
 644                         &optional repeat-count map)
 645   "Subroutine of `query-replace'.  Its complexity handles interactive queries.
 646 Don't use this in your own program unless you want to query and set the mark
 647 just as `query-replace' does.  Instead, write a simple loop like this:
 648   (while (re-search-forward \"foo[ \t]+bar\" nil t)
 649     (replace-match \"foobar\" nil nil))
 650 which will run faster and probably do exactly what you want."
 651   (or map (setq map query-replace-map))
 652   (and query-flag minibuffer-auto-raise
 653        (raise-frame (window-frame (minibuffer-window))))
 654   (let ((nocasify (not (and case-fold-search case-replace
 655                             (string-equal from-string
 656                                           (downcase from-string)))))
 657         (literal (not regexp-flag))
 658         (search-function (if regexp-flag 're-search-forward 'search-forward))
 659         (search-string from-string)
 660         (real-match-data nil)           ; the match data for the current match
 661         (next-replacement nil)
 662         (replacement-index 0)
 663         (keep-going t)
 664         (stack nil)
 665         (next-rotate-count 0)
 666         (replace-count 0)
 667         (nonempty-match nil)
 668
 669         ;; If non-nil, it is marker saying where in the buffer to stop.
 670         (limit nil)
 671
 672         ;; Data for the next match.  If a cons, it has the same format as
 673         ;; (match-data); otherwise it is t if a match is possible at point.
 674         (match-again t)
 675
 676         (message
 677          (if query-flag
 678              (substitute-command-keys
 679               "Query replacing %s with %s: (\\<query-replace-map>\\[help] for help) "))))
 680
 681     ;; If region is active, in Transient Mark mode, operate on region.
 682     (if (and transient-mark-mode mark-active)
 683         (progn
 684           (setq limit (copy-marker (region-end)))
 685           (goto-char (region-beginning))
 686           (deactivate-mark)))
 687     (if (stringp replacements)
 688         (setq next-replacement replacements)
 689       (or repeat-count (setq repeat-count 1)))
 690     (if delimited-flag
 691         (setq search-function 're-search-forward
 692               search-string (concat "\\b"
 693                                     (if regexp-flag from-string
 694                                       (regexp-quote from-string))
 695                                     "\\b")))
 696     (push-mark)
 697     (undo-boundary)
 698     (unwind-protect
 699         ;; Loop finding occurrences that perhaps should be replaced.
 700         (while (and keep-going
 701                     (not (eobp))
 702                     ;; Use the next match if it is already known;
 703                     ;; otherwise, search for a match after moving forward
 704                     ;; one char if progress is required.
 705                     (setq real-match-data
 706                           (if (consp match-again)
 707                               (progn (goto-char (nth 1 match-again))
 708                                      match-again)
 709                             (and (or match-again
 710                                      (progn
 711                                        (forward-char 1)
 712                                        (not (eobp))))
 713                                  (funcall search-function search-string limit t)
 714                                  ;; For speed, use only integers and
 715                                  ;; reuse the list used last time.
 716                                  (match-data t real-match-data)))))
 717
 718           ;; Record whether the match is nonempty, to avoid an infinite loop
 719           ;; repeatedly matching the same empty string.
 720           (setq nonempty-match
 721                 (/= (nth 0 real-match-data) (nth 1 real-match-data)))
 722
 723           ;; If the match is empty, record that the next one can't be adjacent.
 724           ;; Otherwise, if matching a regular expression, do the next
 725           ;; match now, since the replacement for this match may
 726           ;; affect whether the next match is adjacent to this one.
 727           (setq match-again
 728                 (and nonempty-match
 729                      (or (not regexp-flag)
 730                          (and (looking-at search-string)
 731                               (match-data)))))
 732
 733           ;; If time for a change, advance to next replacement string.
 734           (if (and (listp replacements)
 735                    (= next-rotate-count replace-count))
 736               (progn
 737                 (setq next-rotate-count
 738                       (+ next-rotate-count repeat-count))
 739                 (setq next-replacement (nth replacement-index replacements))
 740                 (setq replacement-index (% (1+ replacement-index) (length replacements)))))
 741           (if (not query-flag)
 742               (progn
 743                 (store-match-data real-match-data)
 744                 (replace-match next-replacement nocasify literal)
 745                 (setq replace-count (1+ replace-count)))
 746             (undo-boundary)
 747             (let (done replaced key def)
 748               ;; Loop reading commands until one of them sets done,
 749               ;; which means it has finished handling this occurrence.
 750               (while (not done)
 751                 (store-match-data real-match-data)
 752                 (replace-highlight (match-beginning 0) (match-end 0))
 753                 ;; Bind message-log-max so we don't fill up the message log
 754                 ;; with a bunch of identical messages.
 755                 (let ((message-log-max nil))
 756                   (message message from-string next-replacement))
 757                 (setq key (read-event))
 758                 ;; Necessary in case something happens during read-event
 759                 ;; that clobbers the match data.
 760                 (store-match-data real-match-data)
 761                 (setq key (vector key))
 762                 (setq def (lookup-key map key))
 763                 ;; Restore the match data while we process the command.
 764                 (cond ((eq def 'help)
 765                        (with-output-to-temp-buffer "*Help*"
 766                          (princ
 767                           (concat "Query replacing "
 768                                   (if regexp-flag "regexp " "")
 769                                   from-string " with "
 770                                   next-replacement ".\n\n"
 771                                   (substitute-command-keys
 772                                    query-replace-help)))
 773                          (save-excursion
 774                            (set-buffer standard-output)
 775                            (help-mode))))
 776                       ((eq def 'exit)
 777                        (setq keep-going nil)
 778                        (setq done t))
 779                       ((eq def 'backup)
 780                        (if stack
 781                            (let ((elt (car stack)))
 782                              (goto-char (car elt))
 783                              (setq replaced (eq t (cdr elt)))
 784                              (or replaced
 785                                  (store-match-data (cdr elt)))
 786                              (setq stack (cdr stack)))
 787                          (message "No previous match")
 788                          (ding 'no-terminate)
 789                          (sit-for 1)))
 790                       ((eq def 'act)
 791                        (or replaced
 792                            (progn
 793                              (replace-match next-replacement nocasify literal)
 794                              (setq replace-count (1+ replace-count))))
 795                        (setq done t replaced t))
 796                       ((eq def 'act-and-exit)
 797                        (or replaced
 798                            (progn
 799                              (replace-match next-replacement nocasify literal)
 800                              (setq replace-count (1+ replace-count))))
 801                        (setq keep-going nil)
 802                        (setq done t replaced t))
 803                       ((eq def 'act-and-show)
 804                        (if (not replaced)
 805                            (progn
 806                              (replace-match next-replacement nocasify literal)
 807                              (setq replace-count (1+ replace-count))
 808                              (setq replaced t))))
 809                       ((eq def 'automatic)
 810                        (or replaced
 811                            (progn
 812                              (replace-match next-replacement nocasify literal)
 813                              (setq replace-count (1+ replace-count))))
 814                        (setq done t query-flag nil replaced t))
 815                       ((eq def 'skip)
 816                        (setq done t))
 817                       ((eq def 'recenter)
 818                        (recenter nil))
 819                       ((eq def 'edit)
 820                        (store-match-data
 821                         (prog1 (match-data)
 822                           (save-excursion (recursive-edit))))
 823                        ;; Before we make the replacement,
 824                        ;; decide whether the search string
 825                        ;; can match again just after this match.
 826                        (if (and regexp-flag nonempty-match)
 827                            (setq match-again (and (looking-at search-string)
 828                                                   (match-data)))))
 829                       ((eq def 'delete-and-edit)
 830                        (delete-region (match-beginning 0) (match-end 0))
 831                        (store-match-data
 832                         (prog1 (match-data)
 833                           (save-excursion (recursive-edit))))
 834                        (setq replaced t))
 835                       ;; Note: we do not need to treat `exit-prefix'
 836                       ;; specially here, since we reread
 837                       ;; any unrecognized character.
 838                       (t
 839                        (setq this-command 'mode-exited)
 840                        (setq keep-going nil)
 841                        (setq unread-command-events
 842                              (append (listify-key-sequence key)
 843                                      unread-command-events))
 844                        (setq done t))))
 845               ;; Record previous position for ^ when we move on.
 846               ;; Change markers to numbers in the match data
 847               ;; since lots of markers slow down editing.
 848               (setq stack
 849                     (cons (cons (point)
 850                                 (or replaced (match-data t)))
 851                           stack)))))
 852       (replace-dehighlight))
 853     (or unread-command-events
 854         (message "Replaced %d occurrence%s"
 855                  replace-count
 856                  (if (= replace-count 1) "" "s")))
 857     (and keep-going stack)))
 858
 859 (defcustom query-replace-highlight t
 860   "*Non-nil means to highlight words during query replacement."
 861   :type 'boolean
 862   :group 'matching)
 863
 864 (defvar replace-overlay nil)
 865
 866 (defun replace-dehighlight ()
 867   (and replace-overlay
 868        (progn
 869          (delete-overlay replace-overlay)
 870          (setq replace-overlay nil))))
 871
 872 (defun replace-highlight (start end)
 873   (and query-replace-highlight
 874        (progn
 875          (or replace-overlay
 876              (progn
 877                (setq replace-overlay (make-overlay start end))
 878                (overlay-put replace-overlay 'face
 879                             (if (internal-find-face 'query-replace)
 880                                 'query-replace 'region))))
 881          (move-overlay replace-overlay start end (current-buffer)))))
 882
 883 ;;; replace.el ends here