code.delx.au - gnu-emacs/blob - configure.in

   1 dnl This is an autoconf script.
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 AC_PREREQ(2.0)dnl
   6 AC_INIT(src/lisp.h)
   7 AC_CONFIG_HEADER(src/config.h)
   8
   9 bindir='${exec_prefix}/bin'
  10 datadir='${prefix}/share'
  11 sharedstatedir='${prefix}/com'
  12 libexecdir='${exec_prefix}/libexec'
  13 mandir='${prefix}/man/man1'
  14 infodir='${prefix}/info'
  15 lispdir='${datadir}/emacs/${version}/lisp'
  16 locallisppath='${datadir}/emacs/site-lisp'
  17 lisppath='${locallisppath}:${lispdir}'
  18 etcdir='${datadir}/emacs/${version}/etc'
  19 lockdir='${sharedstatedir}/emacs/lock'
  20 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  21 docdir='${datadir}/emacs/${version}/etc'
  22
  23 AC_ARG_WITH(gcc,
  24 [  --with-gcc              Use GCC to compile Emacs])
  25 AC_ARG_WITH(x-toolkit,
  26 [  --with-x-toolkit=KIT    Use an X toolkit (KIT = yes/lucid/athena/motif)],
  27 [         case "${withval}" in
  28             y | ye | yes )      val=athena ;;
  29             n | no )            val=no  ;;
  30             l | lu | luc | luci | lucid )       val=lucid ;;
  31             a | at | ath | athe | athena )      val=athena ;;
  32             m | mo | mot | moti | motif )       val=motif ;;
  33 dnl These don't currently work.
  34 dnl         o | op | ope | open | open- | open-l | open-lo \
  35 dnl             | open-loo | open-look )        val=open-look ;;
  36             * )
  37 dnl AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  38 dnl which is \`yes', \`no', \`lucid', \`athena', \`motif' or \`open-look'.])
  39 AC_MSG_ERROR([the \`--with-x-toolkit' option is supposed to have a value
  40 which is \`yes', \`no', \`lucid', \`athena', or \`motif'.
  41 Currently, \`yes', \`athena' and \`lucid' are synonyms.])
  42             ;;
  43           esac
  44           with_x_toolkit=$val
  45 ])
  46
  47 #### Make srcdir absolute, if it isn't already.  It's important to
  48 #### avoid running the path through pwd unnecessary, since pwd can
  49 #### give you automounter prefixes, which can go away.  We do all this
  50 #### so Emacs can find its files when run uninstalled.
  51 case "${srcdir}" in
  52   /* ) ;;
  53   . )
  54     ## We may be able to use the $PWD environment variable to make this
  55     ## absolute.  But sometimes PWD is inaccurate.
  56     if test "${PWD}" != "" && test "`(cd ${PWD} ; sh -c pwd)`" = "`pwd`"  ;
  57     then
  58       srcdir="$PWD"
  59     else
  60       srcdir="`(cd ${srcdir}; pwd)`"
  61     fi
  62   ;;
  63   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
  64 esac
  65
  66 #### Check if the source directory already has a configured system in it.
  67 if test `pwd` != `(cd ${srcdir} && pwd)` \
  68    && test -f "${srcdir}/src/config.h" ; then
  69   AC_MSG_WARN([The directory tree \`${srcdir}' is being used
  70    as a build directory right now; it has been configured in its own
  71    right.  To configure in another directory as well, you MUST
  72    use GNU make.  If you do not have GNU make, then you must
  73    now do \`make distclean' in ${srcdir},
  74    and then run $0 again.])
  75
  76   extrasub='/^VPATH[     ]*=/c\
  77 vpath %.c $(srcdir)\
  78 vpath %.h $(srcdir)\
  79 vpath %.y $(srcdir)\
  80 vpath %.l $(srcdir)\
  81 vpath %.s $(srcdir)\
  82 vpath %.in $(srcdir)'
  83 fi
  84
  85 #### Given the configuration name, set machfile and opsysfile to the
  86 #### names of the m/*.h and s/*.h files we should use.
  87
  88 ### Canonicalize the configuration name.
  89
  90 AC_CANONICAL_HOST
  91 canonical=$host
  92 configuration=$host_alias
  93
  94 changequote(, )dnl
  95
  96 ### If you add support for a new configuration, add code to this
  97 ### switch statement to recognize your configuration name and select
  98 ### the appropriate operating system and machine description files.
  99
 100 ### You would hope that you could choose an m/*.h file pretty much
 101 ### based on the machine portion of the configuration name, and an s-
 102 ### file based on the operating system portion.  However, it turns out
 103 ### that each m/*.h file is pretty manufacturer-specific - for
 104 ### example, apollo.h, hp9000s300.h, mega68k, news.h, and tad68k are
 105 ### all 68000 machines; mips.h, pmax.h, and news-risc are all MIPS
 106 ### machines.  So we basically have to have a special case for each
 107 ### configuration name.
 108 ###
 109 ### As far as handling version numbers on operating systems is
 110 ### concerned, make sure things will fail in a fixable way.  If
 111 ### /etc/MACHINES doesn't say anything about version numbers, be
 112 ### prepared to handle anything reasonably.  If version numbers
 113 ### matter, be sure /etc/MACHINES says something about it.
 114 ###
 115 ### Eric Raymond says we should accept strings like "sysvr4" to mean
 116 ### "System V Release 4"; he writes, "The old convention encouraged
 117 ### confusion between `system' and `release' levels'."
 118
 119 machine='' opsys='' unported=no
 120 case "${canonical}" in
 121
 122   ## NetBSD ports
 123   *-*-netbsd* )
 124     opsys=netbsd
 125     case "${canonical}" in
 126       i[345]86-*-netbsd*) machine=intel386 ;;
 127       m68k-*-netbsd*)
 128                         # This is somewhat bogus.
 129                         machine=hp9000s300 ;;
 130       mips-*-netbsd*)   machine=pmax ;;
 131       ns32k-*-netbsd*)  machine=ns32000 ;;
 132       sparc-*-netbsd*)  machine=sparc ;;
 133     esac
 134   ;;
 135
 136   ## Acorn RISCiX:
 137   arm-acorn-riscix1.1* )
 138     machine=acorn opsys=riscix1-1
 139   ;;
 140   arm-acorn-riscix1.2* | arm-acorn-riscix )
 141     machine=acorn opsys=riscix1-2
 142   ;;
 143
 144   ## Alliant machines
 145   ## Strictly speaking, we need the version of the alliant operating
 146   ## system to choose the right machine file, but currently the
 147   ## configuration name doesn't tell us enough to choose the right
 148   ## one; we need to give alliants their own operating system name to
 149   ## do this right.  When someone cares, they can help us.
 150   fx80-alliant-* )
 151     machine=alliant4 opsys=bsd4-2
 152   ;;
 153   i860-alliant-* )
 154     machine=alliant-2800 opsys=bsd4-3
 155   ;;
 156
 157   alpha-dec-osf* )
 158     machine=alpha opsys=osf1
 159   ;;
 160
 161   ## Altos 3068
 162   m68*-altos-sysv* )
 163     machine=altos opsys=usg5-2
 164   ;;
 165
 166   ## Amdahl UTS
 167   580-amdahl-sysv* )
 168     machine=amdahl opsys=usg5-2-2
 169   ;;
 170
 171   ## Appallings - I mean, Apollos - running Domain
 172   m68*-apollo* )
 173     machine=apollo opsys=bsd4-2
 174   ;;
 175
 176   ## AT&T 3b2, 3b5, 3b15, 3b20
 177   we32k-att-sysv* )
 178     machine=att3b opsys=usg5-2-2
 179   ;;
 180
 181   ## AT&T 3b1 - The Mighty Unix PC!
 182   m68*-att-sysv* )
 183     machine=7300 opsys=usg5-2-2
 184   ;;
 185
 186   ## Bull dpx20
 187   rs6000-bull-bosx* )
 188     machine=ibmrs6000 opsys=aix3-2
 189   ;;
 190
 191   ## Bull dpx2
 192   m68*-bull-sysv3* )
 193     machine=dpx2 opsys=usg5-3
 194   ;;
 195
 196   ## Bull sps7
 197   m68*-bull-sysv2* )
 198     machine=sps7 opsys=usg5-2
 199   ;;
 200
 201   ## CCI 5/32, 6/32 -- see "Tahoe".
 202
 203   ## Celerity
 204   ## I don't know what configuration name to use for this; config.sub
 205   ## doesn't seem to know anything about it.  Hey, Celerity users, get
 206   ## in touch with us!
 207   celerity-celerity-bsd* )
 208     machine=celerity opsys=bsd4-2
 209   ;;
 210
 211   ## Clipper
 212   ## What operating systems does this chip run that Emacs has been
 213   ## tested on?
 214   clipper-* )
 215     machine=clipper
 216     ## We'll use the catch-all code at the bottom to guess the
 217     ## operating system.
 218   ;;
 219
 220   ## Convex
 221   *-convex-bsd* | *-convex-convexos* )
 222     machine=convex opsys=bsd4-3
 223     ## Prevents suprious white space in makefiles - d.m.cooke@larc.nasa.gov
 224     NON_GNU_CPP="cc -E -P"
 225   ;;
 226
 227   ## Cubix QBx/386
 228   i[345]86-cubix-sysv* )
 229     machine=intel386 opsys=usg5-3
 230   ;;
 231
 232   ## Cydra 5
 233   cydra*-cydrome-sysv* )
 234     machine=cydra5 opsys=usg5-3
 235   ;;
 236
 237   ## Data General AViiON Machines
 238   m88k-dg-dgux5.4R3* | m88k-dg-dgux5.4.3* )
 239     machine=aviion opsys=dgux5-4r3
 240   ;;
 241   m88k-dg-dgux5.4R2* | m88k-dg-dgux5.4.2* )
 242     machine=aviion opsys=dgux5-4r2
 243   ;;
 244   m88k-dg-dgux* )
 245     machine=aviion opsys=dgux
 246   ;;
 247
 248   ## DECstations
 249   mips-dec-ultrix[0-3].* | mips-dec-ultrix4.0* | mips-dec-bsd4.2* )
 250     machine=pmax opsys=bsd4-2
 251   ;;
 252   mips-dec-ultrix* | mips-dec-bsd* )
 253     machine=pmax opsys=bsd4-3
 254   ;;
 255   mips-dec-osf* )
 256     machine=pmax opsys=osf1
 257   ;;
 258
 259   ## Motorola Delta machines
 260   m68k-motorola-sysv* | m68000-motorola-sysv* )
 261     machine=delta opsys=usg5-3
 262     if test -z "`type gnucc | grep 'not found'`"
 263     then CC=gnucc
 264     else
 265       if test -z "`type gcc | grep 'not found'`"
 266       then CC=gcc
 267       else CC=cc
 268       fi
 269     fi
 270   ;;
 271   m88k-motorola-sysv4* )
 272     machine=delta88k opsys=usg5-4
 273   ;;
 274   m88k-motorola-sysv* | m88k-motorola-m88kbcs* )
 275     machine=delta88k opsys=usg5-3
 276   ;;
 277
 278   ## Dual machines
 279   m68*-dual-sysv* )
 280     machine=dual opsys=usg5-2
 281   ;;
 282   m68*-dual-uniplus* )
 283     machine=dual opsys=unipl5-2
 284   ;;
 285
 286   ## Elxsi 6400
 287   elxsi-elxsi-sysv* )
 288     machine=elxsi opsys=usg5-2
 289   ;;
 290
 291   ## Encore machines
 292   ns16k-encore-bsd* )
 293     machine=ns16000 opsys=umax
 294   ;;
 295
 296   ## The GEC 93 - apparently, this port isn't really finished yet.
 297
 298   ## Gould Power Node and NP1
 299   pn-gould-bsd4.2* )
 300     machine=gould opsys=bsd4-2
 301   ;;
 302   pn-gould-bsd4.3* )
 303     machine=gould opsys=bsd4-3
 304   ;;
 305   np1-gould-bsd* )
 306     machine=gould-np1 opsys=bsd4-3
 307   ;;
 308
 309   ## Harris Night Hawk machines running CX/UX (a 5000 looks just like a 4000
 310   ## as far as Emacs is concerned).
 311   m88k-harris-cxux* )
 312     # Build needs to be different on 7.0 and later releases
 313     case "`uname -r`" in
 314        [56].[0-9] ) machine=nh4000 opsys=cxux ;;
 315        [7].[0-9] ) machine=nh4000 opsys=cxux7 ;;
 316     esac
 317   ;;
 318   ## Harris ecx or gcx running CX/UX (Series 1200, Series 3000)
 319   m68k-harris-cxux* )
 320     machine=nh3000 opsys=cxux
 321   ;;
 322
 323   ## Honeywell XPS100
 324   xps*-honeywell-sysv* )
 325     machine=xps100 opsys=usg5-2
 326   ;;
 327
 328   ## HP 9000 series 200 or 300
 329   m68*-hp-bsd* )
 330     machine=hp9000s300 opsys=bsd4-3
 331   ;;
 332   ## HP/UX 7, 8 and 9 are supported on these machines.
 333   m68*-hp-hpux* )
 334     case "`uname -r`" in
 335       ## Someone's system reports A.B8.05 for this.
 336       ## I wonder what other possibilities there are.
 337       *.B8.* ) machine=hp9000s300 opsys=hpux8 ;;
 338       *.08.* ) machine=hp9000s300 opsys=hpux8 ;;
 339       *.09.* ) machine=hp9000s300 opsys=hpux9 ;;
 340       *) machine=hp9000s300 opsys=hpux ;;
 341     esac
 342   ;;
 343
 344   ## HP 9000 series 700 and 800, running HP/UX
 345   hppa*-hp-hpux7* )
 346     machine=hp800 opsys=hpux
 347   ;;
 348   hppa*-hp-hpux8* )
 349     machine=hp800 opsys=hpux8
 350   ;;
 351   hppa*-hp-hpux9shr* )
 352     machine=hp800 opsys=hpux9shr
 353   ;;
 354   hppa*-hp-hpux9* )
 355     machine=hp800 opsys=hpux9
 356   ;;
 357
 358   ## HP 9000 series 700 and 800, running HP/UX
 359   hppa*-hp-hpux* )
 360     ## Cross-compilation?  Nah!
 361     case "`uname -r`" in
 362       ## Someone's system reports A.B8.05 for this.
 363       ## I wonder what other possibilities there are.
 364       *.B8.* ) machine=hp800 opsys=hpux8 ;;
 365       *.08.* ) machine=hp800 opsys=hpux8 ;;
 366       *.09.* ) machine=hp800 opsys=hpux9 ;;
 367       *) machine=hp800 opsys=hpux ;;
 368     esac
 369   ;;
 370
 371   ## Orion machines
 372   orion-orion-bsd* )
 373     machine=orion opsys=bsd4-2
 374   ;;
 375   clipper-orion-bsd* )
 376     machine=orion105 opsys=bsd4-2
 377   ;;
 378
 379   ## IBM machines
 380   i[345]86-ibm-aix1.1* )
 381     machine=ibmps2-aix opsys=usg5-2-2
 382   ;;
 383   i[345]86-ibm-aix1.[23]* | i[345]86-ibm-aix* )
 384     machine=ibmps2-aix opsys=usg5-3
 385   ;;
 386   i370-ibm-aix*)
 387     machine=ibm370aix opsys=usg5-3
 388   ;;
 389   rs6000-ibm-aix3.1* | powerpc-ibm-aix3.1*  )
 390     machine=ibmrs6000 opsys=aix3-1
 391   ;;
 392   rs6000-ibm-aix3.2.5 | powerpc-ibm-aix3.2.5 )
 393     machine=ibmrs6000 opsys=aix3-2-5
 394   ;;
 395   rs6000-ibm-aix* | powerpc-ibm-aix* )
 396     machine=ibmrs6000 opsys=aix3-2
 397   ;;
 398   romp-ibm-bsd4.3* )
 399     machine=ibmrt opsys=bsd4-3
 400   ;;
 401   romp-ibm-bsd4.2* )
 402     machine=ibmrt opsys=bsd4-2
 403   ;;
 404   romp-ibm-aos4.3* )
 405     machine=ibmrt opsys=bsd4-3
 406   ;;
 407   romp-ibm-aos4.2* )
 408     machine=ibmrt opsys=bsd4-2
 409   ;;
 410   romp-ibm-aos* )
 411     machine=ibmrt opsys=bsd4-3
 412   ;;
 413   romp-ibm-bsd* )
 414     machine=ibmrt opsys=bsd4-3
 415   ;;
 416   romp-ibm-aix* )
 417     machine=ibmrt-aix opsys=usg5-2-2
 418   ;;
 419
 420   ## Integrated Solutions `Optimum V'
 421   m68*-isi-bsd4.2* )
 422     machine=isi-ov opsys=bsd4-2
 423   ;;
 424   m68*-isi-bsd4.3* )
 425     machine=isi-ov opsys=bsd4-3
 426   ;;
 427
 428   ## Intel 386 machines where we do care about the manufacturer
 429   i[345]86-intsys-sysv* )
 430     machine=is386 opsys=usg5-2-2
 431   ;;
 432
 433   ## Prime EXL
 434   i[345]86-prime-sysv* )
 435     machine=i386 opsys=usg5-3
 436   ;;
 437
 438   ## Sequent Symmetry running Dynix
 439   i[345]86-sequent-bsd* )
 440     machine=symmetry opsys=bsd4-3
 441   ;;
 442
 443   ## Sequent Symmetry running DYNIX/ptx
 444   ## Use the old cpp rather than the newer ANSI one.
 445   i[345]86-sequent-ptx* )
 446     machine=sequent-ptx opsys=ptx
 447     NON_GNU_CPP="/lib/cpp"
 448   ;;
 449
 450   ## Unspecified sysv on an ncr machine defaults to svr4.2.
 451   ## (Plain usg5-4 doesn't turn on POSIX signals, which we need.)
 452   i[345]86-ncr-sysv* )
 453     machine=intel386 opsys=usg5-4-2
 454   ;;
 455
 456   ## Intel 860
 457   i860-*-sysv4* )
 458     machine=i860 opsys=usg5-4
 459     NON_GNU_CC="/bin/cc" # Ie, not the one in /usr/ucb/cc.
 460     NON_GNU_CPP="/usr/ccs/lib/cpp" # cc -E tokenizes macro expansion.
 461   ;;
 462
 463   ## Masscomp machines
 464   m68*-masscomp-rtu* )
 465     machine=masscomp opsys=rtu
 466   ;;
 467
 468   ## Megatest machines
 469   m68*-megatest-bsd* )
 470     machine=mega68 opsys=bsd4-2
 471   ;;
 472
 473   ## Workstations sold by MIPS
 474   ## This is not necessarily all workstations using the MIPS processor -
 475   ## Irises are produced by SGI, and DECstations by DEC.
 476
 477   ## etc/MACHINES lists mips.h and mips4.h as possible machine files,
 478   ## and usg5-2-2 and bsd4-3 as possible OS files.  The only guidance
 479   ## it gives for choosing between the alternatives seems to be "Use
 480   ## -machine=mips4 for RISCOS version 4; use -opsystem=bsd4-3 with
 481   ## the BSD world."  I'll assume that these are instructions for
 482   ## handling two odd situations, and that every other situation
 483   ## should use mips.h and usg5-2-2, they being listed first.
 484   mips-mips-usg* )
 485     machine=mips4
 486     ## Fall through to the general code at the bottom to decide on the OS.
 487   ;;
 488   mips-mips-riscos4* )
 489     machine=mips4 opsys=bsd4-3
 490     NON_GNU_CC="cc -systype bsd43"
 491     NON_GNU_CPP="cc -systype bsd43 -E"
 492   ;;
 493   mips-mips-bsd* )
 494     machine=mips opsys=bsd4-3
 495   ;;
 496   mips-mips-* )
 497     machine=mips opsys=usg5-2-2
 498   ;;
 499
 500   ## NeXT
 501   m68*-next-* | i[345]86-next-* )
 502     machine=next opsys=mach2
 503   ;;
 504
 505   ## The complete machine from National Semiconductor
 506   ns32k-ns-genix* )
 507     machine=ns32000 opsys=usg5-2
 508   ;;
 509
 510   ## NCR machines
 511   m68*-ncr-sysv2* | m68*-ncr-sysvr2* )
 512     machine=tower32 opsys=usg5-2-2
 513   ;;
 514   m68*-ncr-sysv3* | m68*-ncr-sysvr3* )
 515     machine=tower32v3 opsys=usg5-3
 516   ;;
 517
 518   ## Nixdorf Targon 31
 519   m68*-nixdorf-sysv* )
 520     machine=targon31 opsys=usg5-2-2
 521   ;;
 522
 523   ## Nu (TI or LMI)
 524   m68*-nu-sysv* )
 525     machine=nu opsys=usg5-2
 526   ;;
 527
 528   ## Plexus
 529   m68*-plexus-sysv* )
 530     machine=plexus opsys=usg5-2
 531   ;;
 532
 533   ## Pyramid machines
 534   ## I don't really have any idea what sort of processor the Pyramid has,
 535   ## so I'm assuming it is its own architecture.
 536   pyramid-pyramid-bsd* )
 537     machine=pyramid opsys=bsd4-2
 538   ;;
 539
 540   ## Sequent Balance
 541   ns32k-sequent-bsd4.2* )
 542     machine=sequent opsys=bsd4-2
 543   ;;
 544   ns32k-sequent-bsd4.3* )
 545     machine=sequent opsys=bsd4-3
 546   ;;
 547
 548   ## Siemens Nixdorf
 549   mips-siemens-sysv* )
 550     machine=mips-siemens opsys=usg5-4
 551     NON_GNU_CC=/usr/ccs/bin/cc
 552     NON_GNU_CPP=/usr/ccs/lib/cpp
 553   ;;
 554
 555   ## Silicon Graphics machines
 556   ## Iris 2500 and Iris 2500 Turbo (aka the Iris 3030)
 557   m68*-sgi-iris3.5* )
 558     machine=irist opsys=iris3-5
 559   ;;
 560   m68*-sgi-iris3.6* | m68*-sgi-iris*)
 561     machine=irist opsys=iris3-6
 562   ;;
 563   ## Iris 4D
 564   mips-sgi-irix3* )
 565     machine=iris4d opsys=irix3-3
 566   ;;
 567   mips-sgi-irix5* )
 568     machine=iris4d opsys=irix5-0
 569   ;;
 570   mips-sgi-irix4* | mips-sgi-irix* )
 571     machine=iris4d opsys=irix4-0
 572   ;;
 573
 574   ## SONY machines
 575   m68*-sony-bsd4.2* )
 576     machine=news opsys=bsd4-2
 577   ;;
 578   m68*-sony-bsd4.3* )
 579     machine=news opsys=bsd4-3
 580   ;;
 581   m68*-sony-newsos3*)
 582     machine=news opsys=bsd4-3
 583   ;;
 584   mips-sony-bsd* | mips-sony-newsos4* )
 585     machine=news-risc opsys=bsd4-3
 586   ;;
 587   mips-sony-newsos* )
 588     machine=news-risc opsys=newsos5
 589   ;;
 590
 591   ## Stride
 592   m68*-stride-sysv* )
 593     machine=stride opsys=usg5-2
 594   ;;
 595
 596   ## Suns
 597   *-sun-sunos* | *-sun-bsd* | *-sun-solaris* | i[345]86-*-solaris2* | i[345]86-*-sunos5* )
 598     case "${canonical}" in
 599       m68*-sunos1* )    machine=sun1 ;;
 600       m68*-sunos2* )    machine=sun2 ;;
 601       m68* )            machine=sun3 ;;
 602       i[345]86-sun-sunos[34]* ) machine=sun386 ;;
 603       i[345]86-*-* )     machine=intel386 ;;
 604       sparc* )          machine=sparc ;;
 605       * )               unported=yes ;;
 606     esac
 607     case "${canonical}" in
 608       ## The Sun386 didn't get past 4.0.
 609       i[345]86-*-sunos4   ) opsys=sunos4-0 ;;
 610       *-sunos4.0*         ) opsys=sunos4-0 ;;
 611       *-sunos4.1.3*       ) opsys=sunos4-1-3
 612                 NON_GCC_TEST_OPTIONS=-Bstatic
 613                 GCC_TEST_OPTIONS=-static
 614                 ;;
 615       *-sunos4shr*        ) opsys=sunos4shr ;;
 616       *-sunos4* | *-sunos ) opsys=sunos4-1
 617                 NON_GCC_TEST_OPTIONS=-Bstatic
 618                 GCC_TEST_OPTIONS=-static
 619                 ;;
 620       *-sunos5.3* | *-solaris2.3* )
 621                 opsys=sol2-3
 622                 NON_GNU_CPP=/usr/ccs/lib/cpp
 623                 ;;
 624       *-sunos5.4* | *-solaris2.4* )
 625                 opsys=sol2-4
 626                 NON_GNU_CPP=/usr/ccs/lib/cpp
 627                 ;;
 628       *-sunos5* | *-solaris* )
 629                 opsys=sol2
 630                 NON_GNU_CPP=/usr/ccs/lib/cpp
 631                 ;;
 632       *                   ) opsys=bsd4-2   ;;
 633     esac
 634   ;;
 635
 636   ## Tadpole 68k
 637   m68*-tadpole-sysv* )
 638     machine=tad68k opsys=usg5-3
 639   ;;
 640
 641   ## Tahoe machines
 642   tahoe-tahoe-bsd4.2* )
 643     machine=tahoe opsys=bsd4-2
 644   ;;
 645   tahoe-tahoe-bsd4.3* )
 646     machine=tahoe opsys=bsd4-3
 647   ;;
 648
 649   ## Tandem Integrity S2
 650   mips-tandem-sysv* )
 651     machine=tandem-s2 opsys=usg5-3
 652   ;;
 653
 654   ## Tektronix XD88
 655   m88k-tektronix-sysv3* )
 656   machine=tekxd88 opsys=usg5-3
 657   ;;
 658
 659   ## Tektronix 16000 box (6130?)
 660   ns16k-tektronix-bsd* )
 661     machine=ns16000 opsys=bsd4-2
 662   ;;
 663   ## Tektronix 4300
 664   ## src/m/tek4300.h hints that this is a m68k machine.
 665   m68*-tektronix-bsd* )
 666     machine=tek4300 opsys=bsd4-3
 667   ;;
 668
 669   ## Titan P2 or P3
 670   ## We seem to have lost the machine-description file titan.h!
 671   titan-titan-sysv* )
 672     machine=titan opsys=usg5-3
 673   ;;
 674
 675   ## Ustation E30 (SS5E)
 676   m68*-unisys-uniplus* )
 677     machine=ustation opsystem=unipl5-2
 678   ;;
 679
 680   ## Vaxen.
 681   vax-dec-* )
 682     machine=vax
 683     case "${canonical}" in
 684       *-bsd4.1* )                                       opsys=bsd4-1 ;;
 685       *-bsd4.2* | *-ultrix[0-3].* | *-ultrix4.0* )      opsys=bsd4-2 ;;
 686       *-bsd4.3* | *-ultrix* )                           opsys=bsd4-3 ;;
 687       *-bsd386* | *-bsdi* )                             opsys=bsd386 ;;
 688       *-sysv[01]* | *-sysvr[01]* )                      opsys=usg5-0 ;;
 689       *-sysv2* | *-sysvr2* )                            opsys=usg5-2 ;;
 690       *-vms* )                                          opsys=vms ;;
 691       * )                                               unported=yes
 692     esac
 693   ;;
 694
 695   ## Whitechapel MG1
 696   ns16k-whitechapel-* )
 697     machine=mg1
 698     ## We don't know what sort of OS runs on these; we'll let the
 699     ## operating system guessing code below try.
 700   ;;
 701
 702   ## Wicat
 703   m68*-wicat-sysv* )
 704     machine=wicat opsys=usg5-2
 705   ;;
 706
 707   ## Intel 386 machines where we don't care about the manufacturer
 708   i[345]86-*-* )
 709     machine=intel386
 710     case "${canonical}" in
 711       *-isc1.* | *-isc2.[01]* ) opsys=386-ix ;;
 712       *-isc2.2* )               opsys=isc2-2 ;;
 713       *-isc4.0* )               opsys=isc4-0 ;;
 714       *-isc* )                  opsys=isc3-0 ;;
 715       *-esix5* )                opsys=esix5r4; NON_GNU_CPP=/usr/lib/cpp ;;
 716       *-esix* )                 opsys=esix ;;
 717       *-xenix* )                opsys=xenix ;;
 718       *-linux* )                opsys=linux ;;
 719       *-sco3.2v4* )             opsys=sco4 ; NON_GNU_CPP=/lib/cpp  ;;
 720       *-bsd386* | *-bsdi* )     opsys=bsd386 ;;
 721       *-386bsd* )               opsys=386bsd ;;
 722       *-freebsd* )              opsys=freebsd ;;
 723       *-nextstep* )             opsys=mach2 ;;
 724       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 725     esac
 726   ;;
 727
 728   * )
 729     unported=yes
 730   ;;
 731 esac
 732
 733 ### If the code above didn't choose an operating system, just choose
 734 ### an operating system based on the configuration name.  You really
 735 ### only want to use this when you have no idea what the right
 736 ### operating system is; if you know what operating systems a machine
 737 ### runs, it's cleaner to make it explicit in the case statement
 738 ### above.
 739 if test x"${opsys}" = x; then
 740   case "${canonical}" in
 741     *-gnu* )                            opsys=gnu ;;
 742     *-bsd4.[01] )                       opsys=bsd4-1 ;;
 743     *-bsd4.2 )                          opsys=bsd4-2 ;;
 744     *-bsd4.3 )                          opsys=bsd4-3 ;;
 745     *-sysv0 | *-sysvr0 )                opsys=usg5-0 ;;
 746     *-sysv2 | *-sysvr2 )                opsys=usg5-2 ;;
 747     *-sysv2.2 | *-sysvr2.2 )            opsys=usg5-2-2 ;;
 748     *-sysv3 | *-sysvr3 )                opsys=usg5-3 ;;
 749     *-sysv4 | *-sysvr4 )                opsys=usg5-4 ;;
 750     *-sysv4.1 | *-sysvr4.1 )
 751         NON_GNU_CPP=/usr/lib/cpp
 752         opsys=usg5-4 ;;
 753     *-sysv4.2 | *-sysvr4.2 )            opsys=usg5-4-2 ;;
 754     * )
 755       unported=yes
 756     ;;
 757   esac
 758 fi
 759
 760 changequote([, ])dnl
 761
 762 if test $unported = yes; then
 763   AC_MSG_ERROR([Emacs hasn't been ported to \`${canonical}' systems.
 764 Check \`etc/MACHINES' for recognized configuration names.])
 765 fi
 766
 767 machfile="m/${machine}.h"
 768 opsysfile="s/${opsys}.h"
 769
 770
 771 #### Choose a compiler.
 772 test -n "$CC" && cc_specified=yes
 773
 774 case ${with_gcc} in
 775   "yes" ) CC="gcc" GCC=yes ;;
 776   "no"  ) : ${CC=cc} ;;
 777   * ) AC_PROG_CC
 778 esac
 779
 780 # On Suns, sometimes $CPP names a directory.
 781 if test -n "$CPP" && test -d "$CPP"; then
 782   CPP=
 783 fi
 784
 785 #### Some systems specify a CPP to use unless we are using GCC.
 786 #### Now that we know whether we are using GCC, we can decide whether
 787 #### to use that one.
 788 if test "x$NON_GNU_CPP" != x && test x$GCC != xyes && test "x$CPP" = x
 789 then
 790   CPP="$NON_GNU_CPP"
 791 fi
 792
 793 #### Some systems specify a CC to use unless we are using GCC.
 794 #### Now that we know whether we are using GCC, we can decide whether
 795 #### to use that one.
 796 if test "x$NON_GNU_CC" != x && test x$GCC != xyes &&
 797   test x$cc_specified != xyes
 798 then
 799   CC="$NON_GNU_CC"
 800 fi
 801
 802 if test x$GCC = xyes && test "x$GCC_TEST_OPTIONS" != x
 803 then
 804   CC="$CC $GCC_TEST_OPTIONS"
 805 fi
 806
 807 if test x$GCC = x && test "x$NON_GCC_TEST_OPTIONS" != x
 808 then
 809   CC="$CC $NON_GCC_TEST_OPTIONS"
 810 fi
 811
 812 #### Some other nice autoconf tests.  If you add a test here which
 813 #### should make an entry in src/config.h, don't forget to add an
 814 #### #undef clause to src/config.h.in for autoconf to modify.
 815
 816 dnl checks for programs
 817 AC_PROG_LN_S
 818 AC_PROG_CPP
 819 AC_PROG_INSTALL
 820 AC_PROG_YACC
 821
 822 dnl checks for Unix variants
 823 AC_AIX
 824
 825 dnl checks for header files
 826 AC_CHECK_HEADERS(sys/timeb.h sys/time.h unistd.h utime.h)
 827 AC_HEADER_STDC
 828 AC_HEADER_TIME
 829 AC_DECL_SYS_SIGLIST
 830
 831 dnl Some systems have utime.h but don't declare the struct anyplace.
 832 AC_MSG_CHECKING(for struct utimbuf)
 833 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 834 #include <sys/time.h>
 835 #include <time.h>
 836 #else
 837 #ifdef HAVE_SYS_TIME_H
 838 #include <sys/time.h>
 839 #else
 840 #include <time.h>
 841 #endif
 842 #endif
 843 #ifdef HAVE_UTIME_H
 844 #include <utime.h>
 845 #endif], [static struct utimbuf x; x.actime = x.modtime;],
 846   [AC_MSG_RESULT(yes)
 847    AC_DEFINE(HAVE_STRUCT_UTIMBUF)],
 848   AC_MSG_RESULT(no))
 849
 850 dnl checks for typedefs
 851 AC_TYPE_SIGNAL
 852
 853 AC_MSG_CHECKING(for struct timeval)
 854 AC_TRY_COMPILE([#ifdef TIME_WITH_SYS_TIME
 855 #include <sys/time.h>
 856 #include <time.h>
 857 #else
 858 #ifdef HAVE_SYS_TIME_H
 859 #include <sys/time.h>
 860 #else
 861 #include <time.h>
 862 #endif
 863 #endif], [static struct timeval x; x.tv_sec = x.tv_usec;],
 864   [AC_MSG_RESULT(yes)
 865    AC_DEFINE(HAVE_TIMEVAL)],
 866   AC_MSG_RESULT(no))
 867
 868 dnl checks for structure members
 869 AC_STRUCT_TM
 870 AC_STRUCT_TIMEZONE
 871
 872 dnl checks for compiler characteristics
 873 AC_C_CONST
 874
 875 dnl check for Make feature
 876 AC_PROG_MAKE_SET
 877
 878 dnl checks for operating system services
 879 AC_SYS_LONG_FILE_NAMES
 880
 881 #### Choose a window system.
 882
 883 AC_PATH_X
 884 if test "$no_x" = yes; then
 885   window_system=none
 886 else
 887   window_system=x11
 888 fi
 889
 890 test "${x_libraries}" != NONE && LD_SWITCH_X_SITE="-L${x_libraries}"
 891 test "${x_libraries}" != NONE && LD_SWITCH_X_SITE_AUX="-R${x_libraries}"
 892 test "${x_includes}" != NONE && C_SWITCH_X_SITE="-I${x_includes}"
 893
 894 if test x"${x_includes}" = x; then
 895   bitmapdir=/usr/include/X11/bitmaps
 896 else
 897   bitmapdir="${x_includes}/bitmaps"
 898 fi
 899
 900 case "${window_system}" in
 901   x11 )
 902     HAVE_X_WINDOWS=yes
 903     HAVE_X11=yes
 904     case "${with_x_toolkit}" in
 905       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
 906       motif ) USE_X_TOOLKIT=MOTIF ;;
 907 dnl      open-look ) USE_X_TOOLKIT=OPEN_LOOK ;;
 908       * ) USE_X_TOOLKIT=none ;;
 909     esac
 910   ;;
 911   none )
 912     HAVE_X_WINDOWS=no
 913     HAVE_X11=no
 914     USE_X_TOOLKIT=none
 915   ;;
 916 esac
 917 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
 918
 919 ### If we're using X11, we should use the X menu package.
 920 HAVE_X_MENU=no
 921 case ${HAVE_X11} in
 922   yes ) HAVE_X_MENU=yes ;;
 923 esac
 924
 925 #### Extract some information from the operating system and machine files.
 926
 927 AC_CHECKING([the machine- and system-dependent files to find out
 928  - which libraries the lib-src programs will want, and
 929  - whether the GNU malloc routines are usable])
 930
 931 ### First figure out CFLAGS (which we use for running the compiler here)
 932 ### and REAL_CFLAGS (which we use for real compilation).
 933 ### The two are the same except on a few systems, where they are made
 934 ### different to work around various lossages.  For example,
 935 ### GCC 2.5 on Linux needs them to be different because it treats -g
 936 ### as implying static linking.
 937
 938 ### If the CFLAGS env var is specified, we use that value
 939 ### instead of the default.
 940
 941 ### It's not important that this name contain the PID; you can't run
 942 ### two configures in the same directory and have anything work
 943 ### anyway.
 944 tempcname="conftest.c"
 945
 946 echo '
 947 #include "'${srcdir}'/src/'${opsysfile}'"
 948 #include "'${srcdir}'/src/'${machfile}'"
 949 #ifndef LIBS_MACHINE
 950 #define LIBS_MACHINE
 951 #endif
 952 #ifndef LIBS_SYSTEM
 953 #define LIBS_SYSTEM
 954 #endif
 955 #ifndef C_SWITCH_SYSTEM
 956 #define C_SWITCH_SYSTEM
 957 #endif
 958 #ifndef C_SWITCH_MACHINE
 959 #define C_SWITCH_MACHINE
 960 #endif
 961 configure___ libsrc_libs=LIBS_MACHINE LIBS_SYSTEM
 962 configure___ c_switch_system=C_SWITCH_SYSTEM
 963 configure___ c_switch_machine=C_SWITCH_MACHINE
 964
 965 #ifndef LIB_X11_LIB
 966 #define LIB_X11_LIB -lX11
 967 #endif
 968
 969 #ifndef LIBX11_MACHINE
 970 #define LIBX11_MACHINE
 971 #endif
 972
 973 #ifndef LIBX11_SYSTEM
 974 #define LIBX11_SYSTEM
 975 #endif
 976 configure___ LIBX=LIB_X11_LIB LIBX11_MACHINE LIBX11_SYSTEM
 977
 978 #ifdef UNEXEC
 979 configure___ unexec=UNEXEC
 980 #else
 981 configure___ unexec=unexec.o
 982 #endif
 983
 984 #ifdef SYSTEM_MALLOC
 985 configure___ system_malloc=yes
 986 #else
 987 configure___ system_malloc=no
 988 #endif
 989
 990 #ifndef C_DEBUG_SWITCH
 991 #define C_DEBUG_SWITCH -g
 992 #endif
 993
 994 #ifndef C_OPTIMIZE_SWITCH
 995 #define C_OPTIMIZE_SWITCH -O
 996 #endif
 997
 998 #ifdef THIS_IS_CONFIGURE
 999
1000 /* Get the CFLAGS for tests in configure.  */
1001 #ifdef __GNUC__
1002 configure___ CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${CFLAGS}'
1003 #else
1004 configure___ CFLAGS=C_DEBUG_SWITCH '${CFLAGS}'
1005 #endif
1006
1007 #else /* not THIS_IS_CONFIGURE */
1008
1009 /* Get the CFLAGS for real compilation.  */
1010 #ifdef __GNUC__
1011 configure___ REAL_CFLAGS=C_DEBUG_SWITCH C_OPTIMIZE_SWITCH '${CFLAGS}'
1012 #else
1013 configure___ REAL_CFLAGS=C_DEBUG_SWITCH '${CFLAGS}'
1014 #endif
1015
1016 #endif /* not THIS_IS_CONFIGURE */
1017 ' > ${tempcname}
1018
1019 # The value of CPP is a quoted variable reference, so we need to do this
1020 # to get its actual value...
1021 CPP=`eval "echo $CPP"`
1022 changequote(, )dnl
1023 eval `${CPP} -Isrc ${tempcname} \
1024        | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1025 if test "x$CFLAGS" = x; then
1026   eval `${CPP} -Isrc -DTHIS_IS_CONFIGURE ${tempcname} \
1027          | sed -n -e 's/^configure___ \([^=]*=\)\(.*\)$/\1"\2"/p'`
1028 else
1029   REAL_CFLAGS="$CFLAGS"
1030 fi
1031 changequote([, ])dnl
1032 rm ${tempcname}
1033
1034 ### Compute the unexec source name from the object name.
1035 UNEXEC_SRC="`echo ${unexec} | sed 's/\.o/.c/'`"
1036
1037 # Do the opsystem or machine files prohibit the use of the GNU malloc?
1038 # Assume not, until told otherwise.
1039 GNU_MALLOC=yes
1040 if test "${system_malloc}" = "yes"; then
1041   GNU_MALLOC=no
1042   GNU_MALLOC_reason="
1043   (The GNU allocators don't work with this system configuration.)"
1044 fi
1045
1046 if test x"${REL_ALLOC}" = x; then
1047   REL_ALLOC=${GNU_MALLOC}
1048 fi
1049
1050 LISP_FLOAT_TYPE=yes
1051
1052
1053 #### Add the libraries to LIBS and check for some functions.
1054
1055 CPPFLAGS="$c_switch_system $c_switch_machine $CPPFLAGS"
1056 LIBS="$libsrc_libs"
1057
1058 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1059 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1060 AC_CHECK_LIB(dnet, dnet_ntoa)
1061 dnl This causes -lresolv to get used in subsequent tests,
1062 dnl which causes failures on some systems such as HPUX 9.
1063 dnl AC_CHECK_LIB(resolv, gethostbyname)
1064
1065 dnl FIXME replace main with a function we actually want from this library.
1066 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1067
1068 AC_MSG_CHECKING(for XFree86)
1069 if test -d /usr/X386/include; then
1070   HAVE_XFREE386=yes
1071   : ${C_SWITCH_X_SITE="-I/usr/X386/include"}
1072 else
1073   HAVE_XFREE386=no
1074 fi
1075 AC_MSG_RESULT($HAVE_XFREE386)
1076
1077 # We change CFLAGS temporarily so that C_SWITCH_X_SITE gets used
1078 # for the tests that follow.
1079
1080 if test "${HAVE_X11}" = "yes"; then
1081   DEFS="$C_SWITCH_X_SITE $DEFS"
1082   LIBS="$LD_SWITCH_X_SITE $LIBX $LIBS"
1083   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1084   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1085 XScreenNumberOfScreen XSetWMProtocols)
1086 fi
1087
1088 if test "${USE_X_TOOLKIT}" != "none"; then
1089   AC_MSG_CHECKING(X11 toolkit version)
1090   AC_TRY_LINK([#include <X11/Intrinsic.h>],
1091 [#if XtSpecificationRelease < 6
1092 fail;
1093 #endif
1094 ], [AC_MSG_RESULT(6)
1095     AC_DEFINE(HAVE_X11XTR6)],
1096    [AC_MSG_RESULT(not 6)])
1097 fi
1098
1099 # If netdb.h doesn't declare h_errno, we must declare it by hand.
1100 AC_MSG_CHECKING(whether netdb declarares h_errno)
1101 AC_TRY_LINK([#include <netdb.h>],
1102 [int
1103 foo ()
1104 {
1105   return h_errno;
1106 }
1107 ], [AC_MSG_RESULT(yes)
1108     AC_DEFINE(HAVE_H_ERRNO)],
1109    [AC_MSG_RESULT(no)])
1110
1111 AC_FUNC_ALLOCA
1112
1113 # logb and frexp are found in -lm on most systems.
1114 AC_CHECK_LIB(m, logb)
1115 AC_CHECK_FUNCS(gettimeofday gethostname dup2 rename closedir mkdir rmdir \
1116 random lrand48 bcopy bcmp logb frexp fmod drem ftime res_init setsid \
1117 strerror fpathconf select mktime eaccess getpagesize)
1118
1119 ok_so_far=yes
1120 AC_CHECK_FUNC(socket, , ok_so_far=no)
1121 if test $ok_so_far = yes; then
1122   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
1123 fi
1124 if test $ok_so_far = yes; then
1125   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
1126 fi
1127 if test $ok_so_far = yes; then
1128   AC_DEFINE(HAVE_INET_SOCKETS)
1129 fi
1130
1131 if test -f /usr/lpp/X11/bin/smt.exp; then
1132   AC_DEFINE(HAVE_AIX_SMT_EXP)
1133 fi
1134
1135 # Set up the CFLAGS for real compilation, so we can substitute it.
1136 CFLAGS="$REAL_CFLAGS"
1137
1138 changequote(, )dnl
1139 #### Find out which version of Emacs this is.
1140 version=`grep 'defconst[         ]*emacs-version' ${srcdir}/lisp/version.el \
1141          | sed -e 's/^[^"]*"\([^"]*\)".*$/\1/'`
1142 changequote([, ])dnl
1143 if test x"${version}" = x; then
1144   AC_MSG_ERROR(can't find current emacs version in \`${srcdir}/lisp/version.el'.)
1145 fi
1146
1147 ### Specify what sort of things we'll be editing into Makefile and config.h.
1148 ### Use configuration here uncanonicalized to avoid exceeding size limits.
1149 AC_SUBST(version)
1150 AC_SUBST(configuration)
1151 AC_SUBST(canonical)
1152 AC_SUBST(srcdir)
1153 AC_SUBST(prefix)
1154 AC_SUBST(exec_prefix)
1155 AC_SUBST(bindir)
1156 AC_SUBST(datadir)
1157 AC_SUBST(sharedstatedir)
1158 AC_SUBST(libexecdir)
1159 AC_SUBST(mandir)
1160 AC_SUBST(infodir)
1161 AC_SUBST(lispdir)
1162 AC_SUBST(locallisppath)
1163 AC_SUBST(lisppath)
1164 AC_SUBST(etcdir)
1165 AC_SUBST(lockdir)
1166 AC_SUBST(archlibdir)
1167 AC_SUBST(docdir)
1168 AC_SUBST(bitmapdir)
1169 AC_SUBST(c_switch_system)
1170 AC_SUBST(c_switch_machine)
1171 AC_SUBST(LD_SWITCH_X_SITE)
1172 AC_SUBST(LD_SWITCH_X_SITE_AUX)
1173 AC_SUBST(C_SWITCH_X_SITE)
1174 AC_SUBST(CFLAGS)
1175 AC_SUBST(X_TOOLKIT_TYPE)
1176 AC_SUBST(machfile)
1177 AC_SUBST(opsysfile)
1178
1179 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}")
1180 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${config_options}")
1181 AC_DEFINE_UNQUOTED(config_machfile,  "${machfile}")
1182 AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}")
1183 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE, ${LD_SWITCH_X_SITE})
1184 AC_DEFINE_UNQUOTED(LD_SWITCH_X_SITE_AUX, ${LD_SWITCH_X_SITE_AUX})
1185 AC_DEFINE_UNQUOTED(C_SWITCH_X_SITE,  ${C_SWITCH_X_SITE})
1186 AC_DEFINE_UNQUOTED(UNEXEC_SRC,       ${UNEXEC_SRC})
1187
1188 if test "${HAVE_X_WINDOWS}" = "yes" ; then
1189   AC_DEFINE(HAVE_X_WINDOWS)
1190 fi
1191 if test "${USE_X_TOOLKIT}" != "none" ; then
1192   AC_DEFINE(USE_X_TOOLKIT)
1193 fi
1194 if test "${HAVE_X11}" = "yes" ; then
1195   AC_DEFINE(HAVE_X11)
1196 fi
1197 if test "${HAVE_XFREE386}" = "yes" ; then
1198   AC_DEFINE(HAVE_XFREE386)
1199 fi
1200 if test "${HAVE_X_MENU}" = "yes" ; then
1201   AC_DEFINE(HAVE_X_MENU)
1202 fi
1203 if test "${GNU_MALLOC}" = "yes" ; then
1204   AC_DEFINE(GNU_MALLOC)
1205 fi
1206 if test "${REL_ALLOC}" = "yes" ; then
1207   AC_DEFINE(REL_ALLOC)
1208 fi
1209 if test "${LISP_FLOAT_TYPE}" = "yes" ; then
1210   AC_DEFINE(LISP_FLOAT_TYPE)
1211 fi
1212
1213 #### Report on what we decided to do.
1214 echo "
1215
1216 Configured for \`${canonical}'.
1217
1218   Where should the build process find the source code?    ${srcdir}
1219   What operating system and machine description files should Emacs use?
1220         \`${opsysfile}' and \`${machfile}'
1221   What compiler should emacs be built with?               ${CC} ${CFLAGS}
1222   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
1223   Should Emacs use the relocating allocator for buffers?  ${REL_ALLOC}
1224   What window system should Emacs use?                    ${window_system}
1225   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}${x_includes+
1226   Where do we find X Windows header files?                }${x_includes}${x_libraries+
1227   Where do we find X Windows libraries?                   }${x_libraries}
1228
1229 "
1230
1231 # Remove any trailing slashes in these variables.
1232 changequote(, )dnl
1233 test "${prefix}" != NONE &&
1234   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
1235 test "${exec_prefix}" != NONE &&
1236   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`
1237 changequote([, ])dnl
1238
1239 AC_OUTPUT(Makefile lib-src/Makefile.in oldXMenu/Makefile \
1240         lwlib/Makefile src/Makefile.in, [
1241
1242 ### Make the necessary directories, if they don't exist.
1243 for dir in ./src ./lib-src ./cpp ./oldXMenu ./lwlib ./etc ; do
1244   if test ! -d ${dir}; then
1245     mkdir ${dir}
1246   fi
1247 done
1248
1249 # Build src/Makefile from ${srcdir}/src/Makefile.in.  This must be done
1250 # after src/config.h is built, since we rely on that file.
1251
1252 changequote(,)dnl The horror, the horror.
1253 # Now get this: Some word that is part of the ${srcdir} directory name
1254 # or the ${configuration} value might, just might, happen to be an
1255 # identifier like `sun4' or `i386' or something, and be predefined by
1256 # the C preprocessor to some helpful value like 1, or maybe the empty
1257 # string.  Needless to say consequent macro substitutions are less
1258 # than conducive to the makefile finding the correct directory.
1259 undefs="`echo $top_srcdir $configuration $canonical |
1260 sed -e 's/[^a-zA-Z0-9_]/ /g' -e 's/^/ /' -e 's/  *$//' \
1261     -e 's/  */ -U/g' -e 's/-U[0-9][^ ]*//g' \
1262 `"
1263 changequote([,])dnl
1264
1265 echo creating lib-src/Makefile
1266 ( cd lib-src
1267   rm -f junk.c junk1.c junk2.c
1268   sed -e '/start of cpp stuff/q' \
1269       < Makefile.in > junk1.c
1270   sed -e '1,/start of cpp stuff/d'\
1271       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1272       < Makefile.in > junk.c
1273   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1274       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1275   cat junk1.c junk2.c > Makefile.new
1276   rm -f junk.c junk1.c junk2.c
1277   chmod 444 Makefile.new
1278   mv -f Makefile.new Makefile
1279 )
1280
1281 echo creating src/Makefile
1282 ( cd src
1283   rm -f junk.c junk1.c junk2.c
1284   sed -e '/start of cpp stuff/q' \
1285       < Makefile.in > junk1.c
1286   sed -e '1,/start of cpp stuff/d'\
1287       -e 's@/\*\*/#\(.*\)$@/* \1 */@' \
1288       < Makefile.in > junk.c
1289   $CPP $undefs -I. -I$top_srcdir/src $CPPFLAGS junk.c | \
1290       sed -e 's/^ /     /' -e '/^#/d' -e '/^[   \f]*$/d' > junk2.c
1291   cat junk1.c junk2.c > Makefile.new
1292   rm -f junk.c junk1.c junk2.c
1293   chmod 444 Makefile.new
1294   mv -f Makefile.new Makefile
1295 )
1296 ], [CPP="$CPP" CPPFLAGS="$CPPFLAGS"])