code.delx.au - gnu-emacs/blob - lisp/emacs-lisp/pp.el

   1 ;; pp.el --- pretty printer for Emacs Lisp
   2 ;; Copyright (C) 1989, 1993 Free Software Foundation, Inc.
   3
   4 ;; Author: Randal Schwartz <merlyn@ora.com>
   5
   6 ;; This file is part of GNU Emacs.
   7
   8 ;; GNU Emacs is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published by
  10 ;; the Free Software Foundation; either version 2, or (at your option)
  11 ;; any later version.
  12
  13 ;; GNU Emacs is distributed in the hope that it will be useful,
  14 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 ;; GNU General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  20 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  21
  22 ;;; Code:
  23
  24 (defvar pp-escape-newlines t
  25   "*Value of print-escape-newlines used by pp-* functions.")
  26
  27 (defun pp-to-string (object)
  28   "Return a string containing the pretty-printed representation of OBJECT,
  29 any Lisp object.  Quoting characters are used when needed to make output
  30 that `read' can handle, whenever this is possible."
  31   (save-excursion
  32     (set-buffer (generate-new-buffer " pp-to-string"))
  33     (unwind-protect
  34         (progn
  35           (emacs-lisp-mode)
  36           (let ((print-escape-newlines pp-escape-newlines))
  37             (prin1 object (current-buffer)))
  38           (goto-char (point-min))
  39           (while (not (eobp))
  40             ;; (message "%06d" (- (point-max) (point)))
  41             (cond
  42              ((looking-at "\\s\(")
  43               (while (looking-at "\\s(")
  44                 (forward-char 1)))
  45              ((and (looking-at "\\(quote[ \t]+\\)\\([^.)]\\)")
  46                    (> (match-beginning 1) 1)
  47                    (= ?\( (char-after (1- (match-beginning 1))))
  48                    ;; Make sure this is a two-element list.
  49                    (save-excursion
  50                      (goto-char (match-beginning 2))
  51                      (forward-sexp)
  52                      ;; (looking-at "[ \t]*\)")
  53                      ;; Avoid mucking with match-data; does this test work?
  54                      (char-equal ?\) (char-after (point)))))
  55               ;; -1 gets the paren preceding the quote as well.
  56               (delete-region (1- (match-beginning 1)) (match-end 1))
  57               (insert "'")
  58               (forward-sexp 1)
  59               (if (looking-at "[ \t]*\)")
  60                   (delete-region (match-beginning 0) (match-end 0))
  61                 (error "Malformed quote"))
  62               (backward-sexp 1))
  63              ((condition-case err-var
  64                   (prog1 t (down-list 1))
  65                 (error nil))
  66               (backward-char 1)
  67               (skip-chars-backward " \t")
  68               (delete-region
  69                (point)
  70                (progn (skip-chars-forward " \t") (point)))
  71               (if (not (char-equal ?' (char-after (1- (point)))))
  72                   (insert ?\n)))
  73              ((condition-case err-var
  74                   (prog1 t (up-list 1))
  75                 (error nil))
  76               (while (looking-at "\\s)")
  77                 (forward-char 1))
  78               (skip-chars-backward " \t")
  79               (delete-region
  80                (point)
  81                (progn (skip-chars-forward " \t") (point)))
  82               (if (not (char-equal ?' (char-after (1- (point)))))
  83                   (insert ?\n)))
  84              (t (goto-char (point-max)))))
  85           (goto-char (point-min))
  86           (indent-sexp)
  87           (buffer-string))
  88       (kill-buffer (current-buffer)))))
  89
  90 ;;;###autoload
  91 (defun pp (object &optional stream)
  92   "Output the pretty-printed representation of OBJECT, any Lisp object.
  93 Quoting characters are printed when needed to make output that `read'
  94 can handle, whenever this is possible.
  95 Output stream is STREAM, or value of `standard-output' (which see)."
  96   (princ (pp-to-string object) (or stream standard-output)))
  97
  98 ;;;###autoload
  99 (defun pp-eval-expression (expression)
 100   "Evaluate EXPRESSION and pretty-print value into a new display buffer.
 101 If the pretty-printed value fits on one line, the message line is used
 102 instead.  Value is also consed on to front of variable  values 's
 103 value."
 104   (interactive "xPp-eval: ")
 105   (setq values (cons (eval expression) values))
 106   (let* ((old-show-hook
 107           (or (let ((sym (if (> (string-to-int emacs-version) 18)
 108                              'temp-buffer-show-function
 109                            'temp-buffer-show-hook)))
 110                 (and (boundp 'sym) (symbol-value sym)))
 111               'display-buffer))
 112          (temp-buffer-show-hook
 113           (function
 114            (lambda (buf)
 115              (save-excursion
 116                (set-buffer buf)
 117                (goto-char (point-min))
 118                (end-of-line 1)
 119                (if (or (< (1+ (point)) (point-max))
 120                        (>= (- (point) (point-min)) (screen-width)))
 121                    (progn
 122                      (goto-char (point-min)) ; expected by some hooks ...
 123                      (funcall old-show-hook buf))
 124                  (message "%s" (buffer-substring (point-min) (point)))
 125                  (delete-windows-on buf) ; no need to kill it
 126                  )))))
 127          (temp-buffer-show-function temp-buffer-show-hook)) ; emacs19 name
 128     (with-output-to-temp-buffer "*Pp Eval Output*"
 129       (pp (car values)))
 130     (save-excursion
 131       (set-buffer "*Pp Eval Output*")
 132       (emacs-lisp-mode))))
 133
 134 ;;;###autoload
 135 (defun pp-eval-last-sexp (arg)
 136   "Run `pp-eval-expression' on sexp before point (which see).
 137 With argument, pretty-print output into current buffer.
 138 Ignores leading comment characters."
 139   (interactive "P")
 140   (let ((stab (syntax-table)) (pt (point)) start exp)
 141     (set-syntax-table emacs-lisp-mode-syntax-table)
 142     (save-excursion
 143       (forward-sexp -1)
 144       ;; If first line is commented, ignore all leading comments:
 145       (if (save-excursion (beginning-of-line) (looking-at "[ \t]*;"))
 146           (progn
 147             (setq exp (buffer-substring (point) pt))
 148             (while (string-match "\n[ \t]*;+" exp start)
 149               (setq start (1+ (match-beginning 0))
 150                     exp (concat (substring exp 0 start)
 151                                 (substring exp (match-end 0)))))
 152             (setq exp (read exp)))
 153         (setq exp (read (current-buffer)))))
 154     (set-syntax-table stab)
 155     (if arg
 156         (insert (pp-to-string (eval exp)))
 157       (pp-eval-expression exp))))
 158
 159 ;;; Test cases for quote
 160 ;; (pp-eval-expression ''(quote quote))
 161 ;; (pp-eval-expression ''((quote a) (quote b)))
 162 ;; (pp-eval-expression ''('a 'b))       ; same as above
 163 ;; (pp-eval-expression ''((quote (quote quote)) (quote quote)))
 164 ;; These do not satisfy the quote test.
 165 ;; (pp-eval-expression ''quote)
 166 ;; (pp-eval-expression ''(quote))
 167 ;; (pp-eval-expression ''(quote . quote))
 168 ;; (pp-eval-expression ''(quote a b))
 169 ;; (pp-eval-expression ''(quotefoo))
 170 ;; (pp-eval-expression ''(a b))
 171
 172 (provide 'pp)                           ; so (require 'pp) works
 173
 174 ;;; pp.el ends here.