code.delx.au - gnu-emacs/blob - lisp/faces.el

   1 ;;; faces.el --- Lisp faces
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  21 ;; Boston, MA 02111-1307, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Code:
  26
  27 (eval-when-compile
  28   (require 'cl))
  29
  30 (require 'cus-face)
  31
  32 \f
  33 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  34 ;;; Font selection.
  35 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  36
  37 (defgroup font-selection nil
  38   "Influencing face font selection."
  39   :group 'faces)
  40
  41
  42 (defcustom face-font-selection-order
  43   '(:width :height :weight :slant)
  44   "*A list specifying how face font selection chooses fonts.
  45 Each of the four symbols `:width', `:height', `:weight', and `:slant'
  46 must appear once in the list, and the list must not contain any other
  47 elements.  Font selection tries to find a best matching font for
  48 those face attributes first that appear first in the list.  For
  49 example, if `:slant' appears before `:height', font selection first
  50 tries to find a font with a suitable slant, even if this results in
  51 a font height that isn't optimal."
  52   :tag "Font selection order."
  53   :type '(list symbol symbol symbol symbol)
  54   :group 'font-selection
  55   :set #'(lambda (symbol value)
  56            (set-default symbol value)
  57            (internal-set-font-selection-order value)))
  58
  59 ;; This is defined originally in {w32,x}faces.c.
  60 (defcustom face-font-family-alternatives
  61   '(("courier" "fixed")
  62     ("helv" "helvetica" "arial" "fixed"))
  63   "*Alist of alternative font family names.
  64 Each element has the the form (FAMILY ALTERNATIVE1 ALTERNATIVE2 ...).
  65 If fonts of family FAMILY can't be loaded, try ALTERNATIVE1, then
  66 ALTERNATIVE2 etc."
  67   :tag "Alternative font families to try."
  68   :type '(repeat (repeat string))
  69   :group 'font-selection
  70   :set #'(lambda (symbol value)
  71            (set-default symbol value)
  72            (internal-set-alternative-font-family-alist value)))
  73
  74
  75 \f
  76 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  77 ;;; Creation, copying.
  78 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  79
  80
  81 (defun face-list ()
  82   "Return a list of all defined face names."
  83   (mapcar #'car face-new-frame-defaults))
  84
  85
  86 ;;; ### If not frame-local initialize by what X resources?
  87
  88 (defun make-face (face &optional no-init-from-resources)
  89   "Define a new face with name FACE, a symbol.
  90 NO-INIT-FROM-RESOURCES non-nil means don't initialize frame-local
  91 variants of FACE from X resources.  (X resources recognized are found
  92 in the global variable `face-x-resources'.)  If FACE is already known
  93 as a face, leave it unmodified.  Value is FACE."
  94   (interactive "SMake face: ")
  95   (unless (facep face)
  96     ;; Make frame-local faces (this also makes the global one).
  97     (dolist (frame (frame-list))
  98       (internal-make-lisp-face face frame))
  99     ;; Add the face to the face menu.
 100     (when (fboundp 'facemenu-add-new-face)
 101       (facemenu-add-new-face face))
 102     ;; Define frame-local faces for all frames from X resources.
 103     (unless no-init-from-resources
 104       (make-face-x-resource-internal face)))
 105   face)
 106
 107
 108 (defun make-empty-face (face)
 109   "Define a new, empty face with name FACE.
 110 If the face already exists, it is left unmodified.  Value is FACE."
 111   (interactive "SMake empty face: ")
 112   (make-face face 'no-init-from-resources))
 113
 114
 115 (defun copy-face (old-face new-face &optional frame new-frame)
 116   "Define a face just like OLD-FACE, with name NEW-FACE.
 117
 118 If NEW-FACE already exists as a face, it is modified to be like
 119 OLD-FACE.  If it doesn't already exist, it is created.
 120
 121 If the optional argument FRAME is given as a frame,  NEW-FACE is
 122 changed on FRAME only.
 123 If FRAME is t, the frame-independent default specification for OLD-FACE
 124 is copied to NEW-FACE.
 125 If FRAME is nil, copying is done for the frame-independent defaults
 126 and for each existing frame.
 127
 128 If the optional fourth argument NEW-FRAME is given,
 129 copy the information from face OLD-FACE on frame FRAME
 130 to NEW-FACE on frame NEW-FRAME."
 131   (let ((inhibit-quit t))
 132     (if (null frame)
 133         (progn
 134           (dolist (frame (frame-list))
 135             (copy-face old-face new-face frame))
 136           (copy-face old-face new-face t))
 137       (internal-copy-lisp-face old-face new-face frame new-frame))
 138     new-face))
 139
 140
 141 \f
 142 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 143 ;;; Obsolete functions
 144 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 145
 146 ;; The functions in this section are defined because Lisp packages use
 147 ;; them, despite the prefix `internal-' suggesting that they are
 148 ;; private to the face implementation.
 149
 150 (defun internal-find-face (name &optional frame)
 151   "Retrieve the face named NAME.
 152 Return nil if there is no such face.
 153 If the optional argument FRAME is given, this gets the face NAME for
 154 that frame; otherwise, it uses the selected frame.
 155 If FRAME is the symbol t, then the global, non-frame face is returned.
 156 If NAME is already a face, it is simply returned.
 157
 158 This function is defined for compatibility with Emacs 20.2.  It
 159 should not be used anymore."
 160   (facep name))
 161 (make-obsolete 'internal-find-face 'facep "21.1")
 162
 163
 164 (defun internal-get-face (name &optional frame)
 165   "Retrieve the face named NAME; error if there is none.
 166 If the optional argument FRAME is given, this gets the face NAME for
 167 that frame; otherwise, it uses the selected frame.
 168 If FRAME is the symbol t, then the global, non-frame face is returned.
 169 If NAME is already a face, it is simply returned.
 170
 171 This function is defined for compatibility with Emacs 20.2.  It
 172 should not be used anymore."
 173   (or (internal-find-face name frame)
 174       (check-face name)))
 175 (make-obsolete 'internal-get-face "See `facep' and `check-face'." "21.1")
 176
 177 \f
 178 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 179 ;;; Predicates, type checks.
 180 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 181
 182 (defun facep (face)
 183   "Return non-nil if FACE is a face name."
 184   (internal-lisp-face-p face))
 185
 186
 187 (defun check-face (face)
 188   "Signal an error if FACE doesn't name a face.
 189 Value is FACE."
 190   (unless (facep face)
 191     (error "Not a face: %s" face))
 192   face)
 193
 194
 195 ;; The ID returned is not to be confused with the internally used IDs
 196 ;; of realized faces.  The ID assigned to Lisp faces is used to
 197 ;; support faces in display table entries.
 198
 199 (defun face-id (face &optional frame)
 200   "Return the interNal ID of face with name FACE.
 201 If optional argument FRAME is nil or omitted, use the selected frame."
 202   (check-face face)
 203   (get face 'face))
 204
 205
 206 (defun face-equal (face1 face2 &optional frame)
 207   "Non-nil if faces FACE1 and FACE2 are equal.
 208 Faces are considered equal if all their attributes are equal.
 209 If the optional argument FRAME is given, report on face FACE in that frame.
 210 If FRAME is t, report on the defaults for face FACE (for new frames).
 211 If FRAME is omitted or nil, use the selected frame."
 212   (internal-lisp-face-equal-p face1 face2 frame))
 213
 214
 215 (defun face-differs-from-default-p (face &optional frame)
 216   "Non-nil if FACE displays differently from the default face.
 217 If the optional argument FRAME is given, report on face FACE in that frame.
 218 If FRAME is t, report on the defaults for face FACE (for new frames).
 219 If FRAME is omitted or nil, use the selected frame.
 220 A face is considered to be ``the same'' as the default face if it is
 221 actually specified in the same way (equal attributes) or if it is
 222 fully-unspecified, and thus inherits the attributes of any face it
 223 is displayed on top of."
 224   (cond ((eq frame t) (setq frame nil))
 225         ((null frame) (setq frame (selected-frame))))
 226   (let* ((v1 (internal-lisp-face-p face frame))
 227          (n (if v1 (length v1) 0))
 228          (v2 (internal-lisp-face-p 'default frame))
 229          (i 1))
 230     (unless v1
 231       (error "Not a face: %S" face))
 232     (while (and (< i n)
 233                 (or (eq 'unspecified (aref v1 i))
 234                     (equal (aref v1 i) (aref v2 i))))
 235       (setq i (1+ i)))
 236     (< i n)))
 237
 238
 239 (defun face-nontrivial-p (face &optional frame)
 240   "True if face FACE has some non-nil attribute.
 241 If the optional argument FRAME is given, report on face FACE in that frame.
 242 If FRAME is t, report on the defaults for face FACE (for new frames).
 243 If FRAME is omitted or nil, use the selected frame."
 244   (not (internal-lisp-face-empty-p face frame)))
 245
 246
 247 \f
 248 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 249 ;;; Setting face attributes from X resources.
 250 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 251
 252 (defcustom face-x-resources
 253   '((:family (".attributeFamily" . "Face.AttributeFamily"))
 254     (:width (".attributeWidth" . "Face.AttributeWidth"))
 255     (:height (".attributeHeight" . "Face.AttributeHeight"))
 256     (:weight (".attributeWeight" . "Face.AttributeWeight"))
 257     (:slant (".attributeSlant" . "Face.AttributeSlant"))
 258     (:foreground (".attributeForeground" . "Face.AttributeForeground"))
 259     (:background (".attributeBackground" . "Face.AttributeBackground"))
 260     (:overline (".attributeOverline" . "Face.AttributeOverline"))
 261     (:strike-through (".attributeStrikeThrough" . "Face.AttributeStrikeThrough"))
 262     (:box (".attributeBox" . "Face.AttributeBox"))
 263     (:underline (".attributeUnderline" . "Face.AttributeUnderline"))
 264     (:inverse-video (".attributeInverse" . "Face.AttributeInverse"))
 265     (:stipple
 266      (".attributeStipple" . "Face.AttributeStipple")
 267      (".attributeBackgroundPixmap" . "Face.AttributeBackgroundPixmap"))
 268     (:bold (".attributeBold" . "Face.AttributeBold"))
 269     (:italic (".attributeItalic" . "Face.AttributeItalic"))
 270     (:font (".attributeFont" . "Face.AttributeFont"))
 271     (:inherit (".attributeInherit" . "Face.AttributeInherit")))
 272   "*List of X resources and classes for face attributes.
 273 Each element has the form (ATTRIBUTE ENTRY1 ENTRY2...) where ATTRIBUTE is
 274 the name of a face attribute, and each ENTRY is a cons of the form
 275 (RESOURCE . CLASS) with RESOURCE being the resource and CLASS being the
 276 X resource class for the attribute."
 277   :type 'sexp
 278   :group 'faces)
 279
 280
 281 (defun set-face-attribute-from-resource (face attribute resource class frame)
 282   "Set FACE's ATTRIBUTE from X resource RESOURCE, class CLASS on FRAME.
 283 Value is the attribute value specified by the resource, or nil
 284 if not present.  This function displays a message if the resource
 285 specifies an invalid attribute."
 286   (let* ((face-name (face-name face))
 287          (value (internal-face-x-get-resource (concat face-name resource)
 288                                               class frame)))
 289     (when value
 290       (condition-case ()
 291           (internal-set-lisp-face-attribute-from-resource
 292            face attribute (downcase value) frame)
 293         (error
 294          (message "Face %s, frame %s: invalid attribute %s %s from X resource"
 295                   face-name frame attribute value))))
 296     value))
 297
 298
 299 (defun set-face-attributes-from-resources (face frame)
 300   "Set attributes of FACE from X resources for FRAME."
 301   (when (memq (framep frame) '(x w32))
 302     (dolist (definition face-x-resources)
 303       (let ((attribute (car definition)))
 304         (dolist (entry (cdr definition))
 305           (set-face-attribute-from-resource face attribute (car entry)
 306                                             (cdr entry) frame))))))
 307
 308
 309 (defun make-face-x-resource-internal (face &optional frame)
 310   "Fill frame-local FACE on FRAME from X resources.
 311 FRAME nil or not specified means do it for all frames."
 312   (if (null frame)
 313       (dolist (frame (frame-list))
 314         (set-face-attributes-from-resources face frame))
 315     (set-face-attributes-from-resources face frame)))
 316
 317
 318 \f
 319 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 320 ;;; Retrieving face attributes.
 321 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 322
 323 (defun face-name (face)
 324   "Return the name of face FACE."
 325   (symbol-name (check-face face)))
 326
 327
 328 (defun face-attribute (face attribute &optional frame)
 329   "Return the value of FACE's ATTRIBUTE on FRAME.
 330 If the optional argument FRAME is given, report on face FACE in that frame.
 331 If FRAME is t, report on the defaults for face FACE (for new frames).
 332 If FRAME is omitted or nil, use the selected frame."
 333   (internal-get-lisp-face-attribute face attribute frame))
 334
 335
 336 (defun face-foreground (face &optional frame)
 337   "Return the foreground color name of FACE, or nil if unspecified.
 338 If the optional argument FRAME is given, report on face FACE in that frame.
 339 If FRAME is t, report on the defaults for face FACE (for new frames).
 340 If FRAME is omitted or nil, use the selected frame."
 341   (internal-get-lisp-face-attribute face :foreground frame))
 342
 343
 344 (defun face-background (face &optional frame)
 345   "Return the background color name of FACE, or nil if unspecified.
 346 If the optional argument FRAME is given, report on face FACE in that frame.
 347 If FRAME is t, report on the defaults for face FACE (for new frames).
 348 If FRAME is omitted or nil, use the selected frame."
 349   (internal-get-lisp-face-attribute face :background frame))
 350
 351
 352 (defun face-stipple (face &optional frame)
 353  "Return the stipple pixmap name of FACE, or nil if unspecified.
 354 If the optional argument FRAME is given, report on face FACE in that frame.
 355 If FRAME is t, report on the defaults for face FACE (for new frames).
 356 If FRAME is omitted or nil, use the selected frame."
 357   (internal-get-lisp-face-attribute face :stipple frame))
 358
 359
 360 (defalias 'face-background-pixmap 'face-stipple)
 361
 362
 363 (defun face-underline-p (face &optional frame)
 364  "Return non-nil if FACE is underlined.
 365 If the optional argument FRAME is given, report on face FACE in that frame.
 366 If FRAME is t, report on the defaults for face FACE (for new frames).
 367 If FRAME is omitted or nil, use the selected frame."
 368  (eq (face-attribute face :underline frame) t))
 369
 370
 371 (defun face-inverse-video-p (face &optional frame)
 372  "Return non-nil if FACE is in inverse video on FRAME.
 373 If the optional argument FRAME is given, report on face FACE in that frame.
 374 If FRAME is t, report on the defaults for face FACE (for new frames).
 375 If FRAME is omitted or nil, use the selected frame."
 376  (eq (face-attribute face :inverse-video frame) t))
 377
 378
 379 (defun face-bold-p (face &optional frame)
 380   "Return non-nil if the font of FACE is bold on FRAME.
 381 If the optional argument FRAME is given, report on face FACE in that frame.
 382 If FRAME is t, report on the defaults for face FACE (for new frames).
 383 If FRAME is omitted or nil, use the selected frame.
 384 Use `face-attribute' for finer control."
 385   (let ((bold (face-attribute face :weight frame)))
 386     (memq bold '(semi-bold bold extra-bold ultra-bold))))
 387
 388
 389 (defun face-italic-p (face &optional frame)
 390   "Return non-nil if the font of FACE is italic on FRAME.
 391 If the optional argument FRAME is given, report on face FACE in that frame.
 392 If FRAME is t, report on the defaults for face FACE (for new frames).
 393 If FRAME is omitted or nil, use the selected frame.
 394 Use `face-attribute' for finer control."
 395   (let ((italic (face-attribute face :slant frame)))
 396     (memq italic '(italic oblique))))
 397
 398
 399
 400
 401 \f
 402 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 403 ;;; Face documentation.
 404 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 405
 406 (defun face-documentation (face)
 407   "Get the documentation string for FACE."
 408   (get face 'face-documentation))
 409
 410
 411 (defun set-face-documentation (face string)
 412   "Set the documentation string for FACE to STRING."
 413   ;; Perhaps the text should go in DOC.
 414   (put face 'face-documentation (purecopy string)))
 415
 416
 417 (defalias 'face-doc-string 'face-documentation)
 418 (defalias 'set-face-doc-string 'set-face-documentation)
 419
 420
 421 \f
 422 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 423 ;; Setting face attributes.
 424 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 425
 426
 427 (defun set-face-attribute (face frame &rest args)
 428   "Set attributes of FACE on FRAME from ARGS.
 429
 430 FRAME nil means change attributes on all frames.  FRAME t means change
 431 the default for new frames (this is done automatically each time an
 432 attribute is changed on all frames).
 433
 434 ARGS must come in pairs ATTRIBUTE VALUE.  ATTRIBUTE must be a valid
 435 face attribute name.  All attributes can be set to `unspecified';
 436 this fact is not further mentioned below.
 437
 438 The following attributes are recognized:
 439
 440 `:family'
 441
 442 VALUE must be a string specifying the font family, e.g. ``courier'',
 443 or a fontset alias name.  If a font family is specified, wild-cards `*'
 444 and `?' are allowed.
 445
 446 `:width'
 447
 448 VALUE specifies the relative proportionate width of the font to use.
 449 It must be one of the symbols `ultra-condensed', `extra-condensed',
 450 `condensed', `semi-condensed', `normal', `semi-expanded', `expanded',
 451 `extra-expanded', or `ultra-expanded'.
 452
 453 `:height'
 454
 455 VALUE must be either an integer specifying the height of the font to use
 456 in 1/10 pt, a floating point number specifying the amount by which to
 457 scale any underlying face, or a function, which is called with the old
 458 height (from the underlying face), and should return the new height.
 459
 460 `:weight'
 461
 462 VALUE specifies the weight of the font to use.  It must be one of the
 463 symbols `ultra-bold', `extra-bold', `bold', `semi-bold', `normal',
 464 `semi-light', `light', `extra-light', `ultra-light'.
 465
 466 `:slant'
 467
 468 VALUE specifies the slant of the font to use.  It must be one of the
 469 symbols `italic', `oblique', `normal', `reverse-italic', or
 470 `reverse-oblique'.
 471
 472 `:foreground', `:background'
 473
 474 VALUE must be a color name, a string.
 475
 476 `:underline'
 477
 478 VALUE specifies whether characters in FACE should be underlined.  If
 479 VALUE is t, underline with foreground color of the face.  If VALUE is
 480 a string, underline with that color.  If VALUE is nil, explicitly
 481 don't underline.
 482
 483 `:overline'
 484
 485 VALUE specifies whether characters in FACE should be overlined.  If
 486 VALUE is t, overline with foreground color of the face.  If VALUE is a
 487 string, overline with that color.  If VALUE is nil, explicitly don't
 488 overline.
 489
 490 `:strike-through'
 491
 492 VALUE specifies whether characters in FACE should be drawn with a line
 493 striking through them.  If VALUE is t, use the foreground color of the
 494 face.  If VALUE is a string, strike-through with that color.  If VALUE
 495 is nil, explicitly don't strike through.
 496
 497 `:box'
 498
 499 VALUE specifies whether characters in FACE should have a box drawn
 500 around them.  If VALUE is nil, explicitly don't draw boxes.  If
 501 VALUE is t, draw a box with lines of width 1 in the foreground color
 502 of the face.  If VALUE is a string, the string must be a color name,
 503 and the box is drawn in that color with a line width of 1.  Otherwise,
 504 VALUE must be a property list of the form `(:line-width WIDTH
 505 :color COLOR :style STYLE)'.  If a keyword/value pair is missing from
 506 the property list, a default value will be used for the value, as
 507 specified below.  WIDTH specifies the width of the lines to draw; it
 508 defaults to 1.  COLOR is the name of the color to draw in, default is
 509 the foreground color of the face for simple boxes, and the background
 510 color of the face for 3D boxes.  STYLE specifies whether a 3D box
 511 should be draw.  If STYLE is `released-button', draw a box looking
 512 like a released 3D button.  If STYLE is `pressed-button' draw a box
 513 that appears like a pressed button.  If STYLE is nil, the default if
 514 the property list doesn't contain a style specification, draw a 2D
 515 box.
 516
 517 `:inverse-video'
 518
 519 VALUE specifies whether characters in FACE should be displayed in
 520 inverse video.  VALUE must be one of t or nil.
 521
 522 `:stipple'
 523
 524 If VALUE is a string, it must be the name of a file of pixmap data.
 525 The directories listed in the `x-bitmap-file-path' variable are
 526 searched.  Alternatively, VALUE may be a list of the form (WIDTH
 527 HEIGHT DATA) where WIDTH and HEIGHT are the size in pixels, and DATA
 528 is a string containing the raw bits of the bitmap.  VALUE nil means
 529 explicitly don't use a stipple pattern.
 530
 531 For convenience, attributes `:family', `:width', `:height', `:weight',
 532 and `:slant' may also be set in one step from an X font name:
 533
 534 `:font'
 535
 536 Set font-related face attributes from VALUE.  VALUE must be a valid
 537 XLFD font name.  If it is a font name pattern, the first matching font
 538 will be used.
 539
 540 For compatibility with Emacs 20, keywords `:bold' and `:italic' can
 541 be used to specify that a bold or italic font should be used.  VALUE
 542 must be t or nil in that case.  A value of `unspecified' is not allowed.
 543
 544 `:inherit'
 545
 546 VALUE is the name of a face from which to inherit attributes, or a list
 547 of face names.  Attributes from inherited faces are merged into the face
 548 like an underlying face would be, with higher priority than underlying faces."
 549   (setq args (purecopy args))
 550   (cond ((null frame)
 551          ;; Change face on all frames.
 552          (dolist (frame (frame-list))
 553            (apply #'set-face-attribute face frame args))
 554          ;; Record that as a default for new frames.
 555          (apply #'set-face-attribute face t args))
 556         (t
 557          (while args
 558            (internal-set-lisp-face-attribute face (car args)
 559                                              (purecopy (cadr args))
 560                                              frame)
 561            (setq args (cdr (cdr args)))))))
 562
 563
 564 (defun make-face-bold (face &optional frame noerror)
 565   "Make the font of FACE be bold, if possible.
 566 FRAME nil or not specified means change face on all frames.
 567 Argument NOERROR is ignored and retained for compatibility.
 568 Use `set-face-attribute' for finer control of the font weight."
 569   (interactive (list (read-face-name "Make which face bold ")))
 570   (set-face-attribute face frame :weight 'bold))
 571
 572
 573 (defun make-face-unbold (face &optional frame noerror)
 574   "Make the font of FACE be non-bold, if possible.
 575 FRAME nil or not specified means change face on all frames.
 576 Argument NOERROR is ignored and retained for compatibility."
 577   (interactive (list (read-face-name "Make which face non-bold ")))
 578   (set-face-attribute face frame :weight 'normal))
 579
 580
 581 (defun make-face-italic (face &optional frame noerror)
 582   "Make the font of FACE be italic, if possible.
 583 FRAME nil or not specified means change face on all frames.
 584 Argument NOERROR is ignored and retained for compatibility.
 585 Use `set-face-attribute' for finer control of the font slant."
 586   (interactive (list (read-face-name "Make which face italic ")))
 587   (set-face-attribute face frame :slant 'italic))
 588
 589
 590 (defun make-face-unitalic (face &optional frame noerror)
 591   "Make the font of FACE be non-italic, if possible.
 592 FRAME nil or not specified means change face on all frames.
 593 Argument NOERROR is ignored and retained for compatibility."
 594   (interactive (list (read-face-name "Make which face non-italic ")))
 595   (set-face-attribute face frame :slant 'normal))
 596
 597
 598 (defun make-face-bold-italic (face &optional frame noerror)
 599   "Make the font of FACE be bold and italic, if possible.
 600 FRAME nil or not specified means change face on all frames.
 601 Argument NOERROR is ignored and retained for compatibility.
 602 Use `set-face-attribute' for finer control of font weight and slant."
 603   (interactive (list (read-face-name "Make which face bold-italic: ")))
 604   (set-face-attribute face frame :weight 'bold :slant 'italic))
 605
 606
 607 (defun set-face-font (face font &optional frame)
 608   "Change font-related attributes of FACE to those of FONT (a string).
 609 FRAME nil or not specified means change face on all frames.
 610 This sets the attributes `:family', `:width', `:height', `:weight',
 611 and `:slant'.  When called interactively, prompt for the face and font."
 612   (interactive (read-face-and-attribute :font))
 613   (set-face-attribute face frame :font font))
 614
 615
 616 ;; Implementation note: Emulating gray background colors with a
 617 ;; stipple pattern is now part of the face realization process, and is
 618 ;; done in C depending on the frame on which the face is realized.
 619
 620 (defun set-face-background (face color &optional frame)
 621   "Change the background color of face FACE to COLOR (a string).
 622 FRAME nil or not specified means change face on all frames.
 623 When called interactively, prompt for the face and color."
 624   (interactive (read-face-and-attribute :background))
 625   (set-face-attribute face frame :background color))
 626
 627
 628 (defun set-face-foreground (face color &optional frame)
 629   "Change the foreground color of face FACE to COLOR (a string).
 630 FRAME nil or not specified means change face on all frames.
 631 When called interactively, prompt for the face and color."
 632   (interactive (read-face-and-attribute :foreground))
 633   (set-face-attribute face frame :foreground color))
 634
 635
 636 (defun set-face-stipple (face stipple &optional frame)
 637   "Change the stipple pixmap of face FACE to STIPPLE.
 638 FRAME nil or not specified means change face on all frames.
 639 STIPPLE should be a string, the name of a file of pixmap data.
 640 The directories listed in the `x-bitmap-file-path' variable are searched.
 641
 642 Alternatively, STIPPLE may be a list of the form (WIDTH HEIGHT DATA)
 643 where WIDTH and HEIGHT are the size in pixels,
 644 and DATA is a string, containing the raw bits of the bitmap."
 645   (interactive (read-face-and-attribute :stipple))
 646   (set-face-attribute face frame :stipple stipple))
 647
 648
 649 (defun set-face-underline (face underline &optional frame)
 650   "Specify whether face FACE is underlined.
 651 UNDERLINE nil means FACE explicitly doesn't underline.
 652 UNDERLINE non-nil means FACE explicitly does underlining
 653 with the same of the foreground color.
 654 If UNDERLINE is a string, underline with the color named UNDERLINE.
 655 FRAME nil or not specified means change face on all frames.
 656 Use `set-face-attribute' to ``unspecify'' underlining."
 657   (interactive
 658    (let ((list (read-face-and-attribute :underline)))
 659      (list (car list) (eq (car (cdr list)) t))))
 660   (set-face-attribute face frame :underline underline))
 661
 662
 663 (defun set-face-underline-p (face underline-p &optional frame)
 664   "Specify whether face FACE is underlined.
 665 UNDERLINE-P nil means FACE explicitly doesn't underline.
 666 UNDERLINE-P non-nil means FACE explicitly does underlining.
 667 FRAME nil or not specified means change face on all frames.
 668 Use `set-face-attribute' to ``unspecify'' underlining."
 669   (interactive
 670    (let ((list (read-face-and-attribute :underline)))
 671      (list (car list) (eq (car (cdr list)) t))))
 672   (set-face-attribute face frame :underline underline-p))
 673
 674
 675 (defun set-face-inverse-video-p (face inverse-video-p &optional frame)
 676   "Specify whether face FACE is in inverse video.
 677 INVERSE-VIDEO-P non-nil means FACE displays explicitly in inverse video.
 678 INVERSE-VIDEO-P nil means FACE explicitly is not in inverse video.
 679 FRAME nil or not specified means change face on all frames.
 680 Use `set-face-attribute' to ``unspecify'' the inverse video attribute."
 681   (interactive
 682    (let ((list (read-face-and-attribute :inverse-video)))
 683      (list (car list) (eq (car (cdr list)) t))))
 684   (set-face-attribute face frame :inverse-video inverse-video-p))
 685
 686
 687 (defun set-face-bold-p (face bold-p &optional frame)
 688   "Specify whether face FACE is bold.
 689 BOLD-P non-nil means FACE should explicitly display bold.
 690 BOLD-P nil means FACE should explicitly display non-bold.
 691 FRAME nil or not specified means change face on all frames.
 692 Use `set-face-attribute' or `modify-face' for finer control."
 693   (if (null bold-p)
 694       (make-face-unbold face frame)
 695     (make-face-bold face frame)))
 696
 697
 698 (defun set-face-italic-p (face italic-p &optional frame)
 699   "Specify whether face FACE is italic.
 700 ITALIC-P non-nil means FACE should explicitly display italic.
 701 ITALIC-P nil means FACE should explicitly display non-italic.
 702 FRAME nil or not specified means change face on all frames.
 703 Use `set-face-attribute' or `modify-face' for finer control."
 704   (if (null italic-p)
 705       (make-face-unitalic face frame)
 706     (make-face-italic face frame)))
 707
 708
 709 (defalias 'set-face-background-pixmap 'set-face-stipple)
 710
 711
 712 (defun invert-face (face &optional frame)
 713   "Swap the foreground and background colors of FACE.
 714 FRAME nil or not specified means change face on all frames.
 715 If FACE specifies neither foreground nor background color,
 716 set its foreground and background to the background and foreground
 717 of the default face.  Value is FACE."
 718   (interactive (list (read-face-name "Invert face ")))
 719   (let ((fg (face-attribute face :foreground frame))
 720         (bg (face-attribute face :background frame)))
 721     (if (or fg bg)
 722         (set-face-attribute face frame :foreground bg :background fg)
 723       (set-face-attribute face frame
 724                           :foreground
 725                           (face-attribute 'default :background frame)
 726                           :background
 727                           (face-attribute 'default :foreground frame))))
 728   face)
 729
 730 \f
 731 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 732 ;;; Interactively modifying faces.
 733 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 734
 735 (defun read-face-name (prompt)
 736   "Read and return a face symbol, prompting with PROMPT.
 737 Value is a symbol naming a known face."
 738   (let ((face-list (mapcar #'(lambda (x) (cons (symbol-name x) x))
 739                            (face-list)))
 740         (def (thing-at-point 'symbol))
 741         face)
 742     (cond ((assoc def face-list)
 743            (setq prompt (concat prompt " (default " def "): ")))
 744           (t (setq def nil)
 745              (setq prompt (concat prompt ": "))))
 746     (while (equal "" (setq face (completing-read
 747                                  prompt face-list nil t nil nil def))))
 748     (intern face)))
 749
 750
 751 (defun face-valid-attribute-values (attribute &optional frame)
 752   "Return valid values for face attribute ATTRIBUTE.
 753 The optional argument FRAME is used to determine available fonts
 754 and colors.  If it is nil or not specified, the selected frame is
 755 used.  Value is an alist of (NAME . VALUE) if ATTRIBUTE expects a value
 756 out of a set of discrete values.  Value is `integerp' if ATTRIBUTE expects
 757 an integer value."
 758   (let (valid)
 759     (setq valid
 760           (case attribute
 761             (:family
 762              (if window-system
 763                  (mapcar #'(lambda (x) (cons (car x) (car x)))
 764                          (x-font-family-list))
 765                ;; Only one font on TTYs.
 766                (list (cons "default" "default"))))
 767             ((:width :weight :slant :inverse-video)
 768              (mapcar #'(lambda (x) (cons (symbol-name x) x))
 769                      (internal-lisp-face-attribute-values attribute)))
 770             ((:underline :overline :strike-through :box)
 771              (if window-system
 772                  (nconc (mapcar #'(lambda (x) (cons (symbol-name x) x))
 773                                 (internal-lisp-face-attribute-values attribute))
 774                         (mapcar #'(lambda (c) (cons c c))
 775                                 (x-defined-colors frame)))
 776                (mapcar #'(lambda (x) (cons (symbol-name x) x))
 777                        (internal-lisp-face-attribute-values attribute))))
 778             ((:foreground :background)
 779              (mapcar #'(lambda (c) (cons c c))
 780                      (defined-colors frame)))
 781             ((:height)
 782              'integerp)
 783             (:stipple
 784              (and (memq window-system '(x w32))
 785                   (mapcar #'list
 786                           (apply #'nconc (mapcar #'directory-files
 787                                                  x-bitmap-file-path)))))
 788             (:inherit
 789              (cons '("none" . nil)
 790                    (mapcar #'(lambda (c) (cons (symbol-name c) c))
 791                            (face-list))))
 792             (t
 793              (error "Internal error"))))
 794     (if (and (listp valid) (not (memq attribute '(:inherit))))
 795         (nconc (list (cons "unspecified" 'unspecified)) valid)
 796       valid)))
 797
 798
 799
 800 (defvar face-attribute-name-alist
 801   '((:family . "font family")
 802     (:width . "character set width")
 803     (:height . "height in 1/10 pt")
 804     (:weight . "weight")
 805     (:slant . "slant")
 806     (:underline . "underline")
 807     (:overline . "overline")
 808     (:strike-through . "strike-through")
 809     (:box . "box")
 810     (:inverse-video . "inverse-video display")
 811     (:foreground . "foreground color")
 812     (:background . "background color")
 813     (:stipple . "background stipple")
 814     (:inherit . "inheritance"))
 815   "An alist of descriptive names for face attributes.
 816 Each element has the form (ATTRIBUTE-NAME . DESCRIPTION) where
 817 ATTRIBUTE-NAME is a face attribute name (a keyword symbol), and
 818 DESCRIPTION is a descriptive name for ATTRIBUTE-NAME.")
 819
 820
 821 (defun face-descriptive-attribute-name (attribute)
 822   "Return a descriptive name for ATTRIBUTE."
 823   (cdr (assq attribute face-attribute-name-alist)))
 824
 825
 826 (defun face-read-string (face default name &optional completion-alist)
 827   "Interactively read a face attribute string value.
 828 FACE is the face whose attribute is read.  If non-nil, DEFAULT is the
 829 default string to return if no new value is entered.  NAME is a
 830 descriptive name of the attribute for prompting.  COMPLETION-ALIST is an
 831 alist of valid values, if non-nil.
 832
 833 Entering nothing accepts the default string DEFAULT.
 834 Value is the new attribute value."
 835   ;; Capitalize NAME (we don't use `capitalize' because that capitalizes
 836   ;; each word in a string separately).
 837   (setq name (concat (upcase (substring name 0 1)) (substring name 1)))
 838   (let* ((completion-ignore-case t)
 839          (value (completing-read
 840                  (if default
 841                      (format "%s for face `%s' (default %s): "
 842                              name face default)
 843                    (format "%s for face `%s': " name face))
 844                  completion-alist)))
 845     (if (equal value "") default value)))
 846
 847
 848 (defun face-read-integer (face default name)
 849   "Interactively read an integer face attribute value.
 850 FACE is the face whose attribute is read.  DEFAULT is the default
 851 value to return if no new value is entered.  NAME is a descriptive
 852 name of the attribute for prompting.  Value is the new attribute value."
 853   (let ((new-value
 854          (face-read-string face
 855                            (format "%s" default)
 856                            name
 857                            (list (cons "unspecified" 'unspecified)))))
 858     (cond ((equal new-value "unspecified")
 859            'unspecified)
 860           ((member new-value '("unspecified-fg" "unspecified-bg"))
 861            new-value)
 862           (t
 863            (string-to-int new-value)))))
 864
 865
 866 (defun read-face-attribute (face attribute &optional frame)
 867   "Interactively read a new value for FACE's ATTRIBUTE.
 868 Optional argument FRAME nil or unspecified means read an attribute value
 869 of a global face.  Value is the new attribute value."
 870   (let* ((old-value (face-attribute face attribute frame))
 871          (attribute-name (face-descriptive-attribute-name attribute))
 872          (valid (face-valid-attribute-values attribute frame))
 873          new-value)
 874     ;; Represent complex attribute values as strings by printing them
 875     ;; out.  Stipple can be a vector; (WIDTH HEIGHT DATA).  Box can be
 876     ;; a list `(:width WIDTH :color COLOR)' or `(:width WIDTH :shadow
 877     ;; SHADOW)'.
 878     (when (and (or (eq attribute :stipple)
 879                    (eq attribute :box))
 880                (or (consp old-value)
 881                    (vectorp old-value)))
 882       (setq old-value (prin1-to-string old-value)))
 883     (cond ((listp valid)
 884            (let ((default
 885                    (or (car (rassoc old-value valid))
 886                        (format "%s" old-value))))
 887              (setq new-value
 888                    (face-read-string face default attribute-name valid))
 889              (if (equal new-value default)
 890                  ;; Nothing changed, so don't bother with all the stuff
 891                  ;; below.  In particular, this avoids a non-tty color
 892                  ;; from being canonicalized for a tty when the user
 893                  ;; just uses the default.
 894                  (setq new-value old-value)
 895                ;; Terminal frames can support colors that don't appear
 896                ;; explicitly in VALID, using color approximation code
 897                ;; in tty-colors.el.
 898                (if (and (memq attribute '(:foreground :background))
 899                         (not (memq window-system '(x w32 mac)))
 900                         (not (member new-value
 901                                      '("unspecified"
 902                                        "unspecified-fg" "unspecified-bg"))))
 903                    (setq new-value (car (tty-color-desc new-value frame))))
 904                (setq new-value (cdr (assoc new-value valid))))))
 905           ((eq valid 'integerp)
 906            (setq new-value (face-read-integer face old-value attribute-name)))
 907           (t (error "Internal error")))
 908     ;; Convert stipple and box value text we read back to a list or
 909     ;; vector if it looks like one.  This makes the assumption that a
 910     ;; pixmap file name won't start with an open-paren.
 911     (when (and (or (eq attribute :stipple)
 912                    (eq attribute :box))
 913                (stringp new-value)
 914                (string-match "^[[(]" new-value))
 915       (setq new-value (read new-value)))
 916     new-value))
 917
 918
 919 (defun read-face-font (face &optional frame)
 920   "Read the name of a font for FACE on FRAME.
 921 If optional argument FRAME Is nil or omitted, use the selected frame."
 922   (let ((completion-ignore-case t))
 923     (completing-read (format "Set font attributes of face `%s' from font: " face)
 924                      (mapcar 'list (x-list-fonts "*" nil frame)))))
 925
 926
 927 (defun read-all-face-attributes (face &optional frame)
 928   "Interactively read all attributes for FACE.
 929 If optional argument FRAME Is nil or omitted, use the selected frame.
 930 Value is a property list of attribute names and new values."
 931   (let (result)
 932     (dolist (attribute face-attribute-name-alist result)
 933       (setq result (cons (car attribute)
 934                          (cons (read-face-attribute face (car attribute) frame)
 935                                result))))))
 936
 937
 938 (defun modify-face (&optional frame)
 939   "Modify attributes of faces interactively.
 940 If optional argument FRAME is nil or omitted, modify the face used
 941 for newly created frame, i.e. the global face."
 942   (interactive)
 943   (let ((face (read-face-name "Modify face")))
 944     (apply #'set-face-attribute face frame
 945            (read-all-face-attributes face frame))))
 946
 947
 948 (defun read-face-and-attribute (attribute &optional frame)
 949   "Read face name and face attribute value.
 950 ATTRIBUTE is the attribute whose new value is read.
 951 FRAME nil or unspecified means read attribute value of global face.
 952 Value is a list (FACE NEW-VALUE) where FACE is the face read
 953 (a symbol), and NEW-VALUE is value read."
 954   (cond ((eq attribute :font)
 955          (let* ((prompt "Set font-related attributes of face")
 956                 (face (read-face-name prompt))
 957                 (font (read-face-font face frame)))
 958            (list face font)))
 959         (t
 960          (let* ((attribute-name (face-descriptive-attribute-name attribute))
 961                 (prompt (format "Set %s of face" attribute-name))
 962                 (face (read-face-name prompt))
 963                 (new-value (read-face-attribute face attribute frame)))
 964            (list face new-value)))))
 965
 966
 967 \f
 968 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 969 ;;; Listing faces.
 970 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 971
 972 (defvar list-faces-sample-text
 973   "abcdefghijklmnopqrstuvwxyz ABCDEFGHIJKLMNOPQRSTUVWXYZ"
 974   "*Text string to display as the sample text for `list-faces-display'.")
 975
 976
 977 ;; The name list-faces would be more consistent, but let's avoid a
 978 ;; conflict with Lucid, which uses that name differently.
 979
 980 (defun list-faces-display ()
 981   "List all faces, using the same sample text in each.
 982 The sample text is a string that comes from the variable
 983 `list-faces-sample-text'."
 984   (interactive)
 985   (let ((faces (sort (face-list) #'string-lessp))
 986         (face nil)
 987         (frame (selected-frame))
 988         disp-frame window face-name)
 989     (with-output-to-temp-buffer "*Faces*"
 990       (save-excursion
 991         (set-buffer standard-output)
 992         (setq truncate-lines t)
 993         (insert
 994          (substitute-command-keys
 995           (concat
 996            "Use "
 997            (if (display-mouse-p) "\\[help-follow-mouse] or ")
 998            "\\[help-follow] on a face name to customize it\n"
 999            "or on its sample text for a decription of the face.\n\n")))
1000         (setq help-xref-stack nil)
1001         (while faces
1002           (setq face (car faces))
1003           (setq faces (cdr faces))
1004           (setq face-name (symbol-name face))
1005           (insert (format "%25s " face-name))
1006           ;; Hyperlink to a customization buffer for the face.  Using
1007           ;; the help xref mechanism may not be the best way.
1008           (save-excursion
1009             (save-match-data
1010               (search-backward face-name)
1011               (help-xref-button 0 (lambda (f)
1012                                     (if help-xref-stack
1013                                         (pop help-xref-stack))
1014                                     (customize-face f))
1015                                 face-name
1016                                 "mouse-2: customize this face")))
1017           (let ((beg (point)))
1018             (insert list-faces-sample-text)
1019             ;; Hyperlink to a help buffer for the face.
1020             (save-excursion
1021               (save-match-data
1022                 (search-backward list-faces-sample-text)
1023                 (help-xref-button 0 #'describe-face face
1024                                   "mouse-2: describe this face")))
1025             (insert "\n")
1026             (put-text-property beg (1- (point)) 'face face)
1027             ;; If the sample text has multiple lines, line up all of them.
1028             (goto-char beg)
1029             (forward-line 1)
1030             (while (not (eobp))
1031               (insert "                          ")
1032               (forward-line 1))))
1033         (goto-char (point-min)))
1034       (print-help-return-message))
1035     ;; If the *Faces* buffer appears in a different frame,
1036     ;; copy all the face definitions from FRAME,
1037     ;; so that the display will reflect the frame that was selected.
1038     (setq window (get-buffer-window (get-buffer "*Faces*") t))
1039     (setq disp-frame (if window (window-frame window)
1040                        (car (frame-list))))
1041     (or (eq frame disp-frame)
1042         (let ((faces (face-list)))
1043           (while faces
1044             (copy-face (car faces) (car faces) frame disp-frame)
1045             (setq faces (cdr faces)))))))
1046
1047
1048 (defun describe-face (face &optional frame)
1049   "Display the properties of face FACE on FRAME.
1050 If the optional argument FRAME is given, report on face FACE in that frame.
1051 If FRAME is t, report on the defaults for face FACE (for new frames).
1052 If FRAME is omitted or nil, use the selected frame."
1053   (interactive (list (read-face-name "Describe face")))
1054   (let* ((attrs '((:family . "Family")
1055                   (:width . "Width")
1056                   (:height . "Height")
1057                   (:weight . "Weight")
1058                   (:slant . "Slant")
1059                   (:foreground . "Foreground")
1060                   (:background . "Background")
1061                   (:underline . "Underline")
1062                   (:overline . "Overline")
1063                   (:strike-through . "Strike-through")
1064                   (:box . "Box")
1065                   (:inverse-video . "Inverse")
1066                   (:stipple . "Stipple")
1067                   (:font . "Font or fontset")
1068                   (:inherit . "Inherit")))
1069         (max-width (apply #'max (mapcar #'(lambda (x) (length (cdr x)))
1070                                         attrs))))
1071     (with-output-to-temp-buffer "*Help*"
1072       (save-excursion
1073         (set-buffer standard-output)
1074         (dolist (a attrs)
1075           (let ((attr (face-attribute face (car a) frame)))
1076             (insert (make-string (- max-width (length (cdr a))) ?\ )
1077                     (cdr a) ": " (format "%s" attr) "\n")))
1078         (insert "\nDocumentation:\n\n"
1079                 (or (face-documentation face)
1080                     "not documented as a face."))
1081         (let ((customize-label "customize"))
1082           (terpri)
1083           (terpri)
1084           (princ (concat "You can " customize-label " this face."))
1085           (with-current-buffer "*Help*"
1086             (save-excursion
1087               (re-search-backward
1088                (concat "\\(" customize-label "\\)") nil t)
1089               (help-xref-button 1 #'customize-face face
1090                                 "mouse-2, RET: customize face")))))
1091       (print-help-return-message)
1092       (with-current-buffer "*Help*"
1093         (help-setup-xref (list #'describe-face face) (interactive-p))
1094         (buffer-string)))))
1095 \f
1096 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1097 ;;; Face specifications (defface).
1098 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1099
1100 ;; Parameter FRAME Is kept for call compatibility to with previous
1101 ;; face implementation.
1102
1103 (defun face-attr-construct (face &optional frame)
1104   "Return a defface-style attribute list for FACE on FRAME.
1105 Value is a property list of pairs ATTRIBUTE VALUE for all specified
1106 face attributes of FACE where ATTRIBUTE is the attribute name and
1107 VALUE is the specified value of that attribute."
1108   (let (result)
1109     (dolist (entry face-attribute-name-alist result)
1110       (let* ((attribute (car entry))
1111              (value (face-attribute face attribute)))
1112         (unless (eq value 'unspecified)
1113           (setq result (nconc (list attribute value) result)))))))
1114
1115
1116 (defun face-spec-set-match-display (display frame)
1117   "Non-nil if DISPLAY matches FRAME.
1118 DISPLAY is part of a spec such as can be used in `defface'.
1119 If FRAME is nil, the current FRAME is used."
1120   (let* ((conjuncts display)
1121          conjunct req options
1122          ;; t means we have succeeded against all the conjuncts in
1123          ;; DISPLAY that have been tested so far.
1124          (match t))
1125     (if (eq conjuncts t)
1126         (setq conjuncts nil))
1127     (while (and conjuncts match)
1128       (setq conjunct (car conjuncts)
1129             conjuncts (cdr conjuncts)
1130             req (car conjunct)
1131             options (cdr conjunct)
1132             match (cond ((eq req 'type)
1133                          (or (memq window-system options)
1134                              (and (null window-system)
1135                                   (memq 'tty options))
1136                              (and (memq 'motif options)
1137                                   (featurep 'motif))
1138                              (and (memq 'lucid options)
1139                                   (featurep 'x-toolkit)
1140                                   (not (featurep 'motif)))
1141                              (and (memq 'x-toolkit options)
1142                                   (featurep 'x-toolkit))))
1143                         ((eq req 'class)
1144                          (memq (frame-parameter frame 'display-type) options))
1145                         ((eq req 'background)
1146                          (memq (frame-parameter frame 'background-mode)
1147                                options))
1148                         (t (error "Unknown req `%S' with options `%S'"
1149                                   req options)))))
1150     match))
1151
1152
1153 (defun face-spec-choose (spec &optional frame)
1154   "Choose the proper attributes for FRAME, out of SPEC."
1155   (unless frame
1156     (setq frame (selected-frame)))
1157   (let ((tail spec)
1158         result)
1159     (while tail
1160       (let* ((entry (car tail))
1161              (display (nth 0 entry))
1162              (attrs (nth 1 entry)))
1163         (setq tail (cdr tail))
1164         (when (face-spec-set-match-display display frame)
1165           (setq result attrs tail nil))))
1166     result))
1167
1168
1169 (defun face-spec-reset-face (face &optional frame)
1170   "Reset all attributes of FACE on FRAME to unspecified."
1171   (let ((attrs face-attribute-name-alist)
1172         params)
1173     (while attrs
1174       (let ((attr-and-name (car attrs)))
1175         (setq params (cons (car attr-and-name) (cons 'unspecified params))))
1176       (setq attrs (cdr attrs)))
1177     (apply #'set-face-attribute face frame params)))
1178
1179
1180 (defun face-spec-set (face spec &optional frame)
1181   "Set FACE's attributes according to the first matching entry in SPEC.
1182 FRAME is the frame whose frame-local face is set.  FRAME nil means
1183 do it on all frames.  See `defface' for information about SPEC."
1184   (let ((attrs (face-spec-choose spec frame))
1185         params)
1186     (while attrs
1187       (let ((attribute (car attrs))
1188             (value (car (cdr attrs))))
1189         ;; Support some old-style attribute names and values.
1190         (case attribute
1191           (:bold (setq attribute :weight value (if value 'bold 'normal)))
1192           (:italic (setq attribute :slant value (if value 'italic 'normal)))
1193           (t (unless (assq attribute face-x-resources)
1194                (setq attribute nil))))
1195         (when attribute
1196           (setq params (cons attribute (cons value params)))))
1197       (setq attrs (cdr (cdr attrs))))
1198     (face-spec-reset-face face frame)
1199     (apply #'set-face-attribute face frame params)))
1200
1201
1202 (defun face-attr-match-p (face attrs &optional frame)
1203   "Return t if attributes of FACE match values in plist ATTRS.
1204 Optional parameter FRAME is the frame whose definition of FACE
1205 is used.  If nil or omitted, use the selected frame."
1206   (unless frame
1207     (setq frame (selected-frame)))
1208   (let ((list face-attribute-name-alist)
1209         (match t))
1210     (while (and match (not (null list)))
1211       (let* ((attr (car (car list)))
1212              (specified-value
1213               (if (plist-member attrs attr)
1214                   (plist-get attrs attr)
1215                 'unspecified))
1216              (value-now (face-attribute face attr frame)))
1217         (setq match (equal specified-value value-now))
1218         (setq list (cdr list))))
1219     match))
1220
1221 (defun face-spec-match-p (face spec &optional frame)
1222   "Return t if FACE, on FRAME, matches what SPEC says it should look like."
1223   (face-attr-match-p face (face-spec-choose spec frame) frame))
1224
1225
1226 \f
1227 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1228 ;;; Frame-type independent color support.
1229 ;;; We keep the old x-* names as aliases for back-compatibility.
1230 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1231
1232 (defun defined-colors (&optional frame)
1233   "Return a list of colors supported for a particular frame.
1234 The argument FRAME specifies which frame to try.
1235 The value may be different for frames on different display types.
1236 If FRAME doesn't support colors, the value is nil."
1237   (if (memq (framep (or frame (selected-frame))) '(x w32))
1238       (xw-defined-colors frame)
1239     (mapcar 'car (tty-color-alist frame))))
1240 (defalias 'x-defined-colors 'defined-colors)
1241
1242 (defun color-defined-p (color &optional frame)
1243   "Return non-nil if color COLOR is supported on frame FRAME.
1244 If FRAME is omitted or nil, use the selected frame.
1245 If COLOR is the symbol `unspecified' or one of the strings
1246 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1247   (if (memq color '(unspecified "unspecified-bg" "unspecified-fg"))
1248       nil
1249     (if (memq (framep (or frame (selected-frame))) '(x w32))
1250         (xw-color-defined-p color frame)
1251       (numberp (tty-color-translate color frame)))))
1252 (defalias 'x-color-defined-p 'color-defined-p)
1253
1254 (defun color-values (color &optional frame)
1255   "Return a description of the color named COLOR on frame FRAME.
1256 The value is a list of integer RGB values--\(RED GREEN BLUE\).
1257 These values appear to range from 0 to 65280 or 65535, depending
1258 on the system; white is \(65280 65280 65280\) or \(65535 65535 65535\).
1259 If FRAME is omitted or nil, use the selected frame.
1260 If FRAME cannot display COLOR, the value is nil.
1261 If COLOR is the symbol `unspecified' or one of the strings
1262 \"unspecified-fg\" or \"unspecified-bg\", the value is nil."
1263   (if (memq color '(unspecified "unspecified-fg" "unspecified-bg"))
1264       nil
1265     (if (memq (framep (or frame (selected-frame))) '(x w32))
1266         (xw-color-values color frame)
1267       (tty-color-values color frame))))
1268 (defalias 'x-color-values 'color-values)
1269
1270 (defun display-color-p (&optional display)
1271   "Return t if DISPLAY supports color.
1272 The optional argument DISPLAY specifies which display to ask about.
1273 DISPLAY should be either a frame or a display name (a string).
1274 If omitted or nil, that stands for the selected frame's display."
1275   (if (memq (framep-on-display display) '(x w32))
1276       (xw-display-color-p display)
1277     (tty-display-color-p display)))
1278 (defalias 'x-display-color-p 'display-color-p)
1279
1280 (defun display-grayscale-p (&optional display)
1281   "Return non-nil if frames on DISPLAY can display shades of gray."
1282   (let ((frame-type (framep-on-display display)))
1283     (cond
1284      ((memq frame-type '(x w32 mac))
1285       (x-display-grayscale-p display))
1286      (t
1287       (> (tty-color-gray-shades display) 2)))))
1288
1289 \f
1290 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1291 ;;; Background mode.
1292 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1293
1294 (defcustom frame-background-mode nil
1295   "*The brightness of the background.
1296 Set this to the symbol `dark' if your background color is dark, `light' if
1297 your background is light, or nil (default) if you want Emacs to
1298 examine the brightness for you.  Don't set this variable with `setq';
1299 this won't have the expected effect."
1300   :group 'faces
1301   :set #'(lambda (var value)
1302            (set-default var value)
1303            (mapcar 'frame-set-background-mode (frame-list)))
1304   :initialize 'custom-initialize-changed
1305   :type '(choice (choice-item dark)
1306                  (choice-item light)
1307                  (choice-item :tag "default" nil)))
1308
1309
1310 (defun frame-set-background-mode (frame)
1311   "Set up the `background-mode' and `display-type' frame parameters for FRAME."
1312   (let* ((bg-resource
1313           (and window-system
1314                (x-get-resource ".backgroundMode" "BackgroundMode")))
1315          (params (frame-parameters frame))
1316          (bg-mode (cond (frame-background-mode)
1317                         ((null window-system)
1318                          ;; No way to determine this automatically (?).
1319                          'dark)
1320                         (bg-resource
1321                          (intern (downcase bg-resource)))
1322                         ((< (apply '+ (x-color-values
1323                                        (cdr (assq 'background-color
1324                                                   params))
1325                                        frame))
1326                             ;; Just looking at the screen, colors whose
1327                             ;; values add up to .6 of the white total
1328                             ;; still look dark to me.
1329                             (* (apply '+ (x-color-values "white" frame)) .6))
1330                          'dark)
1331                         (t 'light)))
1332          (display-type (cond ((null window-system)
1333                               (if (tty-display-color-p frame) 'color 'mono))
1334                              ((x-display-color-p frame)
1335                               'color)
1336                              ((x-display-grayscale-p frame)
1337                               'grayscale)
1338                              (t 'mono))))
1339     (modify-frame-parameters frame
1340                              (list (cons 'background-mode bg-mode)
1341                                    (cons 'display-type display-type))))
1342
1343   ;; For all named faces, choose face specs matching the new frame
1344   ;; parameters.
1345   (let ((face-list (face-list)))
1346     (while face-list
1347       (let* ((face (car face-list))
1348              (spec (get face 'face-defface-spec)))
1349         (when spec
1350           (face-spec-set face spec frame))
1351       (setq face-list (cdr face-list))))))
1352
1353
1354
1355 \f
1356 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1357 ;;; Frame creation.
1358 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1359
1360 (defun x-handle-named-frame-geometry (parameters)
1361   "Add geometry parameters for a named frame to parameter list PARAMETERS.
1362 Value is the new parameter list."
1363   (let* ((name (or (cdr (assq 'name parameters))
1364                    (cdr (assq 'name default-frame-alist))))
1365          (x-resource-name name)
1366          (res-geometry (if name (x-get-resource "geometry" "Geometry"))))
1367     (when res-geometry
1368       (let ((parsed (x-parse-geometry res-geometry)))
1369         ;; If the resource specifies a position, call the position
1370         ;; and size "user-specified".
1371         (when (or (assq 'top parsed)
1372                   (assq 'left parsed))
1373           (setq parsed (append '((user-position . t) (user-size . t)) parsed)))
1374         ;; Put the geometry parameters at the end.  Copy
1375         ;; default-frame-alist so that they go after it.
1376         (setq parameters (append parameters default-frame-alist parsed))))
1377     parameters))
1378
1379
1380 (defun x-handle-reverse-video (frame parameters)
1381   "Handle the reverse-video frame parameter and X resource.
1382 `x-create-frame' does not handle this one."
1383   (when (cdr (or (assq 'reverse parameters)
1384                  (assq 'reverse default-frame-alist)
1385                  (let ((resource (x-get-resource "reverseVideo"
1386                                                  "ReverseVideo")))
1387                    (if resource
1388                        (cons nil (member (downcase resource)
1389                                          '("on" "true")))))))
1390       (let* ((params (frame-parameters frame))
1391              (bg (cdr (assq 'foreground-color params)))
1392              (fg (cdr (assq 'background-color params))))
1393         (modify-frame-parameters frame
1394                                  (list (cons 'foreground-color fg)
1395                                        (cons 'background-color bg)))
1396         (if (equal bg (cdr (assq 'border-color params)))
1397             (modify-frame-parameters frame
1398                                      (list (cons 'border-color fg))))
1399         (if (equal bg (cdr (assq 'mouse-color params)))
1400             (modify-frame-parameters frame
1401                                      (list (cons 'mouse-color fg))))
1402         (if (equal bg (cdr (assq 'cursor-color params)))
1403             (modify-frame-parameters frame
1404                                      (list (cons 'cursor-color fg)))))))
1405
1406
1407 (defun x-create-frame-with-faces (&optional parameters)
1408   "Create a frame from optional frame parameters PARAMETERS.
1409 Parameters not specified by PARAMETERS are taken from
1410 `default-frame-alist'.  If PARAMETERS specify a frame name,
1411 handle X geometry resources for that name.  If either PARAMETERS
1412 or `default-frame-alist' contains a `reverse' parameter, or
1413 the X resource ``reverseVideo'' is present, handle that.
1414 Value is the new frame created."
1415   (setq parameters (x-handle-named-frame-geometry parameters))
1416   (let ((visibility-spec (assq 'visibility parameters))
1417         (frame-list (frame-list))
1418         (frame (x-create-frame (cons '(visibility . nil) parameters)))
1419         success)
1420     (unwind-protect
1421         (progn
1422           (x-handle-reverse-video frame parameters)
1423           (frame-set-background-mode frame)
1424           (face-set-after-frame-default frame)
1425           (if (or (null frame-list) (null visibility-spec))
1426               (make-frame-visible frame)
1427             (modify-frame-parameters frame (list visibility-spec)))
1428           (setq success t))
1429       (unless success
1430         (delete-frame frame)))
1431     frame))
1432
1433
1434 (defun face-set-after-frame-default (frame)
1435   "Set frame-local faces of FRAME from face specs and resources.
1436 Initialize colors of certain faces from frame parameters."
1437   (dolist (face (face-list))
1438     (let ((spec (or (get face 'saved-face)
1439                     (get face 'face-defface-spec))))
1440       (when spec
1441         (face-spec-set face spec frame))
1442       (internal-merge-in-global-face face frame)
1443       (when (memq window-system '(x w32))
1444         (make-face-x-resource-internal face frame))))
1445
1446   ;; Initialize attributes from frame parameters.
1447   (let ((params '((foreground-color default :foreground)
1448                   (background-color default :background)
1449                   (border-color border :background)
1450                   (cursor-color cursor :background)
1451                   (scroll-bar-foreground scroll-bar :foreground)
1452                   (scroll-bar-background scroll-bar :background)
1453                   (mouse-color mouse :background))))
1454     (while params
1455       (let ((param-name (nth 0 (car params)))
1456             (face (nth 1 (car params)))
1457             (attr (nth 2 (car params)))
1458             value)
1459         (when (setq value (frame-parameter frame param-name))
1460           (set-face-attribute face frame attr value)))
1461       (setq params (cdr params)))))
1462
1463
1464 (defun tty-create-frame-with-faces (&optional parameters)
1465   "Create a frame from optional frame parameters PARAMETERS.
1466 Parameters not specified by PARAMETERS are taken from
1467 `default-frame-alist'.  If either PARAMETERS or `default-frame-alist'
1468 contains a `reverse' parameter, handle that.  Value is the new frame
1469 created."
1470   (let ((frame (make-terminal-frame parameters))
1471         success)
1472     (unwind-protect
1473         (progn
1474           (frame-set-background-mode frame)
1475           (face-set-after-frame-default frame)
1476           (setq success t))
1477       (unless success
1478         (delete-frame frame)))
1479     frame))
1480
1481
1482 ;; Called from C function init_display to initialize faces of the
1483 ;; dumped terminal frame on startup.
1484
1485 (defun tty-set-up-initial-frame-faces ()
1486   (let ((frame (selected-frame)))
1487     (frame-set-background-mode frame)
1488     (face-set-after-frame-default frame)))
1489
1490
1491
1492 \f
1493 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1494 ;;; Compatiblity with 20.2
1495 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1496
1497 ;; Update a frame's faces when we change its default font.
1498
1499 (defalias 'frame-update-faces 'ignore)
1500 (make-obsolete 'frame-update-faces "No longer necessary" "21.1")
1501
1502 ;; Update the colors of FACE, after FRAME's own colors have been
1503 ;; changed.
1504
1505 (defalias 'frame-update-face-colors 'frame-set-background-mode)
1506 (make-obsolete 'frame-update-face-colors 'frame-set-background-mode "21.1")
1507
1508 \f
1509 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1510 ;;; Standard faces.
1511 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1512
1513 (defgroup basic-faces nil
1514   "The standard faces of Emacs."
1515   :group 'faces)
1516
1517
1518 (defface default
1519   '((t nil))
1520   "Basic default face."
1521   :group 'basic-faces)
1522
1523
1524 (defface mode-line
1525   '((((type x) (class color))
1526      (:box (:line-width 2 :style released-button)
1527            :background "grey75" :foreground "black"))
1528     (((type w32) (class color))
1529      (:box (:line-width 2 :style released-button)
1530            :background "grey75" :foreground "black"))
1531     (t
1532      (:inverse-video t)))
1533   "Basic mode line face."
1534   :version "21.1"
1535   :group 'modeline
1536   :group 'basic-faces)
1537
1538 ;; Make `modeline' an alias for `mode-line', for compatibility.
1539 (put 'modeline 'face-alias 'mode-line)
1540
1541 (defface header-line
1542   '((((type x) (class color))
1543      (:box (:line-width 2 :style released-button)
1544            :background "grey75" :foreground "black"))
1545     (((type w32) (class color))
1546      (:box (:line-width 2 :style released-button)
1547            :background "grey75" :foreground "black"))
1548     (t
1549      (:inverse-video t)))
1550   "Basic header-line face."
1551   :version "21.1"
1552   :group 'basic-faces)
1553
1554
1555 (defface tool-bar
1556   '((((type x) (class color))
1557      (:box (:line-width 1 :style released-button)
1558            :background "grey75" :foreground "black"))
1559     (((type x) (class mono))
1560      (:box (:line-width 1 :style released-button)
1561            :background "grey" :foreground "black"))
1562     (((type w32) (class color))
1563      (:box (:line-width 1 :style released-button)
1564            :background "grey75" :foreground "black"))
1565     (t
1566      ()))
1567   "Basic tool-bar face."
1568   :version "21.1"
1569   :group 'basic-faces)
1570
1571
1572 (defface region
1573   '((((type tty) (class color))
1574      (:background "blue" :foreground "white"))
1575     (((type tty) (class mono))
1576      (:inverse-video t))
1577     (((class color) (background dark))
1578      (:background "blue"))
1579     (((class color) (background light))
1580      (:background "light goldenrod yellow"))
1581     (t (:background "gray")))
1582   "Basic face for highlighting the region."
1583   :group 'basic-faces)
1584
1585
1586 (defface fringe
1587   '((((class color) (background light))
1588        (:background "grey95"))
1589       (((class color) (background dark))
1590        (:background "grey10"))
1591       (t
1592        (:background "gray")))
1593   "Basic face for the fringes to the left and right of windows under X."
1594   :version "21.1"
1595   :group 'frames
1596   :group 'basic-faces)
1597
1598
1599 (defface scroll-bar '()
1600   "Basic face for the scroll bar colors under X."
1601   :version "21.1"
1602   :group 'frames
1603   :group 'basic-faces)
1604
1605
1606 (defface menu
1607   '((((type x-toolkit)) ())
1608     (t (:inverse-video t)))
1609   "Basic menu face."
1610   :version "21.1"
1611   :group 'menu
1612   :group 'basic-faces)
1613
1614
1615 (defface border '()
1616   "Basic face for the frame border under X."
1617   :version "21.1"
1618   :group 'frames
1619   :group 'basic-faces)
1620
1621
1622 (defface cursor '()
1623   "Basic face for the cursor color under X."
1624   :version "21.1"
1625   :group 'cursor
1626   :group 'basic-faces)
1627
1628
1629 (defface mouse '()
1630   "Basic face for the mouse color under X."
1631   :version "21.1"
1632   :group 'mouse
1633   :group 'basic-faces)
1634
1635
1636 (defface bold '((t (:weight bold)))
1637   "Basic bold face."
1638   :group 'basic-faces)
1639
1640
1641 (defface italic '((t (:slant italic)))
1642   "Basic italic font."
1643   :group 'basic-faces)
1644
1645
1646 (defface bold-italic '((t (:weight bold :slant italic)))
1647   "Basic bold-italic face."
1648   :group 'basic-faces)
1649
1650
1651 (defface underline '((t (:underline t)))
1652   "Basic underlined face."
1653   :group 'basic-faces)
1654
1655
1656 (defface highlight
1657   '((((type tty) (class color))
1658      (:background "green"))
1659     (((class color) (background light))
1660      (:background "darkseagreen2"))
1661     (((class color) (background dark))
1662      (:background "darkolivegreen"))
1663     (t (:inverse-video t)))
1664   "Basic face for highlighting."
1665   :group 'basic-faces)
1666
1667
1668 (defface secondary-selection
1669   '((((type tty) (class color))
1670      (:background "cyan"))
1671     (((class color) (background light))
1672      (:background "yellow"))
1673     (((class color) (background dark))
1674      (:background "yellow"))
1675     (t (:inverse-video t)))
1676   "Basic face for displaying the secondary selection."
1677   :group 'basic-faces)
1678
1679
1680 (defface fixed-pitch '((t (:family "courier")))
1681   "The basic fixed-pitch face."
1682   :group 'basic-faces)
1683
1684
1685 (defface variable-pitch '((t (:family "helv")))
1686   "The basic variable-pitch face."
1687   :group 'basic-faces)
1688
1689
1690 (defface trailing-whitespace
1691   '((((class color) (background light))
1692      (:background "red"))
1693     (((class color) (background dark))
1694      (:background "red"))
1695     (t (:inverse-video t)))
1696   "Basic face for highlighting trailing whitespace."
1697   :version "21.1"
1698   :group 'font-lock                     ; like `show-trailing-whitespace'
1699   :group 'basic-faces)
1700
1701
1702 \f
1703 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1704 ;;; Manipulating font names.
1705 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
1706
1707 ;; This is here for compatibilty with Emacs 20.2.  For example,
1708 ;; international/fontset.el uses x-resolve-font-name.  The following
1709 ;; functions are not used in the face implementation itself.
1710
1711 (defvar x-font-regexp nil)
1712 (defvar x-font-regexp-head nil)
1713 (defvar x-font-regexp-weight nil)
1714 (defvar x-font-regexp-slant nil)
1715
1716 (defconst x-font-regexp-weight-subnum 1)
1717 (defconst x-font-regexp-slant-subnum 2)
1718 (defconst x-font-regexp-swidth-subnum 3)
1719 (defconst x-font-regexp-adstyle-subnum 4)
1720
1721 ;;; Regexps matching font names in "Host Portable Character Representation."
1722 ;;;
1723 (let ((-                "[-?]")
1724       (foundry          "[^-]+")
1725       (family           "[^-]+")
1726       (weight           "\\(bold\\|demibold\\|medium\\)")               ; 1
1727 ;     (weight\?         "\\(\\*\\|bold\\|demibold\\|medium\\|\\)")      ; 1
1728       (weight\?         "\\([^-]*\\)")                                  ; 1
1729       (slant            "\\([ior]\\)")                                  ; 2
1730 ;     (slant\?          "\\([ior?*]?\\)")                               ; 2
1731       (slant\?          "\\([^-]?\\)")                                  ; 2
1732 ;     (swidth           "\\(\\*\\|normal\\|semicondensed\\|\\)")        ; 3
1733       (swidth           "\\([^-]*\\)")                                  ; 3
1734 ;     (adstyle          "\\(\\*\\|sans\\|\\)")                          ; 4
1735       (adstyle          "\\([^-]*\\)")                                  ; 4
1736       (pixelsize        "[0-9]+")
1737       (pointsize        "[0-9][0-9]+")
1738       (resx             "[0-9][0-9]+")
1739       (resy             "[0-9][0-9]+")
1740       (spacing          "[cmp?*]")
1741       (avgwidth         "[0-9]+")
1742       (registry         "[^-]+")
1743       (encoding         "[^-]+")
1744       )
1745   (setq x-font-regexp
1746         (concat "\\`\\*?[-?*]"
1747                 foundry - family - weight\? - slant\? - swidth - adstyle -
1748                 pixelsize - pointsize - resx - resy - spacing - avgwidth -
1749                 registry - encoding "\\*?\\'"
1750                 ))
1751   (setq x-font-regexp-head
1752         (concat "\\`[-?*]" foundry - family - weight\? - slant\?
1753                 "\\([-*?]\\|\\'\\)"))
1754   (setq x-font-regexp-slant (concat - slant -))
1755   (setq x-font-regexp-weight (concat - weight -))
1756   nil)
1757
1758
1759 (defun x-resolve-font-name (pattern &optional face frame)
1760   "Return a font name matching PATTERN.
1761 All wildcards in PATTERN are instantiated.
1762 If PATTERN is nil, return the name of the frame's base font, which never
1763 contains wildcards.
1764 Given optional arguments FACE and FRAME, return a font which is
1765 also the same size as FACE on FRAME, or fail."
1766   (or (symbolp face)
1767       (setq face (face-name face)))
1768   (and (eq frame t)
1769        (setq frame nil))
1770   (if pattern
1771       ;; Note that x-list-fonts has code to handle a face with nil as its font.
1772       (let ((fonts (x-list-fonts pattern face frame 1)))
1773         (or fonts
1774             (if face
1775                 (if (string-match "\\*" pattern)
1776                     (if (null (face-font face))
1777                         (error "No matching fonts are the same height as the frame default font")
1778                       (error "No matching fonts are the same height as face `%s'" face))
1779                   (if (null (face-font face))
1780                       (error "Height of font `%s' doesn't match the frame default font"
1781                              pattern)
1782                     (error "Height of font `%s' doesn't match face `%s'"
1783                            pattern face)))
1784               (error "No fonts match `%s'" pattern)))
1785         (car fonts))
1786     (cdr (assq 'font (frame-parameters (selected-frame))))))
1787
1788
1789 (defun x-frob-font-weight (font which)
1790   (let ((case-fold-search t))
1791     (cond ((string-match x-font-regexp font)
1792            (concat (substring font 0
1793                               (match-beginning x-font-regexp-weight-subnum))
1794                    which
1795                    (substring font (match-end x-font-regexp-weight-subnum)
1796                               (match-beginning x-font-regexp-adstyle-subnum))
1797                    ;; Replace the ADD_STYLE_NAME field with *
1798                    ;; because the info in it may not be the same
1799                    ;; for related fonts.
1800                    "*"
1801                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1802           ((string-match x-font-regexp-head font)
1803            (concat (substring font 0 (match-beginning 1)) which
1804                    (substring font (match-end 1))))
1805           ((string-match x-font-regexp-weight font)
1806            (concat (substring font 0 (match-beginning 1)) which
1807                    (substring font (match-end 1)))))))
1808 (make-obsolete 'x-frob-font-weight 'make-face-... "21.1")
1809
1810 (defun x-frob-font-slant (font which)
1811   (let ((case-fold-search t))
1812     (cond ((string-match x-font-regexp font)
1813            (concat (substring font 0
1814                               (match-beginning x-font-regexp-slant-subnum))
1815                    which
1816                    (substring font (match-end x-font-regexp-slant-subnum)
1817                               (match-beginning x-font-regexp-adstyle-subnum))
1818                    ;; Replace the ADD_STYLE_NAME field with *
1819                    ;; because the info in it may not be the same
1820                    ;; for related fonts.
1821                    "*"
1822                    (substring font (match-end x-font-regexp-adstyle-subnum))))
1823           ((string-match x-font-regexp-head font)
1824            (concat (substring font 0 (match-beginning 2)) which
1825                    (substring font (match-end 2))))
1826           ((string-match x-font-regexp-slant font)
1827            (concat (substring font 0 (match-beginning 1)) which
1828                    (substring font (match-end 1)))))))
1829 (make-obsolete 'x-frob-font-slant 'make-face-... "21.1")
1830
1831 (defun x-make-font-bold (font)
1832   "Given an X font specification, make a bold version of it.
1833 If that can't be done, return nil."
1834   (x-frob-font-weight font "bold"))
1835 (make-obsolete 'x-make-font-bold 'make-face-bold "21.1")
1836
1837 (defun x-make-font-demibold (font)
1838   "Given an X font specification, make a demibold version of it.
1839 If that can't be done, return nil."
1840   (x-frob-font-weight font "demibold"))
1841 (make-obsolete 'x-make-font-demibold 'make-face-bold "21.1")
1842
1843 (defun x-make-font-unbold (font)
1844   "Given an X font specification, make a non-bold version of it.
1845 If that can't be done, return nil."
1846   (x-frob-font-weight font "medium"))
1847 (make-obsolete 'x-make-font-unbold 'make-face-unbold "21.1")
1848
1849 (defun x-make-font-italic (font)
1850   "Given an X font specification, make an italic version of it.
1851 If that can't be done, return nil."
1852   (x-frob-font-slant font "i"))
1853 (make-obsolete 'x-make-font-italic 'make-face-italic "21.1")
1854
1855 (defun x-make-font-oblique (font) ; you say tomayto...
1856   "Given an X font specification, make an oblique version of it.
1857 If that can't be done, return nil."
1858   (x-frob-font-slant font "o"))
1859 (make-obsolete 'x-make-font-oblique 'make-face-italic "21.1")
1860
1861 (defun x-make-font-unitalic (font)
1862   "Given an X font specification, make a non-italic version of it.
1863 If that can't be done, return nil."
1864   (x-frob-font-slant font "r"))
1865 (make-obsolete 'x-make-font-unitalic 'make-face-unitalic "21.1")
1866
1867 (defun x-make-font-bold-italic (font)
1868   "Given an X font specification, make a bold and italic version of it.
1869 If that can't be done, return nil."
1870   (and (setq font (x-make-font-bold font))
1871        (x-make-font-italic font)))
1872 (make-obsolete 'x-make-font-bold-italic 'make-face-bold-italic "21.1")
1873
1874 (provide 'faces)
1875
1876 ;;; faces.el ends here