code.delx.au - gnu-emacs/blob - lisp/select.el

   1 ;;; select.el --- lisp portion of standard selection support
   2
   3 ;; Maintainer: FSF
   4 ;; Keywords: internal
   5
   6 ;; Copyright (c) 1993, 1994 Free Software Foundation, Inc.
   7 ;; Based partially on earlier release by Lucid.
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;;; Commentary:
  27
  28 ;;; Code:
  29
  30 ;; This is for temporary compatibility with pre-release Emacs 19.
  31 (defalias 'x-selection 'x-get-selection)
  32 (defun x-get-selection (&optional type data-type)
  33   "Return the value of an X Windows selection.
  34 The argument TYPE (default `PRIMARY') says which selection,
  35 and the argument DATA-TYPE (default `STRING') says
  36 how to convert the data.
  37
  38 TYPE may be `SECONDARY' or `CLIPBOARD', in addition to `PRIMARY'.
  39 DATA-TYPE is usually `STRING', but can also be one of the symbols
  40 in `selection-converter-alist', which see."
  41   (x-get-selection-internal (or type 'PRIMARY) (or data-type 'STRING)))
  42
  43 (defun x-get-clipboard ()
  44   "Return text pasted to the clipboard."
  45   (x-get-selection-internal 'CLIPBOARD 'STRING))
  46
  47 (defun x-set-selection (type data)
  48   "Make an X Windows selection of type TYPE and value DATA.
  49 The argument TYPE (default `PRIMARY') says which selection,
  50 and DATA specifies the contents.  DATA may be a string,
  51 a symbol, an integer (or a cons of two integers or list of two integers).
  52
  53 The selection may also be a cons of two markers pointing to the same buffer,
  54 or an overlay.  In these cases, the selection is considered to be the text
  55 between the markers *at whatever time the selection is examined*.
  56 Thus, editing done in the buffer after you specify the selection
  57 can alter the effective value of the selection.
  58
  59 The data may also be a vector of valid non-vector selection values.
  60
  61 Interactively, the text of the region is used as the selection value
  62 if the prefix arg is set."
  63   (interactive (if (not current-prefix-arg)
  64                    (list 'PRIMARY (read-string "Set text for pasting: "))
  65                  (list 'PRIMARY (buffer-substring (region-beginning) (region-end)))))
  66   ;; This is for temporary compatibility with pre-release Emacs 19.
  67   (if (stringp type)
  68       (setq type (intern type)))
  69   (or (x-valid-simple-selection-p data)
  70       (and (vectorp data)
  71            (let ((valid t)
  72                  (i (1- (length data))))
  73              (while (>= i 0)
  74                (or (x-valid-simple-selection-p (aref data i))
  75                    (setq valid nil))
  76                (setq i (1- i)))
  77              valid))
  78       (signal 'error (list "invalid selection" data)))
  79   (or type (setq type 'PRIMARY))
  80   (if data
  81       (x-own-selection-internal type data)
  82     (x-disown-selection-internal type))
  83   data)
  84
  85 (defun x-valid-simple-selection-p (data)
  86   (or (stringp data)
  87       (symbolp data)
  88       (integerp data)
  89       (and (consp data)
  90            (integerp (car data))
  91            (or (integerp (cdr data))
  92                (and (consp (cdr data))
  93                     (integerp (car (cdr data))))))
  94       (overlayp data)
  95       (and (consp data)
  96            (markerp (car data))
  97            (markerp (cdr data))
  98            (marker-buffer (car data))
  99            (marker-buffer (cdr data))
 100            (eq (marker-buffer (car data))
 101                (marker-buffer (cdr data)))
 102            (buffer-name (marker-buffer (car data)))
 103            (buffer-name (marker-buffer (cdr data))))))
 104 \f
 105 ;;; Cut Buffer support
 106
 107 (defun x-get-cut-buffer (&optional which-one)
 108   "Returns the value of one of the 8 X server cut-buffers.
 109 Optional arg WHICH-ONE should be a number from 0 to 7, defaulting to 0.
 110 Cut buffers are considered obsolete; you should use selections instead."
 111   (x-get-cut-buffer-internal
 112    (if which-one
 113        (aref [CUT_BUFFER0 CUT_BUFFER1 CUT_BUFFER2 CUT_BUFFER3
 114               CUT_BUFFER4 CUT_BUFFER5 CUT_BUFFER6 CUT_BUFFER7]
 115              which-one)
 116      'CUT_BUFFER0)))
 117
 118 (defun x-set-cut-buffer (string &optional push)
 119   "Store STRING into the X server's primary cut buffer.
 120 If PUSH is non-nil, also rotate the cut buffers:
 121 this means the previous value of the primary cut buffer moves the second
 122 cut buffer, and the second to the third, and so on (there are 8 buffers.)
 123 Cut buffers are considered obsolete; you should use selections instead."
 124   ;; Check the data type of STRING.
 125   (substring string 0 0)
 126   (if push
 127       (x-rotate-cut-buffers-internal 1))
 128   (x-store-cut-buffer-internal 'CUT_BUFFER0 string))
 129
 130 \f
 131 ;;; Functions to convert the selection into various other selection types.
 132 ;;; Every selection type that Emacs handles is implemented this way, except
 133 ;;; for TIMESTAMP, which is a special case.
 134
 135 (defun xselect-convert-to-string (selection type value)
 136   (cond ((stringp value)
 137          ;; Return the type as well, so that xselect.c could honor
 138          ;; requests whose type is STRING.
 139          (cons type value))
 140         ((overlayp value)
 141          (save-excursion
 142            (or (buffer-name (overlay-buffer value))
 143                (error "selection is in a killed buffer"))
 144            (set-buffer (overlay-buffer value))
 145            (buffer-substring (overlay-start value)
 146                              (overlay-end value))))
 147         ((and (consp value)
 148               (markerp (car value))
 149               (markerp (cdr value)))
 150          (or (eq (marker-buffer (car value)) (marker-buffer (cdr value)))
 151              (signal 'error
 152                      (list "markers must be in the same buffer"
 153                            (car value) (cdr value))))
 154          (save-excursion
 155            (set-buffer (or (marker-buffer (car value))
 156                            (error "selection is in a killed buffer")))
 157            (buffer-substring (car value) (cdr value))))
 158         (t nil)))
 159
 160 (defun xselect-convert-to-length (selection type value)
 161   (let ((value
 162          (cond ((stringp value)
 163                 (length value))
 164                ((overlayp value)
 165                 (abs (- (overlay-end value) (overlay-start value))))
 166                ((and (consp value)
 167                      (markerp (car value))
 168                      (markerp (cdr value)))
 169                 (or (eq (marker-buffer (car value))
 170                         (marker-buffer (cdr value)))
 171                     (signal 'error
 172                             (list "markers must be in the same buffer"
 173                                   (car value) (cdr value))))
 174                 (abs (- (car value) (cdr value)))))))
 175     (if value ; force it to be in 32-bit format.
 176         (cons (ash value -16) (logand value 65535))
 177       nil)))
 178
 179 (defun xselect-convert-to-targets (selection type value)
 180   ;; return a vector of atoms, but remove duplicates first.
 181   (let* ((all (cons 'TIMESTAMP (mapcar 'car selection-converter-alist)))
 182          (rest all))
 183     (while rest
 184       (cond ((memq (car rest) (cdr rest))
 185              (setcdr rest (delq (car rest) (cdr rest))))
 186             ((eq (car (cdr rest)) '_EMACS_INTERNAL)  ; shh, it's a secret
 187              (setcdr rest (cdr (cdr rest))))
 188             (t
 189              (setq rest (cdr rest)))))
 190     (apply 'vector all)))
 191
 192 (defun xselect-convert-to-delete (selection type value)
 193   (x-disown-selection-internal selection)
 194   ;; A return value of nil means that we do not know how to do this conversion,
 195   ;; and replies with an "error".  A return value of NULL means that we have
 196   ;; done the conversion (and any side-effects) but have no value to return.
 197   'NULL)
 198
 199 (defun xselect-convert-to-filename (selection type value)
 200   (cond ((overlayp value)
 201          (buffer-file-name (or (overlay-buffer value)
 202                                (error "selection is in a killed buffer"))))
 203         ((and (consp value)
 204               (markerp (car value))
 205               (markerp (cdr value)))
 206          (buffer-file-name (or (marker-buffer (car value))
 207                                (error "selection is in a killed buffer"))))
 208         (t nil)))
 209
 210 (defun xselect-convert-to-charpos (selection type value)
 211   (let (a b tmp)
 212     (cond ((cond ((overlayp value)
 213                   (setq a (overlay-start value)
 214                         b (overlay-end value)))
 215                  ((and (consp value)
 216                        (markerp (car value))
 217                        (markerp (cdr value)))
 218                   (setq a (car value)
 219                         b (cdr value))))
 220            (setq a (1- a) b (1- b)) ; zero-based
 221            (if (< b a) (setq tmp a a b b tmp))
 222            (cons 'SPAN
 223                  (vector (cons (ash a -16) (logand a 65535))
 224                          (cons (ash b -16) (logand b 65535))))))))
 225
 226 (defun xselect-convert-to-lineno (selection type value)
 227   (let (a b buf tmp)
 228     (cond ((cond ((and (consp value)
 229                        (markerp (car value))
 230                        (markerp (cdr value)))
 231                   (setq a (marker-position (car value))
 232                         b (marker-position (cdr value))
 233                         buf (marker-buffer (car value))))
 234                  ((overlayp value)
 235                   (setq buf (overlay-buffer value)
 236                         a (overlay-start value)
 237                         b (overlay-end value)))
 238                  )
 239            (save-excursion
 240              (set-buffer buf)
 241              (setq a (count-lines 1 a)
 242                    b (count-lines 1 b)))
 243            (if (< b a) (setq tmp a a b b tmp))
 244            (cons 'SPAN
 245                  (vector (cons (ash a -16) (logand a 65535))
 246                          (cons (ash b -16) (logand b 65535))))))))
 247
 248 (defun xselect-convert-to-colno (selection type value)
 249   (let (a b buf tmp)
 250     (cond ((cond ((and (consp value)
 251                        (markerp (car value))
 252                        (markerp (cdr value)))
 253                   (setq a (car value)
 254                         b (cdr value)
 255                         buf (marker-buffer a)))
 256                  ((overlayp value)
 257                   (setq buf (overlay-buffer value)
 258                         a (overlay-start value)
 259                         b (overlay-end value)))
 260                  )
 261            (save-excursion
 262              (set-buffer buf)
 263              (goto-char a)
 264              (setq a (current-column))
 265              (goto-char b)
 266              (setq b (current-column)))
 267            (if (< b a) (setq tmp a a b b tmp))
 268            (cons 'SPAN
 269                  (vector (cons (ash a -16) (logand a 65535))
 270                          (cons (ash b -16) (logand b 65535))))))))
 271
 272 (defun xselect-convert-to-os (selection type size)
 273   (symbol-name system-type))
 274
 275 (defun xselect-convert-to-host (selection type size)
 276   (system-name))
 277
 278 (defun xselect-convert-to-user (selection type size)
 279   (user-full-name))
 280
 281 (defun xselect-convert-to-class (selection type size)
 282   "Convert selection to class.
 283 This function returns the string \"Emacs\"."
 284   "Emacs")
 285
 286 ;; We do not try to determine the name Emacs was invoked with,
 287 ;; because it is not clean for a program's behavior to depend on that.
 288 (defun xselect-convert-to-name (selection type size)
 289   "Convert selection to name.
 290 This function returns the string \"emacs\"."
 291   "emacs")
 292
 293 (defun xselect-convert-to-integer (selection type value)
 294   (and (integerp value)
 295        (cons (ash value -16) (logand value 65535))))
 296
 297 (defun xselect-convert-to-atom (selection type value)
 298   (and (symbolp value) value))
 299
 300 (defun xselect-convert-to-identity (selection type value) ; used internally
 301   (vector value))
 302
 303 (setq selection-converter-alist
 304       '((TEXT . xselect-convert-to-string)
 305         (COMPOUND_TEXT . xselect-convert-to-string)
 306         (STRING . xselect-convert-to-string)
 307         (TARGETS . xselect-convert-to-targets)
 308         (LENGTH . xselect-convert-to-length)
 309         (DELETE . xselect-convert-to-delete)
 310         (FILE_NAME . xselect-convert-to-filename)
 311         (CHARACTER_POSITION . xselect-convert-to-charpos)
 312         (LINE_NUMBER . xselect-convert-to-lineno)
 313         (COLUMN_NUMBER . xselect-convert-to-colno)
 314         (OWNER_OS . xselect-convert-to-os)
 315         (HOST_NAME . xselect-convert-to-host)
 316         (USER . xselect-convert-to-user)
 317         (CLASS . xselect-convert-to-class)
 318         (NAME . xselect-convert-to-name)
 319         (ATOM . xselect-convert-to-atom)
 320         (INTEGER . xselect-convert-to-integer)
 321         (_EMACS_INTERNAL . xselect-convert-to-identity)
 322         ))
 323
 324 (provide 'select)
 325
 326 ;;; select.el ends here