code.delx.au - gnu-emacs/blob - lisp/sort.el

   1 ;;; sort.el --- commands to sort text in an Emacs buffer.
   2
   3 ;; Copyright (C) 1986, 1987 Free Software Foundation, Inc.
   4
   5 ;; Author: Howie Kaye
   6 ;; Maintainer: FSF
   7 ;; Keywords: unix
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; This package provides the sorting facilities documented in the Emacs
  28 ;;; user's manual.
  29
  30 ;;; Code:
  31
  32 (defvar sort-fold-case nil
  33   "*Non-nil if the buffer sort functions should ignore case.")
  34
  35 (defun sort-subr (reverse nextrecfun endrecfun &optional startkeyfun endkeyfun)
  36   "General text sorting routine to divide buffer into records and sort them.
  37 Arguments are REVERSE NEXTRECFUN ENDRECFUN &optional STARTKEYFUN ENDKEYFUN.
  38
  39 We divide the accessible portion of the buffer into disjoint pieces
  40 called sort records.  A portion of each sort record (perhaps all of
  41 it) is designated as the sort key.  The records are rearranged in the
  42 buffer in order by their sort keys.  The records may or may not be
  43 contiguous.
  44
  45 Usually the records are rearranged in order of ascending sort key.
  46 If REVERSE is non-nil, they are rearranged in order of descending sort key.
  47
  48 The next four arguments are functions to be called to move point
  49 across a sort record.  They will be called many times from within sort-subr.
  50
  51 NEXTRECFUN is called with point at the end of the previous record.
  52 It moves point to the start of the next record.
  53 It should move point to the end of the buffer if there are no more records.
  54 The first record is assumed to start at the position of point when sort-subr
  55 is called.
  56
  57 ENDRECFUN is called with point within the record.
  58 It should move point to the end of the record.
  59
  60 STARTKEYFUN moves from the start of the record to the start of the key.
  61 It may return either a non-nil value to be used as the key, or
  62 else the key is the substring between the values of point after
  63 STARTKEYFUN and ENDKEYFUN are called.  If STARTKEYFUN is nil, the key
  64 starts at the beginning of the record.
  65
  66 ENDKEYFUN moves from the start of the sort key to the end of the sort key.
  67 ENDKEYFUN may be nil if STARTKEYFUN returns a value or if it would be the
  68 same as ENDRECFUN."
  69   ;; Heuristically try to avoid messages if sorting a small amt of text.
  70   (let ((messages (> (- (point-max) (point-min)) 50000)))
  71     (save-excursion
  72       (if messages (message "Finding sort keys..."))
  73       (let* ((sort-lists (sort-build-lists nextrecfun endrecfun
  74                                            startkeyfun endkeyfun))
  75              (old (reverse sort-lists))
  76              (case-fold-search sort-fold-case))
  77         (if (null sort-lists)
  78             ()
  79           (or reverse (setq sort-lists (nreverse sort-lists)))
  80           (if messages (message "Sorting records..."))
  81           (setq sort-lists
  82                 (if (fboundp 'sortcar)
  83                     (sortcar sort-lists
  84                              (cond ((numberp (car (car sort-lists)))
  85                                     ;; This handles both ints and floats.
  86                                     '<)
  87                                    ((consp (car (car sort-lists)))
  88                                     (function
  89                                      (lambda (a b)
  90                                        (> 0 (compare-buffer-substrings
  91                                              nil (car a) (cdr a)
  92                                              nil (car b) (cdr b))))))
  93                                    (t
  94                                     'string<)))
  95                   (sort sort-lists
  96                         (cond ((numberp (car (car sort-lists)))
  97                                (function
  98                                 (lambda (a b)
  99                                   (< (car a) (car b)))))
 100                               ((consp (car (car sort-lists)))
 101                                (function
 102                                 (lambda (a b)
 103                                   (> 0 (compare-buffer-substrings
 104                                         nil (car (car a)) (cdr (car a))
 105                                         nil (car (car b)) (cdr (car b)))))))
 106                               (t
 107                                (function
 108                                 (lambda (a b)
 109                                   (string< (car a) (car b)))))))))
 110           (if reverse (setq sort-lists (nreverse sort-lists)))
 111           (if messages (message "Reordering buffer..."))
 112           (sort-reorder-buffer sort-lists old)))
 113       (if messages (message "Reordering buffer... Done"))))
 114   nil)
 115
 116 ;; Parse buffer into records using the arguments as Lisp expressions;
 117 ;; return a list of records.  Each record looks like (KEY STARTPOS . ENDPOS)
 118 ;; where KEY is the sort key (a number or string),
 119 ;; and STARTPOS and ENDPOS are the bounds of this record in the buffer.
 120
 121 ;; The records appear in the list lastmost first!
 122
 123 (defun sort-build-lists (nextrecfun endrecfun startkeyfun endkeyfun)
 124   (let ((sort-lists ())
 125         (start-rec nil)
 126         done key)
 127     ;; Loop over sort records.
 128     ;(goto-char (point-min)) -- it is the caller's responsibility to
 129     ;arrange this if necessary
 130     (while (not (eobp))
 131       (setq start-rec (point))          ;save record start
 132       (setq done nil)
 133       ;; Get key value, or move to start of key.
 134       (setq key (catch 'key
 135                   (or (and startkeyfun (funcall startkeyfun))
 136                       ;; If key was not returned as value,
 137                       ;; move to end of key and get key from the buffer.
 138                       (let ((start (point)))
 139                         (funcall (or endkeyfun
 140                                      (prog1 endrecfun (setq done t))))
 141                         (cons start (point))))))
 142       ;; Move to end of this record (start of next one, or end of buffer).
 143       (cond ((prog1 done (setq done nil)))
 144             (endrecfun (funcall endrecfun))
 145             (nextrecfun (funcall nextrecfun) (setq done t)))
 146       (if key (setq sort-lists (cons
 147                                  ;; consing optimization in case in which key
 148                                  ;; is same as record.
 149                                  (if (and (consp key)
 150                                           (equal (car key) start-rec)
 151                                           (equal (cdr key) (point)))
 152                                      (cons key key)
 153                                    (cons key (cons start-rec (point))))
 154                                  sort-lists)))
 155       (and (not done) nextrecfun (funcall nextrecfun)))
 156     sort-lists))
 157
 158 (defun sort-reorder-buffer (sort-lists old)
 159   (let ((inhibit-quit t)
 160         (last (point-min))
 161         (min (point-min)) (max (point-max)))
 162     ;; Make sure insertions done for reordering
 163     ;; do not go after any markers at the end of the sorted region,
 164     ;; by inserting a space to separate them.
 165     (goto-char (point-max))
 166     (insert-before-markers " ")
 167     (narrow-to-region min (1- (point-max)))
 168     (while sort-lists
 169       (goto-char (point-max))
 170       (insert-buffer-substring (current-buffer)
 171                                last
 172                                (nth 1 (car old)))
 173       (goto-char (point-max))
 174       (insert-buffer-substring (current-buffer)
 175                                (nth 1 (car sort-lists))
 176                                (cdr (cdr (car sort-lists))))
 177       (setq last (cdr (cdr (car old)))
 178             sort-lists (cdr sort-lists)
 179             old (cdr old)))
 180     (goto-char (point-max))
 181     (insert-buffer-substring (current-buffer)
 182                              last
 183                              max)
 184     ;; Delete the original copy of the text.
 185     (delete-region min max)
 186     ;; Get rid of the separator " ".
 187     (goto-char (point-max))
 188     (narrow-to-region min (1+ (point)))
 189     (delete-region (point) (1+ (point)))))
 190
 191 ;;;###autoload
 192 (defun sort-lines (reverse beg end)
 193   "Sort lines in region alphabetically; argument means descending order.
 194 Called from a program, there are three arguments:
 195 REVERSE (non-nil means reverse order), BEG and END (region to sort)."
 196   (interactive "P\nr")
 197   (save-excursion
 198     (save-restriction
 199       (narrow-to-region beg end)
 200       (goto-char (point-min))
 201       (sort-subr reverse 'forward-line 'end-of-line))))
 202
 203 ;;;###autoload
 204 (defun sort-paragraphs (reverse beg end)
 205   "Sort paragraphs in region alphabetically; argument means descending order.
 206 Called from a program, there are three arguments:
 207 REVERSE (non-nil means reverse order), BEG and END (region to sort)."
 208   (interactive "P\nr")
 209   (save-excursion
 210     (save-restriction
 211       (narrow-to-region beg end)
 212       (goto-char (point-min))
 213       (sort-subr reverse
 214                  (function (lambda () (skip-chars-forward "\n \t\f")))
 215                  'forward-paragraph))))
 216
 217 ;;;###autoload
 218 (defun sort-pages (reverse beg end)
 219   "Sort pages in region alphabetically; argument means descending order.
 220 Called from a program, there are three arguments:
 221 REVERSE (non-nil means reverse order), BEG and END (region to sort)."
 222   (interactive "P\nr")
 223   (save-excursion
 224     (save-restriction
 225       (narrow-to-region beg end)
 226       (goto-char (point-min))
 227       (sort-subr reverse
 228                  (function (lambda () (skip-chars-forward "\n")))
 229                  'forward-page))))
 230 \f
 231 (defvar sort-fields-syntax-table nil)
 232 (if sort-fields-syntax-table nil
 233   (let ((table (make-syntax-table))
 234         (i 0))
 235     (while (< i 256)
 236       (modify-syntax-entry i "w" table)
 237       (setq i (1+ i)))
 238     (modify-syntax-entry ?\  " " table)
 239     (modify-syntax-entry ?\t " " table)
 240     (modify-syntax-entry ?\n " " table)
 241     (modify-syntax-entry ?\. "_" table) ; for floating pt. numbers. -wsr
 242     (setq sort-fields-syntax-table table)))
 243
 244 ;;;###autoload
 245 (defun sort-numeric-fields (field beg end)
 246   "Sort lines in region numerically by the ARGth field of each line.
 247 Fields are separated by whitespace and numbered from 1 up.
 248 Specified field must contain a number in each line of the region.
 249 With a negative arg, sorts by the ARGth field counted from the right.
 250 Called from a program, there are three arguments:
 251 FIELD, BEG and END.  BEG and END specify region to sort.
 252 If you want to sort floating-point numbers, try `sort-float-fields'."
 253   (interactive "p\nr")
 254   (sort-fields-1 field beg end
 255                  (function (lambda ()
 256                              (sort-skip-fields field)
 257                              (string-to-number
 258                               (buffer-substring
 259                                 (point)
 260                                 (save-excursion
 261                                   ;; This is just wrong! Even without floats...
 262                                   ;; (skip-chars-forward "[0-9]")
 263                                   (forward-sexp 1)
 264                                   (point))))))
 265                  nil))
 266
 267 ;;;###autoload
 268 (defun sort-float-fields (field beg end)
 269   "Sort lines in region numerically by the ARGth field of each line.
 270 Fields are separated by whitespace and numbered from 1 up.  Specified field
 271 must contain a floating point number in each line of the region.  With a
 272 negative arg, sorts by the ARGth field counted from the right.  Called from a
 273 program, there are three arguments: FIELD, BEG and END.  BEG and END specify
 274 region to sort."
 275   (interactive "p\nr")
 276   (sort-fields-1 field beg end
 277                  (function (lambda ()
 278                              (sort-skip-fields field)
 279                              (string-to-number
 280                               (buffer-substring
 281                                (point)
 282                                (save-excursion
 283                                  (re-search-forward
 284                                   "[+-]?[0-9]*\.?[0-9]*\\([eE][+-]?[0-9]+\\)?")
 285                                  (point))))))
 286                  nil))
 287
 288 ;;;###autoload
 289 (defun sort-fields (field beg end)
 290   "Sort lines in region lexicographically by the ARGth field of each line.
 291 Fields are separated by whitespace and numbered from 1 up.
 292 With a negative arg, sorts by the ARGth field counted from the right.
 293 Called from a program, there are three arguments:
 294 FIELD, BEG and END.  BEG and END specify region to sort."
 295   (interactive "p\nr")
 296   (sort-fields-1 field beg end
 297                  (function (lambda ()
 298                              (sort-skip-fields field)
 299                              nil))
 300                  (function (lambda () (skip-chars-forward "^ \t\n")))))
 301
 302 (defun sort-fields-1 (field beg end startkeyfun endkeyfun)
 303   (let ((tbl (syntax-table)))
 304     (if (zerop field) (setq field 1))
 305     (unwind-protect
 306         (save-excursion
 307           (save-restriction
 308             (narrow-to-region beg end)
 309             (goto-char (point-min))
 310             (set-syntax-table sort-fields-syntax-table)
 311             (sort-subr nil
 312                        'forward-line 'end-of-line
 313                        startkeyfun endkeyfun)))
 314       (set-syntax-table tbl))))
 315
 316 ;; Position at the beginning of field N on the current line,
 317 ;; assuming point is initially at the beginning of the line.
 318 (defun sort-skip-fields (n)
 319   (if (> n 0)
 320       ;; Skip across N - 1 fields.
 321       (let ((i (1- n)))
 322         (while (> i 0)
 323           (skip-chars-forward " \t")
 324           (skip-chars-forward "^ \t\n")
 325           (setq i (1- i)))
 326         (skip-chars-forward " \t")
 327         (if (eolp)
 328             (error "Line has too few fields: %s"
 329                    (buffer-substring
 330                     (save-excursion (beginning-of-line) (point))
 331                     (save-excursion (end-of-line) (point))))))
 332     (end-of-line)
 333     ;; Skip back across - N - 1 fields.
 334     (let ((i (1- (- n))))
 335       (while (> i 0)
 336         (skip-chars-backward " \t")
 337         (skip-chars-backward "^ \t\n")
 338         (setq i (1- i)))
 339       (skip-chars-backward " \t"))
 340     (if (bolp)
 341         (error "Line has too few fields: %s"
 342                (buffer-substring
 343                 (save-excursion (beginning-of-line) (point))
 344                 (save-excursion (end-of-line) (point)))))
 345     ;; Position at the front of the field
 346     ;; even if moving backwards.
 347     (skip-chars-backward "^ \t\n")))
 348 \f
 349 ;;;###autoload
 350 (defun sort-regexp-fields (reverse record-regexp key-regexp beg end)
 351   "Sort the region lexicographically as specified by RECORD-REGEXP and KEY.
 352 RECORD-REGEXP specifies the textual units which should be sorted.
 353   For example, to sort lines RECORD-REGEXP would be \"^.*$\"
 354 KEY specifies the part of each record (ie each match for RECORD-REGEXP)
 355   is to be used for sorting.
 356   If it is \"\\digit\" then the digit'th \"\\(...\\)\" match field from
 357   RECORD-REGEXP is used.
 358   If it is \"\\&\" then the whole record is used.
 359   Otherwise, it is a regular-expression for which to search within the record.
 360 If a match for KEY is not found within a record then that record is ignored.
 361
 362 With a negative prefix arg sorts in reverse order.
 363
 364 For example: to sort lines in the region by the first word on each line
 365  starting with the letter \"f\",
 366  RECORD-REGEXP would be \"^.*$\" and KEY would be \"\\=\\<f\\w*\\>\""
 367   ;; using negative prefix arg to mean "reverse" is now inconsistent with
 368   ;; other sort-.*fields functions but then again this was before, since it
 369   ;; didn't use the magnitude of the arg to specify anything.
 370   (interactive "P\nsRegexp specifying records to sort:
 371 sRegexp specifying key within record: \nr")
 372   (cond ((or (equal key-regexp "") (equal key-regexp "\\&"))
 373          (setq key-regexp 0))
 374         ((string-match "\\`\\\\[1-9]\\'" key-regexp)
 375          (setq key-regexp (- (aref key-regexp 1) ?0))))
 376   (save-excursion
 377     (save-restriction
 378       (narrow-to-region beg end)
 379       (goto-char (point-min))
 380       (let (sort-regexp-record-end) ;isn't dynamic scoping wonderful?
 381         (re-search-forward record-regexp)
 382         (setq sort-regexp-record-end (point))
 383         (goto-char (match-beginning 0))
 384         (sort-subr reverse
 385                    (function (lambda ()
 386                                (and (re-search-forward record-regexp nil 'move)
 387                                     (setq sort-regexp-record-end (match-end 0))
 388                                     (goto-char (match-beginning 0)))))
 389                    (function (lambda ()
 390                                (goto-char sort-regexp-record-end)))
 391                    (function (lambda ()
 392                                (let ((n 0))
 393                                  (cond ((numberp key-regexp)
 394                                         (setq n key-regexp))
 395                                        ((re-search-forward
 396                                           key-regexp sort-regexp-record-end t)
 397                                         (setq n 0))
 398                                        (t (throw 'key nil)))
 399                                  (condition-case ()
 400                                      (if (fboundp 'buffer-substring-lessp)
 401                                          (cons (match-beginning n)
 402                                                (match-end n))
 403                                          (buffer-substring (match-beginning n)
 404                                                            (match-end n)))
 405                                    ;; if there was no such register
 406                                    (error (throw 'key nil)))))))))))
 407
 408 \f
 409 (defvar sort-columns-subprocess t)
 410
 411 ;;;###autoload
 412 (defun sort-columns (reverse &optional beg end)
 413   "Sort lines in region alphabetically by a certain range of columns.
 414 For the purpose of this command, the region includes
 415 the entire line that point is in and the entire line the mark is in.
 416 The column positions of point and mark bound the range of columns to sort on.
 417 A prefix argument means sort into reverse order.
 418
 419 Note that `sort-columns' rejects text that contains tabs,
 420 because tabs could be split across the specified columns
 421 and it doesn't know how to handle that.  Also, when possible,
 422 it uses the `sort' utility program, which doesn't understand tabs.
 423 Use \\[untabify] to convert tabs to spaces before sorting."
 424   (interactive "P\nr")
 425   (save-excursion
 426     (let (beg1 end1 col-beg1 col-end1 col-start col-end)
 427       (goto-char (min beg end))
 428       (setq col-beg1 (current-column))
 429       (beginning-of-line)
 430       (setq beg1 (point))
 431       (goto-char (max beg end))
 432       (setq col-end1 (current-column))
 433       (forward-line)
 434       (setq end1 (point))
 435       (setq col-start (min col-beg1 col-end1))
 436       (setq col-end (max col-beg1 col-end1))
 437       (if (search-backward "\t" beg1 t)
 438           (error "sort-columns does not work with tabs.  Use M-x untabify."))
 439       (if (not (eq system-type 'vax-vms))
 440           ;; Use the sort utility if we can; it is 4 times as fast.
 441           (call-process-region beg1 end1 "sort" t t nil
 442                                (if reverse "-rt\n" "-t\n")
 443                                (concat "+0." col-start)
 444                                (concat "-0." col-end))
 445         ;; On VMS, use Emacs's own facilities.
 446         (save-excursion
 447           (save-restriction
 448             (narrow-to-region beg1 end1)
 449             (goto-char beg1)
 450             (sort-subr reverse 'forward-line 'end-of-line
 451                        (function (lambda () (move-to-column col-start) nil))
 452                        (function (lambda () (move-to-column col-end) nil)))))))))
 453
 454 ;;;###autoload
 455 (defun reverse-region (beg end)
 456   "Reverse the order of lines in a region.
 457 From a program takes two point or marker arguments, BEG and END."
 458   (interactive "r")
 459   (if (> beg end)
 460       (let (mid) (setq mid end end beg beg mid)))
 461   (save-excursion
 462     ;; put beg at the start of a line and end and the end of one --
 463     ;; the largest possible region which fits this criteria
 464     (goto-char beg)
 465     (or (bolp) (forward-line 1))
 466     (setq beg (point))
 467     (goto-char end)
 468     ;; the test for bolp is for those times when end is on an empty line;
 469     ;; it is probably not the case that the line should be included in the
 470     ;; reversal; it isn't difficult to add it afterward.
 471     (or (and (eolp) (not (bolp))) (progn (forward-line -1) (end-of-line)))
 472     (setq end (point-marker))
 473     ;; the real work.  this thing cranks through memory on large regions.
 474     (let (ll (do t))
 475       (while do
 476         (goto-char beg)
 477         (setq ll (cons (buffer-substring (point) (progn (end-of-line) (point)))
 478                        ll))
 479         (setq do (/= (point) end))
 480         (delete-region beg (if do (1+ (point)) (point))))
 481       (while (cdr ll)
 482         (insert (car ll) "\n")
 483         (setq ll (cdr ll)))
 484       (insert (car ll)))))
 485
 486 (provide 'sort)
 487
 488 ;;; sort.el ends here