code.delx.au - gnu-emacs/blob - lisp/font-lock.el

   1 ;;; font-lock.el --- Electric font lock mode
   2
   3 ;; Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4 ;;   2000, 2001, 2002, 2003, 2004 2005  Free Software Foundation, Inc.
   5
   6 ;; Author: jwz, then rms, then sm
   7 ;; Maintainer: FSF
   8 ;; Keywords: languages, faces
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28
  29 ;; Font Lock mode is a minor mode that causes your comments to be displayed in
  30 ;; one face, strings in another, reserved words in another, and so on.
  31 ;;
  32 ;; Comments will be displayed in `font-lock-comment-face'.
  33 ;; Strings will be displayed in `font-lock-string-face'.
  34 ;; Regexps are used to display selected patterns in other faces.
  35 ;;
  36 ;; To make the text you type be fontified, use M-x font-lock-mode RET.
  37 ;; When this minor mode is on, the faces of the current line are updated with
  38 ;; every insertion or deletion.
  39 ;;
  40 ;; To turn Font Lock mode on automatically, add this to your ~/.emacs file:
  41 ;;
  42 ;;  (add-hook 'emacs-lisp-mode-hook 'turn-on-font-lock)
  43 ;;
  44 ;; Or if you want to turn Font Lock mode on in many modes:
  45 ;;
  46 ;;  (global-font-lock-mode t)
  47 ;;
  48 ;; Fontification for a particular mode may be available in a number of levels
  49 ;; of decoration.  The higher the level, the more decoration, but the more time
  50 ;; it takes to fontify.  See the variable `font-lock-maximum-decoration', and
  51 ;; also the variable `font-lock-maximum-size'.  Support modes for Font Lock
  52 ;; mode can be used to speed up Font Lock mode.  See `font-lock-support-mode'.
  53 \f
  54 ;;; How Font Lock mode fontifies:
  55
  56 ;; When Font Lock mode is turned on in a buffer, it (a) fontifies the entire
  57 ;; buffer and (b) installs one of its fontification functions on one of the
  58 ;; hook variables that are run by Emacs after every buffer change (i.e., an
  59 ;; insertion or deletion).  Fontification means the replacement of `face' text
  60 ;; properties in a given region; Emacs displays text with these `face' text
  61 ;; properties appropriately.
  62 ;;
  63 ;; Fontification normally involves syntactic (i.e., strings and comments) and
  64 ;; regexp (i.e., keywords and everything else) passes.  There are actually
  65 ;; three passes; (a) the syntactic keyword pass, (b) the syntactic pass and (c)
  66 ;; the keyword pass.  Confused?
  67 ;;
  68 ;; The syntactic keyword pass places `syntax-table' text properties in the
  69 ;; buffer according to the variable `font-lock-syntactic-keywords'.  It is
  70 ;; necessary because Emacs' syntax table is not powerful enough to describe all
  71 ;; the different syntactic constructs required by the sort of people who decide
  72 ;; that a single quote can be syntactic or not depending on the time of day.
  73 ;; (What sort of person could decide to overload the meaning of a quote?)
  74 ;; Obviously the syntactic keyword pass must occur before the syntactic pass.
  75 ;;
  76 ;; The syntactic pass places `face' text properties in the buffer according to
  77 ;; syntactic context, i.e., according to the buffer's syntax table and buffer
  78 ;; text's `syntax-table' text properties.  It involves using a syntax parsing
  79 ;; function to determine the context of different parts of a region of text.  A
  80 ;; syntax parsing function is necessary because generally strings and/or
  81 ;; comments can span lines, and so the context of a given region is not
  82 ;; necessarily apparent from the content of that region.  Because the keyword
  83 ;; pass only works within a given region, it is not generally appropriate for
  84 ;; syntactic fontification.  This is the first fontification pass that makes
  85 ;; changes visible to the user; it fontifies strings and comments.
  86 ;;
  87 ;; The keyword pass places `face' text properties in the buffer according to
  88 ;; the variable `font-lock-keywords'.  It involves searching for given regexps
  89 ;; (or calling given search functions) within the given region.  This is the
  90 ;; second fontification pass that makes changes visible to the user; it
  91 ;; fontifies language reserved words, etc.
  92 ;;
  93 ;; Oh, and the answer is, "Yes, obviously just about everything should be done
  94 ;; in a single syntactic pass, but the only syntactic parser available
  95 ;; understands only strings and comments."  Perhaps one day someone will write
  96 ;; some syntactic parsers for common languages and a son-of-font-lock.el could
  97 ;; use them rather then relying so heavily on the keyword (regexp) pass.
  98
  99 ;;; How Font Lock mode supports modes or is supported by modes:
 100
 101 ;; Modes that support Font Lock mode do so by defining one or more variables
 102 ;; whose values specify the fontification.  Font Lock mode knows of these
 103 ;; variable names from (a) the buffer local variable `font-lock-defaults', if
 104 ;; non-nil, or (b) the global variable `font-lock-defaults-alist', if the major
 105 ;; mode has an entry.  (Font Lock mode is set up via (a) where a mode's
 106 ;; patterns are distributed with the mode's package library, and (b) where a
 107 ;; mode's patterns are distributed with font-lock.el itself.  An example of (a)
 108 ;; is Pascal mode, an example of (b) is Lisp mode.  Normally, the mechanism is
 109 ;; (a); (b) is used where it is not clear which package library should contain
 110 ;; the pattern definitions.)  Font Lock mode chooses which variable to use for
 111 ;; fontification based on `font-lock-maximum-decoration'.
 112 ;;
 113 ;; Font Lock mode fontification behaviour can be modified in a number of ways.
 114 ;; See the below comments and the comments distributed throughout this file.
 115
 116 ;;; Constructing patterns:
 117
 118 ;; See the documentation for the variable `font-lock-keywords'.
 119 ;;
 120 ;; Efficient regexps for use as MATCHERs for `font-lock-keywords' and
 121 ;; `font-lock-syntactic-keywords' can be generated via the function
 122 ;; `regexp-opt'.
 123
 124 ;;; Adding patterns for modes that already support Font Lock:
 125
 126 ;; Though Font Lock highlighting patterns already exist for many modes, it's
 127 ;; likely there's something that you want fontified that currently isn't, even
 128 ;; at the maximum fontification level.  You can add highlighting patterns via
 129 ;; `font-lock-add-keywords'.  For example, say in some C
 130 ;; header file you #define the token `and' to expand to `&&', etc., to make
 131 ;; your C code almost readable.  In your ~/.emacs there could be:
 132 ;;
 133 ;;  (font-lock-add-keywords 'c-mode '("\\<\\(and\\|or\\|not\\)\\>"))
 134 ;;
 135 ;; Some modes provide specific ways to modify patterns based on the values of
 136 ;; other variables.  For example, additional C types can be specified via the
 137 ;; variable `c-font-lock-extra-types'.
 138
 139 ;;; Adding patterns for modes that do not support Font Lock:
 140
 141 ;; Not all modes support Font Lock mode.  If you (as a user of the mode) add
 142 ;; patterns for a new mode, you must define in your ~/.emacs a variable or
 143 ;; variables that specify regexp fontification.  Then, you should indicate to
 144 ;; Font Lock mode, via the mode hook setting `font-lock-defaults', exactly what
 145 ;; support is required.  For example, say Foo mode should have the following
 146 ;; regexps fontified case-sensitively, and comments and strings should not be
 147 ;; fontified automagically.  In your ~/.emacs there could be:
 148 ;;
 149 ;;  (defvar foo-font-lock-keywords
 150 ;;    '(("\\<\\(one\\|two\\|three\\)\\>" . font-lock-keyword-face)
 151 ;;      ("\\<\\(four\\|five\\|six\\)\\>" . font-lock-type-face))
 152 ;;    "Default expressions to highlight in Foo mode.")
 153 ;;
 154 ;;  (add-hook 'foo-mode-hook
 155 ;;   (lambda ()
 156 ;;     (make-local-variable 'font-lock-defaults)
 157 ;;     (setq font-lock-defaults '(foo-font-lock-keywords t))))
 158
 159 ;;; Adding Font Lock support for modes:
 160
 161 ;; Of course, it would be better that the mode already supports Font Lock mode.
 162 ;; The package author would do something similar to above.  The mode must
 163 ;; define at the top-level a variable or variables that specify regexp
 164 ;; fontification.  Then, the mode command should indicate to Font Lock mode,
 165 ;; via `font-lock-defaults', exactly what support is required.  For example,
 166 ;; say Bar mode should have the following regexps fontified case-insensitively,
 167 ;; and comments and strings should be fontified automagically.  In bar.el there
 168 ;; could be:
 169 ;;
 170 ;;  (defvar bar-font-lock-keywords
 171 ;;    '(("\\<\\(uno\\|due\\|tre\\)\\>" . font-lock-keyword-face)
 172 ;;      ("\\<\\(quattro\\|cinque\\|sei\\)\\>" . font-lock-type-face))
 173 ;;    "Default expressions to highlight in Bar mode.")
 174 ;;
 175 ;; and within `bar-mode' there could be:
 176 ;;
 177 ;;  (make-local-variable 'font-lock-defaults)
 178 ;;  (setq font-lock-defaults '(bar-font-lock-keywords nil t))
 179 \f
 180 ;; What is fontification for?  You might say, "It's to make my code look nice."
 181 ;; I think it should be for adding information in the form of cues.  These cues
 182 ;; should provide you with enough information to both (a) distinguish between
 183 ;; different items, and (b) identify the item meanings, without having to read
 184 ;; the items and think about it.  Therefore, fontification allows you to think
 185 ;; less about, say, the structure of code, and more about, say, why the code
 186 ;; doesn't work.  Or maybe it allows you to think less and drift off to sleep.
 187 ;;
 188 ;; So, here are my opinions/advice/guidelines:
 189 ;;
 190 ;; - Highlight conceptual objects, such as function and variable names, and
 191 ;;   different objects types differently, i.e., (a) and (b) above, highlight
 192 ;;   function names differently to variable names.
 193 ;; - Keep the faces distinct from each other as far as possible.
 194 ;;   i.e., (a) above.
 195 ;; - Use the same face for the same conceptual object, across all modes.
 196 ;;   i.e., (b) above, all modes that have items that can be thought of as, say,
 197 ;;   keywords, should be highlighted with the same face, etc.
 198 ;; - Make the face attributes fit the concept as far as possible.
 199 ;;   i.e., function names might be a bold colour such as blue, comments might
 200 ;;   be a bright colour such as red, character strings might be brown, because,
 201 ;;   err, strings are brown (that was not the reason, please believe me).
 202 ;; - Don't use a non-nil OVERRIDE unless you have a good reason.
 203 ;;   Only use OVERRIDE for special things that are easy to define, such as the
 204 ;;   way `...' quotes are treated in strings and comments in Emacs Lisp mode.
 205 ;;   Don't use it to, say, highlight keywords in commented out code or strings.
 206 ;; - Err, that's it.
 207 \f
 208 ;;; Code:
 209
 210 (require 'syntax)
 211
 212 ;; Define core `font-lock' group.
 213 (defgroup font-lock '((jit-lock custom-group))
 214   "Font Lock mode text highlighting package."
 215   :link '(custom-manual "(emacs)Font Lock")
 216   :link '(custom-manual "(elisp)Font Lock Mode")
 217   :group 'faces)
 218
 219 (defgroup font-lock-highlighting-faces nil
 220   "Faces for highlighting text."
 221   :prefix "font-lock-"
 222   :group 'font-lock)
 223
 224 (defgroup font-lock-extra-types nil
 225   "Extra mode-specific type names for highlighting declarations."
 226   :group 'font-lock)
 227
 228 ;; Define support mode groups here to impose `font-lock' group order.
 229 (defgroup fast-lock nil
 230   "Font Lock support mode to cache fontification."
 231   :load 'fast-lock
 232   :group 'font-lock)
 233
 234 (defgroup lazy-lock nil
 235   "Font Lock support mode to fontify lazily."
 236   :load 'lazy-lock
 237   :group 'font-lock)
 238 \f
 239 ;; User variables.
 240
 241 (defcustom font-lock-maximum-size 256000
 242   "*Maximum size of a buffer for buffer fontification.
 243 Only buffers less than this can be fontified when Font Lock mode is turned on.
 244 If nil, means size is irrelevant.
 245 If a list, each element should be a cons pair of the form (MAJOR-MODE . SIZE),
 246 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 247  ((c-mode . 256000) (c++-mode . 256000) (rmail-mode . 1048576))
 248 means that the maximum size is 250K for buffers in C or C++ modes, one megabyte
 249 for buffers in Rmail mode, and size is irrelevant otherwise."
 250   :type '(choice (const :tag "none" nil)
 251                  (integer :tag "size")
 252                  (repeat :menu-tag "mode specific" :tag "mode specific"
 253                          :value ((t . nil))
 254                          (cons :tag "Instance"
 255                                (radio :tag "Mode"
 256                                       (const :tag "all" t)
 257                                       (symbol :tag "name"))
 258                                (radio :tag "Size"
 259                                       (const :tag "none" nil)
 260                                       (integer :tag "size")))))
 261   :group 'font-lock)
 262
 263 (defcustom font-lock-maximum-decoration t
 264   "*Maximum decoration level for fontification.
 265 If nil, use the default decoration (typically the minimum available).
 266 If t, use the maximum decoration available.
 267 If a number, use that level of decoration (or if not available the maximum).
 268 If a list, each element should be a cons pair of the form (MAJOR-MODE . LEVEL),
 269 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 270  ((c-mode . t) (c++-mode . 2) (t . 1))
 271 means use the maximum decoration available for buffers in C mode, level 2
 272 decoration for buffers in C++ mode, and level 1 decoration otherwise."
 273   :type '(choice (const :tag "default" nil)
 274                  (const :tag "maximum" t)
 275                  (integer :tag "level" 1)
 276                  (repeat :menu-tag "mode specific" :tag "mode specific"
 277                          :value ((t . t))
 278                          (cons :tag "Instance"
 279                                (radio :tag "Mode"
 280                                       (const :tag "all" t)
 281                                       (symbol :tag "name"))
 282                                (radio :tag "Decoration"
 283                                       (const :tag "default" nil)
 284                                       (const :tag "maximum" t)
 285                                       (integer :tag "level" 1)))))
 286   :group 'font-lock)
 287
 288 (defcustom font-lock-verbose 0
 289   "*If non-nil, means show status messages for buffer fontification.
 290 If a number, only buffers greater than this size have fontification messages."
 291   :type '(choice (const :tag "never" nil)
 292                  (other :tag "always" t)
 293                  (integer :tag "size"))
 294   :group 'font-lock)
 295
 296 (defcustom font-lock-lines-before 1
 297   "*Number of lines before the changed text to include in refontification."
 298   :type 'integer
 299   :group 'font-lock
 300   :version "22.1")
 301 \f
 302
 303 ;; Originally these variable values were face names such as `bold' etc.
 304 ;; Now we create our own faces, but we keep these variables for compatibility
 305 ;; and they give users another mechanism for changing face appearance.
 306 ;; We now allow a FACENAME in `font-lock-keywords' to be any expression that
 307 ;; returns a face.  So the easiest thing is to continue using these variables,
 308 ;; rather than sometimes evaling FACENAME and sometimes not.  sm.
 309 (defvar font-lock-comment-face          'font-lock-comment-face
 310   "Face name to use for comments.")
 311
 312 (defvar font-lock-comment-delimiter-face 'font-lock-comment-delimiter-face
 313   "Face name to use for comment delimiters.")
 314
 315 (defvar font-lock-string-face           'font-lock-string-face
 316   "Face name to use for strings.")
 317
 318 (defvar font-lock-doc-face              'font-lock-doc-face
 319   "Face name to use for documentation.")
 320
 321 (defvar font-lock-keyword-face          'font-lock-keyword-face
 322   "Face name to use for keywords.")
 323
 324 (defvar font-lock-builtin-face          'font-lock-builtin-face
 325   "Face name to use for builtins.")
 326
 327 (defvar font-lock-function-name-face    'font-lock-function-name-face
 328   "Face name to use for function names.")
 329
 330 (defvar font-lock-variable-name-face    'font-lock-variable-name-face
 331   "Face name to use for variable names.")
 332
 333 (defvar font-lock-type-face             'font-lock-type-face
 334   "Face name to use for type and class names.")
 335
 336 (defvar font-lock-constant-face         'font-lock-constant-face
 337   "Face name to use for constant and label names.")
 338
 339 (defvar font-lock-warning-face          'font-lock-warning-face
 340   "Face name to use for things that should stand out.")
 341
 342 (defvar font-lock-preprocessor-face     'font-lock-preprocessor-face
 343   "Face name to use for preprocessor directives.")
 344
 345 (defvar font-lock-reference-face        'font-lock-constant-face)
 346 (make-obsolete-variable 'font-lock-reference-face 'font-lock-constant-face)
 347
 348 ;; Fontification variables:
 349
 350 (defvar font-lock-keywords nil
 351   "A list of the keywords to highlight.
 352 There are two kinds of values: user-level, and compiled.
 353
 354 A user-level keywords list is what a major mode or the user would
 355 set up.  Normally the list would come from `font-lock-defaults'.
 356 through selection of a fontification level and evaluation of any
 357 contained expressions.  You can also alter it by calling
 358 `font-lock-add-keywords' or `font-lock-remove-keywords' with MODE = nil.
 359
 360 Each element in a user-level keywords list should have one of these forms:
 361
 362  MATCHER
 363  (MATCHER . MATCH)
 364  (MATCHER . FACENAME)
 365  (MATCHER . HIGHLIGHT)
 366  (MATCHER HIGHLIGHT ...)
 367  (eval . FORM)
 368
 369 where MATCHER can be either the regexp to search for, or the function name to
 370 call to make the search (called with one argument, the limit of the search;
 371 it should return non-nil, move point, and set `match-data' appropriately iff
 372 it succeeds; like `re-search-forward' would).
 373 MATCHER regexps can be generated via the function `regexp-opt'.
 374
 375 FORM is an expression, whose value should be a keyword element, evaluated when
 376 the keyword is (first) used in a buffer.  This feature can be used to provide a
 377 keyword that can only be generated when Font Lock mode is actually turned on.
 378
 379 HIGHLIGHT should be either MATCH-HIGHLIGHT or MATCH-ANCHORED.
 380
 381 For highlighting single items, for example each instance of the word \"foo\",
 382 typically only MATCH-HIGHLIGHT is required.
 383 However, if an item or (typically) items are to be highlighted following the
 384 instance of another item (the anchor), for example each instance of the
 385 word \"bar\" following the word \"anchor\" then MATCH-ANCHORED may be required.
 386
 387 MATCH-HIGHLIGHT should be of the form:
 388
 389  (MATCH FACENAME [[OVERRIDE [LAXMATCH]])
 390
 391 MATCH is the subexpression of MATCHER to be highlighted.  FACENAME is an
 392 expression whose value is the face name to use.  Face default attributes
 393 can be modified via \\[customize].  Instead of a face, FACENAME can
 394 evaluate to a property list of the form (face FACE PROP1 VAL1 PROP2 VAL2 ...)
 395 in which case all the listed text-properties will be set rather than
 396 just FACE.  In such a case, you will most likely want to put those
 397 properties in `font-lock-extra-managed-props' or to override
 398 `font-lock-unfontify-region-function'.
 399
 400 OVERRIDE and LAXMATCH are flags.  If OVERRIDE is t, existing fontification can
 401 be overwritten.  If `keep', only parts not already fontified are highlighted.
 402 If `prepend' or `append', existing fontification is merged with the new, in
 403 which the new or existing fontification, respectively, takes precedence.
 404 If LAXMATCH is non-nil, no error is signaled if there is no MATCH in MATCHER.
 405
 406 For example, an element of the form highlights (if not already highlighted):
 407
 408  \"\\\\\\=<foo\\\\\\=>\"                discrete occurrences of \"foo\" in the value of the
 409                         variable `font-lock-keyword-face'.
 410  (\"fu\\\\(bar\\\\)\" . 1)      substring \"bar\" within all occurrences of \"fubar\" in
 411                         the value of `font-lock-keyword-face'.
 412  (\"fubar\" . fubar-face)       Occurrences of \"fubar\" in the value of `fubar-face'.
 413  (\"foo\\\\|bar\" 0 foo-bar-face t)
 414                         occurrences of either \"foo\" or \"bar\" in the value
 415                         of `foo-bar-face', even if already highlighted.
 416  (fubar-match 1 fubar-face)
 417                         the first subexpression within all occurrences of
 418                         whatever the function `fubar-match' finds and matches
 419                         in the value of `fubar-face'.
 420
 421 MATCH-ANCHORED should be of the form:
 422
 423  (MATCHER PRE-MATCH-FORM POST-MATCH-FORM MATCH-HIGHLIGHT ...)
 424
 425 where MATCHER is a regexp to search for or the function name to call to make
 426 the search, as for MATCH-HIGHLIGHT above, but with one exception; see below.
 427 PRE-MATCH-FORM and POST-MATCH-FORM are evaluated before the first, and after
 428 the last, instance MATCH-ANCHORED's MATCHER is used.  Therefore they can be
 429 used to initialise before, and cleanup after, MATCHER is used.  Typically,
 430 PRE-MATCH-FORM is used to move to some position relative to the original
 431 MATCHER, before starting with MATCH-ANCHORED's MATCHER.  POST-MATCH-FORM might
 432 be used to move back, before resuming with MATCH-ANCHORED's parent's MATCHER.
 433
 434 For example, an element of the form highlights (if not already highlighted):
 435
 436  (\"\\\\\\=<anchor\\\\\\=>\" (0 anchor-face) (\"\\\\\\=<item\\\\\\=>\" nil nil (0 item-face)))
 437
 438  discrete occurrences of \"anchor\" in the value of `anchor-face', and subsequent
 439  discrete occurrences of \"item\" (on the same line) in the value of `item-face'.
 440  (Here PRE-MATCH-FORM and POST-MATCH-FORM are nil.  Therefore \"item\" is
 441  initially searched for starting from the end of the match of \"anchor\", and
 442  searching for subsequent instances of \"anchor\" resumes from where searching
 443  for \"item\" concluded.)
 444
 445 The above-mentioned exception is as follows.  The limit of the MATCHER search
 446 defaults to the end of the line after PRE-MATCH-FORM is evaluated.
 447 However, if PRE-MATCH-FORM returns a position greater than the position after
 448 PRE-MATCH-FORM is evaluated, that position is used as the limit of the search.
 449 It is generally a bad idea to return a position greater than the end of the
 450 line, i.e., cause the MATCHER search to span lines.
 451
 452 These regular expressions can match text which spans lines, although
 453 it is better to avoid it if possible since updating them while editing
 454 text is slower, and it is not guaranteed to be always correct when using
 455 support modes like jit-lock or lazy-lock.
 456
 457 This variable is set by major modes via the variable `font-lock-defaults'.
 458 Be careful when composing regexps for this list; a poorly written pattern can
 459 dramatically slow things down!
 460
 461 A compiled keywords list starts with t.  It is produced internal
 462 by `font-lock-compile-keywords' from a user-level keywords list.
 463 Its second element is the user-level keywords list that was
 464 compiled.  The remaining elements have the same form as
 465 user-level keywords, but normally their values have been
 466 optimized.")
 467
 468 (defvar font-lock-keywords-alist nil
 469   "Alist of `font-lock-keywords' local to a `major-mode'.
 470 This is normally set via `font-lock-add-keywords' and
 471 `font-lock-remove-keywords'.")
 472
 473 (defvar font-lock-removed-keywords-alist nil
 474   "Alist of `font-lock-keywords' removed from `major-mode'.
 475 This is normally set via `font-lock-add-keywords' and
 476 `font-lock-remove-keywords'.")
 477
 478 (defvar font-lock-keywords-only nil
 479   "*Non-nil means Font Lock should not fontify comments or strings.
 480 This is normally set via `font-lock-defaults'.")
 481
 482 (defvar font-lock-keywords-case-fold-search nil
 483   "*Non-nil means the patterns in `font-lock-keywords' are case-insensitive.
 484 This is normally set via `font-lock-defaults'.")
 485 (make-variable-buffer-local 'font-lock-keywords-case-fold-search)
 486
 487 (defvar font-lock-syntactically-fontified 0
 488   "Point up to which `font-lock-syntactic-keywords' has been applied.
 489 If nil, this is ignored, in which case the syntactic fontification may
 490 sometimes be slightly incorrect.")
 491 (make-variable-buffer-local 'font-lock-syntactically-fontified)
 492
 493 (defvar font-lock-syntactic-face-function
 494   (lambda (state)
 495     (if (nth 3 state) font-lock-string-face font-lock-comment-face))
 496   "Function to determine which face to use when fontifying syntactically.
 497 The function is called with a single parameter (the state as returned by
 498 `parse-partial-sexp' at the beginning of the region to highlight) and
 499 should return a face.  This is normally set via `font-lock-defaults'.")
 500
 501 (defvar font-lock-syntactic-keywords nil
 502   "A list of the syntactic keywords to highlight.
 503 Can be the list or the name of a function or variable whose value is the list.
 504 See `font-lock-keywords' for a description of the form of this list;
 505 the differences are listed below.  MATCH-HIGHLIGHT should be of the form:
 506
 507  (MATCH SYNTAX OVERRIDE LAXMATCH)
 508
 509 where SYNTAX can be a string (as taken by `modify-syntax-entry'), a syntax
 510 table, a cons cell (as returned by `string-to-syntax') or an expression whose
 511 value is such a form.  OVERRIDE cannot be `prepend' or `append'.
 512
 513 For example, an element of the form highlights syntactically:
 514
 515  (\"\\\\$\\\\(#\\\\)\" 1 \".\")
 516
 517  a hash character when following a dollar character, with a SYNTAX of
 518  \".\" (meaning punctuation syntax).  Assuming that the buffer syntax table does
 519  specify hash characters to have comment start syntax, the element will only
 520  highlight hash characters that do not follow dollar characters as comments
 521  syntactically.
 522
 523  (\"\\\\('\\\\).\\\\('\\\\)\"
 524   (1 \"\\\"\")
 525   (2 \"\\\"\"))
 526
 527  both single quotes which surround a single character, with a SYNTAX of
 528  \"\\\"\" (meaning string quote syntax).  Assuming that the buffer syntax table
 529  does not specify single quotes to have quote syntax, the element will only
 530  highlight single quotes of the form 'c' as strings syntactically.
 531  Other forms, such as foo'bar or 'fubar', will not be highlighted as strings.
 532
 533 This is normally set via `font-lock-defaults'.")
 534
 535 (defvar font-lock-syntax-table nil
 536   "Non-nil means use this syntax table for fontifying.
 537 If this is nil, the major mode's syntax table is used.
 538 This is normally set via `font-lock-defaults'.")
 539
 540 (defvar font-lock-beginning-of-syntax-function nil
 541   "*Non-nil means use this function to move back outside all constructs.
 542 When called with no args it should move point backward to a place which
 543 is not in a string or comment and not within any bracket-pairs (or else,
 544 a place such that any bracket-pairs outside it can be ignored for Emacs
 545 syntax analysis and fontification).
 546
 547 If this is nil, the beginning of the buffer is used, which is
 548 always correct but tends to be slow.
 549 This is normally set via `font-lock-defaults'.
 550 This variable is semi-obsolete; we recommend setting
 551 `syntax-begin-function' instead.")
 552
 553 (defvar font-lock-mark-block-function nil
 554   "*Non-nil means use this function to mark a block of text.
 555 When called with no args it should leave point at the beginning of any
 556 enclosing textual block and mark at the end.
 557 This is normally set via `font-lock-defaults'.")
 558
 559 (defvar font-lock-fontify-buffer-function 'font-lock-default-fontify-buffer
 560   "Function to use for fontifying the buffer.
 561 This is normally set via `font-lock-defaults'.")
 562
 563 (defvar font-lock-unfontify-buffer-function 'font-lock-default-unfontify-buffer
 564   "Function to use for unfontifying the buffer.
 565 This is used when turning off Font Lock mode.
 566 This is normally set via `font-lock-defaults'.")
 567
 568 (defvar font-lock-fontify-region-function 'font-lock-default-fontify-region
 569   "Function to use for fontifying a region.
 570 It should take two args, the beginning and end of the region, and an optional
 571 third arg VERBOSE.  If VERBOSE is non-nil, the function should print status
 572 messages.  This is normally set via `font-lock-defaults'.")
 573
 574 (defvar font-lock-unfontify-region-function 'font-lock-default-unfontify-region
 575   "Function to use for unfontifying a region.
 576 It should take two args, the beginning and end of the region.
 577 This is normally set via `font-lock-defaults'.")
 578
 579 (defvar font-lock-inhibit-thing-lock nil
 580   "List of Font Lock mode related modes that should not be turned on.
 581 Currently, valid mode names are `fast-lock-mode', `jit-lock-mode' and
 582 `lazy-lock-mode'.  This is normally set via `font-lock-defaults'.")
 583
 584 (defvar font-lock-multiline nil
 585   "Whether font-lock should cater to multiline keywords.
 586 If nil, don't try to handle multiline patterns.
 587 If t, always handle multiline patterns.
 588 If `undecided', don't try to handle multiline patterns until you see one.
 589 Major/minor modes can set this variable if they know which option applies.")
 590
 591 (defvar font-lock-fontified nil)        ; Whether we have fontified the buffer.
 592 \f
 593 ;; Font Lock mode.
 594
 595 (eval-when-compile
 596   ;;
 597   ;; We don't do this at the top-level as we only use non-autoloaded macros.
 598   (require 'cl)
 599   ;;
 600   ;; Borrowed from lazy-lock.el.
 601   ;; We use this to preserve or protect things when modifying text properties.
 602   (defmacro save-buffer-state (varlist &rest body)
 603     "Bind variables according to VARLIST and eval BODY restoring buffer state."
 604     (let ((modified (make-symbol "modified")))
 605       `(let* ,(append varlist
 606                       `((,modified (buffer-modified-p))
 607                         (buffer-undo-list t)
 608                         (inhibit-read-only t)
 609                         (inhibit-point-motion-hooks t)
 610                         (inhibit-modification-hooks t)
 611                         deactivate-mark
 612                         buffer-file-name
 613                         buffer-file-truename))
 614          (progn
 615            ,@body)
 616          (unless ,modified
 617            (restore-buffer-modified-p nil)))))
 618   (put 'save-buffer-state 'lisp-indent-function 1)
 619   (def-edebug-spec save-buffer-state let)
 620   ;;
 621   ;; Shut up the byte compiler.
 622   (defvar font-lock-face-attributes))   ; Obsolete but respected if set.
 623
 624 ;;;###autoload
 625 (defun font-lock-mode-internal (arg)
 626   ;; Turn on Font Lock mode.
 627   (when arg
 628     (add-hook 'after-change-functions 'font-lock-after-change-function t t)
 629     (font-lock-set-defaults)
 630     (font-lock-turn-on-thing-lock)
 631     ;; Fontify the buffer if we have to.
 632     (let ((max-size (font-lock-value-in-major-mode font-lock-maximum-size)))
 633       (cond (font-lock-fontified
 634              nil)
 635             ((or (null max-size) (> max-size (buffer-size)))
 636              (font-lock-fontify-buffer))
 637             (font-lock-verbose
 638              (message "Fontifying %s...buffer size greater than font-lock-maximum-size"
 639                       (buffer-name))))))
 640   ;; Turn off Font Lock mode.
 641   (unless font-lock-mode
 642     (remove-hook 'after-change-functions 'font-lock-after-change-function t)
 643     (font-lock-unfontify-buffer)
 644     (font-lock-turn-off-thing-lock)))
 645
 646 ;;;###autoload
 647 (defun font-lock-add-keywords (mode keywords &optional append)
 648   "Add highlighting KEYWORDS for MODE.
 649
 650 MODE should be a symbol, the major mode command name, such as `c-mode'
 651 or nil.  If nil, highlighting keywords are added for the current buffer.
 652 KEYWORDS should be a list; see the variable `font-lock-keywords'.
 653 By default they are added at the beginning of the current highlighting list.
 654 If optional argument APPEND is `set', they are used to replace the current
 655 highlighting list.  If APPEND is any other non-nil value, they are added at the
 656 end of the current highlighting list.
 657
 658 For example:
 659
 660  (font-lock-add-keywords 'c-mode
 661   '((\"\\\\\\=<\\\\(FIXME\\\\):\" 1 font-lock-warning-face prepend)
 662     (\"\\\\\\=<\\\\(and\\\\|or\\\\|not\\\\)\\\\\\=>\" . font-lock-keyword-face)))
 663
 664 adds two fontification patterns for C mode, to fontify `FIXME:' words, even in
 665 comments, and to fontify `and', `or' and `not' words as keywords.
 666
 667 When used from a Lisp program (such as a minor mode), it is recommended to
 668 use nil for MODE (and place the call on a hook) to avoid subtle problems
 669 due to details of the implementation.
 670
 671 Note that some modes have specialized support for additional patterns, e.g.,
 672 see the variables `c-font-lock-extra-types', `c++-font-lock-extra-types',
 673 `objc-font-lock-extra-types' and `java-font-lock-extra-types'."
 674   (cond (mode
 675          ;; If MODE is non-nil, add the KEYWORDS and APPEND spec to
 676          ;; `font-lock-keywords-alist' so `font-lock-set-defaults' uses them.
 677          (let ((spec (cons keywords append)) cell)
 678            (if (setq cell (assq mode font-lock-keywords-alist))
 679                (if (eq append 'set)
 680                    (setcdr cell (list spec))
 681                  (setcdr cell (append (cdr cell) (list spec))))
 682              (push (list mode spec) font-lock-keywords-alist)))
 683          ;; Make sure that `font-lock-removed-keywords-alist' does not
 684          ;; contain the new keywords.
 685          (font-lock-update-removed-keyword-alist mode keywords append))
 686         (t
 687          ;; Otherwise set or add the keywords now.
 688          ;; This is a no-op if it has been done already in this buffer.
 689          (font-lock-set-defaults)
 690          (let ((was-compiled (eq (car font-lock-keywords) t)))
 691            ;; Bring back the user-level (uncompiled) keywords.
 692            (if was-compiled
 693                (setq font-lock-keywords (cadr font-lock-keywords)))
 694            ;; Now modify or replace them.
 695            (if (eq append 'set)
 696                (setq font-lock-keywords keywords)
 697              (font-lock-remove-keywords nil keywords) ;to avoid duplicates
 698              (let ((old (if (eq (car-safe font-lock-keywords) t)
 699                             (cdr font-lock-keywords)
 700                           font-lock-keywords)))
 701                (setq font-lock-keywords (if append
 702                                             (append old keywords)
 703                                           (append keywords old)))))
 704            ;; If the keywords were compiled before, compile them again.
 705            (if was-compiled
 706                (set (make-local-variable 'font-lock-keywords)
 707                     (font-lock-compile-keywords font-lock-keywords t)))))))
 708
 709 (defun font-lock-update-removed-keyword-alist (mode keywords append)
 710   "Update `font-lock-removed-keywords-alist' when adding new KEYWORDS to MODE."
 711   ;; When font-lock is enabled first all keywords in the list
 712   ;; `font-lock-keywords-alist' are added, then all keywords in the
 713   ;; list `font-lock-removed-keywords-alist' are removed.  If a
 714   ;; keyword was once added, removed, and then added again it must be
 715   ;; removed from the removed-keywords list.  Otherwise the second add
 716   ;; will not take effect.
 717   (let ((cell (assq mode font-lock-removed-keywords-alist)))
 718     (if cell
 719         (if (eq append 'set)
 720             ;; A new set of keywords is defined.  Forget all about
 721             ;; our old keywords that should be removed.
 722             (setq font-lock-removed-keywords-alist
 723                   (delq cell font-lock-removed-keywords-alist))
 724           ;; Delete all previously removed keywords.
 725           (dolist (kword keywords)
 726             (setcdr cell (delete kword (cdr cell))))
 727           ;; Delete the mode cell if empty.
 728           (if (null (cdr cell))
 729               (setq font-lock-removed-keywords-alist
 730                     (delq cell font-lock-removed-keywords-alist)))))))
 731
 732 ;; Written by Anders Lindgren <andersl@andersl.com>.
 733 ;;
 734 ;; Case study:
 735 ;; (I)  The keywords are removed from a major mode.
 736 ;;      In this case the keyword could be local (i.e. added earlier by
 737 ;;      `font-lock-add-keywords'), global, or both.
 738 ;;
 739 ;;      (a) In the local case we remove the keywords from the variable
 740 ;;          `font-lock-keywords-alist'.
 741 ;;
 742 ;;      (b) The actual global keywords are not known at this time.
 743 ;;          All keywords are added to `font-lock-removed-keywords-alist',
 744 ;;          when font-lock is enabled those keywords are removed.
 745 ;;
 746 ;;      Note that added keywords are taken out of the list of removed
 747 ;;      keywords.  This ensure correct operation when the same keyword
 748 ;;      is added and removed several times.
 749 ;;
 750 ;; (II) The keywords are removed from the current buffer.
 751 ;;;###autoload
 752 (defun font-lock-remove-keywords (mode keywords)
 753   "Remove highlighting KEYWORDS for MODE.
 754
 755 MODE should be a symbol, the major mode command name, such as `c-mode'
 756 or nil.  If nil, highlighting keywords are removed for the current buffer.
 757
 758 When used from a Lisp program (such as a minor mode), it is recommended to
 759 use nil for MODE (and place the call on a hook) to avoid subtle problems
 760 due to details of the implementation."
 761   (cond (mode
 762          ;; Remove one keyword at the time.
 763          (dolist (keyword keywords)
 764            (let ((top-cell (assq mode font-lock-keywords-alist)))
 765              ;; If MODE is non-nil, remove the KEYWORD from
 766              ;; `font-lock-keywords-alist'.
 767              (when top-cell
 768                (dolist (keyword-list-append-pair (cdr top-cell))
 769                  ;; `keywords-list-append-pair' is a cons with a list of
 770                  ;; keywords in the car top-cell and the original append
 771                  ;; argument in the cdr top-cell.
 772                  (setcar keyword-list-append-pair
 773                          (delete keyword (car keyword-list-append-pair))))
 774                ;; Remove keyword list/append pair when the keyword list
 775                ;; is empty and append doesn't specify `set'.  (If it
 776                ;; should be deleted then previously deleted keywords
 777                ;; would appear again.)
 778                (let ((cell top-cell))
 779                  (while (cdr cell)
 780                    (if (and (null (car (car (cdr cell))))
 781                             (not (eq (cdr (car (cdr cell))) 'set)))
 782                        (setcdr cell (cdr (cdr cell)))
 783                      (setq cell (cdr cell)))))
 784                ;; Final cleanup, remove major mode cell if last keyword
 785                ;; was deleted.
 786                (if (null (cdr top-cell))
 787                    (setq font-lock-keywords-alist
 788                          (delq top-cell font-lock-keywords-alist))))
 789              ;; Remember the keyword in case it is not local.
 790              (let ((cell (assq mode font-lock-removed-keywords-alist)))
 791                (if cell
 792                    (unless (member keyword (cdr cell))
 793                      (nconc cell (list keyword)))
 794                  (push (cons mode (list keyword))
 795                        font-lock-removed-keywords-alist))))))
 796         (t
 797          ;; Otherwise remove it immediately.
 798          (font-lock-set-defaults)
 799          (let ((was-compiled (eq (car font-lock-keywords) t)))
 800            ;; Bring back the user-level (uncompiled) keywords.
 801            (if was-compiled
 802                (setq font-lock-keywords (cadr font-lock-keywords)))
 803
 804            ;; Edit them.
 805            (setq font-lock-keywords (copy-sequence font-lock-keywords))
 806            (dolist (keyword keywords)
 807              (setq font-lock-keywords
 808                    (delete keyword font-lock-keywords)))
 809
 810            ;; If the keywords were compiled before, compile them again.
 811            (if was-compiled
 812                (set (make-local-variable 'font-lock-keywords)
 813                     (font-lock-compile-keywords font-lock-keywords t)))))))
 814 \f
 815 ;;; Font Lock Support mode.
 816
 817 ;; This is the code used to interface font-lock.el with any of its add-on
 818 ;; packages, and provide the user interface.  Packages that have their own
 819 ;; local buffer fontification functions (see below) may have to call
 820 ;; `font-lock-after-fontify-buffer' and/or `font-lock-after-unfontify-buffer'
 821 ;; themselves.
 822
 823 (defcustom font-lock-support-mode 'jit-lock-mode
 824   "*Support mode for Font Lock mode.
 825 Support modes speed up Font Lock mode by being choosy about when fontification
 826 occurs.  Known support modes are Fast Lock mode (symbol `fast-lock-mode'),
 827 Lazy Lock mode (symbol `lazy-lock-mode'), and Just-in-time Lock mode (symbol
 828 `jit-lock-mode'.  See those modes for more info.
 829 If nil, means support for Font Lock mode is never performed.
 830 If a symbol, use that support mode.
 831 If a list, each element should be of the form (MAJOR-MODE . SUPPORT-MODE),
 832 where MAJOR-MODE is a symbol or t (meaning the default).  For example:
 833  ((c-mode . fast-lock-mode) (c++-mode . fast-lock-mode) (t . lazy-lock-mode))
 834 means that Fast Lock mode is used to support Font Lock mode for buffers in C or
 835 C++ modes, and Lazy Lock mode is used to support Font Lock mode otherwise.
 836
 837 The value of this variable is used when Font Lock mode is turned on."
 838   :type '(choice (const :tag "none" nil)
 839                  (const :tag "fast lock" fast-lock-mode)
 840                  (const :tag "lazy lock" lazy-lock-mode)
 841                  (const :tag "jit lock" jit-lock-mode)
 842                  (repeat :menu-tag "mode specific" :tag "mode specific"
 843                          :value ((t . jit-lock-mode))
 844                          (cons :tag "Instance"
 845                                (radio :tag "Mode"
 846                                       (const :tag "all" t)
 847                                       (symbol :tag "name"))
 848                                (radio :tag "Support"
 849                                       (const :tag "none" nil)
 850                                       (const :tag "fast lock" fast-lock-mode)
 851                                       (const :tag "lazy lock" lazy-lock-mode)
 852                                       (const :tag "JIT lock" jit-lock-mode)))
 853                          ))
 854   :version "21.1"
 855   :group 'font-lock)
 856
 857 (defvar fast-lock-mode)
 858 (defvar lazy-lock-mode)
 859 (defvar jit-lock-mode)
 860
 861 (defun font-lock-turn-on-thing-lock ()
 862   (let ((thing-mode (font-lock-value-in-major-mode font-lock-support-mode)))
 863     (cond ((eq thing-mode 'fast-lock-mode)
 864            (fast-lock-mode t))
 865           ((eq thing-mode 'lazy-lock-mode)
 866            (lazy-lock-mode t))
 867           ((eq thing-mode 'jit-lock-mode)
 868            ;; Prepare for jit-lock
 869            (remove-hook 'after-change-functions
 870                         'font-lock-after-change-function t)
 871            (set (make-local-variable 'font-lock-fontify-buffer-function)
 872                 'jit-lock-refontify)
 873            ;; Don't fontify eagerly (and don't abort is the buffer is large).
 874            (set (make-local-variable 'font-lock-fontified) t)
 875            ;; Use jit-lock.
 876            (jit-lock-register 'font-lock-fontify-region
 877                               (not font-lock-keywords-only))))))
 878
 879 (defun font-lock-turn-off-thing-lock ()
 880   (cond ((and (boundp 'fast-lock-mode) fast-lock-mode)
 881          (fast-lock-mode -1))
 882         ((and (boundp 'jit-lock-mode) jit-lock-mode)
 883          (jit-lock-unregister 'font-lock-fontify-region)
 884          ;; Reset local vars to the non-jit-lock case.
 885          (kill-local-variable 'font-lock-fontify-buffer-function))
 886         ((and (boundp 'lazy-lock-mode) lazy-lock-mode)
 887          (lazy-lock-mode -1))))
 888
 889 (defun font-lock-after-fontify-buffer ()
 890   (cond ((and (boundp 'fast-lock-mode) fast-lock-mode)
 891          (fast-lock-after-fontify-buffer))
 892         ;; Useless now that jit-lock intercepts font-lock-fontify-buffer.  -sm
 893         ;; (jit-lock-mode
 894         ;;  (jit-lock-after-fontify-buffer))
 895         ((and (boundp 'lazy-lock-mode) lazy-lock-mode)
 896          (lazy-lock-after-fontify-buffer))))
 897
 898 (defun font-lock-after-unfontify-buffer ()
 899   (cond ((and (boundp 'fast-lock-mode) fast-lock-mode)
 900          (fast-lock-after-unfontify-buffer))
 901         ;; Useless as well.  It's only called when:
 902         ;; - turning off font-lock: it does not matter if we leave spurious
 903         ;;   `fontified' text props around since jit-lock-mode is also off.
 904         ;; - font-lock-default-fontify-buffer fails: this is not run
 905         ;;   any more anyway.   -sm
 906         ;;
 907         ;; (jit-lock-mode
 908         ;;  (jit-lock-after-unfontify-buffer))
 909         ((and (boundp 'lazy-lock-mode) lazy-lock-mode)
 910          (lazy-lock-after-unfontify-buffer))))
 911
 912 ;;; End of Font Lock Support mode.
 913 \f
 914 ;;; Fontification functions.
 915
 916 ;; Rather than the function, e.g., `font-lock-fontify-region' containing the
 917 ;; code to fontify a region, the function runs the function whose name is the
 918 ;; value of the variable, e.g., `font-lock-fontify-region-function'.  Normally,
 919 ;; the value of this variable is, e.g., `font-lock-default-fontify-region'
 920 ;; which does contain the code to fontify a region.  However, the value of the
 921 ;; variable could be anything and thus, e.g., `font-lock-fontify-region' could
 922 ;; do anything.  The indirection of the fontification functions gives major
 923 ;; modes the capability of modifying the way font-lock.el fontifies.  Major
 924 ;; modes can modify the values of, e.g., `font-lock-fontify-region-function',
 925 ;; via the variable `font-lock-defaults'.
 926 ;;
 927 ;; For example, Rmail mode sets the variable `font-lock-defaults' so that
 928 ;; font-lock.el uses its own function for buffer fontification.  This function
 929 ;; makes fontification be on a message-by-message basis and so visiting an
 930 ;; RMAIL file is much faster.  A clever implementation of the function might
 931 ;; fontify the headers differently than the message body.  (It should, and
 932 ;; correspondingly for Mail mode, but I can't be bothered to do the work.  Can
 933 ;; you?)  This hints at a more interesting use...
 934 ;;
 935 ;; Languages that contain text normally contained in different major modes
 936 ;; could define their own fontification functions that treat text differently
 937 ;; depending on its context.  For example, Perl mode could arrange that here
 938 ;; docs are fontified differently than Perl code.  Or Yacc mode could fontify
 939 ;; rules one way and C code another.  Neat!
 940 ;;
 941 ;; A further reason to use the fontification indirection feature is when the
 942 ;; default syntactual fontification, or the default fontification in general,
 943 ;; is not flexible enough for a particular major mode.  For example, perhaps
 944 ;; comments are just too hairy for `font-lock-fontify-syntactically-region' to
 945 ;; cope with.  You need to write your own version of that function, e.g.,
 946 ;; `hairy-fontify-syntactically-region', and make your own version of
 947 ;; `hairy-fontify-region' call that function before calling
 948 ;; `font-lock-fontify-keywords-region' for the normal regexp fontification
 949 ;; pass.  And Hairy mode would set `font-lock-defaults' so that font-lock.el
 950 ;; would call your region fontification function instead of its own.  For
 951 ;; example, TeX modes could fontify {\foo ...} and \bar{...}  etc. multi-line
 952 ;; directives correctly and cleanly.  (It is the same problem as fontifying
 953 ;; multi-line strings and comments; regexps are not appropriate for the job.)
 954
 955 ;;;###autoload
 956 (defun font-lock-fontify-buffer ()
 957   "Fontify the current buffer the way the function `font-lock-mode' would."
 958   (interactive)
 959   (let ((font-lock-verbose (or font-lock-verbose (interactive-p))))
 960     (funcall font-lock-fontify-buffer-function)))
 961
 962 (defun font-lock-unfontify-buffer ()
 963   (funcall font-lock-unfontify-buffer-function))
 964
 965 (defun font-lock-fontify-region (beg end &optional loudly)
 966   (funcall font-lock-fontify-region-function beg end loudly))
 967
 968 (defun font-lock-unfontify-region (beg end)
 969   (save-buffer-state nil
 970     (funcall font-lock-unfontify-region-function beg end)))
 971
 972 (defun font-lock-default-fontify-buffer ()
 973   (let ((verbose (if (numberp font-lock-verbose)
 974                      (> (buffer-size) font-lock-verbose)
 975                    font-lock-verbose)))
 976     (with-temp-message
 977         (when verbose
 978           (format "Fontifying %s..." (buffer-name)))
 979       ;; Make sure we have the right `font-lock-keywords' etc.
 980       (unless font-lock-mode
 981         (font-lock-set-defaults))
 982       ;; Make sure we fontify etc. in the whole buffer.
 983       (save-restriction
 984         (widen)
 985         (condition-case nil
 986             (save-excursion
 987               (save-match-data
 988                 (font-lock-fontify-region (point-min) (point-max) verbose)
 989                 (font-lock-after-fontify-buffer)
 990                 (setq font-lock-fontified t)))
 991           ;; We don't restore the old fontification, so it's best to unfontify.
 992           (quit (font-lock-unfontify-buffer)))))))
 993
 994 (defun font-lock-default-unfontify-buffer ()
 995   ;; Make sure we unfontify etc. in the whole buffer.
 996   (save-restriction
 997     (widen)
 998     (font-lock-unfontify-region (point-min) (point-max))
 999     (font-lock-after-unfontify-buffer)
1000     (setq font-lock-fontified nil)))
1001
1002 (defvar font-lock-dont-widen nil
1003   "If non-nil, font-lock will work on the non-widened buffer.
1004 Useful for things like RMAIL and Info where the whole buffer is not
1005 a very meaningful entity to highlight.")
1006
1007 (defun font-lock-default-fontify-region (beg end loudly)
1008   (save-buffer-state
1009       ((parse-sexp-lookup-properties
1010         (or parse-sexp-lookup-properties font-lock-syntactic-keywords))
1011        (old-syntax-table (syntax-table)))
1012     (unwind-protect
1013         (save-restriction
1014           (unless font-lock-dont-widen (widen))
1015           ;; Use the fontification syntax table, if any.
1016           (when font-lock-syntax-table
1017             (set-syntax-table font-lock-syntax-table))
1018           ;; check to see if we should expand the beg/end area for
1019           ;; proper multiline matches
1020           (when (and font-lock-multiline
1021                      (> beg (point-min))
1022                      (get-text-property (1- beg) 'font-lock-multiline))
1023             ;; We are just after or in a multiline match.
1024             (setq beg (or (previous-single-property-change
1025                            beg 'font-lock-multiline)
1026                           (point-min)))
1027             (goto-char beg)
1028             (setq beg (line-beginning-position)))
1029           (when font-lock-multiline
1030             (setq end (or (text-property-any end (point-max)
1031                                              'font-lock-multiline nil)
1032                           (point-max))))
1033           (goto-char end)
1034           (setq end (line-beginning-position 2))
1035           ;; Now do the fontification.
1036           (font-lock-unfontify-region beg end)
1037           (when font-lock-syntactic-keywords
1038             (font-lock-fontify-syntactic-keywords-region beg end))
1039           (unless font-lock-keywords-only
1040             (font-lock-fontify-syntactically-region beg end loudly))
1041           (font-lock-fontify-keywords-region beg end loudly))
1042       ;; Clean up.
1043       (set-syntax-table old-syntax-table))))
1044
1045 ;; The following must be rethought, since keywords can override fontification.
1046 ;      ;; Now scan for keywords, but not if we are inside a comment now.
1047 ;      (or (and (not font-lock-keywords-only)
1048 ;              (let ((state (parse-partial-sexp beg end nil nil
1049 ;                                               font-lock-cache-state)))
1050 ;                (or (nth 4 state) (nth 7 state))))
1051 ;         (font-lock-fontify-keywords-region beg end))
1052
1053 (defvar font-lock-extra-managed-props nil
1054   "Additional text properties managed by font-lock.
1055 This is used by `font-lock-default-unfontify-region' to decide
1056 what properties to clear before refontifying a region.")
1057
1058 (defun font-lock-default-unfontify-region (beg end)
1059   (remove-list-of-text-properties
1060    beg end (append
1061             font-lock-extra-managed-props
1062             (if font-lock-syntactic-keywords
1063                 '(syntax-table face font-lock-multiline)
1064               '(face font-lock-multiline)))))
1065
1066 ;; Called when any modification is made to buffer text.
1067 (defun font-lock-after-change-function (beg end old-len)
1068   (let ((inhibit-point-motion-hooks t)
1069         (inhibit-quit t))
1070     (save-excursion
1071       (save-match-data
1072         ;; Rescan between start of lines enclosing the region.
1073         (font-lock-fontify-region
1074          (progn (goto-char beg)
1075                 (forward-line (- font-lock-lines-before)) (point))
1076          (progn (goto-char end) (forward-line 1) (point)))))))
1077
1078 (defun font-lock-fontify-block (&optional arg)
1079   "Fontify some lines the way `font-lock-fontify-buffer' would.
1080 The lines could be a function or paragraph, or a specified number of lines.
1081 If ARG is given, fontify that many lines before and after point, or 16 lines if
1082 no ARG is given and `font-lock-mark-block-function' is nil.
1083 If `font-lock-mark-block-function' non-nil and no ARG is given, it is used to
1084 delimit the region to fontify."
1085   (interactive "P")
1086   (let ((inhibit-point-motion-hooks t) font-lock-beginning-of-syntax-function
1087         deactivate-mark)
1088     ;; Make sure we have the right `font-lock-keywords' etc.
1089     (if (not font-lock-mode) (font-lock-set-defaults))
1090     (save-excursion
1091       (save-match-data
1092         (condition-case error-data
1093             (if (or arg (not font-lock-mark-block-function))
1094                 (let ((lines (if arg (prefix-numeric-value arg) 16)))
1095                   (font-lock-fontify-region
1096                    (save-excursion (forward-line (- lines)) (point))
1097                    (save-excursion (forward-line lines) (point))))
1098               (funcall font-lock-mark-block-function)
1099               (font-lock-fontify-region (point) (mark)))
1100           ((error quit) (message "Fontifying block...%s" error-data)))))))
1101
1102 (if (boundp 'facemenu-keymap)
1103     (define-key facemenu-keymap "\M-o" 'font-lock-fontify-block))
1104
1105 ;;; End of Fontification functions.
1106 \f
1107 ;;; Additional text property functions.
1108
1109 ;; The following text property functions should be builtins.  This means they
1110 ;; should be written in C and put with all the other text property functions.
1111 ;; In the meantime, those that are used by font-lock.el are defined in Lisp
1112 ;; below and given a `font-lock-' prefix.  Those that are not used are defined
1113 ;; in Lisp below and commented out.  sm.
1114
1115 (defun font-lock-prepend-text-property (start end prop value &optional object)
1116   "Prepend to one property of the text from START to END.
1117 Arguments PROP and VALUE specify the property and value to prepend to the value
1118 already in place.  The resulting property values are always lists.
1119 Optional argument OBJECT is the string or buffer containing the text."
1120   (let ((val (if (listp value) value (list value))) next prev)
1121     (while (/= start end)
1122       (setq next (next-single-property-change start prop object end)
1123             prev (get-text-property start prop object))
1124       (put-text-property start next prop
1125                          (append val (if (listp prev) prev (list prev)))
1126                          object)
1127       (setq start next))))
1128
1129 (defun font-lock-append-text-property (start end prop value &optional object)
1130   "Append to one property of the text from START to END.
1131 Arguments PROP and VALUE specify the property and value to append to the value
1132 already in place.  The resulting property values are always lists.
1133 Optional argument OBJECT is the string or buffer containing the text."
1134   (let ((val (if (listp value) value (list value))) next prev)
1135     (while (/= start end)
1136       (setq next (next-single-property-change start prop object end)
1137             prev (get-text-property start prop object))
1138       (put-text-property start next prop
1139                          (append (if (listp prev) prev (list prev)) val)
1140                          object)
1141       (setq start next))))
1142
1143 (defun font-lock-fillin-text-property (start end prop value &optional object)
1144   "Fill in one property of the text from START to END.
1145 Arguments PROP and VALUE specify the property and value to put where none are
1146 already in place.  Therefore existing property values are not overwritten.
1147 Optional argument OBJECT is the string or buffer containing the text."
1148   (let ((start (text-property-any start end prop nil object)) next)
1149     (while start
1150       (setq next (next-single-property-change start prop object end))
1151       (put-text-property start next prop value object)
1152       (setq start (text-property-any next end prop nil object)))))
1153
1154 ;; For completeness: this is to `remove-text-properties' as `put-text-property'
1155 ;; is to `add-text-properties', etc.
1156 ;(defun remove-text-property (start end property &optional object)
1157 ;  "Remove a property from text from START to END.
1158 ;Argument PROPERTY is the property to remove.
1159 ;Optional argument OBJECT is the string or buffer containing the text.
1160 ;Return t if the property was actually removed, nil otherwise."
1161 ;  (remove-text-properties start end (list property) object))
1162
1163 ;; For consistency: maybe this should be called `remove-single-property' like
1164 ;; `next-single-property-change' (not `next-single-text-property-change'), etc.
1165 ;(defun remove-single-text-property (start end prop value &optional object)
1166 ;  "Remove a specific property value from text from START to END.
1167 ;Arguments PROP and VALUE specify the property and value to remove.  The
1168 ;resulting property values are not equal to VALUE nor lists containing VALUE.
1169 ;Optional argument OBJECT is the string or buffer containing the text."
1170 ;  (let ((start (text-property-not-all start end prop nil object)) next prev)
1171 ;    (while start
1172 ;      (setq next (next-single-property-change start prop object end)
1173 ;           prev (get-text-property start prop object))
1174 ;      (cond ((and (symbolp prev) (eq value prev))
1175 ;            (remove-text-property start next prop object))
1176 ;           ((and (listp prev) (memq value prev))
1177 ;            (let ((new (delq value prev)))
1178 ;              (cond ((null new)
1179 ;                     (remove-text-property start next prop object))
1180 ;                    ((= (length new) 1)
1181 ;                     (put-text-property start next prop (car new) object))
1182 ;                    (t
1183 ;                     (put-text-property start next prop new object))))))
1184 ;      (setq start (text-property-not-all next end prop nil object)))))
1185
1186 ;;; End of Additional text property functions.
1187 \f
1188 ;;; Syntactic regexp fontification functions.
1189
1190 ;; These syntactic keyword pass functions are identical to those keyword pass
1191 ;; functions below, with the following exceptions; (a) they operate on
1192 ;; `font-lock-syntactic-keywords' of course, (b) they are all `defun' as speed
1193 ;; is less of an issue, (c) eval of property value does not occur JIT as speed
1194 ;; is less of an issue, (d) OVERRIDE cannot be `prepend' or `append' as it
1195 ;; makes no sense for `syntax-table' property values, (e) they do not do it
1196 ;; LOUDLY as it is not likely to be intensive.
1197
1198 (defun font-lock-apply-syntactic-highlight (highlight)
1199   "Apply HIGHLIGHT following a match.
1200 HIGHLIGHT should be of the form MATCH-HIGHLIGHT,
1201 see `font-lock-syntactic-keywords'."
1202   (let* ((match (nth 0 highlight))
1203          (start (match-beginning match)) (end (match-end match))
1204          (value (nth 1 highlight))
1205          (override (nth 2 highlight)))
1206     (if (not start)
1207         ;; No match but we might not signal an error.
1208         (or (nth 3 highlight)
1209             (error "No match %d in highlight %S" match highlight))
1210       (when (and (consp value) (not (numberp (car value))))
1211         (setq value (eval value)))
1212       (when (stringp value) (setq value (string-to-syntax value)))
1213       ;; Flush the syntax-cache.  I believe this is not necessary for
1214       ;; font-lock's use of syntax-ppss, but I'm not 100% sure and it can
1215       ;; still be necessary for other users of syntax-ppss anyway.
1216       (syntax-ppss-after-change-function start)
1217       (cond
1218        ((not override)
1219         ;; Cannot override existing fontification.
1220         (or (text-property-not-all start end 'syntax-table nil)
1221             (put-text-property start end 'syntax-table value)))
1222        ((eq override t)
1223         ;; Override existing fontification.
1224         (put-text-property start end 'syntax-table value))
1225        ((eq override 'keep)
1226         ;; Keep existing fontification.
1227         (font-lock-fillin-text-property start end 'syntax-table value))))))
1228
1229 (defun font-lock-fontify-syntactic-anchored-keywords (keywords limit)
1230   "Fontify according to KEYWORDS until LIMIT.
1231 KEYWORDS should be of the form MATCH-ANCHORED, see `font-lock-keywords',
1232 LIMIT can be modified by the value of its PRE-MATCH-FORM."
1233   (let ((matcher (nth 0 keywords)) (lowdarks (nthcdr 3 keywords)) highlights
1234         ;; Evaluate PRE-MATCH-FORM.
1235         (pre-match-value (eval (nth 1 keywords))))
1236     ;; Set LIMIT to value of PRE-MATCH-FORM or the end of line.
1237     (if (and (numberp pre-match-value) (> pre-match-value (point)))
1238         (setq limit pre-match-value)
1239       (setq limit (line-end-position)))
1240     (save-match-data
1241       ;; Find an occurrence of `matcher' before `limit'.
1242       (while (if (stringp matcher)
1243                  (re-search-forward matcher limit t)
1244                (funcall matcher limit))
1245         ;; Apply each highlight to this instance of `matcher'.
1246         (setq highlights lowdarks)
1247         (while highlights
1248           (font-lock-apply-syntactic-highlight (car highlights))
1249           (setq highlights (cdr highlights)))))
1250     ;; Evaluate POST-MATCH-FORM.
1251     (eval (nth 2 keywords))))
1252
1253 (defun font-lock-fontify-syntactic-keywords-region (start end)
1254   "Fontify according to `font-lock-syntactic-keywords' between START and END.
1255 START should be at the beginning of a line."
1256   ;; Ensure the beginning of the file is properly syntactic-fontified.
1257   (when (and font-lock-syntactically-fontified
1258              (< font-lock-syntactically-fontified start))
1259     (setq start (max font-lock-syntactically-fontified (point-min)))
1260     (setq font-lock-syntactically-fontified end))
1261   ;; If `font-lock-syntactic-keywords' is a symbol, get the real keywords.
1262   (when (symbolp font-lock-syntactic-keywords)
1263     (setq font-lock-syntactic-keywords (font-lock-eval-keywords
1264                                         font-lock-syntactic-keywords)))
1265   ;; If `font-lock-syntactic-keywords' is not compiled, compile it.
1266   (unless (eq (car font-lock-syntactic-keywords) t)
1267     (setq font-lock-syntactic-keywords (font-lock-compile-keywords
1268                                         font-lock-syntactic-keywords)))
1269   ;; Get down to business.
1270   (let ((case-fold-search font-lock-keywords-case-fold-search)
1271         (keywords (cddr font-lock-syntactic-keywords))
1272         keyword matcher highlights)
1273     (while keywords
1274       ;; Find an occurrence of `matcher' from `start' to `end'.
1275       (setq keyword (car keywords) matcher (car keyword))
1276       (goto-char start)
1277       (while (if (stringp matcher)
1278                  (re-search-forward matcher end t)
1279                (funcall matcher end))
1280         ;; Apply each highlight to this instance of `matcher', which may be
1281         ;; specific highlights or more keywords anchored to `matcher'.
1282         (setq highlights (cdr keyword))
1283         (while highlights
1284           (if (numberp (car (car highlights)))
1285               (font-lock-apply-syntactic-highlight (car highlights))
1286             (font-lock-fontify-syntactic-anchored-keywords (car highlights)
1287                                                            end))
1288           (setq highlights (cdr highlights))))
1289       (setq keywords (cdr keywords)))))
1290
1291 ;;; End of Syntactic regexp fontification functions.
1292 \f
1293 ;;; Syntactic fontification functions.
1294
1295 (defun font-lock-fontify-syntactically-region (start end &optional loudly ppss)
1296   "Put proper face on each string and comment between START and END.
1297 START should be at the beginning of a line."
1298   (let (state face beg)
1299     (if loudly (message "Fontifying %s... (syntactically...)" (buffer-name)))
1300     (goto-char start)
1301     ;;
1302     ;; Find the `start' state.
1303     (setq state (or ppss (syntax-ppss start)))
1304     ;;
1305     ;; Find each interesting place between here and `end'.
1306     (while
1307         (progn
1308           (when (or (nth 3 state) (nth 4 state))
1309             (setq face (funcall font-lock-syntactic-face-function state))
1310             (setq beg (max (nth 8 state) start))
1311             (setq state (parse-partial-sexp (point) end nil nil state
1312                                             'syntax-table))
1313             (when face (put-text-property beg (point) 'face face)))
1314           (< (point) end))
1315       (setq state (parse-partial-sexp (point) end nil nil state
1316                                       'syntax-table)))))
1317
1318 ;;; End of Syntactic fontification functions.
1319 \f
1320 ;;; Keyword regexp fontification functions.
1321
1322 (defsubst font-lock-apply-highlight (highlight)
1323   "Apply HIGHLIGHT following a match.
1324 HIGHLIGHT should be of the form MATCH-HIGHLIGHT, see `font-lock-keywords'."
1325   (let* ((match (nth 0 highlight))
1326          (start (match-beginning match)) (end (match-end match))
1327          (override (nth 2 highlight)))
1328     (if (not start)
1329         ;; No match but we might not signal an error.
1330         (or (nth 3 highlight)
1331             (error "No match %d in highlight %S" match highlight))
1332       (let ((val (eval (nth 1 highlight))))
1333         (when (eq (car-safe val) 'face)
1334           (add-text-properties start end (cddr val))
1335           (setq val (cadr val)))
1336         (cond
1337          ((not (or val (eq override t)))
1338           ;; If `val' is nil, don't do anything.  It is important to do it
1339           ;; explicitly, because when adding nil via things like
1340           ;; font-lock-append-text-property, the property is actually
1341           ;; changed from <face> to (<face>) which is undesirable.  --Stef
1342           nil)
1343          ((not override)
1344           ;; Cannot override existing fontification.
1345           (or (text-property-not-all start end 'face nil)
1346               (put-text-property start end 'face val)))
1347          ((eq override t)
1348           ;; Override existing fontification.
1349           (put-text-property start end 'face val))
1350          ((eq override 'prepend)
1351           ;; Prepend to existing fontification.
1352           (font-lock-prepend-text-property start end 'face val))
1353          ((eq override 'append)
1354           ;; Append to existing fontification.
1355           (font-lock-append-text-property start end 'face val))
1356          ((eq override 'keep)
1357           ;; Keep existing fontification.
1358           (font-lock-fillin-text-property start end 'face val)))))))
1359
1360 (defsubst font-lock-fontify-anchored-keywords (keywords limit)
1361   "Fontify according to KEYWORDS until LIMIT.
1362 KEYWORDS should be of the form MATCH-ANCHORED, see `font-lock-keywords',
1363 LIMIT can be modified by the value of its PRE-MATCH-FORM."
1364   (let ((matcher (nth 0 keywords)) (lowdarks (nthcdr 3 keywords)) highlights
1365         (lead-start (match-beginning 0))
1366         ;; Evaluate PRE-MATCH-FORM.
1367         (pre-match-value (eval (nth 1 keywords))))
1368     ;; Set LIMIT to value of PRE-MATCH-FORM or the end of line.
1369     (if (not (and (numberp pre-match-value) (> pre-match-value (point))))
1370         (setq limit (line-end-position))
1371       (setq limit pre-match-value)
1372       (when (and font-lock-multiline (>= limit (line-beginning-position 2)))
1373         ;; this is a multiline anchored match
1374         ;; (setq font-lock-multiline t)
1375         (put-text-property (if (= limit (line-beginning-position 2))
1376                                (1- limit)
1377                              (min lead-start (point)))
1378                            limit
1379                            'font-lock-multiline t)))
1380     (save-match-data
1381       ;; Find an occurrence of `matcher' before `limit'.
1382       (while (and (< (point) limit)
1383                   (if (stringp matcher)
1384                       (re-search-forward matcher limit t)
1385                     (funcall matcher limit)))
1386         ;; Apply each highlight to this instance of `matcher'.
1387         (setq highlights lowdarks)
1388         (while highlights
1389           (font-lock-apply-highlight (car highlights))
1390           (setq highlights (cdr highlights)))))
1391     ;; Evaluate POST-MATCH-FORM.
1392     (eval (nth 2 keywords))))
1393
1394 (defun font-lock-fontify-keywords-region (start end &optional loudly)
1395   "Fontify according to `font-lock-keywords' between START and END.
1396 START should be at the beginning of a line.
1397 LOUDLY, if non-nil, allows progress-meter bar."
1398   (unless (eq (car font-lock-keywords) t)
1399     (setq font-lock-keywords
1400           (font-lock-compile-keywords font-lock-keywords t)))
1401   (let ((case-fold-search font-lock-keywords-case-fold-search)
1402         (keywords (cddr font-lock-keywords))
1403         (bufname (buffer-name)) (count 0)
1404         keyword matcher highlights)
1405     ;;
1406     ;; Fontify each item in `font-lock-keywords' from `start' to `end'.
1407     (while keywords
1408       (if loudly (message "Fontifying %s... (regexps..%s)" bufname
1409                           (make-string (incf count) ?.)))
1410       ;;
1411       ;; Find an occurrence of `matcher' from `start' to `end'.
1412       (setq keyword (car keywords) matcher (car keyword))
1413       (goto-char start)
1414       (while (and (< (point) end)
1415                   (if (stringp matcher)
1416                       (re-search-forward matcher end t)
1417                     (funcall matcher end)))
1418         (when (and font-lock-multiline
1419                    (>= (point)
1420                        (save-excursion (goto-char (match-beginning 0))
1421                                        (forward-line 1) (point))))
1422           ;; this is a multiline regexp match
1423           ;; (setq font-lock-multiline t)
1424           (put-text-property (if (= (point)
1425                                     (save-excursion
1426                                       (goto-char (match-beginning 0))
1427                                       (forward-line 1) (point)))
1428                                  (1- (point))
1429                                (match-beginning 0))
1430                              (point)
1431                              'font-lock-multiline t))
1432         ;; Apply each highlight to this instance of `matcher', which may be
1433         ;; specific highlights or more keywords anchored to `matcher'.
1434         (setq highlights (cdr keyword))
1435         (while highlights
1436           (if (numberp (car (car highlights)))
1437               (font-lock-apply-highlight (car highlights))
1438             (let ((pos (point)))
1439               (font-lock-fontify-anchored-keywords (car highlights) end)
1440               ;; Ensure forward progress.
1441               (if (< (point) pos) (goto-char pos))))
1442           (setq highlights (cdr highlights))))
1443       (setq keywords (cdr keywords)))))
1444
1445 ;;; End of Keyword regexp fontification functions.
1446 \f
1447 ;; Various functions.
1448
1449 (defun font-lock-compile-keywords (keywords &optional regexp)
1450   "Compile KEYWORDS into the form (t KEYWORDS COMPILED...)
1451 Here each COMPILED is of the form (MATCHER HIGHLIGHT ...) as shown in the
1452 `font-lock-keywords' doc string.
1453 If REGEXP is non-nil, it means these keywords are used for
1454 `font-lock-keywords' rather than for `font-lock-syntactic-keywords'."
1455   (if (eq (car-safe keywords) t)
1456       keywords
1457     (setq keywords
1458           (cons t (cons keywords
1459                         (mapcar 'font-lock-compile-keyword keywords))))
1460     (if (and regexp
1461              (eq (or syntax-begin-function
1462                      font-lock-beginning-of-syntax-function)
1463                  'beginning-of-defun)
1464              (not beginning-of-defun-function))
1465         ;; Try to detect when a string or comment contains something that
1466         ;; looks like a defun and would thus confuse font-lock.
1467         (nconc keywords
1468                `((,(if defun-prompt-regexp
1469                        (concat "^\\(?:" defun-prompt-regexp "\\)?\\s(")
1470                      "^\\s(")
1471                   (0
1472                    (if (memq (get-text-property (match-beginning 0) 'face)
1473                              '(font-lock-string-face font-lock-doc-face
1474                                font-lock-comment-face))
1475                        font-lock-warning-face)
1476                    prepend)))))
1477     keywords))
1478
1479 (defun font-lock-compile-keyword (keyword)
1480   (cond ((nlistp keyword)                       ; MATCHER
1481          (list keyword '(0 font-lock-keyword-face)))
1482         ((eq (car keyword) 'eval)               ; (eval . FORM)
1483          (font-lock-compile-keyword (eval (cdr keyword))))
1484         ((eq (car-safe (cdr keyword)) 'quote)   ; (MATCHER . 'FORM)
1485          ;; If FORM is a FACENAME then quote it.  Otherwise ignore the quote.
1486          (if (symbolp (nth 2 keyword))
1487              (list (car keyword) (list 0 (cdr keyword)))
1488            (font-lock-compile-keyword (cons (car keyword) (nth 2 keyword)))))
1489         ((numberp (cdr keyword))                ; (MATCHER . MATCH)
1490          (list (car keyword) (list (cdr keyword) 'font-lock-keyword-face)))
1491         ((symbolp (cdr keyword))                ; (MATCHER . FACENAME)
1492          (list (car keyword) (list 0 (cdr keyword))))
1493         ((nlistp (nth 1 keyword))               ; (MATCHER . HIGHLIGHT)
1494          (list (car keyword) (cdr keyword)))
1495         (t                                      ; (MATCHER HIGHLIGHT ...)
1496          keyword)))
1497
1498 (defun font-lock-eval-keywords (keywords)
1499   "Evalulate KEYWORDS if a function (funcall) or variable (eval) name."
1500   (if (listp keywords)
1501       keywords
1502     (font-lock-eval-keywords (if (fboundp keywords)
1503                                  (funcall keywords)
1504                                (eval keywords)))))
1505
1506 (defun font-lock-value-in-major-mode (alist)
1507   "Return value in ALIST for `major-mode', or ALIST if it is not an alist.
1508 Structure is ((MAJOR-MODE . VALUE) ...) where MAJOR-MODE may be t."
1509   (if (consp alist)
1510       (cdr (or (assq major-mode alist) (assq t alist)))
1511     alist))
1512
1513 (defun font-lock-choose-keywords (keywords level)
1514   "Return LEVELth element of KEYWORDS.
1515 A LEVEL of nil is equal to a LEVEL of 0, a LEVEL of t is equal to
1516 \(1- (length KEYWORDS))."
1517   (cond ((not (and (listp keywords) (symbolp (car keywords))))
1518          keywords)
1519         ((numberp level)
1520          (or (nth level keywords) (car (reverse keywords))))
1521         ((eq level t)
1522          (car (reverse keywords)))
1523         (t
1524          (car keywords))))
1525
1526 (defvar font-lock-set-defaults nil)     ; Whether we have set up defaults.
1527
1528 (defun font-lock-set-defaults ()
1529   "Set fontification defaults appropriately for this mode.
1530 Sets various variables using `font-lock-defaults' (or, if nil, using
1531 `font-lock-defaults-alist') and `font-lock-maximum-decoration'."
1532   ;; Set fontification defaults iff not previously set.
1533   (unless font-lock-set-defaults
1534     (set (make-local-variable 'font-lock-set-defaults) t)
1535     (make-local-variable 'font-lock-fontified)
1536     (make-local-variable 'font-lock-multiline)
1537     (let* ((defaults (or font-lock-defaults
1538                          (cdr (assq major-mode
1539                                     (with-no-warnings
1540                                      font-lock-defaults-alist)))))
1541            (keywords
1542             (font-lock-choose-keywords (nth 0 defaults)
1543                                        (font-lock-value-in-major-mode font-lock-maximum-decoration)))
1544            (local (cdr (assq major-mode font-lock-keywords-alist)))
1545            (removed-keywords
1546             (cdr-safe (assq major-mode font-lock-removed-keywords-alist))))
1547       (set (make-local-variable 'font-lock-defaults) defaults)
1548       ;; Syntactic fontification?
1549       (when (nth 1 defaults)
1550         (set (make-local-variable 'font-lock-keywords-only) t))
1551       ;; Case fold during regexp fontification?
1552       (when (nth 2 defaults)
1553         (set (make-local-variable 'font-lock-keywords-case-fold-search) t))
1554       ;; Syntax table for regexp and syntactic fontification?
1555       (when (nth 3 defaults)
1556         (set (make-local-variable 'font-lock-syntax-table)
1557              (copy-syntax-table (syntax-table)))
1558         (dolist (selem (nth 3 defaults))
1559           ;; The character to modify may be a single CHAR or a STRING.
1560           (let ((syntax (cdr selem)))
1561             (dolist (char (if (numberp (car selem))
1562                               (list (car selem))
1563                             (mapcar 'identity (car selem))))
1564               (modify-syntax-entry char syntax font-lock-syntax-table)))))
1565       ;; Syntax function for syntactic fontification?
1566       (when (nth 4 defaults)
1567         (set (make-local-variable 'font-lock-beginning-of-syntax-function)
1568              (nth 4 defaults)))
1569       ;; Variable alist?
1570       (dolist (x (nthcdr 5 defaults))
1571         (set (make-local-variable (car x)) (cdr x)))
1572       ;; Set up `font-lock-keywords' last because its value might depend
1573       ;; on other settings (e.g. font-lock-compile-keywords uses
1574       ;; font-lock-beginning-of-syntax-function).
1575       (set (make-local-variable 'font-lock-keywords)
1576            (font-lock-eval-keywords keywords))
1577       ;; Local fontification?
1578       (while local
1579         (font-lock-add-keywords nil (car (car local)) (cdr (car local)))
1580         (setq local (cdr local)))
1581       (when removed-keywords
1582         (font-lock-remove-keywords nil removed-keywords))
1583       ;; Now compile the keywords.
1584       (unless (eq (car font-lock-keywords) t)
1585         (set (make-local-variable 'font-lock-keywords)
1586              (font-lock-compile-keywords font-lock-keywords t))))))
1587 \f
1588 ;;; Colour etc. support.
1589
1590 ;; Originally face attributes were specified via `font-lock-face-attributes'.
1591 ;; Users then changed the default face attributes by setting that variable.
1592 ;; However, we try and be back-compatible and respect its value if set except
1593 ;; for faces where M-x customize has been used to save changes for the face.
1594 (when (boundp 'font-lock-face-attributes)
1595   (let ((face-attributes font-lock-face-attributes))
1596     (while face-attributes
1597       (let* ((face-attribute (pop face-attributes))
1598              (face (car face-attribute)))
1599         ;; Rustle up a `defface' SPEC from a `font-lock-face-attributes' entry.
1600         (unless (get face 'saved-face)
1601           (let ((foreground (nth 1 face-attribute))
1602                 (background (nth 2 face-attribute))
1603                 (bold-p (nth 3 face-attribute))
1604                 (italic-p (nth 4 face-attribute))
1605                 (underline-p (nth 5 face-attribute))
1606                 face-spec)
1607             (when foreground
1608               (setq face-spec (cons ':foreground (cons foreground face-spec))))
1609             (when background
1610               (setq face-spec (cons ':background (cons background face-spec))))
1611             (when bold-p
1612               (setq face-spec (append '(:weight bold) face-spec)))
1613             (when italic-p
1614               (setq face-spec (append '(:slant italic) face-spec)))
1615             (when underline-p
1616               (setq face-spec (append '(:underline t) face-spec)))
1617             (custom-declare-face face (list (list t face-spec)) nil)))))))
1618
1619 ;; But now we do it the custom way.  Note that `defface' will not overwrite any
1620 ;; faces declared above via `custom-declare-face'.
1621 (defface font-lock-comment-delimiter-face
1622   '((((class grayscale) (background light))
1623      (:foreground "DimGray" :weight bold :slant italic))
1624     (((class grayscale) (background dark))
1625      (:foreground "LightGray" :weight bold :slant italic))
1626     (((class color) (min-colors 88) (background light))
1627      (:foreground "Firebrick"))
1628     (((class color) (min-colors 88) (background dark))
1629      (:foreground "chocolate1"))
1630     (((class color) (min-colors 16) (background light))
1631      (:foreground "red"))
1632     (((class color) (min-colors 16) (background dark))
1633      (:foreground "red1"))
1634     (((class color) (min-colors 8) (background light))
1635      (:foreground "red"))
1636     (((class color) (min-colors 8) (background dark))
1637      (:foreground "red1"))
1638     (t (:weight bold :slant italic)))
1639   "Font Lock mode face used to highlight comment delimiters."
1640   :group 'font-lock-highlighting-faces)
1641
1642 (defface font-lock-comment-face
1643   '((((class grayscale) (background light))
1644      (:foreground "DimGray" :weight bold :slant italic))
1645     (((class grayscale) (background dark))
1646      (:foreground "LightGray" :weight bold :slant italic))
1647     (((class color) (min-colors 88) (background light))
1648      (:foreground "Firebrick"))
1649     (((class color) (min-colors 88) (background dark))
1650      (:foreground "chocolate1"))
1651     (((class color) (min-colors 16) (background light))
1652      (:foreground "red"))
1653     (((class color) (min-colors 16) (background dark))
1654      (:foreground "red1"))
1655     (((class color) (min-colors 8) (background light))
1656      )
1657     (((class color) (min-colors 8) (background dark))
1658      )
1659     (t (:weight bold :slant italic)))
1660   "Font Lock mode face used to highlight comments."
1661   :group 'font-lock-highlighting-faces)
1662
1663 (defface font-lock-string-face
1664   '((((class grayscale) (background light)) (:foreground "DimGray" :slant italic))
1665     (((class grayscale) (background dark)) (:foreground "LightGray" :slant italic))
1666     (((class color) (min-colors 88) (background light)) (:foreground "RosyBrown"))
1667     (((class color) (min-colors 88) (background dark)) (:foreground "LightSalmon"))
1668     (((class color) (min-colors 16) (background light)) (:foreground "RosyBrown"))
1669     (((class color) (min-colors 16) (background dark)) (:foreground "LightSalmon"))
1670     (((class color) (min-colors 8)) (:foreground "green"))
1671     (t (:slant italic)))
1672   "Font Lock mode face used to highlight strings."
1673   :group 'font-lock-highlighting-faces)
1674
1675 (defface font-lock-doc-face
1676   '((t :inherit font-lock-string-face))
1677   "Font Lock mode face used to highlight documentation."
1678   :group 'font-lock-highlighting-faces)
1679
1680 (defface font-lock-keyword-face
1681   '((((class grayscale) (background light)) (:foreground "LightGray" :weight bold))
1682     (((class grayscale) (background dark)) (:foreground "DimGray" :weight bold))
1683     (((class color) (min-colors 88) (background light)) (:foreground "Purple"))
1684     (((class color) (min-colors 88) (background dark)) (:foreground "Cyan1"))
1685     (((class color) (min-colors 16) (background light)) (:foreground "Purple"))
1686     (((class color) (min-colors 16) (background dark)) (:foreground "Cyan"))
1687     (((class color) (min-colors 8)) (:foreground "cyan" :weight bold))
1688     (t (:weight bold)))
1689   "Font Lock mode face used to highlight keywords."
1690   :group 'font-lock-highlighting-faces)
1691
1692 (defface font-lock-builtin-face
1693   '((((class grayscale) (background light)) (:foreground "LightGray" :weight bold))
1694     (((class grayscale) (background dark)) (:foreground "DimGray" :weight bold))
1695     (((class color) (min-colors 88) (background light)) (:foreground "Orchid"))
1696     (((class color) (min-colors 88) (background dark)) (:foreground "LightSteelBlue"))
1697     (((class color) (min-colors 16) (background light)) (:foreground "Orchid"))
1698     (((class color) (min-colors 16) (background dark)) (:foreground "LightSteelBlue"))
1699     (((class color) (min-colors 8)) (:foreground "blue" :weight bold))
1700     (t (:weight bold)))
1701   "Font Lock mode face used to highlight builtins."
1702   :group 'font-lock-highlighting-faces)
1703
1704 (defface font-lock-function-name-face
1705   '((((class color) (min-colors 88) (background light)) (:foreground "Blue1"))
1706     (((class color) (min-colors 88) (background dark)) (:foreground "LightSkyBlue"))
1707     (((class color) (min-colors 16) (background light)) (:foreground "Blue"))
1708     (((class color) (min-colors 16) (background dark)) (:foreground "LightSkyBlue"))
1709     (((class color) (min-colors 8)) (:foreground "blue" :weight bold))
1710     (t (:inverse-video t :weight bold)))
1711   "Font Lock mode face used to highlight function names."
1712   :group 'font-lock-highlighting-faces)
1713
1714 (defface font-lock-variable-name-face
1715   '((((class grayscale) (background light))
1716      (:foreground "Gray90" :weight bold :slant italic))
1717     (((class grayscale) (background dark))
1718      (:foreground "DimGray" :weight bold :slant italic))
1719     (((class color) (min-colors 88) (background light)) (:foreground "DarkGoldenrod"))
1720     (((class color) (min-colors 88) (background dark)) (:foreground "LightGoldenrod"))
1721     (((class color) (min-colors 16) (background light)) (:foreground "DarkGoldenrod"))
1722     (((class color) (min-colors 16) (background dark)) (:foreground "LightGoldenrod"))
1723     (((class color) (min-colors 8)) (:foreground "yellow" :weight light))
1724     (t (:weight bold :slant italic)))
1725   "Font Lock mode face used to highlight variable names."
1726   :group 'font-lock-highlighting-faces)
1727
1728 (defface font-lock-type-face
1729   '((((class grayscale) (background light)) (:foreground "Gray90" :weight bold))
1730     (((class grayscale) (background dark)) (:foreground "DimGray" :weight bold))
1731     (((class color) (min-colors 88) (background light)) (:foreground "ForestGreen"))
1732     (((class color) (min-colors 88) (background dark)) (:foreground "PaleGreen"))
1733     (((class color) (min-colors 16) (background light)) (:foreground "ForestGreen"))
1734     (((class color) (min-colors 16) (background dark)) (:foreground "PaleGreen"))
1735     (((class color) (min-colors 8)) (:foreground "green"))
1736     (t (:weight bold :underline t)))
1737   "Font Lock mode face used to highlight type and classes."
1738   :group 'font-lock-highlighting-faces)
1739
1740 (defface font-lock-constant-face
1741   '((((class grayscale) (background light))
1742      (:foreground "LightGray" :weight bold :underline t))
1743     (((class grayscale) (background dark))
1744      (:foreground "Gray50" :weight bold :underline t))
1745     (((class color) (min-colors 88) (background light)) (:foreground "CadetBlue"))
1746     (((class color) (min-colors 88) (background dark)) (:foreground "Aquamarine"))
1747     (((class color) (min-colors 16) (background light)) (:foreground "CadetBlue"))
1748     (((class color) (min-colors 16) (background dark)) (:foreground "Aquamarine"))
1749     (((class color) (min-colors 8)) (:foreground "magenta"))
1750     (t (:weight bold :underline t)))
1751   "Font Lock mode face used to highlight constants and labels."
1752   :group 'font-lock-highlighting-faces)
1753
1754 (defface font-lock-warning-face
1755   '((((class color) (min-colors 88) (background light)) (:foreground "Red1" :weight bold))
1756     (((class color) (min-colors 88) (background dark)) (:foreground "Pink" :weight bold))
1757     (((class color) (min-colors 16) (background light)) (:foreground "Red" :weight bold))
1758     (((class color) (min-colors 16) (background dark)) (:foreground "Pink" :weight bold))
1759     (((class color) (min-colors 8)) (:foreground "red"))
1760     (t (:inverse-video t :weight bold)))
1761   "Font Lock mode face used to highlight warnings."
1762   :group 'font-lock-highlighting-faces)
1763
1764 (defface font-lock-preprocessor-face
1765   '((t :inherit font-lock-builtin-face))
1766   "Font Lock mode face used to highlight preprocessor directives."
1767   :group 'font-lock-highlighting-faces)
1768
1769 ;;; End of Colour etc. support.
1770 \f
1771 ;;; Menu support.
1772
1773 ;; This section of code is commented out because Emacs does not have real menu
1774 ;; buttons.  (We can mimic them by putting "( ) " or "(X) " at the beginning of
1775 ;; the menu entry text, but with Xt it looks both ugly and embarrassingly
1776 ;; amateur.)  If/When Emacs gets real menus buttons, put in menu-bar.el after
1777 ;; the entry for "Text Properties" something like:
1778 ;;
1779 ;; (define-key menu-bar-edit-menu [font-lock]
1780 ;;   (cons "Syntax Highlighting" font-lock-menu))
1781 ;;
1782 ;; and remove a single ";" from the beginning of each line in the rest of this
1783 ;; section.  Probably the mechanism for telling the menu code what are menu
1784 ;; buttons and when they are on or off needs tweaking.  I have assumed that the
1785 ;; mechanism is via `menu-toggle' and `menu-selected' symbol properties.  sm.
1786
1787 ;;;;###autoload
1788 ;(progn
1789 ;  ;; Make the Font Lock menu.
1790 ;  (defvar font-lock-menu (make-sparse-keymap "Syntax Highlighting"))
1791 ;  ;; Add the menu items in reverse order.
1792 ;  (define-key font-lock-menu [fontify-less]
1793 ;    '("Less In Current Buffer" . font-lock-fontify-less))
1794 ;  (define-key font-lock-menu [fontify-more]
1795 ;    '("More In Current Buffer" . font-lock-fontify-more))
1796 ;  (define-key font-lock-menu [font-lock-sep]
1797 ;    '("--"))
1798 ;  (define-key font-lock-menu [font-lock-mode]
1799 ;    '("In Current Buffer" . font-lock-mode))
1800 ;  (define-key font-lock-menu [global-font-lock-mode]
1801 ;    '("In All Buffers" . global-font-lock-mode)))
1802 ;
1803 ;;;;###autoload
1804 ;(progn
1805 ;  ;; We put the appropriate `menu-enable' etc. symbol property values on when
1806 ;  ;; font-lock.el is loaded, so we don't need to autoload the three variables.
1807 ;  (put 'global-font-lock-mode 'menu-toggle t)
1808 ;  (put 'font-lock-mode 'menu-toggle t)
1809 ;  (put 'font-lock-fontify-more 'menu-enable '(identity))
1810 ;  (put 'font-lock-fontify-less 'menu-enable '(identity)))
1811 ;
1812 ;;; Put the appropriate symbol property values on now.  See above.
1813 ;(put 'global-font-lock-mode 'menu-selected 'global-font-lock-mode)
1814 ;(put 'font-lock-mode 'menu-selected 'font-lock-mode)
1815 ;(put 'font-lock-fontify-more 'menu-enable '(nth 2 font-lock-fontify-level))
1816 ;(put 'font-lock-fontify-less 'menu-enable '(nth 1 font-lock-fontify-level))
1817 ;
1818 ;(defvar font-lock-fontify-level nil)   ; For less/more fontification.
1819 ;
1820 ;(defun font-lock-fontify-level (level)
1821 ;  (let ((font-lock-maximum-decoration level))
1822 ;    (when font-lock-mode
1823 ;      (font-lock-mode))
1824 ;    (font-lock-mode)
1825 ;    (when font-lock-verbose
1826 ;      (message "Fontifying %s... level %d" (buffer-name) level))))
1827 ;
1828 ;(defun font-lock-fontify-less ()
1829 ;  "Fontify the current buffer with less decoration.
1830 ;See `font-lock-maximum-decoration'."
1831 ;  (interactive)
1832 ;  ;; Check in case we get called interactively.
1833 ;  (if (nth 1 font-lock-fontify-level)
1834 ;      (font-lock-fontify-level (1- (car font-lock-fontify-level)))
1835 ;    (error "No less decoration")))
1836 ;
1837 ;(defun font-lock-fontify-more ()
1838 ;  "Fontify the current buffer with more decoration.
1839 ;See `font-lock-maximum-decoration'."
1840 ;  (interactive)
1841 ;  ;; Check in case we get called interactively.
1842 ;  (if (nth 2 font-lock-fontify-level)
1843 ;      (font-lock-fontify-level (1+ (car font-lock-fontify-level)))
1844 ;    (error "No more decoration")))
1845 ;
1846 ;;; This should be called by `font-lock-set-defaults'.
1847 ;(defun font-lock-set-menu ()
1848 ;  ;; Activate less/more fontification entries if there are multiple levels for
1849 ;  ;; the current buffer.  Sets `font-lock-fontify-level' to be of the form
1850 ;  ;; (CURRENT-LEVEL IS-LOWER-LEVEL-P IS-HIGHER-LEVEL-P) for menu activation.
1851 ;  (let ((keywords (or (nth 0 font-lock-defaults)
1852 ;                     (nth 1 (assq major-mode font-lock-defaults-alist))))
1853 ;       (level (font-lock-value-in-major-mode font-lock-maximum-decoration)))
1854 ;    (make-local-variable 'font-lock-fontify-level)
1855 ;    (if (or (symbolp keywords) (= (length keywords) 1))
1856 ;       (font-lock-unset-menu)
1857 ;      (cond ((eq level t)
1858 ;            (setq level (1- (length keywords))))
1859 ;           ((or (null level) (zerop level))
1860 ;            ;; The default level is usually, but not necessarily, level 1.
1861 ;            (setq level (- (length keywords)
1862 ;                           (length (member (eval (car keywords))
1863 ;                                           (mapcar 'eval (cdr keywords))))))))
1864 ;      (setq font-lock-fontify-level (list level (> level 1)
1865 ;                                         (< level (1- (length keywords))))))))
1866 ;
1867 ;;; This should be called by `font-lock-unset-defaults'.
1868 ;(defun font-lock-unset-menu ()
1869 ;  ;; Deactivate less/more fontification entries.
1870 ;  (setq font-lock-fontify-level nil))
1871
1872 ;;; End of Menu support.
1873 \f
1874 ;;; Various regexp information shared by several modes.
1875 ;;; Information specific to a single mode should go in its load library.
1876
1877 ;; Font Lock support for C, C++, Objective-C and Java modes is now in
1878 ;; cc-fonts.el (and required by cc-mode.el).  However, the below function
1879 ;; should stay in font-lock.el, since it is used by other libraries.  sm.
1880
1881 (defun font-lock-match-c-style-declaration-item-and-skip-to-next (limit)
1882   "Match, and move over, any declaration/definition item after point.
1883 Matches after point, but ignores leading whitespace and `*' characters.
1884 Does not move further than LIMIT.
1885
1886 The expected syntax of a declaration/definition item is `word' (preceded by
1887 optional whitespace and `*' characters and proceeded by optional whitespace)
1888 optionally followed by a `('.  Everything following the item (but belonging to
1889 it) is expected to be skip-able by `scan-sexps', and items are expected to be
1890 separated with a `,' and to be terminated with a `;'.
1891
1892 Thus the regexp matches after point:    word (
1893                                         ^^^^ ^
1894 Where the match subexpressions are:       1  2
1895
1896 The item is delimited by (match-beginning 1) and (match-end 1).
1897 If (match-beginning 2) is non-nil, the item is followed by a `('.
1898
1899 This function could be MATCHER in a MATCH-ANCHORED `font-lock-keywords' item."
1900   (when (looking-at "[ \n\t*]*\\(\\sw+\\)[ \t\n]*\\(((?\\)?")
1901     (when (and (match-end 2) (> (- (match-end 2) (match-beginning 2)) 1))
1902       ;; If `word' is followed by a double open-paren, it's probably
1903       ;; a macro used for "int myfun P_ ((int arg1))".  Let's go back one
1904       ;; word to try and match `myfun' rather than `P_'.
1905       (let ((pos (point)))
1906         (skip-chars-backward " \t\n")
1907         (skip-syntax-backward "w")
1908         (unless (looking-at "\\(\\sw+\\)[ \t\n]*\\sw+[ \t\n]*\\(((?\\)?")
1909           ;; Looks like it was something else, so go back to where we
1910           ;; were and reset the match data by rematching.
1911           (goto-char pos)
1912           (looking-at "[ \n\t*]*\\(\\sw+\\)[ \t\n]*\\(((?\\)?"))))
1913     (save-match-data
1914       (condition-case nil
1915           (save-restriction
1916             ;; Restrict to the LIMIT.
1917             (narrow-to-region (point-min) limit)
1918             (goto-char (match-end 1))
1919             ;; Move over any item value, etc., to the next item.
1920             (while (not (looking-at "[ \t\n]*\\(\\(,\\)\\|;\\|\\'\\)"))
1921               (goto-char (or (scan-sexps (point) 1) (point-max))))
1922             (goto-char (match-end 2)))
1923         (error t)))))
1924 \f
1925 ;; Lisp.
1926
1927 (defconst lisp-font-lock-keywords-1
1928   (eval-when-compile
1929     (list
1930      ;;
1931      ;; Definitions.
1932      (list (concat "(\\(def\\("
1933                    ;; Function declarations.
1934                    "\\(advice\\|varalias\\|alias\\|generic\\|macro\\*?\\|method\\|"
1935                    "setf\\|subst\\*?\\|un\\*?\\|"
1936                    "ine-\\(condition\\|\\(?:derived\\|minor\\|generic\\)-mode\\|"
1937                    "method-combination\\|setf-expander\\|skeleton\\|widget\\|"
1938                    "function\\|\\(compiler\\|modify\\|symbol\\)-macro\\)\\)\\|"
1939                    ;; Variable declarations.
1940                    "\\(const\\(ant\\)?\\|custom\\|face\\|parameter\\|var\\)\\|"
1941                    ;; Structure declarations.
1942                    "\\(class\\|group\\|theme\\|package\\|struct\\|type\\)"
1943                    "\\)\\)\\>"
1944                    ;; Any whitespace and defined object.
1945                    "[ \t'\(]*"
1946                    "\\(setf[ \t]+\\sw+)\\|\\sw+\\)?")
1947            '(1 font-lock-keyword-face)
1948            '(9 (cond ((match-beginning 3) font-lock-function-name-face)
1949                      ((match-beginning 6) font-lock-variable-name-face)
1950                      (t font-lock-type-face))
1951                nil t))
1952      ;;
1953      ;; Emacs Lisp autoload cookies.
1954      '("^;;;###\\(autoload\\)" 1 font-lock-warning-face prepend)
1955      ))
1956   "Subdued level highlighting for Lisp modes.")
1957
1958 (defconst lisp-font-lock-keywords-2
1959   (append lisp-font-lock-keywords-1
1960    (eval-when-compile
1961      (list
1962       ;;
1963       ;; Control structures.  Emacs Lisp forms.
1964       (cons (concat
1965              "(" (regexp-opt
1966                   '("cond" "if" "while" "let" "let*"
1967                     "prog" "progn" "progv" "prog1" "prog2" "prog*"
1968                     "inline" "lambda" "save-restriction" "save-excursion"
1969                     "save-window-excursion" "save-selected-window"
1970                     "save-match-data" "save-current-buffer" "unwind-protect"
1971                     "condition-case" "track-mouse"
1972                     "eval-after-load" "eval-and-compile" "eval-when-compile"
1973                     "eval-when"
1974                     "with-category-table"
1975                     "with-current-buffer" "with-electric-help"
1976                     "with-local-quit" "with-no-warnings"
1977                     "with-output-to-string" "with-output-to-temp-buffer"
1978                     "with-selected-window" "with-syntax-table"
1979                     "with-temp-buffer" "with-temp-file" "with-temp-message"
1980                     "with-timeout" "with-timeout-handler") t)
1981              "\\>")
1982             1)
1983       ;;
1984       ;; Control structures.  Common Lisp forms.
1985       (cons (concat
1986              "(" (regexp-opt
1987                   '("when" "unless" "case" "ecase" "typecase" "etypecase"
1988                     "ccase" "ctypecase" "handler-case" "handler-bind"
1989                     "restart-bind" "restart-case" "in-package"
1990                     "break" "ignore-errors"
1991                     "loop" "do" "do*" "dotimes" "dolist" "the" "locally"
1992                     "proclaim" "declaim" "declare" "symbol-macrolet"
1993                     "lexical-let" "lexical-let*" "flet" "labels" "compiler-let"
1994                     "destructuring-bind" "macrolet" "tagbody" "block" "go"
1995                     "multiple-value-bind" "multiple-value-prog1"
1996                     "return" "return-from"
1997                     "with-accessors" "with-compilation-unit"
1998                     "with-condition-restarts" "with-hash-table-iterator"
1999                     "with-input-from-string" "with-open-file"
2000                     "with-open-stream" "with-output-to-string"
2001                     "with-package-iterator" "with-simple-restart"
2002                     "with-slots" "with-standard-io-syntax") t)
2003              "\\>")
2004             1)
2005       ;;
2006       ;; Exit/Feature symbols as constants.
2007       (list (concat "(\\(catch\\|throw\\|featurep\\|provide\\|require\\)\\>"
2008                     "[ \t']*\\(\\sw+\\)?")
2009             '(1 font-lock-keyword-face)
2010             '(2 font-lock-constant-face nil t))
2011       ;;
2012       ;; Erroneous structures.
2013       '("(\\(abort\\|assert\\|warn\\|check-type\\|cerror\\|error\\|signal\\)\\>" 1 font-lock-warning-face)
2014       ;;
2015       ;; Words inside \\[] tend to be for `substitute-command-keys'.
2016       '("\\\\\\\\\\[\\(\\sw+\\)]" 1 font-lock-constant-face prepend)
2017       ;;
2018       ;; Words inside `' tend to be symbol names.
2019       '("`\\(\\sw\\sw+\\)'" 1 font-lock-constant-face prepend)
2020       ;;
2021       ;; Constant values.
2022       '("\\<:\\sw+\\>" 0 font-lock-builtin-face)
2023       ;;
2024       ;; ELisp and CLisp `&' keywords as types.
2025       '("\\&\\sw+\\>" . font-lock-type-face)
2026       ;;
2027 ;;; This is too general -- rms.
2028 ;;; A user complained that he has functions whose names start with `do'
2029 ;;; and that they get the wrong color.
2030 ;;;      ;; CL `with-' and `do-' constructs
2031 ;;;      '("(\\(\\(do-\\|with-\\)\\(\\s_\\|\\w\\)*\\)" 1 font-lock-keyword-face)
2032       )))
2033   "Gaudy level highlighting for Lisp modes.")
2034
2035 (defvar lisp-font-lock-keywords lisp-font-lock-keywords-1
2036   "Default expressions to highlight in Lisp modes.")
2037 \f
2038 (provide 'font-lock)
2039
2040 ;; arch-tag: 682327e4-64d8-4057-b20b-1fbb9f1fc54c
2041 ;;; font-lock.el ends here