code.delx.au - gnu-emacs/blob - lisp/textmodes/outline.el

   1 ;;; outline.el --- outline mode commands for Emacs
   2
   3 ;; Copyright (C) 1986, 1993, 1994, 1995, 1997 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: outlines
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This package is a major mode for editing outline-format documents.
  28 ;; An outline can be `abstracted' to show headers at any given level,
  29 ;; with all stuff below hidden.  See the Emacs manual for details.
  30
  31 ;;; Code:
  32
  33 (defgroup outlines nil
  34   "Support for hierarchical outlining"
  35   :prefix "outline-"
  36   :group 'editing)
  37
  38 (defcustom outline-regexp nil
  39   "*Regular expression to match the beginning of a heading.
  40 Any line whose beginning matches this regexp is considered to start a heading.
  41 The recommended way to set this is with a Local Variables: list
  42 in the file it applies to.  See also outline-heading-end-regexp."
  43   :type '(choice regexp (const nil))
  44   :group 'outlines)
  45
  46 ;; Can't initialize this in the defvar above -- some major modes have
  47 ;; already assigned a local value to it.
  48 (or (default-value 'outline-regexp)
  49     (setq-default outline-regexp "[*\^L]+"))
  50
  51 (defcustom outline-heading-end-regexp "\n"
  52   "*Regular expression to match the end of a heading line.
  53 You can assume that point is at the beginning of a heading when this
  54 regexp is searched for.  The heading ends at the end of the match.
  55 The recommended way to set this is with a `Local Variables:' list
  56 in the file it applies to."
  57   :type 'regexp
  58   :group 'outlines)
  59
  60 (defvar outline-mode-prefix-map nil)
  61
  62 (if outline-mode-prefix-map
  63     nil
  64   (setq outline-mode-prefix-map (make-sparse-keymap))
  65   (define-key outline-mode-prefix-map "@" 'outline-mark-subtree)
  66   (define-key outline-mode-prefix-map "\C-n" 'outline-next-visible-heading)
  67   (define-key outline-mode-prefix-map "\C-p" 'outline-previous-visible-heading)
  68   (define-key outline-mode-prefix-map "\C-i" 'show-children)
  69   (define-key outline-mode-prefix-map "\C-s" 'show-subtree)
  70   (define-key outline-mode-prefix-map "\C-d" 'hide-subtree)
  71   (define-key outline-mode-prefix-map "\C-u" 'outline-up-heading)
  72   (define-key outline-mode-prefix-map "\C-f" 'outline-forward-same-level)
  73   (define-key outline-mode-prefix-map "\C-b" 'outline-backward-same-level)
  74   (define-key outline-mode-prefix-map "\C-t" 'hide-body)
  75   (define-key outline-mode-prefix-map "\C-a" 'show-all)
  76   (define-key outline-mode-prefix-map "\C-c" 'hide-entry)
  77   (define-key outline-mode-prefix-map "\C-e" 'show-entry)
  78   (define-key outline-mode-prefix-map "\C-l" 'hide-leaves)
  79   (define-key outline-mode-prefix-map "\C-k" 'show-branches)
  80   (define-key outline-mode-prefix-map "\C-q" 'hide-sublevels)
  81   (define-key outline-mode-prefix-map "\C-o" 'hide-other))
  82
  83 (defvar outline-mode-menu-bar-map nil)
  84 (if outline-mode-menu-bar-map
  85     nil
  86   (setq outline-mode-menu-bar-map (make-sparse-keymap))
  87
  88   (define-key outline-mode-menu-bar-map [hide]
  89     (cons "Hide" (make-sparse-keymap "Hide")))
  90
  91   (define-key outline-mode-menu-bar-map [hide hide-other]
  92     '("Hide Other" . hide-other))
  93   (define-key outline-mode-menu-bar-map [hide hide-sublevels]
  94     '("Hide Sublevels" . hide-sublevels))
  95   (define-key outline-mode-menu-bar-map [hide hide-subtree]
  96     '("Hide Subtree" . hide-subtree))
  97   (define-key outline-mode-menu-bar-map [hide hide-entry]
  98     '("Hide Entry" . hide-entry))
  99   (define-key outline-mode-menu-bar-map [hide hide-body]
 100     '("Hide Body" . hide-body))
 101   (define-key outline-mode-menu-bar-map [hide hide-leaves]
 102     '("Hide Leaves" . hide-leaves))
 103
 104   (define-key outline-mode-menu-bar-map [show]
 105     (cons "Show" (make-sparse-keymap "Show")))
 106
 107   (define-key outline-mode-menu-bar-map [show show-subtree]
 108     '("Show Subtree" . show-subtree))
 109   (define-key outline-mode-menu-bar-map [show show-children]
 110     '("Show Children" . show-children))
 111   (define-key outline-mode-menu-bar-map [show show-branches]
 112     '("Show Branches" . show-branches))
 113   (define-key outline-mode-menu-bar-map [show show-entry]
 114     '("Show Entry" . show-entry))
 115   (define-key outline-mode-menu-bar-map [show show-all]
 116     '("Show All" . show-all))
 117
 118   (define-key outline-mode-menu-bar-map [headings]
 119     (cons "Headings" (make-sparse-keymap "Headings")))
 120
 121   (define-key outline-mode-menu-bar-map [headings outline-backward-same-level]
 122     '("Previous Same Level" . outline-backward-same-level))
 123   (define-key outline-mode-menu-bar-map [headings outline-forward-same-level]
 124     '("Next Same Level" . outline-forward-same-level))
 125   (define-key outline-mode-menu-bar-map [headings outline-previous-visible-heading]
 126     '("Previous" . outline-previous-visible-heading))
 127   (define-key outline-mode-menu-bar-map [headings outline-next-visible-heading]
 128     '("Next" . outline-next-visible-heading))
 129   (define-key outline-mode-menu-bar-map [headings outline-up-heading]
 130     '("Up" . outline-up-heading)))
 131
 132 (defvar outline-mode-map nil "")
 133
 134 (if outline-mode-map
 135     nil
 136   (setq outline-mode-map (nconc (make-sparse-keymap) text-mode-map))
 137   (define-key outline-mode-map "\C-c" outline-mode-prefix-map)
 138   (define-key outline-mode-map [menu-bar] outline-mode-menu-bar-map))
 139
 140 (defcustom outline-minor-mode nil
 141   "Non-nil if using Outline mode as a minor mode of some other mode."
 142   :type 'boolean
 143   :group 'outlines)
 144 (make-variable-buffer-local 'outline-minor-mode)
 145 (or (assq 'outline-minor-mode minor-mode-alist)
 146     (setq minor-mode-alist (append minor-mode-alist
 147                                    (list '(outline-minor-mode " Outl")))))
 148
 149 (defvar outline-font-lock-keywords
 150   '(;;
 151     ;; Highlight headings according to the level.
 152     (eval . (list (concat "^" outline-regexp ".+")
 153                   0 '(or (cdr (assq (outline-font-lock-level)
 154                                     '((1 . font-lock-function-name-face)
 155                                       (2 . font-lock-variable-name-face)
 156                                       (3 . font-lock-keyword-face)
 157                                       (4 . font-lock-builtin-face)
 158                                       (5 . font-lock-comment-face)
 159                                       (6 . font-lock-constant-face)
 160                                       (7 . font-lock-type-face)
 161                                       (8 . font-lock-string-face))))
 162                          font-lock-warning-face)
 163                   nil t)))
 164   "Additional expressions to highlight in Outline mode.")
 165
 166 (defun outline-font-lock-level ()
 167   (let ((count 1))
 168     (save-excursion
 169       (outline-back-to-heading)
 170       (condition-case nil
 171           (while (not (bobp))
 172             (outline-up-heading 1)
 173             (setq count (1+ count)))
 174         (error)))
 175     count))
 176
 177 (defvar outline-view-change-hook nil
 178   "Normal hook to be run after outline visibility changes.")
 179
 180 ;;;###autoload
 181 (defun outline-mode ()
 182   "Set major mode for editing outlines with selective display.
 183 Headings are lines which start with asterisks: one for major headings,
 184 two for subheadings, etc.  Lines not starting with asterisks are body lines.
 185
 186 Body text or subheadings under a heading can be made temporarily
 187 invisible, or visible again.  Invisible lines are attached to the end
 188 of the heading, so they move with it, if the line is killed and yanked
 189 back.  A heading with text hidden under it is marked with an ellipsis (...).
 190
 191 Commands:\\<outline-mode-map>
 192 \\[outline-next-visible-heading]   outline-next-visible-heading      move by visible headings
 193 \\[outline-previous-visible-heading]   outline-previous-visible-heading
 194 \\[outline-forward-same-level]   outline-forward-same-level        similar but skip subheadings
 195 \\[outline-backward-same-level]   outline-backward-same-level
 196 \\[outline-up-heading]   outline-up-heading                 move from subheading to heading
 197
 198 \\[hide-body]   make all text invisible (not headings).
 199 \\[show-all]    make everything in buffer visible.
 200
 201 The remaining commands are used when point is on a heading line.
 202 They apply to some of the body or subheadings of that heading.
 203 \\[hide-subtree]   hide-subtree make body and subheadings invisible.
 204 \\[show-subtree]   show-subtree make body and subheadings visible.
 205 \\[show-children]   show-children       make direct subheadings visible.
 206                  No effect on body, or subheadings 2 or more levels down.
 207                  With arg N, affects subheadings N levels down.
 208 \\[hide-entry]     make immediately following body invisible.
 209 \\[show-entry]     make it visible.
 210 \\[hide-leaves]    make body under heading and under its subheadings invisible.
 211                      The subheadings remain visible.
 212 \\[show-branches]  make all subheadings at all levels visible.
 213
 214 The variable `outline-regexp' can be changed to control what is a heading.
 215 A line is a heading if `outline-regexp' matches something at the
 216 beginning of the line.  The longer the match, the deeper the level.
 217
 218 Turning on outline mode calls the value of `text-mode-hook' and then of
 219 `outline-mode-hook', if they are non-nil."
 220   (interactive)
 221   (kill-all-local-variables)
 222   (use-local-map outline-mode-map)
 223   (setq mode-name "Outline")
 224   (setq major-mode 'outline-mode)
 225   (define-abbrev-table 'text-mode-abbrev-table ())
 226   (setq local-abbrev-table text-mode-abbrev-table)
 227   (set-syntax-table text-mode-syntax-table)
 228   (make-local-variable 'line-move-ignore-invisible)
 229   (setq line-move-ignore-invisible t)
 230   ;; Cause use of ellipses for invisible text.
 231   (add-to-invisibility-spec '(outline . t))
 232   (make-local-variable 'paragraph-start)
 233   (setq paragraph-start (concat paragraph-start "\\|\\("
 234                                 outline-regexp "\\)"))
 235   ;; Inhibit auto-filling of header lines.
 236   (make-local-variable 'auto-fill-inhibit-regexp)
 237   (setq auto-fill-inhibit-regexp outline-regexp)
 238   (make-local-variable 'paragraph-separate)
 239   (setq paragraph-separate (concat paragraph-separate "\\|\\("
 240                                    outline-regexp "\\)"))
 241   (make-local-variable 'font-lock-defaults)
 242   (setq font-lock-defaults '(outline-font-lock-keywords t))
 243   (make-local-variable 'change-major-mode-hook)
 244   (add-hook 'change-major-mode-hook 'show-all)
 245   (run-hooks 'text-mode-hook 'outline-mode-hook))
 246
 247 (defcustom outline-minor-mode-prefix "\C-c@"
 248   "*Prefix key to use for Outline commands in Outline minor mode.
 249 The value of this variable is checked as part of loading Outline mode.
 250 After that, changing the prefix key requires manipulating keymaps."
 251   :type 'string
 252   :group 'outlines)
 253
 254 (defvar outline-minor-mode-map nil)
 255 (if outline-minor-mode-map
 256     nil
 257   (setq outline-minor-mode-map (make-sparse-keymap))
 258   (define-key outline-minor-mode-map [menu-bar]
 259     outline-mode-menu-bar-map)
 260   (define-key outline-minor-mode-map outline-minor-mode-prefix
 261     outline-mode-prefix-map))
 262
 263 (or (assq 'outline-minor-mode minor-mode-map-alist)
 264     (setq minor-mode-map-alist
 265           (cons (cons 'outline-minor-mode outline-minor-mode-map)
 266                 minor-mode-map-alist)))
 267
 268 ;;;###autoload
 269 (defun outline-minor-mode (&optional arg)
 270   "Toggle Outline minor mode.
 271 With arg, turn Outline minor mode on if arg is positive, off otherwise.
 272 See the command `outline-mode' for more information on this mode."
 273   (interactive "P")
 274   (setq outline-minor-mode
 275         (if (null arg) (not outline-minor-mode)
 276           (> (prefix-numeric-value arg) 0)))
 277   (if outline-minor-mode
 278       (progn
 279         (make-local-hook 'change-major-mode-hook)
 280         ;; Turn off this mode if we change major modes.
 281         (add-hook 'change-major-mode-hook
 282                   '(lambda () (outline-minor-mode -1))
 283                   nil t)
 284         (make-local-variable 'line-move-ignore-invisible)
 285         (setq line-move-ignore-invisible t)
 286         ;; Cause use of ellipses for invisible text.
 287         (add-to-invisibility-spec '(outline . t))
 288         (run-hooks 'outline-minor-mode-hook))
 289     (setq line-move-ignore-invisible nil)
 290     ;; Cause use of ellipses for invisible text.
 291     (remove-from-invisibility-spec '(outline . t)))
 292   ;; When turning off outline mode, get rid of any outline hiding.
 293   (or outline-minor-mode
 294       (show-all))
 295   (force-mode-line-update))
 296 \f
 297 (defcustom outline-level 'outline-level
 298   "*Function of no args to compute a header's nesting level in an outline.
 299 It can assume point is at the beginning of a header line."
 300   :type 'function
 301   :group 'outlines)
 302
 303 ;; This used to count columns rather than characters, but that made ^L
 304 ;; appear to be at level 2 instead of 1.  Columns would be better for
 305 ;; tab handling, but the default regexp doesn't use tabs, and anyone
 306 ;; who changes the regexp can also redefine the outline-level variable
 307 ;; as appropriate.
 308 (defun outline-level ()
 309   "Return the depth to which a statement is nested in the outline.
 310 Point must be at the beginning of a header line.  This is actually
 311 the number of characters that `outline-regexp' matches."
 312   (save-excursion
 313     (looking-at outline-regexp)
 314     (- (match-end 0) (match-beginning 0))))
 315
 316 (defun outline-next-preface ()
 317   "Skip forward to just before the next heading line.
 318 If there's no following heading line, stop before the newline
 319 at the end of the buffer."
 320   (if (re-search-forward (concat "\n\\(" outline-regexp "\\)")
 321                          nil 'move)
 322       (goto-char (match-beginning 0)))
 323   (if (and (bolp) (not (bobp)))
 324       (forward-char -1)))
 325
 326 (defun outline-next-heading ()
 327   "Move to the next (possibly invisible) heading line."
 328   (interactive)
 329   (if (re-search-forward (concat "\n\\(" outline-regexp "\\)")
 330                          nil 'move)
 331       (goto-char (1+ (match-beginning 0)))))
 332
 333 (defsubst outline-visible ()
 334   "Non-nil if the character after point is visible."
 335   (not (get-char-property (point) 'invisible)))
 336
 337 (defun outline-back-to-heading (&optional invisible-ok)
 338   "Move to previous heading line, or beg of this line if it's a heading.
 339 Only visible heading lines are considered, unless INVISIBLE-OK is non-nil."
 340   (beginning-of-line)
 341   (or (outline-on-heading-p t)
 342       (let (found)
 343         (save-excursion
 344           (while (not found)
 345             (or (re-search-backward (concat "^\\(" outline-regexp "\\)")
 346                                     nil t)
 347                 (error "before first heading"))
 348             (setq found (and (or invisible-ok (outline-visible)) (point)))))
 349         (goto-char found)
 350         found)))
 351
 352 (defun outline-on-heading-p (&optional invisible-ok)
 353   "Return t if point is on a (visible) heading line.
 354 If INVISIBLE-OK is non-nil, an invisible heading line is ok too."
 355   (save-excursion
 356     (beginning-of-line)
 357     (and (bolp) (or invisible-ok (outline-visible))
 358          (looking-at outline-regexp))))
 359
 360 (defun outline-end-of-heading ()
 361   (if (re-search-forward outline-heading-end-regexp nil 'move)
 362       (forward-char -1)))
 363
 364 (defun outline-next-visible-heading (arg)
 365   "Move to the next visible heading line.
 366 With argument, repeats or can move backward if negative.
 367 A heading line is one that starts with a `*' (or that
 368 `outline-regexp' matches)."
 369   (interactive "p")
 370   (if (< arg 0)
 371       (beginning-of-line)
 372     (end-of-line))
 373   (while (and (not (bobp)) (< arg 0))
 374     (while (and (not (bobp))
 375                 (re-search-backward (concat "^\\(" outline-regexp "\\)")
 376                                     nil 'move)
 377                 (not (outline-visible))))
 378     (setq arg (1+ arg)))
 379   (while (and (not (eobp)) (> arg 0))
 380     (while (and (not (eobp))
 381                 (re-search-forward (concat "^\\(" outline-regexp "\\)")
 382                                    nil 'move)
 383                 (not (outline-visible))))
 384     (setq arg (1- arg)))
 385   (beginning-of-line))
 386
 387 (defun outline-previous-visible-heading (arg)
 388   "Move to the previous heading line.
 389 With argument, repeats or can move forward if negative.
 390 A heading line is one that starts with a `*' (or that
 391 `outline-regexp' matches)."
 392   (interactive "p")
 393   (outline-next-visible-heading (- arg)))
 394
 395 (defun outline-mark-subtree ()
 396   "Mark the current subtree in an outlined document.
 397 This puts point at the start of the current subtree, and mark at the end."
 398   (interactive)
 399   (let ((beg))
 400     (if (outline-on-heading-p)
 401         ;; we are already looking at a heading
 402         (beginning-of-line)
 403       ;; else go back to previous heading
 404       (outline-previous-visible-heading 1))
 405     (setq beg (point))
 406     (outline-end-of-subtree)
 407     (push-mark (point))
 408     (goto-char beg)))
 409 \f
 410 (defun outline-flag-region (from to flag)
 411   "Hides or shows lines from FROM to TO, according to FLAG.
 412 If FLAG is nil then text is shown, while if FLAG is t the text is hidden."
 413   (let ((inhibit-read-only t))
 414     (save-excursion
 415       (goto-char from)
 416       (end-of-line)
 417       (outline-discard-overlays (point) to 'outline)
 418       (if flag
 419           (let ((o (make-overlay (point) to)))
 420             (overlay-put o 'invisible 'outline)
 421             (overlay-put o 'isearch-open-invisible
 422                          'outline-isearch-open-invisible)))))
 423   (run-hooks 'outline-view-change-hook))
 424
 425
 426 ;; Function to be set as an outline-isearch-open-invisible' property
 427 ;; to the overlay that makes the outline invisible (see
 428 ;; `outline-flag-region').
 429 (defun outline-isearch-open-invisible (overlay)
 430   (save-excursion
 431     (goto-char (overlay-start overlay))
 432     (show-entry)))
 433
 434
 435 ;; Exclude from the region BEG ... END all overlays
 436 ;; with a non-nil PROP property.
 437 ;; Exclude them by shrinking them to exclude BEG ... END,
 438 ;; or even by splitting them if necessary.
 439 ;; Overlays without a non-nil PROP property are not touched.
 440 (defun outline-discard-overlays (beg end prop)
 441   (if (< end beg)
 442       (setq beg (prog1 end (setq end beg))))
 443   (save-excursion
 444     (let ((overlays (overlays-in beg end))
 445           o
 446           o1)
 447       (while overlays
 448         (setq o (car overlays))
 449         (if (overlay-get o prop)
 450             ;; Either push this overlay outside beg...end
 451             ;; or split it to exclude beg...end
 452             ;; or delete it entirely (if it is contained in beg...end).
 453             (if (< (overlay-start o) beg)
 454                 (if (> (overlay-end o) end)
 455                     (progn
 456                       (setq o1 (outline-copy-overlay o))
 457                       (move-overlay o1 (overlay-start o1) beg)
 458                       (move-overlay o end (overlay-end o)))
 459                   (move-overlay o (overlay-start o) beg))
 460               (if (> (overlay-end o) end)
 461                   (move-overlay o end (overlay-end o))
 462                 (delete-overlay o))))
 463         (setq overlays (cdr overlays))))))
 464
 465 ;; Make a copy of overlay O, with the same beginning, end and properties.
 466 (defun outline-copy-overlay (o)
 467   (let ((o1 (make-overlay (overlay-start o) (overlay-end o)
 468                           (overlay-buffer o)))
 469         (props (overlay-properties o)))
 470     (while props
 471       (overlay-put o1 (car props) (nth 1 props))
 472       (setq props (cdr (cdr props))))
 473     o1))
 474 \f
 475 (defun hide-entry ()
 476   "Hide the body directly following this heading."
 477   (interactive)
 478   (outline-back-to-heading)
 479   (outline-end-of-heading)
 480   (save-excursion
 481    (outline-flag-region (point) (progn (outline-next-preface) (point)) t)))
 482
 483 (defun show-entry ()
 484   "Show the body directly following this heading.
 485 Show the heading too, if it is currently invisible."
 486   (interactive)
 487   (save-excursion
 488     (outline-back-to-heading t)
 489     (outline-flag-region (1- (point))
 490                          (progn (outline-next-preface) (point)) nil)))
 491
 492 (defun hide-body ()
 493   "Hide all of buffer except headings."
 494   (interactive)
 495   (hide-region-body (point-min) (point-max)))
 496
 497 (defun hide-region-body (start end)
 498   "Hide all body lines in the region, but not headings."
 499   (save-excursion
 500     (save-restriction
 501       (narrow-to-region start end)
 502       (goto-char (point-min))
 503       (if (outline-on-heading-p)
 504           (outline-end-of-heading))
 505       (while (not (eobp))
 506         (outline-flag-region (point)
 507                              (progn (outline-next-preface) (point)) t)
 508         (if (not (eobp))
 509             (progn
 510               (forward-char
 511                (if (looking-at "\n\n")
 512                    2 1))
 513               (outline-end-of-heading)))))))
 514
 515 (defun show-all ()
 516   "Show all of the text in the buffer."
 517   (interactive)
 518   (outline-flag-region (point-min) (point-max) nil))
 519
 520 (defun hide-subtree ()
 521   "Hide everything after this heading at deeper levels."
 522   (interactive)
 523   (outline-flag-subtree t))
 524
 525 (defun hide-leaves ()
 526   "Hide all body after this heading at deeper levels."
 527   (interactive)
 528   (outline-back-to-heading)
 529   (outline-end-of-heading)
 530   (hide-region-body (point) (progn (outline-end-of-subtree) (point))))
 531
 532 (defun show-subtree ()
 533   "Show everything after this heading at deeper levels."
 534   (interactive)
 535   (outline-flag-subtree nil))
 536
 537 (defun hide-sublevels (levels)
 538   "Hide everything but the top LEVELS levels of headers, in whole buffer."
 539   (interactive "p")
 540   (if (< levels 1)
 541       (error "Must keep at least one level of headers"))
 542   (setq levels (1- levels))
 543   (save-excursion
 544     (goto-char (point-min))
 545     ;; Keep advancing to the next top-level heading.
 546     (while (or (and (bobp) (outline-on-heading-p))
 547                (outline-next-heading))
 548       (let ((end (save-excursion (outline-end-of-subtree) (point))))
 549         ;; Hide everything under that.
 550         (outline-flag-region (point) end t)
 551         ;; Show the first LEVELS levels under that.
 552         (if (> levels 0)
 553             (show-children levels))
 554         ;; Move to the next, since we already found it.
 555         (goto-char end)))))
 556
 557 (defun hide-other ()
 558   "Hide everything except current body and parent and top-level headings."
 559   (interactive)
 560   (hide-sublevels 1)
 561   (save-excursion
 562     (outline-back-to-heading t)
 563     (show-entry)
 564     (while (condition-case nil (progn (outline-up-heading 1) t) (error nil))
 565       (outline-flag-region (1- (point))
 566                            (save-excursion (forward-line 1) (point))
 567                            nil))))
 568
 569 (defun outline-flag-subtree (flag)
 570   (save-excursion
 571     (outline-back-to-heading)
 572     (outline-end-of-heading)
 573     (outline-flag-region (point)
 574                           (progn (outline-end-of-subtree) (point))
 575                           flag)))
 576
 577 (defun outline-end-of-subtree ()
 578   (outline-back-to-heading)
 579   (let ((opoint (point))
 580         (first t)
 581         (level (funcall outline-level)))
 582     (while (and (not (eobp))
 583                 (or first (> (funcall outline-level) level)))
 584       (setq first nil)
 585       (outline-next-heading))
 586     (if (bolp)
 587         (progn
 588           ;; Go to end of line before heading
 589           (forward-char -1)
 590           (if (bolp)
 591               ;; leave blank line before heading
 592               (forward-char -1))))))
 593 \f
 594 (defun show-branches ()
 595   "Show all subheadings of this heading, but not their bodies."
 596   (interactive)
 597   (show-children 1000))
 598
 599 (defun show-children (&optional level)
 600   "Show all direct subheadings of this heading.
 601 Prefix arg LEVEL is how many levels below the current level should be shown.
 602 Default is enough to cause the following heading to appear."
 603   (interactive "P")
 604   (setq level
 605         (if level (prefix-numeric-value level)
 606           (save-excursion
 607             (outline-back-to-heading)
 608             (let ((start-level (funcall outline-level)))
 609               (outline-next-heading)
 610               (if (eobp)
 611                   1
 612                 (max 1 (- (funcall outline-level) start-level)))))))
 613   (save-excursion
 614     (save-restriction
 615       (outline-back-to-heading)
 616       (setq level (+ level (funcall outline-level)))
 617       (narrow-to-region (point)
 618                         (progn (outline-end-of-subtree)
 619                                (if (eobp) (point-max) (1+ (point)))))
 620       (goto-char (point-min))
 621       (while (and (not (eobp))
 622                   (progn
 623                     (outline-next-heading)
 624                     (not (eobp))))
 625         (if (<= (funcall outline-level) level)
 626             (save-excursion
 627               (outline-flag-region (save-excursion
 628                                      (forward-char -1)
 629                                      (if (bolp)
 630                                          (forward-char -1))
 631                                      (point))
 632                                    (progn (outline-end-of-heading) (point))
 633                                    nil)))))))
 634 \f
 635 (defun outline-up-heading (arg)
 636   "Move to the heading line of which the present line is a subheading.
 637 With argument, move up ARG levels."
 638   (interactive "p")
 639   (outline-back-to-heading)
 640   (if (eq (funcall outline-level) 1)
 641       (error "Already at top level of the outline"))
 642   (while (and (> (funcall outline-level) 1)
 643               (> arg 0)
 644               (not (bobp)))
 645     (let ((present-level (funcall outline-level)))
 646       (while (and (not (< (funcall outline-level) present-level))
 647                   (not (bobp)))
 648         (outline-previous-visible-heading 1))
 649       (setq arg (- arg 1)))))
 650
 651 (defun outline-forward-same-level (arg)
 652   "Move forward to the ARG'th subheading at same level as this one.
 653 Stop at the first and last subheadings of a superior heading."
 654   (interactive "p")
 655   (outline-back-to-heading)
 656   (while (> arg 0)
 657     (let ((point-to-move-to (save-excursion
 658                               (outline-get-next-sibling))))
 659       (if point-to-move-to
 660           (progn
 661             (goto-char point-to-move-to)
 662             (setq arg (1- arg)))
 663         (progn
 664           (setq arg 0)
 665           (error "No following same-level heading"))))))
 666
 667 (defun outline-get-next-sibling ()
 668   "Move to next heading of the same level, and return point or nil if none."
 669   (let ((level (funcall outline-level)))
 670     (outline-next-visible-heading 1)
 671     (while (and (> (funcall outline-level) level)
 672                 (not (eobp)))
 673       (outline-next-visible-heading 1))
 674     (if (< (funcall outline-level) level)
 675         nil
 676       (point))))
 677
 678 (defun outline-backward-same-level (arg)
 679   "Move backward to the ARG'th subheading at same level as this one.
 680 Stop at the first and last subheadings of a superior heading."
 681   (interactive "p")
 682   (outline-back-to-heading)
 683   (while (> arg 0)
 684     (let ((point-to-move-to (save-excursion
 685                               (outline-get-last-sibling))))
 686       (if point-to-move-to
 687           (progn
 688             (goto-char point-to-move-to)
 689             (setq arg (1- arg)))
 690         (progn
 691           (setq arg 0)
 692           (error "No previous same-level heading"))))))
 693
 694 (defun outline-get-last-sibling ()
 695   "Move to next heading of the same level, and return point or nil if none."
 696   (let ((level (funcall outline-level)))
 697     (outline-previous-visible-heading 1)
 698     (while (and (> (funcall outline-level) level)
 699                 (not (bobp)))
 700       (outline-previous-visible-heading 1))
 701     (if (< (funcall outline-level) level)
 702         nil
 703         (point))))
 704
 705 (provide 'outline)
 706 (provide 'noutline)
 707
 708 ;;; outline.el ends here