code.delx.au - gnu-emacs/blob - lisp/net/tramp-ftp.el

   1 ;;; tramp-ftp.el --- Tramp convenience functions for Ange-FTP
   2
   3 ;; Copyright (C) 2002, 2003, 2004, 2005, 2006, 2007,
   4 ;;   2008 Free Software Foundation, Inc.
   5
   6 ;; Author: Michael Albinus <michael.albinus@gmx.de>
   7 ;; Keywords: comm, processes
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 3, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  24 ;; Boston, MA 02110-1301, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; Convenience functions for calling Ange-FTP from Tramp.
  29 ;; Most of them are displaced from tramp.el.
  30
  31 ;;; Code:
  32
  33 (require 'tramp)
  34
  35 (eval-when-compile (require 'custom))
  36
  37 ;; Disable Ange-FTP from file-name-handler-alist.
  38 ;; To handle EFS, the following functions need to be dealt with:
  39 ;;
  40 ;; * dired-before-readin-hook contains efs-dired-before-readin
  41 ;; * file-name-handler-alist contains efs-file-handler-function
  42 ;;   and efs-root-handler-function and efs-sifn-handler-function
  43 ;; * find-file-hooks contains efs-set-buffer-mode
  44 ;;
  45 ;; But it won't happen for EFS since the XEmacs maintainers
  46 ;; don't want to use a unified filename syntax.
  47 (defun tramp-disable-ange-ftp ()
  48   "Turn Ange-FTP off.
  49 This is useful for unified remoting.  See
  50 `tramp-file-name-structure-unified' and
  51 `tramp-file-name-structure-separate' for details.  Requests suitable
  52 for Ange-FTP will be forwarded to Ange-FTP.  Also see the variables
  53 `tramp-ftp-method', `tramp-default-method', and
  54 `tramp-default-method-alist'.
  55
  56 This function is not needed in Emacsen which include Tramp, but is
  57 present for backward compatibility."
  58   (let ((a1 (rassq 'ange-ftp-hook-function file-name-handler-alist))
  59         (a2 (rassq 'ange-ftp-completion-hook-function file-name-handler-alist)))
  60     (setq file-name-handler-alist
  61           (delete a1 (delete a2 file-name-handler-alist)))))
  62
  63 (eval-after-load "ange-ftp"
  64   '(when (functionp 'tramp-disable-ange-ftp)
  65      (tramp-disable-ange-ftp)))
  66
  67 ;;;###autoload
  68 (defun tramp-ftp-enable-ange-ftp ()
  69   ;; The following code is commented out in Ange-FTP.
  70
  71   ;;; This regexp takes care of real ange-ftp file names (with a slash
  72   ;;; and colon).
  73   ;;; Don't allow the host name to end in a period--some systems use /.:
  74   (or (assoc "^/[^/:]*[^/:.]:" file-name-handler-alist)
  75       (setq file-name-handler-alist
  76             (cons '("^/[^/:]*[^/:.]:" . ange-ftp-hook-function)
  77                   file-name-handler-alist)))
  78
  79   ;;; This regexp recognizes absolute filenames with only one component,
  80   ;;; for the sake of hostname completion.
  81   (or (assoc "^/[^/:]*\\'" file-name-handler-alist)
  82       (setq file-name-handler-alist
  83             (cons '("^/[^/:]*\\'" . ange-ftp-completion-hook-function)
  84                   file-name-handler-alist)))
  85
  86   ;;; This regexp recognizes absolute filenames with only one component
  87   ;;; on Windows, for the sake of hostname completion.
  88   (and (memq system-type '(ms-dos windows-nt))
  89        (or (assoc "^[a-zA-Z]:/[^/:]*\\'" file-name-handler-alist)
  90            (setq file-name-handler-alist
  91                  (cons '("^[a-zA-Z]:/[^/:]*\\'" .
  92                          ange-ftp-completion-hook-function)
  93                        file-name-handler-alist)))))
  94
  95 (add-hook 'tramp-ftp-unload-hook 'tramp-ftp-enable-ange-ftp)
  96
  97 ;; Define FTP method ...
  98 (defcustom tramp-ftp-method "ftp"
  99   "*When this method name is used, forward all calls to Ange-FTP."
 100   :group 'tramp
 101   :type 'string)
 102
 103 ;; ... and add it to the method list.
 104 (add-to-list 'tramp-methods (cons tramp-ftp-method nil))
 105
 106 ;; Add some defaults for `tramp-default-method-alist'
 107 (add-to-list 'tramp-default-method-alist
 108              (list "\\`ftp\\." "" tramp-ftp-method))
 109 (add-to-list 'tramp-default-method-alist
 110              (list "" "\\`\\(anonymous\\|ftp\\)\\'" tramp-ftp-method))
 111
 112 ;; Add completion function for FTP method.
 113 (unless (memq system-type '(windows-nt))
 114   (tramp-set-completion-function
 115    tramp-ftp-method
 116    '((tramp-parse-netrc "~/.netrc"))))
 117
 118 (defun tramp-ftp-file-name-handler (operation &rest args)
 119   "Invoke the Ange-FTP handler for OPERATION.
 120 First arg specifies the OPERATION, second arg is a list of arguments to
 121 pass to the OPERATION."
 122   (save-match-data
 123     (or (boundp 'ange-ftp-name-format)
 124         (require 'ange-ftp))
 125     (let ((ange-ftp-name-format
 126            (list (nth 0 tramp-file-name-structure)
 127                  (nth 3 tramp-file-name-structure)
 128                  (nth 2 tramp-file-name-structure)
 129                  (nth 4 tramp-file-name-structure)))
 130           ;; ange-ftp uses `ange-ftp-ftp-name-arg' and `ange-ftp-ftp-name-res'
 131           ;; for optimization in `ange-ftp-ftp-name'. If Tramp wasn't active,
 132           ;; there could be incorrect values from previous calls in case the
 133           ;; "ftp" method is used in the Tramp file name. So we unset
 134           ;; those values.
 135           (ange-ftp-ftp-name-arg "")
 136           (ange-ftp-ftp-name-res nil))
 137       (cond
 138        ;; If argument is a symlink, `file-directory-p' and `file-exists-p'
 139        ;; call the traversed file recursively. So we cannot disable the
 140        ;; file-name-handler this case.
 141        ((memq operation '(file-directory-p file-exists-p))
 142         (apply 'ange-ftp-hook-function operation args))
 143         ;; Normally, the handlers must be discarded
 144         (t (let* ((inhibit-file-name-handlers
 145                    (list 'tramp-file-name-handler
 146                          'tramp-completion-file-name-handler
 147                          (and (eq inhibit-file-name-operation operation)
 148                               inhibit-file-name-handlers)))
 149                   (inhibit-file-name-operation operation))
 150              (apply 'ange-ftp-hook-function operation args)))))))
 151
 152 (defun tramp-ftp-file-name-p (filename)
 153   "Check if it's a filename that should be forwarded to Ange-FTP."
 154   (let ((v (tramp-dissect-file-name filename)))
 155     (string=
 156      (tramp-find-method
 157       (tramp-file-name-multi-method v)
 158       (tramp-file-name-method v)
 159       (tramp-file-name-user v)
 160       (tramp-file-name-host v))
 161      tramp-ftp-method)))
 162
 163 (add-to-list 'tramp-foreign-file-name-handler-alist
 164              (cons 'tramp-ftp-file-name-p 'tramp-ftp-file-name-handler))
 165
 166 (provide 'tramp-ftp)
 167
 168 ;;; TODO:
 169
 170 ;; * In case of "/ftp:host:file" this works only for functions which
 171 ;;   are defined in `tramp-file-name-handler-alist'.  Call has to be
 172 ;;   pretended in `tramp-file-name-handler' otherwise.
 173 ;;   Furthermore, there are no backup files on FTP hosts.
 174 ;;   Worth further investigations.
 175 ;; * Map /multi:ssh:out@gate:ftp:kai@real.host:/path/to.file
 176 ;;   on Ange-FTP gateways.
 177
 178 ;;; arch-tag: 759fb338-5c63-4b99-bd36-b4d59db91cff
 179 ;;; tramp-ftp.el ends here