code.delx.au - gnu-emacs/blob - lisp/cedet/semantic/symref/grep.el

   1 ;;; semantic/symref/grep.el --- Symref implementation using find/grep
   2
   3 ;; Copyright (C) 2008-2016 Free Software Foundation, Inc.
   4
   5 ;; Author: Eric M. Ludlam <eric@siege-engine.com>
   6
   7 ;; This file is part of GNU Emacs.
   8
   9 ;; GNU Emacs is free software: you can redistribute it and/or modify
  10 ;; it under the terms of the GNU General Public License as published by
  11 ;; the Free Software Foundation, either version 3 of the License, or
  12 ;; (at your option) any later version.
  13
  14 ;; GNU Emacs is distributed in the hope that it will be useful,
  15 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 ;; GNU General Public License for more details.
  18
  19 ;; You should have received a copy of the GNU General Public License
  20 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  21
  22 ;;; Commentary:
  23 ;;
  24 ;; Implement the symref tool API using the external tools find/grep.
  25 ;;
  26 ;; The symref GREP tool uses grep in a project to find symbol references.
  27 ;; This is a lowest-common-denominator tool with sucky performance that
  28 ;; can be used in small projects to find symbol references.
  29
  30 (require 'semantic/symref)
  31 (require 'grep)
  32
  33 ;;; Code:
  34
  35 ;;; GREP
  36 ;;;###autoload
  37 (defclass semantic-symref-tool-grep (semantic-symref-tool-baseclass)
  38   (
  39    )
  40   "A symref tool implementation using grep.
  41 This tool uses EDE to find he root of the project, then executes
  42 find-grep in the project.  The output is parsed for hits
  43 and those hits returned.")
  44
  45 (defvar semantic-symref-filepattern-alist
  46   '((c-mode "*.[ch]")
  47     (c++-mode "*.[chCH]" "*.[ch]pp" "*.cc" "*.hh")
  48     (html-mode "*.s?html" "*.php")
  49     (ruby-mode "*.r[bu]" "*.rake" "*.gemspec" "*.erb" "*.haml"
  50                "Rakefile" "Thorfile" "Capfile" "Guardfile" "Vagrantfile")
  51     )
  52   "List of major modes and file extension pattern.
  53 See find -name man page for format.")
  54
  55 (defun semantic-symref-derive-find-filepatterns (&optional mode)
  56   ;; FIXME: This should be moved to grep.el, where it could be used
  57   ;; for "C-u M-x grep" as well.
  58   "Derive a list of file patterns for the current buffer.
  59 Looks first in `semantic-symref-filepattern-alist'.  If it is not
  60 there, it then looks in `auto-mode-alist', and attempts to derive something
  61 from that.
  62 Optional argument MODE specifies the `major-mode' to test."
  63   ;; First, try the filepattern alist.
  64   (let* ((mode (or mode major-mode))
  65          (pat (cdr (assoc mode semantic-symref-filepattern-alist))))
  66     (when (not pat)
  67       ;; No hit, try auto-mode-alist.
  68       (dolist (X auto-mode-alist)
  69         (when (and (eq (cdr X) mode)
  70                    ;; Only take in simple patterns, so try to convert this one.
  71                    (string-match "\\\\\\.\\([^\\'>]+\\)\\\\'" (car X)))
  72           (push (concat "*." (match-string 1 (car X))) pat))))
  73     ;; Convert the list into some find-flags.
  74     (if (null pat)
  75         (error "Customize `semantic-symref-filepattern-alist' for %S"
  76                major-mode)
  77       (let ((args `("-name" ,(car pat))))
  78         (if (null (cdr args))
  79             args
  80           `("(" ,@args
  81             ,@(apply #'nconc (mapcar (lambda (s) `("-o" "-name" ,s)) pat))
  82             ")"))))))
  83
  84 (defvar grepflags)
  85 (defvar greppattern)
  86
  87 (defvar semantic-symref-grep-expand-keywords
  88   (condition-case nil
  89       (let* ((kw (copy-alist grep-expand-keywords))
  90              (C (assoc "<C>" kw))
  91              (R (assoc "<R>" kw)))
  92         (setcdr C 'grepflags)
  93         (setcdr R 'greppattern)
  94         kw)
  95     (error nil))
  96   "Grep expand keywords used when expanding templates for symref.")
  97
  98 (defun semantic-symref-grep-use-template (rootdir filepattern flags pattern)
  99   "Use the grep template expand feature to create a grep command.
 100 ROOTDIR is the root location to run the `find' from.
 101 FILEPATTERN is a string representing find flags for searching file patterns.
 102 GREPFLAGS are flags passed to grep, such as -n or -l.
 103 GREPPATTERN is the pattern used by grep."
 104   ;; We have grep-compute-defaults.  Let's use it.
 105   (grep-compute-defaults)
 106   (let* ((grepflags flags)
 107          (greppattern pattern)
 108          (grep-expand-keywords semantic-symref-grep-expand-keywords)
 109          (cmd (grep-expand-template
 110                (if (memq system-type '(windows-nt ms-dos))
 111                    ;; grep-find uses '--color=always' on MS-Windows
 112                    ;; because it wants the colorized output, to show
 113                    ;; it to the user.  By contrast, here we don't show
 114                    ;; the output, and the SGR escapes get in the way
 115                    ;; of parsing the output.
 116                    (replace-regexp-in-string "--color=always" ""
 117                                              grep-find-template t t)
 118                  grep-find-template)
 119                greppattern
 120                filepattern
 121                rootdir)))
 122     ;; http://debbugs.gnu.org/20719
 123     (when (string-match "find \\(\\.\\)" cmd)
 124       (setq cmd (replace-match rootdir t t cmd 1)))
 125     ;;(message "New command: %s" cmd)
 126     cmd))
 127
 128 (defcustom semantic-symref-grep-shell shell-file-name
 129   "The shell command to use for executing find/grep.
 130 This shell should support pipe redirect syntax."
 131   :group 'semantic
 132   :type 'string)
 133
 134 (cl-defmethod semantic-symref-perform-search ((tool semantic-symref-tool-grep))
 135   "Perform a search with Grep."
 136   ;; Grep doesn't support some types of searches.
 137   (let ((st (oref tool :searchtype)))
 138     (when (not (memq st '(symbol regexp)))
 139       (error "Symref impl GREP does not support searchtype of %s" st))
 140     )
 141   ;; Find the root of the project, and do a find-grep...
 142   (let* (;; Find the file patterns to use.
 143          (rootdir (semantic-symref-calculate-rootdir))
 144          (filepatterns (semantic-symref-derive-find-filepatterns))
 145          (filepattern (mapconcat #'shell-quote-argument filepatterns " "))
 146          ;; Grep based flags.
 147          (grepflags (cond ((eq (oref tool :resulttype) 'file)
 148                            "-l ")
 149                           ((eq (oref tool :searchtype) 'regexp)
 150                            "-nE ")
 151                           (t "-n ")))
 152          (greppat (shell-quote-argument
 153                    (cond ((eq (oref tool :searchtype) 'regexp)
 154                           (oref tool searchfor))
 155                          (t
 156                           ;; Can't use the word boundaries: Grep
 157                           ;; doesn't always agrees with the language
 158                           ;; syntax on those.
 159                           (format "\\(^\\|\\W\\)%s\\(\\W\\|$\\)"
 160                                   (oref tool searchfor))))))
 161          ;; Misc
 162          (b (get-buffer-create "*Semantic SymRef*"))
 163          (ans nil)
 164          )
 165
 166     (with-current-buffer b
 167       (erase-buffer)
 168       (setq default-directory rootdir)
 169
 170       (if (not (fboundp 'grep-compute-defaults))
 171
 172           ;; find . -type f -print0 | xargs -0 -e grep -nH -e
 173           ;; Note : I removed -e as it is not posix, nor necessary it seems.
 174
 175           (let ((cmd (concat "find " default-directory " -type f " filepattern " -print0 "
 176                              "| xargs -0 grep -H " grepflags "-e " greppat)))
 177             ;;(message "Old command: %s" cmd)
 178             (call-process semantic-symref-grep-shell nil b nil
 179                           shell-command-switch cmd)
 180             )
 181         (let ((cmd (semantic-symref-grep-use-template rootdir filepattern grepflags greppat)))
 182           (call-process semantic-symref-grep-shell nil b nil
 183                         shell-command-switch cmd))
 184         ))
 185     (setq ans (semantic-symref-parse-tool-output tool b))
 186     ;; Return the answer
 187     ans))
 188
 189 (cl-defmethod semantic-symref-parse-tool-output-one-line ((tool semantic-symref-tool-grep))
 190   "Parse one line of grep output, and return it as a match list.
 191 Moves cursor to end of the match."
 192   (cond ((eq (oref tool :resulttype) 'file)
 193          ;; Search for files
 194          (when (re-search-forward "^\\([^\n]+\\)$" nil t)
 195            (match-string 1)))
 196         (t
 197          (when (re-search-forward  "^\\(\\(?:[a-zA-Z]:\\)?[^:\n]+\\):\\([0-9]+\\):" nil t)
 198            (cons (string-to-number (match-string 2))
 199                  (match-string 1))
 200            ))))
 201
 202 (provide 'semantic/symref/grep)
 203
 204 ;; Local variables:
 205 ;; generated-autoload-file: "../loaddefs.el"
 206 ;; generated-autoload-load-name: "semantic/symref/grep"
 207 ;; End:
 208
 209 ;;; semantic/symref/grep.el ends here