code.delx.au - gnu-emacs/blob - configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl
   6 dnl  Copyright (C) 1994, 1995, 1996, 1999, 2000, 2001, 2002, 2003, 2004, 2005
   7 dnl  Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software; you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation; either version 2, or (at your option)
  14 dnl  any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs; see the file COPYING.  If not, write to the
  23 dnl  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 dnl  Boston, MA 02111-1307, USA.
  25
  26 AC_PREREQ(2.54)dnl
  27 AC_INIT(src/lisp.h)
  28 AC_CONFIG_HEADER(src/config.h:src/config.in)
  29
  30 dnl Support for --program-prefix, --program-suffix and
  31 dnl --program-transform-name options
  32 AC_ARG_PROGRAM
  33
  34 lispdir='${datadir}/emacs/${version}/lisp'
  35 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  36 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
  37 lisppath='${locallisppath}:${lispdir}'
  38 etcdir='${datadir}/emacs/${version}/etc'
  39 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  40 docdir='${datadir}/emacs/${version}/etc'
  41 gamedir='${localstatedir}/games/emacs'
  42
  43 gameuser=games
  44
  45 AC_ARG_WITH(gcc,
  46 [  --without-gcc           don't use GCC to compile Emacs if GCC is found])
  47 AC_ARG_WITH(pop,
  48 [  --without-pop           don't support POP mail retrieval with movemail],
  49 [if test "$withval" = yes; then
  50    AC_DEFINE(MAIL_USE_POP)
  51 else :
  52 fi],
  53 AC_DEFINE(MAIL_USE_POP))
  54 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  55 AC_ARG_WITH(kerberos,
  56 [  --with-kerberos         support Kerberos-authenticated POP],
  57 [AC_DEFINE(KERBEROS)])
  58 AH_TEMPLATE(KERBEROS,
  59             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  60 AC_ARG_WITH(kerberos5,
  61 [  --with-kerberos5        support Kerberos version 5 authenticated POP],
  62 [if test "${with_kerberos5+set}" = set; then
  63   if test "${with_kerberos+set}" != set; then
  64     with_kerberos=yes
  65     AC_DEFINE(KERBEROS)
  66   fi
  67 fi
  68 AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])])
  69 AC_ARG_WITH(hesiod,
  70 [  --with-hesiod           support Hesiod to get the POP server host],
  71 [AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])])
  72
  73 AC_ARG_WITH(sound,
  74 [  --without-sound         don't compile with sound support])
  75
  76 dnl This should be the last --with option, because --with-x is
  77 dnl added later on when we find the path of X, and it's best to
  78 dnl keep them together visually.
  79 AC_ARG_WITH(x-toolkit,
  80 [  --with-x-toolkit=KIT    use an X toolkit
  81                               (KIT = yes/lucid/athena/motif/gtk/no)],
  82 [         case "${withval}" in
  83             y | ye | yes )      val=athena ;;
  84             n | no )            val=no  ;;
  85             l | lu | luc | luci | lucid )       val=lucid ;;
  86             a | at | ath | athe | athen | athena )      val=athena ;;
  87             m | mo | mot | moti | motif )       val=motif ;;
  88             g | gt | gtk  )     val=gtk ;;
  89 dnl These don't currently work.
  90 dnl         o | op | ope | open | open- | open-l | open-lo \
  91 dnl             | open-loo | open-look )        val=open-look ;;
  92             * )
  93 dnl AC_MSG_ERROR([the `--with-x-toolkit' option is supposed to have a value
  94 dnl which is `yes', `no', `lucid', `athena', `motif' or `open-look'.])
  95 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid\;
  96 this option's value should be `yes', `no', `lucid', `athena', `motif' or `gtk'.
  97 Currently, `yes', `athena' and `lucid' are synonyms.])
  98             ;;
  99           esac
 100           with_x_toolkit=$val
 101 ])
 102 AC_ARG_WITH(xpm,
 103 [  --with-xpm              use -lXpm for displaying XPM images])
 104 AC_ARG_WITH(jpeg,
 105 [  --with-jpeg             use -ljpeg for displaying JPEG images])
 106 AC_ARG_WITH(tiff,
 107 [  --with-tiff             use -ltiff for displaying TIFF images])
 108 AC_ARG_WITH(gif,
 109 [  --with-gif              use -lungif for displaying GIF images])
 110 AC_ARG_WITH(png,
 111 [  --with-png              use -lpng for displaying PNG images])
 112 AC_ARG_WITH(gtk,
 113 [  --with-gtk              use GTK (same as --with-x-toolkit=gtk)])
 114 AC_ARG_WITH(pkg-config-prog,
 115 [  --with-pkg-config-prog  Path to pkg-config to use for finding GTK])
 116 AC_ARG_WITH(toolkit-scroll-bars,
 117 [  --without-toolkit-scroll-bars
 118                           don't use Motif or Xaw3d scroll bars])
 119 AC_ARG_WITH(xim,
 120 [  --without-xim           don't use X11 XIM])
 121 AC_ARG_WITH(carbon,
 122 [  --without-carbon        don't use Carbon GUI on Mac OS X])
 123 AC_ARG_ENABLE(carbon-app,
 124 [[  --enable-carbon-app[=DIR]  [DIR=/Application]
 125                           specify install directory for Emacs.app on Mac OS X]],
 126 [ carbon_appdir_x=${enableval}])
 127
 128 AC_ARG_ENABLE(asserts,
 129 [  --enable-asserts        compile code with asserts enabled],
 130       USE_XASSERTS=$enableval,
 131       USE_XASSERTS=no)
 132
 133 AC_ARG_ENABLE(maintainer-mode,
 134 [  --enable-maintainer-mode enable make rules and dependencies not useful
 135                           (and sometimes confusing) to the casual installer],
 136       USE_MAINTAINER_MODE=$enableval,
 137       USE_MAINTAINER_MODE=no)
 138 if test $USE_MAINTAINER_MODE = yes; then
 139   MAINT=
 140 else
 141   MAINT=#
 142 fi
 143 AC_SUBST(MAINT)
 144
 145 #### Make srcdir absolute, if it isn't already.  It's important to
 146 #### avoid running the path through pwd unnecessarily, since pwd can
 147 #### give you automounter prefixes, which can go away.  We do all this
 148 #### so Emacs can find its files when run uninstalled.
 149 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 150 unset CDPATH
 151 case "${srcdir}" in
 152   /* ) ;;
 153   . )
 154     ## We may be able to use the $PWD environment variable to make this
 155     ## absolute.  But sometimes PWD is inaccurate.
 156     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 157     ## but that tested only for a well-formed and valid PWD,
 158     ## it did not object when PWD was well-formed and valid but just wrong.
 159     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 160     then
 161       srcdir="$PWD"
 162     else
 163       srcdir="`(cd ${srcdir}; pwd)`"
 164     fi
 165   ;;
 166   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 167 esac
 168
 169 #### Check if the source directory already has a configured system in it.
 170 if test `pwd` != `(cd ${srcdir} && pwd)` \
 171    && test -f "${srcdir}/src/config.h" ; then
 172   AC_MSG_WARN([[The directory tree `${srcdir}' is being used
 173    as a build directory right now; it has been configured in its own
 174    right.  To configure in another directory as well, you MUST
 175    use GNU make.  If you do not have GNU make, then you must
 176    now do `make distclean' in ${srcdir},
 177    and then run $0 again.]])
 178 fi
 179
 180 #### Given the configuration name, set machfile and opsysfile to the
 181 #### names of the m/*.h and s/*.h files we should use.
 182
 183 ### Canonicalize the configuration name.
 184
 185 AC_CANONICAL_HOST
 186 canonical=$host
 187 configuration=${host_alias-$host}
 188
 189 dnl This used to use changequote, but, apart from `changequote is evil'
 190 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 191 dnl the great gob of text.  Thus it's not processed for possible expansion.
 192 dnl Just make sure the brackets remain balanced.
 193 dnl
 194 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 195 dnl indicated by comments.
 196 dnl quotation begins
 197 [
 198
 199 ### If you add support for a new configuration, add code to this
 200 ### switch statement to recognize your configuration name and select
 201 ### the appropriate operating system and machine description files.
 202
 203 ### You would hope that you could choose an m/*.h file pretty much
 204 ### based on the machine portion of the configuration name, and an s-
 205 ### file based on the operating system portion.  However, it turns out
 206 ### that each m/*.h file is pretty manufacturer-specific - for
 207 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
 208 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
 209 ### machines.  So we basically have to have a special case for each
 210 ### configuration name.
 211 ###
 212 ### As far as handling version numbers on operating systems is
 213 ### concerned, make sure things will fail in a fixable way.  If
 214 ### /etc/MACHINES doesn't say anything about version numbers, be
 215 ### prepared to handle anything reasonably.  If version numbers
 216 ### matter, be sure /etc/MACHINES says something about it.
 217 ###
 218 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 219 ### "System V Release 4"; he writes, "The old convention encouraged
 220 ### confusion between `system' and `release' levels'."
 221
 222 machine='' opsys='' unported=no
 223 case "${canonical}" in
 224
 225   ## FreeBSD ports
 226   *-*-freebsd* )
 227     opsys=freebsd
 228     case "${canonical}" in
 229       alpha*-*-freebsd*)        machine=alpha ;;
 230       i[3456]86-*-freebsd*)     machine=intel386 ;;
 231     esac
 232   ;;
 233
 234   ## NetBSD ports
 235   *-*-netbsd* )
 236     opsys=netbsd
 237     if test -f /usr/lib/crti.o; then]
 238 dnl The close and open brackets here are because this section is quoted --
 239 dnl see the `changequote' comment above.
 240       AC_DEFINE(HAVE_CRTIN, [], [Define to 1 if you have /usr/lib/crti.o.])
 241 [   fi
 242
 243     case "${canonical}" in
 244       alpha*-*-netbsd*) machine=alpha ;;
 245       i[3456]86-*-netbsd*) machine=intel386 ;;
 246       m68k-*-netbsd*)
 247                         # This is somewhat bogus.
 248                         machine=hp9000s300 ;;
 249       powerpc-apple-netbsd*) machine=macppc ;;
 250       mips-*-netbsd*)   machine=pmax ;;
 251       mipsel-*-netbsd*) machine=pmax ;;
 252       mipseb-*-netbsd*) machine=pmax ;;
 253       ns32k-*-netbsd*)  machine=ns32000 ;;
 254       powerpc-*-netbsd*) machine=macppc ;;
 255       sparc*-*-netbsd*) machine=sparc ;;
 256       vax-*-netbsd*)    machine=vax ;;
 257       arm-*-netbsd*)    machine=arm ;;
 258     esac
 259   ;;
 260
 261   ## OpenBSD ports
 262   *-*-openbsd* )
 263     opsys=openbsd
 264     case "${canonical}" in
 265       alpha*-*-openbsd*)        machine=alpha ;;
 266       i386-*-openbsd*)  machine=intel386 ;;
 267       m68k-*-openbsd*)  machine=hp9000s300 ;;
 268       mipsel-*-openbsd*) machine=pmax ;;
 269       ns32k-*-openbsd*) machine=ns32000 ;;
 270       sparc-*-openbsd*) machine=sparc ;;
 271       vax-*-openbsd*)   machine=vax ;;
 272     esac
 273   ;;
 274
 275   ## Acorn RISCiX:
 276   arm-acorn-riscix1.1* )
 277     machine=acorn opsys=riscix1-1
 278   ;;
 279   arm-acorn-riscix1.2* | arm-acorn-riscix )
 280     ## This name is riscix12 instead of riscix1.2
 281     ## to avoid a file name conflict on MSDOS.
 282     machine=acorn opsys=riscix12
 283   ;;
 284
 285   ## BSDI ports
 286   *-*-bsdi* )
 287     opsys=bsdi
 288     case "${canonical}" in
 289       i[345]86-*-bsdi*) machine=intel386 ;;
 290       sparc-*-bsdi*)  machine=sparc ;;
 291       powerpc-*-bsdi*)  machine=macppc ;;
 292     esac
 293     case "${canonical}" in
 294       *-*-bsd386* | *-*-bsdi1* )        opsys=bsd386 ;;
 295       *-*-bsdi2.0* )            opsys=bsdos2 ;;
 296       *-*-bsdi2* )              opsys=bsdos2-1 ;;
 297       *-*-bsdi3* )              opsys=bsdos3 ;;
 298       *-*-bsdi[45]* )           opsys=bsdos4 ;;
 299     esac
 300   ;;
 301
 302   ## Alliant machines
 303   ## Strictly speaking, we need the version of the alliant operating
 304   ## system to choose the right machine file, but currently the
 305   ## configuration name doesn't tell us enough to choose the right
 306   ## one; we need to give alliants their own operating system name to
 307   ## do this right.  When someone cares, they can help us.
 308   fx80-alliant-* )
 309     machine=alliant4 opsys=bsd4-2
 310   ;;
 311   i860-alliant-* )
 312     machine=alliant-2800 opsys=bsd4-3
 313   ;;
 314
 315   ## Alpha (DEC) machines.
 316   alpha*-dec-osf* )
 317     machine=alpha opsys=osf1
 318     # This is needed to find X11R6.1 libraries for certain tests.
 319     NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 320     GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
 321     # NON_GNU_CPP is necessary on 5.0 to avoid mangling src/Makefile
 322     # due to non-traditional preprocessing with the current compiler
 323     # defaults.  OSF 4 can also have that compiler version, and there
 324     # seems always to have been a usable /usr/bin/cpp.
 325     NON_GNU_CPP=/usr/bin/cpp
 326     case "${canonical}" in
 327     alpha*-dec-osf[5-9]*)
 328       opsys=osf5-0 ;;
 329     esac
 330   ;;
 331
 332   alpha*-*-linux-gnu* )
 333     machine=alpha opsys=gnu-linux
 334   ;;
 335
 336   arm*-*-linux-gnu* )
 337     machine=arm opsys=gnu-linux
 338   ;;
 339
 340   ## Altos 3068
 341   m68*-altos-sysv* )
 342     machine=altos opsys=usg5-2
 343   ;;
 344
 345   ## Amdahl UTS
 346   580-amdahl-sysv* )
 347     machine=amdahl opsys=usg5-2-2
 348   ;;
 349
 350   ## Apollo, Domain/OS
 351   m68*-apollo-* )
 352     machine=apollo opsys=bsd4-3
 353   ;;
 354
 355   ## AT&T 3b2, 3b5, 3b15, 3b20
 356   we32k-att-sysv* )
 357     machine=att3b opsys=usg5-2-2
 358   ;;
 359
 360   ## AT&T 3b1 - The Mighty Unix PC!
 361   m68*-att-sysv* )
 362     machine=7300 opsys=usg5-2-2
 363   ;;
 364
 365   ## Bull dpx20
 366   rs6000-bull-bosx* )
 367     machine=ibmrs6000 opsys=aix3-2
 368   ;;
 369
 370   ## Bull dpx2
 371   m68*-bull-sysv3* )
 372     machine=dpx2 opsys=usg5-3
 373   ;;
 374
 375   ## Bull sps7
 376   m68*-bull-sysv2* )
 377     machine=sps7 opsys=usg5-2
 378   ;;
 379
 380   ## CCI 5/32, 6/32 -- see "Tahoe".
 381
 382   ## Celerity
 383   ## I don't know what configuration name to use for this; config.sub
 384   ## doesn't seem to know anything about it.  Hey, Celerity users, get
 385   ## in touch with us!
 386   celerity-celerity-bsd* )
 387     machine=celerity opsys=bsd4-2
 388   ;;
 389
 390   ## Clipper
 391   ## What operating systems does this chip run that Emacs has been
 392   ## tested on?
 393   clipper-* )
 394     machine=clipper
 395     ## We'll use the catch-all code at the bottom to guess the
 396     ## operating system.
 397   ;;
 398
 399   ## Compaq Nonstop
 400   mips-compaq-nonstopux* )
 401     machine=nonstopux opsys=nonstopux
 402     ;;
 403
 404   ## Convex
 405   *-convex-bsd* | *-convex-convexos* )
 406     machine=convex opsys=bsd4-3
 407     ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
 408     NON_GNU_CPP="cc -E -P"
 409   ;;
 410
 411   ## Cubix QBx/386
 412   i[3456]86-cubix-sysv* )
 413     machine=intel386 opsys=usg5-3
 414   ;;
 415
 416   ## Cydra 5
 417   cydra*-cydrome-sysv* )
 418     machine=cydra5 opsys=usg5-3
 419   ;;
 420
 421   ## Data General AViiON Machines
 422   ## DG changed naming conventions with the release of 5.4.4.10, they
 423   ## dropped the initial 5.4 but left the intervening R.  Because of the
 424   ## R this shouldn't conflict with older versions of the OS (which I
 425   ## think were named like dgux4.*). In addition, DG new AViiONs series
 426   ## uses either Motorola M88k or Intel Pentium CPUs.
 427   m88k-dg-dguxR4.* | m88k-dg-dgux4* )
 428     machine=aviion opsys=dgux4
 429   ;;
 430   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
 431     ## This name is dgux5-4-3 instead of dgux5-4r3
 432     ## to avoid a file name conflict on MSDOS.
 433     machine=aviion opsys=dgux5-4-3
 434   ;;
 435   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
 436     machine=aviion opsys=dgux5-4r2
 437   ;;
 438   m88k-dg-dgux* )
 439     machine=aviion opsys=dgux
 440   ;;
 441
 442   ## Data General AViiON Intel (x86) Machines
 443   ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
 444   ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
 445   i[345]86-dg-dguxR4* )
 446     machine=aviion-intel opsys=dgux4
 447   ;;
 448
 449   ## DECstations
 450   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 451     machine=pmax opsys=bsd4-2
 452   ;;
 453   mips-dec-ultrix4.[12]* | mips-dec-bsd* )
 454     machine=pmax opsys=bsd4-3
 455   ;;
 456   mips-dec-ultrix* )
 457     machine=pmax opsys=ultrix4-3
 458   ;;
 459   mips-dec-osf* )
 460     machine=pmax opsys=osf1
 461   ;;
 462   mips-dec-mach_bsd4.3* )
 463     machine=pmax opsys=mach-bsd4-3
 464   ;;
 465
 466   ## Motorola Delta machines
 467   m68k-motorola-sysv* | m68000-motorola-sysv* )
 468     machine=delta opsys=usg5-3
 469     if test -z "`type gnucc | grep 'not found'`"
 470     then
 471       if test -s /etc/167config
 472       then CC="gnucc -m68040"
 473       else CC="gnucc -m68881"
 474       fi
 475     else
 476       if test -z "`type gcc | grep 'not found'`"
 477       then CC=gcc
 478       else CC=cc
 479       fi
 480     fi
 481   ;;
 482   m88k-motorola-sysv4* )
 483     # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
 484     # needs POSIX_SIGNALS and therefore needs usg5-4-2.
 485     # I hope there are not other 4.0 versions for this machine
 486     # which really need usg5-4 instead.
 487     machine=delta88k opsys=usg5-4-2
 488   ;;
 489   m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
 490     machine=delta88k opsys=usg5-3
 491   ;;
 492
 493   ## Dual machines
 494   m68*-dual-sysv* )
 495     machine=dual opsys=usg5-2
 496   ;;
 497   m68*-dual-uniplus* )
 498     machine=dual opsys=unipl5-2
 499   ;;
 500
 501   ## Elxsi 6400
 502   elxsi-elxsi-sysv* )
 503     machine=elxsi opsys=usg5-2
 504   ;;
 505
 506   ## Encore machines
 507   ns16k-encore-bsd* )
 508     machine=ns16000 opsys=umax
 509   ;;
 510
 511   ## The GEC 63 - apparently, this port isn't really finished yet.
 512   #  I'm sure we finished off the last of the machines, though.  -- fx
 513
 514   ## Gould Power Node and NP1
 515   pn-gould-bsd4.2* )
 516     machine=gould opsys=bsd4-2
 517   ;;
 518   pn-gould-bsd4.3* )
 519     machine=gould opsys=bsd4-3
 520   ;;
 521   np1-gould-bsd* )
 522     machine=gould-np1 opsys=bsd4-3
 523   ;;
 524
 525   ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
 526   ## as far as Emacs is concerned).
 527   m88k-harris-cxux* )
 528     # Build needs to be different on 7.0 and later releases
 529     case "`uname -r`" in
 530        [56].[0-9] ) machine=nh4000 opsys=cxux ;;
 531        [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
 532     esac
 533     NON_GNU_CPP="/lib/cpp"
 534   ;;
 535   ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
 536   m68k-harris-cxux* )
 537     machine=nh3000 opsys=cxux
 538   ;;
 539   ## Harris power pc NightHawk running Power UNIX (Series 6000)
 540   powerpc-harris-powerunix )
 541     machine=nh6000 opsys=powerunix
 542     NON_GNU_CPP="cc -Xo -E -P"
 543   ;;
 544   ## SR2001/SR2201 running HI-UX/MPP
 545   hppa1.1-hitachi-hiuxmpp* )
 546     machine=sr2k opsys=hiuxmpp
 547   ;;
 548   hppa1.1-hitachi-hiuxwe2* )
 549     machine=sr2k opsys=hiuxwe2
 550   ;;
 551   ## Honeywell XPS100
 552   xps*-honeywell-sysv* )
 553     machine=xps100 opsys=usg5-2
 554   ;;
 555
 556   ## HP 9000 series 200 or 300
 557   m68*-hp-bsd* )
 558     machine=hp9000s300 opsys=bsd4-3
 559   ;;
 560   ## HP/UX 7, 8, 9, and 10 are supported on these machines.
 561   m68*-hp-hpux* )
 562     case "`uname -r`" in
 563       ## Someone's system reports A.B8.05 for this.
 564       ## I wonder what other possibilities there are.
 565       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 566       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 567       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 568       *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
 569       *) machine=hp9000s300 opsys=hpux ;;
 570     esac
 571   ;;
 572
 573   ## HP 9000 series 700 and 800, running HP/UX
 574   hppa*-hp-hpux7* )
 575     machine=hp800 opsys=hpux
 576   ;;
 577   hppa*-hp-hpux8* )
 578     machine=hp800 opsys=hpux8
 579   ;;
 580   hppa*-hp-hpux9shr* )
 581     machine=hp800 opsys=hpux9shr
 582   ;;
 583   hppa*-hp-hpux9* )
 584     machine=hp800 opsys=hpux9
 585   ;;
 586   hppa*-hp-hpux10.2* )
 587     machine=hp800 opsys=hpux10-20
 588   ;;
 589   hppa*-hp-hpux10* )
 590     machine=hp800 opsys=hpux10
 591   ;;
 592   hppa*-hp-hpux1[1-9]* )
 593     machine=hp800 opsys=hpux11
 594   ;;
 595
 596   hppa*-*-linux-gnu* )
 597     machine=hp800 opsys=gnu-linux
 598   ;;
 599
 600   ## HP 9000 series 700 and 800, running HP/UX
 601   hppa*-hp-hpux* )
 602     ## Cross-compilation?  Nah!
 603     case "`uname -r`" in
 604       ## Someone's system reports A.B8.05 for this.
 605       ## I wonder what other possibilities there are.
 606       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 607       *.08.* ) machine=hp800 opsys=hpux8 ;;
 608       *.09.* ) machine=hp800 opsys=hpux9 ;;
 609       *) machine=hp800 opsys=hpux10 ;;
 610     esac
 611   ;;
 612   hppa*-*-nextstep* )
 613     machine=hp800 opsys=nextstep
 614   ;;
 615
 616   ## Orion machines
 617   orion-orion-bsd* )
 618     machine=orion opsys=bsd4-2
 619   ;;
 620   clipper-orion-bsd* )
 621     machine=orion105 opsys=bsd4-2
 622   ;;
 623
 624   ## IBM machines
 625   i[3456]86-ibm-aix1.1* )
 626     machine=ibmps2-aix opsys=usg5-2-2
 627   ;;
 628   i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
 629     machine=ibmps2-aix opsys=usg5-3
 630   ;;
 631   i370-ibm-aix*)
 632     machine=ibm370aix opsys=usg5-3
 633   ;;
 634   s390-*-linux-gnu* )
 635     machine=ibms390 opsys=gnu-linux
 636   ;;
 637   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 638     machine=ibmrs6000 opsys=aix3-1
 639   ;;
 640   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 641     machine=ibmrs6000 opsys=aix3-2-5
 642   ;;
 643   rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1*  )
 644     machine=ibmrs6000 opsys=aix4-1
 645   ;;
 646   rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2*  )
 647     machine=ibmrs6000 opsys=aix4-2
 648   ;;
 649   rs6000-ibm-aix5* | powerpc-ibm-aix5*  )
 650     machine=ibmrs6000 opsys=aix4-2
 651   ;;
 652   rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0*  )
 653     machine=ibmrs6000 opsys=aix4
 654   ;;
 655   rs6000-ibm-aix4* | powerpc-ibm-aix4*  )
 656     machine=ibmrs6000 opsys=aix4-1
 657   ;;
 658   rs6000-ibm-aix* | powerpc-ibm-aix* )
 659     machine=ibmrs6000 opsys=aix3-2
 660   ;;
 661   romp-ibm-bsd4.3* )
 662     machine=ibmrt opsys=bsd4-3
 663   ;;
 664   romp-ibm-bsd4.2* )
 665     machine=ibmrt opsys=bsd4-2
 666   ;;
 667   romp-ibm-aos4.3* )
 668     machine=ibmrt opsys=bsd4-3
 669   ;;
 670   romp-ibm-aos4.2* )
 671     machine=ibmrt opsys=bsd4-2
 672   ;;
 673   romp-ibm-aos* )
 674     machine=ibmrt opsys=bsd4-3
 675   ;;
 676   romp-ibm-bsd* )
 677     machine=ibmrt opsys=bsd4-3
 678   ;;
 679   romp-ibm-aix* )
 680     machine=ibmrt-aix opsys=usg5-2-2
 681   ;;
 682
 683   ## Integrated Solutions `Optimum V'
 684   m68*-isi-bsd4.2* )
 685     machine=isi-ov opsys=bsd4-2
 686   ;;
 687   m68*-isi-bsd4.3* )
 688     machine=isi-ov opsys=bsd4-3
 689   ;;
 690
 691   ## Intel 386 machines where we do care about the manufacturer
 692   i[3456]86-intsys-sysv* )
 693     machine=is386 opsys=usg5-2-2
 694   ;;
 695
 696   ## Prime EXL
 697   i[3456]86-prime-sysv* )
 698     machine=i386 opsys=usg5-3
 699   ;;
 700
 701   ## Sequent Symmetry running Dynix
 702   i[3456]86-sequent-bsd* )
 703     machine=symmetry opsys=bsd4-3
 704   ;;
 705
 706   ## Sequent Symmetry running ptx 4, which is a modified SVR4.
 707   i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
 708     machine=sequent-ptx opsys=ptx4
 709     NON_GNU_CPP=/lib/cpp
 710   ;;
 711
 712   ## Sequent Symmetry running DYNIX/ptx
 713   ## Use the old cpp rather than the newer ANSI one.
 714   i[3456]86-sequent-ptx* )
 715     machine=sequent-ptx opsys=ptx
 716     NON_GNU_CPP="/lib/cpp"
 717   ;;
 718
 719   ## ncr machine running svr4.3.
 720   i[3456]86-ncr-sysv4.3 )
 721     machine=ncr386 opsys=usg5-4-3
 722   ;;
 723
 724   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 725   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 726   i[3456]86-ncr-sysv* )
 727     machine=ncr386 opsys=usg5-4-2
 728   ;;
 729
 730   ## Intel Paragon OSF/1
 731   i860-intel-osf1* )
 732     machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
 733   ;;
 734
 735   ## Intel 860
 736   i860-*-sysv4* )
 737     machine=i860 opsys=usg5-4
 738     NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
 739     NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
 740   ;;
 741
 742   ## Macintosh PowerPC
 743   powerpc*-*-linux-gnu* )
 744     machine=macppc opsys=gnu-linux
 745   ;;
 746
 747   ## Masscomp machines
 748   m68*-masscomp-rtu* )
 749     machine=masscomp opsys=rtu
 750   ;;
 751
 752   ## Megatest machines
 753   m68*-megatest-bsd* )
 754     machine=mega68 opsys=bsd4-2
 755   ;;
 756
 757   ## Workstations sold by MIPS
 758   ## This is not necessarily all workstations using the MIPS processor -
 759   ## Irises are produced by SGI, and DECstations by DEC.
 760
 761   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 762   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 763   ## it gives for choosing between the alternatives seems to be "Use
 764   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 765   ## the BSD world."  I'll assume that these are instructions for
 766   ## handling two odd situations, and that every other situation
 767   ## should use mips.h and usg5-2-2, they being listed first.
 768   mips-mips-usg* )
 769     machine=mips4
 770     ## Fall through to the general code at the bottom to decide on the OS.
 771   ;;
 772   mips-mips-riscos4* )
 773     machine=mips4 opsys=bsd4-3
 774     NON_GNU_CC="cc -systype bsd43"
 775     NON_GNU_CPP="cc -systype bsd43 -E"
 776   ;;
 777   mips-mips-riscos5* )
 778     machine=mips4 opsys=riscos5
 779     NON_GNU_CC="cc -systype bsd43"
 780     NON_GNU_CPP="cc -systype bsd43 -E"
 781   ;;
 782   mips-mips-bsd* )
 783     machine=mips opsys=bsd4-3
 784   ;;
 785   mips-mips-* )
 786     machine=mips opsys=usg5-2-2
 787   ;;
 788
 789   ## NeXT
 790   m68*-next-* | m68k-*-nextstep* )
 791     machine=m68k opsys=nextstep
 792   ;;
 793
 794   ## The complete machine from National Semiconductor
 795   ns32k-ns-genix* )
 796     machine=ns32000 opsys=usg5-2
 797   ;;
 798
 799   ## NCR machines
 800   m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
 801     machine=tower32 opsys=usg5-2-2
 802   ;;
 803   m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
 804     machine=tower32v3 opsys=usg5-3
 805   ;;
 806
 807   ## NEC EWS4800
 808   mips-nec-sysv4*)
 809   machine=ews4800 opsys=ux4800
 810   ;;
 811
 812   ## Nixdorf Targon 31
 813   m68*-nixdorf-sysv* )
 814     machine=targon31 opsys=usg5-2-2
 815   ;;
 816
 817   ## Nu (TI or LMI)
 818   m68*-nu-sysv* )
 819     machine=nu opsys=usg5-2
 820   ;;
 821
 822   ## Plexus
 823   m68*-plexus-sysv* )
 824     machine=plexus opsys=usg5-2
 825   ;;
 826
 827   ## Pyramid machines
 828   ## I don't really have any idea what sort of processor the Pyramid has,
 829   ## so I'm assuming it is its own architecture.
 830   pyramid-pyramid-bsd* )
 831     machine=pyramid opsys=bsd4-2
 832   ;;
 833
 834   ## Sequent Balance
 835   ns32k-sequent-bsd4.2* )
 836     machine=sequent opsys=bsd4-2
 837   ;;
 838   ns32k-sequent-bsd4.3* )
 839     machine=sequent opsys=bsd4-3
 840   ;;
 841
 842   ## Siemens Nixdorf
 843   mips-siemens-sysv* | mips-sni-sysv*)
 844     machine=mips-siemens opsys=usg5-4
 845     NON_GNU_CC=/usr/ccs/bin/cc
 846     NON_GNU_CPP=/usr/ccs/lib/cpp
 847   ;;
 848
 849   ## Silicon Graphics machines
 850   ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
 851   m68*-sgi-iris3.5* )
 852     machine=irist opsys=iris3-5
 853   ;;
 854   m68*-sgi-iris3.6* | m68*-sgi-iris*)
 855     machine=irist opsys=iris3-6
 856   ;;
 857   ## Iris 4D
 858   mips-sgi-irix3* )
 859     machine=iris4d opsys=irix3-3
 860   ;;
 861   mips-sgi-irix4* )
 862     machine=iris4d opsys=irix4-0
 863   ;;
 864   mips-sgi-irix6.5 )
 865     machine=iris4d opsys=irix6-5
 866     # Without defining _LANGUAGE_C, things get masked out in the headers
 867     # so that, for instance, grepping for `free' in stdlib.h fails and
 868     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 869     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 870     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 871   ;;
 872   mips-sgi-irix6* )
 873     machine=iris4d opsys=irix6-0
 874     # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
 875     # but presumably it does no harm.
 876     NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
 877     # -32 probably isn't necessary in later v.6s -- anyone know which?
 878     NON_GCC_TEST_OPTIONS=-32
 879   ;;
 880   mips-sgi-irix5.[01]* )
 881     machine=iris4d opsys=irix5-0
 882   ;;
 883   mips-sgi-irix5* | mips-sgi-irix* )
 884     machine=iris4d opsys=irix5-2
 885   ;;
 886
 887   ## SONY machines
 888   m68*-sony-bsd4.2* )
 889     machine=news opsys=bsd4-2
 890   ;;
 891   m68*-sony-bsd4.3* )
 892     machine=news opsys=bsd4-3
 893   ;;
 894   m68*-sony-newsos3* | m68*-sony-news3*)
 895     machine=news opsys=bsd4-3
 896   ;;
 897   mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
 898     machine=news-risc opsys=bsd4-3
 899   ;;
 900   mips-sony-newsos6* )
 901     machine=news-r6 opsys=newsos6
 902   ;;
 903   mips-sony-news* )
 904     machine=news-risc opsys=newsos5
 905   ;;
 906
 907   ## Stride
 908   m68*-stride-sysv* )
 909     machine=stride opsys=usg5-2
 910   ;;
 911
 912   ## Suns
 913   sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
 914     machine=sparc opsys=gnu-linux
 915   ;;
 916
 917   *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
 918     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
 919     | rs6000-*-solaris2*)
 920     case "${canonical}" in
 921       m68*-sunos1* )    machine=sun1 ;;
 922       m68*-sunos2* )    machine=sun2 ;;
 923       m68* )            machine=sun3 ;;
 924       i[3456]86-sun-sunos[34]* )        machine=sun386 ;;
 925       i[3456]86-*-* )     machine=intel386 ;;
 926       powerpcle* )      machine=powerpcle ;;
 927       powerpc* | rs6000* )  machine=ibmrs6000 ;;
 928       sparc* )          machine=sparc ;;
 929       * )               unported=yes ;;
 930     esac
 931     case "${canonical}" in
 932       ## The Sun386 didn't get past 4.0.
 933       i[3456]86-*-sunos4          ) opsys=sunos4-0 ;;
 934       *-sunos4.0*         ) opsys=sunos4-0 ;;
 935       *-sunos4.1.[3-9]*noshare )
 936                 ## This name is sunos413 instead of sunos4-1-3
 937                 ## to avoid a file name conflict on MSDOS.
 938                 opsys=sunos413
 939                 NON_GNU_CPP=/usr/lib/cpp
 940                 NON_GCC_TEST_OPTIONS=-Bstatic
 941                 GCC_TEST_OPTIONS=-static
 942                 ;;
 943       *-sunos4.1.[3-9]* | *-sunos4shr*)
 944                 opsys=sunos4shr
 945                 NON_GNU_CPP=/usr/lib/cpp
 946                 ;;
 947       *-sunos4* | *-sunos )
 948                 opsys=sunos4-1
 949                 NON_GCC_TEST_OPTIONS=-Bstatic
 950                 GCC_TEST_OPTIONS=-static
 951                 ;;
 952       *-sunos5.3* | *-solaris2.3* )
 953                 opsys=sol2-3
 954                 NON_GNU_CPP=/usr/ccs/lib/cpp
 955                 ;;
 956       *-sunos5.4* | *-solaris2.4* )
 957                 opsys=sol2-4
 958                 NON_GNU_CPP=/usr/ccs/lib/cpp
 959                 RANLIB="ar -ts"
 960                 ;;
 961       *-sunos5.5* | *-solaris2.5* )
 962                 opsys=sol2-5
 963                 NON_GNU_CPP=/usr/ccs/lib/cpp
 964                 RANLIB="ar -ts"
 965                 ;;
 966       *-sunos5.6* | *-solaris2.6* )
 967                 opsys=sol2-6
 968                 NON_GNU_CPP=/usr/ccs/lib/cpp
 969                 RANLIB="ar -ts"
 970                 ;;
 971       *-sunos5* | *-solaris* )
 972                 opsys=sol2-6
 973                 NON_GNU_CPP=/usr/ccs/lib/cpp
 974                 ;;
 975       *                   ) opsys=bsd4-2   ;;
 976     esac
 977     ## Watch out for a compiler that we know will not work.
 978     case "${canonical}" in
 979      *-solaris* | *-sunos5* )
 980                 if [ "x$CC" = x/usr/ucb/cc ]; then
 981                   ## /usr/ucb/cc doesn't work;
 982                   ## we should find some other compiler that does work.
 983                   unset CC
 984                 fi
 985                 ;;
 986       *) ;;
 987     esac
 988   ;;
 989   sparc-*-nextstep* )
 990     machine=sparc opsys=nextstep
 991   ;;
 992
 993   ## Tadpole 68k
 994   m68*-tadpole-sysv* )
 995     machine=tad68k opsys=usg5-3
 996   ;;
 997
 998   ## Tahoe machines
 999   tahoe-tahoe-bsd4.2* )
1000     machine=tahoe opsys=bsd4-2
1001   ;;
1002   tahoe-tahoe-bsd4.3* )
1003     machine=tahoe opsys=bsd4-3
1004   ;;
1005
1006   ## Tandem Integrity S2
1007   mips-tandem-sysv* )
1008     machine=tandem-s2 opsys=usg5-3
1009   ;;
1010
1011   ## Tektronix XD88
1012   m88k-tektronix-sysv3* )
1013   machine=tekxd88 opsys=usg5-3
1014   ;;
1015
1016   ## Tektronix 16000 box (6130?)
1017   ns16k-tektronix-bsd* )
1018     machine=ns16000 opsys=bsd4-2
1019   ;;
1020   ## Tektronix 4300
1021   ## src/m/tek4300.h hints that this is a m68k machine.
1022   m68*-tektronix-bsd* )
1023     machine=tek4300 opsys=bsd4-3
1024   ;;
1025
1026   ## Titan P2 or P3
1027   ## We seem to have lost the machine-description file titan.h!
1028   titan-titan-sysv* )
1029     machine=titan opsys=usg5-3
1030   ;;
1031
1032   ## Ustation E30 (SS5E)
1033   m68*-unisys-uniplus* )
1034     machine=ustation opsystem=unipl5-2
1035   ;;
1036
1037   ## Vaxen.
1038   vax-dec-* )
1039     machine=vax
1040     case "${canonical}" in
1041       *-bsd4.1* )                                       opsys=bsd4-1 ;;
1042       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
1043       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
1044       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
1045       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
1046       *-vms* )                                          opsys=vms ;;
1047       * )                                               unported=yes
1048     esac
1049   ;;
1050
1051   ## Whitechapel MG1
1052   ns16k-whitechapel-* )
1053     machine=mg1
1054     ## We don't know what sort of OS runs on these; we'll let the
1055     ## operating system guessing code below try.
1056   ;;
1057
1058   ## Wicat
1059   m68*-wicat-sysv* )
1060     machine=wicat opsys=usg5-2
1061   ;;
1062
1063   ## IA-64
1064   ia64*-*-linux* )
1065     machine=ia64 opsys=gnu-linux
1066   ;;
1067
1068   ## Intel 386 machines where we don't care about the manufacturer
1069   i[3456]86-*-* )
1070     machine=intel386
1071     case "${canonical}" in
1072       *-cygwin )                opsys=cygwin ;;
1073       *-lynxos* )               opsys=lynxos ;;
1074       *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
1075       *-isc2.2* )               opsys=isc2-2 ;;
1076       *-isc4.0* )               opsys=isc4-0 ;;
1077       *-isc4.* )                opsys=isc4-1
1078                                 GCC_TEST_OPTIONS=-posix
1079                                 NON_GCC_TEST_OPTIONS=-Xp
1080                                 ;;
1081       *-isc* )                  opsys=isc3-0 ;;
1082       *-esix5* )                opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
1083       *-esix* )                 opsys=esix ;;
1084       *-xenix* )                opsys=xenix ;;
1085       *-linux-gnu* )            opsys=gnu-linux ;;
1086       *-sco3.2v4* )             opsys=sco4 ; NON_GNU_CPP=/lib/cpp  ;;
1087       *-sco3.2v5* )             opsys=sco5
1088                                 NON_GNU_CPP=/lib/cpp
1089                                 # Prevent -belf from being passed to $CPP.
1090                                 # /lib/cpp does not accept it.
1091                                 OVERRIDE_CPPFLAGS=" "
1092                                 ;;
1093       *-sysv4.2uw* )            opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1094       *-sysv5uw* )              opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1095       *-sysv5OpenUNIX* )        opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1096       *-386bsd* )               opsys=386bsd ;;
1097       *-nextstep* )             opsys=nextstep ;;
1098       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1099     esac
1100   ;;
1101
1102   ## m68k Linux-based GNU system
1103   m68k-*-linux-gnu* )
1104     machine=m68k opsys=gnu-linux
1105   ;;
1106
1107   ## Mips Linux-based GNU system
1108   mips-*-linux-gnu* | mipsel-*-linux-gnu* )
1109     machine=mips opsys=gnu-linux
1110   ;;
1111
1112   ## UXP/DS
1113   sparc-fujitsu-sysv4* )
1114     machine=sparc opsys=uxpds
1115     NON_GNU_CPP=/usr/ccs/lib/cpp
1116     RANLIB="ar -ts"
1117   ;;
1118
1119   ## UXP/V
1120   f301-fujitsu-uxpv4.1)
1121     machine=f301 opsys=uxpv
1122   ;;
1123
1124   ## Darwin / Mac OS X
1125   powerpc-apple-darwin* )
1126     machine=powermac opsys=darwin
1127     # Define CPP as follows to make autoconf work correctly.
1128     CPP="${CC-cc} -E -no-cpp-precomp"
1129     # Use fink packages if available.
1130     if test -d /sw/include && test -d /sw/lib; then
1131         GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
1132         CPP="${CPP} ${GCC_TEST_OPTIONS}"
1133         NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
1134     fi
1135   ;;
1136
1137   ## AMD x86-64 Linux-based GNU system
1138   x86_64-*-linux-gnu* )
1139     machine=amdx86-64 opsys=gnu-linux
1140   ;;
1141
1142   * )
1143     unported=yes
1144   ;;
1145 esac
1146
1147 ### If the code above didn't choose an operating system, just choose
1148 ### an operating system based on the configuration name.  You really
1149 ### only want to use this when you have no idea what the right
1150 ### operating system is; if you know what operating systems a machine
1151 ### runs, it's cleaner to make it explicit in the case statement
1152 ### above.
1153 if test x"${opsys}" = x; then
1154   case "${canonical}" in
1155     *-gnu* )                            opsys=gnu ;;
1156     *-bsd4.[01] )                       opsys=bsd4-1 ;;
1157     *-bsd4.2 )                          opsys=bsd4-2 ;;
1158     *-bsd4.3 )                          opsys=bsd4-3 ;;
1159     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
1160     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
1161     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
1162     *-sysv3* | *-sysvr3* )              opsys=usg5-3 ;;
1163     *-sysv4.2uw* )                      opsys=unixware ;;
1164     *-sysv5uw* )                        opsys=unixware ;;
1165     *-sysv5OpenUNIX* )                  opsys=unixware ;;
1166     *-sysv4.1* | *-sysvr4.1* )
1167         NON_GNU_CPP=/usr/lib/cpp
1168         opsys=usg5-4 ;;
1169     *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1170         if [ x$NON_GNU_CPP = x ]; then
1171           if [ -f /usr/ccs/lib/cpp ]; then
1172             NON_GNU_CPP=/usr/ccs/lib/cpp
1173           else
1174             NON_GNU_CPP=/lib/cpp
1175           fi
1176         fi
1177         opsys=usg5-4-2 ;;
1178     *-sysv4* | *-sysvr4* )              opsys=usg5-4 ;;
1179     * )
1180       unported=yes
1181     ;;
1182   esac
1183 fi
1184
1185 ]
1186 dnl quotation ends
1187
1188 if test $unported = yes; then
1189   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
1190 Check `etc/MACHINES' for recognized configuration names.])
1191 fi
1192
1193 machfile="m/${machine}.h"
1194 opsysfile="s/${opsys}.h"
1195
1196
1197 #### Choose a compiler.
1198 test -n "$CC" && cc_specified=yes
1199
1200 # Save the value of CFLAGS that the user specified.
1201 SPECIFIED_CFLAGS="$CFLAGS"
1202
1203 case ${with_gcc} in
1204   "yes" ) CC="gcc" GCC=yes ;;
1205   "no"  ) : ${CC=cc} ;;
1206   * )
1207 esac
1208 AC_PROG_CC
1209
1210 # On Suns, sometimes $CPP names a directory.
1211 if test -n "$CPP" && test -d "$CPP"; then
1212   CPP=
1213 fi
1214
1215 #### Some systems specify a CPP to use unless we are using GCC.
1216 #### Now that we know whether we are using GCC, we can decide whether
1217 #### to use that one.
1218 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1219 then
1220   CPP="$NON_GNU_CPP"
1221 fi
1222
1223 #### Some systems specify a CC to use unless we are using GCC.
1224 #### Now that we know whether we are using GCC, we can decide whether
1225 #### to use that one.
1226 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1227   test x$cc_specified != xyes
1228 then
1229   CC="$NON_GNU_CC"
1230 fi
1231
1232 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1233 then
1234   CC="$CC $GCC_TEST_OPTIONS"
1235 fi
1236
1237 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1238 then
1239   CC="$CC $NON_GCC_TEST_OPTIONS"
1240 fi
1241
1242 #### Some other nice autoconf tests.
1243
1244 dnl checks for programs
1245 AC_PROG_LN_S
1246 AC_PROG_CPP
1247 AC_PROG_INSTALL
1248 if test "x$RANLIB" = x; then
1249   AC_PROG_RANLIB
1250 fi
1251 AC_PATH_PROG(INSTALL_INFO, install-info)
1252 AC_PATH_PROG(INSTALL_INFO, install-info,, /usr/sbin)
1253 AC_PATH_PROG(INSTALL_INFO, install-info,:, /sbin)
1254
1255 dnl Add our options to ac_link now, after it is set up.
1256
1257 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1258 then
1259   ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1260 fi
1261
1262 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1263 then
1264   ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1265 fi
1266
1267 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
1268 dnl If we can link with the flag, it shouldn't do any harm anyhow.
1269 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
1270 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
1271 dnl if not built to support GNU ld.
1272
1273 late_LDFLAGS=$LDFLAGS
1274 if test "$GCC" = yes; then
1275   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
1276 else
1277   LDFLAGS="$LDFLAGS -znocombreloc"
1278 fi
1279
1280 AC_MSG_CHECKING([For -znocombreloc])
1281 AC_LINK_IFELSE([main(){return 0;}],
1282   [AC_MSG_RESULT(yes)],
1283   LDFLAGS=$late_LDFLAGS
1284   [AC_MSG_RESULT(no)])
1285
1286 dnl checks for Unix variants
1287 AC_AIX
1288
1289
1290 #### Extract some information from the operating system and machine files.
1291
1292 AC_CHECKING([the machine- and system-dependent files to find out
1293  - which libraries the lib-src programs will want, and
1294  - whether the GNU malloc routines are usable])
1295
1296 ### First figure out CFLAGS (which we use for running the compiler here)
1297 ### and REAL_CFLAGS (which we use for real compilation).
1298 ### The two are the same except on a few systems, where they are made
1299 ### different to work around various lossages.  For example,
1300 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1301 ### as implying static linking.
1302
1303 ### If the CFLAGS env var is specified, we use that value
1304 ### instead of the default.
1305
1306 ### It's not important that this name contain the PID; you can't run
1307 ### two configures in the same directory and have anything work
1308 ### anyway.
1309 tempcname="conftest.c"
1310
1311 echo '
1312 #include "'${srcdir}'/src/'${opsysfile}'"
1313 #include "'${srcdir}'/src/'${machfile}'"
1314 #ifndef LIBS_MACHINE
1315 #define LIBS_MACHINE
1316 #endif
1317 #ifndef LIBS_SYSTEM
1318 #define LIBS_SYSTEM
1319 #endif
1320 #ifndef C_SWITCH_SYSTEM
1321 #define C_SWITCH_SYSTEM
1322 #endif
1323 #ifndef C_SWITCH_MACHINE
1324 #define C_SWITCH_MACHINE
1325 #endif
1326 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1327 configure___ c_switch_system=C_SWITCH_SYSTEM
1328 configure___ c_switch_machine=C_SWITCH_MACHINE
1329
1330 #ifndef LIB_X11_LIB
1331 #define LIB_X11_LIB -lX11
1332 #endif
1333
1334 #ifndef LIBX11_MACHINE
1335 #define LIBX11_MACHINE
1336 #endif
1337
1338 #ifndef LIBX11_SYSTEM
1339 #define LIBX11_SYSTEM
1340 #endif
1341 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1342
1343 #ifdef UNEXEC
1344 configure___ unexec=UNEXEC
1345 #else
1346 configure___ unexec=unexec.o
1347 #endif
1348
1349 #ifdef SYSTEM_MALLOC
1350 configure___ system_malloc=yes
1351 #else
1352 configure___ system_malloc=no
1353 #endif
1354
1355 #ifdef USE_MMAP_FOR_BUFFERS
1356 configure___ use_mmap_for_buffers=yes
1357 #else
1358 configure___ use_mmap_for_buffers=no
1359 #endif
1360
1361 #ifndef C_DEBUG_SWITCH
1362 #define C_DEBUG_SWITCH -g
1363 #endif
1364
1365 #ifndef C_OPTIMIZE_SWITCH
1366 #ifdef __GNUC__
1367 #define C_OPTIMIZE_SWITCH -O2
1368 #else
1369 #define C_OPTIMIZE_SWITCH -O
1370 #endif
1371 #endif
1372
1373 #ifndef LD_SWITCH_MACHINE
1374 #define LD_SWITCH_MACHINE
1375 #endif
1376
1377 #ifndef LD_SWITCH_SYSTEM
1378 #define LD_SWITCH_SYSTEM
1379 #endif
1380
1381 #ifndef LD_SWITCH_X_SITE_AUX
1382 #define LD_SWITCH_X_SITE_AUX
1383 #endif
1384
1385 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1386 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1387
1388 #ifdef THIS_IS_CONFIGURE
1389
1390 /* Get the CFLAGS for tests in configure.  */
1391 #ifdef __GNUC__
1392 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1393 #else
1394 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1395 #endif
1396
1397 #else /* not THIS_IS_CONFIGURE */
1398
1399 /* Get the CFLAGS for real compilation.  */
1400 #ifdef __GNUC__
1401 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1402 #else
1403 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1404 #endif
1405
1406 #endif /* not THIS_IS_CONFIGURE */
1407 ' > ${tempcname}
1408
1409 # The value of CPP is a quoted variable reference, so we need to do this
1410 # to get its actual value...
1411 CPP=`eval "echo $CPP"`
1412 [eval `${CPP} -Isrc ${tempcname} \
1413        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1414 if test "x$SPECIFIED_CFLAGS" = x; then
1415   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1416          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1417 else
1418   REAL_CFLAGS="$CFLAGS"
1419 fi]
1420 rm ${tempcname}
1421
1422 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1423
1424 ### Make sure subsequent tests use flags consistent with the build flags.
1425
1426 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1427   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1428 else
1429   CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1430 fi
1431
1432 dnl For AC_FUNC_GETLOADAVG, at least:
1433 AC_CONFIG_LIBOBJ_DIR(src)
1434
1435 AC_GNU_SOURCE
1436
1437 dnl Do this early because it can frob feature test macros for Unix-98 &c.
1438 AC_SYS_LARGEFILE
1439
1440 if test "${with_sound}" != "no"; then
1441   # Sound support for GNU/Linux and the free BSDs.
1442   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h)
1443   # Emulation library used on NetBSD.
1444   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1445   AC_SUBST(LIBSOUND)
1446 fi
1447
1448 dnl checks for header files
1449 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1450   linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1451   termcap.h stdio_ext.h fcntl.h strings.h coff.h pty.h sys/mman.h \
1452   sys/param.h sys/vlimit.h sys/resource.h locale.h sys/_mbstate_t.h \
1453   sys/utsname.h pwd.h)
1454
1455 AC_MSG_CHECKING(if personality LINUX32 can be set)
1456 AC_TRY_COMPILE([#include <sys/personality.h>], [personality (PER_LINUX32)],
1457                emacs_cv_personality_linux32=yes,
1458                emacs_cv_personality_linux32=no)
1459 AC_MSG_RESULT($emacs_cv_personality_linux32)
1460
1461 if test $emacs_cv_personality_linux32 = yes; then
1462   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1463             [Define to 1 if personality LINUX32 can be set.])
1464 fi
1465
1466 dnl On Solaris 8 there's a compilation warning for term.h because
1467 dnl it doesn't define `bool'.
1468 AC_CHECK_HEADERS(term.h, , , -)
1469 AC_HEADER_STDC
1470 AC_HEADER_TIME
1471 AC_CHECK_DECLS([sys_siglist])
1472 if test $ac_cv_have_decl_sys_siglist != yes; then
1473   # For Tru64, at least:
1474   AC_CHECK_DECLS([__sys_siglist])
1475   if test $ac_cv_have_decl___sys_siglist = yes; then
1476     AC_DEFINE(sys_siglist, __sys_siglist,
1477               [Define to any substitute for sys_siglist.])
1478   fi
1479 fi
1480 AC_HEADER_SYS_WAIT
1481
1482 dnl Some systems have utime.h but don't declare the struct anyplace.
1483 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1484 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1485 #include <sys/time.h>
1486 #include <time.h>
1487 #else
1488 #ifdef HAVE_SYS_TIME_H
1489 #include <sys/time.h>
1490 #else
1491 #include <time.h>
1492 #endif
1493 #endif
1494 #ifdef HAVE_UTIME_H
1495 #include <utime.h>
1496 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1497   emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1498 if test $emacs_cv_struct_utimbuf = yes; then
1499   AC_DEFINE(HAVE_STRUCT_UTIMBUF, 1, [Define to 1 if `struct utimbuf' is declared by <utime.h>.])
1500 fi
1501
1502 dnl checks for typedefs
1503 AC_TYPE_SIGNAL
1504
1505 dnl Check for speed_t typedef.
1506 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1507   [AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1508     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1509 if test $emacs_cv_speed_t = yes; then
1510   AC_DEFINE(HAVE_SPEED_T, 1,
1511            [Define to 1 if `speed_t' is declared by <termios.h>.])
1512 fi
1513
1514 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1515 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1516 #include <sys/time.h>
1517 #include <time.h>
1518 #else
1519 #ifdef HAVE_SYS_TIME_H
1520 #include <sys/time.h>
1521 #else
1522 #include <time.h>
1523 #endif
1524 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1525   emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1526 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1527 if test $emacs_cv_struct_timeval = yes; then
1528   AC_DEFINE(HAVE_TIMEVAL, 1, [Define to 1 if `struct timeval' is declared by <sys/time.h>.])
1529 fi
1530
1531 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1532 AC_TRY_COMPILE([#include <math.h>],
1533 [static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;],
1534   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1535 HAVE_EXCEPTION=$emacs_cv_struct_exception
1536 if test $emacs_cv_struct_exception != yes; then
1537   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1538 fi
1539
1540 AC_CHECK_HEADERS(sys/socket.h)
1541 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1542 #if HAVE_SYS_SOCKET_H
1543 #include <sys/socket.h>
1544 #endif])
1545
1546 dnl checks for structure members
1547 AC_STRUCT_TM
1548 AC_STRUCT_TIMEZONE
1549 AC_CHECK_MEMBER(struct tm.tm_gmtoff,
1550                 [AC_DEFINE(HAVE_TM_GMTOFF, 1,
1551                            [Define to 1 if `tm_gmtoff' is member of `struct tm'.])],,
1552                 [#include <time.h>])
1553 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1554                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1555                   struct ifreq.ifr_addr], , ,
1556                  [AC_INCLUDES_DEFAULT
1557 #if HAVE_SYS_SOCKET_H
1558 #include <sys/socket.h>
1559 #endif
1560 #if HAVE_NET_IF_H
1561 #include <net/if.h>
1562 #endif])
1563
1564 dnl checks for compiler characteristics
1565
1566 dnl Testing __STDC__ to determine prototype support isn't good enough.
1567 dnl DEC C, for instance, doesn't define it with default options, and
1568 dnl is used on 64-bit systems (OSF Alphas).  Similarly for volatile
1569 dnl and void *.
1570 AC_C_PROTOTYPES
1571 AC_C_VOLATILE
1572 AC_C_CONST
1573 dnl This isn't useful because we can't turn on use of `inline' unless
1574 dnl the compiler groks `extern inline'.
1575 dnl AC_C_INLINE
1576 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1577   [AC_TRY_COMPILE(, [void * foo;],
1578                    emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1579 if test $emacs_cv_void_star = yes; then
1580   AC_DEFINE(POINTER_TYPE, void)
1581 else
1582   AC_DEFINE(POINTER_TYPE, char)
1583 fi
1584 AH_TEMPLATE(POINTER_TYPE,
1585             [Define as `void' if your compiler accepts `void *'; otherwise
1586              define as `char'.])dnl
1587
1588
1589
1590 dnl This could be used for targets which can have both byte sexes.
1591 dnl We could presumably replace the hardwired WORDS_BIG_ENDIAN generally.
1592 dnl AC_C_BIGENDIAN
1593
1594 dnl check for Make feature
1595 AC_PROG_MAKE_SET
1596
1597 dnl checks for operating system services
1598 AC_SYS_LONG_FILE_NAMES
1599
1600 #### Choose a window system.
1601
1602 AC_PATH_X
1603 if test "$no_x" = yes; then
1604   window_system=none
1605 else
1606   window_system=x11
1607 fi
1608
1609 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1610   LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1611   LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1612   x_default_search_path=""
1613   for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1614     x_search_path="\
1615 ${x_library}/X11/%L/%T/%N%C%S:\
1616 ${x_library}/X11/%l/%T/%N%C%S:\
1617 ${x_library}/X11/%T/%N%C%S:\
1618 ${x_library}/X11/%L/%T/%N%S:\
1619 ${x_library}/X11/%l/%T/%N%S:\
1620 ${x_library}/X11/%T/%N%S"
1621     if test x"${x_default_search_path}" = x; then
1622       x_default_search_path=${x_search_path}
1623     else
1624       x_default_search_path="${x_search_path}:${x_default_search_path}"
1625     fi
1626   done
1627 fi
1628 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1629   C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1630 fi
1631
1632 if test x"${x_includes}" = x; then
1633   bitmapdir=/usr/include/X11/bitmaps
1634 else
1635   # accumulate include directories that have X11 bitmap subdirectories
1636   bmd_acc="dummyval"
1637   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1638     if test -d "${bmd}/X11/bitmaps"; then
1639       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1640     fi
1641     if test -d "${bmd}/bitmaps"; then
1642       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1643     fi
1644   done
1645   if test ${bmd_acc} != "dummyval"; then
1646     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1647   fi
1648 fi
1649
1650 case "${window_system}" in
1651   x11 )
1652     HAVE_X_WINDOWS=yes
1653     HAVE_X11=yes
1654     case "${with_x_toolkit}" in
1655       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1656       motif ) USE_X_TOOLKIT=MOTIF ;;
1657 dnl      open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1658       gtk ) with_gtk=yes
1659 dnl Dont set this for GTK.  A lot of tests below assumes Xt when
1660 dnl USE_X_TOOLKIT is set.
1661             USE_X_TOOLKIT=none ;;
1662       no ) USE_X_TOOLKIT=none ;;
1663 dnl If user did not say whether to use a toolkit,
1664 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1665       * ) USE_X_TOOLKIT=maybe ;;
1666     esac
1667   ;;
1668   none )
1669     HAVE_X_WINDOWS=no
1670     HAVE_X11=no
1671     USE_X_TOOLKIT=none
1672   ;;
1673 esac
1674
1675 ### If we're using X11, we should use the X menu package.
1676 HAVE_MENUS=no
1677 case ${HAVE_X11} in
1678   yes ) HAVE_MENUS=yes ;;
1679 esac
1680
1681 if test "${opsys}" = "hpux9"; then
1682   case "${x_libraries}" in
1683     *X11R4* )
1684       opsysfile="s/hpux9-x11r4.h"
1685       ;;
1686   esac
1687 fi
1688
1689 if test "${opsys}" = "hpux9shr"; then
1690   case "${x_libraries}" in
1691     *X11R4* )
1692       opsysfile="s/hpux9shxr4.h"
1693       ;;
1694   esac
1695 fi
1696
1697 HAVE_CARBON=no
1698 if test "${HAVE_X11}" != "yes"; then
1699   if test "${with_carbon}" != "no"; then
1700      AC_CHECK_HEADER(Carbon/Carbon.h, HAVE_CARBON=yes)
1701   fi
1702 fi
1703
1704 ### Compute the unexec source name from the object name.
1705 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1706
1707 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1708 # Assume not, until told otherwise.
1709 GNU_MALLOC=yes
1710 doug_lea_malloc=yes
1711 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1712 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1713 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1714                emacs_cv_var___after_morecore_hook,
1715 [AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1716   emacs_cv_var___after_morecore_hook=yes,
1717   emacs_cv_var___after_morecore_hook=no)])
1718 if test $emacs_cv_var___after_morecore_hook = no; then
1719   doug_lea_malloc=no
1720 fi
1721 if test "${system_malloc}" = "yes"; then
1722   GNU_MALLOC=no
1723   GNU_MALLOC_reason="
1724     (The GNU allocators don't work with this system configuration.)"
1725 fi
1726 if test "$doug_lea_malloc" = "yes" ; then
1727   if test "$GNU_MALLOC" = yes ; then
1728     GNU_MALLOC_reason="
1729       (Using Doug Lea's new malloc from the GNU C Library.)"
1730   fi
1731   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1732             [Define to 1 if you are using the GNU C Library.])
1733 fi
1734
1735 if test x"${REL_ALLOC}" = x; then
1736   REL_ALLOC=${GNU_MALLOC}
1737 fi
1738
1739 dnl For now, need to use an explicit `#define USE_MMAP_FOR_BUFFERS 1'
1740 dnl the system configuration file (s/*.h) to turn the use of mmap
1741 dnl in the relocating allocator on.
1742
1743 AC_FUNC_MMAP
1744 if test $use_mmap_for_buffers = yes; then
1745   REL_ALLOC=no
1746 fi
1747
1748 LIBS="$libsrc_libs $LIBS"
1749
1750 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1751 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1752 AC_CHECK_LIB(dnet, dnet_ntoa)
1753 dnl This causes -lresolv to get used in subsequent tests,
1754 dnl which causes failures on some systems such as HPUX 9.
1755 dnl AC_CHECK_LIB(resolv, gethostbyname)
1756
1757 dnl FIXME replace main with a function we actually want from this library.
1758 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1759
1760 AC_CHECK_LIB(pthreads, cma_open)
1761
1762 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1763 if test -d /usr/X386/include; then
1764   HAVE_XFREE386=yes
1765   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1766 else
1767   HAVE_XFREE386=no
1768 fi
1769 AC_MSG_RESULT($HAVE_XFREE386)
1770
1771 dnl Check for need for bigtoc support on IBM AIX
1772
1773 case ${host_os} in
1774 aix*)
1775   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1776     case $GCC in
1777     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1778     *) gdb_cv_bigtoc=-bbigtoc ;;
1779     esac
1780
1781     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1782     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1783   ])
1784   ;;
1785 esac
1786
1787 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1788 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1789 # REAL_CPPFLAGS later on.
1790
1791 REAL_CPPFLAGS="$CPPFLAGS"
1792
1793 if test "${HAVE_X11}" = "yes"; then
1794   DEFS="$C_SWITCH_X_SITE $DEFS"
1795   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1796   LIBS="$LIBX $LIBS"
1797   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1798   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1799
1800   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1801   # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1802   # but it's more convenient here to set LD_RUN_PATH
1803   # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1804   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1805     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1806     export LD_RUN_PATH
1807   fi
1808
1809   if test "${opsys}" = "gnu-linux"; then
1810     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1811     AC_TRY_LINK([],
1812      [XOpenDisplay ("foo");],
1813      [xlinux_first_failure=no],
1814      [xlinux_first_failure=yes])
1815     if test "${xlinux_first_failure}" = "yes"; then
1816       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1817       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1818       OLD_CPPFLAGS="$CPPFLAGS"
1819       OLD_LIBS="$LIBS"
1820       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1821       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1822       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1823       LIBS="$LIBS -b i486-linuxaout"
1824       AC_TRY_LINK([],
1825        [XOpenDisplay ("foo");],
1826        [xlinux_second_failure=no],
1827        [xlinux_second_failure=yes])
1828       if test "${xlinux_second_failure}" = "yes"; then
1829         # If we get the same failure with -b, there is no use adding -b.
1830         # So take it out.  This plays safe.
1831         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1832         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1833         CPPFLAGS="$OLD_CPPFLAGS"
1834         LIBS="$OLD_LIBS"
1835         AC_MSG_RESULT(no)
1836       else
1837         AC_MSG_RESULT(yes)
1838       fi
1839     else
1840       AC_MSG_RESULT(no)
1841     fi
1842   fi
1843
1844   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1845   # header files included from there.
1846   AC_MSG_CHECKING(for Xkb)
1847   AC_TRY_LINK([#include <X11/Xlib.h>
1848 #include <X11/XKBlib.h>],
1849         [XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);],
1850         emacs_xkb=yes, emacs_xkb=no)
1851   AC_MSG_RESULT($emacs_xkb)
1852   if test $emacs_xkb = yes; then
1853     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1854   fi
1855
1856   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1857 XScreenNumberOfScreen XSetWMProtocols)
1858 fi
1859
1860 if test "${window_system}" = "x11"; then
1861   AC_MSG_CHECKING(X11 version 6)
1862   AC_CACHE_VAL(emacs_cv_x11_version_6,
1863   [AC_TRY_LINK([#include <X11/Xlib.h>],
1864 [#if XlibSpecificationRelease < 6
1865 fail;
1866 #endif
1867 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1868   if test $emacs_cv_x11_version_6 = yes; then
1869     AC_MSG_RESULT(6 or newer)
1870     AC_DEFINE(HAVE_X11R6, 1,
1871               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1872   else
1873     AC_MSG_RESULT(before 6)
1874   fi
1875 fi
1876
1877 if test "${window_system}" = "x11"; then
1878   AC_MSG_CHECKING(X11 version 5)
1879   AC_CACHE_VAL(emacs_cv_x11_version_5,
1880   [AC_TRY_LINK([#include <X11/Xlib.h>],
1881 [#if XlibSpecificationRelease < 5
1882 fail;
1883 #endif
1884 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no)])
1885   if test $emacs_cv_x11_version_5 = yes; then
1886     AC_MSG_RESULT(5 or newer)
1887     HAVE_X11R5=yes
1888     AC_DEFINE(HAVE_X11R5, 1,
1889               [Define to 1 if you have the X11R5 or newer version of Xlib.])
1890   else
1891     HAVE_X11R5=no
1892     AC_MSG_RESULT(before 5)
1893   fi
1894 fi
1895
1896 dnl This function defintion taken from Gnome 2.0
1897 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1898 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1899 dnl also defines GSTUFF_PKG_ERRORS on error
1900 AC_DEFUN([PKG_CHECK_MODULES], [
1901   succeeded=no
1902
1903   if test -z "$PKG_CONFIG"; then
1904     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1905   fi
1906
1907   if test "$PKG_CONFIG" = "no" ; then
1908      echo "*** The pkg-config script could not be found. Make sure it is"
1909      echo "*** in your path, or give the full path to pkg-config with"
1910      echo "*** the PKG_CONFIG environment variable or --with-pkg-config-prog."
1911      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1912   else
1913      PKG_CONFIG_MIN_VERSION=0.9.0
1914      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1915         AC_MSG_CHECKING(for $2)
1916
1917         if $PKG_CONFIG --exists "$2" ; then
1918             AC_MSG_RESULT(yes)
1919             succeeded=yes
1920
1921             AC_MSG_CHECKING($1_CFLAGS)
1922             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1923             AC_MSG_RESULT($$1_CFLAGS)
1924
1925             AC_MSG_CHECKING($1_LIBS)
1926             $1_LIBS=`$PKG_CONFIG --libs "$2"`
1927             AC_MSG_RESULT($$1_LIBS)
1928         else
1929             $1_CFLAGS=""
1930             $1_LIBS=""
1931             ## If we have a custom action on failure, don't print errors, but
1932             ## do set a variable so people can do so.
1933             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1934             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1935         fi
1936
1937         AC_SUBST($1_CFLAGS)
1938         AC_SUBST($1_LIBS)
1939      else
1940         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1941         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1942      fi
1943   fi
1944
1945   if test $succeeded = yes; then
1946      ifelse([$3], , :, [$3])
1947   else
1948      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1949   fi
1950 ])
1951
1952 HAVE_GTK=no
1953 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "gtk"; then
1954   if test "$USE_X_TOOLKIT" != "none" && test "$USE_X_TOOLKIT" != "maybe"; then
1955     AC_MSG_ERROR([Conflicting options, --with-gtk is incompatible with --with-x-toolkit=${with_x_toolkit}]);
1956   fi
1957   GLIB_REQUIRED=2.0.1
1958   GTK_REQUIRED=2.0.1
1959   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1960
1961   dnl Check if --with-pkg-config-prog has been given.
1962   if test "X${with_pkg_config_prog}" != X; then
1963     PKG_CONFIG="${with_pkg_config_prog}"
1964   fi
1965   dnl Checks for libraries.
1966   PKG_CHECK_MODULES(GTK, $GTK_MODULES)
1967   AC_SUBST(GTK_CFLAGS)
1968   AC_SUBST(GTK_LIBS)
1969   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1970   CFLAGS="$CFLAGS $GTK_CFLAGS"
1971   LIBS="$GTK_LIBS $LIBS"
1972   HAVE_GTK=yes
1973   AC_DEFINE(HAVE_GTK, 1, [Define to 1 if using GTK.])
1974   USE_X_TOOLKIT=none
1975
1976   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1977   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1978   if test "$with_toolkit_scroll_bars" != no; then
1979     with_toolkit_scroll_bars=yes
1980   fi
1981
1982   dnl  Check if we can use multiple displays with this GTK version.
1983   dnl  If gdk_display_open exists, assume all others are there also.
1984   HAVE_GTK_MULTIDISPLAY=no
1985   AC_CHECK_FUNCS(gdk_display_open, HAVE_GTK_MULTIDISPLAY=yes)
1986   if test "${HAVE_GTK_MULTIDISPLAY}" = "yes"; then
1987     AC_DEFINE(HAVE_GTK_MULTIDISPLAY, 1,
1988               [Define to 1 if GTK can handle more than one display.])
1989   fi
1990   dnl  Check if we have the old file selection dialog.
1991   dnl  If gdk_display_open exists, assume all others are there also.
1992   HAVE_GTK_FILE_SELECTION=no
1993   AC_CHECK_FUNCS(gtk_file_selection_new, HAVE_GTK_FILE_SELECTION=yes)
1994
1995   dnl  Check if we have the new file chooser dialog
1996   dnl  If gdk_display_open exists, assume all others are there also.
1997   HAVE_GTK_FILE_CHOOSER=no
1998   AC_CHECK_FUNCS(gtk_file_chooser_dialog_new, HAVE_GTK_FILE_CHOOSER=yes)
1999
2000   if test "$HAVE_GTK_FILE_SELECTION" = yes \
2001      && test "$HAVE_GTK_FILE_CHOOSER" = yes;  then
2002     AC_DEFINE(HAVE_GTK_FILE_BOTH, 1,
2003               [Define to 1 if GTK has both file selection and chooser dialog.])
2004   fi
2005
2006   dnl Check if pthreads are available.  Emacs only needs this when using
2007   dnl gtk_file_chooser under Gnome.
2008   if test "$HAVE_GTK_FILE_CHOOSER" = yes; then
2009     HAVE_GTK_AND_PTHREAD=no
2010     AC_CHECK_HEADERS(pthread.h)
2011     if test "$ac_cv_header_pthread_h"; then
2012       AC_CHECK_LIB(pthread, pthread_self, HAVE_GTK_AND_PTHREAD=yes)
2013     fi
2014     if test "$HAVE_GTK_AND_PTHREAD" = yes; then
2015       GTK_LIBS="$GTK_LIBS -lpthread"
2016       AC_DEFINE(HAVE_GTK_AND_PTHREAD, 1,
2017                [Define to 1 if you have GTK and pthread (-lpthread).])
2018     fi
2019   fi
2020 fi
2021
2022 dnl Do not put whitespace before the #include statements below.
2023 dnl Older compilers (eg sunos4 cc) choke on it.
2024 if test x"${USE_X_TOOLKIT}" = xmaybe; then
2025   if test x"${HAVE_X11R5}" = xyes; then
2026     AC_MSG_CHECKING(X11 version 5 with Xaw)
2027     AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
2028     [AC_TRY_LINK([
2029 #include <X11/Intrinsic.h>
2030 #include <X11/Xaw/Simple.h>],
2031       [],
2032       emacs_cv_x11_version_5_with_xaw=yes,
2033       emacs_cv_x11_version_5_with_xaw=no)])
2034     if test $emacs_cv_x11_version_5_with_xaw = yes; then
2035       AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
2036       USE_X_TOOLKIT=LUCID
2037     else
2038       AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
2039       USE_X_TOOLKIT=none
2040     fi
2041   else
2042     USE_X_TOOLKIT=none
2043   fi
2044 fi
2045
2046 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2047
2048 if test "${USE_X_TOOLKIT}" != "none"; then
2049   AC_MSG_CHECKING(X11 toolkit version)
2050   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2051   [AC_TRY_LINK([#include <X11/Intrinsic.h>],
2052 [#if XtSpecificationRelease < 6
2053 fail;
2054 #endif
2055 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2056   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2057   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2058     AC_MSG_RESULT(6 or newer)
2059     AC_DEFINE(HAVE_X11XTR6, 1,
2060               [Define to 1 if you have the X11R6 or newer version of Xt.])
2061   else
2062     AC_MSG_RESULT(before 6)
2063   fi
2064
2065 dnl If using toolkit, check whether libXmu.a exists.
2066 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2067   OLDLIBS="$LIBS"
2068   if test x$HAVE_X11XTR6 = xyes; then
2069     LIBS="-lXt -lSM -lICE $LIBS"
2070   else
2071     LIBS="-lXt $LIBS"
2072   fi
2073   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2074   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2075 fi
2076
2077 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2078 if test "${HAVE_X11}" = "yes"; then
2079   if test "${USE_X_TOOLKIT}" != "none"; then
2080     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2081   fi
2082 fi
2083
2084 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2085   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2086   [AC_TRY_COMPILE([#include <Xm/Xm.h>],
2087     [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2088 int x = 5;
2089 #else
2090 Motif version prior to 2.1.
2091 #endif],
2092     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2093   HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
2094   if test $emacs_cv_motif_version_2_1 = yes; then
2095     HAVE_LIBXP=no
2096     AC_DEFINE(HAVE_MOTIF_2_1, 1,
2097               [Define to 1 if you have Motif 2.1 or newer.])
2098     AC_CHECK_LIB(Xp, XpCreateContext, HAVE_LIBXP=yes)
2099     if test ${HAVE_LIBXP} = yes; then
2100       AC_DEFINE(HAVE_LIBXP, 1,
2101                 [Define to 1 if you have the Xp library (-lXp).])
2102     fi
2103   else
2104     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2105     # We put this in CFLAGS temporarily to precede other -I options
2106     # that might be in CFLAGS temporarily.
2107     # We put this in CPPFLAGS where it precedes the other -I options.
2108     OLD_CPPFLAGS=$CPPFLAGS
2109     OLD_CFLAGS=$CFLAGS
2110     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2111     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2112     [AC_TRY_COMPILE([#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>],
2113       [int x = 5;],
2114       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2115     if test $emacs_cv_lesstif = yes; then
2116       # Make sure this -I option remains in CPPFLAGS after it is set
2117       # back to REAL_CPPFLAGS.
2118       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2119       # have those other -I options anyway.  Ultimately, having this
2120       # directory ultimately in CPPFLAGS will be enough.
2121       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2122       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2123     else
2124       CFLAGS=$OLD_CFLAGS
2125       CPPFLAGS=$OLD_CPPFLAGS
2126     fi
2127   fi
2128 fi
2129
2130 ### Is -lXaw3d available?
2131 HAVE_XAW3D=no
2132 if test "${HAVE_X11}" = "yes"; then
2133   if test "${USE_X_TOOLKIT}" != "none"; then
2134     dnl Fixme: determine what Scrollbar.h needs to avoid compilation
2135     dnl errors from the test without the `-'.
2136     AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
2137         [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes)], , -)
2138     if test "${HAVE_XAW3D}" = "yes"; then
2139         AC_DEFINE(HAVE_XAW3D, 1,
2140                   [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2141     fi
2142   fi
2143 fi
2144
2145 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2146 dnl using Motif or Xaw3d is available, and unless
2147 dnl --with-toolkit-scroll-bars=no was specified.
2148
2149 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2150             [Define to 1 if we should use toolkit scroll bars.])dnl
2151 USE_TOOLKIT_SCROLL_BARS=no
2152 if test "${with_toolkit_scroll_bars}" != "no"; then
2153   if test "${USE_X_TOOLKIT}" != "none"; then
2154     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2155       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2156       HAVE_XAW3D=no
2157       USE_TOOLKIT_SCROLL_BARS=yes
2158     elif test "${HAVE_XAW3D}" = "yes"; then
2159       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2160       USE_TOOLKIT_SCROLL_BARS=yes
2161     fi
2162   elif test "${HAVE_GTK}" = "yes"; then
2163     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2164     USE_TOOLKIT_SCROLL_BARS=yes
2165   elif test "${HAVE_CARBON}" = "yes"; then
2166     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2167     USE_TOOLKIT_SCROLL_BARS=yes
2168   fi
2169 fi
2170
2171 dnl See if XIM is available.
2172 AC_TRY_COMPILE([
2173           #include <X11/Xlib.h>
2174           #include <X11/Xresource.h>],
2175          [XIMProc  callback;],
2176          HAVE_XIM=yes
2177          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available]),
2178          HAVE_XIM=no)
2179
2180 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2181
2182 if test "${with_xim}" != "no"; then
2183   AC_DEFINE(USE_XIM, 1,
2184             [Define to 1 if we should use XIM, if it is available.])
2185 fi
2186
2187
2188 if test "${HAVE_XIM}" != "no"; then
2189   late_CFLAGS=$CFLAGS
2190   if test "$GCC" = yes; then
2191     CFLAGS="$CFLAGS --pedantic-errors"
2192   fi
2193   AC_TRY_COMPILE([
2194 #include <X11/Xlib.h>
2195 #include <X11/Xresource.h>],
2196 [Display *display;
2197 XrmDatabase db;
2198 char *res_name;
2199 char *res_class;
2200 XIMProc  callback;
2201 XPointer *client_data;
2202 #ifndef __GNUC__
2203 /* If we're not using GCC, it's probably not XFree86, and this is
2204    probably right, but we can't use something like --pedantic-errors.  */
2205 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2206                                            char*, XIMProc, XPointer*);
2207 #endif
2208 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2209    client_data);],
2210     [emacs_cv_arg6_star=yes])
2211   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2212          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2213 either XPointer or XPointer*.])dnl
2214   if test "$emacs_cv_arg6_star" = yes; then
2215     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2216   else
2217     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2218   fi
2219   CFLAGS=$late_CFLAGS
2220 fi
2221
2222 ### Use -lXpm if available, unless `--with-xpm=no'.
2223 HAVE_XPM=no
2224 if test "${HAVE_X11}" = "yes"; then
2225   if test "${with_xpm}" != "no"; then
2226     AC_CHECK_HEADER(X11/xpm.h,
2227       AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
2228     if test "${HAVE_XPM}" = "yes"; then
2229       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2230       AC_EGREP_CPP(no_return_alloc_pixels,
2231       [#include "X11/xpm.h"
2232 #ifndef XpmReturnAllocPixels
2233 no_return_alloc_pixels
2234 #endif
2235       ], HAVE_XPM=no, HAVE_XPM=yes)
2236
2237       if test "${HAVE_XPM}" = "yes"; then
2238         AC_MSG_RESULT(yes)
2239       else
2240         AC_MSG_RESULT(no)
2241       fi
2242     fi
2243   fi
2244
2245   if test "${HAVE_XPM}" = "yes"; then
2246     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm libary (-lXpm).])
2247   fi
2248 fi
2249
2250 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2251 HAVE_JPEG=no
2252 if test "${HAVE_X11}" = "yes"; then
2253   if test "${with_jpeg}" != "no"; then
2254     dnl Checking for jpeglib.h can lose because of a redefinition of
2255     dnl  HAVE_STDLIB_H.
2256     AC_CHECK_HEADER(jerror.h,
2257       AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes))
2258   fi
2259
2260   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2261   if test "${HAVE_JPEG}" = "yes"; then
2262     AC_DEFINE(HAVE_JPEG)
2263     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2264         [#include <jpeglib.h>
2265          version=JPEG_LIB_VERSION
2266 ],
2267         AC_DEFINE(HAVE_JPEG),
2268         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2269         HAVE_JPEG=no])
2270   fi
2271 fi
2272
2273 ### Use -lpng if available, unless `--with-png=no'.
2274 HAVE_PNG=no
2275 if test "${HAVE_X11}" = "yes"; then
2276   if test "${with_png}" != "no"; then
2277     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2278     # in /usr/include/libpng.
2279     AC_CHECK_HEADERS(png.h libpng/png.h)
2280     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2281       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2282     fi
2283   fi
2284
2285   if test "${HAVE_PNG}" = "yes"; then
2286     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2287   fi
2288 fi
2289
2290 ### Use -ltiff if available, unless `--with-tiff=no'.
2291 HAVE_TIFF=no
2292 if test "${HAVE_X11}" = "yes"; then
2293   if test "${with_tiff}" != "no"; then
2294     AC_CHECK_HEADER(tiffio.h,
2295       tifflibs="-lz -lm"
2296       # At least one tiff package requires the jpeg library.
2297       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2298       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
2299   fi
2300
2301   if test "${HAVE_TIFF}" = "yes"; then
2302     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2303   fi
2304 fi
2305
2306 ### Use -lgif if available, unless `--with-gif=no'.
2307 HAVE_GIF=no
2308 if test "${HAVE_X11}" = "yes"; then
2309   if test "${with_gif}" != "no"; then
2310     AC_CHECK_HEADER(gif_lib.h,
2311 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2312 # Earlier versions can crash Emacs.
2313       AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes))
2314   fi
2315
2316   if test "${HAVE_GIF}" = "yes"; then
2317     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have the ungif library (-lungif).])
2318   fi
2319 fi
2320
2321 dnl Check for malloc/malloc.h on darwin
2322 AC_CHECK_HEADER(malloc/malloc.h, AC_DEFINE(HAVE_MALLOC_MALLOC_H, 1, [Define to 1 if you have the <malloc/malloc.h> header file.]))
2323
2324 ### Use Mac OS X Carbon API to implement GUI.
2325 if test "${HAVE_CARBON}" = "yes"; then
2326   AC_DEFINE(HAVE_CARBON, 1, [Define to 1 if you are using the Carbon API on Mac OS X.])
2327   window_system=mac
2328   ## Specify the install directory
2329   carbon_appdir=
2330   if test "${carbon_appdir_x}" != ""; then
2331     case ${carbon_appdir_x} in
2332       y | ye | yes)  carbon_appdir=/Applications ;;
2333       * ) carbon_appdir=${carbon_appdir_x} ;;
2334     esac
2335   fi
2336   # We also have mouse menus.
2337   HAVE_MENUS=yes
2338 fi
2339
2340 ### Use session management (-lSM -lICE) if available
2341 HAVE_X_SM=no
2342 if test "${HAVE_X11}" = "yes"; then
2343   AC_CHECK_HEADER(X11/SM/SMlib.h,
2344     AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE))
2345
2346   if test "${HAVE_X_SM}" = "yes"; then
2347     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2348     case "$LIBS" in
2349       *-lSM*) ;;
2350       *)      LIBS="-lSM -lICE $LIBS" ;;
2351     esac
2352   fi
2353 fi
2354
2355 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2356 AC_CACHE_CHECK(whether netdb declares h_errno,
2357                emacs_cv_netdb_declares_h_errno,
2358 [AC_TRY_LINK([#include <netdb.h>],
2359   [return h_errno;],
2360   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2361 if test $emacs_cv_netdb_declares_h_errno = yes; then
2362   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2363 fi
2364
2365 AC_FUNC_ALLOCA
2366
2367 # fmod, logb, and frexp are found in -lm on most systems.
2368 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2369 AC_CHECK_LIB(m, sqrt)
2370
2371 # Check for mail-locking functions in a "mail" library.  Probably this should
2372 # have the same check as for liblockfile below.
2373 AC_CHECK_LIB(mail, maillock)
2374 dnl Debian, at least:
2375 AC_CHECK_LIB(lockfile, maillock)
2376 # If we have the shared liblockfile, assume we must use it for mail
2377 # locking (e.g. Debian).  If we couldn't link against liblockfile
2378 # (no liblockfile.a installed), ensure that we don't need to.
2379 if test "$ac_cv_lib_lockfile_maillock" = no; then
2380   dnl This works for files generally, not just executables.
2381   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2382   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2383                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2384   if test $ac_cv_prog_liblockfile = yes; then
2385     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2386 This probably means that movemail could lose mail.
2387 There may be a `development' package to install containing liblockfile.])
2388   else :
2389   fi
2390 fi
2391 AC_CHECK_FUNCS(touchlock)
2392 AC_CHECK_HEADERS(maillock.h)
2393
2394 AC_CHECK_FUNCS(gethostname getdomainname dup2 \
2395 rename closedir mkdir rmdir sysinfo getrusage \
2396 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
2397 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
2398 utimes setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2399 __fpending mblen mbrlen mbsinit strsignal setitimer ualarm index rindex \
2400 sendto recvfrom getsockopt setsockopt getsockname getpeername \
2401 gai_strerror mkstemp getline getdelim mremap memmove fsync bzero \
2402 memset memcmp difftime memcpy mempcpy mblen mbrlen posix_memalign)
2403
2404 AC_CHECK_HEADERS(sys/un.h)
2405
2406 AC_FUNC_MKTIME
2407 if test "$ac_cv_func_working_mktime" = no; then
2408   AC_DEFINE(BROKEN_MKTIME, 1, [Define to 1 if the mktime function is broken.])
2409 fi
2410
2411 AC_FUNC_GETLOADAVG
2412
2413 AC_FUNC_FSEEKO
2414
2415 AC_FUNC_GETPGRP
2416
2417 AC_FUNC_STRFTIME
2418
2419 # UNIX98 PTYs.
2420 AC_CHECK_FUNCS(grantpt)
2421
2422 # PTY-related GNU extensions.
2423 AC_CHECK_FUNCS(getpt)
2424
2425 # Check this now, so that we will NOT find the above functions in ncurses.
2426 # That is because we have not set up to link ncurses in lib-src.
2427 # It's better to believe a function is not available
2428 # than to expect to find it in ncurses.
2429 AC_CHECK_LIB(ncurses, tparm)
2430
2431 # Do we need the Hesiod library to provide the support routines?
2432 if test "$with_hesiod" = yes ; then
2433   # Don't set $LIBS here -- see comments above.
2434   resolv=no
2435   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2436      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2437                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2438   if test "$resolv" = yes ; then
2439     RESOLVLIB=-lresolv
2440     AC_DEFINE(HAVE_LIBRESOLV, 1,
2441               [Define to 1 if you have the resolv library (-lresolv).])
2442   else
2443     RESOLVLIB=
2444   fi
2445   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2446         AC_DEFINE(HAVE_LIBHESIOD, 1,
2447                   [Define to 1 if you have the hesiod library (-lhesiod).]),
2448         :, $RESOLVLIB)])
2449 fi
2450
2451 # These tell us which Kerberos-related libraries to use.
2452 if test "${with_kerberos+set}" = set; then
2453   AC_CHECK_LIB(com_err, com_err)
2454   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
2455   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
2456   AC_CHECK_LIB(krb5, krb5_init_context)
2457   if test "${with_kerberos5+set}" != set; then
2458     AC_CHECK_LIB(des425, des_cbc_encrypt,,
2459                  AC_CHECK_LIB(des, des_cbc_encrypt))
2460     AC_CHECK_LIB(krb4, krb_get_cred,,
2461                  AC_CHECK_LIB(krb, krb_get_cred))
2462   fi
2463
2464   if test "${with_kerberos5+set}" = set; then
2465     AC_CHECK_HEADERS(krb5.h)
2466   else
2467     AC_CHECK_HEADERS(des.h,,
2468                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2469                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2470     AC_CHECK_HEADERS(krb.h,,
2471                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2472                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2473   fi
2474   AC_CHECK_HEADERS(com_err.h)
2475 fi
2476
2477 # Solaris requires -lintl if you want strerror (which calls dgettext)
2478 # to return localized messages.
2479 AC_CHECK_LIB(intl, dgettext)
2480
2481 AC_MSG_CHECKING(whether localtime caches TZ)
2482 AC_CACHE_VAL(emacs_cv_localtime_cache,
2483 [if test x$ac_cv_func_tzset = xyes; then
2484 AC_TRY_RUN([#include <time.h>
2485 extern char **environ;
2486 unset_TZ ()
2487 {
2488   char **from, **to;
2489   for (to = from = environ; (*to = *from); from++)
2490     if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
2491       to++;
2492 }
2493 char TZ_GMT0[] = "TZ=GMT0";
2494 char TZ_PST8[] = "TZ=PST8";
2495 main()
2496 {
2497   time_t now = time ((time_t *) 0);
2498   int hour_GMT0, hour_unset;
2499   if (putenv (TZ_GMT0) != 0)
2500     exit (1);
2501   hour_GMT0 = localtime (&now)->tm_hour;
2502   unset_TZ ();
2503   hour_unset = localtime (&now)->tm_hour;
2504   if (putenv (TZ_PST8) != 0)
2505     exit (1);
2506   if (localtime (&now)->tm_hour == hour_GMT0)
2507     exit (1);
2508   unset_TZ ();
2509   if (localtime (&now)->tm_hour != hour_unset)
2510     exit (1);
2511   exit (0);
2512 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2513 [# If we have tzset, assume the worst when cross-compiling.
2514 emacs_cv_localtime_cache=yes])
2515 else
2516         # If we lack tzset, report that localtime does not cache TZ,
2517         # since we can't invalidate the cache if we don't have tzset.
2518         emacs_cv_localtime_cache=no
2519 fi])dnl
2520 AC_MSG_RESULT($emacs_cv_localtime_cache)
2521 if test $emacs_cv_localtime_cache = yes; then
2522   AC_DEFINE(LOCALTIME_CACHE, 1,
2523             [Define to 1 if localtime caches TZ.])
2524 fi
2525
2526 if test "x$HAVE_TIMEVAL" = xyes; then
2527   AC_CHECK_FUNCS(gettimeofday)
2528   if test $ac_cv_func_gettimeofday = yes; then
2529     AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
2530                    emacs_cv_gettimeofday_two_arguments,
2531     [AC_TRY_COMPILE([
2532 #ifdef TIME_WITH_SYS_TIME
2533 #include <sys/time.h>
2534 #include <time.h>
2535 #else
2536 #ifdef HAVE_SYS_TIME_H
2537 #include <sys/time.h>
2538 #else
2539 #include <time.h>
2540 #endif
2541 #endif],
2542       [struct timeval time;
2543        gettimeofday (&time, 0);],
2544       emacs_cv_gettimeofday_two_arguments=yes,
2545       emacs_cv_gettimeofday_two_arguments=no)])
2546     if test $emacs_cv_gettimeofday_two_arguments = no; then
2547       AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT, 1,
2548                 [Define to 1 if gettimeofday accepts only one argument.])
2549     fi
2550   fi
2551 fi
2552
2553 # This defines (or not) HAVE_TZNAME and HAVE_TM_ZONE.
2554 AC_STRUCT_TIMEZONE
2555
2556 dnl Note that AC_STRUCT_TIMEZONE doesn't do what you might expect.
2557 if test "$ac_cv_func_gettimeofday" = yes; then
2558   AC_CACHE_CHECK([for struct timezone], emacs_cv_struct_timezone,
2559     [AC_TRY_COMPILE([#include <sys/time.h>],
2560     [struct timezone tz;],
2561     dnl It may be that we can't call gettimeofday with a non-null pointer,
2562     dnl even though we have struct timezone (e.g. HPUX).  In that case
2563     dnl we'll lie about struct timezone.
2564     [AC_TRY_RUN([
2565 #ifdef TIME_WITH_SYS_TIME
2566 #include <sys/time.h>
2567 #include <time.h>
2568 #else
2569 #ifdef HAVE_SYS_TIME_H
2570 #include <sys/time.h>
2571 #else
2572 #include <time.h>
2573 #endif
2574 #endif
2575 main () {
2576   struct timeval time;
2577   struct timezone dummy;
2578   exit (gettimeofday (&time, &dummy));
2579 }],
2580       emacs_cv_struct_timezone=yes,
2581       emacs_cv_struct_timezone=no, emacs_cv_struct_timezone=yes)],
2582     emacs_cv_struct_timezone=no)])
2583 fi
2584
2585 ok_so_far=yes
2586 AC_CHECK_FUNC(socket, , ok_so_far=no)
2587 if test $ok_so_far = yes; then
2588   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2589 fi
2590 if test $ok_so_far = yes; then
2591   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
2592 fi
2593 if test $ok_so_far = yes; then
2594 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
2595   AC_DEFINE(HAVE_INET_SOCKETS, 1,
2596             [Define to 1 if you have inet sockets.])
2597 fi
2598
2599 AC_CHECK_HEADERS(sys/ioctl.h)
2600
2601 if test -f /usr/lpp/X11/bin/smt.exp; then
2602   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
2603             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
2604 fi
2605
2606 AC_MSG_CHECKING(whether system supports dynamic ptys)
2607 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
2608   AC_MSG_RESULT(yes)
2609   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
2610 else
2611   AC_MSG_RESULT(no)
2612 fi
2613
2614 AC_FUNC_FORK
2615
2616 dnl Adapted from Haible's version.
2617 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
2618   [AC_TRY_LINK([#include <langinfo.h>],
2619     [char* cs = nl_langinfo(CODESET);],
2620     emacs_cv_langinfo_codeset=yes,
2621     emacs_cv_langinfo_codeset=no)
2622   ])
2623 if test $emacs_cv_langinfo_codeset = yes; then
2624   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
2625     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
2626 fi
2627
2628 AC_CHECK_TYPES(size_t)
2629
2630 AC_TYPE_MBSTATE_T
2631
2632 dnl Restrict could probably be used effectively other than in regex.c.
2633 AC_CACHE_CHECK([for C restrict keyword], emacs_cv_c_restrict,
2634   [AC_TRY_COMPILE([void fred (int *restrict x);], [],
2635                   emacs_cv_c_restrict=yes,
2636                   [AC_TRY_COMPILE([void fred (int *__restrict x);], [],
2637                                   emacs_cv_c_restrict=__restrict,
2638                                   emacs_cv_c_restrict=no)])])
2639 case "$emacs_cv_c_restrict" in
2640   yes) emacs_restrict=restrict;;
2641   no) emacs_restrict="";;
2642   *) emacs_restrict="$emacs_cv_c_restrict";;
2643 esac
2644 if test "$emacs_restrict" != __restrict; then
2645   AC_DEFINE_UNQUOTED(__restrict, $emacs_restrict,
2646     [Define to compiler's equivalent of C99 restrict keyword.
2647      Don't define if equivalent is `__restrict'.])
2648 fi
2649
2650 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
2651   [AC_TRY_COMPILE([void fred (int x[__restrict]);], [],
2652                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
2653 if test "$emacs_cv_c_restrict_arr" = yes; then
2654   AC_DEFINE(__restrict_arr, __restrict,
2655     [Define to compiler's equivalent of C99 restrict keyword in array
2656      declarations.  Define as empty for no equivalent.])
2657 fi
2658
2659 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
2660 dnl how the tty code is related to POSIX and/or other versions of termios.
2661 dnl The following looks like a useful start.
2662 dnl
2663 dnl AC_SYS_POSIX_TERMIOS
2664 dnl if test $ac_cv_sys_posix_termios = yes; then
2665 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
2666 dnl                                and macros for terminal control.])
2667 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
2668 dnl fi
2669
2670 dnl Fixme: Use AC_FUNC_MEMCMP since memcmp is used.  (Needs libobj replacement.)
2671
2672 # Set up the CFLAGS for real compilation, so we can substitute it.
2673 CFLAGS="$REAL_CFLAGS"
2674 CPPFLAGS="$REAL_CPPFLAGS"
2675
2676 #### Find out which version of Emacs this is.
2677 [version=`grep 'defconst[        ]*emacs-version' ${srcdir}/lisp/version.el \
2678          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`]
2679 if test x"${version}" = x; then
2680   AC_MSG_ERROR([can't find current emacs version in `${srcdir}/lisp/version.el'.])
2681 fi
2682
2683 ### Specify what sort of things we'll be editing into Makefile and config.h.
2684 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2685 AC_SUBST(version)
2686 AC_SUBST(configuration)
2687 AC_SUBST(canonical)
2688 AC_SUBST(srcdir)
2689 AC_SUBST(prefix)
2690 AC_SUBST(exec_prefix)
2691 AC_SUBST(bindir)
2692 AC_SUBST(datadir)
2693 AC_SUBST(sharedstatedir)
2694 AC_SUBST(libexecdir)
2695 AC_SUBST(mandir)
2696 AC_SUBST(infodir)
2697 AC_SUBST(lispdir)
2698 AC_SUBST(locallisppath)
2699 AC_SUBST(lisppath)
2700 AC_SUBST(x_default_search_path)
2701 AC_SUBST(etcdir)
2702 AC_SUBST(archlibdir)
2703 AC_SUBST(docdir)
2704 AC_SUBST(bitmapdir)
2705 AC_SUBST(gamedir)
2706 AC_SUBST(gameuser)
2707 AC_SUBST(c_switch_system)
2708 AC_SUBST(c_switch_machine)
2709 AC_SUBST(LD_SWITCH_X_SITE)
2710 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2711 AC_SUBST(C_SWITCH_X_SITE)
2712 AC_SUBST(CFLAGS)
2713 AC_SUBST(X_TOOLKIT_TYPE)
2714 AC_SUBST(machfile)
2715 AC_SUBST(opsysfile)
2716 AC_SUBST(GETLOADAVG_LIBS)
2717 AC_SUBST(carbon_appdir)
2718
2719 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
2720                    [Define to the canonical Emacs configuration name.])
2721 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
2722                    [Define to the options passed to configure.])
2723 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}",
2724                    [Define to the used machine dependent file.])
2725 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
2726                    [Define to the used os dependent file.])
2727 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE},
2728 [Define LD_SWITCH_X_SITE to contain any special flags your loader
2729  may need to deal with X Windows.  For instance, if you've defined
2730  HAVE_X_WINDOWS above and your X libraries aren't in a place that
2731  your loader can find on its own, you might want to add "-L/..." or
2732  something similar.])
2733 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX},
2734                    [Define LD_SWITCH_X_SITE_AUX with an -R option
2735                     in case it's needed (for Solaris, for example).])
2736 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE},
2737 [Define C_SWITCH_X_SITE to contain any special flags your compiler
2738  may need to deal with X Windows.  For instance, if you've defined
2739  HAVE_X_WINDOWS above and your X include files aren't in a place
2740  that your compiler can find on its own, you might want to add
2741  "-I/..." or something similar.])
2742 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC},
2743                    [Define to the unexec source file name.])
2744
2745 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2746   AC_DEFINE(HAVE_X_WINDOWS, 1,
2747             [Define to 1 if you want to use the X window system.])
2748 fi
2749 if test "${USE_X_TOOLKIT}" != "none" ; then
2750   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
2751 fi
2752 if test "${HAVE_X11}" = "yes" ; then
2753   AC_DEFINE(HAVE_X11, 1,
2754             [Define to 1 if you want to use version 11 of X windows.
2755              Otherwise, Emacs expects to use version 10.])
2756 fi
2757 if test "${HAVE_XFREE386}" = "yes" ; then
2758   AC_DEFINE(HAVE_XFREE386, 1, [Define to 1 if you're using XFree386.])
2759 fi
2760 if test "${HAVE_MENUS}" = "yes" ; then
2761   AC_DEFINE(HAVE_MENUS, 1,
2762             [Define to 1 if you have mouse menus.
2763              (This is automatic if you use X, but the option to specify it remains.)
2764              It is also defined with other window systems that support xmenu.c.])
2765 fi
2766 if test "${GNU_MALLOC}" = "yes" ; then
2767   AC_DEFINE(GNU_MALLOC, 1,
2768             [Define to 1 if you want to use the GNU memory allocator.])
2769 fi
2770 if test "${REL_ALLOC}" = "yes" ; then
2771   AC_DEFINE(REL_ALLOC, 1,
2772             [Define REL_ALLOC if you want to use the relocating allocator for
2773              buffer space.])
2774 fi
2775
2776 AH_TOP([/* GNU Emacs site configuration template file.
2777    Copyright (C) 1988, 1993, 1994, 1999, 2000, 2002, 2004
2778              Free Software Foundation, Inc.
2779
2780 This file is part of GNU Emacs.
2781
2782 GNU Emacs is free software; you can redistribute it and/or modify
2783 it under the terms of the GNU General Public License as published by
2784 the Free Software Foundation; either version 2, or (at your option)
2785 any later version.
2786
2787 GNU Emacs is distributed in the hope that it will be useful,
2788 but WITHOUT ANY WARRANTY; without even the implied warranty of
2789 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
2790 GNU General Public License for more details.
2791
2792 You should have received a copy of the GNU General Public License
2793 along with GNU Emacs; see the file COPYING.  If not, write to the
2794 Free Software Foundation, Inc., 59 Temple Place - Suite 330,
2795 Boston, MA 02111-1307, USA.  */
2796
2797
2798 /* No code in Emacs #includes config.h twice, but some bits of code
2799    intended to work with other packages as well (like gmalloc.c)
2800    think they can include it as many times as they like.  */
2801 #ifndef EMACS_CONFIG_H
2802 #define EMACS_CONFIG_H
2803 ])dnl
2804
2805 AH_BOTTOM([
2806 /* If we're using any sort of window system, define some consequences.  */
2807 #ifdef HAVE_X_WINDOWS
2808 #define HAVE_WINDOW_SYSTEM
2809 #define MULTI_KBOARD
2810 #define HAVE_MOUSE
2811 #endif
2812
2813 /* If we're using the Carbon API on Mac OS X, define a few more
2814    variables as well.  */
2815 #ifdef HAVE_CARBON
2816 #define HAVE_WINDOW_SYSTEM
2817 #define HAVE_MOUSE
2818 #endif
2819
2820 /* Define USER_FULL_NAME to return a string
2821    that is the user's full name.
2822    It can assume that the variable `pw'
2823    points to the password file entry for this user.
2824
2825    At some sites, the pw_gecos field contains
2826    the user's full name.  If neither this nor any other
2827    field contains the right thing, use pw_name,
2828    giving the user's login name, since that is better than nothing.  */
2829 #define USER_FULL_NAME pw->pw_gecos
2830
2831 /* Define AMPERSAND_FULL_NAME if you use the convention
2832    that & in the full name stands for the login id.  */
2833 /* Turned on June 1996 supposing nobody will mind it.  */
2834 #define AMPERSAND_FULL_NAME
2835
2836 /* We have blockinput.h.  */
2837 #define DO_BLOCK_INPUT
2838
2839 /* Define HAVE_SOUND if we have sound support.  We know it works
2840    and compiles only on the specified platforms.   For others,
2841    it probably doesn't make sense to try.  */
2842
2843 #if defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
2844 #ifdef HAVE_MACHINE_SOUNDCARD_H
2845 #define HAVE_SOUND 1
2846 #endif
2847 #ifdef HAVE_SYS_SOUNDCARD_H
2848 #define HAVE_SOUND 1
2849 #endif
2850 #ifdef HAVE_SOUNDCARD_H
2851 #define HAVE_SOUND 1
2852 #endif
2853 #endif /* __FreeBSD__ || __NetBSD__ || __linux__  */
2854
2855 /* If using GNU, then support inline function declarations. */
2856 /* Don't try to switch on inline handling as detected by AC_C_INLINE
2857    generally, because even if non-gcc compilers accept `inline', they
2858    may reject `extern inline'.  */
2859 #if defined (__GNUC__) && defined (OPTIMIZE)
2860 #define INLINE __inline__
2861 #else
2862 #define INLINE
2863 #endif
2864
2865 /* Include the os and machine dependent files.  */
2866 #include config_opsysfile
2867 #include config_machfile
2868
2869 /* Load in the conversion definitions if this system
2870    needs them and the source file being compiled has not
2871    said to inhibit this.  There should be no need for you
2872    to alter these lines.  */
2873
2874 #ifdef SHORTNAMES
2875 #ifndef NO_SHORTNAMES
2876 #include "../shortnames/remap.h"
2877 #endif /* not NO_SHORTNAMES */
2878 #endif /* SHORTNAMES */
2879
2880 /* If no remapping takes place, static variables cannot be dumped as
2881    pure, so don't worry about the `static' keyword. */
2882 #ifdef NO_REMAP
2883 #undef static
2884 #endif
2885
2886 /* Define `subprocesses' should be defined if you want to
2887    have code for asynchronous subprocesses
2888    (as used in M-x compile and M-x shell).
2889    These do not work for some USG systems yet;
2890    for the ones where they work, the s/SYSTEM.h file defines this flag.  */
2891
2892 #ifndef VMS
2893 #ifndef USG
2894 /* #define subprocesses */
2895 #endif
2896 #endif
2897
2898 /* SIGTYPE is the macro we actually use.  */
2899 #ifndef SIGTYPE
2900 #define SIGTYPE RETSIGTYPE
2901 #endif
2902
2903 #ifdef emacs /* Don't do this for lib-src.  */
2904 /* Tell regex.c to use a type compatible with Emacs.  */
2905 #define RE_TRANSLATE_TYPE Lisp_Object
2906 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
2907 #ifdef make_number
2908 /* If make_number is a macro, use it.  */
2909 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
2910 #else
2911 /* If make_number is a function, avoid it.  */
2912 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
2913 #endif
2914 #endif
2915
2916 /* Avoid link-time collision with system mktime if we will use our own.  */
2917 #if ! HAVE_MKTIME || BROKEN_MKTIME
2918 #define mktime emacs_mktime
2919 #endif
2920
2921 #define my_strftime nstrftime   /* for strftime.c */
2922
2923 /* The rest of the code currently tests the CPP symbol BSTRING.
2924    Override any claims made by the system-description files.
2925    Note that on some SCO version it is possible to have bcopy and not bcmp.  */
2926 #undef BSTRING
2927 #if defined (HAVE_BCOPY) && defined (HAVE_BCMP)
2928 #define BSTRING
2929 #endif
2930
2931 /* Some of the files of Emacs which are intended for use with other
2932    programs assume that if you have a config.h file, you must declare
2933    the type of getenv.
2934
2935    This declaration shouldn't appear when alloca.s or Makefile.in
2936    includes config.h.  */
2937 #ifndef NOT_C_CODE
2938 extern char *getenv ();
2939 #endif
2940
2941 /* These default definitions are good for almost all machines.
2942    The exceptions override them in m/MACHINE.h.  */
2943
2944 #ifndef BITS_PER_CHAR
2945 #define BITS_PER_CHAR 8
2946 #endif
2947
2948 #ifndef BITS_PER_SHORT
2949 #define BITS_PER_SHORT 16
2950 #endif
2951
2952 /* Note that lisp.h uses this in a preprocessor conditional, so it
2953    would not work to use sizeof.  That being so, we do all of them
2954    without sizeof, for uniformity's sake.  */
2955 #ifndef BITS_PER_INT
2956 #define BITS_PER_INT 32
2957 #endif
2958
2959 #ifndef BITS_PER_LONG
2960 #ifdef _LP64
2961 #define BITS_PER_LONG 64
2962 #else
2963 #define BITS_PER_LONG 32
2964 #endif
2965 #endif
2966
2967 /* Define if the compiler supports function prototypes.  It may do so
2968    but not define __STDC__ (e.g. DEC C by default) or may define it as
2969    zero.  */
2970 #undef PROTOTYPES
2971 /* For mktime.c:  */
2972 #ifndef __P
2973 # if defined PROTOTYPES
2974 #  define __P(args) args
2975 # else
2976 #  define __P(args) ()
2977 # endif  /* GCC.  */
2978 #endif /* __P */
2979
2980 /* Don't include "string.h" or <stdlib.h> in non-C code.  */
2981 #ifndef NOT_C_CODE
2982 #ifdef HAVE_STRING_H
2983 #include "string.h"
2984 #endif
2985 #ifdef HAVE_STRINGS_H
2986 #include "strings.h"  /* May be needed for bcopy & al. */
2987 #endif
2988 #ifdef HAVE_STDLIB_H
2989 #include <stdlib.h>
2990 #endif
2991 #ifndef __GNUC__
2992 # ifdef HAVE_ALLOCA_H
2993 #  include <alloca.h>
2994 # else /* AIX files deal with #pragma.  */
2995 #  ifndef alloca /* predefined by HP cc +Olibcalls */
2996 char *alloca ();
2997 #  endif
2998 # endif /* HAVE_ALLOCA_H */
2999 #endif /* __GNUC__ */
3000 #ifndef HAVE_SIZE_T
3001 typedef unsigned size_t;
3002 #endif
3003 #endif /* NOT_C_CODE */
3004
3005 /* Define HAVE_X_I18N if we have usable i18n support.  */
3006
3007 #ifdef HAVE_X11R6
3008 #define HAVE_X_I18N
3009 #elif defined HAVE_X11R5 && !defined X11R5_INHIBIT_I18N
3010 #define HAVE_X_I18N
3011 #endif
3012
3013 /* Define HAVE_X11R6_XIM if we have usable X11R6-style XIM support.  */
3014
3015 #if defined HAVE_X11R6 && !defined INHIBIT_X11R6_XIM
3016 #define HAVE_X11R6_XIM
3017 #endif
3018
3019 /* Should we enable expensive run-time checking of data types?  */
3020 #undef ENABLE_CHECKING
3021
3022 #if defined __GNUC__ && (__GNUC__ > 2 \
3023                          || (__GNUC__ == 2 && __GNUC_MINOR__ >= 5))
3024 #define NO_RETURN       __attribute__ ((__noreturn__))
3025 #else
3026 #define NO_RETURN       /* nothing */
3027 #endif
3028
3029 /* These won't be used automatically yet.  We also need to know, at least,
3030    that the stack is continuous.  */
3031 #ifdef __GNUC__
3032 #  ifndef GC_SETJMP_WORKS
3033   /* GC_SETJMP_WORKS is nearly always appropriate for GCC --
3034      see NON_SAVING_SETJMP in the target descriptions.  */
3035   /* Exceptions (see NON_SAVING_SETJMP in target description) are ns32k,
3036      SCO5 non-ELF (but Emacs specifies ELF) and SVR3 on x86.
3037      Fixme: Deal with ns32k, SVR3.  */
3038 #    define GC_SETJMP_WORKS 1
3039 #  endif
3040 #  ifndef GC_LISP_OBJECT_ALIGNMENT
3041 #    define GC_LISP_OBJECT_ALIGNMENT (__alignof__ (Lisp_Object))
3042 #  endif
3043 #endif
3044
3045 #ifndef HAVE_BCOPY
3046 #define bcopy(a,b,s) memcpy (b,a,s)
3047 #endif
3048 #ifndef HAVE_BZERO
3049 #define bzero(a,s) memset (a,0,s)
3050 #endif
3051 #ifndef HAVE_BCMP
3052 #define BCMP memcmp
3053 #endif
3054
3055 #endif /* EMACS_CONFIG_H */
3056
3057 /*
3058 Local Variables:
3059 mode: c
3060 End:
3061 */
3062 ])dnl
3063
3064 #### Report on what we decided to do.
3065 #### Report GTK as a toolkit, even if it doesn't use Xt.
3066 #### It makes printing result more understandable as using GTK sets
3067 #### toolkit_scroll_bars to yes by default.
3068 if test "${HAVE_GTK}" = "yes"; then
3069   USE_X_TOOLKIT=GTK
3070 fi
3071
3072 echo "
3073 Configured for \`${canonical}'.
3074
3075   Where should the build process find the source code?    ${srcdir}
3076   What operating system and machine description files should Emacs use?
3077         \`${opsysfile}' and \`${machfile}'
3078   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3079   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3080   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3081   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3082   What window system should Emacs use?                    ${window_system}
3083   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3084
3085 if test -n "${x_includes}"; then
3086 echo "  Where do we find X Windows header files?                ${x_includes}"
3087 else
3088 echo "  Where do we find X Windows header files?                Standard dirs"
3089 fi
3090 if test -n "${x_libraries}"; then
3091 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3092 else
3093 echo "  Where do we find X Windows libraries?                   Standard dirs"
3094 fi
3095
3096 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3097 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3098 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3099 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3100 echo "  Does Emacs use -lungif?                                 ${HAVE_GIF}"
3101 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3102 echo "  Does Emacs use X toolkit scroll bars?                   ${USE_TOOLKIT_SCROLL_BARS}"
3103 echo
3104
3105 if test $USE_XASSERTS = yes; then
3106    echo "  Compiling with asserts turned on."
3107    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3108    echo
3109 fi
3110
3111
3112
3113 # Remove any trailing slashes in these variables.
3114 [test "${prefix}" != NONE &&
3115   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3116 test "${exec_prefix}" != NONE &&
3117   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3118
3119 ## Check if the C preprocessor will convert `..' to `. .'.  If so, set
3120 ## CPP_NEED_TRADITIONAL to `yes' so that the code to generate Makefile
3121 ## from Makefile.c can correctly provide the arg `-traditional' to the
3122 ## C preprocessor.
3123
3124 AC_EGREP_CPP(yes..yes,
3125         [yes..yes],
3126         CPP_NEED_TRADITIONAL=no,
3127         CPP_NEED_TRADITIONAL=yes)
3128
3129 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
3130         man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
3131         lisp/Makefile lispref/Makefile lispintro/Makefile leim/Makefile, [
3132
3133 ### Make the necessary directories, if they don't exist.
3134 for dir in etc lisp ; do
3135   test -d ${dir} || mkdir ${dir}
3136 done
3137
3138 # Build src/Makefile from ${srcdir}/src/Makefile.c
3139 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
3140 # This must be done after src/config.h is built, since we rely on that file.
3141
3142 # Now get this: Some word that is part of the ${srcdir} directory name
3143 # or the ${configuration} value might, just might, happen to be an
3144 # identifier like `sun4' or `i386' or something, and be predefined by
3145 # the C preprocessor to some helpful value like 1, or maybe the empty
3146 # string.  Needless to say consequent macro substitutions are less
3147 # than conducive to the makefile finding the correct directory.
3148 [undefs="`echo $top_srcdir $configuration $canonical |
3149 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
3150     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
3151 `"]
3152
3153 echo creating src/epaths.h
3154 ${MAKE-make} epaths-force
3155
3156 # As of 2000-11-19, newest development versions of GNU cpp preprocess
3157 # `..' to `. .'  unless invoked with -traditional
3158
3159 if test "x$GCC" = xyes && test "x$CPP_NEED_TRADITIONAL" = xyes; then
3160   CPPFLAGS="$CPPFLAGS -traditional"
3161 fi
3162
3163 echo creating lib-src/Makefile
3164 ( cd lib-src
3165   rm -f junk.c junk1.c junk2.c
3166   sed -e '/start of cpp stuff/q' \
3167       < Makefile.c > junk1.c
3168   sed -e '1,/start of cpp stuff/d'\
3169       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3170       < Makefile.c > junk.c
3171   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3172       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3173   cat junk1.c junk2.c > Makefile.new
3174   rm -f junk.c junk1.c junk2.c
3175   chmod 444 Makefile.new
3176   mv -f Makefile.new Makefile
3177 )
3178
3179 echo creating src/Makefile
3180 ( cd src
3181   rm -f junk.c junk1.c junk2.c
3182   sed -e '/start of cpp stuff/q' \
3183       < Makefile.c > junk1.c
3184   sed -e '1,/start of cpp stuff/d'\
3185       -e 's,/\*\*/#\(.*\)$,/* \1 */,' \
3186       < Makefile.c > junk.c
3187   $CPP $undefs -I. -I$srcdir/src $CPPFLAGS junk.c | \
3188       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
3189   cat junk1.c junk2.c > Makefile.new
3190   rm -f junk.c junk1.c junk2.c
3191   chmod 444 Makefile.new
3192   mv -f Makefile.new Makefile
3193 )
3194
3195 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3196   echo creating src/.gdbinit
3197   echo source $srcdir/src/.gdbinit > src/.gdbinit
3198 fi
3199
3200 # This is how we know whether to re-run configure in certain cases.
3201 touch src/config.stamp
3202
3203 ], [GCC="$GCC" NON_GNU_CPP="$NON_GNU_CPP" CPP="$CPP" CPP_NEED_TRADITIONAL="$CPP_NEED_TRADITIONAL" CPPFLAGS="$CPPFLAGS"])
3204
3205 m4_if(dnl       Do not change this comment
3206    arch-tag: 156a4dd5-bddc-4d18-96ac-f37742cf6a5e
3207 )dnl