code.delx.au - gnu-emacs/blob - lisp/help-fns.el

   1 ;;; help-fns.el --- Complex help functions
   2
   3 ;; Copyright (C) 1985-1986, 1993-1994, 1998-2011
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; Maintainer: FSF
   7 ;; Keywords: help, internal
   8 ;; Package: emacs
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software: you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation, either version 3 of the License, or
  15 ;; (at your option) any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains those help commands which are complicated, and
  28 ;; which may not be used in every session.  For example
  29 ;; `describe-function' will probably be heavily used when doing elisp
  30 ;; programming, but not if just editing C files.  Simpler help commands
  31 ;; are in help.el
  32
  33 ;;; Code:
  34
  35 ;; Functions
  36
  37 ;;;###autoload
  38 (defun describe-function (function)
  39   "Display the full documentation of FUNCTION (a symbol)."
  40   (interactive
  41    (let ((fn (function-called-at-point))
  42          (enable-recursive-minibuffers t)
  43          val)
  44      (setq val (completing-read (if fn
  45                                     (format "Describe function (default %s): " fn)
  46                                   "Describe function: ")
  47                                 obarray 'fboundp t nil nil
  48                                 (and fn (symbol-name fn))))
  49      (list (if (equal val "")
  50                fn (intern val)))))
  51   (if (null function)
  52       (message "You didn't specify a function")
  53     (help-setup-xref (list #'describe-function function)
  54                      (called-interactively-p 'interactive))
  55     (save-excursion
  56       (with-help-window (help-buffer)
  57         (prin1 function)
  58         ;; Use " is " instead of a colon so that
  59         ;; it is easier to get out the function name using forward-sexp.
  60         (princ " is ")
  61         (describe-function-1 function)
  62         (with-current-buffer standard-output
  63           ;; Return the text we displayed.
  64           (buffer-string))))))
  65
  66 (defun help-split-fundoc (docstring def)
  67   "Split a function DOCSTRING into the actual doc and the usage info.
  68 Return (USAGE . DOC) or nil if there's no usage info.
  69 DEF is the function whose usage we're looking for in DOCSTRING."
  70   ;; Functions can get the calling sequence at the end of the doc string.
  71   ;; In cases where `function' has been fset to a subr we can't search for
  72   ;; function's name in the doc string so we use `fn' as the anonymous
  73   ;; function name instead.
  74   (when (and docstring (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring))
  75     (cons (format "(%s%s"
  76                   ;; Replace `fn' with the actual function name.
  77                   (if (consp def) "anonymous" def)
  78                   (match-string 1 docstring))
  79           (substring docstring 0 (match-beginning 0)))))
  80
  81 (defun help-add-fundoc-usage (docstring arglist)
  82   "Add the usage info to DOCSTRING.
  83 If DOCSTRING already has a usage info, then just return it unchanged.
  84 The usage info is built from ARGLIST.  DOCSTRING can be nil.
  85 ARGLIST can also be t or a string of the form \"(FUN ARG1 ARG2 ...)\"."
  86   (unless (stringp docstring) (setq docstring "Not documented"))
  87   (if (or (string-match "\n\n(fn\\(\\( .*\\)?)\\)\\'" docstring) (eq arglist t))
  88       docstring
  89     (concat docstring
  90             (if (string-match "\n?\n\\'" docstring)
  91                 (if (< (- (match-end 0) (match-beginning 0)) 2) "\n" "")
  92               "\n\n")
  93             (if (and (stringp arglist)
  94                      (string-match "\\`([^ ]+\\(.*\\))\\'" arglist))
  95                 (concat "(fn" (match-string 1 arglist) ")")
  96               (format "%S" (help-make-usage 'fn arglist))))))
  97
  98 (defun help-function-arglist (def)
  99   ;; Handle symbols aliased to other symbols.
 100   (if (and (symbolp def) (fboundp def)) (setq def (indirect-function def)))
 101   ;; If definition is a macro, find the function inside it.
 102   (if (eq (car-safe def) 'macro) (setq def (cdr def)))
 103   ;; and do the same for interpreted closures
 104   (if (eq (car-safe def) 'closure) (setq def (cddr def)))
 105   (cond
 106    ((byte-code-function-p def) (aref def 0))
 107    ((eq (car-safe def) 'lambda) (nth 1 def))
 108    ((and (eq (car-safe def) 'autoload) (not (eq (nth 4 def) 'keymap)))
 109     "[Arg list not available until function definition is loaded.]")
 110    (t t)))
 111
 112 (defun help-make-usage (function arglist)
 113   (cons (if (symbolp function) function 'anonymous)
 114         (mapcar (lambda (arg)
 115                   (if (not (symbolp arg))
 116                       (if (and (consp arg) (symbolp (car arg)))
 117                           ;; CL style default values for optional args.
 118                           (cons (intern (upcase (symbol-name (car arg))))
 119                                 (cdr arg))
 120                         arg)
 121                     (let ((name (symbol-name arg)))
 122                       (if (string-match "\\`&" name) arg
 123                         (intern (upcase name))))))
 124                 arglist)))
 125
 126 ;; Could be this, if we make symbol-file do the work below.
 127 ;; (defun help-C-file-name (subr-or-var kind)
 128 ;;   "Return the name of the C file where SUBR-OR-VAR is defined.
 129 ;; KIND should be `var' for a variable or `subr' for a subroutine."
 130 ;;   (symbol-file (if (symbolp subr-or-var) subr-or-var
 131 ;;               (subr-name subr-or-var))
 132 ;;             (if (eq kind 'var) 'defvar 'defun)))
 133 ;;;###autoload
 134 (defun help-C-file-name (subr-or-var kind)
 135   "Return the name of the C file where SUBR-OR-VAR is defined.
 136 KIND should be `var' for a variable or `subr' for a subroutine."
 137   (let ((docbuf (get-buffer-create " *DOC*"))
 138         (name (if (eq 'var kind)
 139                   (concat "V" (symbol-name subr-or-var))
 140                 (concat "F" (subr-name subr-or-var)))))
 141     (with-current-buffer docbuf
 142       (goto-char (point-min))
 143       (if (eobp)
 144           (insert-file-contents-literally
 145            (expand-file-name internal-doc-file-name doc-directory)))
 146       (let ((file (catch 'loop
 147                     (while t
 148                       (let ((pnt (search-forward (concat "\1f" name "\n"))))
 149                         (re-search-backward "\1fS\\(.*\\)")
 150                         (let ((file (match-string 1)))
 151                           (if (member file build-files)
 152                               (throw 'loop file)
 153                             (goto-char pnt))))))))
 154         (if (string-match "^ns.*\\(\\.o\\|obj\\)\\'" file)
 155             (setq file (replace-match ".m" t t file 1))
 156           (if (string-match "\\.\\(o\\|obj\\)\\'" file)
 157               (setq file (replace-match ".c" t t file))))
 158         (if (string-match "\\.\\(c\\|m\\)\\'" file)
 159             (concat "src/" file)
 160           file)))))
 161
 162 (defcustom help-downcase-arguments nil
 163   "If non-nil, argument names in *Help* buffers are downcased."
 164   :type 'boolean
 165   :group 'help
 166   :version "23.2")
 167
 168 (defun help-highlight-arg (arg)
 169   "Highlight ARG as an argument name for a *Help* buffer.
 170 Return ARG in face `help-argument-name'; ARG is also downcased
 171 if the variable `help-downcase-arguments' is non-nil."
 172   (propertize (if help-downcase-arguments (downcase arg) arg)
 173               'face 'help-argument-name))
 174
 175 (defun help-do-arg-highlight (doc args)
 176   (with-syntax-table (make-syntax-table emacs-lisp-mode-syntax-table)
 177     (modify-syntax-entry ?\- "w")
 178     (dolist (arg args doc)
 179       (setq doc (replace-regexp-in-string
 180                  ;; This is heuristic, but covers all common cases
 181                  ;; except ARG1-ARG2
 182                  (concat "\\<"                   ; beginning of word
 183                          "\\(?:[a-z-]*-\\)?"     ; for xxx-ARG
 184                          "\\("
 185                          (regexp-quote arg)
 186                          "\\)"
 187                          "\\(?:es\\|s\\|th\\)?"  ; for ARGth, ARGs
 188                          "\\(?:-[a-z0-9-]+\\)?"  ; for ARG-xxx, ARG-n
 189                          "\\(?:-[{([<`\"].*?\\)?"; for ARG-{x}, (x), <x>, [x], `x'
 190                          "\\>")                  ; end of word
 191                  (help-highlight-arg arg)
 192                  doc t t 1)))))
 193
 194 (defun help-highlight-arguments (usage doc &rest args)
 195   (when (and usage (string-match "^(" usage))
 196     (with-temp-buffer
 197       (insert usage)
 198       (goto-char (point-min))
 199       (let ((case-fold-search nil)
 200             (next (not (or args (looking-at "\\["))))
 201             (opt nil))
 202         ;; Make a list of all arguments
 203         (skip-chars-forward "^ ")
 204         (while next
 205           (or opt (not (looking-at " &")) (setq opt t))
 206           (if (not (re-search-forward " \\([\\[(]*\\)\\([^] &)\.]+\\)" nil t))
 207               (setq next nil)
 208             (setq args (cons (match-string 2) args))
 209             (when (and opt (string= (match-string 1) "("))
 210               ;; A pesky CL-style optional argument with default value,
 211               ;; so let's skip over it
 212               (search-backward "(")
 213               (goto-char (scan-sexps (point) 1)))))
 214         ;; Highlight aguments in the USAGE string
 215         (setq usage (help-do-arg-highlight (buffer-string) args))
 216         ;; Highlight arguments in the DOC string
 217         (setq doc (and doc (help-do-arg-highlight doc args))))))
 218   ;; Return value is like the one from help-split-fundoc, but highlighted
 219   (cons usage doc))
 220
 221 ;; The following function was compiled from the former functions
 222 ;; `describe-simplify-lib-file-name' and `find-source-lisp-file' with
 223 ;; some excerpts from `describe-function-1' and `describe-variable'.
 224 ;; The only additional twists provided are (1) locate the defining file
 225 ;; for autoloaded functions, and (2) give preference to files in the
 226 ;; "install directory" (directories found via `load-path') rather than
 227 ;; to files in the "compile directory" (directories found by searching
 228 ;; the loaddefs.el file).  We autoload it because it's also used by
 229 ;; `describe-face' (instead of `describe-simplify-lib-file-name').
 230
 231 ;;;###autoload
 232 (defun find-lisp-object-file-name (object type)
 233   "Guess the file that defined the Lisp object OBJECT, of type TYPE.
 234 OBJECT should be a symbol associated with a function, variable, or face;
 235   alternatively, it can be a function definition.
 236 If TYPE is `defvar', search for a variable definition.
 237 If TYPE is `defface', search for a face definition.
 238 If TYPE is the value returned by `symbol-function' for a function symbol,
 239  search for a function definition.
 240
 241 The return value is the absolute name of a readable file where OBJECT is
 242 defined.  If several such files exist, preference is given to a file
 243 found via `load-path'.  The return value can also be `C-source', which
 244 means that OBJECT is a function or variable defined in C.  If no
 245 suitable file is found, return nil."
 246   (let* ((autoloaded (eq (car-safe type) 'autoload))
 247          (file-name (or (and autoloaded (nth 1 type))
 248                         (symbol-file
 249                          object (if (memq type (list 'defvar 'defface))
 250                                     type
 251                                   'defun)))))
 252     (cond
 253      (autoloaded
 254       ;; An autoloaded function: Locate the file since `symbol-function'
 255       ;; has only returned a bare string here.
 256       (setq file-name
 257             (locate-file file-name load-path '(".el" ".elc") 'readable)))
 258      ((and (stringp file-name)
 259            (string-match "[.]*loaddefs.el\\'" file-name))
 260       ;; An autoloaded variable or face.  Visit loaddefs.el in a buffer
 261       ;; and try to extract the defining file.  The following form is
 262       ;; from `describe-function-1' and `describe-variable'.
 263       (let ((location
 264              (condition-case nil
 265                  (find-function-search-for-symbol object nil file-name)
 266                (error nil))))
 267         (when (cdr location)
 268           (with-current-buffer (car location)
 269             (goto-char (cdr location))
 270             (when (re-search-backward
 271                    "^;;; Generated autoloads from \\(.*\\)" nil t)
 272               (setq file-name
 273                     (locate-file
 274                      (file-name-sans-extension
 275                       (match-string-no-properties 1))
 276                      load-path '(".el" ".elc") 'readable))))))))
 277
 278     (cond
 279      ((and (not file-name) (subrp type))
 280       ;; A built-in function.  The form is from `describe-function-1'.
 281       (if (get-buffer " *DOC*")
 282           (help-C-file-name type 'subr)
 283         'C-source))
 284      ((and (not file-name) (symbolp object)
 285            (integerp (get object 'variable-documentation)))
 286       ;; A variable defined in C.  The form is from `describe-variable'.
 287       (if (get-buffer " *DOC*")
 288           (help-C-file-name object 'var)
 289         'C-source))
 290      ((not (stringp file-name))
 291       ;; If we don't have a file-name string by now, we lost.
 292       nil)
 293      ;; Now, `file-name' should have become an absolute file name.
 294      ;; For files loaded from ~/.emacs.elc, try ~/.emacs.
 295      ((let (fn)
 296         (and (string-equal file-name
 297                            (expand-file-name ".emacs.elc" "~"))
 298              (file-readable-p (setq fn (expand-file-name ".emacs" "~")))
 299              fn)))
 300      ;; When the Elisp source file can be found in the install
 301      ;; directory, return the name of that file.
 302      ((let ((lib-name
 303              (if (string-match "[.]elc\\'" file-name)
 304                  (substring-no-properties file-name 0 -1)
 305                file-name)))
 306         (or (and (file-readable-p lib-name) lib-name)
 307             ;; The library might be compressed.
 308             (and (file-readable-p (concat lib-name ".gz")) lib-name))))
 309      ((let* ((lib-name (file-name-nondirectory file-name))
 310              ;; The next form is from `describe-simplify-lib-file-name'.
 311              (file-name
 312               ;; Try converting the absolute file name to a library
 313               ;; name, convert that back to a file name and see if we
 314               ;; get the original one.  If so, they are equivalent.
 315               (if (equal file-name (locate-file lib-name load-path '("")))
 316                   (if (string-match "[.]elc\\'" lib-name)
 317                       (substring-no-properties lib-name 0 -1)
 318                     lib-name)
 319                 file-name))
 320              ;; The next three forms are from `find-source-lisp-file'.
 321              (elc-file (locate-file
 322                         (concat file-name
 323                                 (if (string-match "\\.el\\'" file-name)
 324                                     "c"
 325                                   ".elc"))
 326                         load-path nil 'readable))
 327              (str (when elc-file
 328                     (with-temp-buffer
 329                       (insert-file-contents-literally elc-file nil 0 256)
 330                       (buffer-string))))
 331              (src-file (and str
 332                             (string-match ";;; from file \\(.*\\.el\\)" str)
 333                             (match-string 1 str))))
 334         (and src-file (file-readable-p src-file) src-file))))))
 335
 336 (declare-function ad-get-advice-info "advice" (function))
 337
 338 ;;;###autoload
 339 (defun describe-function-1 (function)
 340   (let* ((advised (and (symbolp function) (featurep 'advice)
 341                        (ad-get-advice-info function)))
 342          ;; If the function is advised, use the symbol that has the
 343          ;; real definition, if that symbol is already set up.
 344          (real-function
 345           (or (and advised
 346                    (let ((origname (cdr (assq 'origname advised))))
 347                      (and (fboundp origname) origname)))
 348               function))
 349          ;; Get the real definition.
 350          (def (if (symbolp real-function)
 351                   (symbol-function real-function)
 352                 function))
 353          file-name string
 354          (beg (if (commandp def) "an interactive " "a "))
 355          (pt1 (with-current-buffer (help-buffer) (point)))
 356          errtype)
 357     (setq string
 358           (cond ((or (stringp def) (vectorp def))
 359                  "a keyboard macro")
 360                 ((subrp def)
 361                  (if (eq 'unevalled (cdr (subr-arity def)))
 362                      (concat beg "special form")
 363                    (concat beg "built-in function")))
 364                 ((byte-code-function-p def)
 365                  (concat beg "compiled Lisp function"))
 366                 ((and (funvecp def) (eq (aref def 0) 'curry))
 367                  (if (symbolp (aref def 1))
 368                      (format "a curried function calling `%s'" (aref def 1))
 369                    "a curried function"))
 370                 ((funvecp def)
 371                  (format "a function-vector (funvec) of type `%s'"
 372                          (aref def 0)))
 373                 ((symbolp def)
 374                  (while (and (fboundp def)
 375                              (symbolp (symbol-function def)))
 376                    (setq def (symbol-function def)))
 377                  ;; Handle (defalias 'foo 'bar), where bar is undefined.
 378                  (or (fboundp def) (setq errtype 'alias))
 379                  (format "an alias for `%s'" def))
 380                 ((eq (car-safe def) 'lambda)
 381                  (concat beg "Lisp function"))
 382                 ((eq (car-safe def) 'macro)
 383                  "a Lisp macro")
 384                 ((eq (car-safe def) 'closure)
 385                  (concat beg "Lisp closure"))
 386                 ((eq (car-safe def) 'autoload)
 387                  (format "%s autoloaded %s"
 388                          (if (commandp def) "an interactive" "an")
 389                          (if (eq (nth 4 def) 'keymap) "keymap"
 390                            (if (nth 4 def) "Lisp macro" "Lisp function"))))
 391                 ((keymapp def)
 392                  (let ((is-full nil)
 393                        (elts (cdr-safe def)))
 394                    (while elts
 395                      (if (char-table-p (car-safe elts))
 396                          (setq is-full t
 397                                elts nil))
 398                      (setq elts (cdr-safe elts)))
 399                    (if is-full
 400                        "a full keymap"
 401                      "a sparse keymap")))
 402                 (t "")))
 403     (princ string)
 404     (if (eq errtype 'alias)
 405         (princ ",\nwhich is not defined.  Please make a bug report.")
 406       (with-current-buffer standard-output
 407         (save-excursion
 408           (save-match-data
 409             (when (re-search-backward "alias for `\\([^`']+\\)'" nil t)
 410               (help-xref-button 1 'help-function def)))))
 411
 412       (setq file-name (find-lisp-object-file-name function def))
 413       (when file-name
 414         (princ " in `")
 415         ;; We used to add .el to the file name,
 416         ;; but that's completely wrong when the user used load-file.
 417         (princ (if (eq file-name 'C-source)
 418                    "C source code"
 419                  (file-name-nondirectory file-name)))
 420         (princ "'")
 421         ;; Make a hyperlink to the library.
 422         (with-current-buffer standard-output
 423           (save-excursion
 424             (re-search-backward "`\\([^`']+\\)'" nil t)
 425             (help-xref-button 1 'help-function-def function file-name))))
 426       (princ ".")
 427       (with-current-buffer (help-buffer)
 428         (fill-region-as-paragraph (save-excursion (goto-char pt1) (forward-line 0) (point))
 429                                   (point)))
 430       (terpri)(terpri)
 431       (when (commandp function)
 432         (let ((pt2 (with-current-buffer (help-buffer) (point)))
 433               (remapped (command-remapping function)))
 434           (unless (memq remapped '(ignore undefined))
 435             (let ((keys (where-is-internal
 436                          (or remapped function) overriding-local-map nil nil))
 437                   non-modified-keys)
 438               (if (and (eq function 'self-insert-command)
 439                        (vectorp (car-safe keys))
 440                        (consp (aref (car keys) 0)))
 441                   (princ "It is bound to many ordinary text characters.\n")
 442                 ;; Which non-control non-meta keys run this command?
 443                 (dolist (key keys)
 444                   (if (member (event-modifiers (aref key 0)) '(nil (shift)))
 445                       (push key non-modified-keys)))
 446                 (when remapped
 447                   (princ "It is remapped to `")
 448                   (princ (symbol-name remapped))
 449                   (princ "'"))
 450
 451                 (when keys
 452                   (princ (if remapped ", which is bound to " "It is bound to "))
 453                   ;; If lots of ordinary text characters run this command,
 454                   ;; don't mention them one by one.
 455                   (if (< (length non-modified-keys) 10)
 456                       (princ (mapconcat 'key-description keys ", "))
 457                     (dolist (key non-modified-keys)
 458                       (setq keys (delq key keys)))
 459                     (if keys
 460                         (progn
 461                           (princ (mapconcat 'key-description keys ", "))
 462                           (princ ", and many ordinary text characters"))
 463                       (princ "many ordinary text characters"))))
 464                 (when (or remapped keys non-modified-keys)
 465                   (princ ".")
 466                   (terpri)))))
 467
 468           (with-current-buffer (help-buffer)
 469             (fill-region-as-paragraph pt2 (point))
 470             (unless (looking-back "\n\n")
 471               (terpri)))))
 472       ;; Note that list* etc do not get this property until
 473       ;; cl-hack-byte-compiler runs, after bytecomp is loaded.
 474       (when (and (symbolp function)
 475                  (eq (get function 'byte-compile)
 476                      'cl-byte-compile-compiler-macro))
 477         (princ "This function has a compiler macro")
 478         (let ((lib (get function 'compiler-macro-file)))
 479           (when (stringp lib)
 480             (princ (format " in `%s'" lib))
 481             (with-current-buffer standard-output
 482               (save-excursion
 483                 (re-search-backward "`\\([^`']+\\)'" nil t)
 484                 (help-xref-button 1 'help-function-cmacro function lib)))))
 485         (princ ".\n\n"))
 486       (let* ((advertised (gethash def advertised-signature-table t))
 487              (arglist (if (listp advertised)
 488                           advertised (help-function-arglist def)))
 489              (doc (documentation function))
 490              (usage (help-split-fundoc doc function)))
 491         (with-current-buffer standard-output
 492           ;; If definition is a keymap, skip arglist note.
 493           (unless (keymapp function)
 494             (if usage (setq doc (cdr usage)))
 495             (let* ((use (cond
 496                          ((and usage (not (listp advertised))) (car usage))
 497                          ((listp arglist)
 498                           (format "%S" (help-make-usage function arglist)))
 499                          ((stringp arglist) arglist)
 500                          ;; Maybe the arglist is in the docstring of a symbol
 501                          ;; this one is aliased to.
 502                          ((let ((fun real-function))
 503                             (while (and (symbolp fun)
 504                                         (setq fun (symbol-function fun))
 505                                         (not (setq usage (help-split-fundoc
 506                                                           (documentation fun)
 507                                                           function)))))
 508                             usage)
 509                           (car usage))
 510                          ((or (stringp def)
 511                               (vectorp def))
 512                           (format "\nMacro: %s" (format-kbd-macro def)))
 513                          ((and (funvecp def) (eq (aref def 0) 'curry))
 514                           ;; Describe a curried-function's function and args
 515                           (let ((slot 0))
 516                             (mapconcat (lambda (arg)
 517                                          (setq slot (1+ slot))
 518                                          (cond
 519                                           ((= slot 1) "")
 520                                           ((= slot 2)
 521                                            (format "  Function: %S" arg))
 522                                           (t
 523                                            (format "Argument %d: %S"
 524                                                    (- slot 3) arg))))
 525                                        def
 526                                        "\n")))
 527                          ((funvecp def) nil)
 528                          (t "[Missing arglist.  Please make a bug report.]")))
 529                    (high (help-highlight-arguments use doc)))
 530               (let ((fill-begin (point)))
 531                 (insert (car high) "\n")
 532                 (fill-region fill-begin (point))))
 533             (setq doc (cdr high))))
 534         (let* ((obsolete (and
 535                           ;; function might be a lambda construct.
 536                           (symbolp function)
 537                           (get function 'byte-obsolete-info)))
 538                (use (car obsolete)))
 539           (when obsolete
 540             (princ "\nThis function is obsolete")
 541             (when (nth 2 obsolete)
 542               (insert (format " since %s" (nth 2 obsolete))))
 543             (insert (cond ((stringp use) (concat ";\n" use))
 544                           (use (format ";\nuse `%s' instead." use))
 545                           (t "."))
 546                     "\n"))
 547           (insert "\n"
 548                   (or doc "Not documented.")))))))
 549
 550 \f
 551 ;; Variables
 552
 553 ;;;###autoload
 554 (defun variable-at-point (&optional any-symbol)
 555   "Return the bound variable symbol found at or before point.
 556 Return 0 if there is no such symbol.
 557 If ANY-SYMBOL is non-nil, don't insist the symbol be bound."
 558   (with-syntax-table emacs-lisp-mode-syntax-table
 559     (or (condition-case ()
 560             (save-excursion
 561               (or (not (zerop (skip-syntax-backward "_w")))
 562                   (eq (char-syntax (following-char)) ?w)
 563                   (eq (char-syntax (following-char)) ?_)
 564                   (forward-sexp -1))
 565               (skip-chars-forward "'")
 566               (let ((obj (read (current-buffer))))
 567                 (and (symbolp obj) (boundp obj) obj)))
 568           (error nil))
 569         (let* ((str (find-tag-default))
 570                (sym (if str (intern-soft str))))
 571           (if (and sym (or any-symbol (boundp sym)))
 572               sym
 573             (save-match-data
 574               (when (and str (string-match "\\`\\W*\\(.*?\\)\\W*\\'" str))
 575                 (setq sym (intern-soft (match-string 1 str)))
 576                 (and (or any-symbol (boundp sym)) sym)))))
 577         0)))
 578
 579 (defun describe-variable-custom-version-info (variable)
 580   (let ((custom-version (get variable 'custom-version))
 581         (cpv (get variable 'custom-package-version))
 582         (output nil))
 583     (if custom-version
 584         (setq output
 585               (format "This variable was introduced, or its default value was changed, in\nversion %s of Emacs.\n"
 586                       custom-version))
 587       (when cpv
 588         (let* ((package (car-safe cpv))
 589                (version (if (listp (cdr-safe cpv))
 590                             (car (cdr-safe cpv))
 591                           (cdr-safe cpv)))
 592                (pkg-versions (assq package customize-package-emacs-version-alist))
 593                (emacsv (cdr (assoc version pkg-versions))))
 594           (if (and package version)
 595               (setq output
 596                     (format (concat "This variable was introduced, or its default value was changed, in\nversion %s of the %s package"
 597                                     (if emacsv
 598                                         (format " that is part of Emacs %s" emacsv))
 599                                     ".\n")
 600                             version package))))))
 601     output))
 602
 603 ;;;###autoload
 604 (defun describe-variable (variable &optional buffer frame)
 605   "Display the full documentation of VARIABLE (a symbol).
 606 Returns the documentation as a string, also.
 607 If VARIABLE has a buffer-local value in BUFFER or FRAME
 608 \(default to the current buffer and current frame),
 609 it is displayed along with the global value."
 610   (interactive
 611    (let ((v (variable-at-point))
 612          (enable-recursive-minibuffers t)
 613          val)
 614      (setq val (completing-read (if (symbolp v)
 615                                     (format
 616                                      "Describe variable (default %s): " v)
 617                                   "Describe variable: ")
 618                                 obarray
 619                                 '(lambda (vv)
 620                                    (or (boundp vv)
 621                                        (get vv 'variable-documentation)))
 622                                 t nil nil
 623                                 (if (symbolp v) (symbol-name v))))
 624      (list (if (equal val "")
 625                v (intern val)))))
 626   (let (file-name)
 627     (unless (buffer-live-p buffer) (setq buffer (current-buffer)))
 628     (unless (frame-live-p frame) (setq frame (selected-frame)))
 629     (if (not (symbolp variable))
 630         (message "You did not specify a variable")
 631       (save-excursion
 632         (let ((valvoid (not (with-current-buffer buffer (boundp variable))))
 633               val val-start-pos locus)
 634           ;; Extract the value before setting up the output buffer,
 635           ;; in case `buffer' *is* the output buffer.
 636           (unless valvoid
 637             (with-selected-frame frame
 638               (with-current-buffer buffer
 639                 (setq val (symbol-value variable)
 640                       locus (variable-binding-locus variable)))))
 641           (help-setup-xref (list #'describe-variable variable buffer)
 642                            (called-interactively-p 'interactive))
 643           (with-help-window (help-buffer)
 644             (with-current-buffer buffer
 645               (prin1 variable)
 646               (setq file-name (find-lisp-object-file-name variable 'defvar))
 647
 648               (if file-name
 649                   (progn
 650                     (princ " is a variable defined in `")
 651                     (princ (if (eq file-name 'C-source)
 652                                "C source code"
 653                              (file-name-nondirectory file-name)))
 654                     (princ "'.\n")
 655                     (with-current-buffer standard-output
 656                       (save-excursion
 657                         (re-search-backward "`\\([^`']+\\)'" nil t)
 658                         (help-xref-button 1 'help-variable-def
 659                                           variable file-name)))
 660                     (if valvoid
 661                         (princ "It is void as a variable.")
 662                       (princ "Its ")))
 663                 (if valvoid
 664                     (princ " is void as a variable.")
 665                   (princ "'s "))))
 666             (unless valvoid
 667               (with-current-buffer standard-output
 668                 (setq val-start-pos (point))
 669                 (princ "value is ")
 670                 (let ((from (point)))
 671                   (terpri)
 672                   (pp val)
 673                   (if (< (point) (+ 68 (line-beginning-position 0)))
 674                       (delete-region from (1+ from))
 675                     (delete-region (1- from) from))
 676                   (let* ((sv (get variable 'standard-value))
 677                          (origval (and (consp sv)
 678                                        (condition-case nil
 679                                            (eval (car sv))
 680                                          (error :help-eval-error)))))
 681                     (when (and (consp sv)
 682                                (not (equal origval val))
 683                                (not (equal origval :help-eval-error)))
 684                       (princ "\nOriginal value was \n")
 685                       (setq from (point))
 686                       (pp origval)
 687                       (if (< (point) (+ from 20))
 688                           (delete-region (1- from) from)))))))
 689             (terpri)
 690             (when locus
 691               (if (bufferp locus)
 692                   (princ (format "%socal in buffer %s; "
 693                                  (if (get variable 'permanent-local)
 694                                      "Permanently l" "L")
 695                                  (buffer-name)))
 696                 (princ (format "It is a frame-local variable; ")))
 697               (if (not (default-boundp variable))
 698                   (princ "globally void")
 699                 (let ((val (default-value variable)))
 700                   (with-current-buffer standard-output
 701                     (princ "global value is ")
 702                     (terpri)
 703                     ;; Fixme: pp can take an age if you happen to
 704                     ;; ask for a very large expression.  We should
 705                     ;; probably print it raw once and check it's a
 706                     ;; sensible size before prettyprinting.  -- fx
 707                     (let ((from (point)))
 708                       (pp val)
 709                       ;; See previous comment for this function.
 710                       ;; (help-xref-on-pp from (point))
 711                       (if (< (point) (+ from 20))
 712                           (delete-region (1- from) from))))))
 713               (terpri))
 714
 715             ;; If the value is large, move it to the end.
 716             (with-current-buffer standard-output
 717               (when (> (count-lines (point-min) (point-max)) 10)
 718                 ;; Note that setting the syntax table like below
 719                 ;; makes forward-sexp move over a `'s' at the end
 720                 ;; of a symbol.
 721                 (set-syntax-table emacs-lisp-mode-syntax-table)
 722                 (goto-char val-start-pos)
 723                 ;; The line below previously read as
 724                 ;; (delete-region (point) (progn (end-of-line) (point)))
 725                 ;; which suppressed display of the buffer local value for
 726                 ;; large values.
 727                 (when (looking-at "value is") (replace-match ""))
 728                 (save-excursion
 729                   (insert "\n\nValue:")
 730                   (set (make-local-variable 'help-button-cache)
 731                        (point-marker)))
 732                 (insert "value is shown ")
 733                 (insert-button "below"
 734                                'action help-button-cache
 735                                'follow-link t
 736                                'help-echo "mouse-2, RET: show value")
 737                 (insert ".\n")))
 738             (terpri)
 739
 740             (let* ((alias (condition-case nil
 741                               (indirect-variable variable)
 742                             (error variable)))
 743                    (obsolete (get variable 'byte-obsolete-variable))
 744                    (use (car obsolete))
 745                    (safe-var (get variable 'safe-local-variable))
 746                    (doc (or (documentation-property variable 'variable-documentation)
 747                             (documentation-property alias 'variable-documentation)))
 748                    (extra-line nil))
 749               ;; Add a note for variables that have been make-var-buffer-local.
 750               (when (and (local-variable-if-set-p variable)
 751                          (or (not (local-variable-p variable))
 752                              (with-temp-buffer
 753                                (local-variable-if-set-p variable))))
 754                 (setq extra-line t)
 755                 (princ "  Automatically becomes buffer-local when set in any fashion.\n"))
 756
 757               ;; Mention if it's an alias
 758               (unless (eq alias variable)
 759                 (setq extra-line t)
 760                 (princ (format "  This variable is an alias for `%s'.\n" alias)))
 761
 762               (when obsolete
 763                 (setq extra-line t)
 764                 (princ "  This variable is obsolete")
 765                 (if (cdr obsolete) (princ (format " since %s" (cdr obsolete))))
 766                 (princ (cond ((stringp use) (concat ";\n  " use))
 767                              (use (format ";\n  use `%s' instead." (car obsolete)))
 768                              (t ".")))
 769                 (terpri))
 770
 771               (when (member (cons variable val) file-local-variables-alist)
 772                 (setq extra-line t)
 773                 (if (member (cons variable val) dir-local-variables-alist)
 774                     (let ((file (and (buffer-file-name)
 775                                      (not (file-remote-p (buffer-file-name)))
 776                                      (dir-locals-find-file (buffer-file-name)))))
 777                       (princ "  This variable is a directory local variable")
 778                       (when file
 779                         (princ (concat "\n  from the file \""
 780                                        (if (consp file)
 781                                            (car file)
 782                                          file)
 783                                        "\"")))
 784                       (princ ".\n"))
 785                   (princ "  This variable is a file local variable.\n")))
 786
 787               (when (memq variable ignored-local-variables)
 788                 (setq extra-line t)
 789                 (princ "  This variable is ignored when used as a file local \
 790 variable.\n"))
 791
 792               ;; Can be both risky and safe, eg auto-fill-function.
 793               (when (risky-local-variable-p variable)
 794                 (setq extra-line t)
 795                 (princ "  This variable is potentially risky when used as a \
 796 file local variable.\n")
 797                 (when (assq variable safe-local-variable-values)
 798                   (princ "  However, you have added it to \
 799 `safe-local-variable-values'.\n")))
 800
 801               (when safe-var
 802                 (setq extra-line t)
 803                 (princ "  This variable is safe as a file local variable ")
 804                 (princ "if its value\n  satisfies the predicate ")
 805                 (princ (if (byte-code-function-p safe-var)
 806                            "which is byte-compiled expression.\n"
 807                          (format "`%s'.\n" safe-var))))
 808
 809               (if extra-line (terpri))
 810               (princ "Documentation:\n")
 811               (with-current-buffer standard-output
 812                 (insert (or doc "Not documented as a variable."))))
 813
 814             ;; Make a link to customize if this variable can be customized.
 815             (when (custom-variable-p variable)
 816               (let ((customize-label "customize"))
 817                 (terpri)
 818                 (terpri)
 819                 (princ (concat "You can " customize-label " this variable."))
 820                 (with-current-buffer standard-output
 821                   (save-excursion
 822                     (re-search-backward
 823                      (concat "\\(" customize-label "\\)") nil t)
 824                     (help-xref-button 1 'help-customize-variable variable))))
 825               ;; Note variable's version or package version
 826               (let ((output (describe-variable-custom-version-info variable)))
 827                 (when output
 828                   (terpri)
 829                   (terpri)
 830                   (princ output))))
 831
 832             (with-current-buffer standard-output
 833               ;; Return the text we displayed.
 834               (buffer-string))))))))
 835
 836
 837 ;;;###autoload
 838 (defun describe-syntax (&optional buffer)
 839   "Describe the syntax specifications in the syntax table of BUFFER.
 840 The descriptions are inserted in a help buffer, which is then displayed.
 841 BUFFER defaults to the current buffer."
 842   (interactive)
 843   (setq buffer (or buffer (current-buffer)))
 844   (help-setup-xref (list #'describe-syntax buffer)
 845                    (called-interactively-p 'interactive))
 846   (with-help-window (help-buffer)
 847     (let ((table (with-current-buffer buffer (syntax-table))))
 848       (with-current-buffer standard-output
 849         (describe-vector table 'internal-describe-syntax-value)
 850         (while (setq table (char-table-parent table))
 851           (insert "\nThe parent syntax table is:")
 852           (describe-vector table 'internal-describe-syntax-value))))))
 853
 854 (defun help-describe-category-set (value)
 855   (insert (cond
 856            ((null value) "default")
 857            ((char-table-p value) "deeper char-table ...")
 858            (t (condition-case err
 859                   (category-set-mnemonics value)
 860                 (error "invalid"))))))
 861
 862 ;;;###autoload
 863 (defun describe-categories (&optional buffer)
 864   "Describe the category specifications in the current category table.
 865 The descriptions are inserted in a buffer, which is then displayed.
 866 If BUFFER is non-nil, then describe BUFFER's category table instead.
 867 BUFFER should be a buffer or a buffer name."
 868   (interactive)
 869   (setq buffer (or buffer (current-buffer)))
 870   (help-setup-xref (list #'describe-categories buffer)
 871                    (called-interactively-p 'interactive))
 872   (with-help-window (help-buffer)
 873     (let* ((table (with-current-buffer buffer (category-table)))
 874            (docs (char-table-extra-slot table 0)))
 875       (if (or (not (vectorp docs)) (/= (length docs) 95))
 876           (error "Invalid first extra slot in this category table\n"))
 877       (with-current-buffer standard-output
 878         (insert "Legend of category mnemonics (see the tail for the longer description)\n")
 879         (let ((pos (point)) (items 0) lines n)
 880           (dotimes (i 95)
 881             (if (aref docs i) (setq items (1+ items))))
 882           (setq lines (1+ (/ (1- items) 4)))
 883           (setq n 0)
 884           (dotimes (i 95)
 885             (let ((elt (aref docs i)))
 886               (when elt
 887                 (string-match ".*" elt)
 888                 (setq elt (match-string 0 elt))
 889                 (if (>= (length elt) 17)
 890                     (setq elt (concat (substring elt 0 14) "...")))
 891                 (if (< (point) (point-max))
 892                     (move-to-column (* 20 (/ n lines)) t))
 893                 (insert (+ i ?\s) ?: elt)
 894                 (if (< (point) (point-max))
 895                     (forward-line 1)
 896                   (insert "\n"))
 897                 (setq n (1+ n))
 898                 (if (= (% n lines) 0)
 899                     (goto-char pos))))))
 900         (goto-char (point-max))
 901         (insert "\n"
 902                 "character(s)\tcategory mnemonics\n"
 903                 "------------\t------------------")
 904         (describe-vector table 'help-describe-category-set)
 905         (insert "Legend of category mnemonics:\n")
 906         (dotimes (i 95)
 907           (let ((elt (aref docs i)))
 908             (when elt
 909               (if (string-match "\n" elt)
 910                   (setq elt (substring elt (match-end 0))))
 911               (insert (+ i ?\s) ": " elt "\n"))))
 912         (while (setq table (char-table-parent table))
 913           (insert "\nThe parent category table is:")
 914           (describe-vector table 'help-describe-category-set))))))
 915
 916 \f
 917 ;;; Replacements for old lib-src/ programs.  Don't seem especially useful.
 918
 919 ;; Replaces lib-src/digest-doc.c.
 920 ;;;###autoload
 921 (defun doc-file-to-man (file)
 922   "Produce an nroff buffer containing the doc-strings from the DOC file."
 923   (interactive (list (read-file-name "Name of DOC file: " doc-directory
 924                                      internal-doc-file-name t)))
 925   (or (file-readable-p file)
 926       (error "Cannot read file `%s'" file))
 927   (pop-to-buffer (generate-new-buffer "*man-doc*"))
 928   (setq buffer-undo-list t)
 929   (insert ".TH \"Command Summary for GNU Emacs\"\n"
 930           ".AU Richard M. Stallman\n")
 931   (insert-file-contents file)
 932   (let (notfirst)
 933     (while (search-forward "\1f" nil 'move)
 934       (if (looking-at "S")
 935           (delete-region (1- (point)) (line-end-position))
 936         (delete-char -1)
 937         (if notfirst
 938             (insert "\n.DE\n")
 939           (setq notfirst t))
 940         (insert "\n.SH ")
 941         (insert (if (looking-at "F") "Function " "Variable "))
 942         (delete-char 1)
 943         (forward-line 1)
 944         (insert ".DS L\n"))))
 945   (insert "\n.DE\n")
 946   (setq buffer-undo-list nil)
 947   (nroff-mode))
 948
 949 ;; Replaces lib-src/sorted-doc.c.
 950 ;;;###autoload
 951 (defun doc-file-to-info (file)
 952   "Produce a texinfo buffer with sorted doc-strings from the DOC file."
 953   (interactive (list (read-file-name "Name of DOC file: " doc-directory
 954                                      internal-doc-file-name t)))
 955   (or (file-readable-p file)
 956       (error "Cannot read file `%s'" file))
 957   (let ((i 0) type name doc alist)
 958     (with-temp-buffer
 959       (insert-file-contents file)
 960       ;; The characters "@{}" need special treatment.
 961       (while (re-search-forward "[@{}]" nil t)
 962         (backward-char)
 963         (insert "@")
 964         (forward-char 1))
 965       (goto-char (point-min))
 966       (while (search-forward "\1f" nil t)
 967         (unless (looking-at "S")
 968           (setq type (char-after)
 969                 name (buffer-substring (1+ (point)) (line-end-position))
 970                 doc (buffer-substring (line-beginning-position 2)
 971                                       (if (search-forward  "\1f" nil 'move)
 972                                           (1- (point))
 973                                         (point)))
 974                 alist (cons (list name type doc) alist))
 975           (backward-char 1))))
 976     (pop-to-buffer (generate-new-buffer "*info-doc*"))
 977     (setq buffer-undo-list t)
 978     ;; Write the output header.
 979     (insert "\\input texinfo  @c -*-texinfo-*-\n"
 980             "@setfilename emacsdoc.info\n"
 981             "@settitle Command Summary for GNU Emacs\n"
 982             "@finalout\n"
 983             "\n@node Top\n"
 984             "@unnumbered Command Summary for GNU Emacs\n\n"
 985             "@table @asis\n\n"
 986             "@iftex\n"
 987             "@global@let@ITEM@item\n"
 988             "@def@item{@filbreak@vskip5pt@ITEM}\n"
 989             "@font@tensy cmsy10 scaled @magstephalf\n"
 990             "@font@teni cmmi10 scaled @magstephalf\n"
 991             "@def\\{{@tensy@char110}}\n" ; this backslash goes with cmr10
 992             "@def|{{@tensy@char106}}\n"
 993             "@def@{{{@tensy@char102}}\n"
 994             "@def@}{{@tensy@char103}}\n"
 995             "@def<{{@teni@char62}}\n"
 996             "@def>{{@teni@char60}}\n"
 997             "@chardef@@64\n"
 998             "@catcode43=12\n"
 999             "@tableindent-0.2in\n"
1000             "@end iftex\n")
1001     ;; Sort the array by name; within each name, by type (functions first).
1002     (setq alist (sort alist (lambda (e1 e2)
1003                               (if (string-equal (car e1) (car e2))
1004                                   (<= (cadr e1) (cadr e2))
1005                                 (string-lessp (car e1) (car e2))))))
1006     ;; Print each function.
1007     (dolist (e alist)
1008       (insert "\n@item "
1009               (if (char-equal (cadr e) ?\F) "Function" "Variable")
1010               " @code{" (car e) "}\n@display\n"
1011               (nth 2 e)
1012               "\n@end display\n")
1013       ;; Try to avoid a save size overflow in the TeX output routine.
1014       (if (zerop (setq i (% (1+ i) 100)))
1015           (insert "\n@end table\n@table @asis\n")))
1016     (insert "@end table\n"
1017             "@bye\n")
1018     (setq buffer-undo-list nil)
1019     (texinfo-mode)))
1020
1021 (provide 'help-fns)
1022
1023 ;;; help-fns.el ends here