]> code.delx.au - gnu-emacs/blob - lisp/tar-mode.el
Minor error in previous change.
[gnu-emacs] / lisp / tar-mode.el
1 ;;; tar-mode.el --- simple editing of tar files from GNU emacs
2
3 ;;; Copyright (C) 1990, 1991 Free Software Foundation, Inc.
4
5 ;; Author: Jamie Zawinski <jwz@lucid.com>
6 ;; Created: 04 Apr 1990
7 ;; Version: 1.21bis (some cleanup by ESR)
8 ;; Keywords: unix
9
10 ;;; This file is part of GNU Emacs.
11 ;;;
12 ;;; GNU Emacs is free software; you can redistribute it and/or modify
13 ;;; it under the terms of the GNU General Public License as published by
14 ;;; the Free Software Foundation; either version 2, or (at your option)
15 ;;; any later version.
16 ;;;
17 ;;; GNU Emacs is distributed in the hope that it will be useful,
18 ;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
19 ;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
20 ;;; GNU General Public License for more details.
21 ;;;
22 ;;; You should have received a copy of the GNU General Public License
23 ;;; along with GNU Emacs; see the file COPYING. If not, write to
24 ;;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
25
26 ;;; Commentary:
27
28 ;;; This package attempts to make dealing with Unix 'tar' archives easier.
29 ;;; When this code is loaded, visiting a file whose name ends in '.tar' will
30 ;;; cause the contents of that archive file to be displayed in a Dired-like
31 ;;; listing. It is then possible to use the customary Dired keybindings to
32 ;;; extract sub-files from that archive, either by reading them into their own
33 ;;; editor buffers, or by copying them directly to arbitrary files on disk.
34 ;;; It is also possible to delete sub-files from within the tar file and write
35 ;;; the modified archive back to disk, or to edit sub-files within the archive
36 ;;; and re-insert the modified files into the archive. See the documentation
37 ;;; string of tar-mode for more info.
38
39 ;;; To autoload, add this to your .emacs file:
40 ;;;
41 ;;; (setq auto-mode-alist (cons '("\\.tar$" . tar-mode) auto-mode-alist))
42 ;;; (autoload 'tar-mode "tar-mode")
43 ;;;
44 ;;; But beware: for certain tar files - those whose very first file has
45 ;;; a -*- property line - autoloading won't work. See the function
46 ;;; "tar-normal-mode" to understand why.
47
48 ;;; This code now understands the extra fields that GNU tar adds to tar files.
49
50 ;;; This interacts correctly with "uncompress.el" in the Emacs library,
51 ;;; which you get with
52 ;;;
53 ;;; (autoload 'uncompress-while-visiting "uncompress")
54 ;;; (setq auto-mode-alist (cons '("\\.Z$" . uncompress-while-visiting)
55 ;;; auto-mode-alist))
56 ;;;
57 ;;; Do not attempt to use tar-mode.el with crypt.el, you will lose.
58
59 ;;; *************** TO DO ***************
60 ;;;
61 ;;; o chmod should understand "a+x,og-w".
62 ;;;
63 ;;; o It's not possible to add a NEW file to a tar archive; not that
64 ;;; important, but still...
65 ;;;
66 ;;; o In the directory listing, we don't show creation times because I don't
67 ;;; know how to print an arbitrary date, and I don't really want to have to
68 ;;; implement decode-universal-time.
69 ;;;
70 ;;; o The code is less efficient that it could be - in a lot of places, I
71 ;;; pull a 512-character string out of the buffer and parse it, when I could
72 ;;; be parsing it in place, not garbaging a string. Should redo that.
73 ;;;
74 ;;; o I'd like a command that searches for a string/regexp in every subfile
75 ;;; of an archive, where <esc> would leave you in a subfile-edit buffer.
76 ;;; (Like the Meta-R command of the Zmacs mail reader.)
77 ;;;
78 ;;; o Sometimes (but not always) reverting the tar-file buffer does not
79 ;;; re-grind the listing, and you are staring at the binary tar data.
80 ;;; Typing 'g' again immediately after that will always revert and re-grind
81 ;;; it, though. I have no idea why this happens.
82 ;;;
83 ;;; o Tar-mode interacts poorly with crypt.el and zcat.el because the tar
84 ;;; write-file-hook actually writes the file. Instead it should remove the
85 ;;; header (and conspire to put it back afterwards) so that other write-file
86 ;;; hooks which frob the buffer have a chance to do their dirty work. There
87 ;;; might be a problem if the tar write-file-hook does not come *first* on
88 ;;; the list.
89 ;;;
90 ;;; o Block files, sparse files, continuation files, and the various header
91 ;;; types aren't editable. Actually I don't know that they work at all.
92
93 ;;; Code:
94
95 (defvar tar-anal-blocksize 20
96 "*The blocksize of tar files written by Emacs, or nil, meaning don't care.
97 The blocksize of a tar file is not really the size of the blocks; rather, it is
98 the number of blocks written with one system call. When tarring to a tape,
99 this is the size of the *tape* blocks, but when writing to a file, it doesn't
100 matter much. The only noticeable difference is that if a tar file does not
101 have a blocksize of 20, tar will tell you that; all this really controls is
102 how many null padding bytes go on the end of the tar file.")
103
104 (defvar tar-update-datestamp nil
105 "*Whether tar-mode should play fast and loose with sub-file datestamps;
106 if this is true, then editing and saving a tar file entry back into its
107 tar file will update its datestamp. If false, the datestamp is unchanged.
108 You may or may not want this - it is good in that you can tell when a file
109 in a tar archive has been changed, but it is bad for the same reason that
110 editing a file in the tar archive at all is bad - the changed version of
111 the file never exists on disk.")
112
113 (defvar tar-parse-info nil)
114 (defvar tar-header-offset nil)
115 (defvar tar-superior-buffer nil)
116 (defvar tar-superior-descriptor nil)
117 (defvar tar-subfile-mode nil)
118 \f
119 ;;; First, duplicate some Common Lisp functions; I used to just (require 'cl)
120 ;;; but "cl.el" was messing some people up (also it's really big).
121
122 (defmacro tar-setf (form val)
123 "A mind-numbingly simple implementation of setf."
124 (let ((mform (macroexpand form (and (boundp 'byte-compile-macro-environment)
125 byte-compile-macro-environment))))
126 (cond ((symbolp mform) (list 'setq mform val))
127 ((not (consp mform)) (error "can't setf %s" form))
128 ((eq (car mform) 'aref)
129 (list 'aset (nth 1 mform) (nth 2 mform) val))
130 ((eq (car mform) 'car)
131 (list 'setcar (nth 1 mform) val))
132 ((eq (car mform) 'cdr)
133 (list 'setcdr (nth 1 mform) val))
134 (t (error "don't know how to setf %s" form)))))
135
136 (defmacro tar-dolist (control &rest body)
137 "syntax: (dolist (var-name list-expr &optional return-value) &body body)"
138 (let ((var (car control))
139 (init (car (cdr control)))
140 (val (car (cdr (cdr control)))))
141 (list 'let (list (list '_dolist_iterator_ init))
142 (list 'while '_dolist_iterator_
143 (cons 'let
144 (cons (list (list var '(car _dolist_iterator_)))
145 (append body
146 (list (list 'setq '_dolist_iterator_
147 (list 'cdr '_dolist_iterator_)))))))
148 val)))
149
150 (defmacro tar-dotimes (control &rest body)
151 "syntax: (dolist (var-name count-expr &optional return-value) &body body)"
152 (let ((var (car control))
153 (n (car (cdr control)))
154 (val (car (cdr (cdr control)))))
155 (list 'let (list (list '_dotimes_end_ n)
156 (list var 0))
157 (cons 'while
158 (cons (list '< var '_dotimes_end_)
159 (append body
160 (list (list 'setq var (list '1+ var))))))
161 val)))
162
163 \f
164 ;;; down to business.
165
166 (defmacro make-tar-header (name mode uid git size date ck lt ln
167 magic uname gname devmaj devmin)
168 (list 'vector name mode uid git size date ck lt ln
169 magic uname gname devmaj devmin))
170
171 (defmacro tar-header-name (x) (list 'aref x 0))
172 (defmacro tar-header-mode (x) (list 'aref x 1))
173 (defmacro tar-header-uid (x) (list 'aref x 2))
174 (defmacro tar-header-gid (x) (list 'aref x 3))
175 (defmacro tar-header-size (x) (list 'aref x 4))
176 (defmacro tar-header-date (x) (list 'aref x 5))
177 (defmacro tar-header-checksum (x) (list 'aref x 6))
178 (defmacro tar-header-link-type (x) (list 'aref x 7))
179 (defmacro tar-header-link-name (x) (list 'aref x 8))
180 (defmacro tar-header-magic (x) (list 'aref x 9))
181 (defmacro tar-header-uname (x) (list 'aref x 10))
182 (defmacro tar-header-gname (x) (list 'aref x 11))
183 (defmacro tar-header-dmaj (x) (list 'aref x 12))
184 (defmacro tar-header-dmin (x) (list 'aref x 13))
185
186 (defmacro make-tar-desc (data-start tokens)
187 (list 'cons data-start tokens))
188
189 (defmacro tar-desc-data-start (x) (list 'car x))
190 (defmacro tar-desc-tokens (x) (list 'cdr x))
191
192 (defconst tar-name-offset 0)
193 (defconst tar-mode-offset (+ tar-name-offset 100))
194 (defconst tar-uid-offset (+ tar-mode-offset 8))
195 (defconst tar-gid-offset (+ tar-uid-offset 8))
196 (defconst tar-size-offset (+ tar-gid-offset 8))
197 (defconst tar-time-offset (+ tar-size-offset 12))
198 (defconst tar-chk-offset (+ tar-time-offset 12))
199 (defconst tar-linkp-offset (+ tar-chk-offset 8))
200 (defconst tar-link-offset (+ tar-linkp-offset 1))
201 ;;; GNU-tar specific slots.
202 (defconst tar-magic-offset (+ tar-link-offset 100))
203 (defconst tar-uname-offset (+ tar-magic-offset 8))
204 (defconst tar-gname-offset (+ tar-uname-offset 32))
205 (defconst tar-dmaj-offset (+ tar-gname-offset 32))
206 (defconst tar-dmin-offset (+ tar-dmaj-offset 8))
207 (defconst tar-end-offset (+ tar-dmin-offset 8))
208
209 (defun tokenize-tar-header-block (string)
210 "Returns a 'tar-header' structure (a list of name, mode, uid, gid, size,
211 write-date, checksum, link-type, and link-name)."
212 (cond ((< (length string) 512) nil)
213 (;(some 'plusp string) ; <-- oops, massive cycle hog!
214 (or (not (= 0 (aref string 0))) ; This will do.
215 (not (= 0 (aref string 101))))
216 (let* ((name-end (1- tar-mode-offset))
217 (link-end (1- tar-magic-offset))
218 (uname-end (1- tar-gname-offset))
219 (gname-end (1- tar-dmaj-offset))
220 (link-p (aref string tar-linkp-offset))
221 (magic-str (substring string tar-magic-offset (1- tar-uname-offset)))
222 (uname-valid-p (or (string= "ustar " magic-str) (string= "GNUtar " magic-str)))
223 name
224 (nulsexp "[^\000]*\000"))
225 (and (string-match nulsexp string tar-name-offset) (setq name-end (min name-end (1- (match-end 0)))))
226 (and (string-match nulsexp string tar-link-offset) (setq link-end (min link-end (1- (match-end 0)))))
227 (and (string-match nulsexp string tar-uname-offset) (setq uname-end (min uname-end (1- (match-end 0)))))
228 (and (string-match nulsexp string tar-gname-offset) (setq gname-end (min gname-end (1- (match-end 0)))))
229 (setq name (substring string tar-name-offset name-end)
230 link-p (if (or (= link-p 0) (= link-p ?0))
231 nil
232 (- link-p ?0)))
233 (if (and (null link-p) (string-match "/$" name)) (setq link-p 5)) ; directory
234 (make-tar-header
235 name
236 (tar-parse-octal-integer string tar-mode-offset (1- tar-uid-offset))
237 (tar-parse-octal-integer string tar-uid-offset (1- tar-gid-offset))
238 (tar-parse-octal-integer string tar-gid-offset (1- tar-size-offset))
239 (tar-parse-octal-integer string tar-size-offset (1- tar-time-offset))
240 (tar-parse-octal-integer string tar-time-offset (1- tar-chk-offset))
241 (tar-parse-octal-integer string tar-chk-offset (1- tar-linkp-offset))
242 link-p
243 (substring string tar-link-offset link-end)
244 uname-valid-p
245 (and uname-valid-p (substring string tar-uname-offset uname-end))
246 (and uname-valid-p (substring string tar-gname-offset gname-end))
247 (tar-parse-octal-integer string tar-dmaj-offset (1- tar-dmin-offset))
248 (tar-parse-octal-integer string tar-dmin-offset (1- tar-end-offset))
249 )))
250 (t 'empty-tar-block)))
251
252
253 (defun tar-parse-octal-integer (string &optional start end)
254 "deletes all your files, and then reboots."
255 (if (null start) (setq start 0))
256 (if (null end) (setq end (length string)))
257 (if (= (aref string start) 0)
258 0
259 (let ((n 0))
260 (while (< start end)
261 (setq n (if (< (aref string start) ?0) n
262 (+ (* n 8) (- (aref string start) 48)))
263 start (1+ start)))
264 n)))
265
266 (defun tar-parse-octal-integer-safe (string)
267 (let ((L (length string)))
268 (if (= L 0) (error "empty string"))
269 (tar-dotimes (i L)
270 (if (or (< (aref string i) ?0)
271 (> (aref string i) ?7))
272 (error "'%c' is not an octal digit."))))
273 (tar-parse-octal-integer string))
274
275
276 (defun checksum-tar-header-block (string)
277 "Computes and returns a tar-acceptable checksum for this block."
278 (let* ((chk-field-start tar-chk-offset)
279 (chk-field-end (+ chk-field-start 8))
280 (sum 0)
281 (i 0))
282 ;; Add up all of the characters except the ones in the checksum field.
283 ;; Add that field as if it were filled with spaces.
284 (while (< i chk-field-start)
285 (setq sum (+ sum (aref string i))
286 i (1+ i)))
287 (setq i chk-field-end)
288 (while (< i 512)
289 (setq sum (+ sum (aref string i))
290 i (1+ i)))
291 (+ sum (* 32 8))))
292
293 (defun check-tar-header-block-checksum (hblock desired-checksum file-name)
294 "Beep and print a warning if the checksum doesn't match."
295 (if (not (= desired-checksum (checksum-tar-header-block hblock)))
296 (progn (beep) (message "Invalid checksum for file %s!" file-name))))
297
298 (defun recompute-tar-header-block-checksum (hblock)
299 "Modifies the given string to have a valid checksum field."
300 (let* ((chk (checksum-tar-header-block hblock))
301 (chk-string (format "%6o" chk))
302 (l (length chk-string)))
303 (aset hblock 154 0)
304 (aset hblock 155 32)
305 (tar-dotimes (i l) (aset hblock (- 153 i) (aref chk-string (- l i 1)))))
306 hblock)
307
308
309 (defun tar-grind-file-mode (mode string start)
310 "Write a \"-rw--r--r-\" representing MODE into STRING beginning at START."
311 (aset string start (if (zerop (logand 256 mode)) ?- ?r))
312 (aset string (+ start 1) (if (zerop (logand 128 mode)) ?- ?w))
313 (aset string (+ start 2) (if (zerop (logand 64 mode)) ?- ?x))
314 (aset string (+ start 3) (if (zerop (logand 32 mode)) ?- ?r))
315 (aset string (+ start 4) (if (zerop (logand 16 mode)) ?- ?w))
316 (aset string (+ start 5) (if (zerop (logand 8 mode)) ?- ?x))
317 (aset string (+ start 6) (if (zerop (logand 4 mode)) ?- ?r))
318 (aset string (+ start 7) (if (zerop (logand 2 mode)) ?- ?w))
319 (aset string (+ start 8) (if (zerop (logand 1 mode)) ?- ?x))
320 (if (zerop (logand 1024 mode)) nil (aset string (+ start 2) ?s))
321 (if (zerop (logand 2048 mode)) nil (aset string (+ start 5) ?s))
322 string)
323
324 (defun summarize-tar-header-block (tar-hblock &optional mod-p)
325 "Returns a line similar to the output of 'tar -vtf'."
326 (let ((name (tar-header-name tar-hblock))
327 (mode (tar-header-mode tar-hblock))
328 (uid (tar-header-uid tar-hblock))
329 (gid (tar-header-gid tar-hblock))
330 (uname (tar-header-uname tar-hblock))
331 (gname (tar-header-gname tar-hblock))
332 (size (tar-header-size tar-hblock))
333 (time (tar-header-date tar-hblock))
334 (ck (tar-header-checksum tar-hblock))
335 (link-p (tar-header-link-type tar-hblock))
336 (link-name (tar-header-link-name tar-hblock))
337 )
338 (let* ((left 11)
339 (namew 8)
340 (groupw 8)
341 (sizew 8)
342 (datew 2)
343 (slash (1- (+ left namew)))
344 (lastdigit (+ slash groupw sizew))
345 (namestart (+ lastdigit datew))
346 (string (make-string (+ namestart (length name) (if link-p (+ 5 (length link-name)) 0)) 32))
347 (type (tar-header-link-type tar-hblock)))
348 (aset string 0 (if mod-p ?* ? ))
349 (aset string 1
350 (cond ((or (eq type nil) (eq type 0)) ?-)
351 ((eq type 1) ?l) ; link
352 ((eq type 2) ?s) ; symlink
353 ((eq type 3) ?c) ; char special
354 ((eq type 4) ?b) ; block special
355 ((eq type 5) ?d) ; directory
356 ((eq type 6) ?p) ; FIFO/pipe
357 ((eq type 20) ?*) ; directory listing
358 ((eq type 29) ?M) ; multivolume continuation
359 ((eq type 35) ?S) ; sparse
360 ((eq type 38) ?V) ; volume header
361 ))
362 (tar-grind-file-mode mode string 2)
363 (setq uid (if (= 0 (length uname)) (int-to-string uid) uname))
364 (setq gid (if (= 0 (length gname)) (int-to-string gid) gname))
365 (setq size (int-to-string size))
366 (tar-dotimes (i (min (1- namew) (length uid))) (aset string (- slash i) (aref uid (- (length uid) i 1))))
367 (aset string (1+ slash) ?/)
368 (tar-dotimes (i (min (1- groupw) (length gid))) (aset string (+ (+ slash 2) i) (aref gid i)))
369 (tar-dotimes (i (min sizew (length size))) (aset string (- lastdigit i) (aref size (- (length size) i 1))))
370 ;; ## bloody hell, how do I print an arbitrary date??
371 (tar-dotimes (i (length name)) (aset string (+ namestart i) (aref name i)))
372 (if (or (eq link-p 1) (eq link-p 2))
373 (progn
374 (tar-dotimes (i 3) (aset string (+ namestart 1 (length name) i) (aref (if (= link-p 1) "==>" "-->") i)))
375 (tar-dotimes (i (length link-name)) (aset string (+ namestart 5 (length name) i) (aref link-name i)))))
376 string)))
377
378
379 (defun tar-summarize-buffer ()
380 "Parse the contents of the tar file in the current buffer, and place a
381 dired-like listing on the front; then narrow to it, so that only that listing
382 is visible (and the real data of the buffer is hidden)."
383 (message "parsing tar file...")
384 (let* ((result '())
385 (pos 1)
386 (bs (max 1 (- (buffer-size) 1024))) ; always 2+ empty blocks at end.
387 (bs100 (max 1 (/ bs 100)))
388 (tokens nil))
389 (while (not (eq tokens 'empty-tar-block))
390 (let* ((hblock (buffer-substring pos (+ pos 512))))
391 (setq tokens (tokenize-tar-header-block hblock))
392 (setq pos (+ pos 512))
393 (message "parsing tar file...%s%%"
394 ;(/ (* pos 100) bs) ; this gets round-off lossage
395 (/ pos bs100) ; this doesn't
396 )
397 (if (eq tokens 'empty-tar-block)
398 nil
399 (if (null tokens) (error "premature EOF parsing tar file."))
400 (if (eq (tar-header-link-type tokens) 20)
401 ;; Foo. There's an extra empty block after these.
402 (setq pos (+ pos 512)))
403 (let ((size (tar-header-size tokens)))
404 (if (< size 0)
405 (error "%s has size %s - corrupted."
406 (tar-header-name tokens) size))
407 ;
408 ; This is just too slow. Don't really need it anyway....
409 ;(check-tar-header-block-checksum
410 ; hblock (checksum-tar-header-block hblock)
411 ; (tar-header-name tokens))
412
413 (setq result (cons (make-tar-desc pos tokens) result))
414
415 (if (and (null (tar-header-link-type tokens))
416 (> size 0))
417 (setq pos
418 (+ pos 512 (ash (ash (1- size) -9) 9)) ; this works
419 ;(+ pos (+ size (- 512 (rem (1- size) 512)))) ; this doesn't
420 ))
421 ))))
422 (make-local-variable 'tar-parse-info)
423 (setq tar-parse-info (nreverse result)))
424 (save-excursion
425 (goto-char (point-min))
426 (let ((buffer-read-only nil))
427 (tar-dolist (tar-desc tar-parse-info)
428 (insert-string
429 (summarize-tar-header-block (tar-desc-tokens tar-desc)))
430 (insert-string "\n"))
431 (make-local-variable 'tar-header-offset)
432 (setq tar-header-offset (point))
433 (narrow-to-region 1 tar-header-offset)
434 (set-buffer-modified-p nil)))
435 (message "parsing tar file...done."))
436
437
438 (defvar tar-mode-map nil "*Local keymap for tar-mode listings.")
439
440 (if tar-mode-map
441 nil
442 (setq tar-mode-map (make-keymap))
443 (suppress-keymap tar-mode-map)
444 (define-key tar-mode-map " " 'tar-next-line)
445 (define-key tar-mode-map "c" 'tar-copy)
446 (define-key tar-mode-map "d" 'tar-flag-deleted)
447 (define-key tar-mode-map "\^D" 'tar-flag-deleted)
448 (define-key tar-mode-map "e" 'tar-extract)
449 (define-key tar-mode-map "f" 'tar-extract)
450 (define-key tar-mode-map "g" 'revert-buffer)
451 (define-key tar-mode-map "h" 'describe-mode)
452 (define-key tar-mode-map "n" 'tar-next-line)
453 (define-key tar-mode-map "\^N" 'tar-next-line)
454 (define-key tar-mode-map "o" 'tar-extract-other-window)
455 (define-key tar-mode-map "\^C" 'tar-copy)
456 (define-key tar-mode-map "p" 'tar-previous-line)
457 (define-key tar-mode-map "\^P" 'tar-previous-line)
458 (define-key tar-mode-map "r" 'tar-rename-entry)
459 (define-key tar-mode-map "u" 'tar-unflag)
460 (define-key tar-mode-map "v" 'tar-view)
461 (define-key tar-mode-map "x" 'tar-expunge)
462 (define-key tar-mode-map "\177" 'tar-unflag-backwards)
463 (define-key tar-mode-map "E" 'tar-extract-other-window)
464 (define-key tar-mode-map "M" 'tar-chmod-entry)
465 (define-key tar-mode-map "G" 'tar-chgrp-entry)
466 (define-key tar-mode-map "O" 'tar-chown-entry)
467 )
468
469 ;; tar mode is suitable only for specially formatted data.
470 (put 'tar-mode 'mode-class 'special)
471 (put 'tar-subfile-mode 'mode-class 'special)
472
473 ;;;###autoload
474 (defun tar-mode ()
475 "Major mode for viewing a tar file as a dired-like listing of its contents.
476 You can move around using the usual cursor motion commands.
477 Letters no longer insert themselves.
478 Type 'e' to pull a file out of the tar file and into its own buffer.
479 Type 'c' to copy an entry from the tar file into another file on disk.
480
481 If you edit a sub-file of this archive (as with the 'e' command) and
482 save it with Control-X Control-S, the contents of that buffer will be
483 saved back into the tar-file buffer; in this way you can edit a file
484 inside of a tar archive without extracting it and re-archiving it.
485
486 See also: variables tar-update-datestamp and tar-anal-blocksize.
487 \\{tar-mode-map}"
488 ;; this is not interactive because you shouldn't be turning this
489 ;; mode on and off. You can corrupt things that way.
490 (make-local-variable 'tar-header-offset)
491 (make-local-variable 'tar-parse-info)
492 (make-local-variable 'require-final-newline)
493 (setq require-final-newline nil) ; binary data, dude...
494 (make-local-variable 'revert-buffer-function)
495 (setq revert-buffer-function 'tar-mode-revert)
496 (setq major-mode 'tar-mode)
497 (setq mode-name "Tar")
498 (use-local-map tar-mode-map)
499 (auto-save-mode 0)
500 (widen)
501 (if (and (boundp 'tar-header-offset) tar-header-offset)
502 (narrow-to-region 1 tar-header-offset)
503 (tar-summarize-buffer))
504 (run-hooks 'tar-mode-hook)
505 )
506
507
508 (defun tar-subfile-mode (p)
509 "Minor mode for editing an element of a tar-file.
510 This mode redefines ^X^S to save the current buffer back into its
511 associated tar-file buffer. You must save that buffer to actually
512 save your changes to disk."
513 (interactive "P")
514 (or (and (boundp 'tar-superior-buffer) tar-superior-buffer)
515 (error "This buffer is not an element of a tar file."))
516 (or (assq 'tar-subfile-mode minor-mode-alist)
517 (setq minor-mode-alist (append minor-mode-alist
518 (list '(tar-subfile-mode
519 " TarFile")))))
520 (make-local-variable 'tar-subfile-mode)
521 (setq tar-subfile-mode
522 (if (null p)
523 (not tar-subfile-mode)
524 (> (prefix-numeric-value p) 0)))
525 (cond (tar-subfile-mode
526 ;; copy the local keymap so that we don't accidentally
527 ;; alter a keymap like 'lisp-mode-map' which is shared
528 ;; by all buffers in that mode.
529 (let ((m (current-local-map)))
530 (if m (use-local-map (copy-keymap m))))
531 (local-set-key "\^X\^S" 'tar-subfile-save-buffer)
532 ;; turn off auto-save.
533 (auto-save-mode nil)
534 (setq buffer-auto-save-file-name nil)
535 (run-hooks 'tar-subfile-mode-hook))
536 (t (local-set-key "\^X\^S" 'save-buffer)))
537 )
538
539
540 (defun tar-mode-revert (&optional no-autosave no-confirm)
541 "Revert this buffer and turn on tar mode again, to re-compute the
542 directory listing."
543 (setq tar-header-offset nil)
544 (let ((revert-buffer-function nil))
545 (revert-buffer t no-confirm)
546 (widen))
547 (tar-mode))
548
549
550 (defun tar-next-line (p)
551 (interactive "p")
552 (forward-line p)
553 (if (eobp) nil (forward-char 36)))
554
555 (defun tar-previous-line (p)
556 (interactive "p")
557 (tar-next-line (- p)))
558
559 (defun tar-current-descriptor (&optional noerror)
560 "Returns the tar-descriptor of the current line, or signals an error."
561 ;; I wish lines had plists, like in ZMACS...
562 (or (nth (count-lines (point-min)
563 (save-excursion (beginning-of-line) (point)))
564 tar-parse-info)
565 (if noerror
566 nil
567 (error "This line does not describe a tar-file entry."))))
568
569
570 (defun tar-extract (&optional other-window-p)
571 "*In tar-mode, extract this entry of the tar file into its own buffer."
572 (interactive)
573 (let* ((view-p (eq other-window-p 'view))
574 (descriptor (tar-current-descriptor))
575 (tokens (tar-desc-tokens descriptor))
576 (name (tar-header-name tokens))
577 (size (tar-header-size tokens))
578 (link-p (tar-header-link-type tokens))
579 (start (+ (tar-desc-data-start descriptor) tar-header-offset -1))
580 (end (+ start size)))
581 (if link-p
582 (error "This is a %s, not a real file."
583 (cond ((eq link-p 5) "directory")
584 ((eq link-p 20) "tar directory header")
585 ((eq link-p 29) "multivolume-continuation")
586 ((eq link-p 35) "sparse entry")
587 ((eq link-p 38) "volume header")
588 (t "link"))))
589 (if (zerop size) (error "This is a zero-length file."))
590 (let* ((tar-buffer (current-buffer))
591 (bufname (concat (file-name-nondirectory name)
592 " (" name " in "
593 (file-name-nondirectory (buffer-file-name))
594 ")"))
595 (read-only-p (or buffer-read-only view-p))
596 (buffer (get-buffer bufname))
597 (just-created nil))
598 (if buffer
599 nil
600 (setq buffer (get-buffer-create bufname))
601 (setq just-created t)
602 (unwind-protect
603 (progn
604 (widen)
605 (save-excursion
606 (set-buffer buffer)
607 (insert-buffer-substring tar-buffer start end)
608 (goto-char 0)
609 (set-visited-file-name name) ; give it a name to decide mode.
610 (normal-mode) ; pick a mode.
611 (set-visited-file-name nil) ; nuke the name - not meaningful.
612 (rename-buffer bufname)
613
614 (make-local-variable 'tar-superior-buffer)
615 (make-local-variable 'tar-superior-descriptor)
616 (setq tar-superior-buffer tar-buffer)
617 (setq tar-superior-descriptor descriptor)
618 (tar-subfile-mode 1)
619
620 (setq buffer-read-only read-only-p)
621 (set-buffer-modified-p nil))
622 (set-buffer tar-buffer))
623 (narrow-to-region 1 tar-header-offset)))
624 (if view-p
625 (progn
626 (view-buffer buffer)
627 (and just-created
628 (setq view-exit-action 'kill-buffer)))
629 (if other-window-p
630 (switch-to-buffer-other-window buffer)
631 (switch-to-buffer buffer))))))
632
633
634 (defun tar-extract-other-window ()
635 "*In tar-mode, extract this entry of the tar file into its own buffer."
636 (interactive)
637 (tar-extract t))
638
639 (defun tar-view ()
640 "*In tar-mode, view the tar file entry on this line."
641 (interactive)
642 (tar-extract 'view))
643
644
645 (defun tar-read-file-name (&optional prompt)
646 "Calls read-file-name, with the default being the file of the current
647 tar-file descriptor."
648 (or prompt (setq prompt "Copy to: "))
649 (let* ((default-file (expand-file-name
650 (tar-header-name (tar-desc-tokens
651 (tar-current-descriptor)))))
652 (target (expand-file-name
653 (read-file-name prompt
654 (file-name-directory default-file)
655 default-file nil))))
656 (if (or (string= "" (file-name-nondirectory target))
657 (file-directory-p target))
658 (setq target (concat (if (string-match "/$" target)
659 (substring target 0 (1- (match-end 0)))
660 target)
661 "/"
662 (file-name-nondirectory default-file))))
663 target))
664
665
666 (defun tar-copy (&optional to-file)
667 "*In tar-mode, extract this entry of the tar file into a file on disk.
668 If TO-FILE is not supplied, it is prompted for, defaulting to the name of
669 the current tar-entry."
670 (interactive (list (tar-read-file-name)))
671 (let* ((descriptor (tar-current-descriptor))
672 (tokens (tar-desc-tokens descriptor))
673 (name (tar-header-name tokens))
674 (size (tar-header-size tokens))
675 (link-p (tar-header-link-type tokens))
676 (start (+ (tar-desc-data-start descriptor) tar-header-offset -1))
677 (end (+ start size)))
678 (if link-p (error "This is a link, not a real file."))
679 (if (zerop size) (error "This is a zero-length file."))
680 (let* ((tar-buffer (current-buffer))
681 buffer)
682 (unwind-protect
683 (progn
684 (setq buffer (generate-new-buffer "*tar-copy-tmp*"))
685 (widen)
686 (save-excursion
687 (set-buffer buffer)
688 (insert-buffer-substring tar-buffer start end)
689 (set-buffer-modified-p nil) ; in case we abort
690 (write-file to-file)
691 (message "Copied tar entry %s to %s" name to-file)
692 (set-buffer tar-buffer)))
693 (narrow-to-region 1 tar-header-offset)
694 (if buffer (kill-buffer buffer)))
695 )))
696
697
698 (defun tar-flag-deleted (p &optional unflag)
699 "*In tar mode, mark this sub-file to be deleted from the tar file.
700 With a prefix argument, mark that many files."
701 (interactive "p")
702 (beginning-of-line)
703 (tar-dotimes (i (if (< p 0) (- p) p))
704 (if (tar-current-descriptor unflag) ; barf if we're not on an entry-line.
705 (progn
706 (delete-char 1)
707 (insert (if unflag " " "D"))))
708 (forward-line (if (< p 0) -1 1)))
709 (if (eobp) nil (forward-char 36)))
710
711 (defun tar-unflag (p)
712 "*In tar mode, un-mark this sub-file if it is marked to be deleted.
713 With a prefix argument, un-mark that many files forward."
714 (interactive "p")
715 (tar-flag-deleted p t))
716
717 (defun tar-unflag-backwards (p)
718 "*In tar mode, un-mark this sub-file if it is marked to be deleted.
719 With a prefix argument, un-mark that many files backward."
720 (interactive "p")
721 (tar-flag-deleted (- p) t))
722
723
724 (defun tar-expunge-internal ()
725 "Expunge the tar-entry specified by the current line."
726 (let* ((descriptor (tar-current-descriptor))
727 (tokens (tar-desc-tokens descriptor))
728 (line (tar-desc-data-start descriptor))
729 (name (tar-header-name tokens))
730 (size (tar-header-size tokens))
731 (link-p (tar-header-link-type tokens))
732 (start (tar-desc-data-start descriptor))
733 (following-descs (cdr (memq descriptor tar-parse-info))))
734 (if link-p (setq size 0)) ; size lies for hard-links.
735 ;;
736 ;; delete the current line...
737 (beginning-of-line)
738 (let ((line-start (point)))
739 (end-of-line) (forward-char)
740 (let ((line-len (- (point) line-start)))
741 (delete-region line-start (point))
742 ;;
743 ;; decrement the header-pointer to be in synch...
744 (setq tar-header-offset (- tar-header-offset line-len))))
745 ;;
746 ;; delete the data pointer...
747 (setq tar-parse-info (delq descriptor tar-parse-info))
748 ;;
749 ;; delete the data from inside the file...
750 (widen)
751 (let* ((data-start (+ start tar-header-offset -513))
752 (data-end (+ data-start 512 (ash (ash (+ size 511) -9) 9))))
753 (delete-region data-start data-end)
754 ;;
755 ;; and finally, decrement the start-pointers of all following
756 ;; entries in the archive. This is a pig when deleting a bunch
757 ;; of files at once - we could optimize this to only do the
758 ;; iteration over the files that remain, or only iterate up to
759 ;; the next file to be deleted.
760 (let ((data-length (- data-end data-start)))
761 (tar-dolist (desc following-descs)
762 (tar-setf (tar-desc-data-start desc)
763 (- (tar-desc-data-start desc) data-length))))
764 ))
765 (narrow-to-region 1 tar-header-offset))
766
767
768 (defun tar-expunge (&optional noconfirm)
769 "*In tar-mode, delete all the archived files flagged for deletion.
770 This does not modify the disk image; you must save the tar file itself
771 for this to be permanent."
772 (interactive)
773 (if (or noconfirm
774 (y-or-n-p "expunge files marked for deletion? "))
775 (let ((n 0))
776 (save-excursion
777 (goto-char 0)
778 (while (not (eobp))
779 (if (looking-at "D")
780 (progn (tar-expunge-internal)
781 (setq n (1+ n)))
782 (forward-line 1)))
783 ;; after doing the deletions, add any padding that may be necessary.
784 (tar-pad-to-blocksize)
785 (narrow-to-region 1 tar-header-offset)
786 )
787 (if (zerop n)
788 (message "nothing to expunge.")
789 (message "%s expunged. Be sure to save this buffer." n)))))
790
791
792 (defun tar-clear-modification-flags ()
793 "remove the stars at the beginning of each line."
794 (save-excursion
795 (goto-char 0)
796 (while (< (point) tar-header-offset)
797 (if (looking-at "*")
798 (progn (delete-char 1) (insert " ")))
799 (forward-line 1))))
800
801
802 (defun tar-chown-entry (new-uid)
803 "*Change the user-id associated with this entry in the tar file.
804 If this tar file was written by GNU tar, then you will be able to edit
805 the user id as a string; otherwise, you must edit it as a number.
806 You can force editing as a number by calling this with a prefix arg.
807 This does not modify the disk image; you must save the tar file itself
808 for this to be permanent."
809 (interactive (list
810 (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
811 (if (or current-prefix-arg
812 (not (tar-header-magic tokens)))
813 (let (n)
814 (while (not (numberp (setq n (read-minibuffer
815 "New UID number: "
816 (format "%s" (tar-header-uid tokens)))))))
817 n)
818 (read-string "New UID string: " (tar-header-uname tokens))))))
819 (cond ((stringp new-uid)
820 (tar-setf (tar-header-uname (tar-desc-tokens (tar-current-descriptor)))
821 new-uid)
822 (tar-alter-one-field tar-uname-offset (concat new-uid "\000")))
823 (t
824 (tar-setf (tar-header-uid (tar-desc-tokens (tar-current-descriptor)))
825 new-uid)
826 (tar-alter-one-field tar-uid-offset
827 (concat (substring (format "%6o" new-uid) 0 6) "\000 ")))))
828
829
830 (defun tar-chgrp-entry (new-gid)
831 "*Change the group-id associated with this entry in the tar file.
832 If this tar file was written by GNU tar, then you will be able to edit
833 the group id as a string; otherwise, you must edit it as a number.
834 You can force editing as a number by calling this with a prefix arg.
835 This does not modify the disk image; you must save the tar file itself
836 for this to be permanent."
837 (interactive (list
838 (let ((tokens (tar-desc-tokens (tar-current-descriptor))))
839 (if (or current-prefix-arg
840 (not (tar-header-magic tokens)))
841 (let (n)
842 (while (not (numberp (setq n (read-minibuffer
843 "New GID number: "
844 (format "%s" (tar-header-gid tokens)))))))
845 n)
846 (read-string "New GID string: " (tar-header-gname tokens))))))
847 (cond ((stringp new-gid)
848 (tar-setf (tar-header-gname (tar-desc-tokens (tar-current-descriptor)))
849 new-gid)
850 (tar-alter-one-field tar-gname-offset
851 (concat new-gid "\000")))
852 (t
853 (tar-setf (tar-header-gid (tar-desc-tokens (tar-current-descriptor)))
854 new-gid)
855 (tar-alter-one-field tar-gid-offset
856 (concat (substring (format "%6o" new-gid) 0 6) "\000 ")))))
857
858 (defun tar-rename-entry (new-name)
859 "*Change the name associated with this entry in the tar file.
860 This does not modify the disk image; you must save the tar file itself
861 for this to be permanent."
862 (interactive
863 (list (read-string "New name: "
864 (tar-header-name (tar-desc-tokens (tar-current-descriptor))))))
865 (if (string= "" new-name) (error "zero length name."))
866 (if (> (length new-name) 98) (error "name too long."))
867 (tar-setf (tar-header-name (tar-desc-tokens (tar-current-descriptor)))
868 new-name)
869 (tar-alter-one-field 0
870 (substring (concat new-name (make-string 99 0)) 0 99)))
871
872
873 (defun tar-chmod-entry (new-mode)
874 "*Change the protection bits associated with this entry in the tar file.
875 This does not modify the disk image; you must save the tar file itself
876 for this to be permanent."
877 (interactive (list (tar-parse-octal-integer-safe
878 (read-string "New protection (octal): "))))
879 (tar-setf (tar-header-mode (tar-desc-tokens (tar-current-descriptor)))
880 new-mode)
881 (tar-alter-one-field tar-mode-offset
882 (concat (substring (format "%6o" new-mode) 0 6) "\000 ")))
883
884
885 (defun tar-alter-one-field (data-position new-data-string)
886 (let* ((descriptor (tar-current-descriptor))
887 (tokens (tar-desc-tokens descriptor)))
888 (unwind-protect
889 (save-excursion
890 ;;
891 ;; update the header-line.
892 (beginning-of-line)
893 (let ((p (point)))
894 (forward-line 1)
895 (delete-region p (point))
896 (insert (summarize-tar-header-block tokens) "\n")
897 (setq tar-header-offset (point-max)))
898
899 (widen)
900 (let* ((start (+ (tar-desc-data-start descriptor) tar-header-offset -513)))
901 ;;
902 ;; delete the old field and insert a new one.
903 (goto-char (+ start data-position))
904 (delete-region (point) (+ (point) (length new-data-string))) ; <--
905 (insert new-data-string) ; <--
906 ;;
907 ;; compute a new checksum and insert it.
908 (let ((chk (checksum-tar-header-block
909 (buffer-substring start (+ start 512)))))
910 (goto-char (+ start tar-chk-offset))
911 (delete-region (point) (+ (point) 8))
912 (insert (format "%6o" chk))
913 (insert 0)
914 (insert ? )
915 (tar-setf (tar-header-checksum tokens) chk)
916 ;;
917 ;; ok, make sure we didn't botch it.
918 (check-tar-header-block-checksum
919 (buffer-substring start (+ start 512))
920 chk (tar-header-name tokens))
921 )))
922 (narrow-to-region 1 tar-header-offset))))
923
924
925 (defun tar-octal-time (timeval)
926 ;; Format a timestamp as 11 octal digits. Ghod, I hope this works...
927 (let ((hibits (car timeval)) (lobits (car (cdr timeval))))
928 (insert (format "%05o%01o%05o"
929 (lsh hibits -2)
930 (logior (lsh (logand 3 hibits) 1) (> (logand lobits 32768) 0))
931 (logand 32767 lobits)
932 ))))
933
934 (defun tar-subfile-save-buffer ()
935 "In tar subfile mode, write this buffer back into its parent tar-file buffer.
936 This doesn't write anything to disk - you must save the parent tar-file buffer
937 to make your changes permanent."
938 (interactive)
939 (if (not (and (boundp 'tar-superior-buffer) tar-superior-buffer))
940 (error "this buffer has no superior tar file buffer."))
941 (if (not (and (boundp 'tar-superior-descriptor) tar-superior-descriptor))
942 (error "this buffer doesn't have an index into its superior tar file!"))
943 (save-excursion
944 (let ((subfile (current-buffer))
945 (subfile-size (buffer-size))
946 (descriptor tar-superior-descriptor))
947 (set-buffer tar-superior-buffer)
948 (let* ((tokens (tar-desc-tokens descriptor))
949 (start (tar-desc-data-start descriptor))
950 (name (tar-header-name tokens))
951 (size (tar-header-size tokens))
952 (size-pad (ash (ash (+ size 511) -9) 9))
953 (head (memq descriptor tar-parse-info))
954 (following-descs (cdr head)))
955 (if (not head)
956 (error "Can't find this tar file entry in its parent tar file!"))
957 (unwind-protect
958 (save-excursion
959 (widen)
960 ;; delete the old data...
961 (let* ((data-start (+ start tar-header-offset -1))
962 (data-end (+ data-start (ash (ash (+ size 511) -9) 9))))
963 (delete-region data-start data-end)
964 ;; insert the new data...
965 (goto-char data-start)
966 (insert-buffer subfile)
967 ;;
968 ;; pad the new data out to a multiple of 512...
969 (let ((subfile-size-pad (ash (ash (+ subfile-size 511) -9) 9)))
970 (goto-char (+ data-start subfile-size))
971 (insert (make-string (- subfile-size-pad subfile-size) 0))
972 ;;
973 ;; update the data pointer of this and all following files...
974 (tar-setf (tar-header-size tokens) subfile-size)
975 (let ((difference (- subfile-size-pad size-pad)))
976 (tar-dolist (desc following-descs)
977 (tar-setf (tar-desc-data-start desc)
978 (+ (tar-desc-data-start desc) difference))))
979 ;;
980 ;; Update the size field in the header block.
981 (let ((header-start (- data-start 512)))
982 (goto-char (+ header-start tar-size-offset))
983 (delete-region (point) (+ (point) 12))
984 (insert (format "%11o" subfile-size))
985 (insert ? )
986 ;;
987 ;; Maybe update the datestamp.
988 (if (not tar-update-datestamp)
989 nil
990 (goto-char (+ header-start tar-time-offset))
991 (delete-region (point) (+ (point) 12))
992 (insert (tar-octal-time (current-time)))
993 (insert ? ))
994 ;;
995 ;; compute a new checksum and insert it.
996 (let ((chk (checksum-tar-header-block
997 (buffer-substring header-start data-start))))
998 (goto-char (+ header-start tar-chk-offset))
999 (delete-region (point) (+ (point) 8))
1000 (insert (format "%6o" chk))
1001 (insert 0)
1002 (insert ? )
1003 (tar-setf (tar-header-checksum tokens) chk)))
1004 ;;
1005 ;; alter the descriptor-line...
1006 ;;
1007 (let ((position (- (length tar-parse-info) (length head))))
1008 (goto-char 1)
1009 (next-line position)
1010 (beginning-of-line)
1011 (let ((p (point))
1012 (m (set-marker (make-marker) tar-header-offset)))
1013 (forward-line 1)
1014 (delete-region p (point))
1015 (insert-before-markers (summarize-tar-header-block tokens t) "\n")
1016 (setq tar-header-offset (marker-position m)))
1017 )))
1018 ;; after doing the insertion, add any final padding that may be necessary.
1019 (tar-pad-to-blocksize))
1020 (narrow-to-region 1 tar-header-offset)))
1021 (set-buffer-modified-p t) ; mark the tar file as modified
1022 (set-buffer subfile)
1023 (set-buffer-modified-p nil) ; mark the tar subfile as unmodified
1024 (message "saved into tar-buffer \"%s\" - remember to save that buffer!"
1025 (buffer-name tar-superior-buffer))
1026 )))
1027
1028
1029 (defun tar-pad-to-blocksize ()
1030 "If we are being anal about tar file blocksizes, fix up the current buffer.
1031 Leaves the region wide."
1032 (if (null tar-anal-blocksize)
1033 nil
1034 (widen)
1035 (let* ((last-desc (nth (1- (length tar-parse-info)) tar-parse-info))
1036 (start (tar-desc-data-start last-desc))
1037 (tokens (tar-desc-tokens last-desc))
1038 (link-p (tar-header-link-type tokens))
1039 (size (if link-p 0 (tar-header-size tokens)))
1040 (data-end (+ start size))
1041 (bbytes (ash tar-anal-blocksize 9))
1042 (pad-to (+ bbytes (* bbytes (/ (1- data-end) bbytes))))
1043 (buffer-read-only nil) ; ##
1044 )
1045 ;; If the padding after the last data is too long, delete some;
1046 ;; else insert some until we are padded out to the right number of blocks.
1047 ;;
1048 (goto-char (+ (or tar-header-offset 0) data-end))
1049 (if (> (1+ (buffer-size)) (+ (or tar-header-offset 0) pad-to))
1050 (delete-region (+ (or tar-header-offset 0) pad-to) (1+ (buffer-size)))
1051 (insert (make-string (- (+ (or tar-header-offset 0) pad-to)
1052 (1+ (buffer-size)))
1053 0)))
1054 )))
1055
1056
1057 (defun maybe-write-tar-file ()
1058 "Used as a write-file-hook to write tar-files out correctly."
1059 ;;
1060 ;; If the current buffer is in tar-mode and has its header-offset set,
1061 ;; only write out the part of the file after the header-offset.
1062 ;;
1063 (if (and (eq major-mode 'tar-mode)
1064 (and (boundp 'tar-header-offset) tar-header-offset))
1065 (unwind-protect
1066 (save-excursion
1067 (tar-clear-modification-flags)
1068 (widen)
1069 ;; Doing this here confuses things - the region gets left too wide!
1070 ;; I suppose this is run in a context where changing the buffer is bad.
1071 ;; (tar-pad-to-blocksize)
1072 (write-region tar-header-offset (1+ (buffer-size)) buffer-file-name nil t)
1073 ;; return T because we've written the file.
1074 t)
1075 (narrow-to-region 1 tar-header-offset)
1076 t)
1077 ;; return NIL because we haven't.
1078 nil))
1079
1080 \f
1081 ;;; Patch it in.
1082
1083 (or (memq 'maybe-write-tar-file write-file-hooks)
1084 (setq write-file-hooks
1085 (cons 'maybe-write-tar-file write-file-hooks)))
1086
1087 (provide 'tar-mode)
1088
1089 ;;; tar-mode.el ends here