code.delx.au - gnu-emacs/blob - lisp/descr-text.el

   1 ;;; descr-text.el --- describe text mode
   2
   3 ;; Copyright (c) 1994, 1995, 1996, 2001, 2002 Free Software Foundation, Inc.
   4
   5 ;; Author: Boris Goldowsky <boris@gnu.org>
   6 ;; Keywords: faces
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  22 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  23 ;; Boston, MA 02111-1307, USA.
  24
  25 ;;; Commentary:
  26
  27 ;;; Describe-Text Mode.
  28
  29 ;;; Code:
  30
  31 (defun describe-text-done ()
  32   "Delete the current window or bury the current buffer."
  33   (interactive)
  34   (if (> (count-windows) 1)
  35       (delete-window)
  36     (bury-buffer)))
  37
  38 (defvar describe-text-mode-map
  39   (let ((map (make-sparse-keymap)))
  40     (set-keymap-parent map widget-keymap)
  41     map)
  42   "Keymap for `describe-text-mode'.")
  43
  44 (defcustom describe-text-mode-hook nil
  45   "List of hook functions ran by `describe-text-mode'."
  46   :type 'hook)
  47
  48 (defun describe-text-mode ()
  49   "Major mode for buffers created by `describe-char'.
  50
  51 \\{describe-text-mode-map}
  52 Entry to this mode calls the value of `describe-text-mode-hook'
  53 if that value is non-nil."
  54   (kill-all-local-variables)
  55   (setq major-mode 'describe-text-mode
  56         mode-name "Describe-Text")
  57   (use-local-map describe-text-mode-map)
  58   (widget-setup)
  59   (run-hooks 'describe-text-mode-hook))
  60
  61 ;;; Describe-Text Utilities.
  62
  63 (defun describe-text-widget (widget)
  64   "Insert text to describe WIDGET in the current buffer."
  65   (widget-create 'link
  66                  :notify `(lambda (&rest ignore)
  67                             (widget-browse ',widget))
  68                  (format "%S" (if (symbolp widget)
  69                                   widget
  70                                 (car widget))))
  71   (widget-insert " ")
  72   (widget-create 'info-link :tag "widget" "(widget)Top"))
  73
  74 (defun describe-text-sexp (sexp)
  75   "Insert a short description of SEXP in the current buffer."
  76   (let ((pp (condition-case signal
  77                 (pp-to-string sexp)
  78               (error (prin1-to-string signal)))))
  79     (when (string-match "\n\\'" pp)
  80       (setq pp (substring pp 0 (1- (length pp)))))
  81     (if (cond ((string-match "\n" pp)
  82                nil)
  83               ((> (length pp) (- (window-width) (current-column)))
  84                nil)
  85               (t t))
  86         (widget-insert pp)
  87       (widget-create 'push-button
  88                      :tag "show"
  89                      :action (lambda (widget &optional event)
  90                                (with-output-to-temp-buffer
  91                                    "*Pp Eval Output*"
  92                                  (princ (widget-get widget :value))))
  93                      pp))))
  94
  95 (defun describe-property-list (properties)
  96   "Insert a description of PROPERTIES in the current buffer.
  97 PROPERTIES should be a list of overlay or text properties.
  98 The `category' property is made into a widget button that call
  99 `describe-text-category' when pushed."
 100   ;; Sort the properties by the size of their value.
 101   (dolist (elt (sort (let ((ret nil)
 102                            (key nil)
 103                            (val nil)
 104                            (len nil))
 105                        (while properties
 106                          (setq key (pop properties)
 107                                val (pop properties)
 108                                len 0)
 109                          (unless (or (eq key 'category)
 110                                      (widgetp val))
 111                            (setq val (pp-to-string val)
 112                                  len (length val)))
 113                          (push (list key val len) ret))
 114                        ret)
 115                      (lambda (a b)
 116                        (< (nth 2 a)
 117                           (nth 2 b)))))
 118     (let ((key (nth 0 elt))
 119           (value (nth 1 elt)))
 120       (widget-insert (propertize (format "  %-20s " key)
 121                                  'font-lock-face 'italic))
 122       (cond ((eq key 'category)
 123              (widget-create 'link
 124                             :notify `(lambda (&rest ignore)
 125                                        (describe-text-category ',value))
 126                             (format "%S" value)))
 127             ((widgetp value)
 128              (describe-text-widget value))
 129             (t
 130              (widget-insert value))))
 131     (widget-insert "\n")))
 132 \f
 133 ;;; Describe-Text Commands.
 134
 135 (defun describe-text-category (category)
 136   "Describe a text property category."
 137   (interactive "S")
 138   (when (get-buffer "*Text Category*")
 139     (kill-buffer "*Text Category*"))
 140   (save-excursion
 141     (with-output-to-temp-buffer "*Text Category*"
 142       (set-buffer "*Text Category*")
 143       (widget-insert "Category " (format "%S" category) ":\n\n")
 144       (describe-property-list (symbol-plist category))
 145       (describe-text-mode)
 146       (goto-char (point-min)))))
 147
 148 ;;;###autoload
 149 (defun describe-text-properties (pos &optional output-buffer)
 150   "Describe widgets, buttons, overlays and text properties at POS.
 151 Interactively, describe them for the character after point.
 152 If optional second argument OUTPUT-BUFFER is non-nil,
 153 insert the output into that buffer, and don't initialize or clear it
 154 otherwise."
 155   (interactive "d")
 156   (when (eq (current-buffer) (get-buffer "*Text Description*"))
 157     (error "Can't do self inspection"))
 158   (if (>= pos (point-max))
 159       (error "No character follows specified position"))
 160   (if output-buffer
 161       (describe-text-properties-1 pos output-buffer)
 162     (if (not (or (text-properties-at pos) (overlays-at pos)))
 163         (message "This is plain text.")
 164       (let ((buffer (current-buffer)))
 165         (save-excursion
 166           (with-output-to-temp-buffer "*Text Description*"
 167             (set-buffer "*Text Description*")
 168             (setq output-buffer (current-buffer))
 169             (widget-insert "Text content at position " (format "%d" pos) ":\n\n")
 170             (with-current-buffer buffer
 171               (describe-text-properties-1 pos output-buffer))
 172             (describe-text-mode)
 173             (goto-char (point-min))))))))
 174
 175 (defun describe-text-properties-1 (pos output-buffer)
 176   (let* ((properties (text-properties-at pos))
 177          (overlays (overlays-at pos))
 178          overlay
 179          (wid-field (get-char-property pos 'field))
 180          (wid-button (get-char-property pos 'button))
 181          (wid-doc (get-char-property pos 'widget-doc))
 182          ;; If button.el is not loaded, we have no buttons in the text.
 183          (button (and (fboundp 'button-at) (button-at pos)))
 184          (button-type (and button (button-type button)))
 185          (button-label (and button (button-label button)))
 186          (widget (or wid-field wid-button wid-doc)))
 187     (with-current-buffer output-buffer
 188       ;; Widgets
 189       (when (widgetp widget)
 190         (newline)
 191         (widget-insert (cond (wid-field "This is an editable text area")
 192                              (wid-button "This is an active area")
 193                              (wid-doc "This is documentation text")))
 194         (widget-insert " of a ")
 195         (describe-text-widget widget)
 196         (widget-insert ".\n\n"))
 197       ;; Buttons
 198       (when (and button (not (widgetp wid-button)))
 199         (newline)
 200         (widget-insert "Here is a " (format "%S" button-type)
 201                        " button labeled `" button-label "'.\n\n"))
 202       ;; Overlays
 203       (when overlays
 204         (newline)
 205         (if (eq (length overlays) 1)
 206             (widget-insert "There is an overlay here:\n")
 207           (widget-insert "There are " (format "%d" (length overlays))
 208                          " overlays here:\n"))
 209         (dolist (overlay overlays)
 210           (widget-insert " From " (format "%d" (overlay-start overlay))
 211                          " to " (format "%d" (overlay-end overlay)) "\n")
 212           (describe-property-list (overlay-properties overlay)))
 213         (widget-insert "\n"))
 214       ;; Text properties
 215       (when properties
 216         (newline)
 217         (widget-insert "There are text properties here:\n")
 218         (describe-property-list properties)))))
 219
 220 ;;;###autoload
 221 (defun describe-char (pos)
 222   "Describe the character after POS (interactively, the character after point).
 223 The information includes character code, charset and code points in it,
 224 syntax, category, how the character is encoded in a file,
 225 character composition information (if relevant),
 226 as well as widgets, buttons, overlays, and text properties."
 227   (interactive "d")
 228   (when (eq (current-buffer) (get-buffer "*Text Description*"))
 229     (error "Can't do self inspection"))
 230   (if (>= pos (point-max))
 231       (error "No character follows specified position"))
 232   (let* ((char (char-after pos))
 233          (charset (char-charset char))
 234          (buffer (current-buffer))
 235          (composition (find-composition (point) nil nil t))
 236          (composed (if composition (buffer-substring (car composition)
 237                                                      (nth 1 composition))))
 238          (multibyte-p enable-multibyte-characters)
 239          item-list max-width)
 240     (if (eq charset 'unknown)
 241         (setq item-list
 242               `(("character"
 243                  ,(format "%s (0%o, %d, 0x%x) -- invalid character code"
 244                           (if (< char 256)
 245                               (single-key-description char)
 246                             (char-to-string char))
 247                           char char char))))
 248       (setq item-list
 249             `(("character"
 250                ,(format "%s (0%o, %d, 0x%x)" (if (< char 256)
 251                                                  (single-key-description char)
 252                                                (char-to-string char))
 253                         char char char))
 254               ("charset"
 255                ,(symbol-name charset)
 256                ,(format "(%s)" (charset-description charset)))
 257               ("code point"
 258                ,(let ((split (split-char char)))
 259                   (if (= (charset-dimension charset) 1)
 260                       (format "%d" (nth 1 split))
 261                     (format "%d %d" (nth 1 split) (nth 2 split)))))
 262               ("syntax"
 263                ,(let ((syntax (get-char-property (point) 'syntax-table)))
 264                   (with-temp-buffer
 265                     (internal-describe-syntax-value
 266                      (if (consp syntax) syntax
 267                        (aref (or syntax (syntax-table)) char)))
 268                     (buffer-string))))
 269               ("category"
 270                ,@(let ((category-set (char-category-set char)))
 271                    (if (not category-set)
 272                        '("-- none --")
 273                      (mapcar #'(lambda (x) (format "%c:%s  "
 274                                                    x (category-docstring x)))
 275                              (category-set-mnemonics category-set)))))
 276               ,@(let ((props (aref char-code-property-table char))
 277                       ps)
 278                   (when props
 279                     (while props
 280                       (push (format "%s:" (pop props)) ps)
 281                       (push (format "%s;" (pop props)) ps))
 282                     (list (cons "Properties" (nreverse ps)))))
 283               ("buffer code"
 284                ,(encoded-string-description
 285                  (string-as-unibyte (char-to-string char)) nil))
 286               ("file code"
 287                ,@(let* ((coding buffer-file-coding-system)
 288                         (encoded (encode-coding-char char coding)))
 289                    (if encoded
 290                        (list (encoded-string-description encoded coding)
 291                              (format "(encoded by coding system %S)" coding))
 292                      (list "not encodable by coding system"
 293                            (symbol-name coding)))))
 294               ,@(if (or (memq 'mule-utf-8
 295                           (find-coding-systems-region (point) (1+ (point))))
 296                         (get-char-property (point) 'untranslated-utf-8))
 297                     (let ((uc (or (get-char-property (point)
 298                                                      'untranslated-utf-8)
 299                                   (encode-char (char-after) 'ucs))))
 300                       (if uc
 301                           (list (list "Unicode"
 302                                       (format "%04X" uc))))))
 303               ,(if (display-graphic-p (selected-frame))
 304                    (list "font" (or (internal-char-font (point))
 305                                     "-- none --"))
 306                  (list "terminal code"
 307                        (let* ((coding (terminal-coding-system))
 308                               (encoded (encode-coding-char char coding)))
 309                          (if encoded
 310                              (encoded-string-description encoded coding)
 311                            "not encodable")))))))
 312     (setq max-width (apply #'max (mapcar #'(lambda (x) (length (car x)))
 313                                          item-list)))
 314     (when (get-buffer "*Help*")
 315       (kill-buffer "*Help*"))
 316     (with-output-to-temp-buffer "*Help*"
 317       (save-excursion
 318         (set-buffer standard-output)
 319         (set-buffer-multibyte multibyte-p)
 320         (let ((formatter (format "%%%ds:" max-width)))
 321           (dolist (elt item-list)
 322             (insert (format formatter (car elt)))
 323             (dolist (clm (cdr elt))
 324               (when (>= (+ (current-column)
 325                            (or (string-match "\n" clm)
 326                                (string-width clm)) 1)
 327                         (frame-width))
 328                 (insert "\n")
 329                 (indent-to (1+ max-width)))
 330               (insert " " clm))
 331             (insert "\n")))
 332         (when composition
 333           (insert "\nComposed with the following character(s) "
 334                   (mapconcat (lambda (x) (format "`%c'" x))
 335                              (substring composed 1)
 336                              ", ")
 337                   " to form `" composed "'")
 338           (if (nth 3 composition)
 339               (insert ".\n")
 340             (insert "\nby the rule ("
 341                     (mapconcat (lambda (x)
 342                                  (format (if (consp x) "%S" "?%c") x))
 343                                (nth 2 composition)
 344                                " ")
 345                     ").\n"
 346                     "See the variable `reference-point-alist' for "
 347                     "the meaning of the rule.\n")))
 348
 349         (let ((output (current-buffer)))
 350           (with-current-buffer buffer
 351             (describe-text-properties pos output))
 352           (describe-text-mode))))))
 353
 354 (provide 'descr-text)
 355
 356 ;;; descr-text.el ends here