code.delx.au - gnu-emacs/blob - lisp/ibuf-ext.el

   1 ;;; ibuf-ext.el --- extensions for ibuffer
   2
   3 ;; Copyright (C) 2000, 2001, 2002 Free Software Foundation, Inc.
   4
   5 ;; Author: Colin Walters <walters@verbum.org>
   6 ;; Created: 2 Dec 2001
   7 ;; Keywords: buffer, convenience
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; This program is free software; you can redistribute it and/or
  12 ;; modify it under the terms of the GNU General Public License as
  13 ;; published by the Free Software Foundation; either version 2, or (at
  14 ;; your option) any later version.
  15
  16 ;; This program is distributed in the hope that it will be useful, but
  17 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  19 ;; General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with this program ; see the file COPYING.  If not, write to
  23 ;; the Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;; These functions should be automatically loaded when called, but you
  29 ;; can explicity (require 'ibuf-ext) in your ~/.emacs to have them
  30 ;; preloaded.
  31
  32 ;;; Code:
  33
  34 (require 'ibuffer)
  35
  36 (eval-when-compile
  37   (require 'derived)
  38   (require 'ibuf-macs)
  39   (require 'cl))
  40
  41 ;;; Utility functions
  42 (defun ibuffer-delete-alist (key alist)
  43   "Delete all entries in ALIST that have a key equal to KEY."
  44   (let (entry)
  45     (while (setq entry (assoc key alist))
  46       (setq alist (delete entry alist)))
  47     alist))
  48
  49 (defun ibuffer-split-list (ibuffer-split-list-fn ibuffer-split-list-elts)
  50   (let ((hip-crowd nil)
  51         (lamers nil))
  52     (dolist (ibuffer-split-list-elt ibuffer-split-list-elts)
  53       (if (funcall ibuffer-split-list-fn ibuffer-split-list-elt)
  54           (push ibuffer-split-list-elt hip-crowd)
  55         (push ibuffer-split-list-elt lamers)))
  56     ;; Too bad Emacs Lisp doesn't have multiple values.
  57     (list (nreverse hip-crowd) (nreverse lamers))))
  58
  59 (defcustom ibuffer-never-show-predicates nil
  60   "A list of predicates (a regexp or function) for buffers not to display.
  61 If a regexp, then it will be matched against the buffer's name.
  62 If a function, it will be called with the buffer as an argument, and
  63 should return non-nil if this buffer should not be shown."
  64   :type '(repeat (choice regexp function))
  65   :group 'ibuffer)
  66
  67 (defcustom ibuffer-always-show-predicates nil
  68   "A list of predicates (a regexp or function) for buffers to always display.
  69 If a regexp, then it will be matched against the buffer's name.
  70 If a function, it will be called with the buffer as an argument, and
  71 should return non-nil if this buffer should be shown.
  72 Note that buffers matching one of these predicates will be shown
  73 regardless of any active filters in this buffer."
  74   :type '(repeat (choice regexp function))
  75   :group 'ibuffer)
  76
  77 (defvar ibuffer-tmp-hide-regexps nil
  78   "A list of regexps which should match buffer names to not show.")
  79
  80 (defvar ibuffer-tmp-show-regexps nil
  81   "A list of regexps which should match buffer names to always show.")
  82
  83 (defvar ibuffer-auto-mode nil
  84   "If non-nil, Ibuffer auto-mode should be enabled for this buffer.
  85 Do not set this variable directly!  Use the function
  86 `ibuffer-auto-mode' instead.")
  87
  88 (defvar ibuffer-auto-buffers-changed nil)
  89
  90 (defcustom ibuffer-saved-filters '(("gnus"
  91                                     ((or (mode . message-mode)
  92                                          (mode . mail-mode)
  93                                          (mode . gnus-group-mode)
  94                                          (mode . gnus-summary-mode)
  95                                          (mode . gnus-article-mode))))
  96                                    ("programming"
  97                                     ((or (mode . emacs-lisp-mode)
  98                                          (mode . cperl-mode)
  99                                          (mode . c-mode)
 100                                          (mode . java-mode)
 101                                          (mode . idl-mode)
 102                                          (mode . lisp-mode)))))
 103
 104   "An alist of filter qualifiers to switch between.
 105
 106 This variable should look like ((\"STRING\" QUALIFIERS)
 107                                 (\"STRING\" QUALIFIERS) ...), where
 108 QUALIFIERS is a list of the same form as
 109 `ibuffer-filtering-qualifiers'.
 110 See also the variables `ibuffer-filtering-qualifiers',
 111 `ibuffer-filtering-alist', and the functions
 112 `ibuffer-switch-to-saved-filters', `ibuffer-save-filters'."
 113   :type '(repeat sexp)
 114   :group 'ibuffer)
 115
 116 (defvar ibuffer-filtering-qualifiers nil
 117   "A list like (SYMBOL . QUALIFIER) which filters the current buffer list.
 118 See also `ibuffer-filtering-alist'.")
 119
 120 ;; This is now frobbed by `define-ibuffer-filter'.
 121 (defvar ibuffer-filtering-alist nil
 122   "An alist of (SYMBOL DESCRIPTION FUNCTION) which describes a filter.
 123
 124 You most likely do not want to modify this variable directly; see
 125 `define-ibuffer-filter'.
 126
 127 SYMBOL is the symbolic name of the filter.  DESCRIPTION is used when
 128 displaying information to the user.  FUNCTION is given a buffer and
 129 the value of the qualifier, and returns non-nil if and only if the
 130 buffer should be displayed.")
 131
 132 (defcustom ibuffer-filter-format-alist nil
 133   "An alist which has special formats used when a filter is active.
 134 The contents of this variable should look like:
 135  ((FILTER (FORMAT FORMAT ...)) (FILTER (FORMAT FORMAT ...)) ...)
 136
 137 For example, suppose that when you add a filter for buffers whose
 138 major mode is `emacs-lisp-mode', you only want to see the mark and the
 139 name of the buffer.  You could accomplish that by adding:
 140  (mode ((mark \" \" name)))
 141 to this variable."
 142   :type '(repeat (list :tag "Association" (symbol :tag "Filter")
 143                        (list :tag "Formats" (repeat (sexp :tag "Format")))))
 144   :group 'ibuffer)
 145
 146 (defvar ibuffer-cached-filter-formats nil)
 147 (defvar ibuffer-compiled-filter-formats nil)
 148
 149 (defvar ibuffer-filter-groups nil
 150   "A list like ((\"NAME\" ((SYMBOL . QUALIFIER) ...) ...) which groups buffers.
 151 The SYMBOL should be one from `ibuffer-filtering-alist'.
 152 The QUALIFIER should be the same as QUALIFIER in
 153 `ibuffer-filtering-qualifiers'.")
 154
 155 (defcustom ibuffer-show-empty-filter-groups t
 156   "If non-nil, then show the names of filter groups which are empty."
 157   :type 'boolean
 158   :group 'ibuffer)
 159
 160 (defcustom ibuffer-saved-filter-groups nil
 161
 162   "An alist of filtering groups to switch between.
 163
 164 This variable should look like ((\"STRING\" QUALIFIERS)
 165                                 (\"STRING\" QUALIFIERS) ...), where
 166 QUALIFIERS is a list of the same form as
 167 `ibuffer-filtering-qualifiers'.
 168
 169 See also the variables `ibuffer-filter-groups',
 170 `ibuffer-filtering-qualifiers', `ibuffer-filtering-alist', and the
 171 functions `ibuffer-switch-to-saved-filter-group',
 172 `ibuffer-save-filter-group'."
 173   :type '(repeat sexp)
 174   :group 'ibuffer)
 175
 176 (defvar ibuffer-hidden-filter-groups nil
 177   "A list of filtering groups which are currently hidden.")
 178
 179 (defvar ibuffer-filter-group-kill-ring nil)
 180
 181 (defcustom ibuffer-old-time 72
 182   "The number of hours before a buffer is considered \"old\"."
 183   :type '(choice (const :tag "72 hours (3 days)" 72)
 184                  (const :tag "48 hours (2 days)" 48)
 185                  (const :tag "24 hours (1 day)" 24)
 186                  (integer :tag "hours"))
 187   :group 'ibuffer)
 188
 189 (defcustom ibuffer-save-with-custom t
 190   "If non-nil, then use Custom to save interactively changed variables.
 191 Currently, this only applies to `ibuffer-saved-filters' and
 192 `ibuffer-saved-filter-groups."
 193   :type 'boolean
 194   :group 'ibuffer)
 195
 196 (defun ibuffer-ext-visible-p (buf all &optional ibuffer-buf)
 197   (or
 198    (ibuffer-buf-matches-predicates buf ibuffer-tmp-show-regexps)
 199    (and (not
 200          (or
 201           (ibuffer-buf-matches-predicates buf ibuffer-tmp-hide-regexps)
 202           (ibuffer-buf-matches-predicates buf ibuffer-never-show-predicates)))
 203         (or all
 204             (not
 205              (ibuffer-buf-matches-predicates buf ibuffer-maybe-show-predicates)))
 206         (or ibuffer-view-ibuffer
 207             (and ibuffer-buf
 208                  (not (eq ibuffer-buf buf))))
 209         (or
 210          (ibuffer-included-in-filters-p buf ibuffer-filtering-qualifiers)
 211          (ibuffer-buf-matches-predicates buf ibuffer-always-show-predicates)))))
 212
 213 (defun ibuffer-auto-update-changed ()
 214   (when ibuffer-auto-buffers-changed
 215     (setq ibuffer-auto-buffers-changed nil)
 216     (mapcar #'(lambda (buf)
 217                 (ignore-errors
 218                   (with-current-buffer buf
 219                     (when (and ibuffer-auto-mode
 220                                (eq major-mode 'ibuffer-mode))
 221                       (ibuffer-update nil t)))))
 222             (buffer-list))))
 223
 224 ;;;###autoload
 225 (defun ibuffer-auto-mode (&optional arg)
 226   "Toggle use of Ibuffer's auto-update facility.
 227 With numeric ARG, enable auto-update if and only if ARG is positive."
 228   (interactive)
 229   (unless (eq major-mode 'ibuffer-mode)
 230     (error "This buffer is not in Ibuffer mode"))
 231   (set (make-local-variable 'ibuffer-auto-mode)
 232        (if arg
 233            (plusp arg)
 234          (not ibuffer-auto-mode)))
 235   (defadvice get-buffer-create (after ibuffer-notify-create activate)
 236     (setq ibuffer-auto-buffers-changed t))
 237   (defadvice kill-buffer (after ibuffer-notify-kill activate)
 238     (setq ibuffer-auto-buffers-changed t))
 239   (add-hook 'post-command-hook 'ibuffer-auto-update-changed)
 240   (ibuffer-update-mode-name))
 241
 242 ;;;###autoload
 243 (defun ibuffer-mouse-filter-by-mode (event)
 244   "Enable or disable filtering by the major mode chosen via mouse."
 245   (interactive "e")
 246   (ibuffer-interactive-filter-by-mode event))
 247
 248 ;;;###autoload
 249 (defun ibuffer-interactive-filter-by-mode (event-or-point)
 250   "Enable or disable filtering by the major mode at point."
 251   (interactive "d")
 252   (if (eventp event-or-point)
 253       (mouse-set-point event-or-point)
 254     (goto-char event-or-point))
 255   (let ((buf (ibuffer-current-buffer)))
 256     (if (assq 'mode ibuffer-filtering-qualifiers)
 257         (setq ibuffer-filtering-qualifiers
 258               (ibuffer-delete-alist 'mode ibuffer-filtering-qualifiers))
 259       (ibuffer-push-filter (cons 'mode
 260                                 (with-current-buffer buf
 261                                   major-mode)))))
 262   (ibuffer-update nil t))
 263
 264 ;;;###autoload
 265 (defun ibuffer-mouse-toggle-filter-group (event)
 266   "Toggle the display status of the filter group chosen with the mouse."
 267   (interactive "e")
 268   (ibuffer-toggle-filter-group-1 (save-excursion
 269                                    (mouse-set-point event)
 270                                    (point))))
 271
 272 ;;;###autoload
 273 (defun ibuffer-toggle-filter-group ()
 274   "Toggle the display status of the filter group on this line."
 275   (interactive)
 276   (ibuffer-toggle-filter-group-1 (point)))
 277
 278 (defun ibuffer-toggle-filter-group-1 (posn)
 279   (let ((name (get-text-property posn 'ibuffer-filter-group-name)))
 280     (unless (stringp name)
 281       (error "No filtering group name present"))
 282     (if (member name ibuffer-hidden-filter-groups)
 283         (setq ibuffer-hidden-filter-groups
 284               (delete name ibuffer-hidden-filter-groups))
 285       (push name ibuffer-hidden-filter-groups))
 286     (ibuffer-update nil t)))
 287
 288 ;;;###autoload
 289 (defun ibuffer-forward-filter-group (&optional count)
 290   "Move point forwards by COUNT filtering groups."
 291   (interactive "P")
 292   (unless count
 293     (setq count 1))
 294   (when (> count 0)
 295     (when (get-text-property (point) 'ibuffer-filter-group-name)
 296       (goto-char (next-single-property-change
 297                   (point) 'ibuffer-filter-group-name
 298                   nil (point-max))))
 299     (goto-char (next-single-property-change
 300                 (point) 'ibuffer-filter-group-name
 301                 nil (point-max)))
 302     (ibuffer-forward-filter-group (1- count)))
 303   (ibuffer-forward-line 0))
 304
 305 ;;;###autoload
 306 (defun ibuffer-backward-filter-group (&optional count)
 307   "Move point backwards by COUNT filtering groups."
 308   (interactive "P")
 309   (unless count
 310     (setq count 1))
 311   (when (> count 0)
 312     (when (get-text-property (point) 'ibuffer-filter-group-name)
 313       (goto-char (previous-single-property-change
 314                   (point) 'ibuffer-filter-group-name
 315                   nil (point-min))))
 316     (goto-char (previous-single-property-change
 317                 (point) 'ibuffer-filter-group-name
 318                 nil (point-min)))
 319     (ibuffer-backward-filter-group (1- count)))
 320   (when (= (point) (point-min))
 321     (goto-char (point-max))
 322     (ibuffer-backward-filter-group 1))
 323   (ibuffer-forward-line 0))
 324
 325 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe "ibuf-ext.el")
 326 (define-ibuffer-op shell-command-pipe (command)
 327   "Pipe the contents of each marked buffer to shell command COMMAND."
 328   (:interactive "sPipe to shell command: "
 329    :opstring "Shell command executed on"
 330    :modifier-p nil)
 331   (shell-command-on-region
 332    (point-min) (point-max) command
 333    (get-buffer-create "* ibuffer-shell-output*")))
 334
 335 ;;;###autoload (autoload 'ibuffer-do-shell-command-pipe-replace "ibuf-ext.el")
 336 (define-ibuffer-op shell-command-pipe-replace (command)
 337   "Replace the contents of marked buffers with output of pipe to COMMAND."
 338   (:interactive "sPipe to shell command (replace): "
 339    :opstring "Buffer contents replaced in"
 340    :active-opstring "replace buffer contents in"
 341    :dangerous t
 342    :modifier-p t)
 343   (with-current-buffer buf
 344     (shell-command-on-region (point-min) (point-max)
 345                              command nil t)))
 346
 347 ;;;###autoload (autoload 'ibuffer-do-shell-command-file "ibuf-ext.el")
 348 (define-ibuffer-op shell-command-file (command)
 349   "Run shell command COMMAND separately on files of marked buffers."
 350   (:interactive "sShell command on buffer's file: "
 351    :opstring "Shell command executed on"
 352    :modifier-p nil)
 353   (shell-command (concat command " "
 354                          (shell-quote-argument
 355                           (if buffer-file-name
 356                               buffer-file-name
 357                             (make-temp-file
 358                              (substring (buffer-name) 0 (min 10 (length (buffer-name))))))))))
 359
 360 ;;;###autoload (autoload 'ibuffer-do-eval "ibuf-ext.el")
 361 (define-ibuffer-op eval (form)
 362   "Evaluate FORM in each of the buffers.
 363 Does not display the buffer during evaluation. See
 364 `ibuffer-do-view-and-eval' for that."
 365   (:interactive "xEval in buffers (form): "
 366    :opstring "evaluated in"
 367    :modifier-p :maybe)
 368   (eval form))
 369
 370 ;;;###autoload (autoload 'ibuffer-do-view-and-eval "ibuf-ext.el")
 371 (define-ibuffer-op view-and-eval (form)
 372   "Evaluate FORM while displaying each of the marked buffers.
 373 To evaluate a form without viewing the buffer, see `ibuffer-do-eval'."
 374   (:interactive "xEval viewing buffers (form): "
 375    :opstring "evaluated in"
 376    :complex t
 377    :modifier-p :maybe)
 378   (let ((ibuffer-buf (current-buffer)))
 379     (unwind-protect
 380         (progn
 381           (switch-to-buffer buf)
 382           (eval form))
 383       (switch-to-buffer ibuffer-buf))))
 384
 385 ;;;###autoload (autoload 'ibuffer-do-rename-uniquely "ibuf-ext.el")
 386 (define-ibuffer-op rename-uniquely ()
 387   "Rename marked buffers as with `rename-uniquely'."
 388   (:opstring "renamed"
 389    :modifier-p t)
 390   (rename-uniquely))
 391
 392 ;;;###autoload (autoload 'ibuffer-do-revert "ibuf-ext.el")
 393 (define-ibuffer-op revert ()
 394   "Revert marked buffers as with `revert-buffer'."
 395   (:dangerous t
 396    :opstring "reverted"
 397    :active-opstring "revert"
 398    :modifier-p :maybe)
 399   (revert-buffer t t))
 400
 401 ;;;###autoload (autoload 'ibuffer-do-replace-regexp "ibuf-ext.el")
 402 (define-ibuffer-op replace-regexp (from-str to-str)
 403   "Perform a `replace-regexp' in marked buffers."
 404   (:interactive
 405    (let* ((from-str (read-from-minibuffer "Replace regexp: "))
 406           (to-str (read-from-minibuffer (concat "Replace " from-str
 407                                                 " with: "))))
 408      (list from-str to-str))
 409    :opstring "replaced in"
 410    :complex t
 411    :modifier-p :maybe)
 412   (save-window-excursion
 413     (switch-to-buffer buf)
 414     (save-excursion
 415       (goto-char (point-min))
 416       (let ((case-fold-search ibuffer-case-fold-search))
 417         (while (re-search-forward from-str nil t)
 418           (replace-match to-str))))
 419     t))
 420
 421 ;;;###autoload (autoload 'ibuffer-do-query-replace "ibuf-ext.el")
 422 (define-ibuffer-op query-replace (&rest args)
 423   "Perform a `query-replace' in marked buffers."
 424   (:interactive
 425    (query-replace-read-args "Query replace" t t)
 426    :opstring "replaced in"
 427    :complex t
 428    :modifier-p :maybe)
 429   (save-window-excursion
 430     (switch-to-buffer buf)
 431     (save-excursion
 432       (let ((case-fold-search ibuffer-case-fold-search))
 433         (goto-char (point-min))
 434         (apply #'query-replace args)))
 435     t))
 436
 437 ;;;###autoload (autoload 'ibuffer-do-query-replace-regexp "ibuf-ext.el")
 438 (define-ibuffer-op query-replace-regexp (&rest args)
 439   "Perform a `query-replace-regexp' in marked buffers."
 440   (:interactive
 441    (query-replace-read-args "Query replace regexp" t t)
 442    :opstring "replaced in"
 443    :complex t
 444    :modifier-p :maybe)
 445   (save-window-excursion
 446     (switch-to-buffer buf)
 447     (save-excursion
 448       (let ((case-fold-search ibuffer-case-fold-search))
 449         (goto-char (point-min))
 450         (apply #'query-replace-regexp args)))
 451     t))
 452
 453 ;;;###autoload (autoload 'ibuffer-do-print "ibuf-ext.el")
 454 (define-ibuffer-op print ()
 455   "Print marked buffers as with `print-buffer'."
 456   (:opstring "printed"
 457    :modifier-p nil)
 458   (print-buffer))
 459
 460 ;;;###autoload
 461 (defun ibuffer-included-in-filters-p (buf filters)
 462   (not
 463    (memq nil ;; a filter will return nil if it failed
 464          (mapcar
 465           ;; filter should be like (TYPE . QUALIFIER), or
 466           ;; (or (TYPE . QUALIFIER) (TYPE . QUALIFIER) ...)
 467           #'(lambda (qual)
 468               (ibuffer-included-in-filter-p buf qual))
 469           filters))))
 470
 471 (defun ibuffer-included-in-filter-p (buf filter)
 472   (if (eq (car filter) 'not)
 473       (not (ibuffer-included-in-filter-p-1 buf (cdr filter)))
 474     (ibuffer-included-in-filter-p-1 buf filter)))
 475
 476 (defun ibuffer-included-in-filter-p-1 (buf filter)
 477   (not
 478    (not
 479     (case (car filter)
 480       (or
 481        (memq t (mapcar #'(lambda (x)
 482                            (ibuffer-included-in-filter-p buf x))
 483                        (cdr filter))))
 484       (saved
 485        (let ((data
 486               (assoc (cdr filter)
 487                      ibuffer-saved-filters)))
 488          (unless data
 489            (ibuffer-filter-disable)
 490            (error "Unknown saved filter %s" (cdr filter)))
 491          (ibuffer-included-in-filters-p buf (cadr data))))
 492       (t
 493        (let ((filterdat (assq (car filter)
 494                               ibuffer-filtering-alist)))
 495          ;; filterdat should be like (TYPE DESCRIPTION FUNC)
 496          ;; just a sanity check
 497         (unless filterdat
 498           (ibuffer-filter-disable)
 499           (error "Undefined filter %s" (car filter)))
 500         (not
 501          (not
 502           (funcall (caddr filterdat)
 503                    buf
 504                    (cdr filter))))))))))
 505
 506 (defun ibuffer-generate-filter-groups (bmarklist)
 507   (let ((filter-group-alist (append ibuffer-filter-groups
 508                                        (list (cons "Default" nil)))))
 509 ;;     (dolist (hidden ibuffer-hidden-filter-groups)
 510 ;;       (setq filter-group-alist (ibuffer-delete-alist
 511 ;;                                 hidden filter-group-alist)))
 512     (let ((vec (make-vector (length filter-group-alist) nil))
 513           (i 0))
 514       (dolist (filtergroup filter-group-alist)
 515         (let ((filterset (cdr filtergroup)))
 516           (multiple-value-bind (hip-crowd lamers)
 517               (ibuffer-split-list (lambda (bufmark)
 518                                     (ibuffer-included-in-filters-p (car bufmark)
 519                                                                    filterset))
 520                                   bmarklist)
 521             (aset vec i hip-crowd)
 522             (incf i)
 523             (setq bmarklist lamers))))
 524       (let ((ret nil))
 525         (dotimes (j i ret)
 526           (push (cons (car (nth j filter-group-alist))
 527                       (aref vec j))
 528                 ret))))))
 529
 530 ;;;###autoload
 531 (defun ibuffer-filters-to-filter-group (name)
 532   "Make the current filters into a filtering group."
 533   (interactive "sName for filtering group: ")
 534   (when (null ibuffer-filtering-qualifiers)
 535     (error "No filters in effect"))
 536   (push (cons name ibuffer-filtering-qualifiers) ibuffer-filter-groups)
 537   (ibuffer-filter-disable))
 538
 539 ;;;###autoload
 540 (defun ibuffer-set-filter-groups-by-mode ()
 541   "Set the current filter groups to filter by mode."
 542   (interactive)
 543   (setq ibuffer-filter-groups
 544         (mapcar (lambda (mode)
 545                   (cons (format "%s" mode) `((mode . ,mode))))
 546                 (let ((modes
 547                        (delete-duplicates
 548                         (mapcar (lambda (buf) (with-current-buffer buf major-mode))
 549                                 (buffer-list)))))
 550                   (if ibuffer-view-ibuffer
 551                       modes
 552                     (delq 'ibuffer-mode modes)))))
 553   (ibuffer-update nil t))
 554
 555 ;;;###autoload
 556 (defun ibuffer-pop-filter-group ()
 557   "Remove the first filter group."
 558   (interactive)
 559   (when (null ibuffer-filter-groups)
 560     (error "No filter groups active"))
 561   (setq ibuffer-hidden-filter-groups
 562         (delete (pop ibuffer-filter-groups)
 563                 ibuffer-hidden-filter-groups))
 564   (ibuffer-update nil t))
 565
 566 (defun ibuffer-read-filter-group-name (msg &optional nodefault noerror)
 567   (when (and (not noerror) (null ibuffer-filter-groups))
 568     (error "No filter groups active"))
 569   (let ((groups (mapcar #'car ibuffer-filter-groups)))
 570     (completing-read msg (if nodefault
 571                              groups
 572                            (cons "Default" groups))
 573                      nil t)))
 574
 575 ;;;###autoload
 576 (defun ibuffer-decompose-filter-group (group)
 577   "Decompose the filter group GROUP into active filters."
 578   (interactive (list (ibuffer-read-filter-group-name "Decompose filter group: " t)))
 579   (let ((data (cdr (assoc group ibuffer-filter-groups))))
 580     (setq ibuffer-filter-groups (ibuffer-delete-alist
 581                                  group ibuffer-filter-groups)
 582           ibuffer-filtering-qualifiers data))
 583   (ibuffer-update nil t))
 584
 585 ;;;###autoload
 586 (defun ibuffer-clear-filter-groups ()
 587   "Remove all filter groups."
 588   (interactive)
 589   (setq ibuffer-filter-groups nil
 590         ibuffer-hidden-filter-groups nil)
 591   (ibuffer-update nil t))
 592
 593 (defun ibuffer-current-filter-groups-with-position ()
 594   (save-excursion
 595     (goto-char (point-min))
 596     (let ((pos nil)
 597           (result nil))
 598       (while (and (not (eobp))
 599                   (setq pos (next-single-property-change
 600                              (point) 'ibuffer-filter-group-name)))
 601         (goto-char pos)
 602         (push (cons (get-text-property (point) 'ibuffer-filter-group-name)
 603                     pos)
 604               result)
 605         (goto-char (next-single-property-change
 606                     pos 'ibuffer-filter-group-name)))
 607       (nreverse result))))
 608
 609 ;;;###autoload
 610 (defun ibuffer-jump-to-filter-group (name)
 611   "Move point to the filter group whose name is NAME."
 612   (interactive (list (ibuffer-read-filter-group-name "Jump to filter group: ")))
 613   (ibuffer-aif (assoc name (ibuffer-current-filter-groups-with-position))
 614       (goto-char (cdr it))
 615     (error "No filter group with name %s" name)))
 616
 617 ;;;###autoload
 618 (defun ibuffer-kill-filter-group (name)
 619   "Kill the filter group named NAME.
 620 The group will be added to `ibuffer-filter-group-kill-ring'."
 621   (interactive (list (ibuffer-read-filter-group-name "Kill filter group: " t)))
 622   (when (equal name "Default")
 623     (error "Can't kill default filter group"))
 624   (ibuffer-aif (assoc name ibuffer-filter-groups)
 625       (progn
 626         (push (copy-tree it) ibuffer-filter-group-kill-ring)
 627         (setq ibuffer-filter-groups (ibuffer-delete-alist
 628                                      name ibuffer-filter-groups))
 629         (setq ibuffer-hidden-filter-groups
 630               (delete name ibuffer-hidden-filter-groups)))
 631     (error "No filter group with name \"%s\"" name))
 632   (ibuffer-update nil t))
 633
 634 ;;;###autoload
 635 (defun ibuffer-kill-line (&optional arg)
 636   "Kill the filter group at point.
 637 See also `ibuffer-kill-filter-group'."
 638   (interactive "P")
 639   (ibuffer-aif (save-excursion
 640                  (ibuffer-forward-line 0)
 641                  (get-text-property (point) 'ibuffer-filter-group-name))
 642       (progn
 643         (ibuffer-kill-filter-group it))
 644       (funcall (if (interactive-p) #'call-interactively #'funcall)
 645                #'kill-line arg)))
 646
 647 (defun ibuffer-insert-filter-group-before (newgroup group)
 648   (let ((pos (or (position group (mapcar #'car ibuffer-filter-groups)
 649                            :test #'equal)
 650                  (length ibuffer-filter-groups))))
 651     (cond ((<= pos 0)
 652            (push newgroup ibuffer-filter-groups))
 653           ((= pos (length ibuffer-filter-groups))
 654            (setq ibuffer-filter-groups (nconc ibuffer-filter-groups (list newgroup))))
 655           (t
 656            (let ((cell (nthcdr pos ibuffer-filter-groups)))
 657              (setf (cdr cell) (cons (car cell) (cdr cell)))
 658              (setf (car cell) newgroup))))))
 659
 660 ;;;###autoload
 661 (defun ibuffer-yank ()
 662   "Yank the last killed filter group before group at point."
 663   (interactive)
 664   (ibuffer-yank-filter-group
 665    (or (get-text-property (point) 'ibuffer-filter-group-name)
 666        (get-text-property (point) 'ibuffer-filter-group)
 667        (error "No filter group at point"))))
 668
 669 ;;;###autoload
 670 (defun ibuffer-yank-filter-group (name)
 671   "Yank the last killed filter group before group named NAME."
 672   (interactive (list (progn
 673                        (unless ibuffer-filter-group-kill-ring
 674                          (error "ibuffer-filter-group-kill-ring is empty"))
 675                        (ibuffer-read-filter-group-name
 676                         "Yank filter group before group: "))))
 677   (save-excursion
 678     (ibuffer-forward-line 0)
 679     (ibuffer-insert-filter-group-before (pop ibuffer-filter-group-kill-ring)
 680                                         name))
 681   (ibuffer-update nil t))
 682
 683 ;;;###autoload
 684 (defun ibuffer-save-filter-groups (name groups)
 685   "Save all active filter groups GROUPS as NAME.
 686 They are added to `ibuffer-saved-filter-groups'.  Interactively,
 687 prompt for NAME, and use the current filters."
 688   (interactive
 689    (if (null ibuffer-filter-groups)
 690        (error "No filter groups active")
 691      (list
 692       (read-from-minibuffer "Save current filter groups as: ")
 693       ibuffer-filter-groups)))
 694   (ibuffer-aif (assoc name ibuffer-saved-filter-groups)
 695       (setcdr it groups)
 696     (push (cons name groups) ibuffer-saved-filter-groups))
 697   (ibuffer-maybe-save-stuff)
 698   (ibuffer-update-mode-name))
 699
 700 ;;;###autoload
 701 (defun ibuffer-delete-saved-filter-groups (name)
 702   "Delete saved filter groups with NAME.
 703 They are removed from `ibuffer-saved-filter-groups'."
 704   (interactive
 705    (list
 706     (if (null ibuffer-saved-filter-groups)
 707         (error "No saved filter groups")
 708       (completing-read "Delete saved filter group: "
 709                        ibuffer-saved-filter-groups nil t))))
 710   (setq ibuffer-saved-filter-groups
 711         (ibuffer-delete-alist name ibuffer-saved-filter-groups))
 712   (ibuffer-maybe-save-stuff)
 713   (ibuffer-update nil t))
 714
 715 ;;;###autoload
 716 (defun ibuffer-switch-to-saved-filter-groups (name)
 717   "Set this buffer's filter groups to saved version with NAME.
 718 The value from `ibuffer-saved-filters' is used.
 719 If prefix argument ADD is non-nil, then add the saved filters instead
 720 of replacing the current filters."
 721   (interactive
 722    (list
 723     (if (null ibuffer-saved-filter-groups)
 724         (error "No saved filters")
 725       (completing-read "Switch to saved filter group: "
 726                        ibuffer-saved-filter-groups nil t))))
 727   (setq ibuffer-filter-groups (cdr (assoc name ibuffer-saved-filter-groups))
 728         ibuffer-hidden-filter-groups nil)
 729   (ibuffer-update nil t))
 730
 731 ;;;###autoload
 732 (defun ibuffer-filter-disable ()
 733   "Disable all filters currently in effect in this buffer."
 734   (interactive)
 735   (setq ibuffer-filtering-qualifiers nil)
 736   (ibuffer-update nil t))
 737
 738 ;;;###autoload
 739 (defun ibuffer-pop-filter ()
 740   "Remove the top filter in this buffer."
 741   (interactive)
 742   (when (null ibuffer-filtering-qualifiers)
 743     (error "No filters in effect"))
 744   (pop ibuffer-filtering-qualifiers)
 745   (ibuffer-update nil t))
 746
 747 (defun ibuffer-push-filter (qualifier)
 748   "Add QUALIFIER to `ibuffer-filtering-qualifiers'."
 749   (push qualifier ibuffer-filtering-qualifiers))
 750
 751 ;;;###autoload
 752 (defun ibuffer-decompose-filter ()
 753   "Separate the top compound filter (OR, NOT, or SAVED) in this buffer.
 754
 755 This means that the topmost filter on the filtering stack, which must
 756 be a complex filter like (OR [name: foo] [mode: bar-mode]), will be
 757 turned into two separate filters [name: foo] and [mode: bar-mode]."
 758   (interactive)
 759   (when (null ibuffer-filtering-qualifiers)
 760     (error "No filters in effect"))
 761   (let ((lim (pop ibuffer-filtering-qualifiers)))
 762     (case (car lim)
 763       (or
 764        (setq ibuffer-filtering-qualifiers (append
 765                                           (cdr lim)
 766                                           ibuffer-filtering-qualifiers)))
 767       (saved
 768        (let ((data
 769               (assoc (cdr lim)
 770                      ibuffer-saved-filters)))
 771          (unless data
 772            (ibuffer-filter-disable)
 773            (error "Unknown saved filter %s" (cdr lim)))
 774          (setq ibuffer-filtering-qualifiers (append
 775                                             (cadr data)
 776                                             ibuffer-filtering-qualifiers))))
 777       (not
 778        (push (cdr lim)
 779              ibuffer-filtering-qualifiers))
 780       (t
 781        (error "Filter type %s is not compound" (car lim)))))
 782   (ibuffer-update nil t))
 783
 784 ;;;###autoload
 785 (defun ibuffer-exchange-filters ()
 786   "Exchange the top two filters on the stack in this buffer."
 787   (interactive)
 788   (when (< (length ibuffer-filtering-qualifiers)
 789            2)
 790     (error "Need two filters to exchange"))
 791   (let ((first (pop ibuffer-filtering-qualifiers))
 792         (second (pop ibuffer-filtering-qualifiers)))
 793     (push first ibuffer-filtering-qualifiers)
 794     (push second ibuffer-filtering-qualifiers))
 795   (ibuffer-update nil t))
 796
 797 ;;;###autoload
 798 (defun ibuffer-negate-filter ()
 799   "Negate the sense of the top filter in the current buffer."
 800   (interactive)
 801   (when (null ibuffer-filtering-qualifiers)
 802     (error "No filters in effect"))
 803   (let ((lim (pop ibuffer-filtering-qualifiers)))
 804     (push (if (eq (car lim) 'not)
 805               (cdr lim)
 806             (cons 'not lim))
 807           ibuffer-filtering-qualifiers))
 808   (ibuffer-update nil t))
 809
 810 ;;;###autoload
 811 (defun ibuffer-or-filter (&optional reverse)
 812   "Replace the top two filters in this buffer with their logical OR.
 813 If optional argument REVERSE is non-nil, instead break the top OR
 814 filter into parts."
 815   (interactive "P")
 816   (if reverse
 817       (progn
 818         (when (or (null ibuffer-filtering-qualifiers)
 819                   (not (eq 'or (caar ibuffer-filtering-qualifiers))))
 820           (error "Top filter is not an OR"))
 821         (let ((lim (pop ibuffer-filtering-qualifiers)))
 822           (setq ibuffer-filtering-qualifiers (nconc (cdr lim) ibuffer-filtering-qualifiers))))
 823     (when (< (length ibuffer-filtering-qualifiers) 2)
 824       (error "Need two filters to OR"))
 825     ;; If the second filter is an OR, just add to it.
 826     (let ((first (pop ibuffer-filtering-qualifiers))
 827           (second (pop ibuffer-filtering-qualifiers)))
 828       (if (eq 'or (car second))
 829           (push (nconc (list 'or first) (cdr second)) ibuffer-filtering-qualifiers)
 830         (push (list 'or first second)
 831               ibuffer-filtering-qualifiers))))
 832   (ibuffer-update nil t))
 833
 834 (defun ibuffer-maybe-save-stuff ()
 835   (when ibuffer-save-with-custom
 836     (if (fboundp 'customize-save-variable)
 837         (progn
 838           (customize-save-variable 'ibuffer-saved-filters
 839                                    ibuffer-saved-filters)
 840           (customize-save-variable 'ibuffer-saved-filter-groups
 841                                    ibuffer-saved-filter-groups))
 842       (message "Not saved permanently: Customize not available"))))
 843
 844 ;;;###autoload
 845 (defun ibuffer-save-filters (name filters)
 846   "Save FILTERS in this buffer with name NAME in `ibuffer-saved-filters'.
 847 Interactively, prompt for NAME, and use the current filters."
 848   (interactive
 849    (if (null ibuffer-filtering-qualifiers)
 850        (error "No filters currently in effect")
 851      (list
 852       (read-from-minibuffer "Save current filters as: ")
 853       ibuffer-filtering-qualifiers)))
 854   (ibuffer-aif (assoc name ibuffer-saved-filters)
 855       (setcdr it filters)
 856     (push (list name filters) ibuffer-saved-filters))
 857   (ibuffer-maybe-save-stuff)
 858   (ibuffer-update-mode-name))
 859
 860 ;;;###autoload
 861 (defun ibuffer-delete-saved-filters (name)
 862   "Delete saved filters with NAME from `ibuffer-saved-filters'."
 863   (interactive
 864    (list
 865     (if (null ibuffer-saved-filters)
 866         (error "No saved filters")
 867       (completing-read "Delete saved filters: "
 868                        ibuffer-saved-filters nil t))))
 869   (setq ibuffer-saved-filters
 870         (ibuffer-delete-alist name ibuffer-saved-filters))
 871   (ibuffer-maybe-save-stuff)
 872   (ibuffer-update nil t))
 873
 874 ;;;###autoload
 875 (defun ibuffer-add-saved-filters (name)
 876   "Add saved filters from `ibuffer-saved-filters' to this buffer's filters."
 877   (interactive
 878    (list
 879     (if (null ibuffer-saved-filters)
 880         (error "No saved filters")
 881       (completing-read "Add saved filters: "
 882                        ibuffer-saved-filters nil t))))
 883   (push (cons 'saved name) ibuffer-filtering-qualifiers)
 884   (ibuffer-update nil t))
 885
 886 ;;;###autoload
 887 (defun ibuffer-switch-to-saved-filters (name)
 888   "Set this buffer's filters to filters with NAME from `ibuffer-saved-filters'.
 889 If prefix argument ADD is non-nil, then add the saved filters instead
 890 of replacing the current filters."
 891   (interactive
 892    (list
 893     (if (null ibuffer-saved-filters)
 894         (error "No saved filters")
 895       (completing-read "Switch to saved filters: "
 896                        ibuffer-saved-filters nil t))))
 897   (setq ibuffer-filtering-qualifiers (list (cons 'saved name)))
 898   (ibuffer-update nil t))
 899
 900 (defun ibuffer-format-filter-group-data (filter)
 901   (if (equal filter "Default")
 902       ""
 903     (concat "Filter: " (mapconcat #'ibuffer-format-qualifier
 904                                   (cdr (assq filter ibuffer-filter-groups))
 905                                   " ") "\n")))
 906
 907 (defun ibuffer-format-qualifier (qualifier)
 908   (if (eq (car-safe qualifier) 'not)
 909       (concat " [NOT" (ibuffer-format-qualifier-1 (cdr qualifier)) "]")
 910     (ibuffer-format-qualifier-1 qualifier)))
 911
 912 (defun ibuffer-format-qualifier-1 (qualifier)
 913   (case (car qualifier)
 914     (saved
 915      (concat " [filter: " (cdr qualifier) "]"))
 916     (or
 917      (concat " [OR" (mapconcat #'ibuffer-format-qualifier
 918                                (cdr qualifier) "") "]"))
 919     (t
 920      (let ((type (assq (car qualifier) ibuffer-filtering-alist)))
 921        (unless qualifier
 922          (error "Ibuffer: bad qualifier %s" qualifier))
 923        (concat " [" (cadr type) ": " (format "%s]" (cdr qualifier)))))))
 924
 925 ;;; Extra operation definitions
 926
 927 ;;;###autoload (autoload 'ibuffer-filter-by-mode "ibuf-ext.el")
 928 (define-ibuffer-filter mode
 929   "Toggle current view to buffers with major mode QUALIFIER."
 930   (:description "major mode"
 931    :reader
 932    (intern
 933     (completing-read "Filter by major mode: " obarray
 934                      #'(lambda (e)
 935                          (string-match "-mode$"
 936                                        (symbol-name e)))
 937                      t
 938                      (let ((buf (ibuffer-current-buffer)))
 939                        (if (and buf (buffer-live-p buf))
 940                            (with-current-buffer buf
 941                              (symbol-name major-mode))
 942                          "")))))
 943   (eq qualifier (with-current-buffer buf major-mode)))
 944
 945 ;;;###autoload (autoload 'ibuffer-filter-by-name "ibuf-ext.el")
 946 (define-ibuffer-filter name
 947   "Toggle current view to buffers with name matching QUALIFIER."
 948   (:description "buffer name"
 949    :reader (read-from-minibuffer "Filter by name (regexp): "))
 950   (string-match qualifier (buffer-name buf)))
 951
 952 ;;;###autoload (autoload 'ibuffer-filter-by-filename "ibuf-ext.el")
 953 (define-ibuffer-filter filename
 954   "Toggle current view to buffers with filename matching QUALIFIER."
 955   (:description "filename"
 956    :reader (read-from-minibuffer "Filter by filename (regexp): "))
 957   (ibuffer-awhen (buffer-file-name buf)
 958     (string-match qualifier it)))
 959
 960 ;;;###autoload (autoload 'ibuffer-filter-by-size-gt  "ibuf-ext.el")
 961 (define-ibuffer-filter size-gt
 962   "Toggle current view to buffers with size greater than QUALIFIER."
 963   (:description "size greater than"
 964    :reader
 965    (string-to-number (read-from-minibuffer "Filter by size greater than: ")))
 966   (> (with-current-buffer buf (buffer-size))
 967      qualifier))
 968
 969 ;;;###autoload (autoload 'ibuffer-filter-by-size-lt  "ibuf-ext.el")
 970 (define-ibuffer-filter size-lt
 971    "Toggle current view to buffers with size less than QUALIFIER."
 972   (:description "size less than"
 973    :reader
 974    (string-to-number (read-from-minibuffer "Filter by size less than: ")))
 975   (< (with-current-buffer buf (buffer-size))
 976      qualifier))
 977
 978 ;;;###autoload (autoload 'ibuffer-filter-by-content "ibuf-ext.el")
 979 (define-ibuffer-filter content
 980    "Toggle current view to buffers whose contents match QUALIFIER."
 981   (:description "content"
 982    :reader (read-from-minibuffer "Filter by content (regexp): "))
 983   (with-current-buffer buf
 984     (save-excursion
 985       (goto-char (point-min))
 986       (re-search-forward qualifier nil t))))
 987
 988 ;;;###autoload (autoload 'ibuffer-filter-by-predicate "ibuf-ext.el")
 989 (define-ibuffer-filter predicate
 990    "Toggle current view to buffers for which QUALIFIER returns non-nil."
 991   (:description "predicate"
 992    :reader (read-minibuffer "Filter by predicate (form): "))
 993   (with-current-buffer buf
 994     (eval qualifier)))
 995
 996 ;;; Sorting
 997
 998 ;;;###autoload
 999 (defun ibuffer-toggle-sorting-mode ()
1000   "Toggle the current sorting mode.
1001 Default sorting modes are:
1002  Recency - the last time the buffer was viewed
1003  Name - the name of the buffer
1004  Major Mode - the name of the major mode of the buffer
1005  Size - the size of the buffer"
1006   (interactive)
1007   (let ((modes (mapcar 'car ibuffer-sorting-functions-alist)))
1008     (add-to-list 'modes 'recency)
1009     (setq modes (sort modes 'string-lessp))
1010     (let ((next (or (car-safe (cdr-safe (memq ibuffer-sorting-mode modes)))
1011                     (car modes))))
1012       (setq ibuffer-sorting-mode next)
1013       (message "Sorting by %s" next)))
1014   (ibuffer-redisplay t))
1015
1016 ;;;###autoload
1017 (defun ibuffer-invert-sorting ()
1018   "Toggle whether or not sorting is in reverse order."
1019   (interactive)
1020   (setq ibuffer-sorting-reversep (not ibuffer-sorting-reversep))
1021   (message "Sorting order %s"
1022            (if ibuffer-sorting-reversep
1023                "reversed"
1024              "normal"))
1025   (ibuffer-redisplay t))
1026
1027 ;;;###autoload (autoload 'ibuffer-do-sort-by-major-mode "ibuf-ext.el")
1028 (define-ibuffer-sorter major-mode
1029   "Sort the buffers by major modes.
1030 Ordering is lexicographic."
1031   (:description "major mode")
1032   (string-lessp (downcase
1033                  (symbol-name (with-current-buffer
1034                                   (car a)
1035                                 major-mode)))
1036                 (downcase
1037                  (symbol-name (with-current-buffer
1038                                   (car b)
1039                                 major-mode)))))
1040
1041 ;;;###autoload (autoload 'ibuffer-do-sort-by-mode-name "ibuf-ext.el")
1042 (define-ibuffer-sorter mode-name
1043   "Sort the buffers by their mode name.
1044 Ordering is lexicographic."
1045   (:description "major mode name")
1046   (string-lessp (downcase
1047                   (with-current-buffer
1048                       (car a)
1049                     mode-name))
1050                 (downcase
1051                  (with-current-buffer
1052                      (car b)
1053                    mode-name))))
1054
1055 ;;;###autoload (autoload 'ibuffer-do-sort-by-alphabetic "ibuf-ext.el")
1056 (define-ibuffer-sorter alphabetic
1057   "Sort the buffers by their names.
1058 Ordering is lexicographic."
1059   (:description "buffer name")
1060   (string-lessp
1061    (buffer-name (car a))
1062    (buffer-name (car b))))
1063
1064 ;;;###autoload (autoload 'ibuffer-do-sort-by-size "ibuf-ext.el")
1065 (define-ibuffer-sorter size
1066  "Sort the buffers by their size."
1067   (:description "size")
1068   (< (with-current-buffer (car a)
1069        (buffer-size))
1070      (with-current-buffer (car b)
1071        (buffer-size))))
1072
1073 ;;; Functions to emulate bs.el
1074
1075 ;;;###autoload
1076 (defun ibuffer-bs-show ()
1077   "Emulate `bs-show' from the bs.el package."
1078   (interactive)
1079   (ibuffer t "*Ibuffer-bs*" '((filename . ".*")) nil t)
1080   (define-key (current-local-map) "a" 'ibuffer-bs-toggle-all))
1081
1082 (defun ibuffer-bs-toggle-all ()
1083   "Emulate `bs-toggle-show-all' from the bs.el package."
1084   (interactive)
1085   (if ibuffer-filtering-qualifiers
1086       (ibuffer-pop-filter)
1087     (progn (ibuffer-push-filter '(filename . ".*"))
1088            (ibuffer-update nil t))))
1089
1090 ;;; Handy functions
1091
1092 ;;;###autoload
1093 (defun ibuffer-add-to-tmp-hide (regexp)
1094   "Add REGEXP to `ibuffer-tmp-hide-regexps'.
1095 This means that buffers whose name matches REGEXP will not be shown
1096 for this ibuffer session."
1097   (interactive
1098    (list
1099     (read-from-minibuffer "Never show buffers matching: "
1100                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1101   (push regexp ibuffer-tmp-hide-regexps))
1102
1103 ;;;###autoload
1104 (defun ibuffer-add-to-tmp-show (regexp)
1105   "Add REGEXP to `ibuffer-tmp-show-regexps'.
1106 This means that buffers whose name matches REGEXP will always be shown
1107 for this ibuffer session."
1108   (interactive
1109    (list
1110     (read-from-minibuffer "Always show buffers matching: "
1111                           (regexp-quote (buffer-name (ibuffer-current-buffer t))))))
1112   (push regexp ibuffer-tmp-show-regexps))
1113
1114 ;;;###autoload
1115 (defun ibuffer-forward-next-marked (&optional count mark direction)
1116   "Move forward by COUNT marked buffers (default 1).
1117
1118 If MARK is non-nil, it should be a character denoting the type of mark
1119 to move by.  The default is `ibuffer-marked-char'.
1120
1121 If DIRECTION is non-nil, it should be an integer; negative integers
1122 mean move backwards, non-negative integers mean move forwards."
1123   (interactive "P")
1124   (unless count
1125     (setq count 1))
1126   (unless mark
1127     (setq mark ibuffer-marked-char))
1128   (unless direction
1129     (setq direction 1))
1130   ;; Skip the title
1131   (ibuffer-forward-line 0)
1132   (let ((opos (point))
1133         curmark)
1134     (ibuffer-forward-line direction)
1135     (while (not (or (= (point) opos)
1136                     (eq (setq curmark (ibuffer-current-mark))
1137                         mark)))
1138       (ibuffer-forward-line direction))
1139     (when (and (= (point) opos)
1140                (not (eq (ibuffer-current-mark) mark)))
1141       (error "No buffers with mark %c" mark))))
1142
1143 ;;;###autoload
1144 (defun ibuffer-backwards-next-marked (&optional count mark)
1145    "Move backwards by COUNT marked buffers (default 1).
1146
1147 If MARK is non-nil, it should be a character denoting the type of mark
1148 to move by.  The default is `ibuffer-marked-char'."
1149    (interactive "P")
1150    (ibuffer-forward-next-marked count mark -1))
1151
1152 ;;;###autoload
1153 (defun ibuffer-do-kill-lines ()
1154   "Hide all of the currently marked lines."
1155   (interactive)
1156   (if (= (ibuffer-count-marked-lines) 0)
1157       (message "No buffers marked; use 'm' to mark a buffer")
1158     (let ((count
1159            (ibuffer-map-marked-lines
1160             #'(lambda (buf mark)
1161                 'kill))))
1162       (message "Killed %s lines" count))))
1163
1164 ;;;###autoload
1165 (defun ibuffer-jump-to-buffer (name)
1166   "Move point to the buffer whose name is NAME."
1167   (interactive (list nil))
1168   (let ((table (mapcar #'(lambda (x)
1169                            (cons (buffer-name (car x))
1170                                  (caddr x)))
1171                        (ibuffer-current-state-list t))))
1172     (when (null table)
1173       (error "No buffers!"))
1174     (when (interactive-p)
1175       (setq name (completing-read "Jump to buffer: " table nil t)))
1176     (ibuffer-aif (assoc name table)
1177         (goto-char (cdr it))
1178       (error "No buffer with name %s" name))))
1179
1180 ;;;###autoload
1181 (defun ibuffer-diff-with-file ()
1182   "View the differences between this buffer and its associated file.
1183 This requires the external program \"diff\" to be in your `exec-path'."
1184   (interactive)
1185   (let* ((buf (ibuffer-current-buffer))
1186          (buf-filename (with-current-buffer buf
1187                          buffer-file-name)))
1188     (unless (buffer-live-p buf)
1189       (error "Buffer %s has been killed" buf))
1190     (unless buf-filename
1191       (error "Buffer %s has no associated file" buf))
1192     (let ((diff-buf (get-buffer-create "*Ibuffer-diff*")))
1193       (with-current-buffer diff-buf
1194         (setq buffer-read-only nil)
1195         (erase-buffer))
1196       (let ((tempfile (make-temp-file "ibuffer-diff-")))
1197         (unwind-protect
1198             (progn
1199               (with-current-buffer buf
1200                 (write-region (point-min) (point-max) tempfile nil 'nomessage))
1201               (if (zerop
1202                    (apply #'call-process "diff" nil diff-buf nil
1203                           (append
1204                            (when (and (boundp 'ediff-custom-diff-options)
1205                                       (stringp ediff-custom-diff-options))
1206                              (list ediff-custom-diff-options))
1207                            (list buf-filename tempfile))))
1208                   (message "No differences found")
1209                 (progn
1210                   (with-current-buffer diff-buf
1211                     (goto-char (point-min))
1212                     (if (fboundp 'diff-mode)
1213                         (diff-mode)
1214                       (fundamental-mode)))
1215                   (display-buffer diff-buf))))
1216           (when (file-exists-p tempfile)
1217             (delete-file tempfile)))))
1218       nil))
1219
1220 ;;;###autoload
1221 (defun ibuffer-copy-filename-as-kill (&optional arg)
1222   "Copy filenames of marked buffers into the kill ring.
1223 The names are separated by a space.
1224 If a buffer has no filename, it is ignored.
1225 With a zero prefix arg, use the complete pathname of each marked file.
1226
1227 You can then feed the file name(s) to other commands with C-y.
1228
1229  [ This docstring shamelessly stolen from the
1230  `dired-copy-filename-as-kill' in \"dired-x\". ]"
1231   ;; Add to docstring later:
1232   ;; With C-u, use the relative pathname of each marked file.
1233   (interactive "P")
1234   (if (= (ibuffer-count-marked-lines) 0)
1235       (message "No buffers marked; use 'm' to mark a buffer")
1236     (let ((ibuffer-copy-filename-as-kill-result "")
1237           (type (cond ((eql arg 0)
1238                        'full)
1239                       ;; ((eql arg 4)
1240                       ;;  'relative)
1241                       (t
1242                        'name))))
1243       (ibuffer-map-marked-lines
1244        #'(lambda (buf mark)
1245            (setq ibuffer-copy-filename-as-kill-result
1246                  (concat ibuffer-copy-filename-as-kill-result
1247                          (let ((name (buffer-file-name buf)))
1248                            (if name
1249                                (case type
1250                                  (full
1251                                   name)
1252                                  (t
1253                                   (file-name-nondirectory name)))
1254                              ""))
1255                          " "))))
1256       (push ibuffer-copy-filename-as-kill-result kill-ring))))
1257
1258 (defun ibuffer-mark-on-buffer (func &optional ibuffer-mark-on-buffer-mark group)
1259   (let ((count
1260          (ibuffer-map-lines
1261           #'(lambda (buf mark)
1262               (when (funcall func buf)
1263                 (ibuffer-set-mark-1 (or ibuffer-mark-on-buffer-mark
1264                                         ibuffer-marked-char))
1265                 t))
1266           nil
1267           group)))
1268     (ibuffer-redisplay t)
1269     (message "Marked %s buffers" count)))
1270
1271 ;;;###autoload
1272 (defun ibuffer-mark-by-name-regexp (regexp)
1273   "Mark all buffers whose name matches REGEXP."
1274   (interactive "sMark by name (regexp): ")
1275   (ibuffer-mark-on-buffer
1276    #'(lambda (buf)
1277        (string-match regexp (buffer-name buf)))))
1278
1279 ;;;###autoload
1280 (defun ibuffer-mark-by-mode-regexp (regexp)
1281   "Mark all buffers whose major mode matches REGEXP."
1282   (interactive "sMark by major mode (regexp): ")
1283   (ibuffer-mark-on-buffer
1284    #'(lambda (buf)
1285        (with-current-buffer buf
1286          (string-match regexp mode-name)))))
1287
1288 ;;;###autoload
1289 (defun ibuffer-mark-by-file-name-regexp (regexp)
1290   "Mark all buffers whose file name matches REGEXP."
1291   (interactive "sMark by file name (regexp): ")
1292   (ibuffer-mark-on-buffer
1293    #'(lambda (buf)
1294        (let ((name (or (buffer-file-name buf)
1295                        (with-current-buffer buf
1296                          (and
1297                           (boundp 'dired-directory)
1298                           (stringp dired-directory)
1299                           dired-directory)))))
1300          (when name
1301            (string-match regexp name))))))
1302
1303 ;;;###autoload
1304 (defun ibuffer-mark-by-mode (mode)
1305   "Mark all buffers whose major mode equals MODE."
1306   (interactive
1307    (list (intern (completing-read "Mark by major mode: " obarray
1308                                   #'(lambda (e)
1309                                       ;; kind of a hack...
1310                                       (and (fboundp e)
1311                                            (string-match "-mode$"
1312                                                          (symbol-name e))))
1313                                   t
1314                                   (let ((buf (ibuffer-current-buffer)))
1315                                     (if (and buf (buffer-live-p buf))
1316                                         (with-current-buffer buf
1317                                           (cons (symbol-name major-mode)
1318                                                 0))
1319                                       ""))))))
1320   (ibuffer-mark-on-buffer
1321    #'(lambda (buf)
1322        (with-current-buffer buf
1323          (eq major-mode mode)))))
1324
1325 ;;;###autoload
1326 (defun ibuffer-mark-modified-buffers ()
1327   "Mark all modified buffers."
1328   (interactive)
1329   (ibuffer-mark-on-buffer
1330    #'(lambda (buf) (buffer-modified-p buf))))
1331
1332 ;;;###autoload
1333 (defun ibuffer-mark-unsaved-buffers ()
1334   "Mark all modified buffers that have an associated file."
1335   (interactive)
1336   (ibuffer-mark-on-buffer
1337    #'(lambda (buf) (and (with-current-buffer buf buffer-file-name)
1338                         (buffer-modified-p buf)))))
1339
1340 ;;;###autoload
1341 (defun ibuffer-mark-dissociated-buffers ()
1342   "Mark all buffers whose associated file does not exist."
1343   (interactive)
1344   (ibuffer-mark-on-buffer
1345    #'(lambda (buf)
1346        (with-current-buffer buf
1347          (or
1348           (and buffer-file-name
1349                (not (file-exists-p buffer-file-name)))
1350           (and (eq major-mode 'dired-mode)
1351                (boundp 'dired-directory)
1352                (stringp dired-directory)
1353                (not (file-exists-p (file-name-directory dired-directory)))))))))
1354
1355 ;;;###autoload
1356 (defun ibuffer-mark-help-buffers ()
1357   "Mark buffers like *Help*, *Apropos*, *Info*."
1358   (interactive)
1359   (ibuffer-mark-on-buffer
1360    #'(lambda (buf)
1361        (with-current-buffer buf
1362          (memq major-mode ibuffer-help-buffer-modes)))))
1363
1364 ;;;###autoload
1365 (defun ibuffer-mark-old-buffers ()
1366   "Mark buffers which have not been viewed in `ibuffer-old-time' days."
1367   (interactive)
1368   (ibuffer-mark-on-buffer
1369    #'(lambda (buf)
1370        (with-current-buffer buf
1371          ;; hacked from midnight.el
1372          (when buffer-display-time
1373            (let* ((tm (current-time))
1374                   (now (+ (* (float (ash 1 16)) (car tm))
1375                           (float (cadr tm)) (* 0.0000001 (caddr tm))))
1376                   (then (+ (* (float (ash 1 16))
1377                               (car buffer-display-time))
1378                            (float (cadr buffer-display-time))
1379                            (* 0.0000001 (caddr buffer-display-time)))))
1380              (> (- now then) (* 60 60 ibuffer-old-time))))))))
1381
1382 ;;;###autoload
1383 (defun ibuffer-mark-special-buffers ()
1384   "Mark all buffers whose name begins and ends with '*'."
1385   (interactive)
1386   (ibuffer-mark-on-buffer
1387    #'(lambda (buf) (string-match "^\\*.+\\*$"
1388                                  (buffer-name buf)))))
1389
1390 ;;;###autoload
1391 (defun ibuffer-mark-read-only-buffers ()
1392   "Mark all read-only buffers."
1393   (interactive)
1394   (ibuffer-mark-on-buffer
1395    #'(lambda (buf)
1396        (with-current-buffer buf
1397          buffer-read-only))))
1398
1399 ;;;###autoload
1400 (defun ibuffer-mark-dired-buffers ()
1401   "Mark all `dired' buffers."
1402   (interactive)
1403   (ibuffer-mark-on-buffer
1404    #'(lambda (buf)
1405        (with-current-buffer buf
1406          (eq major-mode 'dired-mode)))))
1407
1408 ;;;###autoload
1409 (defun ibuffer-do-occur (regexp &optional nlines)
1410   "View lines which match REGEXP in all marked buffers.
1411 Optional argument NLINES says how many lines of context to display: it
1412 defaults to one."
1413   (interactive (occur-read-primary-args))
1414   (if (or (not (integerp nlines))
1415           (< nlines 0))
1416       (setq nlines 0))
1417   (when (zerop (ibuffer-count-marked-lines))
1418     (ibuffer-set-mark ibuffer-marked-char))
1419   (let ((ibuffer-do-occur-bufs nil))
1420     ;; Accumulate a list of marked buffers
1421     (ibuffer-map-marked-lines
1422      #'(lambda (buf mark)
1423          (push buf ibuffer-do-occur-bufs)))
1424     (occur-1 regexp nlines ibuffer-do-occur-bufs)))
1425
1426 (provide 'ibuf-ext)
1427
1428 ;;; ibuf-ext.el ends here