code.delx.au - gnu-emacs/blob - lisp/mail/mail-utils.el

   1 ;;; mail-utils.el --- utility functions used both by rmail and rnews
   2
   3 ;; Copyright (C) 1985 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: mail, news
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ;; Utility functions for mail and netnews handling.  These handle fine
  27 ;; points of header parsing.
  28
  29 ;;; Code:
  30
  31 ;;; We require lisp-mode to make sure that lisp-mode-syntax-table has
  32 ;;; been initialized.
  33 (require 'lisp-mode)
  34
  35 ;;;###autoload
  36 (defvar mail-use-rfc822 nil "\
  37 *If non-nil, use a full, hairy RFC822 parser on mail addresses.
  38 Otherwise, (the default) use a smaller, somewhat faster, and
  39 often correct parser.")
  40
  41 ;; Returns t if file FILE is an Rmail file.
  42 ;;;###autoload
  43 (defun mail-file-babyl-p (file)
  44   (let ((buf (generate-new-buffer " *rmail-file-p*")))
  45     (unwind-protect
  46         (save-excursion
  47           (set-buffer buf)
  48           (insert-file-contents file nil 0 100)
  49           (looking-at "BABYL OPTIONS:"))
  50       (kill-buffer buf))))
  51
  52 (defun mail-string-delete (string start end)
  53   "Returns a string containing all of STRING except the part
  54 from START (inclusive) to END (exclusive)."
  55   (if (null end) (substring string 0 start)
  56     (concat (substring string 0 start)
  57             (substring string end nil))))
  58
  59 (defun mail-strip-quoted-names (address)
  60   "Delete comments and quoted strings in an address list ADDRESS.
  61 Also delete leading/trailing whitespace and replace FOO <BAR> with just BAR.
  62 Return a modified address list."
  63   (if (null address)
  64       nil
  65     (if mail-use-rfc822
  66         (progn (require 'rfc822)
  67                (mapconcat 'identity (rfc822-addresses address) ", "))
  68       (let (pos)
  69        (string-match "\\`[ \t\n]*" address)
  70        ;; strip surrounding whitespace
  71        (setq address (substring address
  72                                 (match-end 0)
  73                                 (string-match "[ \t\n]*\\'" address
  74                                               (match-end 0))))
  75
  76        ;; Detect nested comments.
  77        (if (string-match "[ \t]*(\\([^)\"\\]\\|\\\\.\\|\\\\\n\\)*(" address)
  78            ;; Strip nested comments.
  79            (save-excursion
  80              (set-buffer (get-buffer-create " *temp*"))
  81              (erase-buffer)
  82              (insert address)
  83              (set-syntax-table lisp-mode-syntax-table)
  84              (goto-char 1)
  85              (while (search-forward "(" nil t)
  86                (forward-char -1)
  87                (skip-chars-backward " \t")
  88                (delete-region (point)
  89                               (save-excursion
  90                                 (condition-case ()
  91                                     (forward-sexp 1)
  92                                   (error (goto-char (point-max))))
  93                                   (point))))
  94              (setq address (buffer-string))
  95              (erase-buffer))
  96          ;; Strip non-nested comments an easier way.
  97          (while (setq pos (string-match
  98                             ;; This doesn't hack rfc822 nested comments
  99                             ;;  `(xyzzy (foo) whinge)' properly.  Big deal.
 100                             "[ \t]*(\\([^)\"\\]\\|\\\\.\\|\\\\\n\\)*)"
 101                             address))
 102            (setq address
 103                  (mail-string-delete address
 104                                      pos (match-end 0)))))
 105
 106        ;; strip `quoted' names (This is supposed to hack `"Foo Bar" <bar@host>')
 107        (setq pos 0)
 108        (while (setq pos (string-match
 109                           "[ \t]*\"\\([^\"\\]\\|\\\\.\\|\\\\\n\\)*\"[ \t\n]*"
 110                           address pos))
 111          ;; If the next thing is "@", we have "foo bar"@host.  Leave it.
 112          (if (and (> (length address) (match-end 0))
 113                   (= (aref address (match-end 0)) ?@))
 114              (setq pos (match-end 0))
 115            (setq address
 116                  (mail-string-delete address
 117                                      pos (match-end 0)))))
 118        ;; Retain only part of address in <> delims, if there is such a thing.
 119        (while (setq pos (string-match "\\(,\\|\\`\\)[^,]*<\\([^>,]*>\\)"
 120                                       address))
 121          (let ((junk-beg (match-end 1))
 122                (junk-end (match-beginning 2))
 123                (close (match-end 0)))
 124            (setq address (mail-string-delete address (1- close) close))
 125            (setq address (mail-string-delete address junk-beg junk-end))))
 126        address))))
 127
 128 (or (and (boundp 'rmail-default-dont-reply-to-names)
 129          (not (null rmail-default-dont-reply-to-names)))
 130     (setq rmail-default-dont-reply-to-names "info-"))
 131
 132 ; rmail-dont-reply-to-names is defined in loaddefs
 133 (defun rmail-dont-reply-to (userids)
 134   "Returns string of mail addresses USERIDS sans any recipients
 135 that start with matches for `rmail-dont-reply-to-names'.
 136 Usenet paths ending in an element that matches are removed also."
 137   (if (null rmail-dont-reply-to-names)
 138       (setq rmail-dont-reply-to-names
 139             (concat (if rmail-default-dont-reply-to-names
 140                         (concat rmail-default-dont-reply-to-names "\\|")
 141                         "")
 142                     (concat (regexp-quote (user-login-name))
 143                             "\\>"))))
 144   (let ((match (concat "\\(^\\|,\\)[ \t\n]*\\([^,\n]*!\\|\\)\\("
 145                        rmail-dont-reply-to-names
 146                        "\\)"))
 147         (case-fold-search t)
 148         pos epos)
 149     (while (setq pos (string-match match userids))
 150       (if (> pos 0) (setq pos (1+ pos)))
 151       (setq epos
 152             (if (string-match "[ \t\n,]+" userids (match-end 0))
 153                 (match-end 0)
 154               (length userids)))
 155       (setq userids
 156             (mail-string-delete
 157               userids pos epos)))
 158     ;; get rid of any trailing commas
 159     (if (setq pos (string-match "[ ,\t\n]*\\'" userids))
 160         (setq userids (substring userids 0 pos)))
 161     ;; remove leading spaces. they bother me.
 162     (if (string-match "\\s *" userids)
 163         (substring userids (match-end 0))
 164       userids)))
 165 \f
 166 ;;;###autoload
 167 (defun mail-fetch-field (field-name &optional last all)
 168   "Return the value of the header field FIELD-NAME.
 169 The buffer is expected to be narrowed to just the headers of the message.
 170 If second arg LAST is non-nil, use the last such field if there are several.
 171 If third arg ALL is non-nil, concatenate all such fields with commas between."
 172   (save-excursion
 173     (goto-char (point-min))
 174     (let ((case-fold-search t)
 175           (name (concat "^" (regexp-quote field-name) "[ \t]*:[ \t]*")))
 176       (if all
 177           (let ((value ""))
 178             (while (re-search-forward name nil t)
 179               (let ((opoint (point)))
 180                 (while (progn (forward-line 1)
 181                               (looking-at "[ \t]")))
 182                 ;; Back up over newline, then trailing spaces or tabs
 183                 (forward-char -1)
 184                 (while (member (preceding-char) '(?  ?\t))
 185                   (forward-char -1))
 186                 (setq value (concat value
 187                                     (if (string= value "") "" ", ")
 188                                     (buffer-substring-no-properties
 189                                      opoint (point))))))
 190             (and (not (string= value "")) value))
 191         (if (re-search-forward name nil t)
 192             (progn
 193               (if last (while (re-search-forward name nil t)))
 194               (let ((opoint (point)))
 195                 (while (progn (forward-line 1)
 196                               (looking-at "[ \t]")))
 197                 ;; Back up over newline, then trailing spaces or tabs
 198                 (forward-char -1)
 199                 (while (member (preceding-char) '(?  ?\t))
 200                   (forward-char -1))
 201                 (buffer-substring-no-properties opoint (point)))))))))
 202 \f
 203 ;; Parse a list of tokens separated by commas.
 204 ;; It runs from point to the end of the visible part of the buffer.
 205 ;; Whitespace before or after tokens is ignored,
 206 ;; but whitespace within tokens is kept.
 207 (defun mail-parse-comma-list ()
 208   (let (accumulated
 209         beg)
 210     (skip-chars-forward " ")
 211     (while (not (eobp))
 212       (setq beg (point))
 213       (skip-chars-forward "^,")
 214       (skip-chars-backward " ")
 215       (setq accumulated
 216             (cons (buffer-substring beg (point))
 217                   accumulated))
 218       (skip-chars-forward "^,")
 219       (skip-chars-forward ", "))
 220     accumulated))
 221
 222 (defun mail-comma-list-regexp (labels)
 223   (let (pos)
 224     (setq pos (or (string-match "[^ \t]" labels) 0))
 225     ;; Remove leading and trailing whitespace.
 226     (setq labels (substring labels pos (string-match "[ \t]*$" labels pos)))
 227     ;; Change each comma to \|, and flush surrounding whitespace.
 228     (while (setq pos (string-match "[ \t]*,[ \t]*" labels))
 229       (setq labels
 230             (concat (substring labels 0 pos)
 231                     "\\|"
 232                     (substring labels (match-end 0))))))
 233   labels)
 234 \f
 235 (defun mail-rfc822-time-zone (time)
 236   (let* ((sec (or (car (current-time-zone time)) 0))
 237          (absmin (/ (abs sec) 60)))
 238     (format "%c%02d%02d" (if (< sec 0) ?- ?+) (/ absmin 60) (% absmin 60))))
 239
 240 (defun mail-rfc822-date ()
 241   (let* ((time (current-time))
 242          (s (current-time-string time)))
 243     (string-match "[^ ]+ +\\([^ ]+\\) +\\([^ ]+\\) \\([^ ]+\\) \\([^ ]+\\)" s)
 244     (concat (substring s (match-beginning 2) (match-end 2)) " "
 245             (substring s (match-beginning 1) (match-end 1)) " "
 246             (substring s (match-beginning 4) (match-end 4)) " "
 247             (substring s (match-beginning 3) (match-end 3)) " "
 248             (mail-rfc822-time-zone time))))
 249
 250 (provide 'mail-utils)
 251
 252 ;;; mail-utils.el ends here