code.delx.au - gnu-emacs/blob - lisp/gnus/gnus-srvr.el

   1 ;;; gnus-srvr.el --- virtual server support for Gnus
   2 ;; Copyright (C) 1995, 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003
   3 ;;        Free Software Foundation, Inc.
   4
   5 ;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
   6 ;; Keywords: news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Code:
  28
  29 (eval-when-compile (require 'cl))
  30
  31 (require 'gnus)
  32 (require 'gnus-spec)
  33 (require 'gnus-group)
  34 (require 'gnus-int)
  35 (require 'gnus-range)
  36
  37 (defcustom gnus-server-mode-hook nil
  38   "Hook run in `gnus-server-mode' buffers."
  39   :group 'gnus-server
  40   :type 'hook)
  41
  42 (defcustom gnus-server-exit-hook nil
  43   "Hook run when exiting the server buffer."
  44   :group 'gnus-server
  45   :type 'hook)
  46
  47 (defcustom gnus-server-line-format "     {%(%h:%w%)} %s%a\n"
  48   "Format of server lines.
  49 It works along the same lines as a normal formatting string,
  50 with some simple extensions.
  51
  52 The following specs are understood:
  53
  54 %h backend
  55 %n name
  56 %w address
  57 %s status
  58 %a agent covered
  59
  60 General format specifiers can also be used.
  61 See Info node `(gnus)Formatting Variables'."
  62   :link '(custom-manual "(gnus)Formatting Variables")
  63   :group 'gnus-server-visual
  64   :type 'string)
  65
  66 (defcustom gnus-server-mode-line-format "Gnus: %%b"
  67   "The format specification for the server mode line."
  68   :group 'gnus-server-visual
  69   :type 'string)
  70
  71 (defcustom gnus-server-browse-in-group-buffer nil
  72   "Whether server browsing should take place in the group buffer.
  73 If nil, a faster, but more primitive, buffer is used instead."
  74   :version "22.1"
  75   :group 'gnus-server-visual
  76   :type 'boolean)
  77
  78 ;;; Internal variables.
  79
  80 (defvar gnus-inserted-opened-servers nil)
  81
  82 (defvar gnus-server-line-format-alist
  83   `((?h gnus-tmp-how ?s)
  84     (?n gnus-tmp-name ?s)
  85     (?w gnus-tmp-where ?s)
  86     (?s gnus-tmp-status ?s)
  87     (?a gnus-tmp-agent ?s)))
  88
  89 (defvar gnus-server-mode-line-format-alist
  90   `((?S gnus-tmp-news-server ?s)
  91     (?M gnus-tmp-news-method ?s)
  92     (?u gnus-tmp-user-defined ?s)))
  93
  94 (defvar gnus-server-line-format-spec nil)
  95 (defvar gnus-server-mode-line-format-spec nil)
  96 (defvar gnus-server-killed-servers nil)
  97
  98 (defvar gnus-server-mode-map)
  99
 100 (defvar gnus-server-menu-hook nil
 101   "*Hook run after the creation of the server mode menu.")
 102
 103 (defun gnus-server-make-menu-bar ()
 104   (gnus-turn-off-edit-menu 'server)
 105   (unless (boundp 'gnus-server-server-menu)
 106     (easy-menu-define
 107      gnus-server-server-menu gnus-server-mode-map ""
 108      '("Server"
 109        ["Add..." gnus-server-add-server t]
 110        ["Browse" gnus-server-read-server t]
 111        ["Scan" gnus-server-scan-server t]
 112        ["List" gnus-server-list-servers t]
 113        ["Kill" gnus-server-kill-server t]
 114        ["Yank" gnus-server-yank-server t]
 115        ["Copy" gnus-server-copy-server t]
 116        ["Edit" gnus-server-edit-server t]
 117        ["Regenerate" gnus-server-regenerate-server t]
 118        ["Exit" gnus-server-exit t]))
 119
 120     (easy-menu-define
 121      gnus-server-connections-menu gnus-server-mode-map ""
 122      '("Connections"
 123        ["Open" gnus-server-open-server t]
 124        ["Close" gnus-server-close-server t]
 125        ["Offline" gnus-server-offline-server t]
 126        ["Deny" gnus-server-deny-server t]
 127        "---"
 128        ["Open All" gnus-server-open-all-servers t]
 129        ["Close All" gnus-server-close-all-servers t]
 130        ["Reset All" gnus-server-remove-denials t]))
 131
 132     (gnus-run-hooks 'gnus-server-menu-hook)))
 133
 134 (defvar gnus-server-mode-map nil)
 135 (put 'gnus-server-mode 'mode-class 'special)
 136
 137 (unless gnus-server-mode-map
 138   (setq gnus-server-mode-map (make-sparse-keymap))
 139   (suppress-keymap gnus-server-mode-map)
 140
 141   (gnus-define-keys gnus-server-mode-map
 142     " " gnus-server-read-server-in-server-buffer
 143     "\r" gnus-server-read-server
 144     gnus-mouse-2 gnus-server-pick-server
 145     "q" gnus-server-exit
 146     "l" gnus-server-list-servers
 147     "k" gnus-server-kill-server
 148     "y" gnus-server-yank-server
 149     "c" gnus-server-copy-server
 150     "a" gnus-server-add-server
 151     "e" gnus-server-edit-server
 152     "s" gnus-server-scan-server
 153
 154     "O" gnus-server-open-server
 155     "\M-o" gnus-server-open-all-servers
 156     "C" gnus-server-close-server
 157     "\M-c" gnus-server-close-all-servers
 158     "D" gnus-server-deny-server
 159     "L" gnus-server-offline-server
 160     "R" gnus-server-remove-denials
 161
 162     "n" next-line
 163     "p" previous-line
 164
 165     "g" gnus-server-regenerate-server
 166
 167     "\C-c\C-i" gnus-info-find-node
 168     "\C-c\C-b" gnus-bug))
 169
 170 (defface gnus-server-agent-face
 171   '((((class color) (background light)) (:foreground "PaleTurquoise" :bold t))
 172     (((class color) (background dark)) (:foreground "PaleTurquoise" :bold t))
 173     (t (:bold t)))
 174   "Face used for displaying AGENTIZED servers"
 175   :group 'gnus-server-visual)
 176
 177 (defface gnus-server-opened-face
 178   '((((class color) (background light)) (:foreground "Green3" :bold t))
 179     (((class color) (background dark)) (:foreground "Green1" :bold t))
 180     (t (:bold t)))
 181   "Face used for displaying OPENED servers"
 182   :group 'gnus-server-visual)
 183
 184 (defface gnus-server-closed-face
 185   '((((class color) (background light)) (:foreground "Steel Blue" :italic t))
 186     (((class color) (background dark))
 187      (:foreground "Light Steel Blue" :italic t))
 188     (t (:italic t)))
 189   "Face used for displaying CLOSED servers"
 190   :group 'gnus-server-visual)
 191
 192 (defface gnus-server-denied-face
 193   '((((class color) (background light)) (:foreground "Red" :bold t))
 194     (((class color) (background dark)) (:foreground "Pink" :bold t))
 195     (t (:inverse-video t :bold t)))
 196   "Face used for displaying DENIED servers"
 197   :group 'gnus-server-visual)
 198
 199 (defface gnus-server-offline-face
 200   '((((class color) (background light)) (:foreground "Orange" :bold t))
 201     (((class color) (background dark)) (:foreground "Yellow" :bold t))
 202     (t (:inverse-video t :bold t)))
 203   "Face used for displaying OFFLINE servers"
 204   :group 'gnus-server-visual)
 205
 206 (defcustom gnus-server-agent-face 'gnus-server-agent-face
 207   "Face name to use on AGENTIZED servers."
 208   :version "22.1"
 209   :group 'gnus-server-visual
 210   :type 'face)
 211
 212 (defcustom gnus-server-opened-face 'gnus-server-opened-face
 213   "Face name to use on OPENED servers."
 214   :version "22.1"
 215   :group 'gnus-server-visual
 216   :type 'face)
 217
 218 (defcustom gnus-server-closed-face 'gnus-server-closed-face
 219   "Face name to use on CLOSED servers."
 220   :version "22.1"
 221   :group 'gnus-server-visual
 222   :type 'face)
 223
 224 (defcustom gnus-server-denied-face 'gnus-server-denied-face
 225   "Face name to use on DENIED servers."
 226   :version "22.1"
 227   :group 'gnus-server-visual
 228   :type 'face)
 229
 230 (defcustom gnus-server-offline-face 'gnus-server-offline-face
 231   "Face name to use on OFFLINE servers."
 232   :version "22.1"
 233   :group 'gnus-server-visual
 234   :type 'face)
 235
 236 (defvar gnus-server-font-lock-keywords
 237   (list
 238    '("(\\(agent\\))" 1 gnus-server-agent-face)
 239    '("(\\(opened\\))" 1 gnus-server-opened-face)
 240    '("(\\(closed\\))" 1 gnus-server-closed-face)
 241    '("(\\(offline\\))" 1 gnus-server-offline-face)
 242    '("(\\(denied\\))" 1 gnus-server-denied-face)))
 243
 244 (defun gnus-server-mode ()
 245   "Major mode for listing and editing servers.
 246
 247 All normal editing commands are switched off.
 248 \\<gnus-server-mode-map>
 249 For more in-depth information on this mode, read the manual
 250 \(`\\[gnus-info-find-node]').
 251
 252 The following commands are available:
 253
 254 \\{gnus-server-mode-map}"
 255   (interactive)
 256   (when (gnus-visual-p 'server-menu 'menu)
 257     (gnus-server-make-menu-bar))
 258   (kill-all-local-variables)
 259   (gnus-simplify-mode-line)
 260   (setq major-mode 'gnus-server-mode)
 261   (setq mode-name "Server")
 262   (gnus-set-default-directory)
 263   (setq mode-line-process nil)
 264   (use-local-map gnus-server-mode-map)
 265   (buffer-disable-undo)
 266   (setq truncate-lines t)
 267   (setq buffer-read-only t)
 268   (if (featurep 'xemacs)
 269       (put 'gnus-server-mode 'font-lock-defaults '(gnus-server-font-lock-keywords t))
 270     (set (make-local-variable 'font-lock-defaults)
 271          '(gnus-server-font-lock-keywords t)))
 272   (gnus-run-hooks 'gnus-server-mode-hook))
 273
 274 (defun gnus-server-insert-server-line (gnus-tmp-name method)
 275   (let* ((gnus-tmp-how (car method))
 276          (gnus-tmp-where (nth 1 method))
 277          (elem (assoc method gnus-opened-servers))
 278          (gnus-tmp-status
 279           (cond
 280            ((eq (nth 1 elem) 'denied) "(denied)")
 281            ((eq (nth 1 elem) 'offline) "(offline)")
 282            (t
 283             (condition-case nil
 284                 (if (or (gnus-server-opened method)
 285                         (eq (nth 1 elem) 'ok))
 286                     "(opened)"
 287                   "(closed)")
 288               ((error) "(error)")))))
 289          (gnus-tmp-agent (if (and gnus-agent
 290                                   (gnus-agent-method-p method))
 291                              " (agent)"
 292                            "")))
 293     (beginning-of-line)
 294     (gnus-add-text-properties
 295      (point)
 296      (prog1 (1+ (point))
 297        ;; Insert the text.
 298        (eval gnus-server-line-format-spec))
 299      (list 'gnus-server (intern gnus-tmp-name)
 300            'gnus-named-server (intern (gnus-method-to-server method))))))
 301
 302 (defun gnus-enter-server-buffer ()
 303   "Set up the server buffer."
 304   (gnus-server-setup-buffer)
 305   (gnus-configure-windows 'server)
 306   (gnus-server-prepare))
 307
 308 (defun gnus-server-setup-buffer ()
 309   "Initialize the server buffer."
 310   (unless (get-buffer gnus-server-buffer)
 311     (save-excursion
 312       (set-buffer (gnus-get-buffer-create gnus-server-buffer))
 313       (gnus-server-mode)
 314       (when gnus-carpal
 315         (gnus-carpal-setup-buffer 'server)))))
 316
 317 (defun gnus-server-prepare ()
 318   (gnus-set-format 'server-mode)
 319   (gnus-set-format 'server t)
 320   (let ((alist gnus-server-alist)
 321         (buffer-read-only nil)
 322         (opened gnus-opened-servers)
 323         done server op-ser)
 324     (erase-buffer)
 325     (setq gnus-inserted-opened-servers nil)
 326     ;; First we do the real list of servers.
 327     (while alist
 328       (unless (member (cdar alist) done)
 329         (push (cdar alist) done)
 330         (setq server (pop alist))
 331         (when (and server (car server) (cdr server))
 332           (gnus-server-insert-server-line (car server) (cdr server))))
 333       (when (member (cdar alist) done)
 334         (pop alist)))
 335     ;; Then we insert the list of servers that have been opened in
 336     ;; this session.
 337     (while opened
 338       (when (and (not (member (caar opened) done))
 339                  ;; Just ignore ephemeral servers.
 340                  (not (member (caar opened) gnus-ephemeral-servers)))
 341         (push (caar opened) done)
 342         (gnus-server-insert-server-line
 343          (setq op-ser (format "%s:%s" (caaar opened) (nth 1 (caar opened))))
 344          (caar opened))
 345         (push (list op-ser (caar opened)) gnus-inserted-opened-servers))
 346       (setq opened (cdr opened))))
 347   (goto-char (point-min))
 348   (gnus-server-position-point))
 349
 350 (defun gnus-server-server-name ()
 351   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-server)))
 352     (and server (symbol-name server))))
 353
 354 (defun gnus-server-named-server ()
 355   "Returns a server name that matches one of the names returned by
 356 gnus-method-to-server."
 357   (let ((server (get-text-property (gnus-point-at-bol) 'gnus-named-server)))
 358     (and server (symbol-name server))))
 359
 360 (defalias 'gnus-server-position-point 'gnus-goto-colon)
 361
 362 (defconst gnus-server-edit-buffer "*Gnus edit server*")
 363
 364 (defun gnus-server-update-server (server)
 365   (save-excursion
 366     (set-buffer gnus-server-buffer)
 367     (let* ((buffer-read-only nil)
 368            (entry (assoc server gnus-server-alist))
 369            (oentry (assoc (gnus-server-to-method server)
 370                           gnus-opened-servers)))
 371       (when entry
 372         (gnus-dribble-enter
 373          (concat "(gnus-server-set-info \"" server "\" '"
 374                  (gnus-prin1-to-string (cdr entry)) ")\n")))
 375       (when (or entry oentry)
 376         ;; Buffer may be narrowed.
 377         (save-restriction
 378           (widen)
 379           (when (gnus-server-goto-server server)
 380             (gnus-delete-line))
 381           (if entry
 382               (gnus-server-insert-server-line (car entry) (cdr entry))
 383             (gnus-server-insert-server-line
 384              (format "%s:%s" (caar oentry) (nth 1 (car oentry)))
 385              (car oentry)))
 386           (gnus-server-position-point))))))
 387
 388 (defun gnus-server-set-info (server info)
 389   ;; Enter a select method into the virtual server alist.
 390   (when (and server info)
 391     (gnus-dribble-enter
 392      (concat "(gnus-server-set-info \"" server "\" '"
 393              (gnus-prin1-to-string info) ")"))
 394     (let* ((server (nth 1 info))
 395            (entry (assoc server gnus-server-alist))
 396            (cached (assoc server gnus-server-method-cache)))
 397       (if cached
 398           (setq gnus-server-method-cache
 399                 (delq cached gnus-server-method-cache)))
 400       (if entry (setcdr entry info)
 401         (setq gnus-server-alist
 402               (nconc gnus-server-alist (list (cons server info))))))))
 403
 404 ;;; Interactive server functions.
 405
 406 (defun gnus-server-kill-server (server)
 407   "Kill the server on the current line."
 408   (interactive (list (gnus-server-server-name)))
 409   (unless (gnus-server-goto-server server)
 410     (if server (error "No such server: %s" server)
 411       (error "No server on the current line")))
 412   (unless (assoc server gnus-server-alist)
 413     (error "Read-only server %s" server))
 414   (gnus-dribble-touch)
 415   (let ((buffer-read-only nil))
 416     (gnus-delete-line))
 417   (push (assoc server gnus-server-alist) gnus-server-killed-servers)
 418   (setq gnus-server-alist (delq (car gnus-server-killed-servers)
 419                                 gnus-server-alist))
 420   (let ((groups (gnus-groups-from-server server)))
 421     (when (and groups
 422                (gnus-yes-or-no-p
 423                 (format "Kill all %s groups from this server? "
 424                         (length groups))))
 425       (dolist (group groups)
 426         (setq gnus-newsrc-alist
 427               (delq (assoc group gnus-newsrc-alist)
 428                     gnus-newsrc-alist))
 429         (when gnus-group-change-level-function
 430           (funcall gnus-group-change-level-function
 431                    group gnus-level-killed 3)))))
 432   (gnus-server-position-point))
 433
 434 (defun gnus-server-yank-server ()
 435   "Yank the previously killed server."
 436   (interactive)
 437   (unless gnus-server-killed-servers
 438     (error "No killed servers to be yanked"))
 439   (let ((alist gnus-server-alist)
 440         (server (gnus-server-server-name))
 441         (killed (car gnus-server-killed-servers)))
 442     (if (not server)
 443         (setq gnus-server-alist (nconc gnus-server-alist (list killed)))
 444       (if (string= server (caar gnus-server-alist))
 445           (push killed gnus-server-alist)
 446         (while (and (cdr alist)
 447                     (not (string= server (caadr alist))))
 448           (setq alist (cdr alist)))
 449         (if alist
 450             (setcdr alist (cons killed (cdr alist)))
 451           (setq gnus-server-alist (list killed)))))
 452     (gnus-server-update-server (car killed))
 453     (setq gnus-server-killed-servers (cdr gnus-server-killed-servers))
 454     (gnus-server-position-point)))
 455
 456 (defun gnus-server-exit ()
 457   "Return to the group buffer."
 458   (interactive)
 459   (gnus-run-hooks 'gnus-server-exit-hook)
 460   (gnus-kill-buffer (current-buffer))
 461   (gnus-configure-windows 'group t))
 462
 463 (defun gnus-server-list-servers ()
 464   "List all available servers."
 465   (interactive)
 466   (let ((cur (gnus-server-server-name)))
 467     (gnus-server-prepare)
 468     (if cur (gnus-server-goto-server cur)
 469       (goto-char (point-max))
 470       (forward-line -1))
 471     (gnus-server-position-point)))
 472
 473 (defun gnus-server-set-status (method status)
 474   "Make METHOD have STATUS."
 475   (let ((entry (assoc method gnus-opened-servers)))
 476     (if entry
 477         (setcar (cdr entry) status)
 478       (push (list method status) gnus-opened-servers))))
 479
 480 (defun gnus-opened-servers-remove (method)
 481   "Remove METHOD from the list of opened servers."
 482   (setq gnus-opened-servers (delq (assoc method gnus-opened-servers)
 483                                   gnus-opened-servers)))
 484
 485 (defun gnus-server-open-server (server)
 486   "Force an open of SERVER."
 487   (interactive (list (gnus-server-server-name)))
 488   (let ((method (gnus-server-to-method server)))
 489     (unless method
 490       (error "No such server: %s" server))
 491     (gnus-server-set-status method 'ok)
 492     (prog1
 493         (or (gnus-open-server method)
 494             (progn (message "Couldn't open %s" server) nil))
 495       (gnus-server-update-server server)
 496       (gnus-server-position-point))))
 497
 498 (defun gnus-server-open-all-servers ()
 499   "Open all servers."
 500   (interactive)
 501   (let ((servers gnus-inserted-opened-servers))
 502     (while servers
 503       (gnus-server-open-server (car (pop servers))))))
 504
 505 (defun gnus-server-close-server (server)
 506   "Close SERVER."
 507   (interactive (list (gnus-server-server-name)))
 508   (let ((method (gnus-server-to-method server)))
 509     (unless method
 510       (error "No such server: %s" server))
 511     (gnus-server-set-status method 'closed)
 512     (prog1
 513         (gnus-close-server method)
 514       (gnus-server-update-server server)
 515       (gnus-server-position-point))))
 516
 517 (defun gnus-server-offline-server (server)
 518   "Set SERVER to offline."
 519   (interactive (list (gnus-server-server-name)))
 520   (let ((method (gnus-server-to-method server)))
 521     (unless method
 522       (error "No such server: %s" server))
 523     (prog1
 524         (gnus-close-server method)
 525       (gnus-server-set-status method 'offline)
 526       (gnus-server-update-server server)
 527       (gnus-server-position-point))))
 528
 529 (defun gnus-server-close-all-servers ()
 530   "Close all servers."
 531   (interactive)
 532   (dolist (server gnus-inserted-opened-servers)
 533     (gnus-server-close-server (car server))))
 534
 535 (defun gnus-server-deny-server (server)
 536   "Make sure SERVER will never be attempted opened."
 537   (interactive (list (gnus-server-server-name)))
 538   (let ((method (gnus-server-to-method server)))
 539     (unless method
 540       (error "No such server: %s" server))
 541     (gnus-server-set-status method 'denied))
 542   (gnus-server-update-server server)
 543   (gnus-server-position-point)
 544   t)
 545
 546 (defun gnus-server-remove-denials ()
 547   "Make all denied servers into closed servers."
 548   (interactive)
 549   (dolist (server gnus-opened-servers)
 550     (when (eq (nth 1 server) 'denied)
 551       (setcar (nthcdr 1 server) 'closed)))
 552   (gnus-server-list-servers))
 553
 554 (defun gnus-server-copy-server (from to)
 555   (interactive
 556    (list
 557     (or (gnus-server-server-name)
 558         (error "No server on the current line"))
 559     (read-string "Copy to: ")))
 560   (unless from
 561     (error "No server on current line"))
 562   (unless (and to (not (string= to "")))
 563     (error "No name to copy to"))
 564   (when (assoc to gnus-server-alist)
 565     (error "%s already exists" to))
 566   (unless (gnus-server-to-method from)
 567     (error "%s: no such server" from))
 568   (let ((to-entry (cons from (gnus-copy-sequence
 569                               (gnus-server-to-method from)))))
 570     (setcar to-entry to)
 571     (setcar (nthcdr 2 to-entry) to)
 572     (push to-entry gnus-server-killed-servers)
 573     (gnus-server-yank-server)))
 574
 575 (defun gnus-server-add-server (how where)
 576   (interactive
 577    (list (intern (completing-read "Server method: "
 578                                   gnus-valid-select-methods nil t))
 579          (read-string "Server name: ")))
 580   (when (assq where gnus-server-alist)
 581     (error "Server with that name already defined"))
 582   (push (list where how where) gnus-server-killed-servers)
 583   (gnus-server-yank-server))
 584
 585 (defun gnus-server-goto-server (server)
 586   "Jump to a server line."
 587   (interactive
 588    (list (completing-read "Goto server: " gnus-server-alist nil t)))
 589   (let ((to (text-property-any (point-min) (point-max)
 590                                'gnus-server (intern server))))
 591     (when to
 592       (goto-char to)
 593       (gnus-server-position-point))))
 594
 595 (defun gnus-server-edit-server (server)
 596   "Edit the server on the current line."
 597   (interactive (list (gnus-server-server-name)))
 598   (unless server
 599     (error "No server on current line"))
 600   (unless (assoc server gnus-server-alist)
 601     (error "This server can't be edited"))
 602   (let ((info (cdr (assoc server gnus-server-alist))))
 603     (gnus-close-server info)
 604     (gnus-edit-form
 605      info "Editing the server."
 606      `(lambda (form)
 607         (gnus-server-set-info ,server form)
 608         (gnus-server-list-servers)
 609         (gnus-server-position-point)))))
 610
 611 (defun gnus-server-scan-server (server)
 612   "Request a scan from the current server."
 613   (interactive (list (gnus-server-server-name)))
 614   (let ((method (gnus-server-to-method server)))
 615     (if (not (gnus-get-function method 'request-scan))
 616         (error "Server %s can't scan" (car method))
 617       (gnus-message 3 "Scanning %s..." server)
 618       (gnus-request-scan nil method)
 619       (gnus-message 3 "Scanning %s...done" server))))
 620
 621 (defun gnus-server-read-server-in-server-buffer (server)
 622   "Browse a server in server buffer."
 623   (interactive (list (gnus-server-server-name)))
 624   (let (gnus-server-browse-in-group-buffer)
 625     (gnus-server-read-server server)))
 626
 627 (defun gnus-server-read-server (server)
 628   "Browse a server."
 629   (interactive (list (gnus-server-server-name)))
 630   (let ((buf (current-buffer)))
 631     (prog1
 632         (gnus-browse-foreign-server server buf)
 633       (save-excursion
 634         (set-buffer buf)
 635         (gnus-server-update-server (gnus-server-server-name))
 636         (gnus-server-position-point)))))
 637
 638 (defun gnus-server-pick-server (e)
 639   (interactive "e")
 640   (mouse-set-point e)
 641   (gnus-server-read-server (gnus-server-server-name)))
 642
 643 \f
 644 ;;;
 645 ;;; Browse Server Mode
 646 ;;;
 647
 648 (defvar gnus-browse-menu-hook nil
 649   "*Hook run after the creation of the browse mode menu.")
 650
 651 (defvar gnus-browse-mode-hook nil)
 652 (defvar gnus-browse-mode-map nil)
 653 (put 'gnus-browse-mode 'mode-class 'special)
 654
 655 (unless gnus-browse-mode-map
 656   (setq gnus-browse-mode-map (make-keymap))
 657   (suppress-keymap gnus-browse-mode-map)
 658
 659   (gnus-define-keys
 660       gnus-browse-mode-map
 661     " " gnus-browse-read-group
 662     "=" gnus-browse-select-group
 663     "n" gnus-browse-next-group
 664     "p" gnus-browse-prev-group
 665     "\177" gnus-browse-prev-group
 666     [delete] gnus-browse-prev-group
 667     "N" gnus-browse-next-group
 668     "P" gnus-browse-prev-group
 669     "\M-n" gnus-browse-next-group
 670     "\M-p" gnus-browse-prev-group
 671     "\r" gnus-browse-select-group
 672     "u" gnus-browse-unsubscribe-current-group
 673     "l" gnus-browse-exit
 674     "L" gnus-browse-exit
 675     "q" gnus-browse-exit
 676     "Q" gnus-browse-exit
 677     "d" gnus-browse-describe-group
 678     "\C-c\C-c" gnus-browse-exit
 679     "?" gnus-browse-describe-briefly
 680
 681     "\C-c\C-i" gnus-info-find-node
 682     "\C-c\C-b" gnus-bug))
 683
 684 (defun gnus-browse-make-menu-bar ()
 685   (gnus-turn-off-edit-menu 'browse)
 686   (unless (boundp 'gnus-browse-menu)
 687     (easy-menu-define
 688      gnus-browse-menu gnus-browse-mode-map ""
 689      '("Browse"
 690        ["Subscribe" gnus-browse-unsubscribe-current-group t]
 691        ["Read" gnus-browse-read-group t]
 692        ["Select" gnus-browse-select-group t]
 693        ["Describe" gnus-browse-describe-group t]
 694        ["Next" gnus-browse-next-group t]
 695        ["Prev" gnus-browse-prev-group t]
 696        ["Exit" gnus-browse-exit t]))
 697     (gnus-run-hooks 'gnus-browse-menu-hook)))
 698
 699 (defvar gnus-browse-current-method nil)
 700 (defvar gnus-browse-return-buffer nil)
 701
 702 (defvar gnus-browse-buffer "*Gnus Browse Server*")
 703
 704 (defun gnus-browse-foreign-server (server &optional return-buffer)
 705   "Browse the server SERVER."
 706   (setq gnus-browse-current-method (gnus-server-to-method server))
 707   (setq gnus-browse-return-buffer return-buffer)
 708   (let* ((method gnus-browse-current-method)
 709          (orig-select-method gnus-select-method)
 710          (gnus-select-method method)
 711          groups group)
 712     (gnus-message 5 "Connecting to %s..." (nth 1 method))
 713     (cond
 714      ((not (gnus-check-server method))
 715       (gnus-message
 716        1 "Unable to contact server %s: %s" (nth 1 method)
 717        (gnus-status-message method))
 718       nil)
 719      ((not
 720        (prog2
 721            (gnus-message 6 "Reading active file...")
 722            (gnus-request-list method)
 723          (gnus-message 6 "Reading active file...done")))
 724       (gnus-message
 725        1 "Couldn't request list: %s" (gnus-status-message method))
 726       nil)
 727      (t
 728       (with-current-buffer nntp-server-buffer
 729         (let ((cur (current-buffer)))
 730           (goto-char (point-min))
 731           (unless (string= gnus-ignored-newsgroups "")
 732             (delete-matching-lines gnus-ignored-newsgroups))
 733           ;; We treat NNTP as a special case to avoid problems with
 734           ;; garbage group names like `"foo' that appear in some badly
 735           ;; managed active files. -jh.
 736           (if (eq (car method) 'nntp)
 737               (while (not (eobp))
 738                 (ignore-errors
 739                   (push (cons
 740                          (buffer-substring
 741                           (point)
 742                           (progn
 743                             (skip-chars-forward "^ \t")
 744                             (point)))
 745                          (let ((last (read cur)))
 746                            (cons (read cur) last)))
 747                         groups))
 748                 (forward-line))
 749             (while (not (eobp))
 750               (ignore-errors
 751                 (push (cons
 752                        (if (eq (char-after) ?\")
 753                            (read cur)
 754                          (let ((p (point)) (name ""))
 755                            (skip-chars-forward "^ \t\\\\")
 756                            (setq name (buffer-substring p (point)))
 757                            (while (eq (char-after) ?\\)
 758                              (setq p (1+ (point)))
 759                              (forward-char 2)
 760                              (skip-chars-forward "^ \t\\\\")
 761                              (setq name (concat name (buffer-substring
 762                                                       p (point)))))
 763                            name))
 764                        (let ((last (read cur)))
 765                          (cons (read cur) last)))
 766                       groups))
 767               (forward-line)))))
 768       (setq groups (sort groups
 769                          (lambda (l1 l2)
 770                            (string< (car l1) (car l2)))))
 771       (if gnus-server-browse-in-group-buffer
 772           (let* ((gnus-select-method orig-select-method)
 773                  (gnus-group-listed-groups
 774                   (mapcar (lambda (group)
 775                             (let ((name
 776                                    (gnus-group-prefixed-name
 777                                     (car group) method)))
 778                               (gnus-set-active name (cdr group))
 779                               name))
 780                           groups)))
 781             (gnus-configure-windows 'group)
 782             (funcall gnus-group-prepare-function
 783                      gnus-level-killed 'ignore 1 'ignore))
 784         (gnus-get-buffer-create gnus-browse-buffer)
 785         (when gnus-carpal
 786           (gnus-carpal-setup-buffer 'browse))
 787         (gnus-configure-windows 'browse)
 788         (buffer-disable-undo)
 789         (let ((buffer-read-only nil))
 790           (erase-buffer))
 791         (gnus-browse-mode)
 792         (setq mode-line-buffer-identification
 793               (list
 794                (format
 795                 "Gnus: %%b {%s:%s}" (car method) (cadr method))))
 796         (let ((buffer-read-only nil)
 797               name
 798               (prefix (let ((gnus-select-method orig-select-method))
 799                         (gnus-group-prefixed-name "" method))))
 800           (while (setq group (pop groups))
 801             (gnus-add-text-properties
 802              (point)
 803              (prog1 (1+ (point))
 804                (insert
 805                 (format "%c%7d: %s\n"
 806                         (let ((level (gnus-group-level
 807                                       (concat prefix (setq name (car group))))))
 808                               (cond
 809                                ((<= level gnus-level-subscribed) ? )
 810                                ((<= level gnus-level-unsubscribed) ?U)
 811                                ((= level gnus-level-zombie) ?Z)
 812                                (t ?K)))
 813                         (max 0 (- (1+ (cddr group)) (cadr group)))
 814                         (mm-decode-coding-string
 815                          name
 816                          (inline (gnus-group-name-charset method name))))))
 817              (list 'gnus-group name))))
 818         (switch-to-buffer (current-buffer)))
 819       (goto-char (point-min))
 820       (gnus-group-position-point)
 821       (gnus-message 5 "Connecting to %s...done" (nth 1 method))
 822       t))))
 823
 824 (defun gnus-browse-mode ()
 825   "Major mode for browsing a foreign server.
 826
 827 All normal editing commands are switched off.
 828
 829 \\<gnus-browse-mode-map>
 830 The only things you can do in this buffer is
 831
 832 1) `\\[gnus-browse-unsubscribe-current-group]' to subscribe to a group.
 833 The group will be inserted into the group buffer upon exit from this
 834 buffer.
 835
 836 2) `\\[gnus-browse-read-group]' to read a group ephemerally.
 837
 838 3) `\\[gnus-browse-exit]' to return to the group buffer."
 839   (interactive)
 840   (kill-all-local-variables)
 841   (when (gnus-visual-p 'browse-menu 'menu)
 842     (gnus-browse-make-menu-bar))
 843   (gnus-simplify-mode-line)
 844   (setq major-mode 'gnus-browse-mode)
 845   (setq mode-name "Browse Server")
 846   (setq mode-line-process nil)
 847   (use-local-map gnus-browse-mode-map)
 848   (buffer-disable-undo)
 849   (setq truncate-lines t)
 850   (gnus-set-default-directory)
 851   (setq buffer-read-only t)
 852   (gnus-run-hooks 'gnus-browse-mode-hook))
 853
 854 (defun gnus-browse-read-group (&optional no-article number)
 855   "Enter the group at the current line.
 856 If NUMBER, fetch this number of articles."
 857   (interactive "P")
 858   (let ((group (gnus-browse-group-name)))
 859     (if (or (not (gnus-get-info group))
 860             (gnus-ephemeral-group-p group))
 861         (unless (gnus-group-read-ephemeral-group
 862                  group gnus-browse-current-method nil
 863                  (cons (current-buffer) 'browse)
 864                  nil nil nil number)
 865           (error "Couldn't enter %s" group))
 866       (unless (gnus-group-read-group nil no-article group)
 867         (error "Couldn't enter %s" group)))))
 868
 869 (defun gnus-browse-select-group (&optional number)
 870   "Select the current group.
 871 If NUMBER, fetch this number of articles."
 872   (interactive "P")
 873   (gnus-browse-read-group 'no number))
 874
 875 (defun gnus-browse-next-group (n)
 876   "Go to the next group."
 877   (interactive "p")
 878   (prog1
 879       (forward-line n)
 880     (gnus-group-position-point)))
 881
 882 (defun gnus-browse-prev-group (n)
 883   "Go to the next group."
 884   (interactive "p")
 885   (gnus-browse-next-group (- n)))
 886
 887 (defun gnus-browse-unsubscribe-current-group (arg)
 888   "(Un)subscribe to the next ARG groups."
 889   (interactive "p")
 890   (when (eobp)
 891     (error "No group at current line"))
 892   (let ((ward (if (< arg 0) -1 1))
 893         (arg (abs arg)))
 894     (while (and (> arg 0)
 895                 (not (eobp))
 896                 (gnus-browse-unsubscribe-group)
 897                 (zerop (gnus-browse-next-group ward)))
 898       (decf arg))
 899     (gnus-group-position-point)
 900     (when (/= 0 arg)
 901       (gnus-message 7 "No more newsgroups"))
 902     arg))
 903
 904 (defun gnus-browse-group-name ()
 905   (save-excursion
 906     (beginning-of-line)
 907     (let ((name (get-text-property (point) 'gnus-group)))
 908       (when (re-search-forward ": \\(.*\\)$" (gnus-point-at-eol) t)
 909         (concat (gnus-method-to-server-name gnus-browse-current-method) ":"
 910                 (or name
 911                     (match-string-no-properties 1)))))))
 912
 913 (defun gnus-browse-describe-group (group)
 914   "Describe the current group."
 915   (interactive (list (gnus-browse-group-name)))
 916   (gnus-group-describe-group nil group))
 917
 918 (defun gnus-browse-unsubscribe-group ()
 919   "Toggle subscription of the current group in the browse buffer."
 920   (let ((sub nil)
 921         (buffer-read-only nil)
 922         group)
 923     (save-excursion
 924       (beginning-of-line)
 925       ;; If this group it killed, then we want to subscribe it.
 926       (unless (eq (char-after) ? )
 927         (setq sub t))
 928       (setq group (gnus-browse-group-name))
 929       (when (gnus-server-equal gnus-browse-current-method "native")
 930         (setq group (gnus-group-real-name group)))
 931       (if sub
 932           (progn
 933             ;; Make sure the group has been properly removed before we
 934             ;; subscribe to it.
 935             (gnus-kill-ephemeral-group group)
 936             (gnus-group-change-level
 937              (list t group gnus-level-default-subscribed
 938                    nil nil (if (gnus-server-equal
 939                                 gnus-browse-current-method "native")
 940                                nil
 941                              (gnus-method-simplify
 942                               gnus-browse-current-method)))
 943              gnus-level-default-subscribed (gnus-group-level group)
 944              (and (car (nth 1 gnus-newsrc-alist))
 945                   (gnus-gethash (car (nth 1 gnus-newsrc-alist))
 946                                 gnus-newsrc-hashtb))
 947              t)
 948             (delete-char 1)
 949             (insert ? ))
 950         (gnus-group-change-level
 951          group gnus-level-unsubscribed gnus-level-default-subscribed)
 952         (delete-char 1)
 953         (insert ?U)))
 954     t))
 955
 956 (defun gnus-browse-exit ()
 957   "Quit browsing and return to the group buffer."
 958   (interactive)
 959   (when (eq major-mode 'gnus-browse-mode)
 960     (gnus-kill-buffer (current-buffer)))
 961   ;; Insert the newly subscribed groups in the group buffer.
 962   (save-excursion
 963     (set-buffer gnus-group-buffer)
 964     (gnus-group-list-groups nil))
 965   (if gnus-browse-return-buffer
 966       (gnus-configure-windows 'server 'force)
 967     (gnus-configure-windows 'group 'force)))
 968
 969 (defun gnus-browse-describe-briefly ()
 970   "Give a one line description of the group mode commands."
 971   (interactive)
 972   (gnus-message 6
 973                 (substitute-command-keys "\\<gnus-browse-mode-map>\\[gnus-group-next-group]:Forward  \\[gnus-group-prev-group]:Backward  \\[gnus-browse-exit]:Exit  \\[gnus-info-find-node]:Run Info  \\[gnus-browse-describe-briefly]:This help")))
 974
 975 (defun gnus-server-regenerate-server ()
 976   "Issue a command to the server to regenerate all its data structures."
 977   (interactive)
 978   (let ((server (gnus-server-server-name)))
 979     (unless server
 980       (error "No server on the current line"))
 981     (condition-case ()
 982         (gnus-get-function (gnus-server-to-method server)
 983                            'request-regenerate)
 984       (error
 985         (error "This backend doesn't support regeneration")))
 986     (gnus-message 5 "Requesting regeneration of %s..." server)
 987     (unless (gnus-open-server server)
 988       (error "Couldn't open server"))
 989     (if (gnus-request-regenerate server)
 990         (gnus-message 5 "Requesting regeneration of %s...done" server)
 991       (gnus-message 5 "Couldn't regenerate %s" server))))
 992
 993 (provide 'gnus-srvr)
 994
 995 ;;; arch-tag: c0117f64-27ca-475d-9406-8da6854c7a25
 996 ;;; gnus-srvr.el ends here