code.delx.au - gnu-emacs/blob - lisp/tooltip.el

   1 ;;; tooltip.el --- show tooltip windows
   2
   3 ;; Copyright (C) 1997, 1999, 2000, 2001, 2002, 2003, 2004, 2005
   4 ;;        Free Software Foundation, Inc.
   5
   6 ;; Author: Gerd Moellmann <gerd@acm.org>
   7 ;; Keywords: help c mouse tools
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 (eval-when-compile (require 'cl)) ; for case macro
  31
  32 \f
  33 ;;; Customizable settings
  34
  35 (defgroup tooltip nil
  36   "Customization group for the `tooltip' package."
  37   :group 'help
  38   :group 'gud
  39   :group 'mouse
  40   :group 'tools
  41   :version "21.1"
  42   :tag "Tool Tips")
  43
  44 (defcustom tooltip-delay 0.7
  45   "Seconds to wait before displaying a tooltip the first time."
  46   :tag "Delay"
  47   :type 'number
  48   :group 'tooltip)
  49
  50 (defcustom tooltip-short-delay 0.1
  51   "Seconds to wait between subsequent tooltips on different items."
  52   :tag "Short delay"
  53   :type 'number
  54   :group 'tooltip)
  55
  56 (defcustom tooltip-recent-seconds 1
  57   "Display tooltips if changing tip items within this many seconds.
  58 Do so after `tooltip-short-delay'."
  59   :tag "Recent seconds"
  60   :type 'number
  61   :group 'tooltip)
  62
  63 (defcustom tooltip-hide-delay 10
  64   "Hide tooltips automatically after this many seconds."
  65   :tag "Hide delay"
  66   :type 'number
  67   :group 'tooltip)
  68
  69 (defcustom tooltip-x-offset nil
  70   "X offset, in pixels, for the display of tooltips.
  71 The offset is relative to the position of the mouse.  It must
  72 be chosen so that the tooltip window doesn't contain the mouse
  73 when it pops up.  If the value is nil, the default offset is 5
  74 pixels.
  75
  76 If `tooltip-frame-parameters' includes the `left' parameter,
  77 the value of `tooltip-x-offset' is ignored."
  78   :tag "X offset"
  79   :type '(choice (const :tag "Default" nil)
  80                  (integer :tag "Offset" :value 1))
  81   :group 'tooltip)
  82
  83 (defcustom tooltip-y-offset nil
  84   "Y offset, in pixels, for the display of tooltips.
  85 The offset is relative to the position of the mouse.  It must
  86 be chosen so that the tooltip window doesn't contain the mouse
  87 when it pops up.  If the value is nil, the default offset is -10
  88 pixels.
  89
  90 If `tooltip-frame-parameters' includes the `top' parameter,
  91 the value of `tooltip-y-offset' is ignored."
  92   :tag "Y offset"
  93   :type '(choice (const :tag "Default" nil)
  94                  (integer :tag "Offset" :value 1))
  95   :group 'tooltip)
  96
  97 (defcustom tooltip-frame-parameters
  98   '((name . "tooltip")
  99     (internal-border-width . 5)
 100     (border-width . 1))
 101   "Frame parameters used for tooltips.
 102
 103 If `left' or `top' parameters are included, they specify the absolute
 104 position to pop up the tooltip."
 105   :type 'sexp
 106   :tag "Frame Parameters"
 107   :group 'tooltip)
 108
 109 (defface tooltip
 110   '((((class color))
 111      :background "lightyellow"
 112      :foreground "black"
 113      :inherit variable-pitch)
 114     (t
 115      :inherit variable-pitch))
 116   "Face for tooltips."
 117   :group 'tooltip)
 118
 119 (defcustom tooltip-gud-tips-p nil
 120   "*Non-nil means show tooltips in GUD sessions."
 121   :type 'boolean
 122   :tag "GUD"
 123   :group 'tooltip)
 124
 125 (defcustom tooltip-gud-modes '(gud-mode c-mode c++-mode fortran-mode)
 126   "List of modes for which to enable GUD tips."
 127   :type 'sexp
 128   :tag "GUD modes"
 129   :group 'tooltip)
 130
 131 (defcustom tooltip-gud-display
 132   '((eq (tooltip-event-buffer tooltip-gud-event)
 133         (marker-buffer gud-overlay-arrow-position)))
 134   "List of forms determining where GUD tooltips are displayed.
 135
 136 Forms in the list are combined with AND.  The default is to display
 137 only tooltips in the buffer containing the overlay arrow."
 138   :type 'sexp
 139   :tag "GUD buffers predicate"
 140   :group 'tooltip)
 141
 142 (defcustom tooltip-gud-echo-area nil
 143   "Use the echo area instead of frames for GUD tooltips."
 144   :type 'boolean
 145   :tag "Use echo area"
 146   :group 'tooltip)
 147
 148 \f
 149 ;;; Variables that are not customizable.
 150
 151 (defvar tooltip-hook nil
 152   "Functions to call to display tooltips.
 153 Each function is called with one argument EVENT which is a copy of
 154 the last mouse movement event that occurred.")
 155
 156 (defvar tooltip-timeout-id nil
 157   "The id of the timeout started when Emacs becomes idle.")
 158
 159 (defvar tooltip-last-mouse-motion-event nil
 160   "A copy of the last mouse motion event seen.")
 161
 162 (defvar tooltip-hide-time nil
 163   "Time when the last tooltip was hidden.")
 164
 165 \f
 166 ;;; Event accessors
 167
 168 (defun tooltip-event-buffer (event)
 169   "Return the buffer over which event EVENT occurred.
 170 This might return nil if the event did not occur over a buffer."
 171   (let ((window (posn-window (event-end event))))
 172     (and window (window-buffer window))))
 173
 174 \f
 175 ;;; Switching tooltips on/off
 176
 177 ;; We don't set track-mouse globally because this is a big redisplay
 178 ;; problem in buffers having a pre-command-hook or such installed,
 179 ;; which does a set-buffer, like the summary buffer of Gnus.  Calling
 180 ;; set-buffer prevents redisplay optimizations, so every mouse motion
 181 ;; would be accompanied by a full redisplay.
 182
 183 ;;;###autoload
 184 (define-minor-mode tooltip-mode
 185   "Toggle Tooltip display.
 186 With ARG, turn tooltip mode on if and only if ARG is positive."
 187   :global t
 188   ;; If you change the :init-value below, you also need to change the
 189   ;; corresponding code in startup.el.
 190   :init-value (not (or noninteractive
 191                        (and (boundp 'emacs-quick-startup) emacs-quick-startup)
 192                        (not (and (fboundp 'display-graphic-p)
 193                                  (display-graphic-p)))
 194                        (not (fboundp 'x-show-tip))))
 195   :group 'tooltip
 196   (unless (or (null tooltip-mode) (fboundp 'x-show-tip))
 197     (error "Sorry, tooltips are not yet available on this system"))
 198   (let ((hook-fn (if tooltip-mode 'add-hook 'remove-hook)))
 199     (funcall hook-fn 'change-major-mode-hook 'tooltip-change-major-mode)
 200     (tooltip-activate-mouse-motions-if-enabled)
 201     (funcall hook-fn 'pre-command-hook 'tooltip-hide)
 202     (funcall hook-fn 'tooltip-hook 'tooltip-gud-tips)
 203     (funcall hook-fn 'tooltip-hook 'tooltip-help-tips)
 204     (setq show-help-function (if tooltip-mode 'tooltip-show-help-function nil))
 205     ;; `ignore' is the default binding for mouse movements.
 206     (define-key global-map [mouse-movement]
 207       (if tooltip-mode 'tooltip-mouse-motion 'ignore))))
 208
 209 \f
 210 ;;; Timeout for tooltip display
 211
 212 (defun tooltip-delay ()
 213   "Return the delay in seconds for the next tooltip."
 214   (let ((delay tooltip-delay)
 215         (now (float-time)))
 216     (when (and tooltip-hide-time
 217                (< (- now tooltip-hide-time) tooltip-recent-seconds))
 218       (setq delay tooltip-short-delay))
 219     delay))
 220
 221 (defun tooltip-cancel-delayed-tip ()
 222   "Disable the tooltip timeout."
 223   (when tooltip-timeout-id
 224     (disable-timeout tooltip-timeout-id)
 225     (setq tooltip-timeout-id nil)))
 226
 227 (defun tooltip-start-delayed-tip ()
 228   "Add a one-shot timeout to call function tooltip-timeout."
 229   (setq tooltip-timeout-id
 230         (add-timeout (tooltip-delay) 'tooltip-timeout nil)))
 231
 232 (defun tooltip-timeout (object)
 233   "Function called when timer with id tooltip-timeout-id fires."
 234   (run-hook-with-args-until-success 'tooltip-hook
 235                                     tooltip-last-mouse-motion-event))
 236
 237 \f
 238 ;;; Reacting on mouse movements
 239
 240 (defun tooltip-change-major-mode ()
 241   "Function added to `change-major-mode-hook' when tooltip mode is on."
 242   (add-hook 'post-command-hook 'tooltip-activate-mouse-motions-if-enabled))
 243
 244 (defun tooltip-activate-mouse-motions-if-enabled ()
 245   "Reconsider for all buffers whether mouse motion events are desired."
 246   (remove-hook 'post-command-hook 'tooltip-activate-mouse-motions-if-enabled)
 247   (dolist (buffer (buffer-list))
 248     (save-excursion
 249       (set-buffer buffer)
 250       (if (and tooltip-mode
 251                tooltip-gud-tips-p
 252                (memq major-mode tooltip-gud-modes))
 253           (tooltip-activate-mouse-motions t)
 254         (tooltip-activate-mouse-motions nil)))))
 255
 256 (defvar tooltip-mouse-motions-active nil
 257   "Locally t in a buffer if tooltip processing of mouse motion is enabled.")
 258
 259 (defun tooltip-activate-mouse-motions (activatep)
 260   "Activate/deactivate mouse motion events for the current buffer.
 261 ACTIVATEP non-nil means activate mouse motion events."
 262   (if activatep
 263       (progn
 264         (make-local-variable 'tooltip-mouse-motions-active)
 265         (setq tooltip-mouse-motions-active t)
 266         (make-local-variable 'track-mouse)
 267         (setq track-mouse t))
 268     (when tooltip-mouse-motions-active
 269       (kill-local-variable 'tooltip-mouse-motions-active)
 270       (kill-local-variable 'track-mouse))))
 271
 272 (defun tooltip-mouse-motion (event)
 273   "Command handler for mouse movement events in `global-map'."
 274   (interactive "e")
 275   (tooltip-hide)
 276   (when (car (mouse-pixel-position))
 277     (setq tooltip-last-mouse-motion-event (copy-sequence event))
 278     (tooltip-start-delayed-tip)))
 279
 280 \f
 281 ;;; Displaying tips
 282
 283 (defun tooltip-set-param (alist key value)
 284   "Change the value of KEY in alist ALIST to VALUE.
 285 If there's no association for KEY in ALIST, add one, otherwise
 286 change the existing association.  Value is the resulting alist."
 287   (let ((param (assq key alist)))
 288     (if (consp param)
 289         (setcdr param value)
 290       (push (cons key value) alist))
 291     alist))
 292
 293 (defun tooltip-show (text gud-tip)
 294   "Show a tooltip window displaying TEXT.
 295
 296 Text larger than `x-max-tooltip-size' is clipped.
 297
 298 If the alist in `tooltip-frame-parameters' includes `left' and `top'
 299 parameters, they determine the x and y position where the tooltip
 300 is displayed.  Otherwise, the tooltip pops at offsets specified by
 301 `tooltip-x-offset' and `tooltip-y-offset' from the current mouse
 302 position.
 303
 304 GUD-TIP is t if the tooltip is from a GUD session and nil otherwise."
 305   (if (and gud-tip tooltip-gud-echo-area)
 306       (message "%s" text)
 307     (condition-case error
 308         (let ((params (copy-sequence tooltip-frame-parameters))
 309               (fg (face-attribute 'tooltip :foreground))
 310               (bg (face-attribute 'tooltip :background)))
 311           (when (stringp fg)
 312             (setq params (tooltip-set-param params 'foreground-color fg))
 313             (setq params (tooltip-set-param params 'border-color fg)))
 314           (when (stringp bg)
 315             (setq params (tooltip-set-param params 'background-color bg)))
 316           (x-show-tip (propertize text 'face 'tooltip)
 317                       (selected-frame)
 318                       params
 319                       tooltip-hide-delay
 320                       tooltip-x-offset
 321                       tooltip-y-offset))
 322       (error
 323        (message "Error while displaying tooltip: %s" error)
 324        (sit-for 1)
 325        (message "%s" text)))))
 326
 327 (defun tooltip-hide (&optional ignored-arg)
 328   "Hide a tooltip, if one is displayed.
 329 Value is non-nil if tooltip was open."
 330   (tooltip-cancel-delayed-tip)
 331   (when (x-hide-tip)
 332     (setq tooltip-hide-time (float-time))))
 333
 334 \f
 335 ;;; Debugger-related functions
 336
 337 (defun tooltip-identifier-from-point (point)
 338   "Extract the identifier at POINT, if any.
 339 Value is nil if no identifier exists at point.  Identifier extraction
 340 is based on the current syntax table."
 341   (save-excursion
 342     (goto-char point)
 343     (let ((start (progn (skip-syntax-backward "w_") (point))))
 344       (unless (looking-at "[0-9]")
 345         (skip-syntax-forward "w_")
 346         (when (> (point) start)
 347           (buffer-substring start (point)))))))
 348
 349 (defmacro tooltip-region-active-p ()
 350   "Value is non-nil if the region is currently active."
 351   (if (string-match "^GNU" (emacs-version))
 352       `(and transient-mark-mode mark-active)
 353     `(region-active-p)))
 354
 355 (defun tooltip-expr-to-print (event)
 356   "Return an expression that should be printed for EVENT.
 357 If a region is active and the mouse is inside the region, print
 358 the region.  Otherwise, figure out the identifier around the point
 359 where the mouse is."
 360   (save-excursion
 361     (set-buffer (tooltip-event-buffer event))
 362     (let ((point (posn-point (event-end event))))
 363       (if (tooltip-region-active-p)
 364           (when (and (<= (region-beginning) point) (<= point (region-end)))
 365             (buffer-substring (region-beginning) (region-end)))
 366         (tooltip-identifier-from-point point)))))
 367
 368 (defun tooltip-process-prompt-regexp (process)
 369   "Return regexp matching the prompt of PROCESS at the end of a string.
 370 The prompt is taken from the value of COMINT-PROMPT-REGEXP in the buffer
 371 of PROCESS."
 372   (let ((prompt-regexp (save-excursion
 373                          (set-buffer (process-buffer process))
 374                          comint-prompt-regexp)))
 375     ;; Most start with `^' but the one for `sdb' cannot be easily
 376     ;; stripped.  Code the prompt for `sdb' fixed here.
 377     (if (= (aref prompt-regexp 0) ?^)
 378         (setq prompt-regexp (substring prompt-regexp 1))
 379       (setq prompt-regexp "\\*"))
 380     (concat "\n*" prompt-regexp "$")))
 381
 382 (defun tooltip-strip-prompt (process output)
 383   "Return OUTPUT with any prompt of PROCESS stripped from its end."
 384   (let ((prompt-regexp (tooltip-process-prompt-regexp process)))
 385     (save-match-data
 386       (when (string-match prompt-regexp output)
 387         (setq output (substring output 0 (match-beginning 0)))))
 388     output))
 389
 390 \f
 391 ;;; Tips for `gud'
 392
 393 (defvar tooltip-gud-original-filter nil
 394   "Process filter to restore after GUD output has been received.")
 395
 396 (defvar tooltip-gud-dereference nil
 397   "Non-nil means print expressions with a `*' in front of them.
 398 For C this would dereference a pointer expression.")
 399
 400 (defvar tooltip-gud-event nil
 401   "The mouse movement event that led to a tooltip display.
 402 This event can be examined by forms in TOOLTIP-GUD-DISPLAY.")
 403
 404 (defun tooltip-gud-toggle-dereference ()
 405   "Toggle whether tooltips should show `* expr' or `expr'."
 406   (interactive)
 407   (setq tooltip-gud-dereference (not tooltip-gud-dereference))
 408   (when (interactive-p)
 409     (message "Dereferencing is now %s."
 410              (if tooltip-gud-dereference "on" "off"))))
 411
 412 ; This will only display data that comes in one chunk.
 413 ; Larger arrays (say 400 elements) are displayed in
 414 ; the tootip incompletely and spill over into the gud buffer.
 415 ; Switching the process-filter creates timing problems and
 416 ; it may be difficult to do better. gdba in gdb-ui.el
 417 ; gets round this problem.
 418 (defun tooltip-gud-process-output (process output)
 419   "Process debugger output and show it in a tooltip window."
 420   (set-process-filter process tooltip-gud-original-filter)
 421   (tooltip-show (tooltip-strip-prompt process output) t))
 422
 423 (defun tooltip-gud-print-command (expr)
 424   "Return a suitable command to print the expression EXPR.
 425 If TOOLTIP-GUD-DEREFERENCE is t, also prepend a `*' to EXPR."
 426   (when tooltip-gud-dereference
 427     (setq expr (concat "*" expr)))
 428   (case gud-minor-mode
 429     ((gdb gdba) (concat "server print " expr))
 430     (dbx (concat "print " expr))
 431     (xdb (concat "p " expr))
 432     (sdb (concat expr "/"))
 433     (perldb expr)))
 434
 435 (defun tooltip-gud-tips (event)
 436   "Show tip for identifier or selection under the mouse.
 437 The mouse must either point at an identifier or inside a selected
 438 region for the tip window to be shown.  If tooltip-gud-dereference is t,
 439 add a `*' in front of the printed expression.
 440
 441 This function must return nil if it doesn't handle EVENT."
 442   (let (process)
 443     (when (and (eventp event)
 444                tooltip-gud-tips-p
 445                (boundp 'gud-comint-buffer)
 446                (setq process (get-buffer-process gud-comint-buffer))
 447                (posn-point (event-end event))
 448                (progn (setq tooltip-gud-event event)
 449                       (eval (cons 'and tooltip-gud-display))))
 450       (let ((expr (tooltip-expr-to-print event)))
 451         (when expr
 452           (let ((cmd (tooltip-gud-print-command expr)))
 453             (unless (null cmd)         ; CMD can be nil if unknown debugger
 454               (case gud-minor-mode
 455                     (gdba (gdb-enqueue-input
 456                            (list  (concat cmd "\n") 'gdb-tooltip-print)))
 457                     (t
 458                      (setq tooltip-gud-original-filter (process-filter process))
 459                        (set-process-filter process 'tooltip-gud-process-output)
 460                        (gud-basic-call cmd)))
 461                     expr)))))))
 462
 463 (defun gdb-tooltip-print ()
 464   (tooltip-show
 465    (with-current-buffer (gdb-get-buffer 'gdb-partial-output-buffer)
 466      (let ((string (buffer-string)))
 467        ;; remove newline for tooltip-gud-echo-area
 468        (substring string 0 (- (length string) 1)))) t))
 469
 470 \f
 471 ;;; Tooltip help.
 472
 473 (defvar tooltip-help-message nil
 474   "The last help message received via `tooltip-show-help-function'.")
 475
 476 (defun tooltip-show-help-function (msg)
 477   "Function installed as `show-help-function'.
 478 MSG is either a help string to display, or nil to cancel the display."
 479   (let ((previous-help tooltip-help-message))
 480     (setq tooltip-help-message msg)
 481     (cond ((null msg)
 482            ;; Cancel display.  This also cancels a delayed tip, if
 483            ;; there is one.
 484            (tooltip-hide))
 485           ((equal previous-help msg)
 486            ;; Same help as before (but possibly the mouse has moved).
 487            ;; Keep what we have.
 488            )
 489           (t
 490            ;; A different help.  Remove a previous tooltip, and
 491            ;; display a new one, with some delay.
 492            (tooltip-hide)
 493            (tooltip-start-delayed-tip)))))
 494
 495 (defun tooltip-help-tips (event)
 496   "Hook function to display a help tooltip.
 497 This is installed on the hook `tooltip-hook', which is run when
 498 the timer with ID `tooltip-timeout-id' fires.
 499 Value is non-nil if this function handled the tip."
 500   (when (stringp tooltip-help-message)
 501     (tooltip-show tooltip-help-message nil)
 502     t))
 503
 504 (provide 'tooltip)
 505
 506 ;; arch-tag: 3d61135e-4618-4a78-af28-183f6df5636f
 507 ;;; tooltip.el ends here