code.delx.au - gnu-emacs/blob - lisp/gnus/spam-report.el

   1 ;;; spam-report.el --- Reporting spam
   2 ;; Copyright (C) 2002, 2003, 2004, 2005 Free Software Foundation, Inc.
   3
   4 ;; Author: Teodor Zlatanov <tzz@lifelogs.com>
   5 ;; Keywords: network
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software; you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation; either version 2, or (at your option)
  12 ;; any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  21 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  22 ;; Boston, MA 02111-1307, USA.
  23
  24 ;;; Commentary:
  25
  26 ;;; This module addresses a few aspects of spam reporting under Gnus.  Page
  27 ;;; breaks are used for grouping declarations and documentation relating to
  28 ;;; each particular aspect.
  29
  30 ;;; Code:
  31 (require 'gnus)
  32 (require 'gnus-sum)
  33
  34 (eval-and-compile
  35   (autoload 'mm-url-insert "mm-url"))
  36
  37 (defgroup spam-report nil
  38   "Spam reporting configuration."
  39   :group 'mail
  40   :group 'news)
  41
  42 (defcustom spam-report-gmane-regex nil
  43   "Regexp matching Gmane newsgroups, e.g. \"^nntp\\+.*:gmane\\.\"
  44 If you are using spam.el, consider setting gnus-spam-process-newsgroups
  45 or the gnus-group-spam-exit-processor-report-gmane group/topic parameter
  46 instead."
  47   :type '(radio (const nil)
  48                 (regexp :value "^nntp\+.*:gmane\."))
  49   :group 'spam-report)
  50
  51 (defcustom spam-report-gmane-spam-header
  52   "^X-Report-Spam: http://\\([^/]+\\)\\(.*\\)$"
  53   "String matching Gmane spam-reporting header.  Two match groups are needed."
  54   :type 'regexp
  55   :group 'spam-report)
  56
  57 (defcustom spam-report-gmane-use-article-number t
  58   "Whether the article number (faster!) or the header should be used."
  59   :type 'boolean
  60   :group 'spam-report)
  61
  62 (defcustom spam-report-url-ping-function
  63   'spam-report-url-ping-plain
  64   "Function to use for url ping spam reporting.
  65 The function must accept the arguments `host' and `report'."
  66   :type '(choice
  67           (const :tag "Connect directly"
  68                  spam-report-url-ping-plain)
  69           (const :tag "Use the external program specified in `mm-url-program'"
  70                  spam-report-url-ping-mm-url)
  71           (const :tag "Store request URLs in `spam-report-requests-file'"
  72                  spam-report-url-to-file)
  73           (function :tag "User defined function" nil))
  74   :group 'spam-report)
  75
  76 (defcustom spam-report-requests-file
  77   (nnheader-concat gnus-directory "spam/" "spam-report-requests.url")
  78   ;; Is there a convention for the extension of such a file?
  79   ;; Should we use `spam-directory'?
  80   "File where spam report request are stored."
  81   :type 'file
  82   :group 'spam-report)
  83
  84 (defvar spam-report-url-ping-temp-agent-function nil
  85   "Internal variable for `spam-report-agentize' and `spam-report-deagentize'.
  86 This variable will store the value of `spam-report-url-ping-function' from
  87 before `spam-report-agentize' was run, so that `spam-report-deagentize' can
  88 undo that change.")
  89
  90 (defun spam-report-gmane (&rest articles)
  91   "Report an article as spam through Gmane"
  92   (dolist (article articles)
  93     (when (and gnus-newsgroup-name
  94                (or (null spam-report-gmane-regex)
  95                    (string-match spam-report-gmane-regex gnus-newsgroup-name)))
  96       (gnus-message 6 "Reporting spam article %d to spam.gmane.org..." article)
  97       (if spam-report-gmane-use-article-number
  98           (spam-report-url-ping
  99            "spam.gmane.org"
 100            (format "/%s:%d"
 101                    (gnus-group-real-name gnus-newsgroup-name)
 102                    article))
 103         (with-current-buffer nntp-server-buffer
 104           (gnus-request-head article gnus-newsgroup-name)
 105           (goto-char (point-min))
 106           (if (re-search-forward spam-report-gmane-spam-header nil t)
 107               (let* ((host (match-string 1))
 108                      (report (match-string 2))
 109                      (url (format "http://%s%s" host report)))
 110                 (gnus-message 7 "Reporting spam through URL %s..." url)
 111                 (spam-report-url-ping host report))
 112             (gnus-message 3 "Could not find X-Report-Spam in article %d..."
 113                           article)))))))
 114
 115 (defun spam-report-url-ping (host report)
 116   "Ping a host through HTTP, addressing a specific GET resource using
 117 the function specified by `spam-report-url-ping-function'."
 118   (funcall spam-report-url-ping-function host report))
 119
 120 (defun spam-report-url-ping-plain (host report)
 121   "Ping a host through HTTP, addressing a specific GET resource."
 122   (let ((tcp-connection))
 123     (with-temp-buffer
 124       (or (setq tcp-connection
 125                 (open-network-stream
 126                  "URL ping"
 127                  (buffer-name)
 128                  host
 129                  80))
 130           (error "Could not open connection to %s" host))
 131       (set-marker (process-mark tcp-connection) (point-min))
 132       (process-send-string
 133        tcp-connection
 134        (format "GET %s HTTP/1.1\nUser-Agent: %s (spam-report.el)\nHost: %s\n\n"
 135                report (gnus-emacs-version) host)))))
 136
 137 ;;;###autoload
 138 (defun spam-report-process-queue (&optional file keep)
 139   "Report all queued requests from `spam-report-requests-file'.
 140
 141 If FILE is given, use it instead of `spam-report-requests-file'.
 142 If KEEP is t, leave old requests in the file.  If KEEP is the
 143 symbol `ask', query before flushing the queue file."
 144   (interactive
 145    (list (read-file-name
 146           "File: "
 147           (file-name-directory spam-report-requests-file)
 148           spam-report-requests-file
 149           nil
 150           (file-name-nondirectory spam-report-requests-file))
 151          current-prefix-arg))
 152   (if (eq spam-report-url-ping-function 'spam-report-url-to-file)
 153       (error (concat "Cannot process requests when "
 154                      "`spam-report-url-ping-function' is "
 155                      "`spam-report-url-to-file'."))
 156     (gnus-message 7 "Processing requests using `%s'."
 157                   spam-report-url-ping-function))
 158   (or file (setq file spam-report-requests-file))
 159   (save-excursion
 160     (set-buffer (find-file-noselect file))
 161     (goto-char (point-min))
 162     (while (and (not (eobp))
 163                 (re-search-forward
 164                  "http://\\([^/]+\\)\\(/.*\\) *$" (gnus-point-at-eol) t))
 165       (funcall spam-report-url-ping-function (match-string 1) (match-string 2))
 166       (forward-line 1))
 167     (if (or (eq keep nil)
 168             (and (eq keep 'ask)
 169                  (y-or-n-p
 170                   (format
 171                    "Flush requests from `%s'? " (current-buffer)))))
 172         (progn
 173           (gnus-message 7 "Flushing request file `%s'"
 174                         spam-report-requests-file)
 175           (erase-buffer)
 176           (save-buffer)
 177           (kill-buffer (current-buffer)))
 178       (gnus-message 7 "Keeping requests in `%s'" spam-report-requests-file))))
 179
 180 ;;;###autoload
 181 (defun spam-report-url-ping-mm-url (host report)
 182   "Ping a host through HTTP, addressing a specific GET resource. Use
 183 the external program specified in `mm-url-program' to connect to
 184 server."
 185   (with-temp-buffer
 186     (let ((url (format "http://%s%s" host report)))
 187       (mm-url-insert url t))))
 188
 189 ;;;###autoload
 190 (defun spam-report-url-to-file (host report)
 191   "Collect spam report requests in `spam-report-requests-file'.
 192 Customize `spam-report-url-ping-function' to use this function."
 193   (let ((url (format "http://%s%s" host report))
 194         (file spam-report-requests-file))
 195     (gnus-make-directory (file-name-directory file))
 196     (gnus-message 9 "Writing URL `%s' to file `%s'" url file)
 197     (with-temp-buffer
 198       (insert url)
 199       (newline)
 200       (append-to-file (point-min) (point-max) file))))
 201
 202 ;;;###autoload
 203 (defun spam-report-agentize ()
 204   "Add spam-report support to the Agent.
 205 Spam reports will be queued with \\[spam-report-url-to-file] when
 206 the Agent is unplugged, and will be submitted in a batch when the
 207 Agent is plugged."
 208   (interactive)
 209   (add-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 210   (add-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 211
 212 ;;;###autoload
 213 (defun spam-report-deagentize ()
 214   "Remove spam-report support from the Agent.
 215 Spam reports will be queued with the method used when
 216 \\[spam-report-agentize] was run."
 217   (interactive)
 218   (remove-hook 'gnus-agent-plugged-hook 'spam-report-plug-agent)
 219   (remove-hook 'gnus-agent-unplugged-hook 'spam-report-unplug-agent))
 220
 221 (defun spam-report-plug-agent ()
 222   "Adjust spam report settings for plugged state.
 223 Process queued spam reports."
 224   ;; Process the queue, unless the user only wanted to report to a file
 225   ;; anyway.
 226   (unless (equal spam-report-url-ping-temp-agent-function
 227                  'spam-report-url-to-file)
 228     (spam-report-process-queue))
 229   ;; Set the reporting function, if we have memorized something otherwise,
 230   ;; stick with plain URL reporting.
 231   (setq spam-report-url-ping-function
 232         (or spam-report-url-ping-temp-agent-function
 233             'spam-report-url-ping-plain)))
 234
 235 (defun spam-report-unplug-agent ()
 236   "Restore spam report settings for unplugged state."
 237   ;; save the old value
 238   (setq spam-report-url-ping-temp-agent-function
 239         spam-report-url-ping-function)
 240   ;; store all reports to file
 241   (setq spam-report-url-ping-function
 242         'spam-report-url-to-file))
 243
 244 (provide 'spam-report)
 245
 246 ;;; arch-tag: f6683295-ec89-4ab5-8803-8cc842293022
 247 ;;; spam-report.el ends here.