code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/debug.el

   1 ;;; debug.el --- debuggers and related commands for Emacs
   2
   3 ;; Copyright (C) 1985, 1986, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: lisp, tools, maint
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This is a major mode documented in the Emacs manual.
  28
  29 ;;; Code:
  30
  31 (defvar debug-function-list nil
  32   "List of functions currently set for debug on entry.")
  33
  34 (defvar debugger-step-after-exit nil
  35   "Non-nil means \"single-step\" after the debugger exits.")
  36
  37 (defvar debugger-value nil
  38   "This is the value for the debugger to return, when it returns.")
  39
  40 (defvar debugger-old-buffer nil
  41   "This is the buffer that was current when the debugger was entered.")
  42
  43 (defvar debugger-outer-match-data)
  44 (defvar debugger-outer-load-read-function)
  45 (defvar debugger-outer-overriding-local-map)
  46 (defvar debugger-outer-overriding-terminal-local-map)
  47 (defvar debugger-outer-track-mouse)
  48 (defvar debugger-outer-last-command)
  49 (defvar debugger-outer-this-command)
  50 (defvar debugger-outer-unread-command-char)
  51 (defvar debugger-outer-unread-command-events)
  52 (defvar debugger-outer-last-input-event)
  53 (defvar debugger-outer-last-command-event)
  54 (defvar debugger-outer-last-nonmenu-event)
  55 (defvar debugger-outer-last-event-frame)
  56 (defvar debugger-outer-standard-input)
  57 (defvar debugger-outer-standard-output)
  58 (defvar debugger-outer-cursor-in-echo-area)
  59
  60 ;;;###autoload
  61 (setq debugger 'debug)
  62 ;;;###autoload
  63 (defun debug (&rest debugger-args)
  64   "Enter debugger.  To return, type \\<debugger-mode-map>`\\[debugger-continue]'.
  65 Arguments are mainly for use when this is called from the internals
  66 of the evaluator.
  67
  68 You may call with no args, or you may pass nil as the first arg and
  69 any other args you like.  In that case, the list of args after the
  70 first will be printed into the backtrace buffer."
  71   (interactive)
  72   (message "Entering debugger...")
  73   (let (debugger-value
  74         (debug-on-error nil)
  75         (debug-on-quit nil)
  76         (debugger-buffer (let ((default-major-mode 'fundamental-mode))
  77                            (get-buffer-create "*Backtrace*")))
  78         (debugger-old-buffer (current-buffer))
  79         (debugger-step-after-exit nil)
  80         ;; Don't keep reading from an executing kbd macro!
  81         (executing-kbd-macro nil)
  82         ;; Save the outer values of these vars for the `e' command
  83         ;; before we replace the values.
  84         (debugger-outer-match-data (match-data))
  85         (debugger-outer-load-read-function load-read-function)
  86         (debugger-outer-overriding-local-map overriding-local-map)
  87         (debugger-outer-overriding-terminal-local-map
  88          overriding-terminal-local-map)
  89         (debugger-outer-track-mouse track-mouse)
  90         (debugger-outer-last-command last-command)
  91         (debugger-outer-this-command this-command)
  92         (debugger-outer-unread-command-char unread-command-char)
  93         (debugger-outer-unread-command-events unread-command-events)
  94         (debugger-outer-last-input-event last-input-event)
  95         (debugger-outer-last-command-event last-command-event)
  96         (debugger-outer-last-nonmenu-event last-nonmenu-event)
  97         (debugger-outer-last-event-frame last-event-frame)
  98         (debugger-outer-standard-input standard-input)
  99         (debugger-outer-standard-output standard-output)
 100         (debugger-outer-cursor-in-echo-area cursor-in-echo-area))
 101     ;; Set this instead of binding it, so that `q'
 102     ;; will not restore it.
 103     (setq overriding-terminal-local-map nil)
 104     ;; Don't let these magic variables affect the debugger itself.
 105     (let ((last-command nil) this-command track-mouse
 106           (unread-command-char -1) unread-command-events
 107           last-input-event last-command-event last-nonmenu-event
 108           last-event-frame
 109           overriding-local-map
 110           load-read-function
 111           (standard-input t) (standard-output t)
 112           (cursor-in-echo-area nil))
 113       (unwind-protect
 114           (save-excursion
 115             (save-window-excursion
 116               (pop-to-buffer debugger-buffer)
 117               (erase-buffer)
 118               (let ((standard-output (current-buffer))
 119                     (print-escape-newlines t)
 120                     (print-length 50))
 121                 (backtrace))
 122               (goto-char (point-min))
 123               (debugger-mode)
 124               (delete-region (point)
 125                              (progn
 126                                (search-forward "\n  debug(")
 127                                (forward-line 1)
 128                                (point)))
 129               (debugger-reenable)
 130               ;; lambda is for debug-on-call when a function call is next.
 131               ;; debug is for debug-on-entry function called.
 132               (cond ((memq (car debugger-args) '(lambda debug))
 133                      (insert "Entering:\n")
 134                      (if (eq (car debugger-args) 'debug)
 135                          (progn
 136                            ;; Skip the frames for backtrace-debug, byte-code,
 137                            ;; and debug.
 138                            (backtrace-debug 3 t)
 139                            (delete-char 1)
 140                            (insert ?*)
 141                            (beginning-of-line))))
 142                     ;; Exiting a function.
 143                     ((eq (car debugger-args) 'exit)
 144                      (insert "Return value: ")
 145                      (setq debugger-value (nth 1 debugger-args))
 146                      (prin1 debugger-value (current-buffer))
 147                      (insert ?\n)
 148                      (delete-char 1)
 149                      (insert ? )
 150                      (beginning-of-line))
 151                     ;; Debugger entered for an error.
 152                     ((eq (car debugger-args) 'error)
 153                      (insert "Signaling: ")
 154                      (prin1 (nth 1 debugger-args) (current-buffer))
 155                      (insert ?\n))
 156                     ;; debug-on-call, when the next thing is an eval.
 157                     ((eq (car debugger-args) t)
 158                      (insert "Beginning evaluation of function call form:\n"))
 159                     ;; User calls debug directly.
 160                     (t
 161                      (prin1 (if (eq (car debugger-args) 'nil)
 162                                 (cdr debugger-args) debugger-args)
 163                             (current-buffer))
 164                      (insert ?\n)))
 165               (message "")
 166               (let ((inhibit-trace t)
 167                     (standard-output nil)
 168                     (buffer-read-only t))
 169                 (message "")
 170                 ;; Make sure we unbind buffer-read-only in the right buffer.
 171                 (save-excursion
 172                   (recursive-edit)))))
 173         ;; Kill or at least neuter the backtrace buffer, so that users
 174         ;; don't try to execute debugger commands in an invalid context.
 175         (if (get-buffer-window debugger-buffer 'visible)
 176             ;; Still visible despite the save-window-excursion?  Maybe it
 177             ;; it's in a pop-up frame.  It would be annoying to delete and
 178             ;; recreate it every time the debugger stops, so instead we'll
 179             ;; erase it but leave it visible.
 180             (save-excursion
 181               (set-buffer debugger-buffer)
 182               (erase-buffer)
 183               (fundamental-mode))
 184           (kill-buffer debugger-buffer))
 185         (store-match-data debugger-outer-match-data)))
 186     ;; Put into effect the modified values of these variables
 187     ;; in case the user set them with the `e' command.
 188     (setq load-read-function debugger-outer-load-read-function)
 189     (setq overriding-local-map debugger-outer-overriding-local-map)
 190     (setq overriding-terminal-local-map
 191           debugger-outer-overriding-terminal-local-map)
 192     (setq track-mouse debugger-outer-track-mouse)
 193     (setq last-command debugger-outer-last-command)
 194     (setq this-command debugger-outer-this-command)
 195     (setq unread-command-char debugger-outer-unread-command-char)
 196     (setq unread-command-events debugger-outer-unread-command-events)
 197     (setq last-input-event debugger-outer-last-input-event)
 198     (setq last-command-event debugger-outer-last-command-event)
 199     (setq last-nonmenu-event debugger-outer-last-nonmenu-event)
 200     (setq last-event-frame debugger-outer-last-event-frame)
 201     (setq standard-input debugger-outer-standard-input)
 202     (setq standard-output debugger-outer-standard-output)
 203     (setq cursor-in-echo-area debugger-outer-cursor-in-echo-area)
 204     (setq debug-on-next-call debugger-step-after-exit)
 205     debugger-value))
 206 \f
 207 (defun debugger-step-through ()
 208   "Proceed, stepping through subexpressions of this expression.
 209 Enter another debugger on next entry to eval, apply or funcall."
 210   (interactive)
 211   (setq debugger-step-after-exit t)
 212   (message "Proceeding, will debug on next eval or call.")
 213   (exit-recursive-edit))
 214
 215 (defun debugger-continue ()
 216   "Continue, evaluating this expression without stopping."
 217   (interactive)
 218   (message "Continuing.")
 219   (exit-recursive-edit))
 220
 221 (defun debugger-return-value (val)
 222   "Continue, specifying value to return.
 223 This is only useful when the value returned from the debugger
 224 will be used, such as in a debug on exit from a frame."
 225   (interactive "XReturn value (evaluated): ")
 226   (setq debugger-value val)
 227   (princ "Returning " t)
 228   (prin1 debugger-value)
 229   (exit-recursive-edit))
 230
 231 (defun debugger-jump ()
 232   "Continue to exit from this frame, with all debug-on-entry suspended."
 233   (interactive)
 234   ;; Compensate for the two extra stack frames for debugger-jump.
 235   (let ((debugger-frame-offset (+ debugger-frame-offset 2)))
 236     (debugger-frame))
 237   ;; Turn off all debug-on-entry functions
 238   ;; but leave them in the list.
 239   (let ((list debug-function-list))
 240     (while list
 241       (fset (car list)
 242             (debug-on-entry-1 (car list) (symbol-function (car list)) nil))
 243       (setq list (cdr list))))
 244   (message "Continuing through this frame")
 245   (exit-recursive-edit))
 246
 247 (defun debugger-reenable ()
 248   "Turn all debug-on-entry functions back on."
 249   (let ((list debug-function-list))
 250     (while list
 251       (or (consp (symbol-function (car list)))
 252           (debug-convert-byte-code (car list)))
 253       (fset (car list)
 254             (debug-on-entry-1 (car list) (symbol-function (car list)) t))
 255       (setq list (cdr list)))))
 256
 257 (defun debugger-frame-number ()
 258   "Return number of frames in backtrace before the one point points at."
 259   (save-excursion
 260     (beginning-of-line)
 261     (let ((opoint (point))
 262           (count 0))
 263       (goto-char (point-min))
 264       (if (or (equal (buffer-substring (point) (+ (point) 6))
 265                      "Signal")
 266               (equal (buffer-substring (point) (+ (point) 6))
 267                      "Return"))
 268           (progn
 269             (search-forward ":")
 270             (forward-sexp 1)))
 271       (forward-line 1)
 272       (while (progn
 273                (forward-char 2)
 274                (if (= (following-char) ?\()
 275                    (forward-sexp 1)
 276                  (forward-sexp 2))
 277                (forward-line 1)
 278                (<= (point) opoint))
 279         (setq count (1+ count)))
 280       count)))
 281
 282 ;; Chosen empirically to account for all the frames
 283 ;; that will exist when debugger-frame is called
 284 ;; within the first one that appears in the backtrace buffer.
 285 ;; Assumes debugger-frame is called from a key;
 286 ;; will be wrong if it is called with Meta-x.
 287 (defconst debugger-frame-offset 8 "")
 288
 289 (defun debugger-frame ()
 290   "Request entry to debugger when this frame exits.
 291 Applies to the frame whose line point is on in the backtrace."
 292   (interactive)
 293   (beginning-of-line)
 294   (let ((level (debugger-frame-number)))
 295     (backtrace-debug (+ level debugger-frame-offset) t))
 296   (if (= (following-char) ? )
 297       (let ((buffer-read-only nil))
 298         (delete-char 1)
 299         (insert ?*)))
 300   (beginning-of-line))
 301
 302 (defun debugger-frame-clear ()
 303   "Do not enter to debugger when this frame exits.
 304 Applies to the frame whose line point is on in the backtrace."
 305   (interactive)
 306   (beginning-of-line)
 307   (let ((level (debugger-frame-number)))
 308     (backtrace-debug (+ level debugger-frame-offset) nil))
 309   (if (= (following-char) ?*)
 310       (let ((buffer-read-only nil))
 311         (delete-char 1)
 312         (insert ? )))
 313   (beginning-of-line))
 314
 315 (defun debugger-eval-expression (exp)
 316   "Eval an expression, in an environment like that outside the debugger."
 317   (interactive
 318    (list (read-from-minibuffer "Eval: "
 319                                nil read-expression-map t
 320                                'read-expression-history)))
 321   (save-excursion
 322     (if (null (buffer-name debugger-old-buffer))
 323         ;; old buffer deleted
 324         (setq debugger-old-buffer (current-buffer)))
 325     (set-buffer debugger-old-buffer)
 326     (let ((track-mouse debugger-outer-track-mouse)
 327           (last-command debugger-outer-last-command)
 328           (this-command debugger-outer-this-command)
 329           (unread-command-char debugger-outer-unread-command-char)
 330           (unread-command-events debugger-outer-unread-command-events)
 331           (last-input-event debugger-outer-last-input-event)
 332           (last-command-event debugger-outer-last-command-event)
 333           (last-nonmenu-event debugger-outer-last-nonmenu-event)
 334           (last-event-frame debugger-outer-last-event-frame)
 335           (standard-input debugger-outer-standard-input)
 336           (standard-output debugger-outer-standard-output)
 337           (cursor-in-echo-area debugger-outer-cursor-in-echo-area)
 338           (overriding-local-map debugger-outer-overriding-local-map)
 339           (overriding-terminal-local-map
 340            debugger-outer-overriding-terminal-local-map)
 341           (load-read-function debugger-outer-load-read-function))
 342       (store-match-data debugger-outer-match-data)
 343       (prog1 (eval-expression exp)
 344         (setq debugger-outer-match-data (match-data))
 345         (setq debugger-outer-load-read-function load-read-function)
 346         (setq debugger-outer-overriding-local-map overriding-local-map)
 347         (setq debugger-outer-overriding-terminal-local-map
 348               overriding-terminal-local-map)
 349         (setq debugger-outer-track-mouse track-mouse)
 350         (setq debugger-outer-last-command last-command)
 351         (setq debugger-outer-this-command this-command)
 352         (setq debugger-outer-unread-command-char unread-command-char)
 353         (setq debugger-outer-unread-command-events unread-command-events)
 354         (setq debugger-outer-last-input-event last-input-event)
 355         (setq debugger-outer-last-command-event last-command-event)
 356         (setq debugger-outer-last-nonmenu-event last-nonmenu-event)
 357         (setq debugger-outer-last-event-frame last-event-frame)
 358         (setq debugger-outer-standard-input standard-input)
 359         (setq debugger-outer-standard-output standard-output)
 360         (setq debugger-outer-cursor-in-echo-area cursor-in-echo-area)))))
 361 \f
 362 (defvar debugger-mode-map nil)
 363 (if debugger-mode-map
 364     nil
 365   (let ((loop ? ))
 366     (setq debugger-mode-map (make-keymap))
 367     (suppress-keymap debugger-mode-map)
 368     (define-key debugger-mode-map "-" 'negative-argument)
 369     (define-key debugger-mode-map "b" 'debugger-frame)
 370     (define-key debugger-mode-map "c" 'debugger-continue)
 371     (define-key debugger-mode-map "j" 'debugger-jump)
 372     (define-key debugger-mode-map "r" 'debugger-return-value)
 373     (define-key debugger-mode-map "u" 'debugger-frame-clear)
 374     (define-key debugger-mode-map "d" 'debugger-step-through)
 375     (define-key debugger-mode-map "l" 'debugger-list-functions)
 376     (define-key debugger-mode-map "h" 'describe-mode)
 377     (define-key debugger-mode-map "q" 'top-level)
 378     (define-key debugger-mode-map "e" 'debugger-eval-expression)
 379     (define-key debugger-mode-map " " 'next-line)))
 380
 381 (put 'debugger-mode 'mode-class 'special)
 382
 383 (defun debugger-mode ()
 384   "Mode for backtrace buffers, selected in debugger.
 385 \\<debugger-mode-map>
 386 A line starts with `*' if exiting that frame will call the debugger.
 387 Type \\[debugger-frame] or \\[debugger-frame-clear] to set or remove the `*'.
 388
 389 When in debugger due to frame being exited,
 390 use the \\[debugger-return-value] command to override the value
 391 being returned from that frame.
 392
 393 Use \\[debug-on-entry] and \\[cancel-debug-on-entry] to control
 394 which functions will enter the debugger when called.
 395
 396 Complete list of commands:
 397 \\{debugger-mode-map}"
 398   (kill-all-local-variables)
 399   (setq major-mode 'debugger-mode)
 400   (setq mode-name "Debugger")
 401   (setq truncate-lines t)
 402   (set-syntax-table emacs-lisp-mode-syntax-table)
 403   ;; Since we must handle bytecode...
 404   (setq enable-multibyte-characters nil)
 405   (use-local-map debugger-mode-map))
 406 \f
 407 ;;;###autoload
 408 (defun debug-on-entry (function)
 409   "Request FUNCTION to invoke debugger each time it is called.
 410 If you tell the debugger to continue, FUNCTION's execution proceeds.
 411 This works by modifying the definition of FUNCTION,
 412 which must be written in Lisp, not predefined.
 413 Use \\[cancel-debug-on-entry] to cancel the effect of this command.
 414 Redefining FUNCTION also cancels it."
 415   (interactive "aDebug on entry (to function): ")
 416   (debugger-reenable)
 417   (if (subrp (symbol-function function))
 418       (error "Function %s is a primitive" function))
 419   (or (consp (symbol-function function))
 420       (debug-convert-byte-code function))
 421   (or (consp (symbol-function function))
 422       (error "Definition of %s is not a list" function))
 423   (fset function (debug-on-entry-1 function (symbol-function function) t))
 424   (or (memq function debug-function-list)
 425       (setq debug-function-list (cons function debug-function-list)))
 426   function)
 427
 428 ;;;###autoload
 429 (defun cancel-debug-on-entry (&optional function)
 430   "Undo effect of \\[debug-on-entry] on FUNCTION.
 431 If argument is nil or an empty string, cancel for all functions."
 432   (interactive
 433    (list (let ((name
 434                 (completing-read "Cancel debug on entry (to function): "
 435                                  ;; Make an "alist" of the functions
 436                                  ;; that now have debug on entry.
 437                                  (mapcar 'list
 438                                          (mapcar 'symbol-name
 439                                                  debug-function-list))
 440                                  nil t nil)))
 441            (if name (intern name)))))
 442   (debugger-reenable)
 443   (if (and function (not (string= function "")))
 444       (progn
 445         (fset function
 446               (debug-on-entry-1 function (symbol-function function) nil))
 447         (setq debug-function-list (delq function debug-function-list))
 448         function)
 449     (message "Cancelling debug-on-entry for all functions")
 450     (mapcar 'cancel-debug-on-entry debug-function-list)))
 451
 452 (defun debug-convert-byte-code (function)
 453   (let ((defn (symbol-function function)))
 454     (if (not (consp defn))
 455         ;; Assume a compiled code object.
 456         (let* ((contents (append defn nil))
 457                (body
 458                 (list (list 'byte-code (nth 1 contents)
 459                             (nth 2 contents) (nth 3 contents)))))
 460           (if (nthcdr 5 contents)
 461               (setq body (cons (list 'interactive (nth 5 contents)) body)))
 462           (if (nth 4 contents)
 463               ;; Use `documentation' here, to get the actual string,
 464               ;; in case the compiled function has a reference
 465               ;; to the .elc file.
 466               (setq body (cons (documentation function) body)))
 467           (fset function (cons 'lambda (cons (car contents) body)))))))
 468
 469 (defun debug-on-entry-1 (function defn flag)
 470   (if (subrp defn)
 471       (error "%s is a built-in function" function)
 472     (if (eq (car defn) 'macro)
 473         (debug-on-entry-1 function (cdr defn) flag)
 474       (or (eq (car defn) 'lambda)
 475           (error "%s not user-defined Lisp function" function))
 476       (let (tail prec)
 477         (if (stringp (car (nthcdr 2 defn)))
 478             (setq tail (nthcdr 3 defn)
 479                   prec (list (car defn) (car (cdr defn))
 480                              (car (cdr (cdr defn)))))
 481           (setq tail (nthcdr 2 defn)
 482                 prec (list (car defn) (car (cdr defn)))))
 483         (if (eq flag (equal (car tail) '(debug 'debug)))
 484             defn
 485           (if flag
 486               (nconc prec (cons '(debug 'debug) tail))
 487             (nconc prec (cdr tail))))))))
 488
 489 (defun debugger-list-functions ()
 490   "Display a list of all the functions now set to debug on entry."
 491   (interactive)
 492   (with-output-to-temp-buffer "*Help*"
 493     (if (null debug-function-list)
 494         (princ "No debug-on-entry functions now\n")
 495       (princ "Functions set to debug on entry:\n\n")
 496       (let ((list debug-function-list))
 497         (while list
 498           (prin1 (car list))
 499           (terpri)
 500           (setq list (cdr list))))
 501       (princ "Note: if you have redefined a function, then it may no longer\n")
 502       (princ "be set to debug on entry, even if it is in the list."))
 503     (save-excursion
 504       (set-buffer standard-output)
 505       (help-mode))))
 506
 507 (provide 'debug)
 508
 509 ;;; debug.el ends here