code.delx.au - gnu-emacs/blob - lisp/mail/rmailedit.el

   1 ;;; rmailedit.el --- "RMAIL edit mode"  Edit the current message.
   2
   3 ;; Copyright (C) 1985, 1994 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: mail
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Code:
  25
  26 (require 'rmail)
  27
  28 (defvar rmail-edit-map nil)
  29 (if rmail-edit-map
  30     nil
  31   ;; Make a keymap that inherits text-mode-map.
  32   (setq rmail-edit-map (nconc (make-sparse-keymap) text-mode-map))
  33   (define-key rmail-edit-map "\C-c\C-c" 'rmail-cease-edit)
  34   (define-key rmail-edit-map "\C-c\C-]" 'rmail-abort-edit))
  35
  36 ;; Rmail Edit mode is suitable only for specially formatted data.
  37 (put 'rmail-edit-mode 'mode-class 'special)
  38
  39 (defun rmail-edit-mode ()
  40   "Major mode for editing the contents of an RMAIL message.
  41 The editing commands are the same as in Text mode, together with two commands
  42 to return to regular RMAIL:
  43   *  rmail-abort-edit cancels the changes
  44      you have made and returns to RMAIL
  45   *  rmail-cease-edit makes them permanent.
  46 \\{rmail-edit-map}"
  47   (use-local-map rmail-edit-map)
  48   (setq major-mode 'rmail-edit-mode)
  49   (setq mode-name "RMAIL Edit")
  50   (if (boundp 'mode-line-modified)
  51       (setq mode-line-modified (default-value 'mode-line-modified))
  52     (setq mode-line-format (default-value 'mode-line-format)))
  53   (if (rmail-summary-exists)
  54       (save-excursion
  55         (set-buffer rmail-summary-buffer)
  56         (rmail-summary-disable)))
  57   (run-hooks 'text-mode-hook 'rmail-edit-mode-hook))
  58
  59 (defun rmail-edit-current-message ()
  60   "Edit the contents of this message."
  61   (interactive)
  62   (rmail-edit-mode)
  63   (make-local-variable 'rmail-old-text)
  64   (setq rmail-old-text (buffer-substring (point-min) (point-max)))
  65   (setq buffer-read-only nil)
  66   (set-buffer-modified-p (buffer-modified-p))
  67   ;; Make mode line update.
  68   (if (and (eq (key-binding "\C-c\C-c") 'rmail-cease-edit)
  69            (eq (key-binding "\C-c\C-]") 'rmail-abort-edit))
  70       (message "Editing: Type C-c C-c to return to Rmail, C-c C-] to abort")
  71     (message (substitute-command-keys
  72                "Editing: Type \\[rmail-cease-edit] to return to Rmail, \\[rmail-abort-edit] to abort"))))
  73
  74 (defun rmail-cease-edit ()
  75   "Finish editing message; switch back to Rmail proper."
  76   (interactive)
  77   (if (rmail-summary-exists)
  78       (save-excursion
  79         (set-buffer rmail-summary-buffer)
  80         (rmail-summary-enable)))
  81   ;; Make sure buffer ends with a newline.
  82   (save-excursion
  83     (goto-char (point-max))
  84     (if (/= (preceding-char) ?\n)
  85         (insert "\n"))
  86     ;; Adjust the marker that points to the end of this message.
  87     (set-marker (aref rmail-message-vector (1+ rmail-current-message))
  88                 (point)))
  89   (let ((old rmail-old-text))
  90     ;; Update the mode line.
  91     (set-buffer-modified-p (buffer-modified-p))
  92     (rmail-mode-1)
  93     (if (and (= (length old) (- (point-max) (point-min)))
  94              (string= old (buffer-substring (point-min) (point-max))))
  95         ()
  96       (setq old nil)
  97       (rmail-set-attribute "edited" t)
  98       (if (boundp 'rmail-summary-vector)
  99           (progn
 100             (aset rmail-summary-vector (1- rmail-current-message) nil)
 101             (save-excursion
 102               (rmail-widen-to-current-msgbeg
 103                 (function (lambda ()
 104                             (forward-line 2)
 105                             (if (looking-at "Summary-line: ")
 106                                 (let ((buffer-read-only nil))
 107                                   (delete-region (point)
 108                                                  (progn (forward-line 1)
 109                                                         (point))))))))
 110               (rmail-show-message))))))
 111   (setq buffer-read-only t))
 112
 113 (defun rmail-abort-edit ()
 114   "Abort edit of current message; restore original contents."
 115   (interactive)
 116   (delete-region (point-min) (point-max))
 117   (insert rmail-old-text)
 118   (rmail-cease-edit)
 119   (rmail-highlight-headers))
 120
 121 ;;; rmailedit.el ends here