code.delx.au - gnu-emacs/blob - lisp/progmodes/octave-mod.el

   1 ;;; octave-mod.el --- editing Octave source files under Emacs
   2
   3 ;; Copyright (C) 1997, 2001, 2002, 2003, 2004, 2005
   4 ;; Free Software Foundation, Inc.
   5
   6 ;; Author: Kurt Hornik <Kurt.Hornik@wu-wien.ac.at>
   7 ;; Author: John Eaton <jwe@bevo.che.wisc.edu>
   8 ;; Maintainer: Kurt Hornik <Kurt.Hornik@wu-wien.ac.at>
   9 ;; Keywords: languages
  10
  11 ;; This file is part of GNU Emacs.
  12
  13 ;; GNU Emacs is free software; you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation; either version 2, or (at your option)
  16 ;; any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  25 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  26 ;; Boston, MA 02110-1301, USA.
  27
  28 ;;; Commentary:
  29
  30 ;; This package provides Emacs support for Octave.
  31 ;; It defines Octave mode, a major mode for editing
  32 ;; Octave code.
  33
  34 ;; The file octave-hlp.el provides `octave-help', a facility for looking up
  35 ;; documentation on a symbol in the Octave info files.
  36
  37 ;; The file octave-inf.el contains code for interacting with an inferior
  38 ;; Octave process using comint.
  39
  40 ;; See the documentation of `octave-mode', `octave-help' and
  41 ;; `run-octave' for further information on usage and customization.
  42
  43 ;;; Code:
  44 (require 'custom)
  45
  46 (defgroup octave nil
  47   "Major mode for editing Octave source files."
  48   :link '(custom-group-link :tag "Font Lock Faces group" font-lock-faces)
  49   :group 'languages)
  50
  51 (defvar inferior-octave-output-list nil)
  52 (defvar inferior-octave-output-string nil)
  53 (defvar inferior-octave-receive-in-progress nil)
  54
  55 (defconst octave-maintainer-address
  56   "Kurt Hornik <Kurt.Hornik@wu-wien.ac.at>, bug-gnu-emacs@gnu.org"
  57   "Current maintainer of the Emacs Octave package.")
  58
  59 (defvar octave-abbrev-table nil
  60   "Abbrev table for Octave's reserved words.
  61 Used in `octave-mode' and inferior-octave-mode buffers.
  62 All Octave abbrevs start with a grave accent (`).")
  63 (unless octave-abbrev-table
  64   (let ((ac abbrevs-changed))
  65     (define-abbrev-table 'octave-abbrev-table ())
  66     (define-abbrev octave-abbrev-table "`a" "all_va_args" nil 0 t)
  67     (define-abbrev octave-abbrev-table "`b" "break" nil 0 t)
  68     (define-abbrev octave-abbrev-table "`cs" "case" nil 0 t)
  69     (define-abbrev octave-abbrev-table "`ca" "catch" nil 0 t)
  70     (define-abbrev octave-abbrev-table "`c" "continue" nil 0 t)
  71     (define-abbrev octave-abbrev-table "`el" "else" nil 0 t)
  72     (define-abbrev octave-abbrev-table "`eli" "elseif" nil 0 t)
  73     (define-abbrev octave-abbrev-table "`et" "end_try_catch" nil 0 t)
  74     (define-abbrev octave-abbrev-table "`eu" "end_unwind_protect" nil 0 t)
  75     (define-abbrev octave-abbrev-table "`ef" "endfor" nil 0 t)
  76     (define-abbrev octave-abbrev-table "`efu" "endfunction" nil 0 t)
  77     (define-abbrev octave-abbrev-table "`ei" "endif" nil 0 t)
  78     (define-abbrev octave-abbrev-table "`es" "endswitch" nil 0 t)
  79     (define-abbrev octave-abbrev-table "`ew" "endwhile" nil 0 t)
  80     (define-abbrev octave-abbrev-table "`f" "for" nil 0 t)
  81     (define-abbrev octave-abbrev-table "`fu" "function" nil 0 t)
  82     (define-abbrev octave-abbrev-table "`gl" "global" nil 0 t)
  83     (define-abbrev octave-abbrev-table "`gp" "gplot" nil 0 t)
  84     (define-abbrev octave-abbrev-table "`gs" "gsplot" nil 0 t)
  85     (define-abbrev octave-abbrev-table "`if" "if ()" nil 0 t)
  86     (define-abbrev octave-abbrev-table "`o" "otherwise" nil 0 t)
  87     (define-abbrev octave-abbrev-table "`rp" "replot" nil 0 t)
  88     (define-abbrev octave-abbrev-table "`r" "return" nil 0 t)
  89     (define-abbrev octave-abbrev-table "`s" "switch" nil 0 t)
  90     (define-abbrev octave-abbrev-table "`t" "try" nil 0 t)
  91     (define-abbrev octave-abbrev-table "`up" "unwind_protect" nil 0 t)
  92     (define-abbrev octave-abbrev-table "`upc" "unwind_protect_cleanup" nil 0 t)
  93     (define-abbrev octave-abbrev-table "`w" "while ()" nil 0 t)
  94     (setq abbrevs-changed ac)))
  95
  96 (defvar octave-comment-char ?#
  97   "Character to start an Octave comment.")
  98 (defvar octave-comment-start
  99   (string octave-comment-char ?\ )
 100   "String to insert to start a new Octave in-line comment.")
 101 (defvar octave-comment-start-skip "\\s<+\\s-*"
 102   "Regexp to match the start of an Octave comment up to its body.")
 103
 104 (defvar octave-begin-keywords
 105   '("for" "function" "if" "switch" "try" "unwind_protect" "while"))
 106 (defvar octave-else-keywords
 107   '("case" "catch" "else" "elseif" "otherwise" "unwind_protect_cleanup"))
 108 (defvar octave-end-keywords
 109   '("end" "endfor" "endfunction" "endif" "endswitch" "end_try_catch"
 110     "end_unwind_protect" "endwhile"))
 111
 112 (defvar octave-reserved-words
 113   (append octave-begin-keywords
 114           octave-else-keywords
 115           octave-end-keywords
 116           '("all_va_args" "break" "continue" "global" "gplot" "gsplot"
 117             "replot" "return"))
 118   "Reserved words in Octave.")
 119
 120 (defvar octave-text-functions
 121   '("casesen" "cd" "chdir" "clear" "diary" "dir" "document" "echo"
 122     "edit_history" "format" "gset" "gshow" "help" "history" "hold"
 123     "load" "ls" "more" "run_history" "save" "set" "show" "type"
 124     "which" "who" "whos")
 125   "Text functions in Octave (these names are also reserved).")
 126
 127 (defvar octave-variables
 128   '("EDITOR" "EXEC_PATH" "F_DUPFD" "F_GETFD" "F_GETFL" "F_SETFD"
 129     "F_SETFL" "I" "IMAGEPATH" "INFO_FILE" "INFO_PROGRAM" "Inf" "J"
 130     "LOADPATH" "NaN" "OCTAVE_VERSION" "O_APPEND" "O_CREAT" "O_EXCL"
 131     "O_NONBLOCK" "O_RDONLY" "O_RDWR" "O_TRUNC" "O_WRONLY" "PAGER" "PS1"
 132     "PS2" "PS4" "PWD" "SEEK_CUR" "SEEK_END" "SEEK_SET" "__F_DUPFD__"
 133     "__F_GETFD__" "__F_GETFL__" "__F_SETFD__" "__F_SETFL__" "__I__"
 134     "__Inf__" "__J__" "__NaN__" "__OCTAVE_VERSION__" "__O_APPEND__"
 135     "__O_CREAT__" "__O_EXCL__" "__O_NONBLOCK__" "__O_RDONLY__"
 136     "__O_RDWR__" "__O_TRUNC__" "__O_WRONLY__" "__PWD__" "__SEEK_CUR__"
 137     "__SEEK_END__" "__SEEK_SET__" "__argv__" "__e__" "__eps__"
 138     "__error_text__" "__i__" "__inf__" "__j__" "__nan__" "__pi__"
 139     "__program_invocation_name__" "__program_name__" "__realmax__"
 140     "__realmin__" "__stderr__" "__stdin__" "__stdout__" "ans" "argv"
 141     "automatic_replot" "beep_on_error" "completion_append_char"
 142     "default_return_value" "default_save_format"
 143     "define_all_return_values" "do_fortran_indexing" "e"
 144     "echo_executing_commands" "empty_list_elements_ok" "eps"
 145     "error_text" "gnuplot_binary" "gnuplot_has_multiplot" "history_file"
 146     "history_size" "ignore_function_time_stamp" "implicit_str_to_num_ok"
 147     "inf" "nan" "nargin" "ok_to_lose_imaginary_part"
 148     "output_max_field_width" "output_precision"
 149     "page_output_immediately" "page_screen_output" "pi"
 150     "prefer_column_vectors" "prefer_zero_one_indexing"
 151     "print_answer_id_name" "print_empty_dimensions"
 152     "program_invocation_name" "program_name" "propagate_empty_matrices"
 153     "realmax" "realmin" "resize_on_range_error"
 154     "return_last_computed_value" "save_precision" "saving_history"
 155     "silent_functions" "split_long_rows" "stderr" "stdin" "stdout"
 156     "string_fill_char" "struct_levels_to_print"
 157     "suppress_verbose_help_message" "treat_neg_dim_as_zero"
 158     "warn_assign_as_truth_value" "warn_comma_in_global_decl"
 159     "warn_divide_by_zero" "warn_function_name_clash"
 160     "warn_missing_semicolon" "whitespace_in_literal_matrix")
 161   "Builtin variables in Octave.")
 162
 163 (defvar octave-function-header-regexp
 164   (concat "^\\s-*\\<\\(function\\)\\>"
 165           "\\([^=;\n]*=[ \t]*\\|[ \t]*\\)\\(\\w+\\)\\>")
 166   "Regexp to match an Octave function header.
 167 The string `function' and its name are given by the first and third
 168 parenthetical grouping.")
 169
 170 (defvar octave-font-lock-keywords
 171   (list
 172    ;; Fontify all builtin keywords.
 173    (cons (concat "\\<\\("
 174                  (mapconcat 'identity octave-reserved-words "\\|")
 175                  (mapconcat 'identity octave-text-functions "\\|")
 176                  "\\)\\>")
 177          'font-lock-keyword-face)
 178    ;; Fontify all builtin operators.
 179    (cons "\\(&\\||\\|<=\\|>=\\|==\\|<\\|>\\|!=\\|!\\)"
 180          (if (boundp 'font-lock-builtin-face)
 181              'font-lock-builtin-face
 182            'font-lock-preprocessor-face))
 183    ;; Fontify all builtin variables.
 184    (cons (concat "\\<\\("
 185                  (mapconcat 'identity octave-variables "\\|")
 186                  "\\)\\>")
 187          'font-lock-variable-name-face)
 188    ;; Fontify all function declarations.
 189    (list octave-function-header-regexp
 190          '(1 font-lock-keyword-face)
 191          '(3 font-lock-function-name-face nil t)))
 192   "Additional Octave expressions to highlight.")
 193
 194 (defcustom inferior-octave-buffer "*Inferior Octave*"
 195   "*Name of buffer for running an inferior Octave process."
 196   :type 'string
 197   :group 'octave-inferior)
 198
 199 (defvar inferior-octave-process nil)
 200 \f
 201 (defvar octave-mode-map nil
 202   "Keymap used in Octave mode.")
 203 (if octave-mode-map
 204     ()
 205   (let ((map (make-sparse-keymap)))
 206     (define-key map "`" 'octave-abbrev-start)
 207     (define-key map ";" 'octave-electric-semi)
 208     (define-key map " " 'octave-electric-space)
 209     (define-key map "\n" 'octave-reindent-then-newline-and-indent)
 210     (define-key map "\t" 'indent-according-to-mode)
 211     (define-key map "\e;" 'octave-indent-for-comment)
 212     (define-key map "\e\n" 'octave-indent-new-comment-line)
 213     (define-key map "\e\t" 'octave-complete-symbol)
 214     (define-key map "\M-\C-a" 'octave-beginning-of-defun)
 215     (define-key map "\M-\C-e" 'octave-end-of-defun)
 216     (define-key map "\M-\C-h" 'octave-mark-defun)
 217     (define-key map "\M-\C-q" 'octave-indent-defun)
 218     (define-key map "\C-c;" 'octave-comment-region)
 219     (define-key map "\C-c:" 'octave-uncomment-region)
 220     (define-key map "\C-c\C-b" 'octave-submit-bug-report)
 221     (define-key map "\C-c\C-p" 'octave-previous-code-line)
 222     (define-key map "\C-c\C-n" 'octave-next-code-line)
 223     (define-key map "\C-c\C-a" 'octave-beginning-of-line)
 224     (define-key map "\C-c\C-e" 'octave-end-of-line)
 225     (define-key map "\C-c\M-\C-n" 'octave-forward-block)
 226     (define-key map "\C-c\M-\C-p" 'octave-backward-block)
 227     (define-key map "\C-c\M-\C-u" 'octave-backward-up-block)
 228     (define-key map "\C-c\M-\C-d" 'octave-down-block)
 229     (define-key map "\C-c\M-\C-h" 'octave-mark-block)
 230     (define-key map "\C-c]" 'octave-close-block)
 231     (define-key map "\C-c\C-f" 'octave-insert-defun)
 232     (define-key map "\C-c\C-h" 'octave-help)
 233     (define-key map "\C-c\C-il" 'octave-send-line)
 234     (define-key map "\C-c\C-ib" 'octave-send-block)
 235     (define-key map "\C-c\C-if" 'octave-send-defun)
 236     (define-key map "\C-c\C-ir" 'octave-send-region)
 237     (define-key map "\C-c\C-is" 'octave-show-process-buffer)
 238     (define-key map "\C-c\C-ih" 'octave-hide-process-buffer)
 239     (define-key map "\C-c\C-ik" 'octave-kill-process)
 240     (define-key map "\C-c\C-i\C-l" 'octave-send-line)
 241     (define-key map "\C-c\C-i\C-b" 'octave-send-block)
 242     (define-key map "\C-c\C-i\C-f" 'octave-send-defun)
 243     (define-key map "\C-c\C-i\C-r" 'octave-send-region)
 244     (define-key map "\C-c\C-i\C-s" 'octave-show-process-buffer)
 245     (define-key map "\C-c\C-i\C-h" 'octave-hide-process-buffer)
 246     (define-key map "\C-c\C-i\C-k" 'octave-kill-process)
 247     (setq octave-mode-map map)))
 248
 249 (defvar octave-mode-menu
 250   (list "Octave"
 251         (list "Lines"
 252               ["Previous Code Line"     octave-previous-code-line t]
 253               ["Next Code Line"         octave-next-code-line t]
 254               ["Begin of Continuation"  octave-beginning-of-line t]
 255               ["End of Continuation"    octave-end-of-line t]
 256               ["Split Line at Point"    octave-indent-new-comment-line t])
 257         (list "Blocks"
 258               ["Next Block"             octave-forward-block t]
 259               ["Previous Block"         octave-backward-block t]
 260               ["Down Block"             octave-down-block t]
 261               ["Up Block"               octave-backward-up-block t]
 262               ["Mark Block"             octave-mark-block t]
 263               ["Close Block"            octave-close-block t])
 264         (list "Functions"
 265               ["Begin of Function"      octave-beginning-of-defun t]
 266               ["End of Function"        octave-end-of-defun t]
 267               ["Mark Function"          octave-mark-defun t]
 268               ["Indent Function"        octave-indent-defun t]
 269               ["Insert Function"        octave-insert-defun t])
 270         "-"
 271         (list "Debug"
 272               ["Send Current Line"      octave-send-line t]
 273               ["Send Current Block"     octave-send-block t]
 274               ["Send Current Function"  octave-send-defun t]
 275               ["Send Region"            octave-send-region t]
 276               ["Show Process Buffer"    octave-show-process-buffer t]
 277               ["Hide Process Buffer"    octave-hide-process-buffer t]
 278               ["Kill Process"           octave-kill-process t])
 279         "-"
 280         ["Indent Line"                  indent-according-to-mode t]
 281         ["Complete Symbol"              octave-complete-symbol t]
 282         "-"
 283         ["Toggle Abbrev Mode"           abbrev-mode t]
 284         ["Toggle Auto-Fill Mode"        auto-fill-mode t]
 285         "-"
 286         ["Submit Bug Report"            octave-submit-bug-report t]
 287         "-"
 288         ["Describe Octave Mode"         octave-describe-major-mode t]
 289         ["Lookup Octave Index"          octave-help t])
 290   "Menu for Octave mode.")
 291
 292 (defvar octave-mode-syntax-table
 293   (let ((table (make-syntax-table)))
 294     (modify-syntax-entry ?\r " "  table)
 295     (modify-syntax-entry ?+ "."   table)
 296     (modify-syntax-entry ?- "."   table)
 297     (modify-syntax-entry ?= "."   table)
 298     (modify-syntax-entry ?* "."   table)
 299     (modify-syntax-entry ?/ "."   table)
 300     (modify-syntax-entry ?> "."   table)
 301     (modify-syntax-entry ?< "."   table)
 302     (modify-syntax-entry ?& "."   table)
 303     (modify-syntax-entry ?| "."   table)
 304     (modify-syntax-entry ?! "."   table)
 305     (modify-syntax-entry ?\\ "\\" table)
 306     (modify-syntax-entry ?\' "."  table)
 307     (modify-syntax-entry ?\` "w"  table)
 308     (modify-syntax-entry ?\" "\"" table)
 309     (modify-syntax-entry ?. "w"   table)
 310     (modify-syntax-entry ?_ "w"   table)
 311     (modify-syntax-entry ?\% "<"  table)
 312     (modify-syntax-entry ?\# "<"  table)
 313     (modify-syntax-entry ?\n ">"  table)
 314     table)
 315   "Syntax table in use in `octave-mode' buffers.")
 316
 317 (defcustom octave-auto-indent nil
 318   "*Non-nil means indent line after a semicolon or space in Octave mode."
 319   :type 'boolean
 320   :group 'octave)
 321
 322 (defcustom octave-auto-newline nil
 323   "*Non-nil means automatically newline after a semicolon in Octave mode."
 324   :type 'boolean
 325   :group 'octave)
 326
 327 (defcustom octave-blink-matching-block t
 328   "*Control the blinking of matching Octave block keywords.
 329 Non-nil means show matching begin of block when inserting a space,
 330 newline or semicolon after an else or end keyword."
 331   :type 'boolean
 332   :group 'octave)
 333 (defcustom octave-block-offset 2
 334   "*Extra indentation applied to statements in Octave block structures."
 335   :type 'integer
 336   :group 'octave)
 337
 338 (defvar octave-block-begin-regexp
 339   (concat "\\<\\("
 340           (mapconcat 'identity octave-begin-keywords "\\|")
 341           "\\)\\>"))
 342 (defvar octave-block-else-regexp
 343   (concat "\\<\\("
 344           (mapconcat 'identity octave-else-keywords "\\|")
 345           "\\)\\>"))
 346 (defvar octave-block-end-regexp
 347   (concat "\\<\\("
 348           (mapconcat 'identity octave-end-keywords "\\|")
 349           "\\)\\>"))
 350 (defvar octave-block-begin-or-end-regexp
 351   (concat octave-block-begin-regexp "\\|" octave-block-end-regexp))
 352 (defvar octave-block-else-or-end-regexp
 353   (concat octave-block-else-regexp "\\|" octave-block-end-regexp))
 354 (defvar octave-block-match-alist
 355   '(("for" . ("end" "endfor"))
 356     ("function" . ("end" "endfunction"))
 357     ("if" . ("else" "elseif" "end" "endif"))
 358     ("switch" . ("case" "otherwise" "end" "endswitch"))
 359     ("try" . ("catch" "end" "end_try_catch"))
 360     ("unwind_protect" . ("unwind_protect_cleanup" "end"
 361                          "end_unwind_protect"))
 362     ("while" . ("end" "endwhile")))
 363   "Alist with Octave's matching block keywords.
 364 Has Octave's begin keywords as keys and a list of the matching else or
 365 end keywords as associated values.")
 366
 367 (defvar octave-block-comment-start
 368   (concat (make-string 2 octave-comment-char) " ")
 369   "String to insert to start a new Octave comment on an empty line.")
 370
 371 (defcustom octave-continuation-offset 4
 372   "*Extra indentation applied to Octave continuation lines."
 373   :type 'integer
 374   :group 'octave)
 375 (defvar octave-continuation-regexp
 376   "[^#%\n]*\\(\\\\\\|\\.\\.\\.\\)\\s-*\\(\\s<.*\\)?$")
 377 (defcustom octave-continuation-string "\\"
 378   "*Character string used for Octave continuation lines.  Normally \\."
 379   :type 'string
 380   :group 'octave)
 381
 382 (defvar octave-completion-alist nil
 383   "Alist of Octave symbols for completion in Octave mode.
 384 Each element looks like (VAR . VAR), where the car and cdr are the same
 385 symbol (an Octave command or variable name).
 386 Currently, only builtin variables can be completed.")
 387
 388 (defvar octave-mode-imenu-generic-expression
 389   (list
 390    ;; Functions
 391    (list nil octave-function-header-regexp 3))
 392   "Imenu expression for Octave mode.  See `imenu-generic-expression'.")
 393
 394 (defcustom octave-mode-startup-message t
 395   "*nil means do not display the Octave mode startup message."
 396   :type 'boolean
 397   :group 'octave)
 398
 399 (defcustom octave-mode-hook nil
 400   "*Hook to be run when Octave mode is started."
 401   :type 'hook
 402   :group 'octave)
 403
 404 (defcustom octave-send-show-buffer t
 405   "*Non-nil means display `inferior-octave-buffer' after sending to it."
 406   :type 'boolean
 407   :group 'octave)
 408 (defcustom octave-send-line-auto-forward t
 409   "*Control auto-forward after sending to the inferior Octave process.
 410 Non-nil means always go to the next Octave code line after sending."
 411   :type 'boolean
 412   :group 'octave)
 413 (defcustom octave-send-echo-input t
 414   "*Non-nil means echo input sent to the inferior Octave process."
 415   :type 'boolean
 416   :group 'octave)
 417
 418 \f
 419 ;;;###autoload
 420 (defun octave-mode ()
 421   "Major mode for editing Octave code.
 422
 423 This mode makes it easier to write Octave code by helping with
 424 indentation, doing some of the typing for you (with Abbrev mode) and by
 425 showing keywords, comments, strings, etc. in different faces (with
 426 Font Lock mode on terminals that support it).
 427
 428 Octave itself is a high-level language, primarily intended for numerical
 429 computations.  It provides a convenient command line interface for
 430 solving linear and nonlinear problems numerically.  Function definitions
 431 can also be stored in files, and it can be used in a batch mode (which
 432 is why you need this mode!).
 433
 434 The latest released version of Octave is always available via anonymous
 435 ftp from bevo.che.wisc.edu in the directory `/pub/octave'.  Complete
 436 source and binaries for several popular systems are available.
 437
 438 Type \\[list-abbrevs] to display the built-in abbrevs for Octave keywords.
 439
 440 Keybindings
 441 ===========
 442
 443 \\{octave-mode-map}
 444
 445 Variables you can use to customize Octave mode
 446 ==============================================
 447
 448 octave-auto-indent
 449   Non-nil means indent current line after a semicolon or space.
 450   Default is nil.
 451
 452 octave-auto-newline
 453   Non-nil means auto-insert a newline and indent after a semicolon.
 454   Default is nil.
 455
 456 octave-blink-matching-block
 457   Non-nil means show matching begin of block when inserting a space,
 458   newline or semicolon after an else or end keyword.  Default is t.
 459
 460 octave-block-offset
 461   Extra indentation applied to statements in block structures.
 462   Default is 2.
 463
 464 octave-continuation-offset
 465   Extra indentation applied to Octave continuation lines.
 466   Default is 4.
 467
 468 octave-continuation-string
 469   String used for Octave continuation lines.
 470   Default is a backslash.
 471
 472 octave-mode-startup-message
 473   nil means do not display the Octave mode startup message.
 474   Default is t.
 475
 476 octave-send-echo-input
 477   Non-nil means always display `inferior-octave-buffer' after sending a
 478   command to the inferior Octave process.
 479
 480 octave-send-line-auto-forward
 481   Non-nil means always go to the next unsent line of Octave code after
 482   sending a line to the inferior Octave process.
 483
 484 octave-send-echo-input
 485   Non-nil means echo input sent to the inferior Octave process.
 486
 487 Turning on Octave mode runs the hook `octave-mode-hook'.
 488
 489 To begin using this mode for all `.m' files that you edit, add the
 490 following lines to your `.emacs' file:
 491
 492   (autoload 'octave-mode \"octave-mod\" nil t)
 493   (setq auto-mode-alist
 494         (cons '(\"\\\\.m$\" . octave-mode) auto-mode-alist))
 495
 496 To automatically turn on the abbrev, auto-fill and font-lock features,
 497 add the following lines to your `.emacs' file as well:
 498
 499   (add-hook 'octave-mode-hook
 500             (lambda ()
 501               (abbrev-mode 1)
 502               (auto-fill-mode 1)
 503               (if (eq window-system 'x)
 504                   (font-lock-mode 1))))
 505
 506 To submit a problem report, enter \\[octave-submit-bug-report] from \
 507 an Octave mode buffer.
 508 This automatically sets up a mail buffer with version information
 509 already added.  You just need to add a description of the problem,
 510 including a reproducible test case and send the message."
 511   (interactive)
 512   (kill-all-local-variables)
 513
 514   (use-local-map octave-mode-map)
 515   (setq major-mode 'octave-mode)
 516   (setq mode-name "Octave")
 517   (setq local-abbrev-table octave-abbrev-table)
 518   (set-syntax-table octave-mode-syntax-table)
 519
 520   (make-local-variable 'indent-line-function)
 521   (setq indent-line-function 'octave-indent-line)
 522
 523   (make-local-variable 'comment-start)
 524   (setq comment-start octave-comment-start)
 525   (make-local-variable 'comment-end)
 526   (setq comment-end "")
 527   (make-local-variable 'comment-column)
 528   (setq comment-column 32)
 529   (make-local-variable 'comment-start-skip)
 530   (setq comment-start-skip "\\s<+\\s-*")
 531   (make-local-variable 'comment-indent-function)
 532   (setq comment-indent-function 'octave-comment-indent)
 533
 534   (make-local-variable 'parse-sexp-ignore-comments)
 535   (setq parse-sexp-ignore-comments t)
 536   (make-local-variable 'paragraph-start)
 537   (setq paragraph-start (concat "\\s-*$\\|" page-delimiter))
 538   (make-local-variable 'paragraph-separate)
 539   (setq paragraph-separate paragraph-start)
 540   (make-local-variable 'paragraph-ignore-fill-prefix)
 541   (setq paragraph-ignore-fill-prefix t)
 542   (make-local-variable 'fill-paragraph-function)
 543   (setq fill-paragraph-function 'octave-fill-paragraph)
 544   (make-local-variable 'adaptive-fill-regexp)
 545   (setq adaptive-fill-regexp nil)
 546   (make-local-variable 'fill-column)
 547   (setq fill-column 72)
 548   (make-local-variable 'normal-auto-fill-function)
 549   (setq normal-auto-fill-function 'octave-auto-fill)
 550
 551   (make-local-variable 'font-lock-defaults)
 552   (setq font-lock-defaults '(octave-font-lock-keywords nil nil))
 553
 554   (make-local-variable 'imenu-generic-expression)
 555   (setq imenu-generic-expression octave-mode-imenu-generic-expression
 556         imenu-case-fold-search nil)
 557
 558   (octave-add-octave-menu)
 559   (octave-initialize-completions)
 560   (run-mode-hooks 'octave-mode-hook))
 561 \f
 562 ;;; Miscellaneous useful functions
 563 (defun octave-describe-major-mode ()
 564   "Describe the current major mode."
 565   (interactive)
 566   (describe-function major-mode))
 567
 568 (defsubst octave-in-comment-p ()
 569   "Returns t if point is inside an Octave comment, nil otherwise."
 570   (interactive)
 571   (save-excursion
 572     (nth 4 (parse-partial-sexp (line-beginning-position) (point)))))
 573
 574 (defsubst octave-in-string-p ()
 575   "Returns t if point is inside an Octave string, nil otherwise."
 576   (interactive)
 577   (save-excursion
 578     (nth 3 (parse-partial-sexp (line-beginning-position) (point)))))
 579
 580 (defsubst octave-not-in-string-or-comment-p ()
 581   "Returns t iff point is not inside an Octave string or comment."
 582   (let ((pps (parse-partial-sexp (line-beginning-position) (point))))
 583     (not (or (nth 3 pps) (nth 4 pps)))))
 584
 585 (defun octave-in-block-p ()
 586   "Returns t if point is inside an Octave block, nil otherwise.
 587 The block is taken to start at the first letter of the begin keyword and
 588 to end after the end keyword."
 589   (let ((pos (point)))
 590     (save-excursion
 591       (condition-case nil
 592           (progn
 593             (skip-syntax-forward "w")
 594             (octave-up-block -1)
 595             (octave-forward-block)
 596             t)
 597         (error nil))
 598       (< pos (point)))))
 599
 600 (defun octave-in-defun-p ()
 601   "Returns t iff point is inside an Octave function declaration.
 602 The function is taken to start at the `f' of `function' and to end after
 603 the end keyword."
 604   (let ((pos (point)))
 605     (save-excursion
 606       (or (and (looking-at "\\<function\\>")
 607                (octave-not-in-string-or-comment-p))
 608           (and (octave-beginning-of-defun)
 609                (condition-case nil
 610                    (progn
 611                      (octave-forward-block)
 612                      t)
 613                  (error nil))
 614                (< pos (point)))))))
 615
 616 (defun octave-maybe-insert-continuation-string ()
 617   (if (or (octave-in-comment-p)
 618           (save-excursion
 619             (beginning-of-line)
 620             (looking-at octave-continuation-regexp)))
 621       nil
 622     (delete-horizontal-space)
 623     (insert (concat " " octave-continuation-string))))
 624
 625 (defvar octave-xemacs-p
 626   (string-match "XEmacs\\|Lucid" emacs-version))
 627
 628 ;;; Comments
 629 (defun octave-comment-region (beg end &optional arg)
 630   "Comment or uncomment each line in the region as Octave code.
 631 See `comment-region'."
 632   (interactive "r\nP")
 633   (let ((comment-start (char-to-string octave-comment-char)))
 634     (comment-region beg end arg)))
 635
 636 (defun octave-uncomment-region (beg end &optional arg)
 637   "Uncomment each line in the region as Octave code."
 638   (interactive "r\nP")
 639   (or arg (setq arg 1))
 640   (octave-comment-region beg end (- arg)))
 641
 642 \f
 643 ;;; Indentation
 644 (defun calculate-octave-indent ()
 645   "Return appropriate indentation for current line as Octave code.
 646 Returns an integer (the column to indent to) unless the line is a
 647 comment line with fixed goal golumn.  In that case, returns a list whose
 648 car is the column to indent to, and whose cdr is the current indentation
 649 level."
 650   (let ((is-continuation-line
 651          (save-excursion
 652            (if (zerop (octave-previous-code-line))
 653                (looking-at octave-continuation-regexp))))
 654         (icol 0))
 655     (save-excursion
 656       (beginning-of-line)
 657       ;; If we can move backward out one level of parentheses, take 1
 658       ;; plus the indentation of that parenthesis.  Otherwise, go back
 659       ;; to the beginning of the previous code line, and compute the
 660       ;; offset this line gives.
 661       (if (condition-case nil
 662               (progn
 663                 (up-list -1)
 664                 t)
 665             (error nil))
 666           (setq icol (+ 1 (current-column)))
 667         (if (zerop (octave-previous-code-line))
 668             (progn
 669               (octave-beginning-of-line)
 670               (back-to-indentation)
 671               (setq icol (current-column))
 672               (let ((bot (point))
 673                     (eol (line-end-position)))
 674                 (while (< (point) eol)
 675                   (if (octave-not-in-string-or-comment-p)
 676                       (cond
 677                        ((looking-at "\\<switch\\>")
 678                         (setq icol (+ icol (* 2 octave-block-offset))))
 679                        ((looking-at octave-block-begin-regexp)
 680                         (setq icol (+ icol octave-block-offset)))
 681                        ((looking-at octave-block-else-regexp)
 682                         (if (= bot (point))
 683                             (setq icol (+ icol octave-block-offset))))
 684                        ((looking-at octave-block-end-regexp)
 685                         (if (not (= bot (point)))
 686                             (setq icol (- icol
 687                                           (octave-block-end-offset)))))))
 688                   (forward-char)))
 689               (if is-continuation-line
 690                   (setq icol (+ icol octave-continuation-offset)))))))
 691     (save-excursion
 692       (back-to-indentation)
 693       (cond
 694        ((and (looking-at octave-block-else-regexp)
 695              (octave-not-in-string-or-comment-p))
 696         (setq icol (- icol octave-block-offset)))
 697        ((and (looking-at octave-block-end-regexp)
 698              (octave-not-in-string-or-comment-p))
 699         (setq icol (- icol (octave-block-end-offset))))
 700        ((or (looking-at "\\s<\\s<\\s<\\S<")
 701             (octave-before-magic-comment-p))
 702         (setq icol (list 0 icol)))
 703        ((looking-at "\\s<\\S<")
 704         (setq icol (list comment-column icol)))))
 705     icol))
 706
 707 (defun octave-block-end-offset ()
 708   (save-excursion
 709     (octave-backward-up-block 1)
 710     (* octave-block-offset
 711        (if (string-match (match-string 0) "switch") 2 1))))
 712
 713 (defun octave-before-magic-comment-p ()
 714   (save-excursion
 715     (beginning-of-line)
 716     (and (bobp) (looking-at "\\s-*#!"))))
 717
 718 (defun octave-comment-indent ()
 719   (if (or (looking-at "\\s<\\s<\\s<")
 720           (octave-before-magic-comment-p))
 721       0
 722     (if (looking-at "\\s<\\s<")
 723         (calculate-octave-indent)
 724       (skip-syntax-backward " ")
 725       (max (if (bolp) 0 (+ 1 (current-column)))
 726            comment-column))))
 727
 728 (defun octave-indent-for-comment ()
 729   "Maybe insert and indent an Octave comment.
 730 If there is no comment already on this line, create a code-level comment
 731 \(started by two comment characters) if the line is empty, or an in-line
 732 comment (started by one comment character) otherwise.
 733 Point is left after the start of the comment which is properly aligned."
 734   (interactive)
 735   (indent-for-comment)
 736   (indent-according-to-mode))
 737
 738 (defun octave-indent-line (&optional arg)
 739   "Indent current line as Octave code.
 740 With optional ARG, use this as offset unless this line is a comment with
 741 fixed goal column."
 742   (interactive)
 743   (or arg (setq arg 0))
 744   (let ((icol (calculate-octave-indent))
 745         (relpos (- (current-column) (current-indentation))))
 746     (if (listp icol)
 747         (setq icol (car icol))
 748       (setq icol (+ icol arg)))
 749     (if (< icol 0)
 750         (error "Unmatched end keyword")
 751       (indent-line-to icol)
 752       (if (> relpos 0)
 753           (move-to-column (+ icol relpos))))))
 754
 755 (defun octave-indent-new-comment-line ()
 756   "Break Octave line at point, continuing comment if within one.
 757 If within code, insert `octave-continuation-string' before breaking the
 758 line.  If within a string, signal an error.
 759 The new line is properly indented."
 760   (interactive)
 761   (delete-horizontal-space)
 762   (cond
 763    ((octave-in-comment-p)
 764     (indent-new-comment-line))
 765    ((octave-in-string-p)
 766     (error "Cannot split a code line inside a string"))
 767    (t
 768     (insert (concat " " octave-continuation-string))
 769     (octave-reindent-then-newline-and-indent))))
 770
 771 (defun octave-indent-defun ()
 772   "Properly indents the Octave function which contains point."
 773   (interactive)
 774   (save-excursion
 775     (octave-mark-defun)
 776     (message "Indenting function...")
 777     (indent-region (point) (mark) nil))
 778   (message "Indenting function...done."))
 779
 780 \f
 781 ;;; Motion
 782 (defun octave-next-code-line (&optional arg)
 783   "Move ARG lines of Octave code forward (backward if ARG is negative).
 784 Skips past all empty and comment lines.  Default for ARG is 1.
 785
 786 On success, return 0.  Otherwise, go as far as possible and return -1."
 787   (interactive "p")
 788   (or arg (setq arg 1))
 789   (beginning-of-line)
 790   (let ((n 0)
 791         (inc (if (> arg 0) 1 -1)))
 792     (while (and (/= arg 0) (= n 0))
 793       (setq n (forward-line inc))
 794       (while (and (= n 0)
 795                   (looking-at "\\s-*\\($\\|\\s<\\)"))
 796         (setq n (forward-line inc)))
 797       (setq arg (- arg inc)))
 798     n))
 799
 800 (defun octave-previous-code-line (&optional arg)
 801   "Move ARG lines of Octave code backward (forward if ARG is negative).
 802 Skips past all empty and comment lines.  Default for ARG is 1.
 803
 804 On success, return 0.  Otherwise, go as far as possible and return -1."
 805   (interactive "p")
 806   (or arg (setq arg 1))
 807   (octave-next-code-line (- arg)))
 808
 809 (defun octave-beginning-of-line ()
 810   "Move point to beginning of current Octave line.
 811 If on an empty or comment line, go to the beginning of that line.
 812 Otherwise, move backward to the beginning of the first Octave code line
 813 which is not inside a continuation statement, i.e., which does not
 814 follow a code line ending in `...' or `\\', or is inside an open
 815 parenthesis list."
 816   (interactive)
 817   (beginning-of-line)
 818   (if (not (looking-at "\\s-*\\($\\|\\s<\\)"))
 819       (while (or (condition-case nil
 820                      (progn
 821                        (up-list -1)
 822                        (beginning-of-line)
 823                        t)
 824                    (error nil))
 825                  (and (or (looking-at "\\s-*\\($\\|\\s<\\)")
 826                           (save-excursion
 827                             (if (zerop (octave-previous-code-line))
 828                                 (looking-at octave-continuation-regexp))))
 829                       (zerop (forward-line -1)))))))
 830
 831 (defun octave-end-of-line ()
 832   "Move point to end of current Octave line.
 833 If on an empty or comment line, go to the end of that line.
 834 Otherwise, move forward to the end of the first Octave code line which
 835 does not end in `...' or `\\' or is inside an open parenthesis list."
 836   (interactive)
 837   (end-of-line)
 838   (if (save-excursion
 839         (beginning-of-line)
 840         (looking-at "\\s-*\\($\\|\\s<\\)"))
 841       ()
 842     (while (or (condition-case nil
 843                    (progn
 844                      (up-list 1)
 845                      (end-of-line)
 846                      t)
 847                  (error nil))
 848                (and (save-excursion
 849                       (beginning-of-line)
 850                       (or (looking-at "\\s-*\\($\\|\\s<\\)")
 851                           (looking-at octave-continuation-regexp)))
 852                     (zerop (forward-line 1)))))
 853     (end-of-line)))
 854
 855 (defun octave-scan-blocks (from count depth)
 856   "Scan from character number FROM by COUNT Octave begin-end blocks.
 857 Returns the character number of the position thus found.
 858
 859 If DEPTH is nonzero, block depth begins counting from that value.
 860 Only places where the depth in blocks becomes zero are candidates for
 861 stopping; COUNT such places are counted.
 862
 863 If the beginning or end of the buffer is reached and the depth is wrong,
 864 an error is signaled."
 865   (let ((min-depth (if (> depth 0) 0 depth))
 866         (inc (if (> count 0) 1 -1)))
 867     (save-excursion
 868       (while (/= count 0)
 869         (catch 'foo
 870           (while (or (re-search-forward
 871                       octave-block-begin-or-end-regexp nil 'move inc)
 872                      (if (/= depth 0)
 873                          (error "Unbalanced block")))
 874             (if (octave-not-in-string-or-comment-p)
 875                 (progn
 876                   (cond
 877                    ((match-end 1)
 878                     (setq depth (+ depth inc)))
 879                    ((match-end 2)
 880                     (setq depth (- depth inc))))
 881                   (if (< depth min-depth)
 882                       (error "Containing expression ends prematurely"))
 883                   (if (= depth 0)
 884                       (throw 'foo nil))))))
 885         (setq count (- count inc)))
 886       (point))))
 887
 888 (defun octave-forward-block (&optional arg)
 889   "Move forward across one balanced Octave begin-end block.
 890 With argument, do it that many times.
 891 Negative arg -N means move backward across N blocks."
 892   (interactive "p")
 893   (or arg (setq arg 1))
 894   (goto-char (or (octave-scan-blocks (point) arg 0) (buffer-end arg))))
 895
 896 (defun octave-backward-block (&optional arg)
 897   "Move backward across one balanced Octave begin-end block.
 898 With argument, do it that many times.
 899 Negative arg -N means move forward across N blocks."
 900   (interactive "p")
 901   (or arg (setq arg 1))
 902   (octave-forward-block (- arg)))
 903
 904 (defun octave-down-block (arg)
 905   "Move forward down one begin-end block level of Octave code.
 906 With argument, do this that many times.
 907 A negative argument means move backward but still go down a level.
 908 In Lisp programs, an argument is required."
 909   (interactive "p")
 910   (let ((inc (if (> arg 0) 1 -1)))
 911     (while (/= arg 0)
 912       (goto-char (or (octave-scan-blocks (point) inc -1)
 913                      (buffer-end arg)))
 914       (setq arg (- arg inc)))))
 915
 916 (defun octave-backward-up-block (arg)
 917   "Move backward out of one begin-end block level of Octave code.
 918 With argument, do this that many times.
 919 A negative argument means move forward but still to a less deep spot.
 920 In Lisp programs, an argument is required."
 921   (interactive "p")
 922   (octave-up-block (- arg)))
 923
 924 (defun octave-up-block (arg)
 925   "Move forward out of one begin-end block level of Octave code.
 926 With argument, do this that many times.
 927 A negative argument means move backward but still to a less deep spot.
 928 In Lisp programs, an argument is required."
 929   (interactive "p")
 930   (let ((inc (if (> arg 0) 1 -1)))
 931     (while (/= arg 0)
 932       (goto-char (or (octave-scan-blocks (point) inc 1)
 933                      (buffer-end arg)))
 934       (setq arg (- arg inc)))))
 935
 936 (defun octave-mark-block ()
 937   "Put point at the beginning of this Octave block, mark at the end.
 938 The block marked is the one that contains point or follows point."
 939   (interactive)
 940   (let ((pos (point)))
 941     (if (or (and (octave-in-block-p)
 942                  (skip-syntax-forward "w"))
 943             (condition-case nil
 944                 (progn
 945                   (octave-down-block 1)
 946                   (octave-in-block-p))
 947               (error nil)))
 948         (progn
 949           (octave-up-block -1)
 950           (push-mark (point))
 951           (octave-forward-block)
 952           (exchange-point-and-mark))
 953       (goto-char pos)
 954       (message "No block to mark found"))))
 955
 956 (defun octave-close-block ()
 957   "Close the current Octave block on a separate line.
 958 An error is signaled if no block to close is found."
 959   (interactive)
 960   (let (bb-keyword)
 961     (condition-case nil
 962         (progn
 963           (save-excursion
 964             (octave-backward-up-block 1)
 965             (setq bb-keyword (buffer-substring-no-properties
 966                               (match-beginning 1) (match-end 1))))
 967           (if (save-excursion
 968                 (beginning-of-line)
 969                 (looking-at "^\\s-*$"))
 970               (indent-according-to-mode)
 971             (octave-reindent-then-newline-and-indent))
 972           (insert (car (reverse
 973                         (assoc bb-keyword
 974                                octave-block-match-alist))))
 975           (octave-reindent-then-newline-and-indent)
 976           t)
 977       (error (message "No block to close found")))))
 978
 979 (defun octave-blink-matching-block-open ()
 980   "Blink the matching Octave begin block keyword.
 981 If point is right after an Octave else or end type block keyword, move
 982 cursor momentarily to the corresponding begin keyword.
 983 Signal an error if the keywords are incompatible."
 984   (interactive)
 985   (let (bb-keyword bb-arg eb-keyword pos eol)
 986     (if (and (octave-not-in-string-or-comment-p)
 987              (looking-at "\\>")
 988              (save-excursion
 989                (skip-syntax-backward "w")
 990                (looking-at octave-block-else-or-end-regexp)))
 991         (save-excursion
 992           (cond
 993            ((match-end 1)
 994             (setq eb-keyword
 995                   (buffer-substring-no-properties
 996                    (match-beginning 1) (match-end 1)))
 997             (octave-backward-up-block 1))
 998            ((match-end 2)
 999             (setq eb-keyword
1000                   (buffer-substring-no-properties
1001                    (match-beginning 2) (match-end 2)))
1002             (octave-backward-block)))
1003           (setq pos (match-end 0)
1004                 bb-keyword
1005                 (buffer-substring-no-properties
1006                  (match-beginning 0) pos)
1007                 pos (+ pos 1)
1008                 eol (line-end-position)
1009                 bb-arg
1010                 (save-excursion
1011                   (save-restriction
1012                     (goto-char pos)
1013                     (while (and (skip-syntax-forward "^<" eol)
1014                                 (octave-in-string-p)
1015                                 (not (forward-char 1))))
1016                     (skip-syntax-backward " ")
1017                     (buffer-substring-no-properties pos (point)))))
1018           (if (member eb-keyword
1019                       (cdr (assoc bb-keyword octave-block-match-alist)))
1020               (progn
1021                 (message "Matches `%s %s'" bb-keyword bb-arg)
1022                 (if (pos-visible-in-window-p)
1023                     (sit-for blink-matching-delay)))
1024             (error "Block keywords `%s' and `%s' do not match"
1025                    bb-keyword eb-keyword))))))
1026
1027 (defun octave-beginning-of-defun (&optional arg)
1028   "Move backward to the beginning of an Octave function.
1029 With positive ARG, do it that many times.  Negative argument -N means
1030 move forward to Nth following beginning of a function.
1031 Returns t unless search stops at the beginning or end of the buffer."
1032   (interactive "p")
1033   (let* ((arg (or arg 1))
1034          (inc (if (> arg 0) 1 -1))
1035          (found))
1036     (and (not (eobp))
1037          (not (and (> arg 0) (looking-at "\\<function\\>")))
1038          (skip-syntax-forward "w"))
1039     (while (and (/= arg 0)
1040                 (setq found
1041                       (re-search-backward "\\<function\\>" nil 'move inc)))
1042       (if (octave-not-in-string-or-comment-p)
1043           (setq arg (- arg inc))))
1044     (if found
1045         (progn
1046           (and (< inc 0) (goto-char (match-beginning 0)))
1047           t))))
1048
1049 (defun octave-end-of-defun (&optional arg)
1050   "Move forward to the end of an Octave function.
1051 With positive ARG, do it that many times.  Negative argument -N means
1052 move back to Nth preceding end of a function.
1053
1054 An end of a function occurs right after the end keyword matching the
1055 `function' keyword that starts the function."
1056   (interactive "p")
1057   (or arg (setq arg 1))
1058   (and (< arg 0) (skip-syntax-backward "w"))
1059   (and (> arg 0) (skip-syntax-forward "w"))
1060   (if (octave-in-defun-p)
1061       (setq arg (- arg 1)))
1062   (if (= arg 0) (setq arg -1))
1063   (if (octave-beginning-of-defun (- arg))
1064       (octave-forward-block)))
1065
1066 (defun octave-mark-defun ()
1067   "Put point at the beginning of this Octave function, mark at its end.
1068 The function marked is the one containing point or following point."
1069   (interactive)
1070   (let ((pos (point)))
1071     (if (or (octave-in-defun-p)
1072             (and (octave-beginning-of-defun -1)
1073                  (octave-in-defun-p)))
1074         (progn
1075           (skip-syntax-forward "w")
1076           (octave-beginning-of-defun)
1077           (push-mark (point))
1078           (octave-end-of-defun)
1079           (exchange-point-and-mark))
1080       (goto-char pos)
1081       (message "No function to mark found"))))
1082
1083 \f
1084 ;;; Filling
1085 (defun octave-auto-fill ()
1086   "Perform auto-fill in Octave mode.
1087 Returns nil if no feasible place to break the line could be found, and t
1088 otherwise."
1089   (let (fc give-up)
1090     (if (or (null (setq fc (current-fill-column)))
1091             (save-excursion
1092               (beginning-of-line)
1093               (and auto-fill-inhibit-regexp
1094                    (looking-at auto-fill-inhibit-regexp))))
1095         nil                             ; Can't do anything
1096       (if (and (not (octave-in-comment-p))
1097                (> (current-column) fc))
1098           (setq fc (- fc (+ (length octave-continuation-string) 1))))
1099       (while (and (not give-up) (> (current-column) fc))
1100         (let* ((opoint (point))
1101                (fpoint
1102                 (save-excursion
1103                   (move-to-column (+ fc 1))
1104                   (skip-chars-backward "^ \t\n")
1105                   ;; If we're at the beginning of the line, break after
1106                   ;; the first word
1107                   (if (bolp)
1108                       (re-search-forward "[ \t]" opoint t))
1109                   ;; If we're in a comment line, don't break after the
1110                   ;; comment chars
1111                   (if (save-excursion
1112                         (skip-syntax-backward " <")
1113                         (bolp))
1114                       (re-search-forward "[ \t]" (line-end-position)
1115                                          'move))
1116                   ;; If we're not in a comment line and just ahead the
1117                   ;; continuation string, don't break here.
1118                   (if (and (not (octave-in-comment-p))
1119                            (looking-at
1120                             (concat "\\s-*"
1121                                     (regexp-quote
1122                                      octave-continuation-string)
1123                                     "\\s-*$")))
1124                       (end-of-line))
1125                   (skip-chars-backward " \t")
1126                   (point))))
1127           (if (save-excursion
1128                 (goto-char fpoint)
1129                 (not (or (bolp) (eolp))))
1130               (let ((prev-column (current-column)))
1131                 (if (save-excursion
1132                       (skip-chars-backward " \t")
1133                       (= (point) fpoint))
1134                     (progn
1135                       (octave-maybe-insert-continuation-string)
1136                       (indent-new-comment-line t))
1137                   (save-excursion
1138                     (goto-char fpoint)
1139                     (octave-maybe-insert-continuation-string)
1140                     (indent-new-comment-line t)))
1141                 (if (>= (current-column) prev-column)
1142                     (setq give-up t)))
1143             (setq give-up t))))
1144       (not give-up))))
1145
1146 (defun octave-fill-paragraph (&optional arg)
1147  "Fill paragraph of Octave code, handling Octave comments."
1148  (interactive "P")
1149  (save-excursion
1150    (let ((end (progn (forward-paragraph) (point)))
1151          (beg (progn
1152                 (forward-paragraph -1)
1153                 (skip-chars-forward " \t\n")
1154                 (beginning-of-line)
1155                 (point)))
1156          (cfc (current-fill-column))
1157          (ind (calculate-octave-indent))
1158          comment-prefix)
1159      (save-restriction
1160        (goto-char beg)
1161        (narrow-to-region beg end)
1162        (if (listp ind) (setq ind (nth 1 ind)))
1163        (while (not (eobp))
1164          (condition-case nil
1165              (octave-indent-line ind)
1166            (error nil))
1167          (if (and (> ind 0)
1168                   (not
1169                    (save-excursion
1170                      (beginning-of-line)
1171                      (looking-at "^\\s-*\\($\\|\\s<+\\)"))))
1172              (setq ind 0))
1173          (move-to-column cfc)
1174          ;; First check whether we need to combine non-empty comment lines
1175          (if (and (< (current-column) cfc)
1176                   (octave-in-comment-p)
1177                   (not (save-excursion
1178                          (beginning-of-line)
1179                          (looking-at "^\\s-*\\s<+\\s-*$"))))
1180              ;; This is a nonempty comment line which does not extend
1181              ;; past the fill column.  If it is followed by a nonempty
1182              ;; comment line with the same comment prefix, try to
1183              ;; combine them, and repeat this until either we reach the
1184              ;; fill-column or there is nothing more to combine.
1185              (progn
1186                ;; Get the comment prefix
1187                (save-excursion
1188                  (beginning-of-line)
1189                  (while (and (re-search-forward "\\s<+")
1190                              (not (octave-in-comment-p))))
1191                  (setq comment-prefix (match-string 0)))
1192                ;; And keep combining ...
1193                (while (and (< (current-column) cfc)
1194                            (save-excursion
1195                              (forward-line 1)
1196                              (and (looking-at
1197                                    (concat "^\\s-*"
1198                                            comment-prefix
1199                                            "\\S<"))
1200                                   (not (looking-at
1201                                         (concat "^\\s-*"
1202                                                 comment-prefix
1203                                                 "\\s-*$"))))))
1204                  (delete-char 1)
1205                  (re-search-forward comment-prefix)
1206                  (delete-region (match-beginning 0) (match-end 0))
1207                  (fixup-whitespace)
1208                  (move-to-column cfc))))
1209          ;; We might also try to combine continued code lines>  Perhaps
1210          ;; some other time ...
1211          (skip-chars-forward "^ \t\n")
1212          (delete-horizontal-space)
1213          (if (or (< (current-column) cfc)
1214                  (and (= (current-column) cfc) (eolp)))
1215              (forward-line 1)
1216            (if (not (eolp)) (insert " "))
1217            (or (octave-auto-fill)
1218                (forward-line 1)))))
1219      t)))
1220
1221 \f
1222 ;;; Completions
1223 (defun octave-initialize-completions ()
1224   "Create an alist for Octave completions."
1225   (if octave-completion-alist
1226       ()
1227     (setq octave-completion-alist
1228           (mapcar '(lambda (var) (cons var var))
1229                   (append octave-reserved-words
1230                           octave-text-functions
1231                           octave-variables)))))
1232
1233 (defun octave-complete-symbol ()
1234   "Perform completion on Octave symbol preceding point.
1235 Compare that symbol against Octave's reserved words and builtin
1236 variables."
1237   ;; This code taken from lisp-complete-symbol
1238   (interactive)
1239   (let* ((end (point))
1240          (beg (save-excursion (backward-sexp 1) (point)))
1241          (string (buffer-substring-no-properties beg end))
1242          (completion (try-completion string octave-completion-alist)))
1243     (cond ((eq completion t))           ; ???
1244           ((null completion)
1245            (message "Can't find completion for \"%s\"" string)
1246            (ding))
1247           ((not (string= string completion))
1248            (delete-region beg end)
1249            (insert completion))
1250           (t
1251            (let ((list (all-completions string octave-completion-alist))
1252                  (conf (current-window-configuration)))
1253              ;; Taken from comint.el
1254              (message "Making completion list...")
1255              (with-output-to-temp-buffer "*Completions*"
1256                (display-completion-list list string))
1257              (message "Hit space to flush")
1258              (let (key first)
1259                (if (save-excursion
1260                      (set-buffer (get-buffer "*Completions*"))
1261                      (setq key (read-key-sequence nil)
1262                            first (aref key 0))
1263                      (and (consp first) (consp (event-start first))
1264                           (eq (window-buffer (posn-window (event-start
1265                                                            first)))
1266                               (get-buffer "*Completions*"))
1267                           (eq (key-binding key) 'mouse-choose-completion)))
1268                    (progn
1269                      (mouse-choose-completion first)
1270                      (set-window-configuration conf))
1271                  (if (eq first ?\ )
1272                      (set-window-configuration conf)
1273                    (setq unread-command-events
1274                          (listify-key-sequence key))))))))))
1275
1276 \f
1277 ;;; Electric characters && friends
1278 (defun octave-reindent-then-newline-and-indent ()
1279   "Reindent current Octave line, insert newline, and indent the new line.
1280 If Abbrev mode is on, expand abbrevs first."
1281   (interactive)
1282   (if abbrev-mode (expand-abbrev))
1283   (if octave-blink-matching-block
1284       (octave-blink-matching-block-open))
1285   (save-excursion
1286     (delete-region (point) (progn (skip-chars-backward " \t") (point)))
1287     (indent-according-to-mode))
1288   (insert "\n")
1289   (indent-according-to-mode))
1290
1291 (defun octave-electric-semi ()
1292   "Insert a semicolon in Octave mode.
1293 Maybe expand abbrevs and blink matching block open keywords.
1294 Reindent the line of `octave-auto-indent' is non-nil.
1295 Insert a newline if `octave-auto-newline' is non-nil."
1296   (interactive)
1297   (if (not (octave-not-in-string-or-comment-p))
1298       (insert ";")
1299     (if abbrev-mode (expand-abbrev))
1300     (if octave-blink-matching-block
1301         (octave-blink-matching-block-open))
1302     (if octave-auto-indent
1303         (indent-according-to-mode))
1304     (insert ";")
1305     (if octave-auto-newline
1306         (newline-and-indent))))
1307
1308 (defun octave-electric-space ()
1309   "Insert a space in Octave mode.
1310 Maybe expand abbrevs and blink matching block open keywords.
1311 Reindent the line of `octave-auto-indent' is non-nil."
1312   (interactive)
1313   (setq last-command-char ? )
1314   (if (not (octave-not-in-string-or-comment-p))
1315       (progn
1316         (indent-according-to-mode)
1317         (self-insert-command 1))
1318     (if abbrev-mode (expand-abbrev))
1319     (if octave-blink-matching-block
1320         (octave-blink-matching-block-open))
1321     (if (and octave-auto-indent
1322              (save-excursion
1323                (skip-syntax-backward " ")
1324                (not (bolp))))
1325         (indent-according-to-mode))
1326     (self-insert-command 1)))
1327
1328 (defun octave-abbrev-start ()
1329   "Start entering an Octave abbreviation.
1330 If Abbrev mode is turned on, typing ` (grave accent) followed by ? or
1331 \\[help-command] lists all Octave abbrevs.  Any other key combination is
1332 executed normally.
1333 Note that all Octave mode abbrevs start with a grave accent."
1334   (interactive)
1335   (if (not abbrev-mode)
1336       (self-insert-command 1)
1337     (let (c)
1338       (insert last-command-char)
1339       (if (if octave-xemacs-p
1340               (or (eq (event-to-character (setq c (next-event))) ??)
1341                   (eq (event-to-character c) help-char))
1342             (or (eq (setq c (read-event)) ??)
1343                 (eq c help-char)))
1344           (let ((abbrev-table-name-list '(octave-abbrev-table)))
1345             (list-abbrevs))
1346         (setq unread-command-events (list c))))))
1347
1348 (defun octave-insert-defun (name args vals)
1349   "Insert an Octave function skeleton.
1350 Prompt for the function's name, arguments and return values (to be
1351 entered without parens)."
1352   (interactive
1353    (list
1354     (read-from-minibuffer "Function name: "
1355                           (substring (buffer-name) 0 -2))
1356     (read-from-minibuffer "Arguments: ")
1357     (read-from-minibuffer "Return values: ")))
1358   (let ((string (format "%s %s (%s)"
1359                         (cond
1360                          ((string-equal vals "")
1361                           vals)
1362                          ((string-match "[ ,]" vals)
1363                           (concat " [" vals "] ="))
1364                          (t
1365                           (concat " " vals " =")))
1366                         name
1367                         args))
1368         (prefix octave-block-comment-start))
1369     (if (not (bobp)) (newline))
1370     (insert "function" string)
1371     (indent-according-to-mode)
1372     (newline 2)
1373     (insert prefix "usage: " string)
1374     (reindent-then-newline-and-indent)
1375     (insert prefix)
1376     (reindent-then-newline-and-indent)
1377     (insert prefix)
1378     (indent-according-to-mode)
1379     (save-excursion
1380       (newline 2)
1381       (insert "endfunction")
1382       (indent-according-to-mode))))
1383
1384 \f
1385 ;;; Menu
1386 (defun octave-add-octave-menu ()
1387   "Adds the `Octave' menu to the menu bar in Octave mode."
1388   (require 'easymenu)
1389   (easy-menu-define octave-mode-menu-map octave-mode-map
1390                     "Menu keymap for Octave mode." octave-mode-menu)
1391   (easy-menu-add octave-mode-menu-map octave-mode-map))
1392
1393 \f
1394 ;;; Communication with the inferior Octave process
1395 (defun octave-kill-process ()
1396   "Kill inferior Octave process and its buffer."
1397   (interactive)
1398   (if inferior-octave-process
1399       (progn
1400         (process-send-string inferior-octave-process "quit;\n")
1401         (accept-process-output inferior-octave-process)))
1402   (if inferior-octave-buffer
1403       (kill-buffer inferior-octave-buffer)))
1404
1405 (defun octave-show-process-buffer ()
1406   "Make sure that `inferior-octave-buffer' is displayed."
1407   (interactive)
1408   (if (get-buffer inferior-octave-buffer)
1409       (display-buffer inferior-octave-buffer)
1410     (message "No buffer named %s" inferior-octave-buffer)))
1411
1412 (defun octave-hide-process-buffer ()
1413   "Delete all windows that display `inferior-octave-buffer'."
1414   (interactive)
1415   (if (get-buffer inferior-octave-buffer)
1416       (delete-windows-on inferior-octave-buffer)
1417     (message "No buffer named %s" inferior-octave-buffer)))
1418
1419 (defun octave-send-region (beg end)
1420   "Send current region to the inferior Octave process."
1421   (interactive "r")
1422   (inferior-octave t)
1423   (let ((proc inferior-octave-process)
1424         (string (buffer-substring-no-properties beg end))
1425         line)
1426     (save-excursion
1427       (set-buffer inferior-octave-buffer)
1428       (setq inferior-octave-output-list nil)
1429       (while (not (string-equal string ""))
1430         (if (string-match "\n" string)
1431             (setq line (substring string 0 (match-beginning 0))
1432                   string (substring string (match-end 0)))
1433           (setq line string string ""))
1434         (setq inferior-octave-receive-in-progress t)
1435         (inferior-octave-send-list-and-digest (list (concat line "\n")))
1436         (while inferior-octave-receive-in-progress
1437           (accept-process-output proc))
1438         (insert-before-markers
1439          (mapconcat 'identity
1440                     (append
1441                      (if octave-send-echo-input (list line) (list ""))
1442                      (mapcar 'inferior-octave-strip-ctrl-g
1443                              inferior-octave-output-list)
1444                      (list inferior-octave-output-string))
1445                     "\n")))))
1446   (if octave-send-show-buffer
1447       (display-buffer inferior-octave-buffer)))
1448
1449 (defun octave-send-block ()
1450   "Send current Octave block to the inferior Octave process."
1451   (interactive)
1452   (save-excursion
1453     (octave-mark-block)
1454     (octave-send-region (point) (mark))))
1455
1456 (defun octave-send-defun ()
1457   "Send current Octave function to the inferior Octave process."
1458   (interactive)
1459   (save-excursion
1460     (octave-mark-defun)
1461     (octave-send-region (point) (mark))))
1462
1463 (defun octave-send-line (&optional arg)
1464   "Send current Octave code line to the inferior Octave process.
1465 With positive prefix ARG, send that many lines.
1466 If `octave-send-line-auto-forward' is non-nil, go to the next unsent
1467 code line."
1468   (interactive "P")
1469   (or arg (setq arg 1))
1470   (if (> arg 0)
1471       (let (beg end)
1472         (beginning-of-line)
1473         (setq beg (point))
1474         (octave-next-code-line (- arg 1))
1475         (end-of-line)
1476         (setq end (point))
1477         (if octave-send-line-auto-forward
1478             (octave-next-code-line 1))
1479         (octave-send-region beg end))))
1480
1481 (defun octave-eval-print-last-sexp ()
1482   "Evaluate Octave sexp before point and print value into current buffer."
1483   (interactive)
1484   (inferior-octave t)
1485   (let ((standard-output (current-buffer))
1486         (print-escape-newlines nil)
1487         (opoint (point)))
1488     (terpri)
1489     (prin1
1490      (save-excursion
1491        (forward-sexp -1)
1492        (inferior-octave-send-list-and-digest
1493         (list (concat (buffer-substring-no-properties (point) opoint)
1494                       "\n")))
1495        (mapconcat 'identity inferior-octave-output-list "\n")))
1496     (terpri)))
1497 \f
1498 ;;; Bug reporting
1499 (defun octave-submit-bug-report ()
1500   "Submit a bug report on the Emacs Octave package via mail."
1501   (interactive)
1502   (require 'reporter)
1503   (and
1504    (y-or-n-p "Do you want to submit a bug report? ")
1505    (reporter-submit-bug-report
1506     octave-maintainer-address
1507     (concat "Emacs version " emacs-version)
1508     (list
1509      'octave-auto-indent
1510      'octave-auto-newline
1511      'octave-blink-matching-block
1512      'octave-block-offset
1513      'octave-comment-char
1514      'octave-continuation-offset
1515      'octave-continuation-string
1516      'octave-help-files
1517      'octave-mode-startup-message
1518      'octave-send-echo-input
1519      'octave-send-line-auto-forward
1520      'octave-send-show-buffer))))
1521
1522 ;;; provide ourself
1523
1524 (provide 'octave-mod)
1525
1526 ;;; arch-tag: 05f1ce09-be87-4c00-803e-4919ffa26c23
1527 ;;; octave-mod.el ends here