code.delx.au - gnu-emacs/blob - lisp/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006, 2007 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 3, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  23 ;; Boston, MA 02110-1301, USA.
  24
  25 ;;; Commentary:
  26
  27 ;; This file contains a VC backend for the git version control
  28 ;; system.
  29 ;;
  30
  31 ;;; Installation:
  32
  33 ;; To install: put this file on the load-path and add Git to the list
  34 ;; of supported backends in `vc-handled-backends'; the following line,
  35 ;; placed in your ~/.emacs, will accomplish this:
  36 ;;
  37 ;;     (add-to-list 'vc-handled-backends 'Git)
  38
  39 ;;; Todo:
  40 ;;  - check if more functions could use vc-git-command instead
  41 ;;     of start-process.
  42 ;;  - changelog generation
  43
  44 ;; Implement the rest of the vc interface. See the comment at the
  45 ;; beginning of vc.el. The current status is:
  46 ;; ("??" means: "figure out what to do about it")
  47 ;;
  48 ;; FUNCTION NAME                                   STATUS
  49 ;; BACKEND PROPERTIES
  50 ;; * revision-granularity                          OK
  51 ;; STATE-QUERYING FUNCTIONS
  52 ;; * registered (file)                             OK
  53 ;; * state (file)                                  OK
  54 ;; - state-heuristic (file)                        NOT NEEDED
  55 ;; - dir-state (dir)                               OK
  56 ;; * workfile-version (file)                       OK
  57 ;; - latest-on-branch-p (file)                     NOT NEEDED
  58 ;; * checkout-model (file)                         OK
  59 ;; - workfile-unchanged-p (file)                   OK
  60 ;; - mode-line-string (file)                       NOT NEEDED
  61 ;; - dired-state-info (file)                       OK
  62 ;; STATE-CHANGING FUNCTIONS
  63 ;; * create-repo ()                                OK
  64 ;; * register (files &optional rev comment)        OK
  65 ;; - init-version (file)                           NOT NEEDED
  66 ;; - responsible-p (file)                          OK
  67 ;; - could-register (file)                         NOT NEEDED, DEFAULT IS GOOD
  68 ;; - receive-file (file rev)                       NOT NEEDED
  69 ;; - unregister (file)                             OK
  70 ;; * checkin (files rev comment)                   OK
  71 ;; * find-version (file rev buffer)                OK
  72 ;; * checkout (file &optional editable rev)        OK
  73 ;; * revert (file &optional contents-done)         OK
  74 ;; - rollback (files)                              COULD BE SUPPORTED
  75 ;; - merge (file rev1 rev2)                        It would be possible to merge changes into
  76 ;;                                                 a single file, but when committing they
  77 ;;                                                 wouldn't be identified as a merge by git,
  78 ;;                                                 so it's probably not a good idea.
  79 ;; - merge-news (file)                             see `merge'
  80 ;; - steal-lock (file &optional version)           NOT NEEDED
  81 ;; HISTORY FUNCTIONS
  82 ;; * print-log (files &optional buffer)            OK
  83 ;; - log-view-mode ()                              OK
  84 ;; - show-log-entry (version)                      NOT NEEDED, DEFAULT IS GOOD
  85 ;; - wash-log (file)                               COULD BE SUPPORTED
  86 ;; - logentry-check ()                             NOT NEEDED
  87 ;; - comment-history (file)                        ??
  88 ;; - update-changelog (files)                      COULD BE SUPPORTED
  89 ;; * diff (file &optional rev1 rev2 buffer)        OK
  90 ;; - revision-completion-table (file)              NOT SUPPORTED in emacs-22.x
  91 ;; - diff-tree (dir &optional rev1 rev2)           OK
  92 ;; - annotate-command (file buf &optional rev)     OK
  93 ;; - annotate-time ()                              OK
  94 ;; - annotate-current-time ()                      NOT NEEDED
  95 ;; - annotate-extract-revision-at-line ()          OK
  96 ;; SNAPSHOT SYSTEM
  97 ;; - create-snapshot (dir name branchp)            OK
  98 ;; - assign-name (file name)                       NOT NEEDED
  99 ;; - retrieve-snapshot (dir name update)           OK, needs to update buffers
 100 ;; MISCELLANEOUS
 101 ;; - make-version-backups-p (file)                 NOT NEEDED
 102 ;; - repository-hostname (dirname)                 NOT NEEDED
 103 ;; - previous-version (file rev)                   OK
 104 ;; - next-version (file rev)                       OK
 105 ;; - check-headers ()                              COULD BE SUPPORTED
 106 ;; - clear-headers ()                              NOT NEEDED
 107 ;; - delete-file (file)                            OK
 108 ;; - rename-file (old new)                         OK
 109 ;; - find-file-hook ()                             NOT NEEDED
 110 ;; - find-file-not-found-hook ()                   NOT NEEDED
 111
 112 (eval-when-compile (require 'cl) (require 'vc))
 113
 114 (defvar git-commits-coding-system 'utf-8
 115   "Default coding system for git commits.")
 116
 117 ;;; BACKEND PROPERTIES
 118
 119 (defun vc-git-revision-granularity ()
 120      'repository)
 121
 122 ;;; STATE-QUERYING FUNCTIONS
 123
 124 ;;;###autoload (defun vc-git-registered (file)
 125 ;;;###autoload   "Return non-nil if FILE is registered with git."
 126 ;;;###autoload   (if (vc-find-root file ".git")       ; short cut
 127 ;;;###autoload       (progn
 128 ;;;###autoload         (load "vc-git")
 129 ;;;###autoload         (vc-git-registered file))))
 130
 131 (defun vc-git-registered (file)
 132   "Check whether FILE is registered with git."
 133   (when (vc-git-root file)
 134     (with-temp-buffer
 135       (let* ((dir (file-name-directory file))
 136              (name (file-relative-name file dir)))
 137         (and (ignore-errors
 138               (when dir (cd dir))
 139               (eq 0 (call-process "git" nil '(t nil) nil "ls-files" "-c" "-z" "--" name)))
 140              (let ((str (buffer-string)))
 141                (and (> (length str) (length name))
 142                     (string= (substring str 0 (1+ (length name))) (concat name "\0")))))))))
 143
 144 (defun vc-git-state (file)
 145   "Git-specific version of `vc-state'."
 146   (call-process "git" nil nil nil "add" "--refresh" "--" (file-relative-name file))
 147   (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
 148     (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} [ADMU]\0[^\0]+\0" diff))
 149         'edited
 150       'up-to-date)))
 151
 152 (defun vc-git-dir-state (dir)
 153   (with-temp-buffer
 154     (vc-git-command (current-buffer) nil nil "ls-files" "-t")
 155     (goto-char (point-min))
 156     (let ((status-char nil)
 157           (file nil))
 158       (while (not (eobp))
 159         (setq status-char (char-after))
 160         (setq file
 161               (expand-file-name
 162                (buffer-substring-no-properties (+ (point) 2) (line-end-position))))
 163         (cond
 164          ;; The rest of the possible states in "git ls-files -t" output:
 165          ;;      R              removed/deleted
 166          ;;      K              to be killed
 167          ;; should not show up in vc-dired, so don't deal with them
 168          ;; here.
 169          ((eq status-char ?H)
 170           (vc-file-setprop file 'vc-state 'up-to-date))
 171          ((eq status-char ?M)
 172           (vc-file-setprop file 'vc-state 'edited))
 173          ((eq status-char ?C)
 174           (vc-file-setprop file 'vc-state 'edited))
 175          ((eq status-char ??)
 176           (vc-file-setprop file 'vc-backend 'none)
 177           (vc-file-setprop file 'vc-state 'nil)))
 178         (forward-line)))))
 179
 180 (defun vc-git-workfile-version (file)
 181   "Git-specific version of `vc-workfile-version'."
 182   (let ((str (with-output-to-string
 183                (with-current-buffer standard-output
 184                  (call-process "git" nil '(t nil) nil "symbolic-ref" "HEAD")))))
 185     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 186         (match-string 2 str)
 187       str)))
 188
 189 (defun vc-git-checkout-model (file)
 190   'implicit)
 191
 192 (defun vc-git-workfile-unchanged-p (file)
 193   (eq 'up-to-date (vc-git-state file)))
 194
 195 (defun vc-git-dired-state-info (file)
 196   "Git-specific version of `vc-dired-state-info'."
 197   (let ((git-state (vc-state file)))
 198     (if (eq git-state 'edited)
 199         "(modified)"
 200       ;; fall back to the default VC representation
 201       (vc-default-dired-state-info 'Git file))))
 202
 203 ;;; STATE-CHANGING FUNCTIONS
 204
 205 (defun vc-git-create-repo ()
 206   "Create a new Git repository."
 207   (vc-git-command nil 0 nil "init"))
 208
 209 (defun vc-git-register (files &optional rev comment)
 210   "Register FILE into the git version-control system."
 211   (vc-git-command nil 0 files "update-index" "--add" "--"))
 212
 213 (defalias 'vc-git-responsible-p 'vc-git-root)
 214
 215 (defun vc-git-unregister (file)
 216   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 217
 218
 219 (defun vc-git-checkin (files rev comment)
 220   (let ((coding-system-for-write git-commits-coding-system))
 221     (vc-git-command nil 0 files "commit" "-m" comment "--only" "--")))
 222
 223 (defun vc-git-find-version (file rev buffer)
 224   (let ((coding-system-for-read 'binary)
 225         (coding-system-for-write 'binary)
 226         (fullname (substring
 227                    (vc-git--run-command-string
 228                     file "ls-files" "-z" "--full-name" "--")
 229                    0 -1)))
 230     (vc-git-command
 231      buffer 0
 232      (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
 233
 234 (defun vc-git-checkout (file &optional editable rev)
 235   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 236
 237 (defun vc-git-revert (file &optional contents-done)
 238   "Revert FILE to the version stored in the git repository."
 239   (if contents-done
 240       (vc-git-command nil 0 file "update-index" "--")
 241     (vc-git-command nil 0 file "checkout" "HEAD")))
 242
 243 ;;; HISTORY FUNCTIONS
 244
 245 (defun vc-git-print-log (files &optional buffer)
 246   "Get change log associated with FILES."
 247   (let ((coding-system-for-read git-commits-coding-system)
 248         ;; Support both the old print-log interface that passes a
 249         ;; single file, and the new one that passes a file list.
 250         (flist (if (listp files) files (list files))))
 251     ;; `vc-do-command' creates the buffer, but we need it before running
 252     ;; the command.
 253     (vc-setup-buffer buffer)
 254     ;; If the buffer exists from a previous invocation it might be
 255     ;; read-only.
 256     (let ((inhibit-read-only t))
 257       ;; XXX `log-view-mode' needs to have something to identify where
 258       ;; the log for each individual file starts. It seems that by
 259       ;; default git does not output this info. So loop here and call
 260       ;; "git rev-list" on each file separately to make sure that each
 261       ;; file gets a "File:" header before the corresponding
 262       ;; log. Maybe there is a way to do this with one command...
 263       (dolist (file flist)
 264         (with-current-buffer
 265             buffer
 266           (insert "File: " (file-name-nondirectory file) "\n"))
 267         (vc-git-command buffer 'async (file-relative-name file)
 268                         "rev-list" "--pretty" "HEAD" "--")))))
 269
 270 (defvar log-view-message-re)
 271 (defvar log-view-file-re)
 272 (defvar log-view-font-lock-keywords)
 273
 274 (define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
 275   (require 'add-log) ;; we need the faces add-log
 276   ;; Don't have file markers, so use impossible regexp.
 277   (set (make-local-variable 'log-view-file-re) "^File:[ \t]+\\(.+\\)")
 278   (set (make-local-variable 'log-view-message-re)
 279        "^commit *\\([0-9a-z]+\\)")
 280   (set (make-local-variable 'log-view-font-lock-keywords)
 281        (append
 282        `((,log-view-message-re  (1 'change-log-acknowledgement))
 283          (,log-view-file-re (1 'change-log-file-face)))
 284          ;; Handle the case:
 285          ;; user: foo@bar
 286          '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 287             (1 'change-log-email))
 288            ;; Handle the case:
 289            ;; user: FirstName LastName <foo@bar>
 290            ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 291             (1 'change-log-name)
 292             (2 'change-log-email))
 293            ("^Date:   \\(.+\\)" (1 'change-log-date))
 294            ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 295
 296 (defun vc-git-diff (files &optional rev1 rev2 buffer)
 297   (let ((buf (or buffer "*vc-diff*")))
 298     (if (and rev1 rev2)
 299         (vc-git-command buf 1 files "diff-tree" "--exit-code" "-p" rev1 rev2 "--")
 300       (vc-git-command buf 1 files "diff-index" "--exit-code" "-p" (or rev1 "HEAD") "--"))))
 301
 302 (defun vc-git-revision-table (file)
 303   (let ((table (list "HEAD")))
 304     (with-temp-buffer
 305       (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
 306       (goto-char (point-min))
 307       (while (re-search-forward "^refs/\\(heads\\|tags\\)/\\(.*\\)$" nil t)
 308         (push (match-string 2) table)))
 309     table))
 310
 311 (defun vc-git-revision-completion-table (file)
 312   (lexical-let ((file file)
 313                 table)
 314     (setq table (lazy-completion-table
 315                  table (lambda () (vc-git-revision-table file))))
 316     table))
 317
 318 (defun vc-git-diff-tree (dir &optional rev1 rev2)
 319   (vc-git-diff dir rev1 rev2))
 320
 321 (defun vc-git-annotate-command (file buf &optional rev)
 322   ;; FIXME: rev is ignored
 323   (let ((name (file-relative-name file)))
 324     (vc-git-command buf 0 name "blame" (if rev (concat "-r" rev)))))
 325
 326 (defun vc-git-annotate-time ()
 327   (and (re-search-forward "[0-9a-f]+ (.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+)" nil t)
 328        (vc-annotate-convert-time
 329         (apply #'encode-time (mapcar (lambda (match) (string-to-number (match-string match))) '(6 5 4 3 2 1 7))))))
 330
 331 (defun vc-git-annotate-extract-revision-at-line ()
 332  (save-excursion
 333    (move-beginning-of-line 1)
 334    (and (looking-at "[0-9a-f]+")
 335         (buffer-substring-no-properties (match-beginning 0) (match-end 0)))))
 336
 337 ;;; SNAPSHOT SYSTEM
 338
 339 (defun vc-git-create-snapshot (dir name branchp)
 340   (let ((default-directory dir))
 341     (and (vc-git-command nil 0 nil "update-index" "--refresh")
 342          (if branchp
 343              (vc-git-command nil 0 nil "checkout" "-b" name)
 344            (vc-git-command nil 0 nil "tag" name)))))
 345
 346 (defun vc-git-retrieve-snapshot (dir name update)
 347   (let ((default-directory dir))
 348     (vc-git-command nil 0 nil "checkout" name)
 349     ;; FIXME: update buffers if `update' is true
 350     ))
 351
 352
 353 ;;; MISCELLANEOUS
 354
 355 (defun vc-git-previous-version (file rev)
 356   "Git-specific version of `vc-previous-version'."
 357   (let ((default-directory (file-name-directory (expand-file-name file)))
 358         (file (file-name-nondirectory file)))
 359     (vc-git-symbolic-commit
 360      (with-temp-buffer
 361        (and
 362         (zerop
 363          (call-process "git" nil '(t nil) nil "rev-list"
 364                        "-2" rev "--" file))
 365         (goto-char (point-max))
 366         (bolp)
 367         (zerop (forward-line -1))
 368         (not (bobp))
 369         (buffer-substring-no-properties
 370            (point)
 371            (1- (point-max))))))))
 372
 373 (defun vc-git-next-version (file rev)
 374   "Git-specific version of `vc-next-version'."
 375   (let* ((default-directory (file-name-directory
 376                              (expand-file-name file)))
 377         (file (file-name-nondirectory file))
 378         (current-rev
 379          (with-temp-buffer
 380            (and
 381             (zerop
 382              (call-process "git" nil '(t nil) nil "rev-list"
 383                            "-1" rev "--" file))
 384             (goto-char (point-max))
 385             (bolp)
 386             (zerop (forward-line -1))
 387             (bobp)
 388             (buffer-substring-no-properties
 389              (point)
 390              (1- (point-max)))))))
 391     (and current-rev
 392          (vc-git-symbolic-commit
 393           (with-temp-buffer
 394             (and
 395              (zerop
 396               (call-process "git" nil '(t nil) nil "rev-list"
 397                             "HEAD" "--" file))
 398              (goto-char (point-min))
 399              (search-forward current-rev nil t)
 400              (zerop (forward-line -1))
 401              (buffer-substring-no-properties
 402               (point)
 403               (progn (forward-line 1) (1- (point))))))))))
 404
 405 (defun vc-git-delete-file (file)
 406   (vc-git-command nil 0 file "rm" "-f" "--"))
 407
 408 (defun vc-git-rename-file (old new)
 409   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
 410
 411 \f
 412 ;;; Internal commands
 413
 414 (defun vc-git-root (file)
 415   (vc-find-root file ".git"))
 416
 417 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
 418   "A wrapper around `vc-do-command' for use in vc-git.el.
 419 The difference to vc-do-command is that this function always invokes `git'."
 420   (apply 'vc-do-command buffer okstatus "git" file-or-list flags))
 421
 422 (defun vc-git--run-command-string (file &rest args)
 423   "Run a git command on FILE and return its output as string."
 424   (let* ((ok t)
 425          (str (with-output-to-string
 426                 (with-current-buffer standard-output
 427                   (unless (eq 0 (apply #'call-process "git" nil '(t nil) nil
 428                                        (append args (list (file-relative-name file)))))
 429                     (setq ok nil))))))
 430     (and ok str)))
 431
 432 (defun vc-git-symbolic-commit (commit)
 433   "Translate COMMIT string into symbolic form.
 434 Returns nil if not possible."
 435   (and commit
 436        (with-temp-buffer
 437          (and
 438           (zerop
 439            (call-process "git" nil '(t nil) nil "name-rev"
 440                          "--name-only" "--tags"
 441                          commit))
 442           (goto-char (point-min))
 443           (= (forward-line 2) 1)
 444           (bolp)
 445           (buffer-substring-no-properties (point-min) (1- (point-max)))))))
 446
 447 (provide 'vc-git)
 448
 449 ;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
 450 ;;; vc-git.el ends here