code.delx.au - gnu-emacs/blob - lisp/avoid.el

   1 ;;; avoid.el --- make mouse pointer stay out of the way of editing
   2
   3 ;;; Copyright (C) 1993, 1994 Free Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@gnu.ai.mit.edu>
   6 ;; Keywords: mouse
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; For those who are annoyed by the mouse pointer obscuring text,
  28 ;; this mode moves the mouse pointer - either just a little out of
  29 ;; the way, or all the way to the corner of the frame.
  30 ;; To use, load or evaluate this file and type M-x mouse-avoidance-mode .
  31 ;; To set up permanently, put the following in your .emacs:
  32 ;;
  33 ;; (if window-system (mouse-avoidance-mode 'animate))
  34 ;;
  35 ;; Other legitimate alternatives include
  36 ;; `banish', `exile', `jump', `cat-and-mouse', and `proteus'.
  37 ;; They do somewhat different things.
  38 ;; See the documentation for function `mouse-avoidance-mode' for
  39 ;; details of the different modes.
  40 ;;
  41 ;; For added silliness, make the animatee animate...
  42 ;; put something similar to the following into your .emacs:
  43 ;;
  44 ;; (if window-system
  45 ;;     (mouse-avoidance-set-pointer-shape
  46 ;;           (eval (nth (random 4)
  47 ;;                      '(x-pointer-man x-pointer-spider
  48 ;;                        x-pointer-gobbler x-pointer-gumby)))))
  49 ;;
  50 ;; For completely random pointer shape, replace the setq above with:
  51 ;; (setq x-pointer-shape (mouse-avoidance-random-shape))
  52 ;;
  53 ;; Bugs / Warnings / To-Do:
  54 ;;
  55 ;; - Using this code does slow emacs down.  "banish" mode shouldn't
  56 ;;   be too bad, and on my workstation even "animate" is reasonable.
  57 ;;
  58 ;; - It ought to find out where any overlapping frames are and avoid them,
  59 ;;   rather than always raising the frame.
  60
  61 ;; Credits:
  62 ;; This code was helped by all those who contributed suggestions,
  63 ;;   fixes, and additions
  64 ;; Joe Harrington (and his advisor), for the original inspiration.
  65 ;; Ken Manheimer, for dreaming up the Protean mode.
  66 ;; Richard Stallman, for the awful cat-and-mouse pun, among other things.
  67 ;; Mike Williams, Denis Howe, Bill Benedetto, Chris Moore, Don Morris,
  68 ;; Simon Marshall, and M.S. Ashton, for their feedback.
  69
  70 ;;; Code:
  71
  72 (provide 'avoid)
  73
  74 (defgroup avoid nil
  75   "Make mouse pointer stay out of the way of editing."
  76   :prefix "mouse-avoidance-"
  77   :group 'mouse)
  78
  79
  80 (defcustom mouse-avoidance-mode nil
  81   "Activate mouse avoidance mode.
  82 See function `mouse-avoidance-mode' for possible values.
  83 You must modify via \\[customize] for this variable to have an effect."
  84   :set (lambda (symbol value)
  85          ;; 'none below prevents toggling when value is nil.
  86          (mouse-avoidance-mode (or value 'none)))
  87   :initialize 'custom-initialize-default
  88   :type '(choice (const :tag "none" nil) (const banish) (const jump)
  89                  (const animate) (const exile) (const proteus)
  90                  )
  91   :group 'avoid
  92   :require 'avoid
  93   :version "20.3")
  94
  95
  96 (defcustom mouse-avoidance-nudge-dist 15
  97   "*Average distance that mouse will be moved when approached by cursor.
  98 Only applies in mouse-avoidance-mode `jump' and its derivatives.
  99 For best results make this larger than `mouse-avoidance-threshold'."
 100   :type 'integer
 101   :group 'avoid)
 102
 103 (defcustom mouse-avoidance-nudge-var 10
 104   "*Variability of `mouse-avoidance-nudge-dist' (which see)."
 105   :type 'integer
 106   :group 'avoid)
 107
 108 (defcustom mouse-avoidance-animation-delay .01
 109   "Delay between animation steps, in seconds."
 110   :type 'number
 111   :group 'avoid)
 112
 113 (defcustom mouse-avoidance-threshold 5
 114   "*Mouse-pointer's flight distance.
 115 If the cursor gets closer than this, the mouse pointer will move away.
 116 Only applies in mouse-avoidance-modes `animate' and `jump'."
 117   :type 'integer
 118   :group 'avoid)
 119
 120 ;; Internal variables
 121 (defvar mouse-avoidance-state nil)
 122 (defvar mouse-avoidance-pointer-shapes nil)
 123 (defvar mouse-avoidance-n-pointer-shapes 0)
 124 (defvar mouse-avoidance-old-pointer-shape nil)
 125
 126 ;; This timer is used to run something when Emacs is idle.
 127 (defvar mouse-avoidance-timer nil)
 128
 129 ;;; Functions:
 130
 131 (defsubst mouse-avoidance-set-pointer-shape (shape)
 132   "Set the shape of the mouse pointer to SHAPE."
 133   (setq x-pointer-shape shape)
 134   (set-mouse-color nil))
 135
 136 (defun mouse-avoidance-point-position ()
 137   "Return the position of point as (FRAME X . Y).
 138 Analogous to mouse-position."
 139   (let* ((w (selected-window))
 140          (edges (window-edges w))
 141          (list
 142           (compute-motion (max (window-start w) (point-min))   ; start pos
 143                           ;; window-start can be < point-min if the
 144                           ;; latter has changed since the last redisplay
 145                           '(0 . 0)                             ; start XY
 146                           (point)                              ; stop pos
 147                           (cons (window-width) (window-height)); stop XY: none
 148                           (1- (window-width))                  ; width
 149                           (cons (window-hscroll w) 0)          ; 0 may not be right?
 150                           (selected-window))))
 151     ;; compute-motion returns (pos HPOS VPOS prevhpos contin)
 152     ;; we want:               (frame hpos . vpos)
 153     (cons (selected-frame)
 154           (cons (+ (car edges)       (car (cdr list)))
 155                 (+ (car (cdr edges)) (car (cdr (cdr list))))))))
 156
 157 ;(defun mouse-avoidance-point-position-test ()
 158 ;  (interactive)
 159 ;  (message (format "point=%s mouse=%s"
 160 ;                  (cdr (mouse-avoidance-point-position))
 161 ;                  (cdr (mouse-position)))))
 162
 163 (defun mouse-avoidance-set-mouse-position (pos)
 164   ;; Carefully set mouse position to given position (X . Y)
 165   ;; Ideally, should check if X,Y is in the current frame, and if not,
 166   ;; leave the mouse where it was.  However, this is currently
 167   ;; difficult to do, so we just raise the frame to avoid frame switches.
 168   ;; Returns t if it moved the mouse.
 169   (let ((f (selected-frame)))
 170     (raise-frame f)
 171     (set-mouse-position f (car pos) (cdr pos))
 172     t))
 173
 174 (defun mouse-avoidance-too-close-p (mouse)
 175   ;;  Return t if mouse pointer and point cursor are too close.
 176   ;; Acceptable distance is defined by mouse-avoidance-threshold.
 177   (let ((point (mouse-avoidance-point-position)))
 178     (and (eq (car mouse) (car point))
 179          (car (cdr mouse))
 180          (< (abs (- (car (cdr mouse)) (car (cdr point))))
 181             mouse-avoidance-threshold)
 182          (< (abs (- (cdr (cdr mouse)) (cdr (cdr point))))
 183             mouse-avoidance-threshold))))
 184
 185 (defun mouse-avoidance-banish-destination ()
 186   "The position to which mouse-avoidance-mode `banish' moves the mouse.
 187 You can redefine this if you want the mouse banished to a different corner."
 188  (cons (1- (frame-width))
 189        0))
 190
 191 (defun mouse-avoidance-banish-mouse ()
 192   ;; Put the mouse pointer in the upper-right corner of the current frame.
 193   (mouse-avoidance-set-mouse-position (mouse-avoidance-banish-destination)))
 194
 195 (defsubst mouse-avoidance-delta (cur delta dist var min max)
 196   ;; Decide how far to move in either dimension.
 197   ;; Args are the CURRENT location, the desired DELTA for
 198   ;; warp-conservation, the DISTANCE we like to move, the VARIABILITY
 199   ;; in distance allowed, and the MIN and MAX possible window positions.
 200   ;; Returns something as close to DELTA as possible within the constraints.
 201   (let ((L1 (max (- min cur) (+ (- dist) (- var))))
 202         (R1                  (+ (- dist)    var ))
 203         (L2                  (+    dist  (- var)))
 204         (R2 (min (- max cur) (+    dist     var))))
 205     (if (< R1 (- min cur)) (setq L1 nil R1 nil))
 206     (if (> L2 (- max cur)) (setq L2 nil R2 nil))
 207     (cond ((and L1 (< delta L1)) L1)
 208           ((and R1 (< delta R1)) delta)
 209           ((and R1 (< delta 0)) R1)
 210           ((and L2 (< delta L2)) L2)
 211           ((and R2 (< delta R2)) delta)
 212           (R2)
 213           ((or R1 L2))
 214           (t 0))))
 215
 216 (defun mouse-avoidance-nudge-mouse ()
 217   ;; Push the mouse a little way away, possibly animating the move
 218   ;; For these modes, state keeps track of the total offset that we've
 219   ;; accumulated, and tries to keep it close to zero.
 220   (let* ((cur (mouse-position))
 221          (cur-frame (car cur))
 222          (cur-pos (cdr cur))
 223          (deltax (mouse-avoidance-delta
 224                   (car cur-pos) (- (random mouse-avoidance-nudge-var)
 225                                    (car mouse-avoidance-state))
 226                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 227                   0 (frame-width)))
 228          (deltay (mouse-avoidance-delta
 229                   (cdr cur-pos) (- (random mouse-avoidance-nudge-var)
 230                                    (cdr mouse-avoidance-state))
 231                   mouse-avoidance-nudge-dist mouse-avoidance-nudge-var
 232                   0 (frame-height))))
 233     (setq mouse-avoidance-state
 234           (cons (+ (car mouse-avoidance-state) deltax)
 235                 (+ (cdr mouse-avoidance-state) deltay)))
 236     (if (or (eq mouse-avoidance-mode 'animate)
 237             (eq mouse-avoidance-mode 'proteus))
 238         (let ((i 0.0))
 239           (while (<= i 1)
 240             (mouse-avoidance-set-mouse-position
 241              (cons (+ (car cur-pos) (round (* i deltax)))
 242                    (+ (cdr cur-pos) (round (* i deltay)))))
 243             (setq i (+ i (max .1 (/ 1.0 mouse-avoidance-nudge-dist))))
 244             (if (eq mouse-avoidance-mode 'proteus)
 245                 (mouse-avoidance-set-pointer-shape
 246                  (mouse-avoidance-random-shape)))
 247             (sit-for mouse-avoidance-animation-delay)))
 248       (mouse-avoidance-set-mouse-position (cons (+ (car (cdr cur)) deltax)
 249                                                 (+ (cdr (cdr cur)) deltay))))))
 250
 251 (defun mouse-avoidance-random-shape ()
 252   "Return a random cursor shape.
 253 This assumes that any variable whose name begins with x-pointer- and
 254 has an integer value is a valid cursor shape.  You might want to
 255 redefine this function to suit your own tastes."
 256   (if (null mouse-avoidance-pointer-shapes)
 257       (progn
 258         (setq mouse-avoidance-pointer-shapes
 259               (mapcar '(lambda (x) (symbol-value (intern x)))
 260                       (all-completions "x-pointer-" obarray
 261                                        '(lambda (x)
 262                                           (and (boundp x)
 263                                                (integerp (symbol-value x)))))))
 264         (setq mouse-avoidance-n-pointer-shapes
 265               (length mouse-avoidance-pointer-shapes))))
 266   (nth (random mouse-avoidance-n-pointer-shapes)
 267        mouse-avoidance-pointer-shapes))
 268
 269 (defun mouse-avoidance-banish-hook ()
 270   (if (and (not executing-kbd-macro)    ; don't check inside macro
 271            ;; Don't do anything if last event was a mouse event.
 272            (not (and (consp last-input-event)
 273                      (symbolp (car last-input-event))
 274                      (let ((modifiers (event-modifiers (car last-input-event))))
 275                        (or (memq (car last-input-event)
 276                                  '(mouse-movement scroll-bar-movement))
 277                            (memq 'click modifiers)
 278                            (memq 'drag modifiers)
 279                            (memq 'down modifiers))))))
 280       (mouse-avoidance-banish-mouse)))
 281
 282 (defun mouse-avoidance-exile-hook ()
 283   ;; For exile mode, the state is nil when the mouse is in its normal
 284   ;; position, and set to the old mouse-position when the mouse is in exile.
 285   (if (and (not executing-kbd-macro)
 286            ;; Don't do anything if last event was a mouse event.
 287            (not (and (consp last-input-event)
 288                      (symbolp (car last-input-event))
 289                      (let ((modifiers (event-modifiers (car last-input-event))))
 290                        (or (memq (car last-input-event)
 291                                  '(mouse-movement scroll-bar-movement))
 292                            (memq 'click modifiers)
 293                            (memq 'drag modifiers)
 294                            (memq 'down modifiers))))))
 295       (let ((mp (mouse-position)))
 296         (cond ((and (not mouse-avoidance-state)
 297                     (mouse-avoidance-too-close-p mp))
 298                (setq mouse-avoidance-state mp)
 299                (mouse-avoidance-banish-mouse))
 300               ((and mouse-avoidance-state
 301                     (not (mouse-avoidance-too-close-p mouse-avoidance-state)))
 302                (if (and (eq (car mp) (selected-frame))
 303                         (equal (cdr mp) (mouse-avoidance-banish-destination)))
 304                    (mouse-avoidance-set-mouse-position
 305                     ;; move back only if user has not moved mouse
 306                     (cdr mouse-avoidance-state)))
 307                ;; but clear state anyway, to be ready for another move
 308                (setq mouse-avoidance-state nil))))))
 309
 310 (defun mouse-avoidance-fancy-hook ()
 311   ;; Used for the "fancy" modes, ie jump et al.
 312   (if (and (not executing-kbd-macro)    ; don't check inside macro
 313            ;; Don't do anything if last event was a mouse event.
 314            (not (and (consp last-input-event)
 315                      (symbolp (car last-input-event))
 316                      (let ((modifiers (event-modifiers (car last-input-event))))
 317                        (or (memq (car last-input-event)
 318                                  '(mouse-movement scroll-bar-movement))
 319                            (memq 'click modifiers)
 320                            (memq 'drag modifiers)
 321                            (memq 'down modifiers)))))
 322            (mouse-avoidance-too-close-p (mouse-position)))
 323       (let ((old-pos (mouse-position)))
 324         (mouse-avoidance-nudge-mouse)
 325         (if (not (eq (selected-frame) (car old-pos)))
 326             ;; This should never happen.
 327             (apply 'set-mouse-position old-pos)))))
 328
 329 ;;;###autoload
 330 (defun mouse-avoidance-mode (&optional mode)
 331   "Set cursor avoidance mode to MODE.
 332 MODE should be one of the symbols `banish', `exile', `jump', `animate',
 333 `cat-and-mouse', `proteus', or `none'.
 334
 335 If MODE is nil, toggle mouse avoidance between `none` and `banish'
 336 modes.  Positive numbers and symbols other than the above are treated
 337 as equivalent to `banish'; negative numbers and `-' are equivalent to `none'.
 338
 339 Effects of the different modes:
 340  * banish: Move the mouse to the upper-right corner on any keypress.
 341  * exile: Move the mouse to the corner only if the cursor gets too close,
 342      and allow it to return once the cursor is out of the way.
 343  * jump: If the cursor gets too close to the mouse, displace the mouse
 344      a random distance & direction.
 345  * animate: As `jump', but shows steps along the way for illusion of motion.
 346  * cat-and-mouse: Same as `animate'.
 347  * proteus: As `animate', but changes the shape of the mouse pointer too.
 348
 349 Whenever the mouse is moved, the frame is also raised.
 350
 351 \(see `mouse-avoidance-threshold' for definition of \"too close\",
 352 and `mouse-avoidance-nudge-dist' and `mouse-avoidance-nudge-var' for
 353 definition of \"random distance\".)"
 354   (interactive
 355    (list (intern (completing-read
 356                   "Select cursor avoidance technique (SPACE for list): "
 357                   '(("banish") ("exile") ("jump") ("animate")
 358                     ("cat-and-mouse") ("proteus") ("none"))
 359                   nil t))))
 360   (if (eq mode 'cat-and-mouse)
 361       (setq mode 'animate))
 362   (if mouse-avoidance-timer
 363       (cancel-timer mouse-avoidance-timer))
 364   (setq mouse-avoidance-timer nil)
 365
 366   ;; Restore pointer shape if necessary
 367   (if (eq mouse-avoidance-mode 'proteus)
 368       (mouse-avoidance-set-pointer-shape mouse-avoidance-old-pointer-shape))
 369
 370   ;; Do additional setup depending on version of mode requested
 371   (cond ((eq mode 'none)
 372          (setq mouse-avoidance-mode nil))
 373         ((or (eq mode 'jump)
 374              (eq mode 'animate)
 375              (eq mode 'proteus))
 376          (setq mouse-avoidance-timer
 377                (run-with-idle-timer 0.1 t 'mouse-avoidance-fancy-hook))
 378          (setq mouse-avoidance-mode mode
 379                mouse-avoidance-state (cons 0 0)
 380                mouse-avoidance-old-pointer-shape x-pointer-shape))
 381         ((eq mode 'exile)
 382          (setq mouse-avoidance-timer
 383                (run-with-idle-timer 0.1 t 'mouse-avoidance-exile-hook))
 384          (setq mouse-avoidance-mode mode
 385                mouse-avoidance-state nil))
 386         ((or (eq mode 'banish)
 387              (eq mode t)
 388              (and (null mode) (null mouse-avoidance-mode))
 389              (and mode (> (prefix-numeric-value mode) 0)))
 390          (setq mouse-avoidance-timer
 391                (run-with-idle-timer 0.1 t 'mouse-avoidance-banish-hook))
 392          (setq mouse-avoidance-mode 'banish))
 393         (t (setq mouse-avoidance-mode nil)))
 394   (force-mode-line-update))
 395
 396 ;; Most people who use avoid mode leave it on all the time, so it's not
 397 ;; very informative to announce it in the mode line.
 398 ;;(or (assq 'mouse-avoidance-mode minor-mode-alist)
 399 ;;    (setq minor-mode-alist (cons '(mouse-avoidance-mode " Avoid")
 400 ;;                               minor-mode-alist)))
 401
 402 ;; Needed for custom.
 403 (if mouse-avoidance-mode
 404     (mouse-avoidance-mode mouse-avoidance-mode))
 405
 406 ;;; avoid.el ends here