]> code.delx.au - gnu-emacs/blob - configure.in
delx.au / code / gnu-emacs / blob
summary | shortlog | log | commit | commitdiff | tree
history | raw | HEAD
(w32fns.obj, w32menu.obj): Add charset.h and coding.h to dependencies.
[gnu-emacs] / configure.in
1 dnl Autoconf script for GNU Emacs
2 dnl To rebuild the `configure' script from this, execute the command
3 dnl autoconf
4 dnl in the directory containing this script.
5 dnl
6 dnl Copyright (C) 1994, 1995, 1996, 1999, 2000 Free Software Foundation, Inc.
7 dnl
8 dnl This file is part of GNU Emacs.
9 dnl
10 dnl GNU Emacs is free software; you can redistribute it and/or modify
11 dnl it under the terms of the GNU General Public License as published by
12 dnl the Free Software Foundation; either version 2, or (at your option)
13 dnl any later version.
14 dnl
15 dnl GNU Emacs is distributed in the hope that it will be useful,
16 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
17 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
18 dnl GNU General Public License for more details.
19 dnl
20 dnl You should have received a copy of the GNU General Public License
21 dnl along with GNU Emacs; see the file COPYING. If not, write to the
22 dnl Free Software Foundation, Inc., 59 Temple Place - Suite 330,
23 dnl Boston, MA 02111-1307, USA.
24
25 AC_PREREQ(2.8)dnl
26 AC_INIT(src/lisp.h)
27 AC_CONFIG_HEADER(src/config.h:src/config.in)
28
29 lispdir='${datadir}/emacs/${version}/lisp'
30 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
31 '${datadir}/emacs/site-lisp:${datadir}/emacs/${version}/leim'
32 lisppath='${locallisppath}:${lispdir}'
33 etcdir='${datadir}/emacs/${version}/etc'
34 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
35 docdir='${datadir}/emacs/${version}/etc'
36
37 AC_ARG_WITH(gcc,
38 [ --without-gcc don't use GCC to compile Emacs if GCC is found])
39 AC_ARG_WITH(pop,
40 [ --without-pop don't support POP mail retrieval with movemail],
41 [if test "$withval" = yes; then
42 AC_DEFINE(MAIL_USE_POP)
43 else :
44 fi],
45 AC_DEFINE(MAIL_USE_POP))
46 AC_ARG_WITH(kerberos,
47 [ --with-kerberos support Kerberos-authenticated POP],
48 [AC_DEFINE(KERBEROS)])
49 AC_ARG_WITH(kerberos5,
50 [ --with-kerberos5 support Kerberos version 5 authenticated POP],
51 [if test "${with_kerberos5+set}" = set; then
52 if test "${with_kerberos+set}" != set; then
53 with_kerberos=yes
54 AC_DEFINE(KERBEROS)
55 fi
56 fi
57 AC_DEFINE(KERBEROS5)])
58 AC_ARG_WITH(hesiod,
59 [ --with-hesiod support Hesiod to get the POP server host],
60 [AC_DEFINE(HESIOD)])
61 dnl This should be the last --with option, because --with-x is
62 dnl added later on when we find the path of X, and it's best to
63 dnl keep them together visually.
64 AC_ARG_WITH(x-toolkit,
65 [ --with-x-toolkit=KIT use an X toolkit (KIT = yes/lucid/athena/motif/no)],
66 [ case "${withval}" in
67 y | ye | yes ) val=athena ;;
68 n | no ) val=no ;;
69 l | lu | luc | luci | lucid ) val=lucid ;;
70 a | at | ath | athe | athen | athena ) val=athena ;;
71 m | mo | mot | moti | motif ) val=motif ;;
72 dnl These don't currently work.
73 dnl o | op | ope | open | open- | open-l | open-lo \
74 dnl | open-loo | open-look ) val=open-look ;;
75 * )
76 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
77 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
78 AC_MSG_ERROR([\`--with-x-toolkit=$withval' is invalid\;
79 this option's value should be \`yes', \`no', \`lucid', \`athena', or \`motif'.
80 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
81 ;;
82 esac
83 with_x_toolkit=$val
84 ])
85 AC_ARG_WITH(xpm,
86 [ --with-xpm use -lXpm for displaying XPM images])
87 AC_ARG_WITH(jpeg,
88 [ --with-jpeg use -ljpeg for displaying JPEG images])
89 AC_ARG_WITH(tiff,
90 [ --with-tiff use -ltiff for displaying TIFF images])
91 AC_ARG_WITH(gif,
92 [ --with-gif use -lungif for displaying GIF images])
93 AC_ARG_WITH(png,
94 [ --with-png use -lpng for displaying PNG images])
95 AC_ARG_WITH(toolkit-scroll-bars,
96 [ --without-toolkit-scroll-bars
97 don't use Motif or Xaw3d scroll bars])
98
99 #### Make srcdir absolute, if it isn't already. It's important to
100 #### avoid running the path through pwd unnecessary, since pwd can
101 #### give you automounter prefixes, which can go away. We do all this
102 #### so Emacs can find its files when run uninstalled.
103 case "${srcdir}" in
104 /* ) ;;
105 . )
106 ## We may be able to use the $PWD environment variable to make this
107 ## absolute. But sometimes PWD is inaccurate.
108 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
109 unset CDPATH
110 if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`" ;
111 then
112 srcdir="$PWD"
113 else
114 srcdir="`(cd ${srcdir}; pwd)`"
115 fi
116 ;;
117 * ) srcdir="`(cd ${srcdir}; pwd)`" ;;
118 esac
119
120 #### Check if the source directory already has a configured system in it.
121 if test `pwd` != `(cd ${srcdir} && pwd)` \
122 && test -f "${srcdir}/src/config.h" ; then
123 AC_MSG_WARN([The directory tree \`${srcdir}' is being used
124 as a build directory right now; it has been configured in its own
125 right. To configure in another directory as well, you MUST
126 use GNU make. If you do not have GNU make, then you must
127 now do \`make distclean' in ${srcdir},
128 and then run $0 again.])
129
130 changequote(, )dnl
131 extrasub='/^VPATH[ ]*=/c\
132 changequote([, ])dnl
133 vpath %.c $(srcdir)\
134 vpath %.h $(srcdir)\
135 vpath %.y $(srcdir)\
136 vpath %.l $(srcdir)\
137 vpath %.s $(srcdir)\
138 vpath %.in $(srcdir)\
139 vpath %.texi $(srcdir)'
140 fi
141
142 #### Given the configuration name, set machfile and opsysfile to the
143 #### names of the m/*.h and s/*.h files we should use.
144
145 ### Canonicalize the configuration name.
146
147 AC_CANONICAL_HOST
148 canonical=$host
149 configuration=$host_alias
150
151 changequote(, )dnl
152
153 ### If you add support for a new configuration, add code to this
154 ### switch statement to recognize your configuration name and select
155 ### the appropriate operating system and machine description files.
156
157 ### You would hope that you could choose an m/*.h file pretty much
158 ### based on the machine portion of the configuration name, and an s-
159 ### file based on the operating system portion. However, it turns out
160 ### that each m/*.h file is pretty manufacturer-specific - for
161 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
162 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
163 ### machines. So we basically have to have a special case for each
164 ### configuration name.
165 ###
166 ### As far as handling version numbers on operating systems is
167 ### concerned, make sure things will fail in a fixable way. If
168 ### /etc/MACHINES doesn't say anything about version numbers, be
169 ### prepared to handle anything reasonably. If version numbers
170 ### matter, be sure /etc/MACHINES says something about it.
171 ###
172 ### Eric Raymond says we should accept strings like "sysvr4" to mean
173 ### "System V Release 4"; he writes, "The old convention encouraged
174 ### confusion between `system' and `release' levels'."
175
176 machine='' opsys='' unported=no
177 case "${canonical}" in
178
179 ## NetBSD ports
180 *-*-netbsd* )
181 opsys=netbsd
182 case "${canonical}" in
183 alpha*-*-netbsd*) machine=alpha ;;
184 i[3456]86-*-netbsd*) machine=intel386 ;;
185 m68k-*-netbsd*)
186 # This is somewhat bogus.
187 machine=hp9000s300 ;;
188 powerpc-apple-netbsd*) machine=macppc ;;
189 mips-*-netbsd*) machine=pmax ;;
190 mipsel-*-netbsd*) machine=pmax ;;
191 ns32k-*-netbsd*) machine=ns32000 ;;
192 powerpc-*-netbsd*) machine=macppc ;;
193 sparc-*-netbsd*) machine=sparc ;;
194 vax-*-netbsd*) machine=vax ;;
195 arm-*-netbsd*) machine=arm ;;
196 esac
197 ;;
198
199 ## OpenBSD ports
200 *-*-openbsd* )
201 opsys=openbsd
202 case "${canonical}" in
203 alpha*-*-openbsd*) machine=alpha ;;
204 i386-*-openbsd*) machine=intel386 ;;
205 m68k-*-openbsd*) machine=hp9000s300 ;;
206 mipsel-*-openbsd*) machine=pmax ;;
207 ns32k-*-openbsd*) machine=ns32000 ;;
208 sparc-*-openbsd*) machine=sparc ;;
209 vax-*-openbsd*) machine=vax ;;
210 esac
211 ;;
212
213 ## Acorn RISCiX:
214 arm-acorn-riscix1.1* )
215 machine=acorn opsys=riscix1-1
216 ;;
217 arm-acorn-riscix1.2* | arm-acorn-riscix )
218 ## This name is riscix12 instead of riscix1.2
219 ## to avoid a file name conflict on MSDOS.
220 machine=acorn opsys=riscix12
221 ;;
222
223 ## BSDI ports
224 *-*-bsdi* )
225 opsys=bsdi
226 case "${canonical}" in
227 i[345]86-*-bsdi*) machine=intel386 ;;
228 sparc-*-bsdi*) machine=sparc ;;
229 powerpc-*-bsdi*) machine=powerpc ;;
230 esac
231 case "${canonical}" in
232 *-*-bsd386* | *-*-bsdi1* ) opsys=bsd386 ;;
233 *-*-bsdi2.0* ) opsys=bsdos2 ;;
234 *-*-bsdi2* ) opsys=bsdos2-1 ;;
235 *-*-bsdi3* ) opsys=bsdos3 ;;
236 *-*-bsdi4* ) opsys=bsdos4 ;;
237 esac
238 ;;
239
240 ## Alliant machines
241 ## Strictly speaking, we need the version of the alliant operating
242 ## system to choose the right machine file, but currently the
243 ## configuration name doesn't tell us enough to choose the right
244 ## one; we need to give alliants their own operating system name to
245 ## do this right. When someone cares, they can help us.
246 fx80-alliant-* )
247 machine=alliant4 opsys=bsd4-2
248 ;;
249 i860-alliant-* )
250 machine=alliant-2800 opsys=bsd4-3
251 ;;
252
253 ## Alpha (DEC) machines.
254 alpha*-dec-osf* )
255 machine=alpha opsys=osf1
256 # This is needed to find X11R6.1 libraries for certain tests.
257 NON_GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
258 GCC_LINK_TEST_OPTIONS=-Wl,-rpath,/usr/X11R6/lib
259 case "${canonical}" in
260 # This is necessary on 5.0 to avoid mangling src/Makefile.
261 # Separated out in case it causes problems on earlier versions.
262 alpha*-dec-osf[5-9]*)
263 NON_GNU_CPP='cc -E -std0' ;;
264 esac
265 ;;
266
267 alpha*-*-linux-gnu* )
268 machine=alpha opsys=gnu-linux
269 ;;
270
271 arm*-*-linux-gnu* )
272 machine=arm opsys=gnu-linux
273 ;;
274
275 ppc-*-linux | \
276 powerpc-*-linux* )
277 machine=powerpc opsys=gnu-linux
278 ;;
279
280 ## Altos 3068
281 m68*-altos-sysv* )
282 machine=altos opsys=usg5-2
283 ;;
284
285 ## Amdahl UTS
286 580-amdahl-sysv* )
287 machine=amdahl opsys=usg5-2-2
288 ;;
289
290 ## Apollo, Domain/OS
291 m68*-apollo-* )
292 machine=apollo opsys=bsd4-3
293 ;;
294
295 ## AT&T 3b2, 3b5, 3b15, 3b20
296 we32k-att-sysv* )
297 machine=att3b opsys=usg5-2-2
298 ;;
299
300 ## AT&T 3b1 - The Mighty Unix PC!
301 m68*-att-sysv* )
302 machine=7300 opsys=usg5-2-2
303 ;;
304
305 ## Bull dpx20
306 rs6000-bull-bosx* )
307 machine=ibmrs6000 opsys=aix3-2
308 ;;
309
310 ## Bull dpx2
311 m68*-bull-sysv3* )
312 machine=dpx2 opsys=usg5-3
313 ;;
314
315 ## Bull sps7
316 m68*-bull-sysv2* )
317 machine=sps7 opsys=usg5-2
318 ;;
319
320 ## CCI 5/32, 6/32 -- see "Tahoe".
321
322 ## Celerity
323 ## I don't know what configuration name to use for this; config.sub
324 ## doesn't seem to know anything about it. Hey, Celerity users, get
325 ## in touch with us!
326 celerity-celerity-bsd* )
327 machine=celerity opsys=bsd4-2
328 ;;
329
330 ## Clipper
331 ## What operating systems does this chip run that Emacs has been
332 ## tested on?
333 clipper-* )
334 machine=clipper
335 ## We'll use the catch-all code at the bottom to guess the
336 ## operating system.
337 ;;
338
339 ## Convex
340 *-convex-bsd* | *-convex-convexos* )
341 machine=convex opsys=bsd4-3
342 ## Prevents spurious white space in makefiles - d.m.cooke@larc.nasa.gov
343 NON_GNU_CPP="cc -E -P"
344 ;;
345
346 ## Cubix QBx/386
347 i[3456]86-cubix-sysv* )
348 machine=intel386 opsys=usg5-3
349 ;;
350
351 ## Cydra 5
352 cydra*-cydrome-sysv* )
353 machine=cydra5 opsys=usg5-3
354 ;;
355
356 ## Data General AViiON Machines
357 ## DG changed naming conventions with the release of 5.4.4.10, they
358 ## dropped the initial 5.4 but left the intervening R. Because of the
359 ## R this shouldn't conflict with older versions of the OS (which I
360 ## think were named like dgux4.*). In addition, DG new AViiONs series
361 ## uses either Motorola M88k or Intel Pentium CPUs.
362 m88k-dg-dguxR4.* | m88k-dg-dgux4* )
363 machine=aviion opsys=dgux4
364 ;;
365 m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
366 ## This name is dgux5-4-3 instead of dgux5-4r3
367 ## to avoid a file name conflict on MSDOS.
368 machine=aviion opsys=dgux5-4-3
369 ;;
370 m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
371 machine=aviion opsys=dgux5-4r2
372 ;;
373 m88k-dg-dgux* )
374 machine=aviion opsys=dgux
375 ;;
376
377 ## Data General AViiON Intel (x86) Machines
378 ## Exists from 5.4.3 (current i586-dg-dguxR4.11)
379 ## Ehud Karni, 1998-may-30, ehud@unix.simonwiesel.co.il
380 i[345]86-dg-dguxR4* )
381 machine=aviion-intel opsys=dgux4
382 ;;
383
384 ## DECstations
385 mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
386 machine=pmax opsys=bsd4-2
387 ;;
388 mips-dec-ultrix4.[12]* | mips-dec-bsd* )
389 machine=pmax opsys=bsd4-3
390 ;;
391 mips-dec-ultrix* )
392 machine=pmax opsys=ultrix4-3
393 ;;
394 mips-dec-osf* )
395 machine=pmax opsys=osf1
396 ;;
397 mips-dec-mach_bsd4.3* )
398 machine=pmax opsys=mach-bsd4-3
399 ;;
400
401 ## Motorola Delta machines
402 m68k-motorola-sysv* | m68000-motorola-sysv* )
403 machine=delta opsys=usg5-3
404 if test -z "`type gnucc | grep 'not found'`"
405 then
406 if test -s /etc/167config
407 then CC="gnucc -m68040"
408 else CC="gnucc -m68881"
409 fi
410 else
411 if test -z "`type gcc | grep 'not found'`"
412 then CC=gcc
413 else CC=cc
414 fi
415 fi
416 ;;
417 m88k-motorola-sysv4* )
418 # jbotte@bnr.ca says that UNIX_System_V <hostName> 4.0 R40V4.3 m88k mc88110
419 # needs POSIX_SIGNALS and therefore needs usg5-4-2.
420 # I hope there are not other 4.0 versions for this machine
421 # which really need usg5-4 instead.
422 machine=delta88k opsys=usg5-4-2
423 ;;
424 m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
425 machine=delta88k opsys=usg5-3
426 ;;
427
428 ## Dual machines
429 m68*-dual-sysv* )
430 machine=dual opsys=usg5-2
431 ;;
432 m68*-dual-uniplus* )
433 machine=dual opsys=unipl5-2
434 ;;
435
436 ## Elxsi 6400
437 elxsi-elxsi-sysv* )
438 machine=elxsi opsys=usg5-2
439 ;;
440
441 ## Encore machines
442 ns16k-encore-bsd* )
443 machine=ns16000 opsys=umax
444 ;;
445
446 ## The GEC 93 - apparently, this port isn't really finished yet.
447
448 ## Gould Power Node and NP1
449 pn-gould-bsd4.2* )
450 machine=gould opsys=bsd4-2
451 ;;
452 pn-gould-bsd4.3* )
453 machine=gould opsys=bsd4-3
454 ;;
455 np1-gould-bsd* )
456 machine=gould-np1 opsys=bsd4-3
457 ;;
458
459 ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
460 ## as far as Emacs is concerned).
461 m88k-harris-cxux* )
462 # Build needs to be different on 7.0 and later releases
463 case "`uname -r`" in
464 [56].[0-9] ) machine=nh4000 opsys=cxux ;;
465 [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
466 esac
467 NON_GNU_CPP="/lib/cpp"
468 ;;
469 ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
470 m68k-harris-cxux* )
471 machine=nh3000 opsys=cxux
472 ;;
473 ## Harris power pc NightHawk running Power UNIX (Series 6000)
474 powerpc-harris-powerunix )
475 machine=nh6000 opsys=powerunix
476 NON_GNU_CPP="cc -Xo -E -P"
477 ;;
478 ## SR2001/SR2201 running HI-UX/MPP
479 hppa1.1-hitachi-hiuxmpp* )
480 machine=sr2k opsys=hiuxmpp
481 ;;
482 ## Honeywell XPS100
483 xps*-honeywell-sysv* )
484 machine=xps100 opsys=usg5-2
485 ;;
486
487 ## HP 9000 series 200 or 300
488 m68*-hp-bsd* )
489 machine=hp9000s300 opsys=bsd4-3
490 ;;
491 ## HP/UX 7, 8, 9, and 10 are supported on these machines.
492 m68*-hp-hpux* )
493 case "`uname -r`" in
494 ## Someone's system reports A.B8.05 for this.
495 ## I wonder what other possibilities there are.
496 *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
497 *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
498 *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
499 *.1[0-9].* ) machine=hp9000s300 opsys=hpux9shr ;;
500 *) machine=hp9000s300 opsys=hpux ;;
501 esac
502 ;;
503
504 ## HP 9000 series 700 and 800, running HP/UX
505 hppa*-hp-hpux7* )
506 machine=hp800 opsys=hpux
507 ;;
508 hppa*-hp-hpux8* )
509 machine=hp800 opsys=hpux8
510 ;;
511 hppa*-hp-hpux9shr* )
512 machine=hp800 opsys=hpux9shr
513 ;;
514 hppa*-hp-hpux9* )
515 machine=hp800 opsys=hpux9
516 ;;
517 hppa*-hp-hpux1[0-9]* )
518 machine=hp800 opsys=hpux10
519 ;;
520
521 ## HP 9000 series 700 and 800, running HP/UX
522 hppa*-hp-hpux* )
523 ## Cross-compilation? Nah!
524 case "`uname -r`" in
525 ## Someone's system reports A.B8.05 for this.
526 ## I wonder what other possibilities there are.
527 *.B8.* ) machine=hp800 opsys=hpux8 ;;
528 *.08.* ) machine=hp800 opsys=hpux8 ;;
529 *.09.* ) machine=hp800 opsys=hpux9 ;;
530 *) machine=hp800 opsys=hpux10 ;;
531 esac
532 ;;
533 hppa*-*-nextstep* )
534 machine=hp800 opsys=nextstep
535 ;;
536
537 ## Orion machines
538 orion-orion-bsd* )
539 machine=orion opsys=bsd4-2
540 ;;
541 clipper-orion-bsd* )
542 machine=orion105 opsys=bsd4-2
543 ;;
544
545 ## IBM machines
546 i[3456]86-ibm-aix1.1* )
547 machine=ibmps2-aix opsys=usg5-2-2
548 ;;
549 i[3456]86-ibm-aix1.[23]* | i[3456]86-ibm-aix* )
550 machine=ibmps2-aix opsys=usg5-3
551 ;;
552 i370-ibm-aix*)
553 machine=ibm370aix opsys=usg5-3
554 ;;
555 rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1* )
556 machine=ibmrs6000 opsys=aix3-1
557 ;;
558 rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
559 machine=ibmrs6000 opsys=aix3-2-5
560 ;;
561 rs6000-ibm-aix4.1* | powerpc-ibm-aix4.1* )
562 machine=ibmrs6000 opsys=aix4-1
563 ;;
564 rs6000-ibm-aix4.2* | powerpc-ibm-aix4.2* )
565 machine=ibmrs6000 opsys=aix4-2
566 ;;
567 rs6000-ibm-aix4.0* | powerpc-ibm-aix4.0* )
568 machine=ibmrs6000 opsys=aix4
569 ;;
570 rs6000-ibm-aix4* | powerpc-ibm-aix4* )
571 machine=ibmrs6000 opsys=aix4-1
572 ;;
573 rs6000-ibm-aix* | powerpc-ibm-aix* )
574 machine=ibmrs6000 opsys=aix3-2
575 ;;
576 romp-ibm-bsd4.3* )
577 machine=ibmrt opsys=bsd4-3
578 ;;
579 romp-ibm-bsd4.2* )
580 machine=ibmrt opsys=bsd4-2
581 ;;
582 romp-ibm-aos4.3* )
583 machine=ibmrt opsys=bsd4-3
584 ;;
585 romp-ibm-aos4.2* )
586 machine=ibmrt opsys=bsd4-2
587 ;;
588 romp-ibm-aos* )
589 machine=ibmrt opsys=bsd4-3
590 ;;
591 romp-ibm-bsd* )
592 machine=ibmrt opsys=bsd4-3
593 ;;
594 romp-ibm-aix* )
595 machine=ibmrt-aix opsys=usg5-2-2
596 ;;
597
598 ## Integrated Solutions `Optimum V'
599 m68*-isi-bsd4.2* )
600 machine=isi-ov opsys=bsd4-2
601 ;;
602 m68*-isi-bsd4.3* )
603 machine=isi-ov opsys=bsd4-3
604 ;;
605
606 ## Intel 386 machines where we do care about the manufacturer
607 i[3456]86-intsys-sysv* )
608 machine=is386 opsys=usg5-2-2
609 ;;
610
611 ## Prime EXL
612 i[3456]86-prime-sysv* )
613 machine=i386 opsys=usg5-3
614 ;;
615
616 ## Sequent Symmetry running Dynix
617 i[3456]86-sequent-bsd* )
618 machine=symmetry opsys=bsd4-3
619 ;;
620
621 ## Sequent Symmetry running ptx 4, which is a modified SVR4.
622 i[3456]86-sequent-ptx4* | i[3456]86-sequent-sysv4* )
623 machine=sequent-ptx opsys=ptx4
624 NON_GNU_CPP=/lib/cpp
625 ;;
626
627 ## Sequent Symmetry running DYNIX/ptx
628 ## Use the old cpp rather than the newer ANSI one.
629 i[3456]86-sequent-ptx* )
630 machine=sequent-ptx opsys=ptx
631 NON_GNU_CPP="/lib/cpp"
632 ;;
633
634 ## ncr machine running svr4.3.
635 i[3456]86-ncr-sysv4.3 )
636 machine=ncr386 opsys=usg5-4-3
637 ;;
638
639 ## Unspecified sysv on an ncr machine defaults to svr4.2.
640 ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
641 i[3456]86-ncr-sysv* )
642 machine=ncr386 opsys=usg5-4-2
643 ;;
644
645 ## Intel Paragon OSF/1
646 i860-intel-osf1* )
647 machine=paragon opsys=osf1 NON_GNU_CPP=/usr/mach/lib/cpp
648 ;;
649
650 ## Intel 860
651 i860-*-sysv4* )
652 machine=i860 opsys=usg5-4
653 NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
654 NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
655 ;;
656
657 ## Macintosh PowerPC
658 powerpc*-*-linux-gnu* )
659 machine=macppc opsys=gnu-linux
660 ;;
661
662 ## Masscomp machines
663 m68*-masscomp-rtu* )
664 machine=masscomp opsys=rtu
665 ;;
666
667 ## Megatest machines
668 m68*-megatest-bsd* )
669 machine=mega68 opsys=bsd4-2
670 ;;
671
672 ## Workstations sold by MIPS
673 ## This is not necessarily all workstations using the MIPS processor -
674 ## Irises are produced by SGI, and DECstations by DEC.
675
676 ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
677 ## and usg5-2-2 and bsd4-3 as possible OS files. The only guidance
678 ## it gives for choosing between the alternatives seems to be "Use
679 ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
680 ## the BSD world." I'll assume that these are instructions for
681 ## handling two odd situations, and that every other situation
682 ## should use mips.h and usg5-2-2, they being listed first.
683 mips-mips-usg* )
684 machine=mips4
685 ## Fall through to the general code at the bottom to decide on the OS.
686 ;;
687 mips-mips-riscos4* )
688 machine=mips4 opsys=bsd4-3
689 NON_GNU_CC="cc -systype bsd43"
690 NON_GNU_CPP="cc -systype bsd43 -E"
691 ;;
692 mips-mips-riscos5* )
693 machine=mips4 opsys=riscos5
694 NON_GNU_CC="cc -systype bsd43"
695 NON_GNU_CPP="cc -systype bsd43 -E"
696 ;;
697 mips-mips-bsd* )
698 machine=mips opsys=bsd4-3
699 ;;
700 mips-mips-* )
701 machine=mips opsys=usg5-2-2
702 ;;
703
704 ## NeXT
705 m68*-next-* | m68k-*-nextstep* )
706 machine=m68k opsys=nextstep
707 ;;
708
709 ## The complete machine from National Semiconductor
710 ns32k-ns-genix* )
711 machine=ns32000 opsys=usg5-2
712 ;;
713
714 ## NCR machines
715 m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
716 machine=tower32 opsys=usg5-2-2
717 ;;
718 m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
719 machine=tower32v3 opsys=usg5-3
720 ;;
721
722 ## NEC EWS4800
723 mips-nec-sysv4*)
724 machine=ews4800 opsys=ux4800
725 ;;
726
727 ## Nixdorf Targon 31
728 m68*-nixdorf-sysv* )
729 machine=targon31 opsys=usg5-2-2
730 ;;
731
732 ## Nu (TI or LMI)
733 m68*-nu-sysv* )
734 machine=nu opsys=usg5-2
735 ;;
736
737 ## Plexus
738 m68*-plexus-sysv* )
739 machine=plexus opsys=usg5-2
740 ;;
741
742 ## PowerPC reference platform
743 powerpcle-*-solaris2* )
744 machine=prep
745 opsys=sol2-5
746 ;;
747
748 ## Pyramid machines
749 ## I don't really have any idea what sort of processor the Pyramid has,
750 ## so I'm assuming it is its own architecture.
751 pyramid-pyramid-bsd* )
752 machine=pyramid opsys=bsd4-2
753 ;;
754
755 ## Sequent Balance
756 ns32k-sequent-bsd4.2* )
757 machine=sequent opsys=bsd4-2
758 ;;
759 ns32k-sequent-bsd4.3* )
760 machine=sequent opsys=bsd4-3
761 ;;
762
763 ## Siemens Nixdorf
764 mips-siemens-sysv* | mips-sni-sysv*)
765 machine=mips-siemens opsys=usg5-4
766 NON_GNU_CC=/usr/ccs/bin/cc
767 NON_GNU_CPP=/usr/ccs/lib/cpp
768 ;;
769
770 ## Silicon Graphics machines
771 ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
772 m68*-sgi-iris3.5* )
773 machine=irist opsys=iris3-5
774 ;;
775 m68*-sgi-iris3.6* | m68*-sgi-iris*)
776 machine=irist opsys=iris3-6
777 ;;
778 ## Iris 4D
779 mips-sgi-irix3* )
780 machine=iris4d opsys=irix3-3
781 ;;
782 mips-sgi-irix4* )
783 machine=iris4d opsys=irix4-0
784 ;;
785 mips-sgi-irix6.5 )
786 machine=iris4d opsys=irix6-5
787 # Without defining _LANGUAGE_C, things get masked out in the headers
788 # so that, for instance, grepping for `free' in stdlib.h fails and
789 # AC_HEADER_STD_C fails. (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
790 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
791 NON_GCC_TEST_OPTIONS="-n32 -D_LANGUAGE_C"
792 ;;
793 mips-sgi-irix6* )
794 machine=iris4d opsys=irix6-0
795 # It's not clear whether -D_LANGUAGE_C is necessary as it is for 6.5,
796 # but presumably it does no harm.
797 NON_GNU_CPP="/lib/cpp -D_LANGUAGE_C"
798 NON_GCC_TEST_OPTIONS=-32
799 ;;
800 mips-sgi-irix5.[01]* )
801 machine=iris4d opsys=irix5-0
802 ;;
803 mips-sgi-irix5* | mips-sgi-irix* )
804 machine=iris4d opsys=irix5-2
805 ;;
806
807 ## SONY machines
808 m68*-sony-bsd4.2* )
809 machine=news opsys=bsd4-2
810 ;;
811 m68*-sony-bsd4.3* )
812 machine=news opsys=bsd4-3
813 ;;
814 m68*-sony-newsos3* | m68*-sony-news3*)
815 machine=news opsys=bsd4-3
816 ;;
817 mips-sony-bsd* | mips-sony-newsos4* | mips-sony-news4*)
818 machine=news-risc opsys=bsd4-3
819 ;;
820 mips-sony-newsos6* )
821 machine=news-r6 opsys=newsos6
822 ;;
823 mips-sony-news* )
824 machine=news-risc opsys=newsos5
825 ;;
826
827 ## Stride
828 m68*-stride-sysv* )
829 machine=stride opsys=usg5-2
830 ;;
831
832 ## Suns
833 sparc-*-linux-gnu* | sparc64-*-linux-gnu* )
834 machine=sparc opsys=gnu-linux
835 ;;
836
837 *-auspex-sunos* | *-sun-sunos* | *-sun-bsd* | *-sun-solaris* \
838 | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* | powerpc*-*-solaris2* \
839 | rs6000-*-solaris2*)
840 case "${canonical}" in
841 m68*-sunos1* ) machine=sun1 ;;
842 m68*-sunos2* ) machine=sun2 ;;
843 m68* ) machine=sun3 ;;
844 i[3456]86-sun-sunos[34]* ) machine=sun386 ;;
845 i[3456]86-*-* ) machine=intel386 ;;
846 powerpcle* ) machine=powerpcle ;;
847 powerpc* | rs6000* ) machine=ibmrs6000 ;;
848 sparc* ) machine=sparc ;;
849 * ) unported=yes ;;
850 esac
851 case "${canonical}" in
852 ## The Sun386 didn't get past 4.0.
853 i[3456]86-*-sunos4 ) opsys=sunos4-0 ;;
854 *-sunos4.0* ) opsys=sunos4-0 ;;
855 *-sunos4.1.[3-9]*noshare )
856 ## This name is sunos413 instead of sunos4-1-3
857 ## to avoid a file name conflict on MSDOS.
858 opsys=sunos413
859 NON_GNU_CPP=/usr/lib/cpp
860 NON_GCC_TEST_OPTIONS=-Bstatic
861 GCC_TEST_OPTIONS=-static
862 ;;
863 *-sunos4.1.[3-9]* | *-sunos4shr*)
864 opsys=sunos4shr
865 NON_GNU_CPP=/usr/lib/cpp
866 ;;
867 *-sunos4* | *-sunos )
868 opsys=sunos4-1
869 NON_GCC_TEST_OPTIONS=-Bstatic
870 GCC_TEST_OPTIONS=-static
871 ;;
872 *-sunos5.3* | *-solaris2.3* )
873 opsys=sol2-3
874 NON_GNU_CPP=/usr/ccs/lib/cpp
875 ;;
876 *-sunos5.4* | *-solaris2.4* )
877 opsys=sol2-4
878 NON_GNU_CPP=/usr/ccs/lib/cpp
879 RANLIB="ar -ts"
880 ;;
881 *-sunos5.5* | *-solaris2.5* )
882 opsys=sol2-5
883 NON_GNU_CPP=/usr/ccs/lib/cpp
884 RANLIB="ar -ts"
885 ;;
886 *-sunos5* | *-solaris* )
887 opsys=sol2-5
888 NON_GNU_CPP=/usr/ccs/lib/cpp
889 ;;
890 * ) opsys=bsd4-2 ;;
891 esac
892 ## Watch out for a compiler that we know will not work.
893 case "${canonical}" in
894 *-solaris* | *-sunos5* )
895 if [ "x$CC" = x/usr/ucb/cc ]; then
896 ## /usr/ucb/cc doesn't work;
897 ## we should find some other compiler that does work.
898 unset CC
899 fi
900 ;;
901 *) ;;
902 esac
903 ;;
904 sparc-*-nextstep* )
905 machine=sparc opsys=nextstep
906 ;;
907
908 ## Tadpole 68k
909 m68*-tadpole-sysv* )
910 machine=tad68k opsys=usg5-3
911 ;;
912
913 ## Tahoe machines
914 tahoe-tahoe-bsd4.2* )
915 machine=tahoe opsys=bsd4-2
916 ;;
917 tahoe-tahoe-bsd4.3* )
918 machine=tahoe opsys=bsd4-3
919 ;;
920
921 ## Tandem Integrity S2
922 mips-tandem-sysv* )
923 machine=tandem-s2 opsys=usg5-3
924 ;;
925
926 ## Tektronix XD88
927 m88k-tektronix-sysv3* )
928 machine=tekxd88 opsys=usg5-3
929 ;;
930
931 ## Tektronix 16000 box (6130?)
932 ns16k-tektronix-bsd* )
933 machine=ns16000 opsys=bsd4-2
934 ;;
935 ## Tektronix 4300
936 ## src/m/tek4300.h hints that this is a m68k machine.
937 m68*-tektronix-bsd* )
938 machine=tek4300 opsys=bsd4-3
939 ;;
940
941 ## Titan P2 or P3
942 ## We seem to have lost the machine-description file titan.h!
943 titan-titan-sysv* )
944 machine=titan opsys=usg5-3
945 ;;
946
947 ## Ustation E30 (SS5E)
948 m68*-unisys-uniplus* )
949 machine=ustation opsystem=unipl5-2
950 ;;
951
952 ## Vaxen.
953 vax-dec-* )
954 machine=vax
955 case "${canonical}" in
956 *-bsd4.1* ) opsys=bsd4-1 ;;
957 *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* ) opsys=bsd4-2 ;;
958 *-bsd4.3* | *-ultrix* ) opsys=bsd4-3 ;;
959 *-sysv[01]* | *-sysvr[01]* ) opsys=usg5-0 ;;
960 *-sysv2* | *-sysvr2* ) opsys=usg5-2 ;;
961 *-vms* ) opsys=vms ;;
962 * ) unported=yes
963 esac
964 ;;
965
966 ## Whitechapel MG1
967 ns16k-whitechapel-* )
968 machine=mg1
969 ## We don't know what sort of OS runs on these; we'll let the
970 ## operating system guessing code below try.
971 ;;
972
973 ## Wicat
974 m68*-wicat-sysv* )
975 machine=wicat opsys=usg5-2
976 ;;
977
978 ## Intel 386 machines where we don't care about the manufacturer
979 i[3456]86-*-* )
980 machine=intel386
981 case "${canonical}" in
982 *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
983 *-isc2.2* ) opsys=isc2-2 ;;
984 *-isc4.0* ) opsys=isc4-0 ;;
985 *-isc4.* ) opsys=isc4-1
986 GCC_TEST_OPTIONS=-posix
987 NON_GCC_TEST_OPTIONS=-Xp
988 ;;
989 *-isc* ) opsys=isc3-0 ;;
990 *-esix5* ) opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
991 *-esix* ) opsys=esix ;;
992 *-xenix* ) opsys=xenix ;;
993 *-linux-gnu* ) opsys=gnu-linux ;;
994 *-sco3.2v4* ) opsys=sco4 ; NON_GNU_CPP=/lib/cpp ;;
995 *-sco3.2v5* ) opsys=sco5
996 NON_GNU_CPP=/lib/cpp
997 # Prevent -belf from being passed to $CPP.
998 # /lib/cpp does not accept it.
999 OVERRIDE_CPPFLAGS=" "
1000 ;;
1001 *-sysv4.2uw* ) opsys=unixware; NON_GNU_CPP=/lib/cpp ;;
1002 *-386bsd* ) opsys=386bsd ;;
1003 *-freebsd* ) opsys=freebsd ;;
1004 *-nextstep* ) opsys=nextstep ;;
1005 ## Otherwise, we'll fall through to the generic opsys code at the bottom.
1006 esac
1007 ;;
1008
1009 ## m68k Linux-based GNU system
1010 m68k-*-linux-gnu* )
1011 machine=m68k opsys=gnu-linux
1012 ;;
1013
1014 ## Mips Linux-based GNU system
1015 mips-*-linux-gnu* )
1016 machine=mips opsys=gnu-linux
1017 ;;
1018
1019 ## UXP/DS
1020 sparc-fujitsu-sysv4* )
1021 machine=sparc opsys=uxpds
1022 NON_GNU_CPP=/usr/ccs/lib/cpp
1023 RANLIB="ar -ts"
1024 ;;
1025
1026 ## UXP/V
1027 f301-fujitsu-uxpv4.1)
1028 machine=f301 opsys=uxpv
1029 ;;
1030
1031 * )
1032 unported=yes
1033 ;;
1034 esac
1035
1036 ### If the code above didn't choose an operating system, just choose
1037 ### an operating system based on the configuration name. You really
1038 ### only want to use this when you have no idea what the right
1039 ### operating system is; if you know what operating systems a machine
1040 ### runs, it's cleaner to make it explicit in the case statement
1041 ### above.
1042 if test x"${opsys}" = x; then
1043 case "${canonical}" in
1044 *-gnu* ) opsys=gnu ;;
1045 *-bsd4.[01] ) opsys=bsd4-1 ;;
1046 *-bsd4.2 ) opsys=bsd4-2 ;;
1047 *-bsd4.3 ) opsys=bsd4-3 ;;
1048 *-sysv0 | *-sysvr0 ) opsys=usg5-0 ;;
1049 *-sysv2 | *-sysvr2 ) opsys=usg5-2 ;;
1050 *-sysv2.2 | *-sysvr2.2 ) opsys=usg5-2-2 ;;
1051 *-sysv3* | *-sysvr3* ) opsys=usg5-3 ;;
1052 *-sysv4.2uw* ) opsys=unixware ;;
1053 *-sysv4.1* | *-sysvr4.1* )
1054 NON_GNU_CPP=/usr/lib/cpp
1055 opsys=usg5-4 ;;
1056 *-sysv4.[2-9]* | *-sysvr4.[2-9]* )
1057 if [ x$NON_GNU_CPP = x ]; then
1058 if [ -f /usr/ccs/lib/cpp ]; then
1059 NON_GNU_CPP=/usr/ccs/lib/cpp
1060 else
1061 NON_GNU_CPP=/lib/cpp
1062 fi
1063 fi
1064 opsys=usg5-4-2 ;;
1065 *-sysv4* | *-sysvr4* ) opsys=usg5-4 ;;
1066 * )
1067 unported=yes
1068 ;;
1069 esac
1070 fi
1071
1072 changequote([, ])dnl
1073
1074 if test $unported = yes; then
1075 AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
1076 Check \`etc/MACHINES' for recognized configuration names.])
1077 fi
1078
1079 machfile="m/${machine}.h"
1080 opsysfile="s/${opsys}.h"
1081
1082
1083 #### Choose a compiler.
1084 test -n "$CC" && cc_specified=yes
1085
1086 # Save the value of CFLAGS that the user specified.
1087 SPECIFIED_CFLAGS="$CFLAGS"
1088
1089 case ${with_gcc} in
1090 "yes" ) CC="gcc" GCC=yes ;;
1091 "no" ) : ${CC=cc} ;;
1092 * ) AC_PROG_CC
1093 esac
1094
1095 # On Suns, sometimes $CPP names a directory.
1096 if test -n "$CPP" && test -d "$CPP"; then
1097 CPP=
1098 fi
1099
1100 #### Some systems specify a CPP to use unless we are using GCC.
1101 #### Now that we know whether we are using GCC, we can decide whether
1102 #### to use that one.
1103 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
1104 then
1105 CPP="$NON_GNU_CPP"
1106 fi
1107
1108 #### Some systems specify a CC to use unless we are using GCC.
1109 #### Now that we know whether we are using GCC, we can decide whether
1110 #### to use that one.
1111 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
1112 test x$cc_specified != xyes
1113 then
1114 CC="$NON_GNU_CC"
1115 fi
1116
1117 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
1118 then
1119 CC="$CC $GCC_TEST_OPTIONS"
1120 fi
1121
1122 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
1123 then
1124 CC="$CC $NON_GCC_TEST_OPTIONS"
1125 fi
1126
1127 if test x$GCC = xyes && test "x$GCC_LINK_TEST_OPTIONS" != x
1128 then
1129 ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
1130 fi
1131
1132 if test x$GCC = x && test "x$NON_GCC_LINK_TEST_OPTIONS" != x
1133 then
1134 ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
1135 fi
1136
1137 #### Some other nice autoconf tests. If you add a test here which
1138 #### should make an entry in src/config.h, don't forget to add an
1139 #### #undef clause to src/config.h.in for autoconf to modify.
1140
1141 dnl checks for programs
1142 AC_PROG_LN_S
1143 AC_PROG_CPP
1144 AC_PROG_INSTALL
1145 AC_PROG_YACC
1146 if test "x$RANLIB" = x; then
1147 AC_PROG_RANLIB
1148 fi
1149
1150 dnl checks for Unix variants
1151 AC_AIX
1152
1153 # Sound support for GNU/Linux and the free BSDs.
1154 AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h)
1155
1156 dnl checks for header files
1157 AC_CHECK_HEADERS(sys/select.h sys/timeb.h sys/time.h unistd.h utime.h \
1158 linux/version.h sys/systeminfo.h termios.h limits.h string.h stdlib.h \
1159 termcap.h stdio_ext.h)
1160 AC_HEADER_STDC
1161 AC_HEADER_TIME
1162 AC_DECL_SYS_SIGLIST
1163
1164 dnl Some systems have utime.h but don't declare the struct anyplace.
1165 AC_CACHE_CHECK(for struct utimbuf, emacs_cv_struct_utimbuf,
1166 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1167 #include <sys/time.h>
1168 #include <time.h>
1169 #else
1170 #ifdef HAVE_SYS_TIME_H
1171 #include <sys/time.h>
1172 #else
1173 #include <time.h>
1174 #endif
1175 #endif
1176 #ifdef HAVE_UTIME_H
1177 #include <utime.h>
1178 #endif], [static struct utimbuf x; x.actime = x.modtime;],
1179 emacs_cv_struct_utimbuf=yes, emacs_cv_struct_utimbuf=no))
1180 if test $emacs_cv_struct_utimbuf = yes; then
1181 AC_DEFINE(HAVE_STRUCT_UTIMBUF)
1182 fi
1183
1184 dnl checks for typedefs
1185 AC_TYPE_SIGNAL
1186
1187 dnl Check for speed_t typedef.
1188 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1189 AC_TRY_COMPILE([#include <termios.h>], [speed_t x = 1;],
1190 emacs_cv_speed_t=yes))
1191 if test $emacs_cv_speed_t = yes; then
1192 AC_DEFINE(HAVE_SPEED_T)
1193 fi
1194
1195 AC_CACHE_CHECK(for struct timeval, emacs_cv_struct_timeval,
1196 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
1197 #include <sys/time.h>
1198 #include <time.h>
1199 #else
1200 #ifdef HAVE_SYS_TIME_H
1201 #include <sys/time.h>
1202 #else
1203 #include <time.h>
1204 #endif
1205 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
1206 emacs_cv_struct_timeval=yes, emacs_cv_struct_timeval=no))
1207 HAVE_TIMEVAL=$emacs_cv_struct_timeval
1208 if test $emacs_cv_struct_timeval = yes; then
1209 AC_DEFINE(HAVE_TIMEVAL)
1210 fi
1211
1212 dnl checks for structure members
1213 AC_STRUCT_TM
1214 AC_STRUCT_TIMEZONE
1215 AC_CACHE_CHECK(for tm_gmtoff in struct tm, emacs_cv_tm_gmtoff,
1216 AC_TRY_LINK([#include <time.h>], [struct tm t; t.tm_gmtoff = 0],
1217 emacs_cv_tm_gmtoff=yes,
1218 emacs_cv_tm_gmtoff=no))
1219 if test $emacs_cv_tm_gmtoff = yes; then
1220 AC_DEFINE(HAVE_TM_GMTOFF)
1221 fi
1222
1223 dnl checks for compiler characteristics
1224
1225 dnl Testing __STDC__ to determine prototype support isn't good enough.
1226 dnl DEC C, for instance, doesn't define it with default options, and
1227 dnl is used on 64-bit systems (OSF Alphas). Similarly for volatile
1228 dnl and void *.
1229 AC_C_PROTOTYPES
1230 AC_C_VOLATILE
1231 AC_C_CONST
1232 dnl This isn't useful because we can't turn on use of `inline' unless
1233 dnl the compiler groks `extern inline'.
1234 dnl AC_C_INLINE
1235 AC_CACHE_CHECK([for void * support], emacs_cv_void_star,
1236 [AC_TRY_COMPILE(, [void * foo;],
1237 emacs_cv_void_star=yes, emacs_cv_void_star=no)])
1238 if test $emacs_cv_void_star = yes; then
1239 AC_DEFINE(POINTER_TYPE, void)
1240 else
1241 AC_DEFINE(POINTER_TYPE, char)
1242 fi
1243
1244 dnl check for Make feature
1245 AC_PROG_MAKE_SET
1246
1247 dnl checks for operating system services
1248 AC_SYS_LONG_FILE_NAMES
1249
1250 #### Choose a window system.
1251
1252 AC_PATH_X
1253 if test "$no_x" = yes; then
1254 window_system=none
1255 else
1256 window_system=x11
1257 fi
1258
1259 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1260 LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1261 LD_SWITCH_X_SITE_AUX=-R`echo ${x_libraries} | sed -e "s/:/ -R/g"`
1262 x_default_search_path=""
1263 for x_library in `echo ${x_libraries} | sed -e "s/:/ /g"`; do
1264 x_search_path="${x_library}/X11/%L/%T/%N%C%S:\
1265 ${x_library}/X11/%L/%T/%N%C%S:${x_libary}/X11/%l/%T/%N%C%S:\
1266 ${x_library}/X11/%T/%N%C%S:${x_library}/X11/%L/%T/%N%S:\
1267 ${x_library}/X11/%l/%T/%N%S:${x_library}/X11/%T/%N%S"
1268 if test x"${x_default_search_path}" = x; then
1269 x_default_search_path=${x_search_path}
1270 else
1271 x_default_search_path="${x_search_path}:${x_default_search_path}"
1272 fi
1273 done
1274 fi
1275 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1276 C_SWITCH_X_SITE=-I`echo ${x_includes} | sed -e "s/:/ -I/g"`
1277 fi
1278
1279 if test x"${x_includes}" = x; then
1280 bitmapdir=/usr/include/X11/bitmaps
1281 else
1282 # accumulate include directories that have X11 bitmap subdirectories
1283 bmd_acc="dummyval"
1284 for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1285 if test -d "${bmd}/X11/bitmaps"; then
1286 bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1287 fi
1288 if test -d "${bmd}/bitmaps"; then
1289 bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1290 fi
1291 done
1292 if test ${bmd_acc} != "dummyval"; then
1293 bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1294 fi
1295 fi
1296
1297 case "${window_system}" in
1298 x11 )
1299 HAVE_X_WINDOWS=yes
1300 HAVE_X11=yes
1301 case "${with_x_toolkit}" in
1302 athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1303 motif ) USE_X_TOOLKIT=MOTIF ;;
1304 dnl open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
1305 no ) USE_X_TOOLKIT=none ;;
1306 dnl If user did not say whether to use a toolkit,
1307 dnl make this decision later: use the toolkit if we have X11R5 or newer.
1308 * ) USE_X_TOOLKIT=maybe ;;
1309 esac
1310 ;;
1311 none )
1312 HAVE_X_WINDOWS=no
1313 HAVE_X11=no
1314 USE_X_TOOLKIT=none
1315 ;;
1316 esac
1317
1318 ### If we're using X11, we should use the X menu package.
1319 HAVE_MENUS=no
1320 case ${HAVE_X11} in
1321 yes ) HAVE_MENUS=yes ;;
1322 esac
1323
1324 if test "${opsys}" = "hpux9"; then
1325 case "${x_libraries}" in
1326 *X11R4* )
1327 opsysfile="s/hpux9-x11r4.h"
1328 ;;
1329 esac
1330 fi
1331
1332 if test "${opsys}" = "hpux9shr"; then
1333 case "${x_libraries}" in
1334 *X11R4* )
1335 opsysfile="s/hpux9shxr4.h"
1336 ;;
1337 esac
1338 fi
1339
1340 #### Extract some information from the operating system and machine files.
1341
1342 AC_CHECKING([the machine- and system-dependent files to find out
1343 - which libraries the lib-src programs will want, and
1344 - whether the GNU malloc routines are usable])
1345
1346 ### First figure out CFLAGS (which we use for running the compiler here)
1347 ### and REAL_CFLAGS (which we use for real compilation).
1348 ### The two are the same except on a few systems, where they are made
1349 ### different to work around various lossages. For example,
1350 ### GCC 2.5 on GNU/Linux needs them to be different because it treats -g
1351 ### as implying static linking.
1352
1353 ### If the CFLAGS env var is specified, we use that value
1354 ### instead of the default.
1355
1356 ### It's not important that this name contain the PID; you can't run
1357 ### two configures in the same directory and have anything work
1358 ### anyway.
1359 tempcname="conftest.c"
1360
1361 echo '
1362 #include "'${srcdir}'/src/'${opsysfile}'"
1363 #include "'${srcdir}'/src/'${machfile}'"
1364 #ifndef LIBS_MACHINE
1365 #define LIBS_MACHINE
1366 #endif
1367 #ifndef LIBS_SYSTEM
1368 #define LIBS_SYSTEM
1369 #endif
1370 #ifndef C_SWITCH_SYSTEM
1371 #define C_SWITCH_SYSTEM
1372 #endif
1373 #ifndef C_SWITCH_MACHINE
1374 #define C_SWITCH_MACHINE
1375 #endif
1376 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
1377 configure___ c_switch_system=C_SWITCH_SYSTEM
1378 configure___ c_switch_machine=C_SWITCH_MACHINE
1379
1380 #ifndef LIB_X11_LIB
1381 #define LIB_X11_LIB -lX11
1382 #endif
1383
1384 #ifndef LIBX11_MACHINE
1385 #define LIBX11_MACHINE
1386 #endif
1387
1388 #ifndef LIBX11_SYSTEM
1389 #define LIBX11_SYSTEM
1390 #endif
1391 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
1392
1393 #ifdef UNEXEC
1394 configure___ unexec=UNEXEC
1395 #else
1396 configure___ unexec=unexec.o
1397 #endif
1398
1399 #ifdef SYSTEM_MALLOC
1400 configure___ system_malloc=yes
1401 #else
1402 configure___ system_malloc=no
1403 #endif
1404
1405 #ifndef C_DEBUG_SWITCH
1406 #define C_DEBUG_SWITCH -g
1407 #endif
1408
1409 #ifndef C_OPTIMIZE_SWITCH
1410 #ifdef __GNUC__
1411 #define C_OPTIMIZE_SWITCH -O2
1412 #else
1413 #define C_OPTIMIZE_SWITCH -O
1414 #endif
1415 #endif
1416
1417 #ifndef LD_SWITCH_MACHINE
1418 #define LD_SWITCH_MACHINE
1419 #endif
1420
1421 #ifndef LD_SWITCH_SYSTEM
1422 #define LD_SWITCH_SYSTEM
1423 #endif
1424
1425 #ifndef LD_SWITCH_X_SITE_AUX
1426 #define LD_SWITCH_X_SITE_AUX
1427 #endif
1428
1429 configure___ ld_switch_system=LD_SWITCH_SYSTEM
1430 configure___ ld_switch_machine=LD_SWITCH_MACHINE
1431
1432 #ifdef THIS_IS_CONFIGURE
1433
1434 /* Get the CFLAGS for tests in configure. */
1435 #ifdef __GNUC__
1436 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1437 #else
1438 configure___ CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1439 #endif
1440
1441 #else /* not THIS_IS_CONFIGURE */
1442
1443 /* Get the CFLAGS for real compilation. */
1444 #ifdef __GNUC__
1445 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${SPECIFIED_CFLAGS}'
1446 #else
1447 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${SPECIFIED_CFLAGS}'
1448 #endif
1449
1450 #endif /* not THIS_IS_CONFIGURE */
1451 ' > ${tempcname}
1452
1453 # The value of CPP is a quoted variable reference, so we need to do this
1454 # to get its actual value...
1455 CPP=`eval "echo $CPP"`
1456 changequote(, )dnl
1457 eval `${CPP} -Isrc ${tempcname} \
1458 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1459 if test "x$SPECIFIED_CFLAGS" = x; then
1460 eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1461 | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1462 else
1463 REAL_CFLAGS="$CFLAGS"
1464 fi
1465 changequote([, ])dnl
1466 rm ${tempcname}
1467
1468 ac_link="$ac_link $ld_switch_machine $ld_switch_system"
1469
1470 ### Compute the unexec source name from the object name.
1471 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1472
1473 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1474 # Assume not, until told otherwise.
1475 GNU_MALLOC=yes
1476 doug_lea_malloc=yes
1477 AC_CHECK_FUNC(malloc_get_state, ,doug_lea_malloc=no)
1478 AC_CHECK_FUNC(malloc_set_state, ,doug_lea_malloc=no)
1479 AC_CACHE_CHECK(whether __after_morecore_hook exists,
1480 emacs_cv_var___after_morecore_hook,
1481 AC_TRY_LINK([extern void (* __after_morecore_hook)();],[__after_morecore_hook = 0],
1482 emacs_cv_var___after_morecore_hook=yes,
1483 emacs_cv_var___after_morecore_hook=no))
1484 if test $emacs_cv_var___after_morecore_hook = no; then
1485 doug_lea_malloc=no
1486 fi
1487 if test "${system_malloc}" = "yes"; then
1488 GNU_MALLOC=no
1489 GNU_MALLOC_reason="
1490 (The GNU allocators don't work with this system configuration.)"
1491 fi
1492 if test "$doug_lea_malloc" = "yes" ; then
1493 if test "$GNU_MALLOC" = yes ; then
1494 GNU_MALLOC_reason="
1495 (Using Doug Lea's new malloc from the GNU C Library.)"
1496 fi
1497 AC_DEFINE(DOUG_LEA_MALLOC)
1498 fi
1499
1500 if test x"${REL_ALLOC}" = x; then
1501 REL_ALLOC=${GNU_MALLOC}
1502 fi
1503
1504 #### Add the libraries to LIBS and check for some functions.
1505
1506 if test x"${OVERRIDE_CPPFLAGS}" != x; then
1507 CPPFLAGS="${OVERRIDE_CPPFLAGS}"
1508 else
1509 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1510 fi
1511
1512 LIBS="$libsrc_libs $LIBS"
1513
1514 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1515 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1516 AC_CHECK_LIB(dnet, dnet_ntoa)
1517 dnl This causes -lresolv to get used in subsequent tests,
1518 dnl which causes failures on some systems such as HPUX 9.
1519 dnl AC_CHECK_LIB(resolv, gethostbyname)
1520
1521 dnl FIXME replace main with a function we actually want from this library.
1522 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1523
1524 AC_CHECK_LIB(pthreads, cma_open)
1525
1526 AC_MSG_CHECKING(for XFree86 in /usr/X386)
1527 if test -d /usr/X386/include; then
1528 HAVE_XFREE386=yes
1529 : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1530 else
1531 HAVE_XFREE386=no
1532 fi
1533 AC_MSG_RESULT($HAVE_XFREE386)
1534
1535 # Change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1536 # for the tests that follow. We set it back to REAL_CFLAGS later on.
1537
1538 if test "${HAVE_X11}" = "yes"; then
1539 DEFS="$C_SWITCH_X_SITE $DEFS"
1540 LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1541 LIBS="$LIBX $LIBS"
1542 CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1543
1544 # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1545 # This is handled by LD_SWITCH_X_SITE_AUX during the real build,
1546 # but it's more convenient here to set LD_RUN_PATH
1547 # since this also works on hosts that don't understand LD_SWITCH_X_SITE_AUX.
1548 if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1549 LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1550 export LD_RUN_PATH
1551 fi
1552
1553 if test "${opsys}" = "gnu-linux"; then
1554 AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1555 AC_TRY_LINK([],
1556 [XOpenDisplay ("foo");],
1557 [xlinux_first_failure=no],
1558 [xlinux_first_failure=yes])
1559 if test "${xlinux_first_failure}" = "yes"; then
1560 OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1561 OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1562 OLD_CPPFLAGS="$CPPFLAGS"
1563 OLD_LIBS="$LIBS"
1564 LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1565 C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1566 CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1567 LIBS="$LIBS -b i486-linuxaout"
1568 AC_TRY_LINK([],
1569 [XOpenDisplay ("foo");],
1570 [xlinux_second_failure=no],
1571 [xlinux_second_failure=yes])
1572 if test "${xlinux_second_failure}" = "yes"; then
1573 # If we get the same failure with -b, there is no use adding -b.
1574 # So take it out. This plays safe.
1575 LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1576 C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1577 CPPFLAGS="$OLD_CPPFLAGS"
1578 LIBS="$OLD_LIBS"
1579 AC_MSG_RESULT(no)
1580 else
1581 AC_MSG_RESULT(yes)
1582 fi
1583 else
1584 AC_MSG_RESULT(no)
1585 fi
1586 fi
1587
1588 AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1589 XScreenNumberOfScreen XSetWMProtocols)
1590 fi
1591
1592 if test "${window_system}" = "x11"; then
1593 AC_MSG_CHECKING(X11 version 6)
1594 AC_CACHE_VAL(emacs_cv_x11_version_6,
1595 AC_TRY_LINK([#include <X11/Xlib.h>],
1596 [#if XlibSpecificationRelease < 6
1597 fail;
1598 #endif
1599 ], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no))
1600 if test $emacs_cv_x11_version_6 = yes; then
1601 AC_MSG_RESULT(6 or newer)
1602 AC_DEFINE(HAVE_X11R6)
1603 else
1604 AC_MSG_RESULT(before 6)
1605 fi
1606 fi
1607
1608 if test "${window_system}" = "x11"; then
1609 AC_MSG_CHECKING(X11 version 5)
1610 AC_CACHE_VAL(emacs_cv_x11_version_5,
1611 AC_TRY_LINK([#include <X11/Xlib.h>],
1612 [#if XlibSpecificationRelease < 5
1613 fail;
1614 #endif
1615 ], emacs_cv_x11_version_5=yes, emacs_cv_x11_version_5=no))
1616 if test $emacs_cv_x11_version_5 = yes; then
1617 AC_MSG_RESULT(5 or newer)
1618 HAVE_X11R5=yes
1619 AC_DEFINE(HAVE_X11R5)
1620 else
1621 HAVE_X11R5=no
1622 AC_MSG_RESULT(before 5)
1623 fi
1624 fi
1625
1626 dnl Do not put whitespace before the #include statements below.
1627 dnl Older compilers (eg sunos4 cc) choke on it.
1628 if test x"${USE_X_TOOLKIT}" = xmaybe; then
1629 if test x"${HAVE_X11R5}" = xyes; then
1630 AC_MSG_CHECKING(X11 version 5 with Xaw)
1631 AC_CACHE_VAL(emacs_cv_x11_version_5_with_xaw,
1632 AC_TRY_LINK([
1633 #include <X11/Intrinsic.h>
1634 #include <X11/Xaw/Simple.h>],
1635 [],
1636 emacs_cv_x11_version_5_with_xaw=yes,
1637 emacs_cv_x11_version_5_with_xaw=no))
1638 if test $emacs_cv_x11_version_5_with_xaw = yes; then
1639 AC_MSG_RESULT([5 or newer, with Xaw; use toolkit by default])
1640 USE_X_TOOLKIT=LUCID
1641 else
1642 AC_MSG_RESULT(before 5 or no Xaw; do not use toolkit by default)
1643 USE_X_TOOLKIT=none
1644 fi
1645 else
1646 USE_X_TOOLKIT=none
1647 fi
1648 fi
1649
1650 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
1651
1652 if test "${USE_X_TOOLKIT}" != "none"; then
1653 AC_MSG_CHECKING(X11 toolkit version)
1654 AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
1655 AC_TRY_LINK([#include <X11/Intrinsic.h>],
1656 [#if XtSpecificationRelease < 6
1657 fail;
1658 #endif
1659 ], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no))
1660 HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
1661 if test $emacs_cv_x11_toolkit_version_6 = yes; then
1662 AC_MSG_RESULT(6 or newer)
1663 AC_DEFINE(HAVE_X11XTR6)
1664 else
1665 AC_MSG_RESULT(before 6)
1666 fi
1667
1668 dnl If using toolkit, check whether libXmu.a exists.
1669 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
1670 OLDLIBS="$LIBS"
1671 if test x$HAVE_X11XTR6 = xyes; then
1672 LIBS="-lXt -lSM -lICE $LIBS"
1673 else
1674 LIBS="-lXt $LIBS"
1675 fi
1676 AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
1677 LIBS="$OLDLIBS"
1678 fi
1679
1680 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1681 AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
1682 AC_TRY_COMPILE([#include <Xm/Xm.h>],
1683 [#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
1684 int x = 5;
1685 #else
1686 Motif version prior to 2.1.
1687 #endif],
1688 emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no))
1689 HAVE_MOTIF_2_1=$emacs_cv_motif_version_2_1
1690 if test $emacs_cv_motif_version_2_1 = yes; then
1691 AC_DEFINE(HAVE_MOTIF_2_1)
1692 AC_CHECK_LIB(Xp, XpCreateContext)
1693 fi
1694 fi
1695
1696 ### Is -lXaw3d available?
1697 HAVE_XAW3D=no
1698 if test "${HAVE_X11}" = "yes"; then
1699 if test "${USE_X_TOOLKIT}" != "none"; then
1700 old_c_flags="${CFLAGS}"
1701 CFLAGS="${LD_SWITCH_X_SITE}"
1702 AC_CHECK_HEADER(X11/Xaw3d/Scrollbar.h,
1703 AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb, HAVE_XAW3D=yes, , -lX11))
1704 CFLAGS="${old_c_flags}"
1705
1706 if test "${HAVE_XAW3D}" = "yes"; then
1707 AC_DEFINE(HAVE_XAW3D)
1708 fi
1709 fi
1710 fi
1711
1712 dnl Use toolkit scroll bars if configured for X toolkit and either
1713 dnl using Motif or Xaw3d is available, and unless
1714 dnl --with-toolkit-scroll-bars=no was specified.
1715
1716 USE_TOOLKIT_SCROLL_BARS=no
1717 if test "${with_toolkit_scroll_bars}" != "no"; then
1718 if test "${USE_X_TOOLKIT}" != "none"; then
1719 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
1720 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1721 HAVE_XAW3D=no
1722 USE_TOOLKIT_SCROLL_BARS=yes
1723 elif test "${HAVE_XAW3D}" = "yes"; then
1724 AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
1725 USE_TOOLKIT_SCROLL_BARS=yes
1726 fi
1727 fi
1728 fi
1729
1730 ### Use -lXpm if available, unless `--with-xpm=no'.
1731 HAVE_XPM=no
1732 if test "${HAVE_X11}" = "yes"; then
1733 if test "${with_xpm}" != "no"; then
1734 old_c_flags="${CFLAGS}"
1735 CFLAGS="${LD_SWITCH_X_SITE}"
1736 AC_CHECK_HEADER(X11/xpm.h,
1737 AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11))
1738 CFLAGS="${old_c_flags}"
1739 fi
1740
1741 if test "${HAVE_XPM}" = "yes"; then
1742 AC_DEFINE(HAVE_XPM)
1743 fi
1744 fi
1745
1746 ### Use -ljpeg if available, unless `--with-jpeg=no'.
1747 HAVE_JPEG=no
1748 if test "${HAVE_X11}" = "yes"; then
1749 if test "${with_jpeg}" != "no"; then
1750 old_c_flags="${CFLAGS}"
1751 CFLAGS="${LD_SWITCH_X_SITE} ${CFLAGS}"
1752 dnl Checking for jpeglib.h can lose becsue of a redefinition of
1753 dnl HAVE_STDLIB_H.
1754 AC_CHECK_HEADER(jerror.h,
1755 AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes, , -lX11))
1756 CFLAGS="${old_c_flags}"
1757 fi
1758
1759 if test "${HAVE_JPEG}" = "yes"; then
1760 AC_DEFINE(HAVE_JPEG)
1761 fi
1762 fi
1763
1764 ### Use -lpng if available, unless `--with-png=no'.
1765 HAVE_PNG=no
1766 if test "${HAVE_X11}" = "yes"; then
1767 if test "${with_png}" != "no"; then
1768 old_c_flags="${CFLAGS}"
1769 CFLAGS="${LD_SWITCH_X_SITE} ${CFLAGS}"
1770 AC_CHECK_HEADER(png.h,
1771 AC_CHECK_LIB(png, png_set_expand, HAVE_PNG=yes, , -lX11 -lz -lm))
1772 CFLAGS="${old_c_flags}"
1773 fi
1774
1775 if test "${HAVE_PNG}" = "yes"; then
1776 AC_DEFINE(HAVE_PNG)
1777 fi
1778 fi
1779
1780 ### Use -ltiff if available, unless `--with-tiff=no'.
1781 HAVE_TIFF=no
1782 if test "${HAVE_X11}" = "yes"; then
1783 if test "${with_tiff}" != "no"; then
1784 old_c_flags="${CFLAGS}"
1785 CFLAGS="${LD_SWITCH_X_SITE} ${CFLAGS}"
1786 AC_CHECK_HEADER(tiffio.h,
1787 tifflibs="-lX11 -lz -lm"
1788 # At least one tiff package requires the jpeg library.
1789 if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
1790 AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs))
1791 CFLAGS="${old_c_flags}"
1792 fi
1793
1794 if test "${HAVE_TIFF}" = "yes"; then
1795 AC_DEFINE(HAVE_TIFF)
1796 fi
1797 fi
1798
1799 ### Use -lgif if available, unless `--with-gif=no'.
1800 HAVE_GIF=no
1801 if test "${HAVE_X11}" = "yes"; then
1802 if test "${with_gif}" != "no"; then
1803 old_c_flags="${CFLAGS}"
1804 CFLAGS="${LD_SWITCH_X_SITE} ${CFLAGS}"
1805 AC_CHECK_HEADER(gif_lib.h,
1806 AC_CHECK_LIB(ungif, DGifOpen, HAVE_GIF=yes, , -lX11))
1807 CFLAGS="${old_c_flags}"
1808 fi
1809
1810 if test "${HAVE_GIF}" = "yes"; then
1811 AC_DEFINE(HAVE_GIF)
1812 fi
1813 fi
1814
1815 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1816 AC_CACHE_CHECK(whether netdb declares h_errno,
1817 emacs_cv_netdb_declares_h_errno,
1818 AC_TRY_LINK([#include <netdb.h>],
1819 [return h_errno;],
1820 emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no))
1821 if test $emacs_cv_netdb_declares_h_errno = yes; then
1822 AC_DEFINE(HAVE_H_ERRNO)
1823 fi
1824
1825 AC_FUNC_ALLOCA
1826
1827 # fmod, logb, and frexp are found in -lm on most systems.
1828 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
1829 AC_CHECK_LIB(m, sqrt)
1830
1831 # Check for mail-locking functions in a "mail" library
1832 AC_CHECK_LIB(mail, maillock)
1833 dnl Debian, at least:
1834 dnl AC_CHECK_LIB(lockfile, maillock, [AC_DEFINE(HAVE_LIBMAIL)])
1835 AC_CHECK_LIB(lockfile, maillock)
1836 # If we have the shared liblockfile, assume we must use it for mail
1837 # locking (e.g. Debian). If we couldn't link against liblockfile
1838 # (no liblockfile.a installed), ensure that we don't need to.
1839 if test "$ac_cv_lib_lockfile_maillock" = no; then
1840 dnl This works for files generally, not just executables.
1841 dnl Should we look elsewhere for it? Maybe examine /etc/ld.so.conf?
1842 AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
1843 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
1844 if test $ac_cv_prog_liblockfile = yes; then
1845 AC_MSG_ERROR([Shared liblockfile found but can't link against it.
1846 This probably means that movemail could lose mail.
1847 There may be a \`development' package to install containing liblockfile.])
1848 else AC_DEFINE(LIBMAIL, -llockfile)
1849 fi
1850 else :
1851 fi
1852 AC_CHECK_FUNCS(touchlock)
1853 AC_CHECK_HEADERS(maillock.h)
1854
1855 AC_CHECK_FUNCS(gettimeofday gethostname getdomainname dup2 \
1856 rename closedir mkdir rmdir sysinfo \
1857 random lrand48 bcopy bcmp logb frexp fmod rint cbrt ftime res_init setsid \
1858 strerror fpathconf select mktime euidaccess getpagesize tzset setlocale \
1859 utimes setrlimit setpgid getcwd shutdown strftime getaddrinfo \
1860 __fpending ftello getloadavg mblen mbrlen strsignal setitimer ualarm)
1861
1862 AC_FUNC_MKTIME
1863 if test "$ac_cv_func_working_mktime" = no; then
1864 AC_DEFINE(BROKEN_MKTIME)
1865 fi
1866
1867 # UNIX98 PTYs.
1868 AC_CHECK_FUNCS(grantpt)
1869
1870 # PTY-related GNU extensions.
1871 AC_CHECK_FUNCS(getpt)
1872
1873 # Check this now, so that we will NOT find the above functions in ncurses.
1874 # That is because we have not set up to link ncurses in lib-src.
1875 # It's better to believe a function is not available
1876 # than to expect to find it in ncurses.
1877 AC_CHECK_LIB(ncurses, tparm)
1878
1879 # These tell us which Kerberos-related libraries to use.
1880 if test "${with_kerberos+set}" = set; then
1881 AC_CHECK_LIB(com_err, com_err)
1882 AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt)
1883 AC_CHECK_LIB(crypto, mit_des_cbc_encrypt)
1884 AC_CHECK_LIB(krb5, krb5_init_context)
1885 if test "${with_kerberos5+set}" != set; then
1886 AC_CHECK_LIB(des425, des_cbc_encrypt,,
1887 AC_CHECK_LIB(des, des_cbc_encrypt))
1888 AC_CHECK_LIB(krb4, krb_get_cred,,
1889 AC_CHECK_LIB(krb, krb_get_cred))
1890 fi
1891
1892 if test "${with_kerberos5+set}" = set; then
1893 AC_CHECK_HEADERS(krb5.h)
1894 else
1895 AC_CHECK_HEADERS(des.h,,
1896 AC_CHECK_HEADERS(kerberosIV/des.h,,
1897 AC_CHECK_HEADERS(kerberos/des.h)))
1898 AC_CHECK_HEADERS(krb.h,,
1899 AC_CHECK_HEADERS(kerberosIV/krb.h,,
1900 AC_CHECK_HEADERS(kerberos/krb.h)))
1901 fi
1902 AC_CHECK_HEADERS(com_err.h)
1903 fi
1904
1905 # Solaris requires -lintl if you want strerror (which calls dgettext)
1906 # to return localized messages.
1907 AC_CHECK_LIB(intl, dgettext)
1908
1909 AC_MSG_CHECKING(whether localtime caches TZ)
1910 AC_CACHE_VAL(emacs_cv_localtime_cache,
1911 [if test x$ac_cv_func_tzset = xyes; then
1912 AC_TRY_RUN([#include <time.h>
1913 extern char **environ;
1914 unset_TZ ()
1915 {
1916 char **from, **to;
1917 for (to = from = environ; (*to = *from); from++)
1918 if (! (to[0][0] == 'T' && to[0][1] == 'Z' && to[0][2] == '='))
1919 to++;
1920 }
1921 char TZ_GMT0[] = "TZ=GMT0";
1922 char TZ_PST8[] = "TZ=PST8";
1923 main()
1924 {
1925 time_t now = time ((time_t *) 0);
1926 int hour_GMT0, hour_unset;
1927 if (putenv (TZ_GMT0) != 0)
1928 exit (1);
1929 hour_GMT0 = localtime (&now)->tm_hour;
1930 unset_TZ ();
1931 hour_unset = localtime (&now)->tm_hour;
1932 if (putenv (TZ_PST8) != 0)
1933 exit (1);
1934 if (localtime (&now)->tm_hour == hour_GMT0)
1935 exit (1);
1936 unset_TZ ();
1937 if (localtime (&now)->tm_hour != hour_unset)
1938 exit (1);
1939 exit (0);
1940 }], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
1941 [# If we have tzset, assume the worst when cross-compiling.
1942 emacs_cv_localtime_cache=yes])
1943 else
1944 # If we lack tzset, report that localtime does not cache TZ,
1945 # since we can't invalidate the cache if we don't have tzset.
1946 emacs_cv_localtime_cache=no
1947 fi])dnl
1948 AC_MSG_RESULT($emacs_cv_localtime_cache)
1949 if test $emacs_cv_localtime_cache = yes; then
1950 AC_DEFINE(LOCALTIME_CACHE)
1951 fi
1952
1953 if test "x$HAVE_TIMEVAL" = xyes; then
1954 AC_CACHE_CHECK(whether gettimeofday can accept two arguments,
1955 emacs_cv_gettimeofday_two_arguments,
1956 AC_TRY_LINK([
1957 #ifdef TIME_WITH_SYS_TIME
1958 #include <sys/time.h>
1959 #include <time.h>
1960 #else
1961 #ifdef HAVE_SYS_TIME_H
1962 #include <sys/time.h>
1963 #else
1964 #include <time.h>
1965 #endif
1966 #endif
1967 ],
1968 [
1969 struct timeval time;
1970 struct timezone dummy;
1971 gettimeofday (&time, &dummy);
1972 ],
1973 emacs_cv_gettimeofday_two_arguments=yes,
1974 emacs_cv_gettimeofday_two_arguments=no))
1975 if test $emacs_cv_gettimeofday_two_arguments = no; then
1976 AC_DEFINE(GETTIMEOFDAY_ONE_ARGUMENT)
1977 fi
1978 fi
1979
1980 ok_so_far=yes
1981 AC_CHECK_FUNC(socket, , ok_so_far=no)
1982 if test $ok_so_far = yes; then
1983 AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
1984 fi
1985 if test $ok_so_far = yes; then
1986 AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
1987 fi
1988 if test $ok_so_far = yes; then
1989 AC_DEFINE(HAVE_INET_SOCKETS)
1990 fi
1991
1992 if test -f /usr/lpp/X11/bin/smt.exp; then
1993 AC_DEFINE(HAVE_AIX_SMT_EXP)
1994 fi
1995
1996 AC_MSG_CHECKING(whether system supports dynamic ptys)
1997 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
1998 AC_MSG_RESULT(yes)
1999 AC_DEFINE(HAVE_DEV_PTMX)
2000 else
2001 AC_MSG_RESULT(no)
2002 fi
2003
2004 AC_FUNC_VFORK
2005
2006 # Set up the CFLAGS for real compilation, so we can substitute it.
2007 CFLAGS="$REAL_CFLAGS"
2008
2009 changequote(, )dnl
2010 #### Find out which version of Emacs this is.
2011 version=`grep 'defconst[ ]*emacs-version' ${srcdir}/lisp/version.el \
2012 | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
2013 changequote([, ])dnl
2014 if test x"${version}" = x; then
2015 AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
2016 fi
2017
2018 ### Specify what sort of things we'll be editing into Makefile and config.h.
2019 ### Use configuration here uncanonicalized to avoid exceeding size limits.
2020 AC_SUBST(version)
2021 AC_SUBST(configuration)
2022 AC_SUBST(canonical)
2023 AC_SUBST(srcdir)
2024 AC_SUBST(prefix)
2025 AC_SUBST(exec_prefix)
2026 AC_SUBST(bindir)
2027 AC_SUBST(datadir)
2028 AC_SUBST(sharedstatedir)
2029 AC_SUBST(libexecdir)
2030 AC_SUBST(mandir)
2031 AC_SUBST(infodir)
2032 AC_SUBST(lispdir)
2033 AC_SUBST(locallisppath)
2034 AC_SUBST(lisppath)
2035 AC_SUBST(x_default_search_path)
2036 AC_SUBST(etcdir)
2037 AC_SUBST(archlibdir)
2038 AC_SUBST(docdir)
2039 AC_SUBST(bitmapdir)
2040 AC_SUBST(c_switch_system)
2041 AC_SUBST(c_switch_machine)
2042 AC_SUBST(LD_SWITCH_X_SITE)
2043 AC_SUBST(LD_SWITCH_X_SITE_AUX)
2044 AC_SUBST(C_SWITCH_X_SITE)
2045 AC_SUBST(CFLAGS)
2046 AC_SUBST(X_TOOLKIT_TYPE)
2047 AC_SUBST(machfile)
2048 AC_SUBST(opsysfile)
2049
2050 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION, "${canonical}")
2051 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}")
2052 AC_DEFINE_UNQUOTED(config_machfile, "${machfile}")
2053 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
2054 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
2055 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
2056 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE, ${C_SWITCH_X_SITE})
2057 AC_DEFINE_UNQUOTED(UNEXEC_SRC, ${UNEXEC_SRC})
2058
2059 if test "${HAVE_X_WINDOWS}" = "yes" ; then
2060 AC_DEFINE(HAVE_X_WINDOWS)
2061 fi
2062 if test "${USE_X_TOOLKIT}" != "none" ; then
2063 AC_DEFINE(USE_X_TOOLKIT)
2064 fi
2065 if test "${HAVE_X11}" = "yes" ; then
2066 AC_DEFINE(HAVE_X11)
2067 fi
2068 if test "${HAVE_XFREE386}" = "yes" ; then
2069 AC_DEFINE(HAVE_XFREE386)
2070 fi
2071 if test "${HAVE_MENUS}" = "yes" ; then
2072 AC_DEFINE(HAVE_MENUS)
2073 fi
2074 if test "${GNU_MALLOC}" = "yes" ; then
2075 AC_DEFINE(GNU_MALLOC)
2076 fi
2077 if test "${REL_ALLOC}" = "yes" ; then
2078 AC_DEFINE(REL_ALLOC)
2079 fi
2080
2081 #### Report on what we decided to do.
2082 echo "
2083 Configured for \`${canonical}'.
2084
2085 Where should the build process find the source code? ${srcdir}
2086 What operating system and machine description files should Emacs use?
2087 \`${opsysfile}' and \`${machfile}'
2088 What compiler should emacs be built with? ${CC} ${CFLAGS}
2089 Should Emacs use the GNU version of malloc? ${GNU_MALLOC}${GNU_MALLOC_reason}
2090 Should Emacs use the relocating allocator for buffers? ${REL_ALLOC}
2091 What window system should Emacs use? ${window_system}
2092 What toolkit should Emacs use? ${USE_X_TOOLKIT}"
2093
2094 if test -n "${x_includes}"; then
2095 echo " Where do we find X Windows header files? ${x_includes}"
2096 else
2097 echo " Where do we find X Windows header files? Standard dirs"
2098 fi
2099 if test -n "${x_libraries}"; then
2100 echo " Where do we find X Windows libraries? ${x_libraries}"
2101 else
2102 echo " Where do we find X Windows libraries? Standard dirs"
2103 fi
2104
2105 echo " Does Emacs use -lXaw3d? ${HAVE_XAW3D}"
2106 echo " Does Emacs use -lXpm? ${HAVE_XPM}"
2107 echo " Does Emacs use -ljpeg? ${HAVE_JPEG}"
2108 echo " Does Emacs use -ltiff? ${HAVE_TIFF}"
2109 echo " Does Emacs use -lungif? ${HAVE_GIF}"
2110 echo " Does Emacs use -lpng? ${HAVE_PNG}"
2111 echo " Does Emacs use X toolkit scroll bars? ${USE_TOOLKIT_SCROLL_BARS}"
2112 echo
2113
2114 # Remove any trailing slashes in these variables.
2115 changequote(, )dnl
2116 test "${prefix}" != NONE &&
2117 prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
2118 test "${exec_prefix}" != NONE &&
2119 exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
2120 changequote([, ])dnl
2121
2122 AC_OUTPUT(Makefile lib-src/Makefile.c:lib-src/Makefile.in oldXMenu/Makefile \
2123 man/Makefile lwlib/Makefile src/Makefile.c:src/Makefile.in \
2124 leim/Makefile, [
2125
2126 ### Make the necessary directories, if they don't exist.
2127 for dir in etc lisp ; do
2128 test -d ${dir} || mkdir ${dir}
2129 done
2130
2131 # Build src/Makefile from ${srcdir}/src/Makefile.c
2132 # and lib-src/Makefile from ${srcdir}/lib-src/Makefile.c
2133 # This must be done after src/config.h is built, since we rely on that file.
2134
2135 changequote(, )dnl The horror, the horror.
2136 # Now get this: Some word that is part of the ${srcdir} directory name
2137 # or the ${configuration} value might, just might, happen to be an
2138 # identifier like `sun4' or `i386' or something, and be predefined by
2139 # the C preprocessor to some helpful value like 1, or maybe the empty
2140 # string. Needless to say consequent macro substitutions are less
2141 # than conducive to the makefile finding the correct directory.
2142 undefs="`echo $top_srcdir $configuration $canonical |
2143 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/ *$//' \
2144 -e 's/ */ -U/g' -e 's/-U[0-9][^ ]*//g' \
2145 `"
2146 changequote([, ])dnl
2147
2148 echo creating src/epaths.h
2149 make epaths-force
2150
2151 echo creating lib-src/Makefile
2152 ( cd lib-src
2153 rm -f junk.c junk1.c junk2.c
2154 sed -e '/start of cpp stuff/q' \
2155 < Makefile.c > junk1.c
2156 sed -e '1,/start of cpp stuff/d'\
2157 -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
2158 < Makefile.c > junk.c
2159 $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
2160 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2161 cat junk1.c junk2.c > Makefile.new
2162 rm -f junk.c junk1.c junk2.c
2163 chmod 444 Makefile.new
2164 mv -f Makefile.new Makefile
2165 )
2166
2167 echo creating src/Makefile
2168 ( cd src
2169 rm -f junk.c junk1.c junk2.c
2170 sed -e '/start of cpp stuff/q' \
2171 < Makefile.c > junk1.c
2172 sed -e '1,/start of cpp stuff/d'\
2173 -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
2174 < Makefile.c > junk.c
2175 $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
2176 sed -e 's/^ / /' -e '/^#/d' -e '/^[ \f]*$/d' > junk2.c
2177 cat junk1.c junk2.c > Makefile.new
2178 rm -f junk.c junk1.c junk2.c
2179 chmod 444 Makefile.new
2180 mv -f Makefile.new Makefile
2181 )
2182
2183 if test ! -f src/.gdbinit && test -f $top_srcdir/src/.gdbinit; then
2184 echo creating src/.gdbinit
2185 echo source $top_srcdir/src/.gdbinit > src/.gdbinit
2186 fi
2187
2188 # This is how we know whether to re-run configure in certain cases.
2189 touch src/config.stamp
2190
2191 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])